// =====================================================
//  Server side game commands code, reworked by Samual
//  Last updated: July 13th, 2011
// =====================================================

#define GC_REQUEST_HELP 1
#define GC_REQUEST_COMMAND 2
#define GC_REQUEST_USAGE 3

entity radarmapper;

float RADAR_WIDTH_MAX = 512;
float RADAR_HEIGHT_MAX = 512;
float sharpen_buffer[RADAR_WIDTH_MAX * 3];

string GotoMap(string m);
string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
// FF is contained twice, to map 256 to FF too
// removes the need to bound()

void race_deleteTime(string map, float pos);


// ============================
//  Misc. Supporting Functions
// ============================

// used by GameCommand_radarmap()
float FullTraceFraction(vector a, vector mi, vector ma, vector b)
{
	vector c;
	float white, black;

	white = 0.001;
	black = 0.001;

	c = a;

	float n, m;
	n = m = 0;

	while(vlen(c - b) > 1)
	{
		++m;

		tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
		++n;

		if(!trace_startsolid)
		{
			black += vlen(trace_endpos - c);
			c = trace_endpos;
		}

		n += tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);

		white += vlen(trace_endpos - c);
		c = trace_endpos;
	}

	if(n > 200)
		dprint("HOLY SHIT! FullTraceFraction: ", ftos(n), " total traces, ", ftos(m), " iterations\n");

	return white / (black + white);
}
float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
{
	vector a, b, mi, ma;

	mi = '0 0 0';
	ma = '1 0 0' * w + '0 1 0' * h;
	a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
	b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);

	return FullTraceFraction(a, mi, ma, b);
}
float RadarMapAtPoint_LineBlock(float x, float y, float w, float h, float zmin, float zsize, float q)
{
	vector o, mi, ma;
	float i, r;
	vector dz;

	q = 256 * q - 1;
	// 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value

	mi = '0 0 0';
	dz = (zsize / q) * '0 0 1';
	ma = '1 0 0' * w + '0 1 0' * h + dz;
	o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;

	if(x < world.absmin_x - w)
		return 0;
	if(y < world.absmin_y - h)
		return 0;
	if(x > world.absmax_x)
		return 0;
	if(y > world.absmax_y)
		return 0;

	r = 0;
	for(i = 0; i < q; ++i)
	{
		vector v1, v2;
		v1 = v2 = o + dz * i + mi;
		v1_x += random() * (ma_x - mi_x);
		v1_y += random() * (ma_y - mi_y);
		v1_z += random() * (ma_z - mi_z);
		v2_x += random() * (ma_x - mi_x);
		v2_y += random() * (ma_y - mi_y);
		v2_z += random() * (ma_z - mi_z);
		traceline(v1, v2, MOVE_WORLDONLY, world);
		if(trace_startsolid || trace_fraction < 1)
			++r;
	}
	return r / q;
}
float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
{
	vector o, mi, ma;
	float i, r;
	vector dz;

	q = 256 * q - 1;
	// 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value

	mi = '0 0 0';
	dz = (zsize / q) * '0 0 1';
	ma = '1 0 0' * w + '0 1 0' * h + dz;
	o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;

	if(x < world.absmin_x - w)
		return 0;
	if(y < world.absmin_y - h)
		return 0;
	if(x > world.absmax_x)
		return 0;
	if(y > world.absmax_y)
		return 0;

	r = 0;
	for(i = 0; i < q; ++i)
	{
		tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
		if(trace_startsolid)
			++r;
	}
	return r / q;
}
float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
{
	vector a, b, mi, ma;

	q *= 4; // choose q so it matches the regular algorithm in speed

	q = 256 * q - 1;
	// 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value

	mi = '0 0 0';
	ma = '1 0 0' * w + '0 1 0' * h;
	a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
	b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;

	float c, i;
	c = 0;

	for(i = 0; i < q; ++i)
	{
		vector v;
		v_x = a_x + random() * b_x;
		v_y = a_y + random() * b_y;
		v_z = a_z + random() * b_z;
		traceline(v, v, MOVE_WORLDONLY, world);
		if(trace_startsolid)
			++c;
	}

	return c / q;
}
void sharpen_set(float x, float v)
{
	sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
}
float sharpen_getpixel(float x, float y)
{
	if(x < 0)
		return 0;
	if(x >= RADAR_WIDTH_MAX)
		return 0;
	if(y < 0)
		return 0;
	if(y > 2)
		return 0;
	return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
}
float sharpen_get(float x, float a)
{
	float sum;
	sum = sharpen_getpixel(x, 1);
	if(a == 0)
		return sum;
	sum *= (8 + 1/a);
	sum -= sharpen_getpixel(x - 1, 0);
	sum -= sharpen_getpixel(x - 1, 1);
	sum -= sharpen_getpixel(x - 1, 2);
	sum -= sharpen_getpixel(x + 1, 0);
	sum -= sharpen_getpixel(x + 1, 1);
	sum -= sharpen_getpixel(x + 1, 2);
	sum -= sharpen_getpixel(x, 0);
	sum -= sharpen_getpixel(x, 2);
	return bound(0, sum * a, 1);
}
void sharpen_shift(float w)
{
	float i;
	for(i = 0; i < w; ++i)
	{
		sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
		sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
		sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
	}
}
void sharpen_init(float w)
{
	float i;
	for(i = 0; i < w; ++i)
	{
		sharpen_buffer[i] = 0;
		sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
		sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
	}
}
void RadarMap_Next()
{
	if(radarmapper.count & 4)
	{
		localcmd("quit\n");
	}
	else if(radarmapper.count & 2)
	{
		localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
		GotoNextMap();
	}
	remove(radarmapper);
	radarmapper = world;
}
void RadarMap_Think()
{
	// rough map entity
	//   cnt: current line
	//   size: pixel width/height
	//   maxs: cell width/height
	//   frame: counter
	
	float i, x, l;
	string si;

	if(self.frame == 0)
	{
		// initialize
		get_mi_min_max_texcoords(1);
		self.mins = mi_picmin;
		self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
		self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
		self.maxs_z = mi_max_z - mi_min_z;
		print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
		self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
		if(!(self.count & 1))
		{
			self.cnt = fopen(self.netname, FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.tga"), FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.png"), FILE_READ);
			if(self.cnt < 0)
				self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.jpg"), FILE_READ);
			if(self.cnt >= 0)
			{
				fclose(self.cnt);

				print(self.netname, " already exists, aborting (you may want to specify --force)\n");
				RadarMap_Next();
				return;
			}
		}
		self.cnt = fopen(self.netname, FILE_WRITE);
		if(self.cnt < 0)
		{
			print("Error writing ", self.netname, "\n");
			remove(self);
			radarmapper = world;
			return;
		}
		print("Writing to ", self.netname, "...\n");
		fputs(self.cnt, "/* XPM */\n");
		fputs(self.cnt, "static char *RadarMap[] = {\n");
		fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
		fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
		for(i = 0; i < 256; ++i)
		{
			si = substring(doublehex, i*2, 2);
			fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
		}
		self.frame += 1;
		self.nextthink = time;
		sharpen_init(self.size_x);
	}
	else if(self.frame <= self.size_y)
	{
		// fill the sharpen buffer with this line
		sharpen_shift(self.size_x);
		i = self.count & 24;

		switch(i)
		{
			case 0:
			default:
				for(x = 0; x < self.size_x; ++x)
				{
					l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
					sharpen_set(x, l);
				}
				break;
			case 8:
				for(x = 0; x < self.size_x; ++x)
				{
					l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
					sharpen_set(x, l);
				}
				break;
			case 16:
				for(x = 0; x < self.size_x; ++x)
				{
					l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
					sharpen_set(x, l);
				}
				break;
			case 24:
				for(x = 0; x < self.size_x; ++x)
				{
					l = RadarMapAtPoint_LineBlock(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
					sharpen_set(x, l);
				}
				break;
		}

		// do we have enough lines?
		if(self.frame >= 2)
		{
			// write a pixel line
			fputs(self.cnt, "\"");
			for(x = 0; x < self.size_x; ++x)
			{
				l = sharpen_get(x, self.ltime);
				fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
			}
			if(self.frame == self.size_y)
				fputs(self.cnt, "\"\n");
			else
			{
				fputs(self.cnt, "\",\n");
				print(ftos(self.size_y - self.frame), " lines left\n");
			}
		}

		// is this the last line? then write back the missing line
		if(self.frame == self.size_y)
		{
			sharpen_shift(self.size_x);
			// write a pixel line
			fputs(self.cnt, "\"");
			for(x = 0; x < self.size_x; ++x)
			{
				l = sharpen_get(x, self.ltime);
				fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
			}
			if(self.frame == self.size_y)
				fputs(self.cnt, "\"\n");
			else
			{
				fputs(self.cnt, "\",\n");
				print(ftos(self.size_y - self.frame), " lines left\n");
			}
		}

		self.frame += 1;
		self.nextthink = time;
	}
	else
	{
		// close the file
		fputs(self.cnt, "};\n");
		fclose(self.cnt);
		print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
		RadarMap_Next();
	}
}

