qcsrc/warpzonelib/server.qc

   1 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
   2 .float warpzone_teleport_time;
   3
   4 void WarpZone_StoreProjectileData(entity e)
   5 {
   6         e.warpzone_oldorigin = e.origin;
   7         e.warpzone_oldvelocity = e.velocity;
   8         e.warpzone_oldangles = e.angles;
   9 }
  10
  11 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  12 {
  13         vector from;
  14
  15         makevectors (to_angles);
  16
  17         from = player.origin;
  18         setorigin (player, to);
  19         player.oldorigin = to; // for DP's unsticking
  20         player.angles = to_angles;
  21         player.fixangle = TRUE;
  22         player.velocity = to_velocity;
  23
  24         if(player.effects & EF_TELEPORT_BIT)
  25                 player.effects &~= EF_TELEPORT_BIT;
  26         else
  27                 player.effects |= EF_TELEPORT_BIT;
  28
  29         if(player.classname == "player")
  30                 player.flags &~= FL_ONGROUND;
  31
  32         WarpZone_PostTeleportPlayer_Callback(player);
  33 }
  34
  35 float WarpZone_Teleport(entity player)
  36 {
  37         vector o0, a0, v0, o1, a1, v1;
  38
  39         o0 = player.origin + player.view_ofs;
  40         v0 = player.velocity;
  41         a0 = player.angles;
  42
  43         if(WarpZone_PlaneDist(self, o0) >= 0) // wrong side of the trigger_warpzone
  44                 return 2;
  45         // no failure, we simply don't want to teleport yet; TODO in
  46         // this situation we may want to create a temporary clone
  47         // entity of the player to fix graphics glitch
  48
  49         o1 = WarpZone_TransformOrigin(self, o0);
  50         v1 = WarpZone_TransformVelocity(self, v0);
  51         if(clienttype(player) != CLIENTTYPE_NOTACLIENT)
  52                 a1 = WarpZone_TransformVAngles(self, player.v_angle);
  53         else
  54                 a1 = WarpZone_TransformAngles(self, a0);
  55
  56         // put him inside solid
  57         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
  58         if(trace_startsolid)
  59         {
  60                 vector mi, ma;
  61                 mi = player.mins;
  62                 ma = player.maxs;
  63                 setsize(player, mi - player.view_ofs, ma - player.view_ofs);
  64                 setorigin(player, o1);
  65                 if(WarpZoneLib_MoveOutOfSolid(player))
  66                 {
  67                         o1 = player.origin;
  68                         setsize(player, mi, ma);
  69                         setorigin(player, o0);
  70                 }
  71                 else
  72                 {
  73                         print("would have to put player in solid, won't do that\n");
  74                         setsize(player, mi, ma);
  75                         setorigin(player, o0 - player.view_ofs);
  76                         return 0; // cannot fix
  77                 }
  78         }
  79
  80         if(WarpZone_TargetPlaneDist(self, o1) <= 0)
  81         {
  82                 print("inconsistent warp zones or evil roundoff error\n");
  83                 return 0;
  84         }
  85
  86         //print(sprintf("warpzone: %f %f %f -> %f %f %f\n", o0_x, o0_y, o0_z, o1_x, o1_y, o1_z));
  87
  88         //o1 = trace_endpos;
  89         WarpZone_RefSys_Add(player, self);
  90         WarpZone_TeleportPlayer(self, player, o1 - player.view_ofs, a1, v1);
  91         WarpZone_StoreProjectileData(player);
  92         player.warpzone_teleport_time = time;
  93
  94         return 1;
  95 }
  96
  97 void WarpZone_Touch (void)
  98 {
  99         entity oldself, e;
 100
 101         if(other.classname == "trigger_warpzone")
 102                 return;
 103
 104         // FIXME needs a better check to know what is safe to teleport and what not
 105         if(other.movetype == MOVETYPE_NONE)
 106                 return;
 107
 108         if(WarpZoneLib_ExactTrigger_Touch())
 109                 return;
 110
 111         e = self.enemy;
 112         if(WarpZone_Teleport(other))
 113         {
 114                 string save1, save2;
 115                 activator = other;
 116
 117                 save1 = self.target; self.target = string_null;
 118                 save2 = self.target3; self.target3 = string_null;
 119                 SUB_UseTargets();
 120                 if not(self.target) self.target = save1;
 121                 if not(self.target3) self.target3 = save2;
 122
 123                 oldself = self;
 124                 self = self.enemy;
 125                 save1 = self.target; self.target = string_null;
 126                 save2 = self.target2; self.target2 = string_null;
 127                 SUB_UseTargets();
 128                 if not(self.target) self.target = save1;
 129                 if not(self.target2) self.target2 = save2;
 130                 self = oldself;
 131         }
 132         else
 133         {
 134                 dprint("WARPZONE FAIL AHAHAHAHAH))\n");
 135         }
 136 }
 137
 138 float WarpZone_Send(entity to, float sendflags)
 139 {
 140         float f;
 141         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 142
 143         // we must send this flag for clientside to match properly too
 144         f = 0;
 145         if(self.warpzone_isboxy)
 146                 f |= 1;
 147         if(self.warpzone_fadestart)
 148                 f |= 2;
 149         if(self.origin != '0 0 0')
 150                 f |= 4;
 151         WriteByte(MSG_ENTITY, f);
 152
 153         // we need THESE to render the warpzone (and cull properly)...
 154         if(f & 4)
 155         {
 156                 WriteCoord(MSG_ENTITY, self.origin_x);
 157                 WriteCoord(MSG_ENTITY, self.origin_y);
 158                 WriteCoord(MSG_ENTITY, self.origin_z);
 159         }
 160
 161         WriteShort(MSG_ENTITY, self.modelindex);
 162         WriteCoord(MSG_ENTITY, self.mins_x);
 163         WriteCoord(MSG_ENTITY, self.mins_y);
 164         WriteCoord(MSG_ENTITY, self.mins_z);
 165         WriteCoord(MSG_ENTITY, self.maxs_x);
 166         WriteCoord(MSG_ENTITY, self.maxs_y);
 167         WriteCoord(MSG_ENTITY, self.maxs_z);
 168         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 169
 170         // we need THESE to calculate the proper transform
 171         WriteCoord(MSG_ENTITY, self.warpzone_origin_x);
 172         WriteCoord(MSG_ENTITY, self.warpzone_origin_y);
 173         WriteCoord(MSG_ENTITY, self.warpzone_origin_z);
 174         WriteCoord(MSG_ENTITY, self.warpzone_angles_x);
 175         WriteCoord(MSG_ENTITY, self.warpzone_angles_y);
 176         WriteCoord(MSG_ENTITY, self.warpzone_angles_z);
 177         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_x);
 178         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_y);
 179         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_z);
 180         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_x);
 181         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_y);
 182         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_z);
 183
 184         if(f & 2)
 185         {
 186                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 187                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 188         }
 189
 190         return TRUE;
 191 }
 192
 193 float WarpZone_Camera_Send(entity to, float sendflags)
 194 {
 195         float f;
 196         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 197
 198         if(self.warpzone_fadestart)
 199                 f |= 2;
 200         if(self.origin != '0 0 0')
 201                 f |= 4;
 202         WriteByte(MSG_ENTITY, f);
 203
 204         // we need THESE to render the warpzone (and cull properly)...
 205         if(f & 4)
 206         {
 207                 WriteCoord(MSG_ENTITY, self.origin_x);
 208                 WriteCoord(MSG_ENTITY, self.origin_y);
 209                 WriteCoord(MSG_ENTITY, self.origin_z);
 210         }
 211
 212         WriteShort(MSG_ENTITY, self.modelindex);
 213         WriteCoord(MSG_ENTITY, self.mins_x);
 214         WriteCoord(MSG_ENTITY, self.mins_y);
 215         WriteCoord(MSG_ENTITY, self.mins_z);
 216         WriteCoord(MSG_ENTITY, self.maxs_x);
 217         WriteCoord(MSG_ENTITY, self.maxs_y);
 218         WriteCoord(MSG_ENTITY, self.maxs_z);
 219         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 220
 221         // we need THESE to calculate the proper transform
 222         WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 223         WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 224         WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 225         WriteCoord(MSG_ENTITY, self.enemy.angles_x);
 226         WriteCoord(MSG_ENTITY, self.enemy.angles_y);
 227         WriteCoord(MSG_ENTITY, self.enemy.angles_z);
 228
 229         if(f & 2)
 230         {
 231                 WriteShort(MSG_ENTITY, self.warpzone_fadestart);
 232                 WriteShort(MSG_ENTITY, self.warpzone_fadeend);
 233         }
 234
 235         return TRUE;
 236 }
 237
 238 float WarpZone_CheckProjectileImpact()
 239 {
 240         // if self hit a warpzone, abort
 241         vector o0, v0, a0;
 242         float mpd, pd, dpd;
 243         entity wz;
 244         wz = WarpZone_Find(self.origin + self.mins, self.origin + self.maxs);
 245         if(!wz)
 246                 return 0;
 247         if(self.warpzone_teleport_time == time)
 248         {
 249                 // just ignore if we got teleported this frame already and now hit a wall and are in a warpzone again (this will cause a detonation)
 250                 // print("2 warps 1 frame\n");
 251                 return -1;
 252         }
 253         o0 = self.origin;
 254         v0 = self.velocity;
 255         a0 = self.angles;
 256
 257         // this approach transports the projectile at its full speed, but does
 258         // not properly retain the projectile trail (but we can't retain it
 259         // easily anyway without delaying the projectile by two frames, so who
 260         // cares)
 261         WarpZone_TraceBox_ThroughZone(self.warpzone_oldorigin, self.mins, self.maxs, self.warpzone_oldorigin + self.warpzone_oldvelocity * frametime, MOVE_NORMAL, self, wz, WarpZone_trace_callback_t_null); // this will get us through the warpzone
 262         setorigin(self, trace_endpos);
 263         self.angles = WarpZone_TransformAngles(WarpZone_trace_transform, self.angles);
 264         self.velocity = WarpZone_TransformVelocity(WarpZone_trace_transform, self.warpzone_oldvelocity);
 265
 266         // in case we are in our warp zone post-teleport, shift the projectile forward a bit
 267         mpd = max(vlen(self.mins), vlen(self.maxs));
 268         pd = WarpZone_TargetPlaneDist(wz, self.origin);
 269         if(pd < mpd)
 270         {
 271                 dpd = normalize(self.velocity) * wz.warpzone_targetforward;
 272                 setorigin(self, self.origin + normalize(self.velocity) * ((mpd - pd) / dpd));
 273                 if(!WarpZoneLib_MoveOutOfSolid(self))
 274                 {
 275                         setorigin(self, o0);
 276                         self.angles = a0;
 277                         self.velocity = v0;
 278                         return 0;
 279                 }
 280         }
 281         WarpZone_RefSys_Add(self, wz);
 282         WarpZone_StoreProjectileData(self);
 283         self.warpzone_teleport_time = time;
 284
 285         return +1;
 286 }
 287 float WarpZone_Projectile_Touch()
 288 {
 289         float f;
 290         if(other.classname == "trigger_warpzone")
 291                 return TRUE;
 292         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 293                 return TRUE;
 294         if((f = WarpZone_CheckProjectileImpact()) != 0)
 295                 return (f > 0);
 296         if(self.warpzone_teleport_time == time)
 297         {
 298                 // sequence: hit warpzone, get teleported, hit wall
 299                 // print("2 hits 1 frame\n");
 300                 setorigin(self, self.warpzone_oldorigin);
 301                 self.velocity = self.warpzone_oldvelocity;
 302                 self.angles = self.warpzone_oldangles;
 303                 return TRUE;
 304         }
 305         return FALSE;
 306 }
 307
 308 void WarpZone_InitStep_FindOriginTarget()
 309 {
 310         if(self.killtarget != "")
 311         {
 312                 self.aiment = find(world, targetname, self.killtarget);
 313                 if(self.aiment == world)
 314                 {
 315                         error("Warp zone with nonexisting killtarget");
 316                         return;
 317                 }
 318                 self.killtarget = string_null;
 319         }
 320 }
 321
 322 void WarpZonePosition_InitStep_FindTarget()
 323 {
 324         if(self.target == "")
 325         {
 326                 error("Warp zone position with no target");
 327                 return;
 328         }
 329         self.enemy = find(world, targetname, self.target);
 330         if(self.enemy == world)
 331         {
 332                 error("Warp zone position with nonexisting target");
 333                 return;
 334         }
 335         if(self.enemy.aiment)
 336         {
 337                 // already is positioned
 338                 error("Warp zone position targeting already oriented warpzone");
 339                 return;
 340         }
 341         self.enemy.aiment = self;
 342 }
 343
 344 void WarpZoneCamera_InitStep_FindTarget()
 345 {
 346         entity e;
 347         float i;
 348         if(self.target == "")
 349         {
 350                 error("Camera with no target");
 351                 return;
 352         }
 353         self.enemy = world;
 354         for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 355                 if(random() * ++i < 1)
 356                         self.enemy = e;
 357         if(self.enemy == world)
 358         {
 359                 error("Camera with nonexisting target");
 360                 return;
 361         }
 362         warpzone_cameras_exist = 1;
 363         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 364         self.SendFlags = 0xFFFFFF;
 365 }
 366
 367 void WarpZone_InitStep_UpdateTransform()
 368 {
 369         vector org, ang, norm, point;
 370         float area;
 371         vector tri, a, b, c, p, q, n;
 372         float i_s, i_t, n_t;
 373         string tex;
 374
 375         org = self.origin;
 376         if(org == '0 0 0')
 377                 org = 0.5 * (self.mins + self.maxs);
 378
 379         norm = point = '0 0 0';
 380         area = 0;
 381         for(i_s = 0; ; ++i_s)
 382         {
 383                 tex = getsurfacetexture(self, i_s);
 384                 if not(tex)
 385                         break; // this is beyond the last one
 386                 if(tex == "textures/common/trigger")
 387                         continue;
 388                 n_t = getsurfacenumtriangles(self, i_s);
 389                 for(i_t = 0; i_t < n_t; ++i_t)
 390                 {
 391                         tri = getsurfacetriangle(self, i_s, i_t);
 392                         a = getsurfacepoint(self, i_s, tri_x);
 393                         b = getsurfacepoint(self, i_s, tri_y);
 394                         c = getsurfacepoint(self, i_s, tri_z);
 395                         p = b - a;
 396                         q = c - a;
 397                         n =     '1 0 0' * (q_y * p_z - q_z * p_y)
 398                         +       '0 1 0' * (q_z * p_x - q_x * p_z)
 399                         +       '0 0 1' * (q_x * p_y - q_y * p_x);
 400                         area = area + vlen(n);
 401                         norm = norm + n;
 402                         point = point + vlen(n) * (a + b + c);
 403                 }
 404         }
 405         if(area > 0)
 406         {
 407                 norm = norm * (1 / area);
 408                 point = point * (1 / (3 * area));
 409                 if(vlen(norm) < 0.99)
 410                 {
 411                         print("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 412                         area = 0; // no autofixing in this case
 413                 }
 414                 norm = normalize(norm);
 415         }
 416
 417         if(self.aiment)
 418         {
 419                 org = self.aiment.origin;
 420                 ang = self.aiment.angles;
 421                 if(area > 0)
 422                 {
 423                         org = org - ((org - point) * norm) * norm; // project to plane
 424                         makevectors(ang);
 425                         if(norm * v_forward < 0)
 426                         {
 427                                 print("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 428                                 norm = -1 * norm;
 429                         }
 430                         ang = vectoangles(norm, v_up); // keep rotation, but turn exactly against plane
 431                         ang_x = -ang_x;
 432                         if(norm * v_forward < 0.99)
 433                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 434                         if(vlen(org - self.aiment.origin) > 0.5)
 435                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 436                 }
 437         }
 438         else if(area > 0)
 439         {
 440                 org = point;
 441                 ang = vectoangles(norm);
 442                 ang_x = -ang_x;
 443         }
 444         else
 445                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 446
 447         self.warpzone_origin = org;
 448         self.warpzone_angles = ang;
 449 }
 450
 451 void WarpZone_InitStep_ClearTarget()
 452 {
 453         if(self.enemy)
 454                 self.enemy.enemy = world;
 455         self.enemy = world;
 456 }
 457
 458 entity warpzone_first; .entity warpzone_next;
 459 void WarpZone_InitStep_FindTarget()
 460 {
 461         float i;
 462         entity e, e2;
 463
 464         if(self.enemy)
 465                 return;
 466
 467         // this way only one of the two ents needs to target
 468         if(self.target != "")
 469         {
 470                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 471
 472                 e2 = world;
 473                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 474                         if(!e.enemy)
 475                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 476                                         if(random() * ++i < 1)
 477                                                 e2 = e;
 478                 if(!e2)
 479                 {
 480                         self.enemy = world;
 481                         error("Warpzone with non-existing target");
 482                         return;
 483                 }
 484                 self.enemy = e2;
 485                 e2.enemy = self;
 486         }
 487 }
 488
 489 void WarpZone_InitStep_FinalizeTransform()
 490 {
 491         if(!self.enemy || self.enemy.enemy != self)
 492         {
 493                 error("Invalid warp zone detected. Killed.");
 494                 return;
 495         }
 496
 497         warpzone_warpzones_exist = 1;
 498         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 499         self.touch = WarpZone_Touch;
 500         self.SendFlags = 0xFFFFFF;
 501 }
 502
 503 float warpzone_initialized;
 504 entity warpzone_first;
 505 entity warpzone_position_first;
 506 entity warpzone_camera_first;
 507 .entity warpzone_next;
 508 void spawnfunc_misc_warpzone_position(void)
 509 {
 510         // "target", "angles", "origin"
 511         self.warpzone_next = warpzone_position_first;
 512         warpzone_position_first = self;
 513 }
 514 void spawnfunc_trigger_warpzone_position(void)
 515 {
 516         spawnfunc_misc_warpzone_position();
 517 }
 518 void spawnfunc_trigger_warpzone(void)
 519 {
 520         // warp zone entities must have:
 521         // "killtarget" pointing to a target_position with a direction arrow
 522         //              that points AWAY from the warp zone, and that is inside
 523         //              the warp zone trigger
 524         // "target"     pointing to an identical warp zone at another place in
 525         //              the map, with another killtarget to designate its
 526         //              orientation
 527
 528         if(!self.scale)
 529                 self.scale = self.modelscale;
 530         if(!self.scale)
 531                 self.scale = 1;
 532         string m;
 533         m = self.model;
 534         WarpZoneLib_ExactTrigger_Init();
 535         if(m != "")
 536         {
 537                 precache_model(m);
 538                 setmodel(self, m); // no precision needed
 539         }
 540         setorigin(self, self.origin);
 541         if(self.scale)
 542                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 543         else
 544                 setsize(self, self.mins, self.maxs);
 545         self.SendEntity = WarpZone_Send;
 546         self.SendFlags = 0xFFFFFF;
 547         self.effects |= EF_NODEPTHTEST;
 548         self.warpzone_next = warpzone_first;
 549         warpzone_first = self;
 550 }
 551 void spawnfunc_func_camera(void)
 552 {
 553         if(!self.scale)
 554                 self.scale = self.modelscale;
 555         if(!self.scale)
 556                 self.scale = 1;
 557         if(self.model != "")
 558         {
 559                 precache_model(self.model);
 560                 setmodel(self, self.model); // no precision needed
 561         }
 562         setorigin(self, self.origin);
 563         if(self.scale)
 564                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 565         else
 566                 setsize(self, self.mins, self.maxs);
 567         if(!self.solid)
 568                 self.solid = SOLID_BSP;
 569         else if(self.solid < 0)
 570                 self.solid = SOLID_NOT;
 571         self.SendEntity = WarpZone_Camera_Send;
 572         self.SendFlags = 0xFFFFFF;
 573         self.warpzone_next = warpzone_camera_first;
 574         warpzone_camera_first = self;
 575 }
 576 void WarpZones_Reconnect()
 577 {
 578         entity e;
 579         e = self;
 580         for(self = warpzone_first; self; self = self.warpzone_next)
 581                 WarpZone_InitStep_ClearTarget();
 582         for(self = warpzone_first; self; self = self.warpzone_next)
 583                 WarpZone_InitStep_FindTarget();
 584         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 585                 WarpZoneCamera_InitStep_FindTarget();
 586         for(self = warpzone_first; self; self = self.warpzone_next)
 587                 WarpZone_InitStep_FinalizeTransform();
 588         self = e;
 589 }
 590
 591 void WarpZone_StartFrame()
 592 {
 593         entity e;
 594         if(warpzone_initialized == 0)
 595         {
 596                 warpzone_initialized = 1;
 597                 e = self;
 598                 for(self = warpzone_first; self; self = self.warpzone_next)
 599                         WarpZone_InitStep_FindOriginTarget();
 600                 for(self = warpzone_position_first; self; self = self.warpzone_next)
 601                         WarpZonePosition_InitStep_FindTarget();
 602                 for(self = warpzone_first; self; self = self.warpzone_next)
 603                         WarpZone_InitStep_UpdateTransform();
 604                 self = e;
 605                 WarpZones_Reconnect();
 606         }
 607
 608         entity oldself, oldother;
 609         oldself = self;
 610         oldother = other;
 611         for(e = world; (e = nextent(e)); )
 612         {
 613                 WarpZone_StoreProjectileData(e);
 614                 float f;
 615                 f = clienttype(e);
 616                 if(f == CLIENTTYPE_REAL)
 617                 {
 618                         if(e.solid != SOLID_NOT) // not spectating?
 619                                 continue;
 620                         if(e.movetype != MOVETYPE_NOCLIP && e.movetype != MOVETYPE_FLY) // not spectating? (this is to catch observers)
 621                                 continue;
 622                         self = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 623                         if(!self)
 624                                 continue;
 625                         other = e;
 626                         if(WarpZoneLib_ExactTrigger_Touch())
 627                                 continue;
 628                         WarpZone_Teleport(e); // NOT triggering targets by this!
 629                 }
 630                 if(f == CLIENTTYPE_NOTACLIENT)
 631                 {
 632                         for(; (e = nextent(e)); )
 633                                 WarpZone_StoreProjectileData(e);
 634                         break;
 635                 }
 636         }
 637         self = oldself;
 638         other = oldother;
 639 }
 640
 641 .float warpzone_reconnecting;
 642 float visible_to_some_client(entity ent)
 643 {
 644         entity e;
 645         for(e = nextent(world); clienttype(e) != CLIENTTYPE_NOTACLIENT; e = nextent(e))
 646                 if(e.classname == "player" && clienttype(e) == CLIENTTYPE_REAL)
 647                         if(checkpvs(e.origin + e.view_ofs, ent))
 648                                 return 1;
 649         return 0;
 650 }
 651 void trigger_warpzone_reconnect_use()
 652 {
 653         entity e;
 654         e = self;
 655         // NOTE: this matches for target, not targetname, but of course
 656         // targetname must be set too on the other entities
 657         for(self = warpzone_first; self; self = self.warpzone_next)
 658                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && (visible_to_some_client(self) || visible_to_some_client(self.enemy))));
 659         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 660                 self.warpzone_reconnecting = ((e.target == "" || self.target == e.target) && !((e.spawnflags & 1) && visible_to_some_client(self)));
 661         for(self = warpzone_first; self; self = self.warpzone_next)
 662                 if(self.warpzone_reconnecting)
 663                         WarpZone_InitStep_ClearTarget();
 664         for(self = warpzone_first; self; self = self.warpzone_next)
 665                 if(self.warpzone_reconnecting)
 666                         WarpZone_InitStep_FindTarget();
 667         for(self = warpzone_camera_first; self; self = self.warpzone_next)
 668                 if(self.warpzone_reconnecting)
 669                         WarpZoneCamera_InitStep_FindTarget();
 670         for(self = warpzone_first; self; self = self.warpzone_next)
 671                 if(self.warpzone_reconnecting || self.enemy.warpzone_reconnecting)
 672                         WarpZone_InitStep_FinalizeTransform();
 673         self = e;
 674 }
 675
 676 void spawnfunc_trigger_warpzone_reconnect()
 677 {
 678         self.use = trigger_warpzone_reconnect_use;
 679 }
 680
 681 void spawnfunc_target_warpzone_reconnect()
 682 {
 683         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 684 }