#if defined(CSQC)
#elif defined(MENUQC)
#elif defined(SVQC)
    #include <common/state.qh>
    #include <common/vehicles/all.qh>
    #include "antilag.qh"
#endif

const int ANTILAG_MAX_ORIGINS = 64;
.vector antilag_origins[ANTILAG_MAX_ORIGINS];
.float antilag_times[ANTILAG_MAX_ORIGINS];
.int antilag_index;
.vector antilag_saved_origin;
.float antilag_takenback;

.float antilag_debug;

void antilag_record(entity e, float t)
{
    if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
        return;

    if(e.vehicle)
        antilag_record(e.vehicle, t);

	if(time < CS(e).antilag_times[CS(e).antilag_index])
		return;
	CS(e).antilag_index += 1;
	if(CS(e).antilag_index >= ANTILAG_MAX_ORIGINS)
		CS(e).antilag_index = 0;
	CS(e).antilag_times[CS(e).antilag_index] = t;
	CS(e).antilag_origins[CS(e).antilag_index] = e.origin;

	if(CS(e).antilag_debug)
		te_spark(antilag_takebackorigin(e, t - CS(e).antilag_debug), '0 0 0', 32);

}

// finds the index BEFORE t
float antilag_find(entity e, float t)
{
	for(int i = CS(e).antilag_index; i > 0; --i)
		if(CS(e).antilag_times[i] >= t)
			if(CS(e).antilag_times[i - 1] < t)
				return i - 1;

	if(CS(e).antilag_times[0] >= t)
		if(CS(e).antilag_times[ANTILAG_MAX_ORIGINS - 1] < t)
			return ANTILAG_MAX_ORIGINS - 1;

	for(int i = ANTILAG_MAX_ORIGINS - 1; i > CS(e).antilag_index + 1; --i)
		if(CS(e).antilag_times[i] >= t)
			if(CS(e).antilag_times[i - 1] < t)
				return i - 1;

	// if we get here, t is sandwiched nowhere, so let's assume it's in the present
	return -1;
}

vector antilag_takebackorigin(entity e, float t)
{
	int i0 = antilag_find(e, t);
	if (i0 < 0)
	{
		// IN THE PRESENT
		if(CS(e).antilag_takenback)
			return CS(e).antilag_saved_origin;
		else
			return e.origin;
	}
	int i1 = i0 + 1;
	if (i1 >= ANTILAG_MAX_ORIGINS)
		i1 = 0;

	return lerpv(CS(e).antilag_times[i0], CS(e).antilag_origins[i0], CS(e).antilag_times[i1], CS(e).antilag_origins[i1], t);
}

vector antilag_takebackavgvelocity(entity e, float t0, float t1)
{
	vector o0, o1;

	if(t0 >= t1)
		return '0 0 0';
	o0 = antilag_takebackorigin(e, t0);
	o1 = antilag_takebackorigin(e, t1);
	return (o1 - o0) * (1 / (t1 - t0));
}

void antilag_takeback(entity e, float t)
{

    if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
        return;

	if(e.vehicle)
		antilag_takeback(e.vehicle, t);

	if(!CS(e).antilag_takenback)
		CS(e).antilag_saved_origin = e.origin;

	vector org = antilag_takebackorigin(e, t);
	setorigin(e, org);
	CS(e).antilag_takenback = true;
}

void antilag_restore(entity e)
{
    if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
        return;

	if(e.vehicle)
		antilag_restore(e.vehicle);

	if(!CS(e).antilag_takenback)
		return;

	setorigin(e, CS(e).antilag_saved_origin);
	CS(e).antilag_takenback = false;
}

void antilag_clear(entity e)
{
	antilag_restore(e);
	for (int i = 0; i < ANTILAG_MAX_ORIGINS; ++i)
	{
		CS(e).antilag_times[i] = -2342;
		CS(e).antilag_origins[i] = e.origin;
	}
	CS(e).antilag_index = ANTILAG_MAX_ORIGINS - 1; // next one is 0
}