qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write("\n");
  39
  40                 HUD_Write_Cvar_q("_hud_panelorder");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("hud_configure_grid");
  44                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  45                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  46                 HUD_Write("\n");
  47
  48                 HUD_Write_Cvar_q("scr_centerpos");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_complainbubble");
  69                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  70                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  73                                         HUD_Write_PanelCvar_q("_ammo_color");
  74                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  75                                         HUD_Write_PanelCvar_q("_aspect");
  76                                         HUD_Write_PanelCvar_q("_timeout");
  77                                         HUD_Write_PanelCvar_q("_timeout_effect");
  78                                         break;
  79                                 case HUD_PANEL_AMMO:
  80                                         HUD_Write_PanelCvar_q("_onlycurrent");
  81                                         HUD_Write_PanelCvar_q("_iconalign");
  82                                         HUD_Write_PanelCvar_q("_progressbar");
  83                                         HUD_Write_PanelCvar_q("_progressbar_name");
  84                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  85                                         HUD_Write_PanelCvar_q("_text");
  86                                         break;
  87                                 case HUD_PANEL_POWERUPS:
  88                                         HUD_Write_PanelCvar_q("_flip");
  89                                         HUD_Write_PanelCvar_q("_iconalign");
  90                                         HUD_Write_PanelCvar_q("_baralign");
  91                                         HUD_Write_PanelCvar_q("_progressbar");
  92                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  93                                         HUD_Write_PanelCvar_q("_progressbar_shield");
  94                                         break;
  95                                 case HUD_PANEL_HEALTHARMOR:
  96                                         HUD_Write_PanelCvar_q("_flip");
  97                                         HUD_Write_PanelCvar_q("_iconalign");
  98                                         HUD_Write_PanelCvar_q("_baralign");
  99                                         HUD_Write_PanelCvar_q("_progressbar");
 100                                         HUD_Write_PanelCvar_q("_progressbar_health");
 101                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 102                                         HUD_Write_PanelCvar_q("_text");
 103                                         break;
 104                                 case HUD_PANEL_NOTIFY:
 105                                         HUD_Write_PanelCvar_q("_flip");
 106                                         HUD_Write_PanelCvar_q("_print");
 107                                         break;
 108                                 case HUD_PANEL_RADAR:
 109                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 110                                         break;
 111                                 case HUD_PANEL_VOTE:
 112                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 113                                         break;
 114                                 case HUD_PANEL_PRESSEDKEYS:
 115                                         HUD_Write_PanelCvar_q("_aspect");
 116                                         break;
 117                                 case HUD_PANEL_INFOMESSAGES:
 118                                         HUD_Write_PanelCvar_q("_flip");
 119                                         break;
 120                                 case HUD_PANEL_PHYSICS:
 121                                         HUD_Write_PanelCvar_q("_flip");
 122                                         HUD_Write_PanelCvar_q("_baralign");
 123                                         HUD_Write_PanelCvar_q("_progressbar");
 124                                         break;
 125                         }
 126                         HUD_Write("\n");
 127                 }
 128                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 129
 130                 print("^2Successfully exported to ", filename, "! (Note: It's saved in data/data/)\n");
 131                 fclose(fh);
 132         }
 133         else
 134                 print("^1Couldn't write to ", filename, "\n");
 135 }
 136
 137 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 138 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 139 {
 140         float i;
 141         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 142         vector myTarget;
 143         myTarget = myPos;
 144
 145         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 146                 if(i == highlightedPanel || !panel_enabled)
 147                         continue;
 148
 149                 HUD_Panel_UpdatePosSizeForId(i);
 150
 151                 panel_pos -= '1 1 0' * panel_bg_border;
 152                 panel_size += '2 2 0' * panel_bg_border;
 153
 154                 if(myPos_y + mySize_y < panel_pos_y)
 155                         continue;
 156                 if(myPos_y > panel_pos_y + panel_size_y)
 157                         continue;
 158
 159                 if(myPos_x + mySize_x < panel_pos_x)
 160                         continue;
 161                 if(myPos_x > panel_pos_x + panel_size_x)
 162                         continue;
 163
 164                 // OK, there IS a collision.
 165
 166                 myCenter_x = myPos_x + 0.5 * mySize_x;
 167                 myCenter_y = myPos_y + 0.5 * mySize_y;
 168
 169                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 170                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 171
 172                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 173                 {
 174                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 175                                 myTarget_x = panel_pos_x - mySize_x;
 176                         else // push it upwards
 177                                 myTarget_y = panel_pos_y - mySize_y;
 178                 }
 179                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 180                 {
 181                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 182                                 myTarget_x = panel_pos_x + panel_size_x;
 183                         else // push it upwards
 184                                 myTarget_y = panel_pos_y - mySize_y;
 185                 }
 186                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 187                 {
 188                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 189                                 myTarget_x = panel_pos_x - mySize_x;
 190                         else // push it downwards
 191                                 myTarget_y = panel_pos_y + panel_size_y;
 192                 }
 193                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 194                 {
 195                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 196                                 myTarget_x = panel_pos_x + panel_size_x;
 197                         else // push it downwards
 198                                 myTarget_y = panel_pos_y + panel_size_y;
 199                 }
 200                 //if(cvar("hud_configure_checkcollisions_debug"))
 201                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 202         }
 203
 204         return myTarget;
 205 }
 206
 207 void HUD_Panel_SetPos(vector pos)
 208 {
 209         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 210         vector mySize;
 211         mySize = panel_size;
 212
 213         //if(cvar("hud_configure_checkcollisions_debug"))
 214                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 215
 216         if(autocvar_hud_configure_grid)
 217         {
 218                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 219                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 220         }
 221
 222         if(hud_configure_checkcollisions)
 223                 pos = HUD_Panel_CheckMove(pos, mySize);
 224
 225         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 226         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 227
 228         string s;
 229         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 230
 231         HUD_Panel_GetName(highlightedPanel);
 232         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 233 }
 234
 235 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 236 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 237         float i;
 238
 239         vector targEndPos;
 240
 241         float dist_x, dist_y;
 242         float ratio;
 243         ratio = mySize_x/mySize_y;
 244
 245         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 246                 if(i == highlightedPanel || !panel_enabled)
 247                         continue;
 248
 249                 HUD_Panel_UpdatePosSizeForId(i);
 250
 251                 panel_pos -= '1 1 0' * panel_bg_border;
 252                 panel_size += '2 2 0' * panel_bg_border;
 253
 254                 targEndPos = panel_pos + panel_size;
 255
 256                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 257                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 258                         continue;
 259
 260                 if (resizeCorner == 1)
 261                 {
 262                         // check if this panel is on our way
 263                         if (resizeorigin_x <= panel_pos_x)
 264                                 continue;
 265                         if (resizeorigin_y <= panel_pos_y)
 266                                 continue;
 267                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 268                                 continue;
 269                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 270                                 continue;
 271
 272                         // there is a collision:
 273                         // detect which side of the panel we are facing is actually limiting the resizing
 274                         // (which side the resize direction finds for first) and reduce the size up to there
 275                         //
 276                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 277                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 278                         dist_x = resizeorigin_x - targEndPos_x;
 279                         dist_y = resizeorigin_y - targEndPos_y;
 280                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 281                                 mySize_x = min(mySize_x, dist_x);
 282                         else
 283                                 mySize_y = min(mySize_y, dist_y);
 284                 }
 285                 else if (resizeCorner == 2)
 286                 {
 287                         if (resizeorigin_x >= targEndPos_x)
 288                                 continue;
 289                         if (resizeorigin_y <= panel_pos_y)
 290                                 continue;
 291                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 292                                 continue;
 293                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 294                                 continue;
 295
 296                         dist_x = panel_pos_x - resizeorigin_x;
 297                         dist_y = resizeorigin_y - targEndPos_y;
 298                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 299                                 mySize_x = min(mySize_x, dist_x);
 300                         else
 301                                 mySize_y = min(mySize_y, dist_y);
 302                 }
 303                 else if (resizeCorner == 3)
 304                 {
 305                         if (resizeorigin_x <= panel_pos_x)
 306                                 continue;
 307                         if (resizeorigin_y >= targEndPos_y)
 308                                 continue;
 309                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 310                                 continue;
 311                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 312                                 continue;
 313
 314                         dist_x = resizeorigin_x - targEndPos_x;
 315                         dist_y = panel_pos_y - resizeorigin_y;
 316                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 317                                 mySize_x = min(mySize_x, dist_x);
 318                         else
 319                                 mySize_y = min(mySize_y, dist_y);
 320                 }
 321                 else if (resizeCorner == 4)
 322                 {
 323                         if (resizeorigin_x >= targEndPos_x)
 324                                 continue;
 325                         if (resizeorigin_y >= targEndPos_y)
 326                                 continue;
 327                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 328                                 continue;
 329                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 330                                 continue;
 331
 332                         dist_x = panel_pos_x - resizeorigin_x;
 333                         dist_y = panel_pos_y - resizeorigin_y;
 334                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 335                                 mySize_x = min(mySize_x, dist_x);
 336                         else
 337                                 mySize_y = min(mySize_y, dist_y);
 338                 }
 339                 //if(cvar("hud_configure_checkcollisions_debug"))
 340                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 341         }
 342
 343         return mySize;
 344 }
 345
 346 void HUD_Panel_SetPosSize(vector mySize)
 347 {
 348         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 349         vector resizeorigin;
 350         resizeorigin = panel_click_resizeorigin;
 351         vector myPos;
 352
 353         // minimum panel size cap
 354         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 355         mySize_y = max(0.025 * vid_conheight, mySize_y);
 356
 357         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 358         {
 359                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 360                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 361         }
 362
 363         // collision testing|
 364         // -----------------+
 365
 366         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 367         if(resizeCorner == 1) {
 368                 myPos_x = resizeorigin_x - mySize_x;
 369                 myPos_y = resizeorigin_y - mySize_y;
 370         } else if(resizeCorner == 2) {
 371                 myPos_x = resizeorigin_x;
 372                 myPos_y = resizeorigin_y - mySize_y;
 373         } else if(resizeCorner == 3) {
 374                 myPos_x = resizeorigin_x - mySize_x;
 375                 myPos_y = resizeorigin_y;
 376         } else { // resizeCorner == 4
 377                 myPos_x = resizeorigin_x;
 378                 myPos_y = resizeorigin_y;
 379         }
 380
 381         // left/top screen edges
 382         if(myPos_x < 0)
 383                 mySize_x = mySize_x + myPos_x;
 384         if(myPos_y < 0)
 385                 mySize_y = mySize_y + myPos_y;
 386
 387         // bottom/right screen edges
 388         if(myPos_x + mySize_x > vid_conwidth)
 389                 mySize_x = vid_conwidth - myPos_x;
 390         if(myPos_y + mySize_y > vid_conheight)
 391                 mySize_y = vid_conheight - myPos_y;
 392
 393         //if(cvar("hud_configure_checkcollisions_debug"))
 394                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 395
 396         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 397         if(autocvar_hud_configure_grid)
 398         {
 399                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 400                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 401         }
 402
 403         if(hud_configure_checkcollisions)
 404                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 405
 406         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 407         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 408         mySize_y = max(0.025 * vid_conheight, mySize_y);
 409
 410         // do another pos check, as size might have changed by now
 411         if(resizeCorner == 1) {
 412                 myPos_x = resizeorigin_x - mySize_x;
 413                 myPos_y = resizeorigin_y - mySize_y;
 414         } else if(resizeCorner == 2) {
 415                 myPos_x = resizeorigin_x;
 416                 myPos_y = resizeorigin_y - mySize_y;
 417         } else if(resizeCorner == 3) {
 418                 myPos_x = resizeorigin_x - mySize_x;
 419                 myPos_y = resizeorigin_y;
 420         } else { // resizeCorner == 4
 421                 myPos_x = resizeorigin_x;
 422                 myPos_y = resizeorigin_y;
 423         }
 424
 425         //if(cvar("hud_configure_checkcollisions_debug"))
 426                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 427
 428         HUD_Panel_GetName(highlightedPanel);
 429         string s;
 430         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 431         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 432
 433         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 434         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 435 }
 436
 437 float pressed_key_time;
 438 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 439 void HUD_Panel_Arrow_Action(float nPrimary)
 440 {
 441         if (highlightedPanel == -1)
 442                 return;
 443
 444         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 445
 446         float step;
 447         if(autocvar_hud_configure_grid)
 448         {
 449                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 450                 {
 451                         if (hudShiftState & S_SHIFT)
 452                                 step = hud_configure_realGridSize_y;
 453                         else
 454                                 step = 2 * hud_configure_realGridSize_y;
 455                 }
 456                 else
 457                 {
 458                         if (hudShiftState & S_SHIFT)
 459                                 step = hud_configure_realGridSize_x;
 460                         else
 461                                 step = 2 * hud_configure_realGridSize_x;
 462                 }
 463         }
 464         else
 465         {
 466                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 467                         step = vid_conheight;
 468                 else
 469                         step = vid_conwidth;
 470                 if (hudShiftState & S_SHIFT)
 471                         step = (step / 256); // more precision
 472                 else
 473                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 474         }
 475
 476         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 477
 478         highlightedPanel_initial_pos = panel_pos;
 479         highlightedPanel_initial_size = panel_size;
 480
 481         if (hudShiftState & S_ALT) // resize
 482         {
 483                 highlightedAction = 1;
 484                 if(nPrimary == K_UPARROW)
 485                         resizeCorner = 1;
 486                 else if(nPrimary == K_RIGHTARROW)
 487                         resizeCorner = 2;
 488                 else if(nPrimary == K_LEFTARROW)
 489                         resizeCorner = 3;
 490                 else // if(nPrimary == K_DOWNARROW)
 491                         resizeCorner = 4;
 492
 493                 // ctrl+arrow reduces the size, instead of increasing it
 494                 // Note that ctrl disables collisions check too, but it's fine
 495                 // since we don't collide with anything reducing the size
 496                 if (hudShiftState & S_CTRL) {
 497                         step = -step;
 498                         resizeCorner = 5 - resizeCorner;
 499                 }
 500
 501                 vector mySize;
 502                 mySize = panel_size;
 503                 panel_click_resizeorigin = panel_pos;
 504                 if(resizeCorner == 1) {
 505                         panel_click_resizeorigin += mySize;
 506                         mySize_y += step;
 507                 } else if(resizeCorner == 2) {
 508                         panel_click_resizeorigin_y += mySize_y;
 509                         mySize_x += step;
 510                 } else if(resizeCorner == 3) {
 511                         panel_click_resizeorigin_x += mySize_x;
 512                         mySize_x += step;
 513                 } else { // resizeCorner == 4
 514                         mySize_y += step;
 515                 }
 516                 HUD_Panel_SetPosSize(mySize);
 517         }
 518         else // move
 519         {
 520                 highlightedAction = 2;
 521                 vector pos;
 522                 pos = panel_pos;
 523                 if(nPrimary == K_UPARROW)
 524                         pos_y -= step;
 525                 else if(nPrimary == K_DOWNARROW)
 526                         pos_y += step;
 527                 else if(nPrimary == K_LEFTARROW)
 528                         pos_x -= step;
 529                 else // if(nPrimary == K_RIGHTARROW)
 530                         pos_x += step;
 531
 532                 HUD_Panel_SetPos(pos);
 533         }
 534
 535         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 536
 537         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 538         {
 539                 // backup!
 540                 panel_pos_backup = highlightedPanel_initial_pos;
 541                 panel_size_backup = highlightedPanel_initial_size;
 542                 highlightedPanel_backup = highlightedPanel;
 543         }
 544 }
 545
 546 float mouseClicked;
 547 float prevMouseClicked; // previous state
 548 float prevMouseClickedTime; // time during previous mouse click, to check for doubleclicks
 549 vector prevMouseClickedPos; // pos during previous mouse click, to check for doubleclicks
 550
 551 void HUD_Panel_EnableMenu();
 552 float tab_panels[HUD_PANEL_NUM];
 553 float tab_panel, tab_backward;
 554 vector tab_panel_pos;
 555 void HUD_Panel_FirstInDrawQ(float id);
 556 void reset_tab_panels()
 557 {
 558         int i;
 559         for(i = 0; i < HUD_PANEL_NUM; ++i)
 560                 tab_panels[i] = -1;
 561 }
 562 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 563 {
 564         string s;
 565
 566         if(!autocvar__hud_configure)
 567                 return false;
 568
 569         // allow console bind to work
 570         string con_keys;
 571         float keys;
 572         con_keys = findkeysforcommand("toggleconsole");
 573         keys = tokenize(con_keys);
 574
 575         float hit_con_bind, i;
 576         for (i = 0; i < keys; ++i)
 577         {
 578                 if(nPrimary == stof(argv(i)))
 579                         hit_con_bind = 1;
 580         }
 581
 582         if(bInputType == 0) {
 583                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 584                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 585                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 586         }
 587         else if(bInputType == 1) {
 588                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 589                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 590                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 591         }
 592
 593         if(nPrimary == K_CTRL)
 594         {
 595                 if (bInputType == 1) //ctrl has been released
 596                 {
 597                         if (tab_panel != -1)
 598                         {
 599                                 //switch to selected panel
 600                                 highlightedPanel = tab_panel;
 601                                 highlightedAction = 0;
 602                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 603                         }
 604                         tab_panel = -1;
 605                         reset_tab_panels();
 606                 }
 607         }
 608
 609         if(nPrimary == K_MOUSE1)
 610         {
 611                 if(bInputType == 0) { // key pressed
 612                         mouseClicked = 1;
 613                         return true;
 614                 }
 615                 else if(bInputType == 1) {// key released
 616                         mouseClicked = 0;
 617                         return true;
 618                 }
 619         }
 620         else if(nPrimary == K_ESCAPE)
 621         {
 622                 if (bInputType == 1)
 623                         return true;
 624                 menu_enabled = 1;
 625                 menu_enabled_time = time;
 626                 localcmd("menu_showhudexit\n");
 627         }
 628         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 629         {
 630                 if (bInputType == 1 || mouseClicked)
 631                         return true;
 632
 633                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 634                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 635                 //(it should only after every other panel of the hud)
 636                 //It's a minor bug anyway, we can live with it
 637
 638                 float starting_panel;
 639                 float old_tab_panel = tab_panel;
 640                 if (tab_panel == -1) //first press of TAB
 641                 {
 642                         if (highlightedPanel != -1)
 643                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 644                         else
 645                                 panel_pos = '0 0 0';
 646                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 647                         tab_panel_pos = panel_pos; //to compute level
 648                 }
 649                 else
 650                 {
 651                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 652                                 reset_tab_panels();
 653                         starting_panel = tab_panel;
 654                 }
 655                 tab_backward = (hudShiftState & S_SHIFT);
 656
 657                 float k, level, start_pos_x;
 658                 vector candidate_pos;
 659                 const float LEVELS_NUM = 4;
 660                 const float level_height = vid_conheight / LEVELS_NUM;
 661 :find_tab_panel
 662                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 663                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 664                 start_pos_x = tab_panel_pos_x;
 665                 tab_panel = -1;
 666                 k=0;
 667                 while(++k)
 668                 {
 669                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 670                         {
 671                                 if (i == tab_panels[i] || i == starting_panel)
 672                                         continue;
 673                                 HUD_Panel_UpdatePosSizeForId(i)
 674                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 675                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 676                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 677                                 {
 678                                         tab_panel = i;
 679                                         tab_panel_pos = candidate_pos = panel_pos;
 680                                 }
 681                         }
 682                         if (tab_panel != -1)
 683                                 break;
 684                         if (k == LEVELS_NUM) //tab_panel not found
 685                         {
 686                                 reset_tab_panels();
 687                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 688                                 {
 689                                         tab_panel = -1;
 690                                         return true;
 691                                 }
 692                                 starting_panel = old_tab_panel;
 693                                 old_tab_panel = -2;
 694                                 goto find_tab_panel; //u must find tab_panel!
 695                         }
 696                         if (!tab_backward)
 697                         {
 698                                 level = mod(level + level_height, vid_conheight);
 699                                 start_pos_x = 0;
 700                                 candidate_pos_x = vid_conwidth;
 701                         }
 702                         else
 703                         {
 704                                 level = mod(level - level_height, vid_conheight);
 705                                 start_pos_x = vid_conwidth;
 706                                 candidate_pos_x = 0;
 707                         }
 708                 }
 709
 710                 tab_panels[tab_panel] = tab_panel;
 711         }
 712         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 713         {
 714                 if (bInputType == 1 || mouseClicked)
 715                         return true;
 716
 717                 if (highlightedPanel != -1)
 718                 {
 719                         HUD_Panel_GetName(highlightedPanel);
 720                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 721                 }
 722                 else
 723                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 724         }
 725         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 726         {
 727                 if (bInputType == 1 || mouseClicked)
 728                         return true;
 729
 730                 if (highlightedPanel != -1)
 731                 {
 732                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 733                         panel_size_copied = panel_size;
 734                         highlightedPanel_copied = highlightedPanel;
 735                 }
 736         }
 737         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 738         {
 739                 if (bInputType == 1 || mouseClicked)
 740                         return true;
 741
 742                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 743                         return true;
 744
 745                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 746
 747                 // reduce size if it'd go beyond screen boundaries
 748                 vector tmp_size = panel_size_copied;
 749                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 750                         tmp_size_x = vid_conwidth - panel_pos_x;
 751                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 752                         tmp_size_y = vid_conheight - panel_pos_y;
 753
 754                 if (panel_size == tmp_size)
 755                         return true;
 756
 757                 // backup first!
 758                 panel_pos_backup = panel_pos;
 759                 panel_size_backup = panel_size;
 760                 highlightedPanel_backup = highlightedPanel;
 761
 762                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 763                 HUD_Panel_GetName(highlightedPanel);
 764                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 765         }
 766         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 767         {
 768                 if (bInputType == 1 || mouseClicked)
 769                         return true;
 770                 //restore previous values
 771                 if (highlightedPanel_backup != -1)
 772                 {
 773                         HUD_Panel_GetName(highlightedPanel_backup);
 774                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 775                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 776                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 777                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 778                         highlightedPanel_backup = -1;
 779                 }
 780         }
 781         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 782         {
 783                 if (bInputType == 1)
 784                 {
 785                         pressed_key_time = 0;
 786                         return true;
 787                 }
 788                 else if (pressed_key_time == 0)
 789                         pressed_key_time = time;
 790
 791                 if (!mouseClicked)
 792                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 793         }
 794         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 795         {
 796                 if (bInputType == 1)
 797                         return true;
 798                 if (highlightedPanel != -1)
 799                         HUD_Panel_EnableMenu();
 800         }
 801         else if(hit_con_bind)
 802                 return false;
 803
 804         return true;
 805 }
 806
 807 float HUD_Panel_Check_Mouse_Pos()
 808 {
 809         float i, j, border;
 810
 811         while(j < HUD_PANEL_NUM)
 812         {
 813                 i = panel_order[j];
 814                 j += 1;
 815
 816                 HUD_Panel_UpdatePosSizeForId(i);
 817
 818                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 819
 820                 // move
 821                 if(mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 822                 {
 823                         return 1;
 824                 }
 825                 // resize from topleft border
 826                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 827                 {
 828                         return 2;
 829                 }
 830                 // resize from topright border
 831                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 832                 {
 833                         return 3;
 834                 }
 835                 // resize from bottomleft border
 836                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 837                 {
 838                         return 3;
 839                 }
 840                 // resize from bottomright border
 841                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 842                 {
 843                         return 2;
 844                 }
 845         }
 846         return 0;
 847 }
 848
 849 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 850 void HUD_Panel_FirstInDrawQ(float id)
 851 {
 852         float i;
 853         var float place = -1;
 854         // find out where in the array our current id is, save into place
 855         for(i = 0; i < HUD_PANEL_NUM; ++i)
 856         {
 857                 if(panel_order[i] == id)
 858                 {
 859                         place = i;
 860                         break;
 861                 }
 862         }
 863         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 864         if(place == -1)
 865                 place = HUD_PANEL_NUM - 1;
 866
 867         // move all ids up by one step in the array until "place"
 868         for(i = place; i > 0; --i)
 869         {
 870                 panel_order[i] = panel_order[i-1];
 871         }
 872         // now save the new top id
 873         panel_order[0] = id;
 874
 875         // let's save them into the cvar by some strcat trickery
 876         string s;
 877         for(i = 0; i < HUD_PANEL_NUM; ++i)
 878         {
 879                 s = strcat(s, ftos(panel_order[i]), " ");
 880         }
 881         cvar_set("_hud_panelorder", s);
 882         if(hud_panelorder_prev)
 883                 strunzone(hud_panelorder_prev);
 884         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 885 }
 886
 887 void HUD_Panel_Highlight()
 888 {
 889         float i, j, border;
 890
 891         while(j < HUD_PANEL_NUM)
 892         {
 893                 i = panel_order[j];
 894                 j += 1;
 895
 896                 HUD_Panel_UpdatePosSizeForId(i);
 897
 898                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 899
 900                 // move
 901                 if(mousepos_x >= panel_pos_x && mousepos_y >= panel_pos_y && mousepos_x <= panel_pos_x + panel_size_x && mousepos_y <= panel_pos_y + panel_size_y)
 902                 {
 903                         highlightedPanel = i;
 904                         HUD_Panel_FirstInDrawQ(i);
 905                         highlightedAction = 1;
 906                         panel_click_distance = mousepos - panel_pos;
 907                         return;
 908                 }
 909                 // resize from topleft border
 910                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 911                 {
 912                         highlightedPanel = i;
 913                         HUD_Panel_FirstInDrawQ(i);
 914                         highlightedAction = 2;
 915                         resizeCorner = 1;
 916                         panel_click_distance = mousepos - panel_pos;
 917                         panel_click_resizeorigin = panel_pos + panel_size;
 918                         return;
 919                 }
 920                 // resize from topright border
 921                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 922                 {
 923                         highlightedPanel = i;
 924                         HUD_Panel_FirstInDrawQ(i);
 925                         highlightedAction = 2;
 926                         resizeCorner = 2;
 927                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
 928                         panel_click_distance_y = mousepos_y - panel_pos_y;
 929                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
 930                         return;
 931                 }
 932                 // resize from bottomleft border
 933                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 934                 {
 935                         highlightedPanel = i;
 936                         HUD_Panel_FirstInDrawQ(i);
 937                         highlightedAction = 2;
 938                         resizeCorner = 3;
 939                         panel_click_distance_x = mousepos_x - panel_pos_x;
 940                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
 941                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
 942                         return;
 943                 }
 944                 // resize from bottomright border
 945                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 946                 {
 947                         highlightedPanel = i;
 948                         HUD_Panel_FirstInDrawQ(i);
 949                         highlightedAction = 2;
 950                         resizeCorner = 4;
 951                         panel_click_distance = panel_size - mousepos + panel_pos;
 952                         panel_click_resizeorigin = panel_pos;
 953                         return;
 954                 }
 955         }
 956         highlightedPanel = -1;
 957         highlightedAction = 0;
 958 }
 959
 960 void HUD_Panel_EnableMenu()
 961 {
 962         menu_enabled = 2;
 963         menu_enabled_time = time;
 964         HUD_Panel_GetName(highlightedPanel);
 965         localcmd("menu_showhudoptions ", panel_name, "\n");
 966 }
 967 float mouse_over_panel;
 968 void HUD_Panel_Mouse()
 969 {
 970         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
 971         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
 972                 menu_enabled = 0;
 973
 974         /*
 975         print("menu_enabled: ", ftos(menu_enabled), "\n");
 976         print("Highlighted: ", ftos(highlightedPanel), "\n");
 977         print("Menu alpha: ", ftos(autocvar__menu_alpha), "\n");
 978         */
 979
 980         // instantly hide the editor cursor if we open the HUDExit dialog
 981         // as hud_fade_alpha doesn't decrease to 0 in this case
 982         // TODO: find a way to fade the cursor out even in this case
 983         if(menu_enabled == 1 || (menu_enabled == 2 && !hud_fade_alpha))
 984                 return;
 985
 986         mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
 987
 988         mousepos_x = bound(0, mousepos_x, vid_conwidth);
 989         mousepos_y = bound(0, mousepos_y, vid_conheight);
 990
 991         if(mouseClicked)
 992         {
 993                 if(prevMouseClicked == 0)
 994                 {
 995                         if (tab_panel != -1)
 996                         {
 997                                 //stop ctrl-tab selection
 998                                 tab_panel = -1;
 999                                 reset_tab_panels();
1000                         }
1001                         HUD_Panel_Highlight(); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1002                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1003                         if (highlightedPanel != -1)
1004                         {
1005                                 highlightedPanel_initial_pos = panel_pos;
1006                                 highlightedPanel_initial_size = panel_size;
1007                         }
1008                         // doubleclick check
1009                         if (time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1010                         {
1011                                 mouseClicked = 0; // to prevent spam, I guess.
1012                                 HUD_Panel_EnableMenu();
1013                         }
1014                         else
1015                         {
1016                                 prevMouseClickedTime = time;
1017                                 prevMouseClickedPos = mousepos;
1018                         }
1019                 }
1020                 else
1021                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1022
1023                 if (highlightedPanel != -1)
1024                 {
1025                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1026                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1027                         {
1028                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1029                                 // backup!
1030                                 panel_pos_backup = highlightedPanel_initial_pos;
1031                                 panel_size_backup = highlightedPanel_initial_size;
1032                                 highlightedPanel_backup = highlightedPanel;
1033                         }
1034                         else
1035                                 // in case the clicked panel is inside another panel and we aren't
1036                                 // moving it, avoid the immediate "fix" of its position/size
1037                                 // (often unwanted and hateful) by disabling collisions check
1038                                 hud_configure_checkcollisions = false;
1039                 }
1040
1041                 if(highlightedAction == 1)
1042                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1043                 else if(highlightedAction == 2)
1044                 {
1045                         vector mySize;
1046                         if(resizeCorner == 1) {
1047                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1048                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1049                         } else if(resizeCorner == 2) {
1050                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1051                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1052                         } else if(resizeCorner == 3) {
1053                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1054                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1055                         } else { // resizeCorner == 4
1056                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1057                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1058                         }
1059                         HUD_Panel_SetPosSize(mySize);
1060                 }
1061         }
1062         else
1063         {
1064                 if(menu_enabled == 2)
1065                         mouse_over_panel = 0;
1066                 else
1067                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos();
1068                 if (mouse_over_panel && tab_panel == -1)
1069                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1070         }
1071         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1072         const vector cursorsize = '32 32 0';
1073
1074         if(!mouse_over_panel)
1075                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1076         else if(mouse_over_panel == 1)
1077                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1078         else if(mouse_over_panel == 2)
1079                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1080         else
1081                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', hud_fade_alpha, DRAWFLAG_NORMAL);
1082
1083         prevMouseClicked = mouseClicked;
1084 }
1085
1086 const float hlBorderSize = 4;
1087 const string hlBorder = "gfx/hud/default/border_highlighted";
1088 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1089 void HUD_Panel_HlBorder(float myBorder, vector color, float alpha)
1090 {
1091         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * alpha, DRAWFLAG_NORMAL);
1092         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1093         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1094         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1095         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, alpha, DRAWFLAG_NORMAL);
1096 }