qcsrc/warpzonelib/common.qc

   1 float trace_dphitcontents;
   2 .float dphitcontents;
   3
   4 void WarpZone_Accumulator_Clear(entity acc)
   5 {
   6         acc.warpzone_transform = '0 0 0';
   7         acc.warpzone_shift = '0 0 0';
   8 }
   9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  10 {
  11         vector tr, st;
  12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  14         acc.warpzone_transform = tr;
  15         acc.warpzone_shift = st;
  16 }
  17 void WarpZone_Accumulator_Add(entity acc, entity wz)
  18 {
  19         vector t, st;
  20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
  21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
  22         acc.warpzone_transform = t;
  23         acc.warpzone_shift = st;
  24 }
  25
  26 .vector(vector, vector) camera_transform;
  27 var float autocvar_cl_warpzone_usetrace = 1;
  28 vector WarpZone_camera_transform(vector org, vector ang)
  29 {
  30         vector vf, vr, vu;
  31         if(self.warpzone_fadestart)
  32                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  33                         return org;
  34                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  35                         // unneeded on client, on server this helps a lot
  36         vf = v_forward;
  37         vr = v_right;
  38         vu = v_up;
  39         org = WarpZone_TransformOrigin(self, org);
  40         vf = WarpZone_TransformVelocity(self, vf);
  41         vr = WarpZone_TransformVelocity(self, vr);
  42         vu = WarpZone_TransformVelocity(self, vu);
  43         if(autocvar_cl_warpzone_usetrace)
  44                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  45         else
  46                 trace_endpos = self.warpzone_targetorigin;
  47         v_forward = vf;
  48         v_right = vr;
  49         v_up = vu;
  50         return org;
  51 }
  52
  53 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  54 {
  55         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  56         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  57         e.warpzone_origin = my_org;
  58         e.warpzone_targetorigin = other_org;
  59         e.warpzone_angles = my_ang;
  60         e.warpzone_targetangles = other_ang;
  61         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  62         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  63         e.camera_transform = WarpZone_camera_transform;
  64 }
  65
  66 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  67 {
  68         // a fixed camera view
  69         if(self.warpzone_fadestart)
  70                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  71                         return org;
  72                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  73                         // unneeded on client, on server this helps a lot
  74         trace_endpos = self.warpzone_origin;
  75         makevectors(self.warpzone_angles);
  76         return self.warpzone_origin;
  77 }
  78
  79 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  80 {
  81         e.warpzone_origin = my_org;
  82         e.warpzone_angles = my_ang;
  83         e.camera_transform = WarpZone_Camera_camera_transform;
  84 }
  85
  86 .entity enemy;
  87
  88 vector WarpZoneLib_BoxTouchesBrush_mins;
  89 vector WarpZoneLib_BoxTouchesBrush_maxs;
  90 entity WarpZoneLib_BoxTouchesBrush_ent;
  91 entity WarpZoneLib_BoxTouchesBrush_ignore;
  92 float WarpZoneLib_BoxTouchesBrush_Recurse()
  93 {
  94         float s;
  95         entity se;
  96         float f;
  97
  98         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  99 #ifdef CSQC
 100         if (trace_networkentity)
 101         {
 102                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
 103                 // we cannot continue, as a player blocks us...
 104                 // so, abort
 105                 return 0;
 106         }
 107 #endif
 108         if not(trace_ent)
 109                 return 0;
 110         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 111                 return 1;
 112
 113         se = trace_ent;
 114         s = se.solid;
 115         se.solid = SOLID_NOT;
 116         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 117         se.solid = s;
 118
 119         return f;
 120 }
 121
 122 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 123 {
 124     float f, s;
 125
 126     if(!e.modelindex || e.warpzone_isboxy)
 127         return 1;
 128
 129     s = e.solid;
 130     e.solid = SOLID_BSP;
 131     WarpZoneLib_BoxTouchesBrush_mins = mi;
 132     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 133     WarpZoneLib_BoxTouchesBrush_ent = e;
 134     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 135     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 136     e.solid = s;
 137
 138     return f;
 139 }
 140
 141 entity WarpZone_Find(vector mi, vector ma)
 142 {
 143         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 144         entity e;
 145         if(!warpzone_warpzones_exist)
 146                 return world;
 147         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 148                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 149                         return e;
 150         return world;
 151 }
 152
 153 void WarpZone_MakeAllSolid()
 154 {
 155         entity e;
 156         if(!warpzone_warpzones_exist)
 157                 return;
 158         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 159                 e.solid = SOLID_BSP;
 160 }
 161
 162 void WarpZone_MakeAllOther()
 163 {
 164         entity e;
 165         if(!warpzone_warpzones_exist)
 166                 return;
 167         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 168                 e.solid = SOLID_TRIGGER;
 169 }
 170
 171 void WarpZone_Trace_InitTransform()
 172 {
 173         if(!WarpZone_trace_transform)
 174         {
 175                 WarpZone_trace_transform = spawn();
 176                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 177         }
 178         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 179 }
 180 void WarpZone_Trace_AddTransform(entity wz)
 181 {
 182         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 183 }
 184
 185 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 186 {
 187         float nomonsters_adjusted;
 188         float frac, sol, i;
 189         float contentshack;
 190         vector o0, e0;
 191         entity wz;
 192         vector vf, vr, vu;
 193
 194         WarpZone_Trace_InitTransform();
 195         if(!warpzone_warpzones_exist)
 196         {
 197                 if(nomonsters == MOVE_NOTHING)
 198                 {
 199                         trace_endpos = end;
 200                         trace_fraction = 1;
 201                         if(cb)
 202                                 cb(org, trace_endpos, end);
 203                         return;
 204                 }
 205                 else
 206                 {
 207                         tracebox(org, mi, ma, end, nomonsters, forent);
 208                         if(cb)
 209                                 cb(org, trace_endpos, end);
 210                         return;
 211                 }
 212         }
 213
 214         vf = v_forward;
 215         vr = v_right;
 216         vu = v_up;
 217         o0 = org;
 218         e0 = end;
 219
 220         switch(nomonsters)
 221         {
 222                 case MOVE_WORLDONLY:
 223                 case MOVE_NOTHING:
 224                         nomonsters_adjusted = MOVE_NOMONSTERS;
 225                         break;
 226                 default:
 227                         nomonsters_adjusted = nomonsters;
 228                         break;
 229         }
 230         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 231                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
 232
 233         // if starting in warpzone, first transform
 234         wz = WarpZone_Find(org + mi, org + ma);
 235         if(wz)
 236         {
 237                 if(zone && wz != zone)
 238                 {
 239                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 240                         sol = 1;
 241                         trace_fraction = 0;
 242                         trace_endpos = org;
 243                         goto fail;
 244                 }
 245                 WarpZone_Trace_AddTransform(wz);
 246                 org = WarpZone_TransformOrigin(wz, org);
 247                 end = WarpZone_TransformOrigin(wz, end);
 248         }
 249         WarpZone_MakeAllSolid();
 250         sol = -1;
 251         frac = 0;
 252         i = 16;
 253         for(;;)
 254         {
 255                 if(--i < 1)
 256                 {
 257                         dprint("Too many warpzones in sequence, aborting trace.\n");
 258                         trace_ent = world;
 259                         break;
 260                 }
 261                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
 262                 if(cb)
 263                         cb(org, trace_endpos, end);
 264                 if(sol < 0)
 265                         sol = trace_startsolid;
 266
 267                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 268                 if(trace_fraction >= 1)
 269                         break;
 270                 if(trace_ent.classname != "trigger_warpzone")
 271                 {
 272                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 273                         {
 274                                 // continue the trace, ignoring this hit (we only care for warpzones)
 275                                 org = trace_endpos + normalize(end - org);
 276                                 continue;
 277                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 278                                 // otherwise, players could block entrances that way
 279                         }
 280                         break;
 281                 }
 282                 if(trace_ent == wz)
 283                 {
 284                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 285                         trace_ent = world;
 286                         break;
 287                 }
 288                 wz = trace_ent;
 289                 if(zone && wz != zone)
 290                         break;
 291                 WarpZone_Trace_AddTransform(wz);
 292                 // we hit a warpzone... so, let's perform the trace after the warp again
 293                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 294                 end = WarpZone_TransformOrigin(wz, end);
 295         }
 296         WarpZone_MakeAllOther();
 297 :fail
 298         if(contentshack)
 299                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
 300         trace_startsolid = sol;
 301         v_forward = vf;
 302         v_right = vr;
 303         v_up = vu;
 304 }
 305
 306 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 307 {
 308         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 309 }
 310
 311 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 312 {
 313         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 314 }
 315
 316 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 317 {
 318         float g, dt, i;
 319         vector vf, vr, vu, v0, o0;
 320         entity wz;
 321
 322         o0 = e.origin;
 323         v0 = e.velocity;
 324
 325         WarpZone_Trace_InitTransform();
 326         WarpZone_tracetoss_time = 0;
 327         if(!warpzone_warpzones_exist)
 328         {
 329                 tracetoss(e, forent);
 330                 if(cb)
 331                         cb(e.origin, trace_endpos, trace_endpos);
 332                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 333                 WarpZone_tracetoss_time += dt;
 334                 e.velocity_z -= dt * g;
 335                 WarpZone_tracetoss_velocity = e.velocity;
 336                 e.velocity = v0;
 337                 return;
 338         }
 339
 340         vf = v_forward;
 341         vr = v_right;
 342         vu = v_up;
 343
 344         // if starting in warpzone, first transform
 345         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 346         if(wz)
 347         {
 348                 if(zone && wz != zone)
 349                 {
 350                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 351
 352                         WarpZone_tracetoss_time = 0;
 353                         trace_endpos = o0;
 354                         goto fail;
 355                 }
 356                 WarpZone_Trace_AddTransform(wz);
 357                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 358                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 359         }
 360         WarpZone_MakeAllSolid();
 361         g = cvar("sv_gravity") * e.gravity;
 362         i = 16;
 363         for(;;)
 364         {
 365                 if(--i < 1)
 366                 {
 367                         dprint("Too many warpzones in sequence, aborting trace.\n");
 368                         trace_ent = world;
 369                         break;
 370                 }
 371                 tracetoss(e, forent);
 372                 if(cb)
 373                         cb(e.origin, trace_endpos, trace_endpos);
 374                 e.origin = trace_endpos;
 375                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 376                 WarpZone_tracetoss_time += dt;
 377                 e.velocity_z -= dt * g;
 378                 if(trace_fraction >= 1)
 379                         break;
 380                 if(trace_ent.classname != "trigger_warpzone")
 381                         break;
 382                 if(trace_ent == wz)
 383                 {
 384                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 385                         trace_ent = world;
 386                         break;
 387                 }
 388                 wz = trace_ent;
 389                 if(zone && wz != zone)
 390                         break;
 391                 WarpZone_Trace_AddTransform(wz);
 392                 // we hit a warpzone... so, let's perform the trace after the warp again
 393                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 394                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 395         }
 396         WarpZone_MakeAllOther();
 397 :fail
 398         WarpZone_tracetoss_velocity = e.velocity;
 399         v_forward = vf;
 400         v_right = vr;
 401         v_up = vu;
 402         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 403         e.velocity = v0;
 404         e.origin = o0;
 405 }
 406
 407 void WarpZone_TraceToss(entity e, entity forent)
 408 {
 409         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 410 }
 411
 412 entity WarpZone_TrailParticles_trace_callback_own;
 413 float WarpZone_TrailParticles_trace_callback_eff;
 414 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 415 {
 416         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 417 }
 418
 419 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 420 {
 421         WarpZone_TrailParticles_trace_callback_own = own;
 422         WarpZone_TrailParticles_trace_callback_eff = eff;
 423         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 424 }
 425
 426 float WarpZone_PlaneDist(entity wz, vector v)
 427 {
 428         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 429 }
 430
 431 float WarpZone_TargetPlaneDist(entity wz, vector v)
 432 {
 433         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 434 }
 435
 436 vector WarpZone_TransformOrigin(entity wz, vector v)
 437 {
 438         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 439 }
 440
 441 vector WarpZone_TransformVelocity(entity wz, vector v)
 442 {
 443         return AnglesTransform_Apply(wz.warpzone_transform, v);
 444 }
 445
 446 vector WarpZone_TransformAngles(entity wz, vector v)
 447 {
 448         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 449 }
 450
 451 vector WarpZone_TransformVAngles(entity wz, vector ang)
 452 {
 453 #ifdef KEEP_ROLL
 454         float roll;
 455         roll = ang_z;
 456         ang_z = 0;
 457 #endif
 458
 459         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 460
 461 #ifdef KEEP_ROLL
 462         ang = AnglesTransform_Normalize(ang, TRUE);
 463         ang = AnglesTransform_CancelRoll(ang);
 464         ang_z = roll;
 465 #else
 466         ang = AnglesTransform_Normalize(ang, FALSE);
 467 #endif
 468
 469         return ang;
 470 }
 471
 472 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 473 {
 474         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 475 }
 476
 477 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 478 {
 479         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 480 }
 481
 482 vector WarpZone_UnTransformAngles(entity wz, vector v)
 483 {
 484         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 485 }
 486
 487 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 488 {
 489         float roll;
 490
 491         roll = ang_z;
 492         ang_z = 0;
 493
 494         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 495         ang = AnglesTransform_Normalize(ang, TRUE);
 496         ang = AnglesTransform_CancelRoll(ang);
 497
 498         ang_z = roll;
 499         return ang;
 500 }
 501
 502 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 503 {
 504         vector nearest;
 505         nearest_x = bound(mi_x, org_x, ma_x);
 506         nearest_y = bound(mi_y, org_y, ma_y);
 507         nearest_z = bound(mi_z, org_z, ma_z);
 508         return nearest;
 509 }
 510
 511 .float WarpZone_findradius_hit;
 512 .entity WarpZone_findradius_next;
 513 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 514 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 515 {
 516         vector org_new;
 517         vector org0_new;
 518         vector shift_new, transform_new;
 519         vector p;
 520         entity e, e0;
 521         entity wz;
 522         if(rad <= 0)
 523                 return;
 524         e0 = findradius(org, rad);
 525         wz = world;
 526
 527         for(e = e0; e; e = e.chain)
 528         {
 529                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 530                 if(needlineofsight)
 531                 {
 532                         traceline(org, p, MOVE_NOMONSTERS, e);
 533                         if(trace_fraction < 1)
 534                                 continue;
 535                 }
 536                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 537                 {
 538                         e.WarpZone_findradius_nearest = p;
 539                         e.WarpZone_findradius_dist = org0 - p;
 540                         e.WarpZone_findradius_findorigin = org;
 541                         e.WarpZone_findradius_findradius = rad;
 542                         if(e.classname == "warpzone_refsys")
 543                         {
 544                                 // ignore, especially: do not overwrite the refsys parameters
 545                         }
 546                         else if(e.classname == "trigger_warpzone")
 547                         {
 548                                 e.WarpZone_findradius_next = wz;
 549                                 wz = e;
 550                                 e.WarpZone_findradius_hit = 1;
 551                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 552                                 e.enemy.WarpZone_findradius_hit = 1;
 553                         }
 554                         else
 555                         {
 556                                 e.warpzone_transform = transform;
 557                                 e.warpzone_shift = shift;
 558                                 e.WarpZone_findradius_hit = 1;
 559                         }
 560                 }
 561         }
 562         for(e = wz; e; e = e.WarpZone_findradius_next)
 563         {
 564                 org0_new = WarpZone_TransformOrigin(e, org);
 565                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 566                 org_new = trace_endpos;
 567
 568                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 569                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 570                 WarpZone_FindRadius_Recurse(
 571                         org_new,
 572                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 573                         org0_new,
 574                         transform_new, shift_new,
 575                         needlineofsight);
 576                 e.WarpZone_findradius_hit = 0;
 577                 e.enemy.WarpZone_findradius_hit = 0;
 578         }
 579 }
 580 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 581 {
 582         entity e0, e;
 583         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 584         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 585         for(e = e0; e; e = e.chain)
 586                 e.WarpZone_findradius_hit = 0;
 587         return e0;
 588 }
 589
 590 .entity WarpZone_refsys;
 591 void WarpZone_RefSys_GC()
 592 {
 593         // garbage collect unused reference systems
 594         self.nextthink = time + 1;
 595         if(self.owner.WarpZone_refsys != self)
 596                 remove(self);
 597 }
 598 void WarpZone_RefSys_Add(entity me, entity wz)
 599 {
 600         if(me.WarpZone_refsys.owner != me)
 601         {
 602                 me.WarpZone_refsys = spawn();
 603                 me.WarpZone_refsys.classname = "warpzone_refsys";
 604                 me.WarpZone_refsys.owner = me;
 605                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 606                 me.WarpZone_refsys.nextthink = time + 1;
 607                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 608         }
 609         if(wz)
 610                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
 611 }
 612 .vector WarpZone_refsys_incremental_shift;
 613 .vector WarpZone_refsys_incremental_transform;
 614 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 615 {
 616         vector t, s;
 617         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 618         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 619                 return;
 620         if(me.WarpZone_refsys.owner != me)
 621         {
 622                 me.WarpZone_refsys = spawn();
 623                 me.WarpZone_refsys.classname = "warpzone_refsys";
 624                 me.WarpZone_refsys.owner = me;
 625                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 626                 me.WarpZone_refsys.nextthink = time + 1;
 627                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 628         }
 629         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
 630         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
 631         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 632         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
 633         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 634         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 635 }
 636 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 637 {
 638         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 639         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 640 }
 641 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 642 {
 643         if(from.WarpZone_refsys)
 644                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 645         if(to.WarpZone_refsys)
 646                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 647         return org;
 648 }
 649 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 650 {
 651         if(from.WarpZone_refsys)
 652                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 653         if(to.WarpZone_refsys)
 654                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 655         return vel;
 656 }
 657 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 658 {
 659         if(from.WarpZone_refsys)
 660                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 661         if(to.WarpZone_refsys)
 662                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 663         return ang;
 664 }
 665 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 666 {
 667         if(from.WarpZone_refsys)
 668                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 669         if(to.WarpZone_refsys)
 670                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 671         return ang;
 672 }
 673 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 674 {
 675         entity e;
 676         e = spawn();
 677         if(me.WarpZone_refsys)
 678         {
 679                 e.WarpZone_refsys = spawn();
 680                 e.WarpZone_refsys.classname = "warpzone_refsys";
 681                 e.WarpZone_refsys.owner = e;
 682                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
 683                 e.WarpZone_refsys.nextthink = time + 1;
 684                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
 685                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
 686         }
 687         return e;
 688 }