qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/ipban.qh>
  39 #include <server/items/items.qh>
  40 #include <server/main.qh>
  41 #include <server/mapvoting.qh>
  42 #include <server/mutators/_mod.qh>
  43 #include <server/race.qh>
  44 #include <server/scores.qh>
  45 #include <server/scores_rules.qh>
  46 #include <server/spawnpoints.qh>
  47 #include <server/teamplay.qh>
  48 #include <server/weapons/weaponstats.qh>
  49
  50 const float LATENCY_THINKRATE = 10;
  51 .float latency_sum;
  52 .float latency_cnt;
  53 .float latency_time;
  54 entity pingplreport;
  55 void PingPLReport_Think(entity this)
  56 {
  57         float delta;
  58         entity e;
  59
  60         delta = 3 / maxclients;
  61         if(delta < sys_frametime)
  62                 delta = 0;
  63         this.nextthink = time + delta;
  64
  65         e = edict_num(this.cnt + 1);
  66         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  67         {
  68                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  69                 WriteByte(MSG_BROADCAST, this.cnt);
  70                 WriteShort(MSG_BROADCAST, bound(1, rint(CS(e).ping), 32767));
  71                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  72                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  73
  74                 // record latency times for clients throughout the match so we can report it to playerstats
  75                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  76                 {
  77                         CS(e).latency_sum += CS(e).ping;
  78                         CS(e).latency_cnt += 1;
  79                         CS(e).latency_time = time;
  80                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  81                 }
  82         }
  83         else
  84         {
  85                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  86                 WriteByte(MSG_BROADCAST, this.cnt);
  87                 WriteShort(MSG_BROADCAST, 0);
  88                 WriteByte(MSG_BROADCAST, 0);
  89                 WriteByte(MSG_BROADCAST, 0);
  90         }
  91         this.cnt = (this.cnt + 1) % maxclients;
  92 }
  93 void PingPLReport_Spawn()
  94 {
  95         pingplreport = new_pure(pingplreport);
  96         setthink(pingplreport, PingPLReport_Think);
  97         pingplreport.nextthink = time;
  98 }
  99
 100 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 101
 102 void SetDefaultAlpha()
 103 {
 104         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 105         {
 106                 default_player_alpha = autocvar_g_player_alpha;
 107                 if(default_player_alpha == 0)
 108                         default_player_alpha = 1;
 109                 default_weapon_alpha = default_player_alpha;
 110         }
 111 }
 112
 113 void GotoFirstMap(entity this)
 114 {
 115         float n;
 116         if(autocvar__sv_init)
 117         {
 118                 // cvar_set("_sv_init", "0");
 119                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 120                 // to this "init" map on a dedicated server will cause no permanent
 121                 // harm
 122                 if(autocvar_g_maplist_shuffle)
 123                         ShuffleMaplist();
 124                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 125                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 126
 127                 MapInfo_Enumerate();
 128                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 129
 130                 if(!DoNextMapOverride(1))
 131                         GotoNextMap(1);
 132
 133                 return;
 134         }
 135
 136         if(time < 5)
 137         {
 138                 this.nextthink = time;
 139         }
 140         else
 141         {
 142                 this.nextthink = time + 1;
 143                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 144         }
 145 }
 146
 147 void cvar_changes_init()
 148 {
 149         float h;
 150         string k, v, d;
 151         float n, i, adding, pureadding;
 152
 153         strfree(cvar_changes);
 154         strfree(cvar_purechanges);
 155         cvar_purechanges_count = 0;
 156
 157         h = buf_create();
 158         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 159         n = buf_getsize(h);
 160
 161         adding = true;
 162         pureadding = true;
 163
 164         for(i = 0; i < n; ++i)
 165         {
 166                 k = bufstr_get(h, i);
 167
 168 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 169 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 170 #define BADCVAR(p) if(k == p) continue
 171 #define BADVALUE(p, val) if (k == p && v == val) continue
 172
 173                 // general excludes and namespaces for server admin used cvars
 174                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 175
 176                 // internal
 177                 BADPREFIX("csqc_");
 178                 BADPREFIX("cvar_check_");
 179                 BADCVAR("gamecfg");
 180                 BADCVAR("g_configversion");
 181                 BADCVAR("halflifebsp");
 182                 BADCVAR("sv_mapformat_is_quake2");
 183                 BADCVAR("sv_mapformat_is_quake3");
 184                 BADPREFIX("sv_world");
 185
 186                 // client
 187                 BADPREFIX("chase_");
 188                 BADPREFIX("cl_");
 189                 BADPREFIX("con_");
 190                 BADPREFIX("scoreboard_");
 191                 BADPREFIX("g_campaign");
 192                 BADPREFIX("g_waypointsprite_");
 193                 BADPREFIX("gl_");
 194                 BADPREFIX("joy");
 195                 BADPREFIX("hud_");
 196                 BADPREFIX("m_");
 197                 BADPREFIX("menu_");
 198                 BADPREFIX("net_slist_");
 199                 BADPREFIX("r_");
 200                 BADPREFIX("sbar_");
 201                 BADPREFIX("scr_");
 202                 BADPREFIX("snd_");
 203                 BADPREFIX("show");
 204                 BADPREFIX("sensitivity");
 205                 BADPREFIX("userbind");
 206                 BADPREFIX("v_");
 207                 BADPREFIX("vid_");
 208                 BADPREFIX("crosshair");
 209                 BADCVAR("mod_q3bsp_lightmapmergepower");
 210                 BADCVAR("mod_q3bsp_nolightmaps");
 211                 BADCVAR("fov");
 212                 BADCVAR("mastervolume");
 213                 BADCVAR("volume");
 214                 BADCVAR("bgmvolume");
 215                 BADCVAR("in_pitch_min");
 216                 BADCVAR("in_pitch_max");
 217
 218                 // private
 219                 BADCVAR("developer");
 220                 BADCVAR("log_dest_udp");
 221                 BADCVAR("net_address");
 222                 BADCVAR("net_address_ipv6");
 223                 BADCVAR("port");
 224                 BADCVAR("savedgamecfg");
 225                 BADCVAR("serverconfig");
 226                 BADCVAR("sv_autoscreenshot");
 227                 BADCVAR("sv_heartbeatperiod");
 228                 BADCVAR("sv_vote_master_password");
 229                 BADCVAR("sys_colortranslation");
 230                 BADCVAR("sys_specialcharactertranslation");
 231                 BADCVAR("timeformat");
 232                 BADCVAR("timestamps");
 233                 BADCVAR("g_require_stats");
 234                 BADPREFIX("developer_");
 235                 BADPREFIX("g_ban_");
 236                 BADPREFIX("g_banned_list");
 237                 BADPREFIX("g_require_stats_");
 238                 BADPREFIX("g_chat_flood_");
 239                 BADPREFIX("g_ghost_items");
 240                 BADPREFIX("g_playerstats_");
 241                 BADPREFIX("g_voice_flood_");
 242                 BADPREFIX("log_file");
 243                 BADPREFIX("quit_");
 244                 BADPREFIX("rcon_");
 245                 BADPREFIX("sv_allowdownloads");
 246                 BADPREFIX("sv_autodemo");
 247                 BADPREFIX("sv_curl_");
 248                 BADPREFIX("sv_eventlog");
 249                 BADPREFIX("sv_logscores_");
 250                 BADPREFIX("sv_master");
 251                 BADPREFIX("sv_weaponstats_");
 252                 BADPREFIX("sv_waypointsprite_");
 253                 BADCVAR("rescan_pending");
 254
 255                 // these can contain player IDs, so better hide
 256                 BADPREFIX("g_forced_team_");
 257                 BADCVAR("sv_muteban_list");
 258                 BADCVAR("sv_voteban_list");
 259                 BADCVAR("sv_allow_customplayermodels_idlist");
 260                 BADCVAR("sv_allow_customplayermodels_speciallist");
 261
 262                 // mapinfo
 263                 BADCVAR("fraglimit");
 264                 BADCVAR("g_arena");
 265                 BADCVAR("g_assault");
 266                 BADCVAR("g_ca");
 267                 BADCVAR("g_ca_teams");
 268                 BADCVAR("g_conquest");
 269                 BADCVAR("g_conquest_teams");
 270                 BADCVAR("g_ctf");
 271                 BADCVAR("g_cts");
 272                 BADCVAR("g_dotc");
 273                 BADCVAR("g_dm");
 274                 BADCVAR("g_domination");
 275                 BADCVAR("g_domination_default_teams");
 276                 BADCVAR("g_duel");
 277                 BADCVAR("g_duel_not_dm_maps");
 278                 BADCVAR("g_freezetag");
 279                 BADCVAR("g_freezetag_teams");
 280                 BADCVAR("g_invasion_type");
 281                 BADCVAR("g_jailbreak");
 282                 BADCVAR("g_jailbreak_teams");
 283                 BADCVAR("g_keepaway");
 284                 BADCVAR("g_keyhunt");
 285                 BADCVAR("g_keyhunt_teams");
 286                 BADCVAR("g_lms");
 287                 BADCVAR("g_nexball");
 288                 BADCVAR("g_onslaught");
 289                 BADCVAR("g_race");
 290                 BADCVAR("g_race_laps_limit");
 291                 BADCVAR("g_race_qualifying_timelimit");
 292                 BADCVAR("g_race_qualifying_timelimit_override");
 293                 BADCVAR("g_runematch");
 294                 BADCVAR("g_shootfromeye");
 295                 BADCVAR("g_snafu");
 296                 BADCVAR("g_survival");
 297                 BADCVAR("g_survival_not_dm_maps");
 298                 BADCVAR("g_tdm");
 299                 BADCVAR("g_tdm_on_dm_maps");
 300                 BADCVAR("g_tdm_teams");
 301                 BADCVAR("g_vip");
 302                 BADCVAR("leadlimit");
 303                 BADCVAR("nextmap");
 304                 BADCVAR("teamplay");
 305                 BADCVAR("timelimit");
 306                 BADCVAR("g_mapinfo_settemp_acl");
 307                 BADCVAR("g_mapinfo_ignore_warnings");
 308                 BADCVAR("g_maplist_ignore_sizes");
 309                 BADCVAR("g_maplist_sizes_count_bots");
 310
 311                 // long
 312                 BADCVAR("hostname");
 313                 BADCVAR("g_maplist");
 314                 BADCVAR("g_maplist_mostrecent");
 315                 BADCVAR("sv_motd");
 316
 317                 v = cvar_string(k);
 318                 d = cvar_defstring(k);
 319                 if(v == d)
 320                         continue;
 321
 322                 if(adding)
 323                 {
 324                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 325                         if(strlen(cvar_changes) > 16384)
 326                         {
 327                                 cvar_changes = "// too many settings have been changed to show them here\n";
 328                                 adding = 0;
 329                         }
 330                 }
 331
 332                 // now check if the changes are actually gameplay relevant
 333
 334                 // does nothing gameplay relevant
 335                 BADCVAR("captureleadlimit_override");
 336                 BADCVAR("condump_stripcolors");
 337                 BADCVAR("gameversion");
 338                 BADCVAR("fs_gamedir");
 339                 BADCVAR("g_allow_oldvortexbeam");
 340                 BADCVAR("g_balance_kill_delay");
 341                 BADCVAR("g_buffs_pickup_anyway");
 342                 BADCVAR("g_buffs_randomize");
 343                 BADCVAR("g_buffs_randomize_teamplay");
 344                 BADCVAR("g_campcheck_distance");
 345                 BADCVAR("g_chatsounds");
 346                 BADCVAR("g_ca_point_leadlimit");
 347                 BADCVAR("g_ca_point_limit");
 348                 BADCVAR("g_ca_spectate_enemies");
 349                 BADCVAR("g_ctf_captimerecord_always");
 350                 BADCVAR("g_ctf_flag_glowtrails");
 351                 BADCVAR("g_ctf_dynamiclights");
 352                 BADCVAR("g_ctf_flag_pickup_verbosename");
 353                 BADCVAR("g_ctf_flagcarrier_auto_helpme_damage");
 354                 BADPRESUFFIX("g_ctf_flag_", "_model");
 355                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 356                 BADCVAR("g_domination_point_leadlimit");
 357                 BADCVAR("g_forced_respawn");
 358                 BADCVAR("g_freezetag_point_leadlimit");
 359                 BADCVAR("g_freezetag_point_limit");
 360                 BADCVAR("g_glowtrails");
 361                 BADCVAR("g_hats");
 362                 BADCVAR("g_casings");
 363                 BADCVAR("g_invasion_point_limit");
 364                 BADCVAR("g_jump_grunt");
 365                 BADCVAR("g_keepaway_ballcarrier_effects");
 366                 BADCVAR("g_keepawayball_effects");
 367                 BADCVAR("g_keyhunt_point_leadlimit");
 368                 BADCVAR("g_nexball_goalleadlimit");
 369                 BADCVAR("g_new_toys_autoreplace");
 370                 BADCVAR("g_new_toys_use_pickupsound");
 371                 BADCVAR("g_physics_predictall");
 372                 BADCVAR("g_piggyback");
 373                 BADCVAR("g_playerclip_collisions");
 374                 BADCVAR("g_spawn_alloweffects");
 375                 BADCVAR("g_tdm_point_leadlimit");
 376                 BADCVAR("g_tdm_point_limit");
 377                 BADCVAR("leadlimit_and_fraglimit");
 378                 BADCVAR("leadlimit_override");
 379                 BADCVAR("pausable");
 380                 BADCVAR("sv_announcer");
 381                 BADCVAR("sv_checkforpacketsduringsleep");
 382                 BADCVAR("sv_damagetext");
 383                 BADCVAR("sv_db_saveasdump");
 384                 BADCVAR("sv_intermission_cdtrack");
 385                 BADCVAR("sv_mapchange_delay");
 386                 BADCVAR("sv_minigames");
 387                 BADCVAR("sv_namechangetimer");
 388                 BADCVAR("sv_precacheplayermodels");
 389                 BADCVAR("sv_qcphysics");
 390                 BADCVAR("sv_radio");
 391                 BADCVAR("sv_stepheight");
 392                 BADCVAR("sv_timeout");
 393                 BADCVAR("sv_weapons_modeloverride");
 394                 BADCVAR("w_prop_interval");
 395                 BADPREFIX("chat_");
 396                 BADPREFIX("crypto_");
 397                 BADPREFIX("gameversion_");
 398                 BADPREFIX("g_chat_");
 399                 BADPREFIX("g_ctf_captimerecord_");
 400                 BADPREFIX("g_hats_");
 401                 BADPREFIX("g_maplist_");
 402                 BADPREFIX("g_mod_");
 403                 BADPREFIX("g_respawn_");
 404                 BADPREFIX("net_");
 405                 BADPREFIX("notification_");
 406                 BADPREFIX("prvm_");
 407                 BADPREFIX("skill_");
 408                 BADPREFIX("sv_allow_");
 409                 BADPREFIX("sv_cullentities_");
 410                 BADPREFIX("sv_maxidle");
 411                 BADPREFIX("sv_minigames_");
 412                 BADPREFIX("sv_radio_");
 413                 BADPREFIX("sv_timeout_");
 414                 BADPREFIX("sv_vote_");
 415                 BADPREFIX("timelimit_");
 416                 BADPRESUFFIX("g_", "_round_timelimit");
 417
 418                 // allowed changes to server admins (please sync this to server.cfg)
 419                 // vi commands:
 420                 //   :/"impure"/,$d
 421                 //   :g!,^\/\/[^ /],d
 422                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 423                 //   :%!sort
 424                 // yes, this does contain some redundant stuff, don't really care
 425                 BADPREFIX("bot_ai_");
 426                 BADCVAR("bot_config_file");
 427                 BADCVAR("bot_number");
 428                 BADCVAR("bot_prefix");
 429                 BADCVAR("bot_suffix");
 430                 BADCVAR("capturelimit_override");
 431                 BADCVAR("fraglimit_override");
 432                 BADCVAR("gametype");
 433                 BADCVAR("g_antilag");
 434                 BADCVAR("g_balance_teams");
 435                 BADCVAR("g_balance_teams_prevent_imbalance");
 436                 BADCVAR("g_balance_teams_scorefactor");
 437                 BADCVAR("g_ban_sync_trusted_servers");
 438                 BADCVAR("g_ban_sync_uri");
 439                 BADCVAR("g_buffs");
 440                 BADCVAR("g_ca_teams_override");
 441                 BADCVAR("g_ctf_fullbrightflags");
 442                 BADCVAR("g_ctf_ignore_frags");
 443                 BADCVAR("g_ctf_leaderboard");
 444                 BADCVAR("g_domination_point_limit");
 445                 BADCVAR("g_domination_teams_override");
 446                 BADCVAR("g_freezetag_revive_spawnshield");
 447                 BADCVAR("g_freezetag_teams_override");
 448                 BADCVAR("g_friendlyfire");
 449                 BADCVAR("g_fullbrightitems");
 450                 BADCVAR("g_fullbrightplayers");
 451                 BADCVAR("g_keyhunt_point_limit");
 452                 BADCVAR("g_keyhunt_teams_override");
 453                 BADCVAR("g_lms_lives_override");
 454                 BADCVAR("g_maplist");
 455                 BADCVAR("g_maxplayers");
 456                 BADCVAR("g_mirrordamage");
 457                 BADCVAR("g_nexball_goallimit");
 458                 BADCVAR("g_norecoil");
 459                 BADCVAR("g_physics_clientselect");
 460                 BADCVAR("g_pinata");
 461                 BADCVAR("g_powerups");
 462                 BADCVAR("g_powerups_drop_ondeath");
 463                 BADCVAR("g_player_brightness");
 464                 BADCVAR("g_rocket_flying");
 465                 BADCVAR("g_rocket_flying_disabledelays");
 466                 BADPREFIX("g_spawnshield");
 467                 BADCVAR("g_start_delay");
 468                 BADCVAR("g_superspectate");
 469                 BADCVAR("g_tdm_teams_override");
 470                 BADCVAR("g_warmup");
 471                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 472                 BADCVAR("hostname");
 473                 BADCVAR("log_file");
 474                 BADCVAR("maxplayers");
 475                 BADCVAR("minplayers");
 476                 BADCVAR("minplayers_per_team");
 477                 BADCVAR("net_address");
 478                 BADCVAR("port");
 479                 BADCVAR("rcon_password");
 480                 BADCVAR("rcon_restricted_commands");
 481                 BADCVAR("rcon_restricted_password");
 482                 BADCVAR("skill");
 483                 BADCVAR("sv_adminnick");
 484                 BADCVAR("sv_autoscreenshot");
 485                 BADCVAR("sv_autotaunt");
 486                 BADCVAR("sv_curl_defaulturl");
 487                 BADCVAR("sv_defaultcharacter");
 488                 BADCVAR("sv_defaultcharacterskin");
 489                 BADCVAR("sv_defaultplayercolors");
 490                 BADCVAR("sv_defaultplayermodel");
 491                 BADCVAR("sv_defaultplayerskin");
 492                 BADCVAR("sv_maxrate");
 493                 BADCVAR("sv_motd");
 494                 BADCVAR("sv_public");
 495                 BADCVAR("sv_showfps");
 496                 BADCVAR("sv_showspectators");
 497                 BADCVAR("sv_status_privacy");
 498                 BADCVAR("sv_taunt");
 499                 BADCVAR("sv_vote_call");
 500                 BADCVAR("sv_vote_commands");
 501                 BADCVAR("sv_vote_majority_factor");
 502                 BADCVAR("sv_vote_master");
 503                 BADCVAR("sv_vote_master_commands");
 504                 BADCVAR("sv_vote_master_password");
 505                 BADCVAR("sv_vote_simple_majority_factor");
 506                 BADVALUE("sys_ticrate", "0.0166667");
 507                 BADVALUE("sys_ticrate", "0.0333333");
 508                 BADCVAR("teamplay_mode");
 509                 BADCVAR("timelimit_override");
 510                 BADPREFIX("g_warmup_");
 511                 BADPREFIX("sv_info_");
 512                 BADPREFIX("sv_ready_restart_");
 513
 514                 // mutators that announce themselves properly to the server browser
 515                 BADCVAR("g_instagib");
 516                 BADCVAR("g_new_toys");
 517                 BADCVAR("g_nix");
 518                 BADCVAR("g_grappling_hook");
 519                 BADCVAR("g_jetpack");
 520
 521                 // temporary for testing
 522                 // TODO remove before 0.8.3 release
 523                 BADCVAR("g_ca_weaponarena");
 524                 BADCVAR("g_freezetag_weaponarena");
 525                 BADCVAR("g_lms_weaponarena");
 526                 BADCVAR("g_ctf_stalemate_time");
 527
 528 #undef BADPRESUFFIX
 529 #undef BADPREFIX
 530 #undef BADCVAR
 531 #undef BADVALUE
 532
 533                 if(pureadding)
 534                 {
 535                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 536                         if(strlen(cvar_purechanges) > 16384)
 537                         {
 538                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 539                                 pureadding = 0;
 540                         }
 541                 }
 542                 ++cvar_purechanges_count;
 543                 // WARNING: this variable is used for the server list
 544                 // NEVER dare to skip this code!
 545                 // Hacks to intentionally appearing as "pure server" even though you DO have
 546                 // modified settings may be punished by removal from the server list.
 547                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 548                 // though.
 549         }
 550         buf_del(h);
 551         if(cvar_changes == "")
 552                 cvar_changes = "// this server runs at default server settings\n";
 553         else
 554                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 555         cvar_changes = strzone(cvar_changes);
 556         if(cvar_purechanges == "")
 557                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 558         else
 559                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 560         cvar_purechanges = strzone(cvar_purechanges);
 561 }
 562
 563 entity randomseed;
 564 bool RandomSeed_Send(entity this, entity to, int sf)
 565 {
 566         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 567         WriteShort(MSG_ENTITY, this.cnt);
 568         return true;
 569 }
 570 void RandomSeed_Think(entity this)
 571 {
 572         this.cnt = bound(0, floor(random() * 65536), 65535);
 573         this.nextthink = time + 5;
 574
 575         this.SendFlags |= 1;
 576 }
 577 void RandomSeed_Spawn()
 578 {
 579         randomseed = new_pure(randomseed);
 580         setthink(randomseed, RandomSeed_Think);
 581         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 582
 583         getthink(randomseed)(randomseed); // sets random seed and nextthink
 584 }
 585
 586 spawnfunc(__init_dedicated_server)
 587 {
 588         // handler for _init/_init map (only for dedicated server initialization)
 589
 590         world_initialized = -1; // don't complain
 591
 592         delete_fn = remove_unsafely;
 593
 594         entity e = new(GotoFirstMap);
 595         setthink(e, GotoFirstMap);
 596         e.nextthink = time; // this is usually 1 at this point
 597
 598         e = new(info_player_deathmatch);  // safeguard against player joining
 599
 600     // assign reflectively to avoid "assignment to world" warning
 601     for (int i = 0, n = numentityfields(); i < n; ++i) {
 602         string k = entityfieldname(i);
 603         if (k == "classname") {
 604             // safeguard against various stuff ;)
 605             putentityfieldstring(i, this, "worldspawn");
 606             break;
 607         }
 608     }
 609
 610         // needs to be done so early because of the constants they create
 611         static_init();
 612         static_init_late();
 613         static_init_precache();
 614
 615         IL_PUSH(g_spawnpoints, e); // just incase
 616
 617         MapInfo_Enumerate();
 618         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 619 }
 620
 621 void __init_dedicated_server_shutdown() {
 622         MapInfo_Shutdown();
 623 }
 624
 625 STATIC_INIT_EARLY(maxclients)
 626 {
 627         maxclients = 0;
 628         for (entity head = nextent(NULL); head; head = nextent(head)) {
 629                 ++maxclients;
 630         }
 631 }
 632
 633 void GameplayMode_DelayedInit(entity this)
 634 {
 635         if(!scores_initialized)
 636                 ScoreRules_generic();
 637 }
 638
 639 void InitGameplayMode()
 640 {
 641         VoteReset();
 642
 643         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 644         get_mi_min_max(1);
 645         // assign reflectively to avoid "assignment to world" warning
 646         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 647             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 648             if (v) {
 649             putentityfieldstring(i, world, sprintf("%v", v));
 650             if (++done == 2) break;
 651         }
 652         }
 653         // currently, NetRadiant's limit is 131072 qu for each side
 654         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 655         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 656         // in case somebody makes extremely large maps
 657         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 658
 659         MapInfo_LoadMapSettings(mapname);
 660         GameRules_teams(false);
 661
 662         if (!cvar_value_issafe(world.fog))
 663         {
 664                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 665                 world.fog = string_null;
 666         }
 667         if(MapInfo_Map_fog != "")
 668         {
 669                 if(MapInfo_Map_fog == "none")
 670                         world.fog = string_null;
 671                 else
 672                         world.fog = strzone(MapInfo_Map_fog);
 673         }
 674         clientstuff = strzone(MapInfo_Map_clientstuff);
 675
 676         MapInfo_ClearTemps();
 677
 678         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 679
 680         cache_mutatormsg = strzone("");
 681         cache_lastmutatormsg = strzone("");
 682
 683         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 684 }
 685
 686 bool world_already_spawned;
 687 spawnfunc(worldspawn)
 688 {
 689         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 690
 691         if (autocvar_sv_termsofservice_url && autocvar_sv_termsofservice_url != "")
 692         {
 693                 strcpy(sv_termsofservice_url_escaped, strreplace(":", "|", autocvar_sv_termsofservice_url));
 694         }
 695         else
 696         {
 697                 strcpy(sv_termsofservice_url_escaped, "INVALID");
 698         }
 699
 700         bool wantrestart = false;
 701         {
 702                 if (!server_is_dedicated)
 703                 {
 704                         // force unloading of server pk3 files when starting a listen server
 705                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 706                         // restore csqc_progname too
 707                         string expect = "csprogs.dat";
 708                         wantrestart = cvar_string("csqc_progname") != expect;
 709                         cvar_set("csqc_progname", expect);
 710                 }
 711                 else
 712                 {
 713                         // Try to use versioned csprogs from pk3
 714                         // Only ever use versioned csprogs.dat files on dedicated servers;
 715                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 716                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 717                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 718                         string select = "csprogs.dat";
 719                         if (fexists(pk3csprogs)) select = pk3csprogs;
 720                         if (cvar_string("csqc_progname") != select)
 721                         {
 722                                 cvar_set("csqc_progname", select);
 723                                 wantrestart = true;
 724                         }
 725                         // Check for updates on startup
 726                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 727                         int sentinel = fopen("progs.txt", FILE_READ);
 728                         if (sentinel >= 0)
 729                         {
 730                                 string switchversion = fgets(sentinel);
 731                                 fclose(sentinel);
 732                                 if (switchversion != "" && switchversion != WATERMARK)
 733                                 {
 734                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 735                                         // if it doesn't exist, assume either:
 736                                         //   a) the current program was overwritten
 737                                         //   b) this is a client only update
 738                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 739                                         if (fexists(newprogs))
 740                                         {
 741                                                 cvar_set("sv_progs", newprogs);
 742                                                 wantrestart = true;
 743                                         }
 744                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 745                                         if (fexists(newcsprogs))
 746                                         {
 747                                                 cvar_set("csqc_progname", newcsprogs);
 748                                                 wantrestart = true;
 749                                         }
 750                                 }
 751                         }
 752                 }
 753                 if (wantrestart)
 754                 {
 755                         LOG_INFO("Restart requested");
 756                         changelevel(mapname);
 757                         // let initialization continue, shutdown depends on it
 758                 }
 759         }
 760
 761         if(world_already_spawned)
 762                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 763         world_already_spawned = true;
 764
 765         delete_fn = remove_safely; // during spawning, watch what you remove!
 766
 767         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 768
 769         // default to RACE_RECORD, can be overwritten by gamemodes
 770         record_type = RACE_RECORD;
 771
 772         // needs to be done so early because of the constants they create
 773         static_init();
 774
 775         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 776
 777         TemporaryDB = db_create();
 778
 779         // 0 normal
 780         lightstyle(0, "m");
 781
 782         // 1 FLICKER (first variety)
 783         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 784
 785         // 2 SLOW STRONG PULSE
 786         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 787
 788         // 3 CANDLE (first variety)
 789         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 790
 791         // 4 FAST STROBE
 792         lightstyle(4, "mamamamamama");
 793
 794         // 5 GENTLE PULSE 1
 795         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 796
 797         // 6 FLICKER (second variety)
 798         lightstyle(6, "nmonqnmomnmomomno");
 799
 800         // 7 CANDLE (second variety)
 801         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 802
 803         // 8 CANDLE (third variety)
 804         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 805
 806         // 9 SLOW STROBE (fourth variety)
 807         lightstyle(9, "aaaaaaaazzzzzzzz");
 808
 809         // 10 FLUORESCENT FLICKER
 810         lightstyle(10, "mmamammmmammamamaaamammma");
 811
 812         // 11 SLOW PULSE NOT FADE TO BLACK
 813         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 814
 815         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 816
 817         // 63 testing
 818         lightstyle(63, "a");
 819
 820         if(autocvar_g_campaign)
 821                 CampaignPreInit();
 822         else
 823                 PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 824
 825         Map_MarkAsRecent(mapname);
 826
 827         InitGameplayMode();
 828         static_init_late();
 829         static_init_precache();
 830         readlevelcvars();
 831
 832         GameRules_limit_fallbacks();
 833
 834         if(warmup_limit == 0)
 835                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 836
 837         player_count = 0;
 838         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 839         if(bot_waypoints_for_items == 1)
 840                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 841                         bot_waypoints_for_items = 0;
 842
 843         WaypointSprite_Init();
 844
 845         // NOTE for matchid:
 846         // changing the logic generating it is okay. But:
 847         // it HAS to stay <= 64 chars
 848         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 849         // strftime(false, "%s") isn't reliable, see strftime_s description
 850         matchid = strzone(sprintf("%d.%s.%06d", autocvar_sv_eventlog_files_counter, strftime_s(), random() * 1000000));
 851
 852         if(autocvar_sv_eventlog)
 853                 GameLogInit(); // requires matchid to be set
 854
 855         cvar_set("nextmap", "");
 856
 857         SetDefaultAlpha();
 858
 859         if(autocvar_g_campaign)
 860                 CampaignPostInit();
 861
 862         Ban_LoadBans();
 863
 864         MapInfo_Enumerate();
 865         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 866
 867         q3compat = BITSET(q3compat, Q3COMPAT_ARENA, fexists(strcat("scripts/", mapname, ".arena")));
 868         q3compat = BITSET(q3compat, Q3COMPAT_DEFI, fexists(strcat("scripts/", mapname, ".defi")));
 869
 870         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 871         {
 872                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 873                 if(fd != -1)
 874                 {
 875                         string s;
 876                         while((s = fgets(fd)))
 877                         {
 878                                 int l = tokenize_console(s);
 879                                 if(l < 2)
 880                                         continue;
 881                                 if(argv(0) == "cd")
 882                                 {
 883                                         string trackname = argv(2);
 884                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 885                                         LOG_INFO("  cdtrack ", trackname);
 886                                         if (cvar_value_issafe(trackname))
 887                                         {
 888                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 889                                                 strcpy(clientstuff, newstuff);
 890                                         }
 891                                 }
 892                                 else if(argv(0) == "fog")
 893                                 {
 894                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 895                                         LOG_INFO("  \"fog\" \"", s, "\"");
 896                                 }
 897                                 else if(argv(0) == "set")
 898                                 {
 899                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 900                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 901                                 }
 902                                 else if(argv(0) != "//")
 903                                 {
 904                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 905                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 906                                 }
 907                         }
 908                         fclose(fd);
 909                 }
 910         }
 911
 912         WeaponStats_Init();
 913
 914         Nagger_Init();
 915
 916         // set up information replies for clients and server to use
 917         maplist_reply = strzone(getmaplist());
 918         lsmaps_reply = strzone(getlsmaps());
 919         monsterlist_reply = strzone(getmonsterlist());
 920         bool records_available = false;
 921         for(int i = 0; i < 10; ++i)
 922         {
 923                 string s = getrecords(i);
 924                 if (s != "")
 925                 {
 926                         records_reply[i] = strzone(s);
 927                         records_available = true;
 928                 }
 929         }
 930         if (!records_available)
 931                 records_reply[0] = "No records available for the current game mode.\n";
 932         ladder_reply = strzone(getladder());
 933         rankings_reply = strzone(getrankings());
 934
 935         // begin other init
 936         ClientInit_Spawn();
 937         RandomSeed_Spawn();
 938         PingPLReport_Spawn();
 939
 940         CheatInit();
 941
 942         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 943
 944         // fill sv_curl_serverpackages from .serverpackage files
 945         if (autocvar_sv_curl_serverpackages_auto)
 946         {
 947                 string s = "csprogs-" WATERMARK ".dat";
 948                 // remove automatically managed files from the list to prevent duplicates
 949                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 950                 {
 951                         string pkg = argv(i);
 952                         if (startsWith(pkg, "csprogs-")) continue;
 953                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 954                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 955                         s = cons(s, pkg);
 956                 }
 957                 // add automatically managed files to the list
 958                 #define X(match) MACRO_BEGIN \
 959                         int fd = search_begin(match, true, false); \
 960                         if (fd >= 0) \
 961                         { \
 962                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 963                                 { \
 964                                         s = cons(s, search_getfilename(fd, i)); \
 965                                 } \
 966                                 search_end(fd); \
 967                         } \
 968                 MACRO_END
 969                 X("*-serverpackage.txt");
 970                 X("*.serverpackage");
 971                 #undef X
 972                 cvar_set("sv_curl_serverpackages", s);
 973         }
 974
 975         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 976         modname = "Xonotic";
 977         // physics/balance/config changes that count as mod
 978         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 979                 modname = cvar_string("g_mod_physics");
 980         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
 981                 modname = cvar_string("g_mod_balance");
 982         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 983                 modname = cvar_string("g_mod_config");
 984         // extra mutators that deserve to count as mod
 985         MUTATOR_CALLHOOK(SetModname, modname);
 986         modname = M_ARGV(0, string);
 987
 988         // save it for later
 989         modname = strzone(modname);
 990
 991         WinningConditionHelper(this); // set worldstatus
 992
 993         world_initialized = 1;
 994         __spawnfunc_spawn_all();
 995 }
 996
 997 spawnfunc(light)
 998 {
 999         //makestatic (this); // Who the f___ did that?
1000         delete(this);
1001 }
1002
1003 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance, bool frompos)
1004 {
1005     float m = e.dphitcontentsmask;
1006     e.dphitcontentsmask = goodcontents | badcontents;
1007
1008     vector org = boundmin;
1009     vector delta = boundmax - boundmin;
1010
1011     vector start, end;
1012     start = end = org;
1013     int j; // used after the loop
1014     for(j = 0; j < attempts; ++j)
1015     {
1016         start.x = org.x + random() * delta.x;
1017         start.y = org.y + random() * delta.y;
1018         start.z = org.z + random() * delta.z;
1019
1020         // rule 1: start inside world bounds, and outside
1021         // solid, and don't start from somewhere where you can
1022         // fall down to evil
1023         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1024         if (trace_fraction >= 1)
1025             continue;
1026         if (trace_startsolid)
1027             continue;
1028         if (trace_dphitcontents & badcontents)
1029             continue;
1030         if (trace_dphitq3surfaceflags & badsurfaceflags)
1031             continue;
1032
1033         // rule 2: if we are too high, lower the point
1034         if (trace_fraction * delta.z > maxaboveground)
1035             start = trace_endpos + '0 0 1' * maxaboveground;
1036         vector enddown = trace_endpos;
1037
1038         // rule 3: make sure we aren't outside the map. This only works
1039         // for somewhat well formed maps. A good rule of thumb is that
1040         // the map should have a convex outside hull.
1041         // these can be traceLINES as we already verified the starting box
1042         vector mstart = start + 0.5 * (e.mins + e.maxs);
1043         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1044         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1045             continue;
1046         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1047         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1048             continue;
1049         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1050         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1051             continue;
1052         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1053         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1054             continue;
1055         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1056         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1057             continue;
1058
1059                 // rule 4: we must "see" some spawnpoint or item
1060                 entity sp = NULL;
1061                 if(frompos)
1062                 {
1063                         if((traceline(mstart, e.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1064                                 sp = e;
1065                 }
1066                 if(!sp)
1067                 {
1068                         IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1069                         {
1070                                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1071                                 {
1072                                         sp = it;
1073                                         break;
1074                                 }
1075                         });
1076                 }
1077                 if(!sp)
1078                 {
1079                         int items_checked = 0;
1080                         IL_EACH(g_items, checkpvs(mstart, it),
1081                         {
1082                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1083                                 {
1084                                         sp = it;
1085                                         break;
1086                                 }
1087
1088                                 ++items_checked;
1089                                 if(items_checked >= attempts)
1090                                         break; // sanity
1091                         });
1092
1093                         if(!sp)
1094                                 continue;
1095                 }
1096
1097         // find a random vector to "look at"
1098         end.x = org.x + random() * delta.x;
1099         end.y = org.y + random() * delta.y;
1100         end.z = org.z + random() * delta.z;
1101         end = start + normalize(end - start) * vlen(delta);
1102
1103         // rule 4: start TO end must not be too short
1104         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1105         if(trace_startsolid)
1106             continue;
1107         if(trace_fraction < minviewdistance / vlen(delta))
1108             continue;
1109
1110         // rule 5: don't want to look at sky
1111         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1112             continue;
1113
1114         // rule 6: we must not end up in trigger_hurt
1115         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1116             continue;
1117
1118         break;
1119     }
1120
1121     e.dphitcontentsmask = m;
1122
1123     if(j < attempts)
1124     {
1125         setorigin(e, start);
1126         e.angles = vectoangles(end - start);
1127         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1128         return true;
1129     }
1130     return false;
1131 }
1132
1133 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1134 {
1135         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance, false);
1136 }
1137
1138 /*
1139 ===============================================================================
1140
1141 RULES
1142
1143 ===============================================================================
1144 */
1145
1146 void DumpStats(float final)
1147 {
1148         float file;
1149         string s;
1150         float to_console;
1151         float to_eventlog;
1152         float to_file;
1153         float i;
1154
1155         to_console = autocvar_sv_logscores_console;
1156         to_eventlog = autocvar_sv_eventlog;
1157         to_file = autocvar_sv_logscores_file;
1158
1159         if(!final)
1160         {
1161                 to_console = true; // always print printstats replies
1162                 to_eventlog = false; // but never print them to the event log
1163         }
1164
1165         if(to_eventlog)
1166                 if(autocvar_sv_eventlog_console)
1167                         to_console = false; // otherwise we get the output twice
1168
1169         if(final)
1170                 s = ":scores:";
1171         else
1172                 s = ":status:";
1173         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1174
1175         if(to_console)
1176                 LOG_HELP(s);
1177         if(to_eventlog)
1178                 GameLogEcho(s);
1179
1180         file = -1;
1181         if(to_file)
1182         {
1183                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1184                 if(file == -1)
1185                         to_file = false;
1186                 else
1187                         fputs(file, strcat(s, "\n"));
1188         }
1189
1190         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1191         if(to_console)
1192                 LOG_HELP(s);
1193         if(to_eventlog)
1194                 GameLogEcho(s);
1195         if(to_file)
1196                 fputs(file, strcat(s, "\n"));
1197
1198         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1199                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1200                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1201                 if(IS_PLAYER(it) || INGAME_JOINED(it))
1202                         s = strcat(s, ftos(it.team), ":");
1203                 else
1204                         s = strcat(s, "spectator:");
1205
1206                 if(to_console)
1207                         LOG_HELP(s, playername(it.netname, it.team, false));
1208                 if(to_eventlog)
1209                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1210                 if(to_file)
1211                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1212         });
1213
1214         if(teamplay)
1215         {
1216                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1217                 if(to_console)
1218                         LOG_HELP(s);
1219                 if(to_eventlog)
1220                         GameLogEcho(s);
1221                 if(to_file)
1222                         fputs(file, strcat(s, "\n"));
1223
1224                 for(i = 1; i < 16; ++i)
1225                 {
1226                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1227                         s = strcat(s, ":", ftos(i));
1228                         if(to_console)
1229                                 LOG_HELP(s);
1230                         if(to_eventlog)
1231                                 GameLogEcho(s);
1232                         if(to_file)
1233                                 fputs(file, strcat(s, "\n"));
1234                 }
1235         }
1236
1237         if(to_console)
1238                 LOG_HELP(":end");
1239         if(to_eventlog)
1240                 GameLogEcho(":end");
1241         if(to_file)
1242         {
1243                 fputs(file, ":end\n");
1244                 fclose(file);
1245         }
1246 }
1247
1248 /*
1249 go to the next level for deathmatch
1250 only called if a time or frag limit has expired
1251 */
1252 void NextLevel()
1253 {
1254         cvar_set("_endmatch", "0");
1255         game_stopped = true;
1256         intermission_running = true; // game over
1257
1258         // enforce a wait time before allowing changelevel
1259         if(player_count > 0)
1260                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1261         else
1262                 intermission_exittime = -1;
1263
1264         /*
1265         WriteByte (MSG_ALL, SVC_CDTRACK);
1266         WriteByte (MSG_ALL, 3);
1267         WriteByte (MSG_ALL, 3);
1268         // done in FixIntermission
1269         */
1270
1271         //pos = FindIntermission ();
1272
1273         VoteReset();
1274
1275         DumpStats(true);
1276
1277         // send statistics
1278         PlayerStats_GameReport(true);
1279         WeaponStats_Shutdown();
1280
1281         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1282
1283         if(autocvar_sv_eventlog)
1284                 GameLogEcho(":gameover");
1285
1286         GameLogClose();
1287
1288         int winner_team = 0;
1289         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1290                 FixIntermissionClient(it);
1291                 if(it.winning)
1292                 {
1293                         if (teamplay && !winner_team)
1294                         {
1295                                 winner_team = it.team;
1296                                 bprint(Team_ColorCode(winner_team), Team_ColorName_Upper(winner_team), "^7 team wins the match\n");
1297                         }
1298                         bprint(playername(it.netname, it.team, false), " ^7wins\n");
1299                 }
1300         });
1301
1302         target_music_kill();
1303
1304         if(autocvar_g_campaign)
1305                 CampaignPreIntermission();
1306
1307         MUTATOR_CALLHOOK(MatchEnd);
1308
1309         localcmd("\nsv_hook_gameend\n");
1310 }
1311
1312
1313 int InitiateSuddenDeath()
1314 {
1315         // Check first whether normal overtimes could be added before initiating suddendeath mode
1316         // - for this timelimit_overtime needs to be >0 of course
1317         // - also check the winning condition calculated in the previous frame and only add normal overtime
1318         //   again, if at the point at which timelimit would be extended again, still no winner was found
1319         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1320                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1321                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1322         {
1323                 return 1; // need to call InitiateOvertime later
1324         }
1325         else
1326         {
1327                 if(!checkrules_suddendeathend)
1328                 {
1329                         if(autocvar_g_campaign)
1330                         {
1331                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1332                         }
1333                         else
1334                         {
1335                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1336                                 overtimes = -1;
1337                         }
1338                         if(g_race && !g_race_qualifying)
1339                                 race_StartCompleting();
1340                 }
1341                 return 0;
1342         }
1343 }
1344
1345 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1346 {
1347         ++checkrules_overtimesadded;
1348         overtimes = checkrules_overtimesadded;
1349         //add one more overtime by simply extending the timelimit
1350         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1351         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1352 }
1353
1354 float GetWinningCode(float fraglimitreached, float equality)
1355 {
1356         if(autocvar_g_campaign == 1)
1357         {
1358                 if(fraglimitreached)
1359                         return WINNING_YES;
1360                 else
1361                         return WINNING_NO;
1362         }
1363         else
1364         {
1365                 if(equality)
1366                 {
1367                         if(fraglimitreached)
1368                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1369                         else
1370                                 return WINNING_NEVER;
1371                 }
1372                 else
1373                 {
1374                         if(fraglimitreached)
1375                                 return WINNING_YES;
1376                         else
1377                                 return WINNING_NO;
1378                 }
1379         }
1380 }
1381
1382 // set the .winning flag for exactly those players with a given field value
1383 void SetWinners(.float field, float value)
1384 {
1385         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = (it.(field) == value); });
1386 }
1387
1388 // set the .winning flag for those players with a given field value
1389 void AddWinners(.float field, float value)
1390 {
1391         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), {
1392                 if(it.(field) == value)
1393                         it.winning = 1;
1394         });
1395 }
1396
1397 // clear the .winning flags
1398 void ClearWinners()
1399 {
1400         FOREACH_CLIENT(IS_PLAYER(it) || INGAME(it), { it.winning = 0; });
1401 }
1402
1403 int fragsleft_last;
1404 float WinningCondition_Scores(float limit, float leadlimit)
1405 {
1406         // TODO make everything use THIS winning condition (except LMS)
1407         WinningConditionHelper(NULL);
1408
1409         if(teamplay)
1410         {
1411                 for (int i = 1; i < 5; ++i)
1412                 {
1413                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1414                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1415                 }
1416         }
1417
1418         ClearWinners();
1419         if(WinningConditionHelper_winner)
1420                 WinningConditionHelper_winner.winning = 1;
1421         if(WinningConditionHelper_winnerteam >= 0)
1422                 SetWinners(team, WinningConditionHelper_winnerteam);
1423
1424         if(WinningConditionHelper_lowerisbetter)
1425         {
1426                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1427                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1428                 limit = -limit;
1429         }
1430
1431         if(WinningConditionHelper_zeroisworst)
1432                 leadlimit = 0; // not supported in this mode
1433
1434         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1435         {
1436                 float fragsleft;
1437                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1438                 {
1439                         fragsleft = 1;
1440                 }
1441                 else
1442                 {
1443                         fragsleft = FLOAT_MAX;
1444                         float leadingfragsleft = FLOAT_MAX;
1445                         if (limit)
1446                                 fragsleft = limit - WinningConditionHelper_topscore;
1447                         if (leadlimit)
1448                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1449
1450                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1451                                 fragsleft = max(fragsleft, leadingfragsleft);
1452                         else
1453                                 fragsleft = min(fragsleft, leadingfragsleft);
1454                 }
1455
1456                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1457                 {
1458                         if (fragsleft == 1)
1459                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1460                         else if (fragsleft == 2)
1461                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1462                         else if (fragsleft == 3)
1463                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1464
1465                         fragsleft_last = fragsleft;
1466                 }
1467         }
1468
1469         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1470         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1471
1472         bool limit_reached;
1473         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1474         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1475                 limit_reached = (fraglimit_reached && leadlimit_reached);
1476         else
1477                 limit_reached = (fraglimit_reached || leadlimit_reached);
1478
1479         return GetWinningCode(
1480                 WinningConditionHelper_topscore && limit_reached,
1481                 WinningConditionHelper_equality
1482         );
1483 }
1484
1485 float WinningCondition_RanOutOfSpawns()
1486 {
1487         if(have_team_spawns <= 0)
1488                 return WINNING_NO;
1489
1490         if(!autocvar_g_spawn_useallspawns)
1491                 return WINNING_NO;
1492
1493         if(!some_spawn_has_been_used)
1494                 return WINNING_NO;
1495
1496         for (int i = 1; i < 5; ++i)
1497         {
1498                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1499         }
1500
1501         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1502         {
1503                 if (Team_IsValidTeam(it.team))
1504                 {
1505                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1506                 }
1507         });
1508
1509         IL_EACH(g_spawnpoints, true,
1510         {
1511                 if (Team_IsValidTeam(it.team))
1512                 {
1513                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1514                 }
1515         });
1516
1517         ClearWinners();
1518         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1519         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1520         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1521         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1522         if(team1_score + team2_score + team3_score + team4_score == 0)
1523         {
1524                 checkrules_equality = true;
1525                 return WINNING_YES;
1526         }
1527         else if(team1_score + team2_score + team3_score + team4_score == 1)
1528         {
1529                 float t, i;
1530                 if(team1_score)
1531                         t = 1;
1532                 else if(team2_score)
1533                         t = 2;
1534                 else if(team3_score)
1535                         t = 3;
1536                 else // if(team4_score)
1537                         t = 4;
1538                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1539                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1540                 {
1541                         for (int j = 1; j <= NUM_TEAMS; ++j)
1542                         {
1543                                 if (t == j)
1544                                 {
1545                                         continue;
1546                                 }
1547                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1548                                 {
1549                                         continue;
1550                                 }
1551                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1552                         }
1553                 }
1554
1555                 AddWinners(team, t);
1556                 return WINNING_YES;
1557         }
1558         else
1559                 return WINNING_NO;
1560 }
1561
1562 /*
1563 ============
1564 CheckRules_World
1565
1566 Exit deathmatch games upon conditions
1567 ============
1568 */
1569 void CheckRules_World()
1570 {
1571         VoteThink();
1572         MapVote_Think();
1573
1574         SetDefaultAlpha();
1575
1576         if (intermission_running) // someone else quit the game already
1577         {
1578                 if(player_count == 0) // Nobody there? Then let's go to the next map
1579                         MapVote_Start();
1580                         // this will actually check the player count in the next frame
1581                         // again, but this shouldn't hurt
1582                 return;
1583         }
1584
1585         float timelimit = autocvar_timelimit * 60;
1586         float fraglimit = autocvar_fraglimit;
1587         float leadlimit = autocvar_leadlimit;
1588         if (leadlimit < 0) leadlimit = 0;
1589
1590         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1591         {
1592                 if(timelimit > 0)
1593                         timelimit = 0; // timelimit is not made for warmup
1594                 if(fraglimit > 0)
1595                         fraglimit = 0; // no fraglimit for now
1596                 leadlimit = 0; // no leadlimit for now
1597         }
1598
1599         if (autocvar__endmatch || timelimit < 0)
1600         {
1601                 // endmatch
1602                 NextLevel();
1603                 return;
1604         }
1605
1606         if(timelimit > 0)
1607                 timelimit += game_starttime;
1608
1609         int overtimes_prev = overtimes;
1610         int wantovertime = 0;
1611
1612         if(checkrules_suddendeathend)
1613         {
1614                 if(!checkrules_suddendeathwarning)
1615                 {
1616                         checkrules_suddendeathwarning = true;
1617                         if(g_race && !g_race_qualifying)
1618                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1619                         else
1620                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1621                 }
1622         }
1623         else
1624         {
1625                 if (timelimit && time >= timelimit)
1626                 {
1627                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1628                         {
1629                                 float totalplayers;
1630                                 float playerswithlaps;
1631                                 float readyplayers;
1632                                 totalplayers = playerswithlaps = readyplayers = 0;
1633                                 FOREACH_CLIENT(IS_PLAYER(it), {
1634                                         ++totalplayers;
1635                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1636                                                 ++playerswithlaps;
1637                                         if(it.ready)
1638                                                 ++readyplayers;
1639                                 });
1640
1641                                 // at least 2 of the players have completed a lap: start the RACE
1642                                 // otherwise, the players should end the qualifying on their own
1643                                 if(readyplayers || playerswithlaps >= 2)
1644                                 {
1645                                         checkrules_suddendeathend = 0;
1646                                         ReadyRestart(true); // go to race
1647                                         return;
1648                                 }
1649                                 else
1650                                         wantovertime |= InitiateSuddenDeath();
1651                         }
1652                         else
1653                                 wantovertime |= InitiateSuddenDeath();
1654                 }
1655         }
1656
1657         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1658         {
1659                 NextLevel();
1660                 return;
1661         }
1662
1663         int checkrules_status = WinningCondition_RanOutOfSpawns();
1664         if(checkrules_status == WINNING_YES)
1665                 bprint("Hey! Someone ran out of spawns!\n");
1666         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1667                 checkrules_status = M_ARGV(0, float);
1668         else
1669                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1670
1671         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1672         {
1673                 checkrules_status = WINNING_NEVER;
1674                 checkrules_overtimesadded = -1;
1675                 wantovertime |= InitiateSuddenDeath();
1676         }
1677
1678         if(checkrules_status == WINNING_NEVER)
1679                 // equality cases! Nobody wins if the overtime ends in a draw.
1680                 ClearWinners();
1681
1682         if(wantovertime)
1683         {
1684                 if(checkrules_status == WINNING_NEVER)
1685                         InitiateOvertime();
1686                 else
1687                         checkrules_status = WINNING_YES;
1688         }
1689
1690         if(checkrules_suddendeathend)
1691                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1692                         checkrules_status = WINNING_YES;
1693
1694         if(checkrules_status == WINNING_YES)
1695         {
1696                 if (overtimes == -1 && overtimes != overtimes_prev)
1697                 {
1698                         // if suddendeathend overtime has just begun, revert it
1699                         checkrules_suddendeathend = 0;
1700                         overtimes = overtimes_prev;
1701                 }
1702                 //print("WINNING\n");
1703                 NextLevel();
1704         }
1705 }
1706
1707 float want_weapon(entity weaponinfo, float allguns)
1708 {
1709         int d = 0;
1710         bool allow_mutatorblocked = false;
1711
1712         if(!weaponinfo.m_id)
1713                 return 0;
1714
1715         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1716         d = M_ARGV(1, float);
1717         allguns = M_ARGV(2, bool);
1718         allow_mutatorblocked = M_ARGV(3, bool);
1719
1720         if(allguns)
1721                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1722         else if(!mutator_returnvalue)
1723                 d = !(!weaponinfo.weaponstart);
1724
1725         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1726                 d = 0;
1727
1728         float t = weaponinfo.weaponstartoverride;
1729
1730         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1731
1732         // bit order in t:
1733         // 1: want or not
1734         // 2: is default?
1735         // 4: is set by default?
1736         if(t < 0)
1737                 t = 4 | (3 * d);
1738         else
1739                 t |= (2 * d);
1740
1741         return t;
1742 }
1743
1744 /// Weapons the player normally starts with outside weapon arena.
1745 WepSet weapons_start()
1746 {
1747         WepSet ret = '0 0 0';
1748         FOREACH(Weapons, it != WEP_Null, {
1749                 int w = want_weapon(it, false);
1750                 if (w & 1)
1751                         ret |= it.m_wepset;
1752         });
1753         return ret;
1754 }
1755
1756 WepSet weapons_all()
1757 {
1758         WepSet ret = '0 0 0';
1759         FOREACH(Weapons, it != WEP_Null, {
1760                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1761                         ret |= it.m_wepset;
1762         });
1763         return ret;
1764 }
1765
1766 WepSet weapons_devall()
1767 {
1768         WepSet ret = '0 0 0';
1769         FOREACH(Weapons, it != WEP_Null,
1770         {
1771                 ret |= it.m_wepset;
1772         });
1773         return ret;
1774 }
1775
1776 WepSet weapons_most()
1777 {
1778         WepSet ret = '0 0 0';
1779         FOREACH(Weapons, it != WEP_Null, {
1780                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1781                         ret |= it.m_wepset;
1782         });
1783         return ret;
1784 }
1785
1786 void weaponarena_available_all_update(entity this)
1787 {
1788         if (weaponsInMapAll)
1789         {
1790                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1791         }
1792         else
1793         {
1794                 // if no weapons are available on the map, just fall back to all weapons arena
1795                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1796         }
1797 }
1798
1799 void weaponarena_available_devall_update(entity this)
1800 {
1801         if (weaponsInMapAll)
1802         {
1803                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1804         }
1805         else
1806         {
1807                 // if no weapons are available on the map, just fall back to devall weapons arena
1808                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1809         }
1810 }
1811
1812 void weaponarena_available_most_update(entity this)
1813 {
1814         if (weaponsInMapAll)
1815         {
1816                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1817         }
1818         else
1819         {
1820                 // if no weapons are available on the map, just fall back to most weapons arena
1821                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1822         }
1823 }
1824
1825 void readplayerstartcvars()
1826 {
1827         // initialize starting values for players
1828         start_weapons = '0 0 0';
1829         start_weapons_default = '0 0 0';
1830         start_weapons_defaultmask = '0 0 0';
1831         start_items = 0;
1832         start_ammo_shells = 0;
1833         start_ammo_nails = 0;
1834         start_ammo_rockets = 0;
1835         start_ammo_cells = 0;
1836         start_ammo_plasma = 0;
1837         if (random_start_ammo == NULL)
1838         {
1839                 random_start_ammo = new_pure(random_start_ammo);
1840         }
1841         start_health = cvar("g_balance_health_start");
1842         start_armorvalue = cvar("g_balance_armor_start");
1843
1844         g_weaponarena = 0;
1845         g_weaponarena_weapons = '0 0 0';
1846
1847         string s = cvar_string("g_weaponarena");
1848
1849         MUTATOR_CALLHOOK(SetWeaponArena, s);
1850         s = M_ARGV(0, string);
1851
1852         if (s == "0" || s == "")
1853         {
1854                 // no arena
1855         }
1856         else if (s == "off")
1857         {
1858                 // forcibly turn off weaponarena
1859         }
1860         else if (s == "all" || s == "1")
1861         {
1862                 g_weaponarena = 1;
1863                 g_weaponarena_list = "All Weapons Arena";
1864                 g_weaponarena_weapons = weapons_all();
1865         }
1866         else if (s == "devall")
1867         {
1868                 g_weaponarena = 1;
1869                 g_weaponarena_list = "Dev All Weapons Arena";
1870                 g_weaponarena_weapons = weapons_devall();
1871         }
1872         else if (s == "most")
1873         {
1874                 g_weaponarena = 1;
1875                 g_weaponarena_list = "Most Weapons Arena";
1876                 g_weaponarena_weapons = weapons_most();
1877         }
1878         else if (s == "all_available")
1879         {
1880                 g_weaponarena = 1;
1881                 g_weaponarena_list = "All Available Weapons Arena";
1882
1883                 // this needs to run after weaponsInMapAll is initialized
1884                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1885         }
1886         else if (s == "devall_available")
1887         {
1888                 g_weaponarena = 1;
1889                 g_weaponarena_list = "Dev All Available Weapons Arena";
1890
1891                 // this needs to run after weaponsInMapAll is initialized
1892                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1893         }
1894         else if (s == "most_available")
1895         {
1896                 g_weaponarena = 1;
1897                 g_weaponarena_list = "Most Available Weapons Arena";
1898
1899                 // this needs to run after weaponsInMapAll is initialized
1900                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1901         }
1902         else if (s == "none")
1903         {
1904                 g_weaponarena = 1;
1905                 g_weaponarena_list = "No Weapons Arena";
1906         }
1907         else
1908         {
1909                 g_weaponarena = 1;
1910                 float t = tokenize_console(s);
1911                 g_weaponarena_list = "";
1912                 for (int j = 0; j < t; ++j)
1913                 {
1914                         s = argv(j);
1915                         Weapon wep = Weapon_from_name(s);
1916                         if(wep != WEP_Null)
1917                         {
1918                                 g_weaponarena_weapons |= (wep.m_wepset);
1919                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.netname, " & ");
1920                         }
1921                 }
1922                 if (g_weaponarena_list != "") // remove trailing " & "
1923                         g_weaponarena_list = substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3);
1924                 else // no valid weapon found
1925                         g_weaponarena_list = "No Weapons Arena";
1926         }
1927
1928         if (g_weaponarena)
1929         {
1930                 g_weapon_stay = 0; // incompatible
1931                 start_weapons = g_weaponarena_weapons;
1932                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1933                 g_weaponarena_list = strzone(g_weaponarena_list);
1934         }
1935         else
1936         {
1937                 FOREACH(Weapons, it != WEP_Null, {
1938                         int w = want_weapon(it, false);
1939                         WepSet s = it.m_wepset;
1940                         if(w & 1)
1941                                 start_weapons |= s;
1942                         if(w & 2)
1943                                 start_weapons_default |= s;
1944                         if(w & 4)
1945                                 start_weapons_defaultmask |= s;
1946                 });
1947         }
1948
1949         if(cvar("g_balance_superweapons_time") < 0)
1950                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1951
1952         if(!cvar("g_use_ammunition"))
1953                 start_items |= IT_UNLIMITED_AMMO;
1954
1955         if(start_items & IT_UNLIMITED_AMMO)
1956         {
1957                 start_ammo_shells = 999;
1958                 start_ammo_nails = 999;
1959                 start_ammo_rockets = 999;
1960                 start_ammo_cells = 999;
1961                 start_ammo_plasma = 999;
1962                 start_ammo_fuel = 999;
1963         }
1964         else
1965         {
1966                 start_ammo_shells = cvar("g_start_ammo_shells");
1967                 start_ammo_nails = cvar("g_start_ammo_nails");
1968                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1969                 start_ammo_cells = cvar("g_start_ammo_cells");
1970                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1971                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1972                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1973                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1974                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1975                 SetResource(random_start_ammo, RES_ROCKETS, cvar("g_random_start_rockets"));
1976                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1977                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1978         }
1979
1980         warmup_start_ammo_shells = start_ammo_shells;
1981         warmup_start_ammo_nails = start_ammo_nails;
1982         warmup_start_ammo_rockets = start_ammo_rockets;
1983         warmup_start_ammo_cells = start_ammo_cells;
1984         warmup_start_ammo_plasma = start_ammo_plasma;
1985         warmup_start_ammo_fuel = start_ammo_fuel;
1986         warmup_start_health = start_health;
1987         warmup_start_armorvalue = start_armorvalue;
1988         warmup_start_weapons = start_weapons;
1989         warmup_start_weapons_default = start_weapons_default;
1990         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
1991
1992         if (!g_weaponarena)
1993         {
1994                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1995                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1996                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1997                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1998                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
1999                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
2000                 warmup_start_health = cvar("g_warmup_start_health");
2001                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
2002                 warmup_start_weapons = '0 0 0';
2003                 warmup_start_weapons_default = '0 0 0';
2004                 warmup_start_weapons_defaultmask = '0 0 0';
2005                 FOREACH(Weapons, it != WEP_Null, {
2006                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2007                         WepSet s = it.m_wepset;
2008                         if(w & 1)
2009                                 warmup_start_weapons |= s;
2010                         if(w & 2)
2011                                 warmup_start_weapons_default |= s;
2012                         if(w & 4)
2013                                 warmup_start_weapons_defaultmask |= s;
2014                 });
2015         }
2016
2017         if (autocvar_g_jetpack)
2018                 start_items |= ITEM_Jetpack.m_itemid;
2019
2020         MUTATOR_CALLHOOK(SetStartItems);
2021
2022         if (start_items & ITEM_Jetpack.m_itemid)
2023         {
2024                 start_items |= ITEM_JetpackRegen.m_itemid;
2025                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2026                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2027         }
2028
2029         start_ammo_shells = max(0, start_ammo_shells);
2030         start_ammo_nails = max(0, start_ammo_nails);
2031         start_ammo_rockets = max(0, start_ammo_rockets);
2032         start_ammo_cells = max(0, start_ammo_cells);
2033         start_ammo_plasma = max(0, start_ammo_plasma);
2034         start_ammo_fuel = max(0, start_ammo_fuel);
2035         SetResource(random_start_ammo, RES_SHELLS, max(0, GetResource(random_start_ammo, RES_SHELLS)));
2036         SetResource(random_start_ammo, RES_BULLETS, max(0, GetResource(random_start_ammo, RES_BULLETS)));
2037         SetResource(random_start_ammo, RES_ROCKETS, max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2038         SetResource(random_start_ammo, RES_CELLS, max(0, GetResource(random_start_ammo, RES_CELLS)));
2039         SetResource(random_start_ammo, RES_PLASMA, max(0, GetResource(random_start_ammo, RES_PLASMA)));
2040
2041         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2042         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2043         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2044         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2045         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2046         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2047 }
2048
2049 void readlevelcvars()
2050 {
2051         if(cvar("sv_allow_fullbright"))
2052                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2053
2054         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2055
2056         warmup_stage = cvar("g_warmup");
2057         warmup_limit = cvar("g_warmup_limit");
2058
2059         if(cvar("g_campaign"))
2060                 warmup_stage = 0; // no warmup during campaign
2061
2062         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2063         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2064         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2065         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2066         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2067         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2068         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2069         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2070         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2071         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2072         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2073         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2074         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2075         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2076
2077         g_pickup_shells = cvar("g_pickup_shells");
2078         g_pickup_shells_max = cvar("g_pickup_shells_max");
2079         g_pickup_nails = cvar("g_pickup_nails");
2080         g_pickup_nails_max = cvar("g_pickup_nails_max");
2081         g_pickup_rockets = cvar("g_pickup_rockets");
2082         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2083         g_pickup_cells = cvar("g_pickup_cells");
2084         g_pickup_cells_max = cvar("g_pickup_cells_max");
2085         g_pickup_plasma = cvar("g_pickup_plasma");
2086         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2087         g_pickup_fuel = cvar("g_pickup_fuel");
2088         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2089         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2090         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2091         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2092         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2093         g_pickup_armormedium = cvar("g_pickup_armormedium");
2094         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2095         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2096         g_pickup_armorbig = cvar("g_pickup_armorbig");
2097         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2098         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2099         g_pickup_armormega = cvar("g_pickup_armormega");
2100         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2101         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2102         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2103         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2104         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2105         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2106         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2107         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2108         g_pickup_healthbig = cvar("g_pickup_healthbig");
2109         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2110         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2111         g_pickup_healthmega = cvar("g_pickup_healthmega");
2112         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2113         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2114
2115         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2116         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2117
2118     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2119     if(!g_weapon_stay)
2120         g_weapon_stay = cvar("g_weapon_stay");
2121
2122     MUTATOR_CALLHOOK(ReadLevelCvars);
2123
2124         if (!warmup_stage && !autocvar_g_campaign)
2125                 game_starttime = time + cvar("g_start_delay");
2126
2127         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2128
2129         readplayerstartcvars();
2130 }
2131
2132 void InitializeEntity(entity e, void(entity this) func, int order)
2133 {
2134     entity prev, cur;
2135
2136     if (!e || e.initialize_entity)
2137     {
2138         // make a proxy initializer entity
2139         entity e_old = e;
2140         e = new(initialize_entity);
2141         e.enemy = e_old;
2142     }
2143
2144     e.initialize_entity = func;
2145     e.initialize_entity_order = order;
2146
2147     cur = initialize_entity_first;
2148     prev = NULL;
2149     for (;;)
2150     {
2151         if (!cur || cur.initialize_entity_order > order)
2152         {
2153             // insert between prev and cur
2154             if (prev)
2155                 prev.initialize_entity_next = e;
2156             else
2157                 initialize_entity_first = e;
2158             e.initialize_entity_next = cur;
2159             return;
2160         }
2161         prev = cur;
2162         cur = cur.initialize_entity_next;
2163     }
2164 }
2165 void InitializeEntitiesRun()
2166 {
2167     entity startoflist = initialize_entity_first;
2168     initialize_entity_first = NULL;
2169     delete_fn = remove_except_protected;
2170     for (entity e = startoflist; e; e = e.initialize_entity_next)
2171     {
2172                 e.remove_except_protected_forbidden = 1;
2173     }
2174     for (entity e = startoflist; e; )
2175     {
2176                 e.remove_except_protected_forbidden = 0;
2177         e.initialize_entity_order = 0;
2178         entity next = e.initialize_entity_next;
2179         e.initialize_entity_next = NULL;
2180         var void(entity this) func = e.initialize_entity;
2181         e.initialize_entity = func_null;
2182         if (e.classname == "initialize_entity")
2183         {
2184             entity wrappee = e.enemy;
2185             builtin_remove(e);
2186             e = wrappee;
2187         }
2188         //dprint("Delayed initialization: ", e.classname, "\n");
2189         if (func)
2190         {
2191                 func(e);
2192         }
2193         else
2194         {
2195             eprint(e);
2196             backtrace(strcat("Null function in: ", e.classname, "\n"));
2197         }
2198         e = next;
2199     }
2200     delete_fn = remove_unsafely;
2201 }
2202
2203 // deferred dropping
2204 void DropToFloor_Handler(entity this)
2205 {
2206         WITHSELF(this, builtin_droptofloor());
2207         this.dropped_origin = this.origin;
2208 }
2209
2210 void droptofloor(entity this)
2211 {
2212         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2213 }
2214
2215 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2216 void RunThink(entity this, float dt)
2217 {
2218         // don't let things stay in the past.
2219         // it is possible to start that way by a trigger with a local time.
2220         if(this.nextthink <= 0 || this.nextthink > time + dt)
2221                 return;
2222
2223         float oldtime = time; // do we need to save this?
2224
2225         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2226         {
2227                 time = max(oldtime, this.nextthink);
2228                 this.nextthink = 0;
2229
2230                 if(getthink(this))
2231                         getthink(this)(this);
2232                 // mods often set nextthink to time to cause a think every frame,
2233                 // we don't want to loop in that case, so exit if the new nextthink is
2234                 // <= the time the qc was told, also exit if it is past the end of the
2235                 // frame
2236                 if(this.nextthink <= time || this.nextthink > oldtime + dt || !autocvar_sv_gameplayfix_multiplethinksperframe)
2237                         break;
2238         }
2239
2240         time = oldtime;
2241 }
2242
2243 bool autocvar_sv_freezenonclients;
2244 void Physics_Frame()
2245 {
2246         if(autocvar_sv_freezenonclients)
2247                 return;
2248
2249         IL_EACH(g_moveables, true,
2250         {
2251                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2252                         continue;
2253
2254                 //set_movetype(it, it.move_movetype);
2255                 // inline the set_movetype function, since this is called a lot
2256                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2257
2258                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2259                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2260
2261                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2262                 {
2263                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2264                                 continue; // these movetypes have no regular think function
2265                         // handle thinking here
2266                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + PHYS_INPUT_TIMELENGTH)
2267                                 RunThink(it, PHYS_INPUT_TIMELENGTH);
2268                 }
2269         });
2270
2271         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2272                 return;
2273
2274         // make a second pass to see if any ents spawned this frame and make
2275         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2276         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2277         IL_EACH(g_moveables, it.move_qcphysics,
2278         {
2279                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2280                         continue;
2281                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2282         });
2283 }
2284
2285 void systems_update();
2286 void EndFrame()
2287 {
2288         anticheat_endframe();
2289
2290         Physics_Frame();
2291
2292         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2293                 entity e = IS_SPEC(it) ? it.enemy : it;
2294                 if (e.typehitsound) {
2295                         STAT(TYPEHIT_TIME, it) = time;
2296                 } else if (e.killsound) {
2297                         STAT(KILL_TIME, it) = time;
2298                 } else if (e.hitsound_damage_dealt) {
2299                         STAT(HIT_TIME, it) = time;
2300                         // NOTE: this is not accurate as client code doesn't need so much accuracy for its purposes
2301                         STAT(HITSOUND_DAMAGE_DEALT_TOTAL, it) += ceil(e.hitsound_damage_dealt);
2302                 }
2303         });
2304         // add 1 frametime because after this, engine SV_Physics
2305         // increases time by a frametime and then networks the frame
2306         // add another frametime because client shows everything with
2307         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2308         // needed!
2309         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2310         FOREACH_CLIENT(true, {
2311                 it.typehitsound = false;
2312                 it.hitsound_damage_dealt = 0;
2313                 it.killsound = false;
2314                 antilag_record(it, CS(it), altime);
2315         });
2316         IL_EACH(g_monsters, true,
2317         {
2318                 antilag_record(it, it, altime);
2319         });
2320         IL_EACH(g_projectiles, it.classname == "nade",
2321         {
2322                 antilag_record(it, it, altime);
2323         });
2324         systems_update();
2325         IL_ENDFRAME();
2326 }
2327
2328
2329 /*
2330  * RedirectionThink:
2331  * returns true if redirecting
2332  */
2333 float redirection_timeout;
2334 float redirection_nextthink;
2335 float RedirectionThink()
2336 {
2337         float clients_found;
2338
2339         if(redirection_target == "")
2340                 return false;
2341
2342         if(!redirection_timeout)
2343         {
2344                 cvar_set("sv_public", "-2");
2345                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2346                 if(redirection_target == "self")
2347                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2348                 else
2349                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2350         }
2351
2352         if(time < redirection_nextthink)
2353                 return true;
2354
2355         redirection_nextthink = time + 1;
2356
2357         clients_found = 0;
2358         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2359                 // TODO add timer
2360                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2361                 if(redirection_target == "self")
2362                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2363                 else
2364                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2365                 ++clients_found;
2366         });
2367
2368         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2369
2370         if(time > redirection_timeout || clients_found == 0)
2371                 localcmd("\nwait; wait; wait; quit\n");
2372
2373         return true;
2374 }
2375
2376 void RestoreGame()
2377 {
2378         // Loaded from a save game
2379         // some things then break, so let's work around them...
2380
2381         // Progs DB (capture records)
2382         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2383
2384         // Mapinfo
2385         MapInfo_Shutdown();
2386         MapInfo_Enumerate();
2387         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2388         WeaponStats_Init();
2389
2390         TargetMusic_RestoreGame();
2391 }
2392
2393 void Shutdown()
2394 {
2395         game_stopped = 2;
2396
2397         if(world_initialized > 0)
2398         {
2399                 world_initialized = 0;
2400
2401                 // if a timeout is active, reset the slowmo value to normal
2402                 if(timeout_status == TIMEOUT_ACTIVE)
2403                         cvar_set("slowmo", ftos(orig_slowmo));
2404
2405                 LOG_TRACE("Saving persistent data...");
2406                 Ban_SaveBans();
2407
2408                 // playerstats with unfinished match
2409                 PlayerStats_GameReport(false);
2410
2411                 if(!cheatcount_total)
2412                 {
2413                         if(autocvar_sv_db_saveasdump)
2414                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2415                         else
2416                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2417                 }
2418                 if(autocvar_developer > 0)
2419                 {
2420                         if(autocvar_sv_db_saveasdump)
2421                                 db_dump(TemporaryDB, "server-temp.db");
2422                         else
2423                                 db_save(TemporaryDB, "server-temp.db");
2424                 }
2425                 CheatShutdown(); // must be after cheatcount check
2426                 db_close(ServerProgsDB);
2427                 db_close(TemporaryDB);
2428                 LOG_TRACE("Saving persistent data... done!");
2429                 // tell the bot system the game is ending now
2430                 bot_endgame();
2431
2432                 WeaponStats_Shutdown();
2433                 MapInfo_Shutdown();
2434
2435                 strfree(sv_termsofservice_url_escaped);
2436         }
2437         else if(world_initialized == 0)
2438         {
2439                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2440         }
2441         else
2442         {
2443                 __init_dedicated_server_shutdown();
2444         }
2445 }