//  used by GameCommand_make_mapinfo()
void make_mapinfo_Think()
{
	if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
	{
		print("Done rebuiling mapinfos.\n");
		MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
		remove(self);
	}
	else
	{
		self.think = make_mapinfo_Think;
		self.nextthink = time;
	}
}

//  used by GameCommand_extendmatchtime() and GameCommand_reducematchtime()
void changematchtime(float delta, float mi, float ma)
{
	float cur;
	float new;
	float lim;

	if(delta == 0)
		return;
	if(autocvar_timelimit < 0)
		return;

	if(mi <= 10)
		mi = 10; // at least ten sec in the future
	cur = time - game_starttime;
	if(cur > 0)
		mi += cur; // from current time!

	lim = autocvar_timelimit * 60;

	if(delta > 0)
	{
		if(lim == 0)
			return; // cannot increase any further
		else if(lim < ma)
			new = min(ma, lim + delta);
		else // already above maximum: FAIL
			return;
	}
	else
	{
		if(lim == 0) // infinite: try reducing to max, if we are allowed to
			new = max(mi, ma);
		else if(lim > mi) // above minimum: decrease
			new = max(mi, lim + delta);
		else // already below minimum: FAIL
			return;
	}

	cvar_set("timelimit", ftos(new / 60));
}

//  used by GameCommand_modelbug() // TODO: is this even needed?
float g_clientmodel_genericsendentity (entity to, float sf);
void modelbug_make_svqc();
void modelbug_make_csqc()
{
	Net_LinkEntity(self, TRUE, 0, g_clientmodel_genericsendentity);
	self.think = modelbug_make_svqc;
	self.nextthink = time + 1;
	setorigin(self, self.origin - '0 0 8');
}
void modelbug_make_svqc()
{
	self.SendEntity = func_null;
	self.think = modelbug_make_csqc;
	self.nextthink = time + 1;
	setorigin(self, self.origin + '0 0 8');
}
void modelbug()
{
	entity e;
	e = spawn();
	setorigin(e, nextent(world).origin);
	precache_model("models_portal.md3");
	setmodel(e, "models/portal.md3");
	e.think = modelbug_make_svqc;
	e.nextthink = time + 1;
}


// =======================
//  Command Sub-Functions
// =======================

void GameCommand_adminmsg(float request, float argc)
{
	entity client;
	float entno = stof(argv(1)); 
	float n, i;
	string s;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2adminmsg^7: Send an admin message to a client directly\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc >= 3 && argc <= 4) {
				if((entno < 0) | (entno > maxclients)) {
					print("Player ", argv(1), " doesn't exist\n");
					return;
				}
				n = 0;
				for(i = (entno ? entno : 1); i <= (entno ? entno : maxclients); ++i)
				{
					client = edict_num(i);
					if(client.flags & FL_CLIENT)
					{
						if(argc == 4)
						{
							// make the string console safe
							s = argv(2);
							s = strreplace("\n", "", s);
							s = strreplace("\\", "\\\\", s);
							s = strreplace("$", "$$", s);
							s = strreplace("\"", "\\\"", s);
							stuffcmd(client, sprintf("\ninfobar %f \"%s\"\n", stof(argv(3)), s));
						}
						else
						{
							centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3", admin_name(), ":\n\n^7", argv(2)));
							sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: ", argv(2), "\n"));
						}
						dprint("Message sent to ", client.netname, "\n");
						++n;
					}
				}
				if(!n) { print(strcat("Client (", argv(1) ,") not found.\n")); } 
				return;
			} 
			
		default:
			print("Incorrect parameters for ^2adminmsg^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd adminmsg clientnumber \"message\" [infobartime]\n");
			print("  If infobartime is provided, the message will be sent to infobar.\n");
			print("  Otherwise, it will just be sent as a centerprint message.\n");
			print("Examples: adminmsg 4 \"this infomessage will last for ten seconds\" 10\n");
			print("          adminmsg 2 \"this message will be a centerprint\"\n");
			return;
	}
}

void GameCommand_allready(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2allready^7: Restart the server and reset the players\n");
			return;
			
		case GC_REQUEST_COMMAND:
			ReadyRestart();
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd allready\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_allspec(float request, float argc)
{
	entity client;
	float i;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2allspec^7: Force all players to spectate\n");
			return;
			
		case GC_REQUEST_COMMAND:
			FOR_EACH_PLAYER(client)
			{
				self = client;
				PutObserverInServer();
				++i;
			}
			if(i) { bprint(strcat("Successfully forced all (", ftos(i), ") players to spectate", (argv(1) ? strcat(" for reason: '", argv(1), "'") : ""), ".\n")); }
			else { print("No players found to spectate.\n"); }
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd allspec [reason]\n");
			print("  Where 'reason' is an optional argument for explanation of allspec command.\n");
			print("See also: ^2moveplayer^7\n");
			return;
	}
}

