qcsrc/warpzonelib/server.qc

   1 .vector warpzone_oldorigin, warpzone_oldvelocity, warpzone_oldangles;
   2 .float warpzone_teleport_time;
   3
   4 void WarpZone_StoreProjectileData(entity e)
   5 {
   6         e.warpzone_oldorigin = e.origin;
   7         e.warpzone_oldvelocity = e.velocity;
   8         e.warpzone_oldangles = e.angles;
   9 }
  10
  11 void WarpZone_TeleportPlayer(entity teleporter, entity player, vector to, vector to_angles, vector to_velocity)
  12 {
  13         vector from;
  14
  15         makevectors (to_angles);
  16
  17         from = player.origin;
  18         setorigin (player, to);
  19         player.oldorigin = to; // for DP's unsticking
  20         player.angles = to_angles;
  21         player.fixangle = TRUE;
  22         player.velocity = to_velocity;
  23
  24         if(player.effects & EF_TELEPORT_BIT)
  25                 player.effects &~= EF_TELEPORT_BIT;
  26         else
  27                 player.effects |= EF_TELEPORT_BIT;
  28
  29         if(player.classname == "player")
  30                 player.flags &~= FL_ONGROUND;
  31
  32         WarpZone_PostTeleportPlayer_Callback(player);
  33 }
  34
  35 float WarpZone_Teleport(entity player)
  36 {
  37         vector o0, a0, v0, o1, a1, v1;
  38
  39         o0 = player.origin + player.view_ofs;
  40         v0 = player.velocity;
  41         a0 = player.angles;
  42
  43         if(WarpZone_PlaneDist(self, o0) >= 0) // wrong side of the trigger_warpzone
  44                 return 2;
  45         // no failure, we simply don't want to teleport yet; TODO in
  46         // this situation we may want to create a temporary clone
  47         // entity of the player to fix graphics glitch
  48
  49         o1 = WarpZone_TransformOrigin(self, o0);
  50         v1 = WarpZone_TransformVelocity(self, v0);
  51         if(player.classname == "player")
  52                 a1 = WarpZone_TransformVAngles(self, player.v_angle);
  53         else
  54                 a1 = WarpZone_TransformAngles(self, a0);
  55
  56         // put him inside solid
  57         tracebox(o1 - player.view_ofs, player.mins, player.maxs, o1 - player.view_ofs, MOVE_NOMONSTERS, player);
  58         if(trace_startsolid)
  59         {
  60                 vector mi, ma;
  61                 mi = player.mins;
  62                 ma = player.maxs;
  63                 setsize(player, mi - player.view_ofs, ma - player.view_ofs);
  64                 setorigin(player, o1);
  65                 if(WarpZoneLib_MoveOutOfSolid(player))
  66                 {
  67                         o1 = player.origin;
  68                         setsize(player, mi, ma);
  69                         setorigin(player, o0);
  70                 }
  71                 else
  72                 {
  73                         print("would have to put player in solid, won't do that\n");
  74                         setsize(player, mi, ma);
  75                         setorigin(player, o0 - player.view_ofs);
  76                         return 0; // cannot fix
  77                 }
  78         }
  79
  80         if(WarpZone_TargetPlaneDist(self, o1) <= 0)
  81         {
  82                 print("inconsistent warp zones or evil roundoff error\n");
  83                 return 0;
  84         }
  85
  86         //print(sprintf("warpzone: %f %f %f -> %f %f %f\n", o0_x, o0_y, o0_z, o1_x, o1_y, o1_z));
  87
  88         //o1 = trace_endpos;
  89         WarpZone_RefSys_Add(player, self);
  90         WarpZone_TeleportPlayer(self, player, o1 - player.view_ofs, a1, v1);
  91         WarpZone_StoreProjectileData(player);
  92         player.warpzone_teleport_time = time;
  93
  94         return 1;
  95 }
  96
  97 void WarpZone_Touch (void)
  98 {
  99         entity oldself, e;
 100
 101         if(other.classname == "trigger_warpzone")
 102                 return;
 103
 104         // FIXME needs a better check to know what is safe to teleport and what not
 105         if(other.movetype == MOVETYPE_NONE)
 106                 return;
 107
 108         if(WarpZoneLib_ExactTrigger_Touch())
 109                 return;
 110
 111         e = self.enemy;
 112         if(WarpZone_Teleport(other))
 113         {
 114                 string save1, save2;
 115                 activator = other;
 116
 117                 save1 = self.target; self.target = string_null;
 118                 save2 = self.target3; self.target3 = string_null;
 119                 SUB_UseTargets();
 120                 if not(self.target) self.target = save1;
 121                 if not(self.target3) self.target3 = save2;
 122
 123                 oldself = self;
 124                 self = self.enemy;
 125                 save1 = self.target; self.target = string_null;
 126                 save2 = self.target2; self.target2 = string_null;
 127                 SUB_UseTargets();
 128                 if not(self.target) self.target = save1;
 129                 if not(self.target2) self.target2 = save2;
 130                 self = oldself;
 131         }
 132         else
 133         {
 134                 dprint("WARPZONE FAIL AHAHAHAHAH))\n");
 135         }
 136 }
 137
 138 float WarpZone_Send(entity to, float sendflags)
 139 {
 140         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE);
 141
 142         // we must send this flag for clientside to match properly too
 143         WriteByte(MSG_ENTITY, self.warpzone_isboxy);
 144
 145         // we need THESE to render the warpzone (and cull properly)...
 146         WriteCoord(MSG_ENTITY, self.origin_x);
 147         WriteCoord(MSG_ENTITY, self.origin_y);
 148         WriteCoord(MSG_ENTITY, self.origin_z);
 149
 150         WriteShort(MSG_ENTITY, self.modelindex);
 151         WriteCoord(MSG_ENTITY, self.mins_x);
 152         WriteCoord(MSG_ENTITY, self.mins_y);
 153         WriteCoord(MSG_ENTITY, self.mins_z);
 154         WriteCoord(MSG_ENTITY, self.maxs_x);
 155         WriteCoord(MSG_ENTITY, self.maxs_y);
 156         WriteCoord(MSG_ENTITY, self.maxs_z);
 157         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 158
 159         // we need THESE to calculate the proper transform
 160         WriteCoord(MSG_ENTITY, self.warpzone_origin_x);
 161         WriteCoord(MSG_ENTITY, self.warpzone_origin_y);
 162         WriteCoord(MSG_ENTITY, self.warpzone_origin_z);
 163         WriteCoord(MSG_ENTITY, self.warpzone_angles_x);
 164         WriteCoord(MSG_ENTITY, self.warpzone_angles_y);
 165         WriteCoord(MSG_ENTITY, self.warpzone_angles_z);
 166         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_x);
 167         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_y);
 168         WriteCoord(MSG_ENTITY, self.warpzone_targetorigin_z);
 169         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_x);
 170         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_y);
 171         WriteCoord(MSG_ENTITY, self.warpzone_targetangles_z);
 172
 173         return TRUE;
 174 }
 175
 176 float WarpZone_Camera_Send(entity to, float sendflags)
 177 {
 178         WriteByte(MSG_ENTITY, ENT_CLIENT_WARPZONE_CAMERA);
 179
 180         // we need THESE to render the warpzone (and cull properly)...
 181         WriteCoord(MSG_ENTITY, self.origin_x);
 182         WriteCoord(MSG_ENTITY, self.origin_y);
 183         WriteCoord(MSG_ENTITY, self.origin_z);
 184
 185         WriteShort(MSG_ENTITY, self.modelindex);
 186         WriteCoord(MSG_ENTITY, self.mins_x);
 187         WriteCoord(MSG_ENTITY, self.mins_y);
 188         WriteCoord(MSG_ENTITY, self.mins_z);
 189         WriteCoord(MSG_ENTITY, self.maxs_x);
 190         WriteCoord(MSG_ENTITY, self.maxs_y);
 191         WriteCoord(MSG_ENTITY, self.maxs_z);
 192         WriteByte(MSG_ENTITY, bound(1, self.scale * 16, 255));
 193
 194         // we need THESE to calculate the proper transform
 195         WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 196         WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 197         WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 198         WriteCoord(MSG_ENTITY, self.enemy.angles_x);
 199         WriteCoord(MSG_ENTITY, self.enemy.angles_y);
 200         WriteCoord(MSG_ENTITY, self.enemy.angles_z);
 201
 202         return TRUE;
 203 }
 204
 205 float WarpZone_CheckProjectileImpact()
 206 {
 207         // if self hit a warpzone, abort
 208         vector o0, v0, a0;
 209         float mpd, pd, dpd;
 210         entity wz;
 211         wz = WarpZone_Find(self.origin + self.mins, self.origin + self.maxs);
 212         if(!wz)
 213                 return FALSE;
 214         o0 = self.origin;
 215         v0 = self.velocity;
 216         a0 = self.angles;
 217
 218         // this approach transports the projectile at its full speed, but does
 219         // not properly retain the projectile trail (but we can't retain it
 220         // easily anyway without delaying the projectile by two frames, so who
 221         // cares)
 222         WarpZone_TraceBox_ThroughZone(self.warpzone_oldorigin, self.mins, self.maxs, self.warpzone_oldorigin + self.warpzone_oldvelocity * frametime, MOVE_NORMAL, self, wz, WarpZone_trace_callback_t_null); // this will get us through the warpzone
 223         setorigin(self, trace_endpos);
 224         self.angles = WarpZone_TransformAngles(WarpZone_trace_transform, self.angles);
 225         self.velocity = WarpZone_TransformVelocity(WarpZone_trace_transform, self.velocity);
 226
 227         // in case we are in our warp zone post-teleport, shift the projectile forward a bit
 228         mpd = max(vlen(self.mins), vlen(self.maxs));
 229         pd = WarpZone_TargetPlaneDist(wz, self.origin);
 230         if(pd < mpd)
 231         {
 232                 dpd = normalize(self.velocity) * self.warpzone_targetforward;
 233                 setorigin(self, self.origin + normalize(self.velocity) * ((mpd - pd) / dpd));
 234                 if(!WarpZoneLib_MoveOutOfSolid(self))
 235                 {
 236                         setorigin(self, o0);
 237                         self.angles = a0;
 238                         self.velocity = v0;
 239                         return FALSE;
 240                 }
 241         }
 242         WarpZone_RefSys_Add(self, wz);
 243         WarpZone_StoreProjectileData(self);
 244         self.warpzone_teleport_time = time;
 245
 246         return TRUE;
 247 }
 248 float WarpZone_Projectile_Touch()
 249 {
 250         if(other.classname == "trigger_warpzone")
 251                 return TRUE;
 252         if(WarpZone_Projectile_Touch_ImpactFilter_Callback())
 253                 return TRUE;
 254         if(WarpZone_CheckProjectileImpact())
 255                 return TRUE;
 256         if(self.warpzone_teleport_time == time) // already got teleported this frame? no collision then please
 257         {
 258                 setorigin(self, self.warpzone_oldorigin);
 259                 self.velocity = self.warpzone_oldvelocity;
 260                 self.angles = self.warpzone_oldangles;
 261                 return TRUE;
 262         }
 263
 264         return FALSE;
 265 }
 266
 267 void WarpZone_InitStep_FindOriginTarget()
 268 {
 269         if(self.killtarget != "")
 270         {
 271                 self.aiment = find(world, targetname, self.killtarget);
 272                 if(self.aiment == world)
 273                 {
 274                         error("Warp zone with nonexisting killtarget");
 275                         return;
 276                 }
 277                 self.killtarget = string_null;
 278         }
 279 }
 280
 281 void WarpZonePosition_InitStep_FindTarget()
 282 {
 283         if(self.target == "")
 284         {
 285                 error("Warp zone position with no target");
 286                 return;
 287         }
 288         self.enemy = find(world, targetname, self.target);
 289         if(self.enemy == world)
 290         {
 291                 error("Warp zone position with nonexisting target");
 292                 return;
 293         }
 294         if(self.enemy.aiment)
 295         {
 296                 // already is positioned
 297                 error("Warp zone position targeting already oriented warpzone");
 298                 return;
 299         }
 300         self.enemy.aiment = self;
 301 }
 302
 303 void WarpZoneCamera_InitStep_FindTarget()
 304 {
 305         if(self.target == "")
 306         {
 307                 error("Camera with no target");
 308                 return;
 309         }
 310         self.enemy = find(world, targetname, self.target);
 311         if(self.enemy == world)
 312         {
 313                 error("Camera with nonexisting target");
 314                 return;
 315         }
 316         ++warpzone_cameras_exist;
 317         WarpZone_Camera_SetUp(self, self.enemy.origin, self.enemy.angles);
 318 }
 319
 320 void WarpZone_InitStep_UpdateTransform()
 321 {
 322         vector org, ang, norm, point;
 323         float area;
 324         vector tri, a, b, c, p, q, n;
 325         float i_s, i_t, n_t;
 326         string tex;
 327
 328         org = self.origin;
 329         if(org == '0 0 0')
 330                 org = 0.5 * (self.mins + self.maxs);
 331
 332         norm = point = '0 0 0';
 333         area = 0;
 334         for(i_s = 0; ; ++i_s)
 335         {
 336                 tex = getsurfacetexture(self, i_s);
 337                 if not(tex)
 338                         break; // this is beyond the last one
 339                 if(tex == "textures/common/trigger")
 340                         continue;
 341                 n_t = getsurfacenumtriangles(self, i_s);
 342                 for(i_t = 0; i_t < n_t; ++i_t)
 343                 {
 344                         tri = getsurfacetriangle(self, i_s, i_t);
 345                         a = getsurfacepoint(self, i_s, tri_x);
 346                         b = getsurfacepoint(self, i_s, tri_y);
 347                         c = getsurfacepoint(self, i_s, tri_z);
 348                         p = b - a;
 349                         q = c - a;
 350                         n =     '1 0 0' * (q_y * p_z - q_z * p_y)
 351                         +       '0 1 0' * (q_z * p_x - q_x * p_z)
 352                         +       '0 0 1' * (q_x * p_y - q_y * p_x);
 353                         area = area + vlen(n);
 354                         norm = norm + n;
 355                         point = point + vlen(n) * (a + b + c);
 356                 }
 357         }
 358         if(area > 0)
 359         {
 360                 norm = norm * (1 / area);
 361                 point = point * (1 / (3 * area));
 362                 if(vlen(norm) < 0.99)
 363                 {
 364                         print("trigger_warpzone near ", vtos(self.aiment.origin), " is nonplanar. BEWARE.\n");
 365                         area = 0; // no autofixing in this case
 366                 }
 367                 norm = normalize(norm);
 368         }
 369
 370         if(self.aiment)
 371         {
 372                 org = self.aiment.origin;
 373                 ang = self.aiment.angles;
 374                 if(area > 0)
 375                 {
 376                         org = org - ((org - point) * norm) * norm; // project to plane
 377                         makevectors(ang);
 378                         if(norm * v_forward < 0)
 379                         {
 380                                 print("Position target of trigger_warpzone near ", vtos(self.aiment.origin), " points into trigger_warpzone. BEWARE.\n");
 381                                 norm = -1 * norm;
 382                         }
 383                         ang = vectoangles(norm, v_up); // keep rotation, but turn exactly against plane
 384                         ang_x = -ang_x;
 385                         if(norm * v_forward < 0.99)
 386                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been turned to match plane orientation (", vtos(self.aiment.angles), " -> ", vtos(ang), "\n");
 387                         if(vlen(org - self.aiment.origin) > 0.5)
 388                                 print("trigger_warpzone near ", vtos(self.aiment.origin), " has been moved to match the plane (", vtos(self.aiment.origin), " -> ", vtos(org), ").\n");
 389                 }
 390         }
 391         else if(area > 0)
 392         {
 393                 org = point;
 394                 ang = vectoangles(norm);
 395                 ang_x = -ang_x;
 396         }
 397         else
 398                 error("cannot infer origin/angles for this warpzone, please use a killtarget or a trigger_warpzone_position");
 399
 400         self.warpzone_origin = org;
 401         self.warpzone_angles = ang;
 402 }
 403
 404 void WarpZone_InitStep_ClearTarget()
 405 {
 406         if(self.enemy)
 407                 self.enemy.enemy = world;
 408         self.enemy = world;
 409 }
 410
 411 entity warpzone_first; .entity warpzone_next;
 412 void WarpZone_InitStep_FindTarget()
 413 {
 414         float i;
 415         entity e, e2;
 416
 417         if(self.enemy)
 418                 return;
 419
 420         // this way only one of the two ents needs to target
 421         if(self.target != "")
 422         {
 423                 self.enemy = self; // so the if(!e.enemy) check also skips self, saves one IF
 424
 425                 e2 = world;
 426                 for(e = world, i = 0; (e = find(e, targetname, self.target)); )
 427                         if(!e.enemy)
 428                                 if(e.classname == self.classname) // possibly non-warpzones may use the same targetname!
 429                                         if(random() * ++i < 1)
 430                                                 e2 = e;
 431                 if(!e2)
 432                 {
 433                         self.enemy = world;
 434                         error("Warpzone with non-existing target");
 435                         return;
 436                 }
 437                 self.enemy = e2;
 438                 e2.enemy = self;
 439         }
 440 }
 441
 442 void WarpZone_InitStep_FinalizeTransform()
 443 {
 444         if(!self.enemy || self.enemy.enemy != self)
 445         {
 446                 error("Invalid warp zone detected. Killed.");
 447                 return;
 448         }
 449
 450         ++warpzone_warpzones_exist;
 451         WarpZone_SetUp(self, self.warpzone_origin, self.warpzone_angles, self.enemy.warpzone_origin, self.enemy.warpzone_angles);
 452         self.touch = WarpZone_Touch;
 453         self.SendFlags = 0xFFFFFF;
 454 }
 455
 456 float warpzone_initialized;
 457 entity warpzone_first;
 458 entity warpzone_position_first;
 459 entity warpzone_camera_first;
 460 .entity warpzone_next;
 461 void spawnfunc_misc_warpzone_position(void)
 462 {
 463         // "target", "angles", "origin"
 464         self.warpzone_next = warpzone_position_first;
 465         warpzone_position_first = self;
 466 }
 467 void spawnfunc_trigger_warpzone_position(void)
 468 {
 469         spawnfunc_misc_warpzone_position();
 470 }
 471 void spawnfunc_trigger_warpzone(void)
 472 {
 473         // warp zone entities must have:
 474         // "killtarget" pointing to a target_position with a direction arrow
 475         //              that points AWAY from the warp zone, and that is inside
 476         //              the warp zone trigger
 477         // "target"     pointing to an identical warp zone at another place in
 478         //              the map, with another killtarget to designate its
 479         //              orientation
 480
 481         if(!self.scale)
 482                 self.scale = self.modelscale;
 483         if(!self.scale)
 484                 self.scale = 1;
 485         string m;
 486         m = self.model;
 487         WarpZoneLib_ExactTrigger_Init();
 488         if(m != "")
 489         {
 490                 precache_model(m);
 491                 setmodel(self, m); // no precision needed
 492         }
 493         setorigin(self, self.origin);
 494         if(self.scale)
 495                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 496         else
 497                 setsize(self, self.mins, self.maxs);
 498         self.SendEntity = WarpZone_Send;
 499         self.SendFlags = 0xFFFFFF;
 500         self.effects |= EF_NODEPTHTEST;
 501         self.warpzone_next = warpzone_first;
 502         warpzone_first = self;
 503 }
 504 void spawnfunc_func_camera(void)
 505 {
 506         if(!self.scale)
 507                 self.scale = self.modelscale;
 508         if(!self.scale)
 509                 self.scale = 1;
 510         if(self.model != "")
 511         {
 512                 precache_model(self.model);
 513                 setmodel(self, self.model); // no precision needed
 514         }
 515         setorigin(self, self.origin);
 516         if(self.scale)
 517                 setsize(self, self.mins * self.scale, self.maxs * self.scale);
 518         else
 519                 setsize(self, self.mins, self.maxs);
 520         if(!self.solid)
 521                 self.solid = SOLID_BSP;
 522         else if(self.solid < 0)
 523                 self.solid = SOLID_NOT;
 524         self.SendEntity = WarpZone_Camera_Send;
 525         self.SendFlags = 0xFFFFFF;
 526         self.warpzone_next = warpzone_camera_first;
 527         warpzone_camera_first = self;
 528 }
 529 void WarpZones_Reconnect()
 530 {
 531         entity e;
 532         e = self;
 533         for(self = warpzone_first; self; self = self.warpzone_next)
 534                 WarpZone_InitStep_ClearTarget();
 535         for(self = warpzone_first; self; self = self.warpzone_next)
 536                 WarpZone_InitStep_FindTarget();
 537         for(self = warpzone_first; self; self = self.warpzone_next)
 538                 WarpZone_InitStep_FinalizeTransform();
 539         self = e;
 540 }
 541
 542 void WarpZone_StartFrame()
 543 {
 544         entity e;
 545         if(warpzone_initialized == 0)
 546         {
 547                 warpzone_initialized = 1;
 548                 e = self;
 549                 for(self = warpzone_first; self; self = self.warpzone_next)
 550                         WarpZone_InitStep_FindOriginTarget();
 551                 for(self = warpzone_position_first; self; self = self.warpzone_next)
 552                         WarpZonePosition_InitStep_FindTarget();
 553                 for(self = warpzone_camera_first; self; self = self.warpzone_next)
 554                         WarpZoneCamera_InitStep_FindTarget();
 555                 for(self = warpzone_first; self; self = self.warpzone_next)
 556                         WarpZone_InitStep_UpdateTransform();
 557                 self = e;
 558                 WarpZones_Reconnect();
 559         }
 560         for(e = world; (e = nextent(e)); )
 561                 WarpZone_StoreProjectileData(e);
 562 }
 563
 564 void trigger_warpzone_reconnect_use()
 565 {
 566         entity e;
 567         e = self;
 568         // NOTE: this matches for target, not targetname, but of course
 569         // targetname must be set too on the other entities
 570         for(self = warpzone_first; self; self = self.warpzone_next)
 571                 if(e.target == "" || self.target == e.target)
 572                         WarpZone_InitStep_ClearTarget();
 573         for(self = warpzone_first; self; self = self.warpzone_next)
 574                 if(e.target == "" || self.target == e.target)
 575                         WarpZone_InitStep_FindTarget();
 576         for(self = warpzone_first; self; self = self.warpzone_next)
 577                 if(e.target == "" || self.target == e.target || self.enemy.target == e.target)
 578                         WarpZone_InitStep_FinalizeTransform();
 579         self = e;
 580 }
 581
 582 void spawnfunc_trigger_warpzone_reconnect()
 583 {
 584         self.use = trigger_warpzone_reconnect_use;
 585 }
 586
 587 void spawnfunc_target_warpzone_reconnect()
 588 {
 589         spawnfunc_trigger_warpzone_reconnect(); // both names make sense here :(
 590 }