qcsrc/warpzonelib/common.qc

   1 #include "common.qh"
   2
   3 #if defined(CSQC)
   4         #include "../dpdefs/csprogsdefs.qh"
   5     #include "../server/t_items.qh"
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "../common/weapons/all.qh"
   9     #include "../dpdefs/dpextensions.qh"
  10         #include "../dpdefs/progsdefs.qh"
  11 #endif
  12
  13 void WarpZone_Accumulator_Clear(entity acc)
  14 {
  15         acc.warpzone_transform = '0 0 0';
  16         acc.warpzone_shift = '0 0 0';
  17 }
  18 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  19 {
  20         vector tr, st;
  21         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  22         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  23         acc.warpzone_transform = tr;
  24         acc.warpzone_shift = st;
  25 }
  26 void WarpZone_Accumulator_Add(entity acc, entity wz)
  27 {
  28         WarpZone_Accumulator_AddTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  29 }
  30 void WarpZone_Accumulator_AddInverseTransform(entity acc, vector t, vector s)
  31 {
  32         vector tt, ss;
  33         tt = AnglesTransform_Invert(t);
  34         ss = AnglesTransform_PrePostShift_GetPostShift(s, tt, '0 0 0');
  35         WarpZone_Accumulator_AddTransform(acc, tt, ss);
  36         // yes, this probably can be done simpler... but this way is "obvious" :)
  37 }
  38 void WarpZone_Accumulator_AddInverse(entity acc, entity wz)
  39 {
  40         WarpZone_Accumulator_AddInverseTransform(acc, wz.warpzone_transform, wz.warpzone_shift);
  41 }
  42
  43 .vector(vector, vector) camera_transform;
  44 float autocvar_cl_warpzone_usetrace = 1;
  45 vector WarpZone_camera_transform(vector org, vector ang)
  46 {
  47         vector vf, vr, vu;
  48         if(self.warpzone_fadestart)
  49                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  50                         return org;
  51                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  52                         // unneeded on client, on server this helps a lot
  53         vf = v_forward;
  54         vr = v_right;
  55         vu = v_up;
  56         org = WarpZone_TransformOrigin(self, org);
  57         vf = WarpZone_TransformVelocity(self, vf);
  58         vr = WarpZone_TransformVelocity(self, vr);
  59         vu = WarpZone_TransformVelocity(self, vu);
  60         if(autocvar_cl_warpzone_usetrace)
  61                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  62         else
  63                 trace_endpos = self.warpzone_targetorigin;
  64         v_forward = vf;
  65         v_right = vr;
  66         v_up = vu;
  67         return org;
  68 }
  69
  70 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  71 {
  72         e.warpzone_transform = AnglesTransform_RightDivide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  73         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  74         e.warpzone_origin = my_org;
  75         e.warpzone_targetorigin = other_org;
  76         e.warpzone_angles = my_ang;
  77         e.warpzone_targetangles = other_ang;
  78         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  79         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  80         e.camera_transform = WarpZone_camera_transform;
  81 }
  82
  83 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  84 {
  85         // a fixed camera view
  86         if(self.warpzone_fadestart)
  87                 if(vlen(org - self.origin - 0.5 * (self.mins + self.maxs)) > self.warpzone_fadeend + 400)
  88                         return org;
  89                         // don't transform if zone faded out (plus 400qu safety margin for typical speeds and latencies)
  90                         // unneeded on client, on server this helps a lot
  91         trace_endpos = self.warpzone_origin;
  92         makevectors(self.warpzone_angles);
  93         return self.warpzone_origin;
  94 }
  95
  96 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  97 {
  98         e.warpzone_origin = my_org;
  99         e.warpzone_angles = my_ang;
 100         e.camera_transform = WarpZone_Camera_camera_transform;
 101 }
 102
 103 .entity enemy;
 104
 105 vector WarpZoneLib_BoxTouchesBrush_mins;
 106 vector WarpZoneLib_BoxTouchesBrush_maxs;
 107 entity WarpZoneLib_BoxTouchesBrush_ent;
 108 entity WarpZoneLib_BoxTouchesBrush_ignore;
 109 float WarpZoneLib_BoxTouchesBrush_Recurse()
 110 {
 111         float s;
 112         entity se;
 113         float f;
 114
 115         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
 116 #ifdef CSQC
 117         if (trace_networkentity)
 118         {
 119                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
 120                 // we cannot continue, as a player blocks us...
 121                 // so, abort
 122                 return 0;
 123         }
 124 #endif
 125         if (!trace_ent)
 126                 return 0;
 127         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 128                 return 1;
 129
 130         se = trace_ent;
 131         s = se.solid;
 132         se.solid = SOLID_NOT;
 133         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 134         se.solid = s;
 135
 136         return f;
 137 }
 138
 139 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 140 {
 141     float f, s;
 142
 143     if(!e.modelindex || e.warpzone_isboxy)
 144         return 1;
 145
 146     s = e.solid;
 147     e.solid = SOLID_BSP;
 148     WarpZoneLib_BoxTouchesBrush_mins = mi;
 149     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 150     WarpZoneLib_BoxTouchesBrush_ent = e;
 151     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 152     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 153     e.solid = s;
 154
 155     return f;
 156 }
 157
 158 entity WarpZone_Find(vector mi, vector ma)
 159 {
 160         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 161         entity e;
 162         if(!warpzone_warpzones_exist)
 163                 return world;
 164         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 165                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 166                         return e;
 167         return world;
 168 }
 169
 170 void WarpZone_MakeAllSolid()
 171 {
 172         entity e;
 173         if(!warpzone_warpzones_exist)
 174                 return;
 175         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 176                 e.solid = SOLID_BSP;
 177 }
 178
 179 void WarpZone_MakeAllOther()
 180 {
 181         entity e;
 182         if(!warpzone_warpzones_exist)
 183                 return;
 184         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 185                 e.solid = SOLID_TRIGGER;
 186 }
 187
 188 void WarpZone_Trace_InitTransform()
 189 {
 190         if(!WarpZone_trace_transform)
 191         {
 192                 WarpZone_trace_transform = spawn();
 193                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 194         }
 195         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 196 }
 197 void WarpZone_Trace_AddTransform(entity wz)
 198 {
 199         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 200 }
 201
 202 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 203 {
 204         float nomonsters_adjusted;
 205         float frac, sol, i;
 206         float contentshack;
 207         vector o0, e0;
 208         entity wz;
 209         vector vf, vr, vu;
 210
 211         WarpZone_trace_forent = forent;
 212         WarpZone_trace_firstzone = world;
 213         WarpZone_trace_lastzone = world;
 214         WarpZone_Trace_InitTransform();
 215         if(!warpzone_warpzones_exist)
 216         {
 217                 if(nomonsters == MOVE_NOTHING)
 218                 {
 219                         trace_endpos = end;
 220                         trace_fraction = 1;
 221                         if(cb)
 222                                 cb(org, trace_endpos, end);
 223                         return;
 224                 }
 225                 else
 226                 {
 227                         tracebox(org, mi, ma, end, nomonsters, WarpZone_trace_forent);
 228                         if(cb)
 229                                 cb(org, trace_endpos, end);
 230                         return;
 231                 }
 232         }
 233
 234         vf = v_forward;
 235         vr = v_right;
 236         vu = v_up;
 237         o0 = org;
 238         e0 = end;
 239
 240         switch(nomonsters)
 241         {
 242                 case MOVE_WORLDONLY:
 243                 case MOVE_NOTHING:
 244                         nomonsters_adjusted = MOVE_NOMONSTERS;
 245                         break;
 246                 default:
 247                         nomonsters_adjusted = nomonsters;
 248                         break;
 249         }
 250         if((contentshack = (WarpZone_trace_forent.dphitcontentsmask && !(WarpZone_trace_forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 251                 BITSET_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 252
 253         // if starting in warpzone, first transform
 254         wz = WarpZone_Find(org + mi, org + ma);
 255         if(wz)
 256         {
 257                 WarpZone_trace_firstzone = wz;
 258                 WarpZone_trace_lastzone = wz;
 259                 if(zone && wz != zone)
 260                 {
 261                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 262                         sol = 1;
 263                         trace_fraction = 0;
 264                         trace_endpos = org;
 265                         goto fail;
 266                 }
 267                 WarpZone_Trace_AddTransform(wz);
 268                 org = WarpZone_TransformOrigin(wz, org);
 269                 end = WarpZone_TransformOrigin(wz, end);
 270         }
 271         WarpZone_MakeAllSolid();
 272         sol = -1;
 273         frac = 0;
 274         i = 16;
 275         for (;;)
 276         {
 277                 if(--i < 1)
 278                 {
 279                         dprint("Too many warpzones in sequence, aborting trace.\n");
 280                         trace_ent = world;
 281                         break;
 282                 }
 283                 tracebox(org, mi, ma, end, nomonsters_adjusted, WarpZone_trace_forent);
 284                 if(cb)
 285                         cb(org, trace_endpos, end);
 286                 if(sol < 0)
 287                         sol = trace_startsolid;
 288
 289                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 290                 if(trace_fraction >= 1)
 291                         break;
 292                 if(trace_ent.classname != "trigger_warpzone")
 293                 {
 294                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & WarpZone_trace_forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 295                         {
 296                                 // continue the trace, ignoring this hit (we only care for warpzones)
 297                                 org = trace_endpos + normalize(end - org);
 298                                 continue;
 299                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 300                                 // otherwise, players could block entrances that way
 301                         }
 302                         break;
 303                 }
 304                 if(trace_ent == wz)
 305                 {
 306                         // FIXME can this check be removed? Do we really need it?
 307                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 308                         trace_ent = world;
 309                         break;
 310                 }
 311                 wz = trace_ent;
 312                 if(!WarpZone_trace_firstzone)
 313                         WarpZone_trace_firstzone = wz;
 314                 WarpZone_trace_lastzone = wz;
 315                 if(zone && wz != zone)
 316                         break;
 317                 WarpZone_Trace_AddTransform(wz);
 318                 // we hit a warpzone... so, let's perform the trace after the warp again
 319                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 320                 end = WarpZone_TransformOrigin(wz, end);
 321
 322                 // we got warped, so let's step back a bit
 323                 tracebox(org, mi, ma, org + normalize(org - end) * 32, nomonsters_adjusted, WarpZone_trace_forent);
 324                 org = trace_endpos;
 325         }
 326         WarpZone_MakeAllOther();
 327 :fail
 328         if(contentshack)
 329                 BITCLR_ASSIGN(WarpZone_trace_forent.dphitcontentsmask, DPCONTENTS_SOLID);
 330         trace_startsolid = sol;
 331         v_forward = vf;
 332         v_right = vr;
 333         v_up = vu;
 334 }
 335
 336 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 337 {
 338         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 339 }
 340
 341 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 342 {
 343         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 344 }
 345
 346 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 347 {
 348         float g, dt, i;
 349         vector vf, vr, vu, v0, o0;
 350         entity wz;
 351
 352         o0 = e.origin;
 353         v0 = e.velocity;
 354         g = cvar("sv_gravity") * e.gravity;
 355
 356         WarpZone_trace_forent = forent;
 357         WarpZone_trace_firstzone = world;
 358         WarpZone_trace_lastzone = world;
 359         WarpZone_Trace_InitTransform();
 360         WarpZone_tracetoss_time = 0;
 361         if(!warpzone_warpzones_exist)
 362         {
 363                 tracetoss(e, WarpZone_trace_forent);
 364                 if(cb)
 365                         cb(e.origin, trace_endpos, trace_endpos);
 366                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 367                 WarpZone_tracetoss_time += dt;
 368                 e.velocity_z -= dt * g;
 369                 WarpZone_tracetoss_velocity = e.velocity;
 370                 e.velocity = v0;
 371                 return;
 372         }
 373
 374         vf = v_forward;
 375         vr = v_right;
 376         vu = v_up;
 377
 378         // if starting in warpzone, first transform
 379         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 380         if(wz)
 381         {
 382                 WarpZone_trace_firstzone = wz;
 383                 WarpZone_trace_lastzone = wz;
 384                 if(zone && wz != zone)
 385                 {
 386                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 387
 388                         WarpZone_tracetoss_time = 0;
 389                         trace_endpos = o0;
 390                         goto fail;
 391                 }
 392                 WarpZone_Trace_AddTransform(wz);
 393                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 394                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 395         }
 396         WarpZone_MakeAllSolid();
 397         i = 16;
 398         for (;;)
 399         {
 400                 if(--i < 1)
 401                 {
 402                         dprint("Too many warpzones in sequence, aborting trace.\n");
 403                         trace_ent = world;
 404                         break;
 405                 }
 406                 tracetoss(e, WarpZone_trace_forent);
 407                 if(cb)
 408                         cb(e.origin, trace_endpos, trace_endpos);
 409                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 410                 WarpZone_tracetoss_time += dt;
 411                 e.origin = trace_endpos;
 412                 e.velocity_z -= dt * g;
 413                 if(trace_fraction >= 1)
 414                         break;
 415                 if(trace_ent.classname != "trigger_warpzone")
 416                         break;
 417                 if(trace_ent == wz)
 418                 {
 419                         // FIXME can this check be removed? Do we really need it?
 420                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 421                         trace_ent = world;
 422                         break;
 423                 }
 424                 wz = trace_ent;
 425                 if(!WarpZone_trace_firstzone)
 426                         WarpZone_trace_firstzone = wz;
 427                 WarpZone_trace_lastzone = wz;
 428                 if(zone && wz != zone)
 429                         break;
 430                 WarpZone_Trace_AddTransform(wz);
 431                 // we hit a warpzone... so, let's perform the trace after the warp again
 432                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 433                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 434
 435                 // we got warped, so let's step back a bit
 436                 e.velocity = -e.velocity;
 437                 tracetoss(e, WarpZone_trace_forent);
 438                 dt = vlen(trace_endpos - e.origin) / vlen(e.velocity);
 439                 WarpZone_tracetoss_time -= dt;
 440                 e.origin = trace_endpos;
 441                 e.velocity = -e.velocity;
 442         }
 443         WarpZone_MakeAllOther();
 444 :fail
 445         WarpZone_tracetoss_velocity = e.velocity;
 446         v_forward = vf;
 447         v_right = vr;
 448         v_up = vu;
 449         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 450         e.velocity = v0;
 451         e.origin = o0;
 452 }
 453
 454 void WarpZone_TraceToss(entity e, entity forent)
 455 {
 456         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 457 }
 458
 459 entity WarpZone_TrailParticles_trace_callback_own;
 460 float WarpZone_TrailParticles_trace_callback_eff;
 461 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 462 {
 463         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 464 }
 465
 466 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 467 {
 468         WarpZone_TrailParticles_trace_callback_own = own;
 469         WarpZone_TrailParticles_trace_callback_eff = eff;
 470         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 471 }
 472
 473 #ifdef CSQC
 474 float WarpZone_TrailParticles_trace_callback_f;
 475 float WarpZone_TrailParticles_trace_callback_flags;
 476 void WarpZone_TrailParticles_WithMultiplier_trace_callback(vector from, vector endpos, vector to)
 477 {
 478         boxparticles(WarpZone_TrailParticles_trace_callback_eff, WarpZone_TrailParticles_trace_callback_own, from, endpos, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_own.velocity, WarpZone_TrailParticles_trace_callback_f, WarpZone_TrailParticles_trace_callback_flags);
 479 }
 480
 481 void WarpZone_TrailParticles_WithMultiplier(entity own, float eff, vector org, vector end, float f, int boxflags)
 482 {
 483         WarpZone_TrailParticles_trace_callback_own = own;
 484         WarpZone_TrailParticles_trace_callback_eff = eff;
 485         WarpZone_TrailParticles_trace_callback_f = f;
 486         WarpZone_TrailParticles_trace_callback_flags = boxflags | PARTICLES_DRAWASTRAIL;
 487         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_WithMultiplier_trace_callback);
 488 }
 489 #endif
 490
 491 float WarpZone_PlaneDist(entity wz, vector v)
 492 {
 493         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 494 }
 495
 496 float WarpZone_TargetPlaneDist(entity wz, vector v)
 497 {
 498         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 499 }
 500
 501 vector WarpZone_TransformOrigin(entity wz, vector v)
 502 {
 503         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 504 }
 505
 506 vector WarpZone_TransformVelocity(entity wz, vector v)
 507 {
 508         return AnglesTransform_Apply(wz.warpzone_transform, v);
 509 }
 510
 511 vector WarpZone_TransformAngles(entity wz, vector v)
 512 {
 513         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 514 }
 515
 516 vector WarpZone_TransformVAngles(entity wz, vector ang)
 517 {
 518 #ifdef KEEP_ROLL
 519         float roll;
 520         roll = ang.z;
 521         ang.z = 0;
 522 #endif
 523
 524         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 525
 526 #ifdef KEEP_ROLL
 527         ang = AnglesTransform_Normalize(ang, true);
 528         ang = AnglesTransform_CancelRoll(ang);
 529         ang.z = roll;
 530 #else
 531         ang = AnglesTransform_Normalize(ang, false);
 532 #endif
 533
 534         return ang;
 535 }
 536
 537 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 538 {
 539         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 540 }
 541
 542 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 543 {
 544         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 545 }
 546
 547 vector WarpZone_UnTransformAngles(entity wz, vector v)
 548 {
 549         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 550 }
 551
 552 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 553 {
 554         float roll;
 555
 556         roll = ang.z;
 557         ang.z = 0;
 558
 559         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 560         ang = AnglesTransform_Normalize(ang, true);
 561         ang = AnglesTransform_CancelRoll(ang);
 562
 563         ang.z = roll;
 564         return ang;
 565 }
 566
 567 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 568 {
 569         vector nearest;
 570         nearest.x = bound(mi.x, org.x, ma.x);
 571         nearest.y = bound(mi.y, org.y, ma.y);
 572         nearest.z = bound(mi.z, org.z, ma.z);
 573         return nearest;
 574 }
 575
 576 float WarpZoneLib_BadClassname(string myclassname)
 577 {
 578         switch(myclassname)
 579         {
 580                 case "weapon_info":
 581                 case "monster_info":
 582                 case "deathtype":
 583                 case "callback":
 584                 case "callbackchain":
 585                 case "weaponentity":
 586                 case "exteriorweaponentity":
 587                 case "csqc_score_team":
 588                 case "pingplreport":
 589                 case "ent_client_scoreinfo":
 590                 case "saved_cvar_value":
 591                 case "accuracy":
 592                 case "entcs_sender_v2":
 593                 case "entcs_receiver_v2":
 594                 case "clientinit":
 595                 case "sprite_waypoint":
 596                 case "waypoint":
 597                 case "gibsplash":
 598                 //case "net_linked": // actually some real entities are linked without classname, fail
 599                 case "":
 600                         return true;
 601         }
 602
 603         if(startsWith(myclassname, "msg_"))
 604                 return true;
 605
 606         if(startsWith(myclassname, "target_"))
 607                 return true;
 608
 609         if(startsWith(myclassname, "info_"))
 610                 return true;
 611
 612         return false;
 613 }
 614
 615 .float WarpZone_findradius_hit;
 616 .entity WarpZone_findradius_next;
 617 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 618 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 619 {
 620         vector org_new;
 621         vector org0_new;
 622         vector shift_new, transform_new;
 623         vector p;
 624         entity e, e0;
 625         entity wz;
 626         if(rad <= 0)
 627                 return;
 628         e0 = findradius(org, rad);
 629         wz = world;
 630
 631         for(e = e0; e; e = e.chain)
 632         {
 633                 if(WarpZoneLib_BadClassname(e.classname))
 634                         continue;
 635                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 636                 if(needlineofsight)
 637                 {
 638                         traceline(org, p, MOVE_NOMONSTERS, e);
 639                         if(trace_fraction < 1)
 640                                 continue;
 641                 }
 642                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 643                 {
 644                         e.WarpZone_findradius_nearest = p;
 645                         e.WarpZone_findradius_dist = org0 - p;
 646                         e.WarpZone_findradius_findorigin = org;
 647                         e.WarpZone_findradius_findradius = rad;
 648                         if(e.classname == "warpzone_refsys")
 649                         {
 650                                 // ignore, especially: do not overwrite the refsys parameters
 651                         }
 652                         else if(e.classname == "trigger_warpzone")
 653                         {
 654                                 e.WarpZone_findradius_next = wz;
 655                                 wz = e;
 656                                 e.WarpZone_findradius_hit = 1;
 657                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 658                                 e.enemy.WarpZone_findradius_hit = 1;
 659                         }
 660                         else
 661                         {
 662                                 e.warpzone_transform = transform;
 663                                 e.warpzone_shift = shift;
 664                                 e.WarpZone_findradius_hit = 1;
 665                         }
 666                 }
 667         }
 668         for(e = wz; e; e = e.WarpZone_findradius_next)
 669         {
 670                 if(WarpZoneLib_BadClassname(e.classname))
 671                         continue;
 672
 673                 org0_new = WarpZone_TransformOrigin(e, org);
 674                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 675                 org_new = trace_endpos;
 676
 677                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 678                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 679                 WarpZone_FindRadius_Recurse(
 680                         org_new,
 681                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 682                         org0_new,
 683                         transform_new, shift_new,
 684                         needlineofsight);
 685                 e.WarpZone_findradius_hit = 0;
 686                 e.enemy.WarpZone_findradius_hit = 0;
 687         }
 688 }
 689 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 690 {
 691         entity e0, e;
 692         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 693         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 694         for(e = e0; e; e = e.chain)
 695                 e.WarpZone_findradius_hit = 0;
 696         return e0;
 697 }
 698
 699 .entity WarpZone_refsys;
 700 void WarpZone_RefSys_GC()
 701 {
 702         // garbage collect unused reference systems
 703         self.nextthink = time + 1;
 704         if(self.owner.WarpZone_refsys != self)
 705                 remove(self);
 706 }
 707 void WarpZone_RefSys_CheckCreate(entity me)
 708 {
 709         if(me.WarpZone_refsys.owner != me)
 710         {
 711                 me.WarpZone_refsys = spawn();
 712                 me.WarpZone_refsys.classname = "warpzone_refsys";
 713                 me.WarpZone_refsys.owner = me;
 714                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 715                 me.WarpZone_refsys.nextthink = time + 1;
 716                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 717         }
 718 }
 719 void WarpZone_RefSys_Clear(entity me)
 720 {
 721         if(me.WarpZone_refsys)
 722         {
 723                 remove(me.WarpZone_refsys);
 724                 me.WarpZone_refsys = world;
 725         }
 726 }
 727 void WarpZone_RefSys_AddTransform(entity me, vector t, vector s)
 728 {
 729         if(t != '0 0 0' || s != '0 0 0')
 730         {
 731                 WarpZone_RefSys_CheckCreate(me);
 732                 WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 733         }
 734 }
 735 void WarpZone_RefSys_Add(entity me, entity wz)
 736 {
 737         WarpZone_RefSys_AddTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 738 }
 739 void WarpZone_RefSys_AddInverseTransform(entity me, vector t, vector s)
 740 {
 741         if(t != '0 0 0' || s != '0 0 0')
 742         {
 743                 WarpZone_RefSys_CheckCreate(me);
 744                 WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, t, s);
 745         }
 746 }
 747 void WarpZone_RefSys_AddInverse(entity me, entity wz)
 748 {
 749         WarpZone_RefSys_AddInverseTransform(me, wz.warpzone_transform, wz.warpzone_shift);
 750 }
 751 .vector WarpZone_refsys_incremental_shift;
 752 .vector WarpZone_refsys_incremental_transform;
 753 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 754 {
 755         //vector t, s;
 756         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 757         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 758                 return;
 759         WarpZone_Accumulator_AddInverseTransform(me.WarpZone_refsys, me.WarpZone_refsys_incremental_transform, me.WarpZone_refsys_incremental_shift);
 760         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref.WarpZone_refsys);
 761         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 762         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 763 }
 764 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 765 {
 766         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 767         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 768 }
 769 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 770 {
 771         if(from.WarpZone_refsys)
 772                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 773         if(to.WarpZone_refsys)
 774                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 775         return org;
 776 }
 777 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 778 {
 779         if(from.WarpZone_refsys)
 780                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 781         if(to.WarpZone_refsys)
 782                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 783         return vel;
 784 }
 785 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 786 {
 787         if(from.WarpZone_refsys)
 788                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 789         if(to.WarpZone_refsys)
 790                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 791         return ang;
 792 }
 793 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 794 {
 795         if(from.WarpZone_refsys)
 796                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 797         if(to.WarpZone_refsys)
 798                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 799         return ang;
 800 }
 801 void WarpZone_RefSys_Copy(entity me, entity from)
 802 {
 803         if(from.WarpZone_refsys)
 804         {
 805                 WarpZone_RefSys_CheckCreate(me);
 806                 me.WarpZone_refsys.warpzone_shift = from.WarpZone_refsys.warpzone_shift;
 807                 me.WarpZone_refsys.warpzone_transform = from.WarpZone_refsys.warpzone_transform;
 808         }
 809         else
 810                 WarpZone_RefSys_Clear(me);
 811 }
 812 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 813 {
 814         entity e;
 815         e = spawn();
 816         WarpZone_RefSys_Copy(e, me);
 817         return e;
 818 }
 819
 820 float WarpZoneLib_ExactTrigger_Touch()
 821 {
 822         return !WarpZoneLib_BoxTouchesBrush(other.absmin, other.absmax, self, other);
 823 }
 824
 825
 826 void WarpZoneLib_MoveOutOfSolid_Expand(entity e, vector by)
 827 {
 828         float eps = 0.0625;
 829         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
 830         if (trace_startsolid)
 831                 return;
 832         if (trace_fraction < 1)
 833         {
 834                 // hit something
 835                 // adjust origin in the other direction...
 836                 setorigin(e,e.origin - by * (1 - trace_fraction));
 837         }
 838 }
 839
 840 float WarpZoneLib_MoveOutOfSolid(entity e)
 841 {
 842         vector o, m0, m1;
 843
 844         o = e.origin;
 845         traceline(o, o, MOVE_WORLDONLY, e);
 846         if (trace_startsolid)
 847                 return false;
 848
 849         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
 850         if (!trace_startsolid)
 851                 return true;
 852
 853         m0 = e.mins;
 854         m1 = e.maxs;
 855         e.mins = '0 0 0';
 856         e.maxs = '0 0 0';
 857         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m0_x);
 858         e.mins_x = m0_x;
 859         WarpZoneLib_MoveOutOfSolid_Expand(e, '1 0 0' * m1_x);
 860         e.maxs_x = m1_x;
 861         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m0_y);
 862         e.mins_y = m0_y;
 863         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 1 0' * m1_y);
 864         e.maxs_y = m1_y;
 865         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m0_z);
 866         e.mins_z = m0_z;
 867         WarpZoneLib_MoveOutOfSolid_Expand(e, '0 0 1' * m1_z);
 868         e.maxs_z = m1_z;
 869         setorigin(e, e.origin);
 870
 871         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 872         if (trace_startsolid)
 873         {
 874                 setorigin(e, o);
 875                 return false;
 876         }
 877
 878         return true;
 879 }