void GameCommand_anticheat(float request, float argc) // FIXME: player entity is never found
{
	entity client;
	float entno = stof(argv(1)); 
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2anticheat^7: Create an anticheat report for a client\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if((entno < 1) | (entno > maxclients)) {
				print("Player ", argv(1), " doesn't exist\n");
				return;
			}
			client = edict_num(entno);
			if(clienttype(client) != CLIENTTYPE_REAL && clienttype(client) != CLIENTTYPE_BOT) {
				print("Player ", client.netname, " is not active\n");
				return;
			}
			self = client;
			anticheat_report();
			return;
			
		default:
			print("Incorrect parameters for ^2anticheat^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd anticheat clientnumber\n");
			print("  where clientnumber is player entity number.\n");
			return;
	}
}

void GameCommand_bbox(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2bbox^7: Print detailed information about world size\n");
			return;
			
		case GC_REQUEST_COMMAND:
			print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
			print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
			print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
			print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
			print("Solid bounding box size:");

			tracebox('1 0 0' * world.absmin_x,
							'0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
							'0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
							'1 0 0' * world.absmax_x,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmin_x));
			else
				print(" ", ftos(trace_endpos_x));

			tracebox('0 1 0' * world.absmin_y,
							'1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
							'1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
							'0 1 0' * world.absmax_y,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmin_y));
			else
				print(" ", ftos(trace_endpos_y));

			tracebox('0 0 1' * world.absmin_z,
							'1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
							'1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
							'0 0 1' * world.absmax_z,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmin_z));
			else
				print(" ", ftos(trace_endpos_z));

			tracebox('1 0 0' * world.absmax_x,
							'0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
							'0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
							'1 0 0' * world.absmin_x,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmax_x));
			else
				print(" ", ftos(trace_endpos_x));

			tracebox('0 1 0' * world.absmax_y,
							'1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
							'1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
							'0 1 0' * world.absmin_y,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmax_y));
			else
				print(" ", ftos(trace_endpos_y));

			tracebox('0 0 1' * world.absmax_z,
							'1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
							'1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
							'0 0 1' * world.absmin_z,
					MOVE_WORLDONLY,
					world);
			if(trace_startsolid)
				print(" ", ftos(world.absmax_z));
			else
				print(" ", ftos(trace_endpos_z));
				
			print("\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd bbox\n");
			print("  No arguments required.\n");
			print("See also: ^2gettaginfo^7\n");
			return;
	}
}

void GameCommand_bot_cmd(float request, float argc) // what a mess... old old code.
{
	entity bot;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2bot_cmd^7: Control and send commands to bots\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argv(1) == "reset")
			{
				bot_resetqueues();
				return;
			}
			else if(argv(1) == "load" && argc == 3)
			{
				float fh, i;
				string s;
				fh = fopen(argv(2), FILE_READ);
				if(fh < 0)
				{
					print("cannot open the file\n");
					return;
				}

				i = 0;
				while((s = fgets(fh)))
				{
					argc = tokenize_console(s);

					if(argc >= 3 && argv(0) == "sv_cmd" && argv(1) == "bot_cmd")
					{
						// let's start at token 2 so we can skip sv_cmd bot_cmd
						bot = find_bot_by_number(stof(argv(2)));
						if(bot == world)
							bot = find_bot_by_name(argv(2));
						if(bot)
							bot_queuecommand(bot, strcat(argv(3), " ", argv(4)));
					}
					else
						localcmd(strcat(s, "\n"));

					++i;
				}
				print(ftos(i), " commands read\n");
				fclose(fh);
				return;
			}
			else if(argv(1) == "help")
			{
				if(argv(2))
					bot_cmdhelp(argv(2));
				else
					bot_list_commands();
				return;
			}
			else if(argc >= 3) // this comes last
			{
				bot = find_bot_by_number(stof(argv(1)));
				if(bot == world)
					bot = find_bot_by_name(argv(1));
				if(bot)
				{
					print(strcat("Command '", (argv(2), " ", argv(3)), "' sent to bot ", bot.netname, "\n"));
					bot_queuecommand(bot, strcat(argv(2), " ", argv(3)));
					return;
				}
				else
					print(strcat("Error: Can't find bot with the name or id '", argv(1),"' - Did you mistype the command?\n")); // don't return so that usage is shown
			}
			
		default:
			print("Incorrect parameters for ^2bot_cmd^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd bot_cmd client command [argument]\n");
			print("  'client' can be either the name or entity id of the bot\n");
			print("  For full list of commands, see bot_cmd help [command].\n");
			print("Examples: bot_cmd <id> cc \"say something\"\n");
			print("          bot_cmd <id> presskey jump\n");
			return;
	}
}

void GameCommand_cointoss(float request, float argc)
{
	entity client;
	string result1 = (argv(2) ? strcat("^7", argv(1), "^3!\n") : "^1HEADS^3!\n");
	string result2 = (argv(2) ? strcat("^7", argv(2), "^3!\n") : "^4TAILS^3!\n");
	string choice = ((random() > 0.5) ? result1 : result2);
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2cointoss^7: Flip a virtual coin and give random result\n");
			return;
			
		case GC_REQUEST_COMMAND:
			FOR_EACH_CLIENT(client)
				centerprint(client, strcat("^3Throwing coin... Result: ", choice));
			bprint(strcat("^3Throwing coin... Result: ", choice));
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd cointoss [result1 result2]\n");
			print("  Where 'result1' and 'result2' are user created options.\n");
			return;
	}
}

void GameCommand_cvar_changes(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2cvar_changes^7: Prints a list of all changed server cvars\n");
			return;
			
		case GC_REQUEST_COMMAND:
			print(cvar_changes);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd \n");
			print("  No arguments required.\n");
			print("See also: ^2cvar_purechanges^7\n");
			return;
	}
}

void GameCommand_cvar_purechanges(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2cvar_purechanges^7: Prints a list of all changed gameplay cvars\n");
			return;
			
		case GC_REQUEST_COMMAND:
			print(cvar_purechanges);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd cvar_purechanges\n");
			print("  No arguments required.\n");
			print("See also: ^2cvar_changes^7\n");
			return;
	}
}

void GameCommand_database(float request, float argc)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2database^7: Extra controls of the serverprogs database\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc == 3)
			{
				if(argv(1) == "save")
				{
					db_save(ServerProgsDB, argv(2));
					print(strcat("Copied serverprogs database to '", argv(2), "' in the data directory.\n"));
					return;
				}
				else if(argv(1) == "dump")
				{
					db_dump(ServerProgsDB, argv(2));
					print("DB dumped.\n"); // wtf does this do?
					return;
				}
				else if(argv(1) == "load")
				{
					db_close(ServerProgsDB);
					ServerProgsDB = db_load(argv(2));
					print(strcat("Loaded '", argv(2), "' as new serverprogs database.\n"));
					return;
				}
			}
			
		default:
			print("Incorrect parameters for ^2database^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd database action filename\n");
			print("  Where 'action' is the command to complete,\n");
			print("  and 'filename' is what it acts upon.\n");
			print("  Full list of commands here: \"save, dump, load.\"\n");
			return;
	}
}

void GameCommand_defer_clear(float request, float argc)
{
	entity client;
	float entno = stof(argv(1));
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2defer_clear^7: Clear all queued defer commands for client\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc == 2)
			{
				// player_id is out of range
				if((entno < 1) | (entno > maxclients)) {
					print("Player ", argv(1), " doesn't exist\n");
					return;
				}
				client = edict_num(entno);
				if not(client.flags & FL_CLIENT) {
					print("Player ", argv(1), " doesn't exist\n");
					return;
				}
				if(clienttype(client) == CLIENTTYPE_BOT) {
					print("Player ", argv(1), " (", client.netname, ") is a bot\n");
					return;
				}
				stuffcmd(client, "defer clear\n");
				print("defer clear stuffed to ", argv(1), " (", client.netname, ")\n");
				return;
			}
		
		default:
			print("Incorrect parameters for ^2defer_clear^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd defer_clear clientnumber\n");
			print("  where 'clientnumber' is player entity number.\n");
			print("See also: ^2defer_clear_all^7\n");
			return;
	}
}

void GameCommand_defer_clear_all(float request)
{
	entity client;
	float i;
	float argc;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2defer_clear_all^7: Clear all queued defer commands for all clients\n");
			return;
			
		case GC_REQUEST_COMMAND:
			FOR_EACH_CLIENT(client)
			{
				argc = tokenize_console(strcat("defer_clear ", ftos(num_for_edict(client))));
				GameCommand_defer_clear(GC_REQUEST_COMMAND, argc);	
				++i;
			}
			if(i) { bprint(strcat("Successfully stuffed defer clear to all clients (", ftos(i), ")\n")); } // should a message be added if no players were found? 
			return;
		
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd defer_clear_all\n");
			print("  No arguments required.\n");
			print("See also: ^2defer_clear^7\n");
			return;
	}
}

void GameCommand_delrec(float request, float argc) // UNTESTED // perhaps merge later with records and printstats and such?
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2delrec^7: Delete race time record for a map\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argv(1))
			{
				if(argv(2))
					race_deleteTime(argv(2), stof(argv(1)));
				else
					race_deleteTime(GetMapname(), stof(argv(1)));
				return;
			}
			
		default:
			print("Incorrect parameters for ^2delrec^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd delrec ranking [map]\n");
			print("  'ranking' is which ranking level to clear up to, \n");
			print("  it will clear all records up to nth place.\n");
			print("  if 'map' is not provided it will use current map.\n");
			return;
	}
}

void GameCommand_effectindexdump(float request)
{
	float fh, d;
	string s;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2effectindexdump^7: Dump list of effects from code and effectinfo.txt\n");
			return;
			
		case GC_REQUEST_COMMAND:
			d = db_create();
			print("begin of effects list\n");
			db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
			db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
			db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
			db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
			db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
			db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
			db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
			db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
			db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
			db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
			db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
			db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
			db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
			db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
			db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
			db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
			db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
			db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
			db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
			db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
			db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
			db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
			db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
			db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
			db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
			db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
			db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
			db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
			db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
			db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
			db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
			db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
			db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
			db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
			db_put(d, "TR_SEEKER", "1"); print("effect TR_SEEKER is ", ftos(particleeffectnum("TR_SEEKER")), "\n");
			db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");

			fh = fopen("effectinfo.txt", FILE_READ);
			while((s = fgets(fh)))
			{
				tokenize(s); // tokenize_console would hit the loop counter :(
				if(argv(0) == "effect")
				{
					if(db_get(d, argv(1)) != "1")
					{
						if(particleeffectnum(argv(1)) >= 0)
							print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
						db_put(d, argv(1), "1");
					}
				}
			}
			print("end of effects list\n");

			db_close(d);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd effectindexdump\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_extendmatchtime(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2extendmatchtime^7: Increase the timelimit value incrementally\n");
			return;
			
		case GC_REQUEST_COMMAND:
			changematchtime(autocvar_timelimit_increment* 60, autocvar_timelimit_min*60, autocvar_timelimit_max*60);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd extendmatchtime\n");
			print("  No arguments required.\n");
			print("See also: ^2reducematchtime^7\n");
			return;
	}
}

void GameCommand_find(float request, float argc)
{
	entity client;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2find^7: Search through entities for matching classname\n");
			return;
			
		case GC_REQUEST_COMMAND:
			for(client = world; (client = find(client, classname, argv(1))); )
				print(etos(client), "\n");
			return;
			
		default:
			print("Incorrect parameters for ^2find^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd find classname\n");
			print("  Where 'classname' is the classname to search for.\n");
			return;
	}
}

void GameCommand_gametype(float request, float argc)
{
	string s = argv(1);
	float t = MapInfo_Type_FromString(s), tsave = MapInfo_CurrentGametype();
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2gametype^7: Simple command to change the active gametype\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(t)
			{
				MapInfo_SwitchGameType(t);
				MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
				if(MapInfo_count > 0)
					bprint("Game type successfully switched to ", s, "\n");
				else
				{
					bprint("Cannot use this game type: no map for it found\n");
					MapInfo_SwitchGameType(tsave);
					MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
				}
			}
			else
				bprint("Game type switch to ", s, " failed: this type does not exist!\n");
			return;
			
		default:
			print("Incorrect parameters for ^2gametype^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd gametype mode\n");
			print("  Where 'mode' is the gametype mode to switch to.\n");
			print("See also: ^2gotomap^7\n");
			return;
	}
}

void GameCommand_gettaginfo(float request, float argc) // UNTESTED // todo: finish usage description for it (but, must first learn this shit)
{
	entity tmp_entity;
	float i;
	vector v;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2gettaginfo^7: Get specific information about a weapon model\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc >= 4)
			{
				tmp_entity = spawn();
				if(argv(1) == "w")
					setmodel(tmp_entity, (nextent(world)).weaponentity.model);
				else
				{
					precache_model(argv(1));
					setmodel(tmp_entity, argv(1));
				}
				tmp_entity.frame = stof(argv(2));
				if(substring(argv(3), 0, 1) == "#")
					i = stof(substring(argv(3), 1, -1));
				else
					i = gettagindex(tmp_entity, argv(3));
				if(i)
				{
					v = gettaginfo(tmp_entity, i);
					print("model ", tmp_entity.model, " frame ", ftos(tmp_entity.frame), " tag ", gettaginfo_name);
					print(" index ", ftos(i), " parent ", ftos(gettaginfo_parent), "\n");
					print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
					print(" offset = ", ftos(gettaginfo_offset_x), " ", ftos(gettaginfo_offset_y), " ", ftos(gettaginfo_offset_z), "\n");
					print(" forward = ", ftos(gettaginfo_forward_x), " ", ftos(gettaginfo_forward_y), " ", ftos(gettaginfo_forward_z), "\n");
					print(" right = ", ftos(gettaginfo_right_x), " ", ftos(gettaginfo_right_y), " ", ftos(gettaginfo_right_z), "\n");
					print(" up = ", ftos(gettaginfo_up_x), " ", ftos(gettaginfo_up_y), " ", ftos(gettaginfo_up_z), "\n");
					if(argc >= 6)
					{
						v_y = -v_y;
						localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
					}
				}
				else
					print("bone not found\n");
					
				remove(tmp_entity);
				return;
			}
			
		default:
			print("Incorrect parameters for ^2gettaginfo^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd gettaginfo\n");
			print("  FIXME: Arguments currently unknown\n");
			print("See also: ^2bbox^7\n");
			return;
	}
}

void GameCommand_gotomap(float request, float argc)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2gotomap^7: Simple command to switch to another map\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc == 2)
			{
				print(GotoMap(argv(1)), "\n");
				return;
			}
			
		default:
			print("Incorrect parameters for ^2gotomap^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd gotomap map\n");
			print("  Where 'map' is the *.bsp file to change to.\n");
			print("See also: ^2gametype^7\n");
			return;
	}
}

void GameCommand_ladder(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2ladder^7: Get information about top players if supported\n");
			return;
			
		case GC_REQUEST_COMMAND:
			print(ladder_reply);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd ladder\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_lockteams(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2lockteams^7: Disable the ability for players to switch or enter teams\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(teamplay)
			{
				lockteams = 1;
				bprint("^1The teams are now locked.\n");
			}
			else
				bprint("That command can only be used in a team-based gamemode.\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd lockteams\n");
			print("  No arguments required.\n");
			print("See also: ^2unlockteams^7\n");
			return;
	}
}

void GameCommand_make_mapinfo(float request) // UNTESTED
{
	entity tmp_entity;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2make_mapinfo^7: Automatically rebuild mapinfo files\n");
			return;
			
		case GC_REQUEST_COMMAND: 
			tmp_entity = spawn();
			tmp_entity.classname = "make_mapinfo";
			tmp_entity.think = make_mapinfo_Think;
			tmp_entity.nextthink = time; // this sucks... todo: re-write this -- Use initializeentity later
			MapInfo_Enumerate();
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd make_mapinfo\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_modelbug(float request) // UNTESTED // is this even needed anymore? 
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2modelbug^7: foobar\n");
			return;
			
		case GC_REQUEST_COMMAND:
			modelbug();
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd modelbug\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_moveplayer(float request, float argc)
{
	entity client;
	string targets = argv(1);
	string destination = argv(2);
	string notify = argv(3);
	float i;
	argc = tokenizebyseparator(targets, ","); // re-use argc for the targets
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2moveplayer^7: Change the team/status of a player\n");
			return;
			
		case GC_REQUEST_COMMAND:
			// lets see if the target(s) even actually exist.
			if((targets) && (destination))
			{ 
				for(i = 0; i < argc; ++i)
				{
					// Check to see if the player is a valid target
					if((stof(argv(i)) < 1) | (stof(argv(i)) > maxclients)) // player_id is out of range
					{
						print(strcat("Player ", argv(i), " doesn't exist", (((i + 1) < argc) ? ", skipping to next player.\n" : ".\n")));
						continue; 
					}
					client = edict_num(stof(argv(i)));
					if not(client.flags & FL_CLIENT) // player entity is not a client
					{
						print(strcat("Player ", argv(i), " doesn't exist", (((i + 1) < argc) ? ", skipping to next player.\n" : ".\n")));
						continue;
					}
					
					// Where are we putting this player?
					if(destination == "spec" || destination == "spectator") 
					{
						if(client.classname != "spectator" && client.classname != "observer")
						{
							self = client;
							PutObserverInServer();
						}
						else
						{
							print("Player ", argv(i), " (", client.netname, ") is already spectating.\n");
						}
						return;
					}
					else
					{
						if(client.classname != "spectator" && client.classname != "observer")
						{
							if(teamplay)
							{
								// set up
								float team_color;
								float save = client.team_forced;
								client.team_forced = 0;

								// find the team to move the player to
								team_color = ColourToNumber(destination);
								if(team_color == client.team) // already on the destination team
								{
									// keep the forcing undone
									print("Player ", argv(i), " (", client.netname, ") is already on the ", ColoredTeamName(client.team), ".\n");
									return;
								} 
								else if(team_color == 0)  // auto team
								{
									team_color = NumberToTeamNumber(FindSmallestTeam(client, FALSE));
								}
								else
								{
									CheckAllowedTeams(client);
								}
								client.team_forced = save;
								
								// Check to see if the destination team is even available
								switch(team_color) 
								{
									case COLOR_TEAM1:
										if(c1 == -1) {
											print("Sorry, can't move player to red team if it doesn't exist.\n");
											return;
										}
										break;

									case COLOR_TEAM2:
										if(c2 == -1) {
											print("Sorry, can't move player to blue team if it doesn't exist.\n");
											return;
										}
										break;

									case COLOR_TEAM3:
										if(c3 == -1) {
											print("Sorry, can't move player to yellow team if it doesn't exist.\n");
											return;
										}
										break;

									case COLOR_TEAM4:
										if(c4 == -1) {
											print("Sorry, can't move player to pink team if it doesn't exist.\n");
											return;
										}
										break;

									default:
										print("Sorry, can't move player here if team ", destination, " doesn't exist.\n");
										return;
								}
								
								// If so, lets continue and finally move the player
								client.team_forced = 0;
								MoveToTeam(client, team_color, 6, stof(notify));
								print("Player ", argv(i), " (", client.netname, ") has been moved to the ", ColoredTeamName(team_color), ".\n");
								return;
							}
							else
							{
								print("Can't change teams when currently not playing a team game.\n");
								return;
							}
						}
						else
						{
							print("Can't change teams if the player isn't in the game.\n"); // well technically we could, but should we allow that? :P 
							return;
						}
					}
				}
				print("No acceptable players given, aborting.\n");
				return; // still correct parameters so return to avoid usage print
			}
			
		default:
			print("Incorrect parameters for ^2moveplayer^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd moveplayer clientnumbers destination [notify]\n");
			print("  'clientnumbers' is a list (separated by commas) of player entity ID's\n");
			print("  'destination' is what to send the player to, be it team or spectating\n");
			print("  Full list of destinations here: \"spec, spectator, red, blue, yellow, pink, auto.\"\n");
			print("  'notify' is whether or not to send messages notifying of the move. Detail below.\n");
			print("    0 (00) automove centerprint, admin message; 1 (01) automove centerprint, no admin message\n");
			print("    2 (10) no centerprint, admin message; 3 (11) no centerprint, no admin message\n");
			print("Examples: moveplayer 1,3,5 red 3\n");
			print("          moveplayer 2 spec \n");
			print("See also: ^2allspec^7\n");
			return;
	}
}

void GameCommand_nospectators(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2nospectators^7: Automatically remove spectators from a match\n");
			return;
			
		case GC_REQUEST_COMMAND:
			blockSpectators = 1;
			entity plr;
			FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
			{
				if(plr.classname == "spectator" || plr.classname == "observer")
				{
					plr.spectatortime = time;
					sprint(plr, strcat("^7You have to become a player within the next ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
				}
			}
			bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(autocvar_g_maxplayers_spectator_blocktime), " seconds!\n"));
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd nospectators\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_onslaught_updatelinks(float request) // UNTESTED // should this be here? Perhaps some mutatorhook call instead....
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2onslaught_updatelinks^7: Refresh link status for onslaught\n");
			return;
			
		case GC_REQUEST_COMMAND:
			onslaught_updatelinks();
			print("ONS links updated\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd onslaught_updatelinks\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_playerdemo(float request, float argc) // UNTESTED // TODO: change the if statements for sub arguments to switches
{
	entity client;
	float i, n, entno;
	string s;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2playerdemo^7: Control the ability to save demos of players\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argv(1) == "read")
			{
				// TODO: Create a general command for looking this up, save a lot of space everywhere in this file
				entno = stof(argv(2));
				if((entno < 1) | (entno > maxclients)) {
					print("Player ", argv(2), " doesn't exist\n");
					return;
				}
				client = edict_num(entno);
				if(clienttype(client) != CLIENTTYPE_BOT) {
					print("Player ", client.netname, " is not a bot\n");
					return;
				}
				self = client;
				playerdemo_open_read(argv(3));
				return;
			}
			else if(argv(1) == "write")
			{
				entno = stof(argv(2));
				if((entno < 1) | (entno > maxclients)) {
					print("Player ", argv(2), " doesn't exist\n");
					return;
				}
				client = edict_num(entno);
				self = client;
				playerdemo_open_write(argv(3));
				return;
			}
			else if(argv(1) == "auto_read_and_write")
			{
				s = argv(2);
				n = stof(argv(3));
				cvar_set("bot_number", ftos(n));
				localcmd("wait; wait; wait\n");
				for(i = 0; i < n; ++i)
					localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
				localcmd("sv_cmd playerdemo write 1 ", ftos(n+1), "\n");
				return;
			}
			else if(argv(1) == "auto_read")
			{
				s = argv(2);
				n = stof(argv(3));
				cvar_set("bot_number", ftos(n));
				localcmd("wait; wait; wait\n");
				for(i = 0; i < n; ++i)
					localcmd("sv_cmd playerdemo read ", ftos(i+2), " ", s, ftos(i+1), "\n");
				return;
			}
			return;
			
		default:
			print("Incorrect parameters for ^2radarmap^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd \n");
			print("  FIXME: Arguments currently unknown\n");
			return;
	}
}

void GameCommand_printstats(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2printstats^7: foobar\n");
			return;
			
		case GC_REQUEST_COMMAND:
			DumpStats(FALSE);
			print("stats dumped.\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd printstats\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_radarmap(float request, float argc)
{
	float i;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2radarmap^7: Generate a radar image of the map\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(!radarmapper)
			{
				radarmapper = spawn();
				radarmapper.classname = "radarmapper";
				radarmapper.think = RadarMap_Think;
				radarmapper.nextthink = time;
				radarmapper.count = 8; // default to the --trace method, as it is faster now
				radarmapper.ltime = 1;
				radarmapper.size = '512 512 1';

				for(i = 1; i < argc; ++i)
				{
					switch(argv(i))
					{
						case "--force": { radarmapper.count |= 1; break;	}
						case "--loop": { radarmapper.count |= 2; break; }
						case "--quit": { radarmapper.count |= 4; break; }
						case "--block": { radarmapper.count &~= 24; break; }
						case "--trace": { radarmapper.count &~= 24; radarmapper.count |= 8; break; }
						case "--sample": { radarmapper.count &~= 24; radarmapper.count |= 16; break; }
						case "--lineblock": { radarmapper.count |= 24; break; }
						case "--flags": { ++i; radarmapper.count = stof(argv(i)); break; } // for the recursive call
						case "--sharpen": { ++i; radarmapper.ltime = stof(argv(i)); break; } // for the recursive call
						case "--res": // minor alias
						case "--resolution": { ++i; radarmapper.size_x = stof(argv(i)); ++i; radarmapper.size_y = stof(argv(i)); break; }
						case "--qual": // minor alias
						case "--quality": { ++i; radarmapper.size_z = stof(argv(i)); break; }
						
						default: 
							i = argc; 
							remove(radarmapper);
							radarmapper = world;
							break;
					}
				}
				
				if(radarmapper) // after doing the arguments, see if we successfully went forward. 
				{
					print("Radarmap entity spawned.\n");
					return; // if so, don't print usage.
				}
			}
			
		default:
			print("Incorrect parameters for ^2radarmap^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample | --lineblock] [--sharpen N] [--res W H] [--qual Q]\n");
			print("  The quality factor Q is roughly proportional to the time taken.\n");
			print("  trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
			return;
	}
}

void GameCommand_rankings(float request) // this is OLD.... jeez.
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2rankings^7: Print information about rankings\n");
			return;
			
		case GC_REQUEST_COMMAND:
			strunzone(rankings_reply);
			rankings_reply = strzone(getrankings());
			print(rankings_reply);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd rankings\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_records(float request)
{
	float i;
	
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2records^7: List top 10 records for the current map\n");
			return;
			
		case GC_REQUEST_COMMAND:
			for (i = 0; i < 10; ++i)
				print(records_reply[i]);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd records\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_reducematchtime(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2reducematchtime^7: Decrease the timelimit value incrementally\n");
			return;
			
		case GC_REQUEST_COMMAND:
			changematchtime(autocvar_timelimit_decrement*-60, autocvar_timelimit_min*60, autocvar_timelimit_max*60);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd reducematchtime\n");
			print("  No arguments required.\n");
			print("See also: ^2extendmatchtime^7\n");
			return;
	}
}

void GameCommand_stuffto(float request, float argc)
{
	// This... is a fairly dangerous and powerful command... - It allows any arguments to be sent to a client via rcon.
	// Because of this, it is disabled by default and must be enabled by the server owner when doing compilation. That way,
	// we can be certain they understand the risks of it... So to enable, compile server with -DSTUFFTO_ENABLED argument.
	
	entity client;
	float entno;
	
	#ifdef STUFFTO_ENABLED
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2stuffto^7: Send a command to be executed on a client\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(argc == 3)
			{
				entno = stof(argv(1));
				client = world;
				if(entno <= maxclients)
					client = edict_num(entno);
				if(client.flags & FL_CLIENT)
				{
					stuffcmd(client, strcat("\n", argv(2), "\n"));
					print(strcat("Command: \"", argv(2), "\" sent to ", client.netname, " (", argv(1) ,").\n"));
				}
				else
					print(strcat("Client (", argv(1) ,") not found.\n"));
				
				return;
			}
			
		default:
			print("Incorrect parameters for ^2stuffto^7\n");
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd stuffto clientnumber command\n");
			print("  FIXME: Arguments currently unknown\n");
			return;
	}
	#else // give the response for missing command to fake them out ;3
	if(request == GC_REQUEST_COMMAND)
	{
		print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
		return;
	}
	#endif
}

void GameCommand_teamstatus(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2teamstatus^7: Show information about player and team scores\n");
			return;
			
		case GC_REQUEST_COMMAND:
			Score_NicePrint(world);
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd teamstatus\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_time(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2time^7: Print different formats/readouts of time\n");
			return;
			
		case GC_REQUEST_COMMAND:
			print("time = ", ftos(time), "\n");
			print("frame start = ", ftos(gettime(GETTIME_FRAMESTART)), "\n");
			print("realtime = ", ftos(gettime(GETTIME_REALTIME)), "\n");
			print("hires = ", ftos(gettime(GETTIME_HIRES)), "\n");
			print("uptime = ", ftos(gettime(GETTIME_UPTIME)), "\n");
			print("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"); // FIXME: Why is strftime broken? is engine problem, I think.
			print("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y"), "\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd time\n");
			print("  No arguments required.\n");
			return;
	}
}

void GameCommand_trace(float request, float argc)
{
	entity e;
	vector org, delta, start, end, p, q, q0, pos, vv, dv;
	float i, f, safe, unsafe, dq, dqf;
	
	// TODO: Clean up all of these variables and merge the code below to use only a few
						
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2trace^7: Various debugging tools with tracing\n");
			return;
			
		case GC_REQUEST_COMMAND:
			switch(argv(1))
			{
				case "debug":
					print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
					for(;;)
					{
						org = world.mins;
						delta = world.maxs - world.mins;

						start_x = org_x + random() * delta_x;
						start_y = org_y + random() * delta_y;
						start_z = org_z + random() * delta_z;

						end_x = org_x + random() * delta_x;
						end_y = org_y + random() * delta_y;
						end_z = org_z + random() * delta_z;

						start = stov(vtos(start));
						end = stov(vtos(end));

						tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
						if(!trace_startsolid)
						{
							p = trace_endpos;
							tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
							if(trace_startsolid || trace_fraction == 1)
							{
								rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
								tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
								tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);

								if(trace_startsolid)
								{
									// how much do we need to back off?
									safe = 1;
									unsafe = 0;
									for(;;)
									{
										pos = p * (1 - (safe + unsafe) * 0.5) + start * ((safe + unsafe) * 0.5);
										tracebox(pos, PL_MIN, PL_MAX, pos, MOVE_NOMONSTERS, world);
										if(trace_startsolid)
										{
											if((safe + unsafe) * 0.5 == unsafe)
												break;
											unsafe = (safe + unsafe) * 0.5;
										}
										else
										{
											if((safe + unsafe) * 0.5 == safe)
												break;
											safe = (safe + unsafe) * 0.5;
										}
									}

									print("safe distance to back off: ", ftos(safe * vlen(p - start)), "qu\n");
									print("unsafe distance to back off: ", ftos(unsafe * vlen(p - start)), "qu\n");

									tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
									if(trace_startsolid)
										print("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
									else
										print("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
									break;
								}

								q0 = p;
								dq = 0;
								dqf = 1;
								for(;;)
								{
									q = p + normalize(end - p) * (dq + dqf);
									if(q == q0)
										break;
									tracebox(p, PL_MIN, PL_MAX, q, MOVE_NOMONSTERS, world);
									if(trace_startsolid)
										error("THIS ONE cannot happen");
									if(trace_fraction > 0)
										dq += dqf * trace_fraction;
									dqf *= 0.5;
									q0 = q;
								}
								if(dq > 0)
								{
									print("trace_endpos still before solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(p), "\n");
									print("could go ", ftos(dq), " units further to ", vtos(q), "\n");
									break;
								}
							}
						}
					}
					return;
					
				case "debug2":
					e = nextent(world);
					tracebox(e.origin + '0 0 32', e.mins, e.maxs, e.origin + '0 0 -1024', MOVE_NORMAL, e);
					vv = trace_endpos;
					if(trace_fraction == 1)
					{
						print("not above ground, aborting\n");
						return;
					}
					f = 0;
					for(i = 0; i < 100000; ++i)
					{
						dv = randomvec();
						if(dv_z > 0)
							dv = -1 * dv;
						tracebox(vv, e.mins, e.maxs, vv + dv, MOVE_NORMAL, e);
						if(trace_startsolid)
							print("bug 1\n");
						if(trace_fraction == 1)
						if(dv_z < f)
						{
							print("bug 2: ", ftos(dv_x), " ", ftos(dv_y), " ", ftos(dv_z));
							print(" (", ftos(asin(dv_z / vlen(dv)) * 180 / M_PI), " degrees)\n");
							f = dv_z;
						}
					}
					print("highest possible dist: ", ftos(f), "\n");
					return;
				
				case "walk":
					if(argc == 3)
					{
						e = nextent(world);
						if(tracewalk(e, stov(argv(1)), e.mins, e.maxs, stov(argv(2)), MOVE_NORMAL))
							print("can walk\n");
						else
							print("cannot walk\n");
						return;
					}
						
				case "showline":
					if(argc == 3)
					{
						vv = stov(argv(1));
						dv = stov(argv(2));
						traceline(vv, dv, MOVE_NORMAL, world);
						trailparticles(world, particleeffectnum("TR_NEXUIZPLASMA"), vv, trace_endpos);
						trailparticles(world, particleeffectnum("TR_CRYLINKPLASMA"), trace_endpos, dv);
						return;
					}
					
				// no default case, just go straight to "invalid arguments"
			}
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd trace command [arguments]\n");
			print("  FIXME: Arguments currently unknown\n");
			return;
	}
}

void GameCommand_unlockteams(float request)
{
	switch(request)
	{
		case GC_REQUEST_HELP:
			print("  ^2unlockteams^7: Enable the ability for players to switch or enter teams\n");
			return;
			
		case GC_REQUEST_COMMAND:
			if(teamplay)
			{
				lockteams = 0;
				bprint("^1The teams are now unlocked.\n");
			}
			else
				bprint("That command can only be used in a team-based gamemode.\n");
			return;
			
		default:
		case GC_REQUEST_USAGE:
			print("\nUsage:^3 sv_cmd unlockteams\n");
			print("  No arguments required.\n");
			print("See also: ^2lockteams^7\n");
			return;
	}
}


// =========================================
//  Main Function Called By Engine (sv_cmd)
// =========================================

void GameCommand(string command)
{
	// ===== TODO list =====
	// find all FIXME's and TODO'S and UNTESTED'S and finish them :P

	float search_request_type;
	float argc = tokenize_console(command);

	if(argv(0) == "help") 
	{
		if(argc == 1) 
		{
			print("\nUsage:^3 sv_cmd COMMAND...^7, where possible commands are:\n");
			GameCommand_adminmsg(GC_REQUEST_HELP, 0);
			GameCommand_allready(GC_REQUEST_HELP);
			GameCommand_allspec(GC_REQUEST_HELP, 0);
			GameCommand_anticheat(GC_REQUEST_HELP, 0);
			GameCommand_bbox(GC_REQUEST_HELP);
			GameCommand_bot_cmd(GC_REQUEST_HELP, 0);
			GameCommand_cointoss(GC_REQUEST_HELP, 0);
			GameCommand_cvar_changes(GC_REQUEST_HELP);
			GameCommand_cvar_purechanges(GC_REQUEST_HELP);
			GameCommand_database(GC_REQUEST_HELP, 0);
			GameCommand_defer_clear(GC_REQUEST_HELP, 0);
			GameCommand_defer_clear_all(GC_REQUEST_HELP);
			GameCommand_delrec(GC_REQUEST_HELP, 0);
			GameCommand_effectindexdump(GC_REQUEST_HELP);
			GameCommand_extendmatchtime(GC_REQUEST_HELP);
			GameCommand_find(GC_REQUEST_HELP, 0);
			GameCommand_gametype(GC_REQUEST_HELP, 0);
			GameCommand_gettaginfo(GC_REQUEST_HELP, 0);
			GameCommand_gotomap(GC_REQUEST_HELP, 0);
			GameCommand_ladder(GC_REQUEST_HELP);
			GameCommand_lockteams(GC_REQUEST_HELP);
			GameCommand_make_mapinfo(GC_REQUEST_HELP);
			GameCommand_modelbug(GC_REQUEST_HELP);
			GameCommand_moveplayer(GC_REQUEST_HELP, 0);
			GameCommand_nospectators(GC_REQUEST_HELP);
			GameCommand_onslaught_updatelinks(GC_REQUEST_HELP);
			GameCommand_playerdemo(GC_REQUEST_HELP, 0);
			GameCommand_printstats(GC_REQUEST_HELP);
			GameCommand_radarmap(GC_REQUEST_HELP, 0);
			GameCommand_rankings(GC_REQUEST_HELP);
			GameCommand_records(GC_REQUEST_HELP);
			GameCommand_reducematchtime(GC_REQUEST_HELP);
			GameCommand_stuffto(GC_REQUEST_HELP, 0);
			GameCommand_teamstatus(GC_REQUEST_HELP);
			GameCommand_time(GC_REQUEST_HELP);
			GameCommand_trace(GC_REQUEST_HELP, 0);
			GameCommand_unlockteams(GC_REQUEST_HELP);
			GameCommand_Vote("help", world);
			GameCommand_Ban("help");
			GameCommand_Generic("help");
			print("For help about specific commands, type sv_cmd help COMMAND\n");
			return;
		} 
		else
			search_request_type = GC_REQUEST_USAGE; // Instead of trying to call a command, we're going to see detailed information about it
	} 
	else if(GameCommand_Vote(command, world)) 
	{
		return; // handled by server/vote.qc 
	}
	else if(GameCommand_Ban(command)) 
	{
		return; // handled by server/ipban.qc
	}
	else if(GameCommand_Generic(command)) 
	{
		return; // handled by common/gamecommand.qc
	}
	else
		search_request_type = GC_REQUEST_COMMAND; // continue as usual and scan for normal commands
		
	switch( ((argv(0) == "help") ? argv(1) : argv(0)) ) // if first argument is help, then search for the second argument. Else, search for first. 
	{
		// Do not hard code aliases for these, instead create them in defaultXonotic.cfg
		// also: keep in alphabetical order, please ;)
		
		case "adminmsg": GameCommand_adminmsg(search_request_type, argc); break;
		case "allready": GameCommand_allready(search_request_type); break;
		case "allspec": GameCommand_allspec(search_request_type, argc); break;
		case "anticheat": GameCommand_anticheat(search_request_type, argc); break;
		case "bbox": GameCommand_bbox(search_request_type); break;
		case "bot_cmd": GameCommand_bot_cmd(search_request_type, argc); break;
		case "cointoss": GameCommand_cointoss(search_request_type, argc); break; 
		case "cvar_changes": GameCommand_cvar_changes(search_request_type); break; 
		case "cvar_purechanges": GameCommand_cvar_purechanges(search_request_type); break; 
		case "database": GameCommand_database(search_request_type, argc); break;
		case "defer_clear": GameCommand_defer_clear(search_request_type, argc); break;
		case "defer_clear_all": GameCommand_defer_clear_all(search_request_type); break;
		case "delrec": GameCommand_delrec(search_request_type, argc); break;
		case "effectindexdump": GameCommand_effectindexdump(search_request_type); break;
		case "extendmatchtime": GameCommand_extendmatchtime(search_request_type); break;
		case "find": GameCommand_find(search_request_type, argc); break; 
		case "gametype": GameCommand_gametype(search_request_type, argc); break;
		case "gettaginfo": GameCommand_gettaginfo(search_request_type, argc); break;
		case "gotomap": GameCommand_gotomap(search_request_type, argc); break;
		case "ladder": GameCommand_ladder(search_request_type); break;
		case "lockteams": GameCommand_lockteams(search_request_type); break;
		case "make_mapinfo": GameCommand_make_mapinfo(search_request_type); break;
		case "modelbug": GameCommand_modelbug(search_request_type); break;
		case "moveplayer": GameCommand_moveplayer(search_request_type, argc); break;
		case "nospectators": GameCommand_nospectators(search_request_type); break;
		case "onslaught_updatelinks": GameCommand_onslaught_updatelinks(search_request_type); break;
		case "playerdemo": GameCommand_playerdemo(search_request_type, argc); break;
		case "printstats": GameCommand_printstats(search_request_type); break;
		case "radarmap": GameCommand_radarmap(search_request_type, argc); break;
		case "rankings": GameCommand_rankings(search_request_type); break;
		case "records": GameCommand_records(search_request_type); break;
		case "reducematchtime": GameCommand_reducematchtime(search_request_type); break;
		case "stuffto": GameCommand_stuffto(search_request_type, argc); break;
		case "teamstatus": GameCommand_teamstatus(search_request_type); break;
		case "time": GameCommand_time(search_request_type); break;
		case "trace": GameCommand_trace(search_request_type, argc); break;
		case "unlockteams": GameCommand_unlockteams(search_request_type); break;
		
		default:
			print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
	}
}