qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap(float reinit);
  48 void ShuffleMaplist()
  49 float(float reinit) DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride(1))
 193                         GotoNextMap(1);
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_ghost_items");
 301                 BADPREFIX("g_playerstats_");
 302                 BADPREFIX("g_respawn_ghosts");
 303                 BADPREFIX("g_voice_flood_");
 304                 BADPREFIX("rcon_");
 305                 BADPREFIX("sv_allowdownloads");
 306                 BADPREFIX("sv_autodemo");
 307                 BADPREFIX("sv_curl_");
 308                 BADPREFIX("sv_eventlog");
 309                 BADPREFIX("sv_logscores_");
 310                 BADPREFIX("sv_master");
 311                 BADPREFIX("sv_weaponstats_");
 312                 BADPREFIX("sv_waypointsprite_");
 313                 BADCVAR("rescan_pending");
 314
 315                 // these can contain player IDs, so better hide
 316                 BADPREFIX("g_forced_team_");
 317
 318                 // mapinfo
 319                 BADCVAR("fraglimit");
 320                 BADCVAR("g_arena");
 321                 BADCVAR("g_assault");
 322                 BADCVAR("g_ca");
 323                 BADCVAR("g_ctf");
 324                 BADCVAR("g_cts");
 325                 BADCVAR("g_dm");
 326                 BADCVAR("g_domination");
 327                 BADCVAR("g_domination_default_teams");
 328                 BADCVAR("g_freezetag");
 329                 BADCVAR("g_keepaway");
 330                 BADCVAR("g_keyhunt");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_keyhunt_teams");
 333                 BADCVAR("g_lms");
 334                 BADCVAR("g_nexball");
 335                 BADCVAR("g_onslaught");
 336                 BADCVAR("g_race");
 337                 BADCVAR("g_race_qualifying_timelimit");
 338                 BADCVAR("g_runematch");
 339                 BADCVAR("g_tdm");
 340                 BADCVAR("g_tdm_teams");
 341                 BADCVAR("leadlimit");
 342                 BADCVAR("nextmap");
 343                 BADCVAR("teamplay");
 344                 BADCVAR("timelimit");
 345
 346                 // long
 347                 BADCVAR("hostname");
 348                 BADCVAR("g_maplist");
 349                 BADCVAR("g_maplist_mostrecent");
 350                 BADCVAR("sv_motd");
 351
 352                 v = cvar_string(k);
 353                 d = cvar_defstring(k);
 354                 if(v == d)
 355                         continue;
 356
 357                 if(adding)
 358                 {
 359                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 360                         if(strlen(cvar_changes) > 16384)
 361                         {
 362                                 cvar_changes = "// too many settings have been changed to show them here\n";
 363                                 adding = 0;
 364                         }
 365                 }
 366
 367                 // now check if the changes are actually gameplay relevant
 368
 369                 // does nothing visible
 370                 BADCVAR("captureleadlimit_override");
 371                 BADCVAR("g_arena_point_leadlimit");
 372                 BADCVAR("g_balance_kill_delay");
 373                 BADCVAR("g_ca_point_leadlimit");
 374                 BADCVAR("g_ctf_captimerecord_always");
 375                 BADCVAR("g_ctf_capture_leadlimit");
 376                 BADCVAR("g_ctf_flag_capture_effects");
 377                 BADCVAR("g_ctf_flag_glowtrails");
 378                 BADCVAR("g_ctf_flag_pickup_effects");
 379                 BADCVAR("g_domination_point_leadlimit");
 380                 BADCVAR("g_forced_respawn");
 381                 BADCVAR("g_keyhunt_point_leadlimit");
 382                 BADCVAR("g_nexball_goalleadlimit");
 383                 BADCVAR("g_runematch_point_leadlimit");
 384                 BADCVAR("leadlimit_and_fraglimit");
 385                 BADCVAR("leadlimit_override");
 386                 BADCVAR("pausable");
 387                 BADCVAR("sv_allow_fullbright");
 388                 BADCVAR("sv_checkforpacketsduringsleep");
 389                 BADCVAR("sv_timeout");
 390                 BADPREFIX("sv_timeout_");
 391                 BADCVAR("welcome_message_time");
 392                 BADPREFIX("crypto_");
 393                 BADPREFIX("g_chat_");
 394                 BADPREFIX("g_ctf_captimerecord_");
 395                 BADPREFIX("g_maplist_votable_");
 396                 BADPREFIX("net_");
 397                 BADPREFIX("prvm_");
 398                 BADPREFIX("skill_");
 399                 BADPREFIX("sv_cullentities_");
 400                 BADPREFIX("sv_fraginfo_");
 401                 BADPREFIX("sv_maxidle_");
 402                 BADPREFIX("sv_vote_");
 403                 BADPREFIX("timelimit_");
 404                 BADCVAR("gameversion");
 405                 BADPREFIX("gameversion_");
 406                 BADCVAR("sv_namechangetimer");
 407 #ifndef NO_LEGACY_NETWORKING
 408                 BADCVAR("sv_use_csqc_players"); // transition
 409 #endif
 410
 411                 // allowed changes to server admins (please sync this to server.cfg)
 412                 // vi commands:
 413                 //   :/"impure"/,$d
 414                 //   :g!,^\/\/[^ /],d
 415                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 416                 //   :%!sort
 417                 // yes, this does contain some redundant stuff, don't really care
 418                 BADCVAR("bot_config_file");
 419                 BADCVAR("bot_number");
 420                 BADCVAR("bot_prefix");
 421                 BADCVAR("bot_suffix");
 422                 BADCVAR("capturelimit_override");
 423                 BADCVAR("fraglimit_override");
 424                 BADCVAR("gametype");
 425                 BADCVAR("g_antilag");
 426                 BADCVAR("g_balance_teams");
 427                 BADCVAR("g_balance_teams_force");
 428                 BADCVAR("g_ban_sync_trusted_servers");
 429                 BADCVAR("g_ban_sync_uri");
 430                 BADCVAR("g_ctf_capture_limit");
 431                 BADCVAR("g_ctf_ignore_frags");
 432                 BADCVAR("g_ctf_win_mode");
 433                 BADCVAR("g_domination_point_limit");
 434                 BADCVAR("g_friendlyfire");
 435                 BADCVAR("g_fullbrightitems");
 436                 BADCVAR("g_fullbrightplayers");
 437                 BADCVAR("g_keyhunt_point_limit");
 438                 BADCVAR("g_keyhunt_teams_override");
 439                 BADCVAR("g_lms_lives_override");
 440                 BADCVAR("g_maplist");
 441                 BADCVAR("g_maplist_check_waypoints");
 442                 BADCVAR("g_maplist_mostrecent_count");
 443                 BADCVAR("g_maplist_shuffle");
 444                 BADCVAR("g_maplist_votable");
 445                 BADCVAR("g_maplist_votable_abstain");
 446                 BADCVAR("g_maplist_votable_nodetail");
 447                 BADCVAR("g_maplist_votable_suggestions");
 448                 BADCVAR("g_maxplayers");
 449                 BADCVAR("g_minstagib");
 450                 BADCVAR("g_mirrordamage");
 451                 BADCVAR("g_nexball_goallimit");
 452                 BADCVAR("g_powerups");
 453                 BADCVAR("g_runematch_point_limit");
 454                 BADCVAR("g_start_delay");
 455                 BADCVAR("g_warmup");
 456                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 457                 BADCVAR("hostname");
 458                 BADCVAR("log_file");
 459                 BADCVAR("maxplayers");
 460                 BADCVAR("minplayers");
 461                 BADCVAR("net_address");
 462                 BADCVAR("port");
 463                 BADCVAR("rcon_password");
 464                 BADCVAR("rcon_restricted_commands");
 465                 BADCVAR("rcon_restricted_password");
 466                 BADCVAR("skill");
 467                 BADCVAR("sv_adminnick");
 468                 BADCVAR("sv_autoscreenshot");
 469                 BADCVAR("sv_autotaunt");
 470                 BADCVAR("sv_curl_defaulturl");
 471                 BADCVAR("sv_defaultcharacter");
 472                 BADCVAR("sv_defaultplayercolors");
 473                 BADCVAR("sv_defaultplayermodel");
 474                 BADCVAR("sv_defaultplayerskin");
 475                 BADCVAR("sv_maxidle");
 476                 BADCVAR("sv_maxrate");
 477                 BADCVAR("sv_motd");
 478                 BADCVAR("sv_public");
 479                 BADCVAR("sv_ready_restart");
 480                 BADCVAR("sv_status_privacy");
 481                 BADCVAR("sv_taunt");
 482                 BADCVAR("sv_vote_call");
 483                 BADCVAR("sv_vote_commands");
 484                 BADCVAR("sv_vote_majority_factor");
 485                 BADCVAR("sv_vote_master");
 486                 BADCVAR("sv_vote_master_commands");
 487                 BADCVAR("sv_vote_master_password");
 488                 BADCVAR("sv_vote_simple_majority_factor");
 489                 BADCVAR("sys_ticrate");
 490                 BADCVAR("teamplay_mode");
 491                 BADCVAR("timelimit_override");
 492                 BADCVAR("g_spawnshieldtime");
 493                 BADPREFIX("g_warmup_");
 494                 BADPREFIX("sv_ready_restart_");
 495
 496                 if(autocvar_g_minstagib)
 497                 {
 498                         BADCVAR("g_grappling_hook");
 499                         BADCVAR("g_jetpack");
 500                 }
 501 #undef BADPREFIX
 502 #undef BADCVAR
 503
 504                 if(pureadding)
 505                 {
 506                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 507                         if(strlen(cvar_purechanges) > 16384)
 508                         {
 509                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 510                                 pureadding = 0;
 511                         }
 512                 }
 513                 ++cvar_purechanges_count;
 514                 // WARNING: this variable is used for the server list
 515                 // NEVER dare to skip this code!
 516                 // Hacks to intentionally appearing as "pure server" even though you DO have
 517                 // modified settings may be punished by removal from the server list.
 518                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 519                 // though.
 520         }
 521         buf_del(h);
 522         if(cvar_changes == "")
 523                 cvar_changes = "// this server runs at default server settings\n";
 524         else
 525                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 526         cvar_changes = strzone(cvar_changes);
 527         if(cvar_purechanges == "")
 528                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 529         else
 530                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 531         cvar_purechanges = strzone(cvar_purechanges);
 532 }
 533
 534 void detect_maptype()
 535 {
 536 #if 0
 537         vector o, v;
 538         float i;
 539
 540         for(;;)
 541         {
 542                 o = world.mins;
 543                 o_x += random() * (world.maxs_x - world.mins_x);
 544                 o_y += random() * (world.maxs_y - world.mins_y);
 545                 o_z += random() * (world.maxs_z - world.mins_z);
 546
 547                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 548                 if(trace_fraction == 1)
 549                         continue;
 550
 551                 v = trace_endpos;
 552
 553                 for(i = 0; i < 64; i += 4)
 554                 {
 555                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 556         if(trace_fraction == 1)
 557                 continue;
 558                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 559                 }
 560
 561                 break;
 562         }
 563 #endif
 564 }
 565
 566 entity randomseed;
 567 float RandomSeed_Send(entity to, float sf)
 568 {
 569         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 570         WriteShort(MSG_ENTITY, self.cnt);
 571         return TRUE;
 572 }
 573 void RandomSeed_Think()
 574 {
 575         self.cnt = bound(0, floor(random() * 65536), 65535);
 576         self.nextthink = time + 5;
 577
 578         self.SendFlags |= 1;
 579 }
 580 void RandomSeed_Spawn()
 581 {
 582         randomseed = spawn();
 583         randomseed.think = RandomSeed_Think;
 584         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 585
 586         entity oldself;
 587         oldself = self;
 588         self = randomseed;
 589         self.think(); // sets random seed and nextthink
 590         self = oldself;
 591 }
 592
 593 void spawnfunc___init_dedicated_server(void)
 594 {
 595         // handler for _init/_init map (only for dedicated server initialization)
 596
 597         world_initialized = -1; // don't complain
 598         cvar = cvar_normal;
 599         cvar_string = cvar_string_normal;
 600         cvar_set = cvar_set_normal;
 601
 602         remove = remove_unsafely;
 603
 604         entity e;
 605         e = spawn();
 606         e.think = GotoFirstMap;
 607         e.nextthink = time; // this is usually 1 at this point
 608
 609         e = spawn();
 610         e.classname = "info_player_deathmatch"; // safeguard against player joining
 611
 612         self.classname = "worldspawn"; // safeguard against various stuff ;)
 613
 614         MapInfo_Enumerate();
 615         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 616 }
 617
 618 void Map_MarkAsRecent(string m);
 619 float world_already_spawned;
 620 void RegisterWeapons();
 621 void Nagger_Init();
 622 void ClientInit_Spawn();
 623 void WeaponStats_Init();
 624 void WeaponStats_Shutdown();
 625 void spawnfunc_worldspawn (void)
 626 {
 627         float fd, l, i, j, n;
 628         string s, col;
 629
 630         cvar = cvar_normal;
 631         cvar_string = cvar_string_normal;
 632         cvar_set = cvar_set_normal;
 633
 634         if(world_already_spawned)
 635                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 636         world_already_spawned = TRUE;
 637
 638         remove = remove_safely; // during spawning, watch what you remove!
 639
 640         check_unacceptable_compiler_bugs();
 641
 642         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 643
 644         compressShortVector_init();
 645
 646         allowed_to_spawn = TRUE;
 647
 648         entity head;
 649         head = nextent(world);
 650         maxclients = 0;
 651         while(head)
 652         {
 653                 ++maxclients;
 654                 head = nextent(head);
 655         }
 656
 657         // needs to be done so early as they would still spawn
 658         RegisterWeapons();
 659
 660         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 661
 662         TemporaryDB = db_create();
 663
 664         // 0 normal
 665         lightstyle(0, "m");
 666
 667         // 1 FLICKER (first variety)
 668         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 669
 670         // 2 SLOW STRONG PULSE
 671         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 672
 673         // 3 CANDLE (first variety)
 674         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 675
 676         // 4 FAST STROBE
 677         lightstyle(4, "mamamamamama");
 678
 679         // 5 GENTLE PULSE 1
 680         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 681
 682         // 6 FLICKER (second variety)
 683         lightstyle(6, "nmonqnmomnmomomno");
 684
 685         // 7 CANDLE (second variety)
 686         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 687
 688         // 8 CANDLE (third variety)
 689         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 690
 691         // 9 SLOW STROBE (fourth variety)
 692         lightstyle(9, "aaaaaaaazzzzzzzz");
 693
 694         // 10 FLUORESCENT FLICKER
 695         lightstyle(10, "mmamammmmammamamaaamammma");
 696
 697         // 11 SLOW PULSE NOT FADE TO BLACK
 698         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 699
 700         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 701
 702         // 63 testing
 703         lightstyle(63, "a");
 704
 705         if(autocvar_g_campaign)
 706                 CampaignPreInit();
 707
 708         Map_MarkAsRecent(mapname);
 709
 710         precache_model ("null"); // we need this one before InitGameplayMode
 711         InitGameplayMode();
 712         readlevelcvars();
 713         GrappleHookInit();
 714         ElectroInit();
 715         LaserInit();
 716
 717         player_count = 0;
 718         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 719         if(bot_waypoints_for_items == 1)
 720                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 721                         bot_waypoints_for_items = 0;
 722
 723         precache();
 724
 725         WaypointSprite_Init();
 726
 727         //if (g_domination)
 728         //      dom_init();
 729
 730         GameLogInit(); // prepare everything
 731         // NOTE for matchid:
 732         // changing the logic generating it is okay. But:
 733         // it HAS to stay <= 64 chars
 734         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 735         if(autocvar_sv_eventlog)
 736         {
 737                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 738                 matchid = strzone(s);
 739
 740                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 741                 s = ":gameinfo:mutators:LIST";
 742
 743                 ret_string = s;
 744                 MUTATOR_CALLHOOK(BuildMutatorsString);
 745                 s = ret_string;
 746
 747                 // simple, probably not good in the mutator system
 748                 if(autocvar_g_grappling_hook)
 749                         s = strcat(s, ":grappling_hook");
 750
 751                 // initialiation stuff, not good in the mutator system
 752                 if(!autocvar_g_use_ammunition)
 753                         s = strcat(s, ":no_use_ammunition");
 754
 755                 // initialiation stuff, not good in the mutator system
 756                 if(autocvar_g_pickup_items == 0)
 757                         s = strcat(s, ":no_pickup_items");
 758                 if(autocvar_g_pickup_items > 0)
 759                         s = strcat(s, ":pickup_items");
 760
 761                 // initialiation stuff, not good in the mutator system
 762                 if(autocvar_g_weaponarena != "0")
 763                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 764
 765                 // TODO to mutator system
 766                 if(autocvar_g_norecoil)
 767                         s = strcat(s, ":norecoil");
 768
 769                 // TODO to mutator system
 770                 if(autocvar_g_midair)
 771                         s = strcat(s, ":midair");
 772
 773                 // TODO to mutator system
 774                 if(autocvar_g_minstagib)
 775                         s = strcat(s, ":minstagib");
 776
 777                 // TODO to mutator system
 778                 if(autocvar_g_powerups == 0)
 779                         s = strcat(s, ":no_powerups");
 780                 if(autocvar_g_powerups > 0)
 781                         s = strcat(s, ":powerups");
 782
 783                 GameLogEcho(s);
 784                 GameLogEcho(":gameinfo:end");
 785         }
 786         else
 787                 matchid = strzone(ftos(random()));
 788
 789         cvar_set("nextmap", "");
 790
 791         SetDefaultAlpha();
 792
 793         if(autocvar_g_campaign)
 794                 CampaignPostInit();
 795
 796         fteqcc_testbugs();
 797
 798         Ban_LoadBans();
 799
 800         MapInfo_Enumerate();
 801         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 802
 803         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 804         {
 805                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 806                 if(fd != -1)
 807                 {
 808                         while((s = fgets(fd)))
 809                         {
 810                                 l = tokenize_console(s);
 811                                 if(l < 2)
 812                                         continue;
 813                                 if(argv(0) == "cd")
 814                                 {
 815                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 816                                         print("  cdtrack ", argv(2), "\n");
 817                                 }
 818                                 else if(argv(0) == "fog")
 819                                 {
 820                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 821                                         print("  \"fog\" \"", s, "\"\n");
 822                                 }
 823                                 else if(argv(0) == "set")
 824                                 {
 825                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 826                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 827                                 }
 828                                 else if(argv(0) != "//")
 829                                 {
 830                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 831                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 832                                 }
 833                         }
 834                         fclose(fd);
 835                 }
 836         }
 837
 838         WeaponStats_Init();
 839
 840         addstat(STAT_WEAPONS, AS_INT, weapons);
 841         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 842         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 843         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 844         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 845         Nagger_Init();
 846
 847         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 848         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 849         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 850         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 851         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 852         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 853         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 854         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 855         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 856         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 857         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 858         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 859
 860         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 861         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 862
 863         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 864
 865         if(g_ca || g_freezetag)
 866         {
 867                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 868                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 869                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 870                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 871         }
 872         if(g_freezetag)
 873         {
 874                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 875                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 876         }
 877
 878         // g_movementspeed hack
 879         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 880         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 881         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 882         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 883
 884         // secrets
 885         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 886         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 887
 888         next_pingtime = time + 5;
 889
 890         detect_maptype();
 891
 892         lsmaps_reply = "^7Maps available: ";
 893         lsnewmaps_reply = "^7Maps without a record set: ";
 894         for(i = 0, j = 0; i < MapInfo_count; ++i)
 895         {
 896                 if(MapInfo_Get_ByID(i))
 897                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 898                         {
 899                                 if(mod(i, 2))
 900                                         col = "^2";
 901                                 else
 902                                         col = "^3";
 903                                 ++j;
 904                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 905                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 906                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 907                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 908                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 909                         }
 910         }
 911         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 912         if (!g_race && !g_cts)
 913                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 914         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 915
 916         maplist_reply = "^7Maps in list: ";
 917         n = tokenize_console(autocvar_g_maplist);
 918         for(i = 0, j = 0; i < n; ++i)
 919         {
 920                 if(MapInfo_CheckMap(argv(i)))
 921                 {
 922                         if(mod(j, 2))
 923                                 col = "^2";
 924                         else
 925                                 col = "^3";
 926                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 927                         ++j;
 928                 }
 929         }
 930         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 931         MapInfo_ClearTemps();
 932
 933         for(i = 0; i < 10; ++i)
 934         {
 935                 records_reply[i] = strzone(getrecords(i));
 936         }
 937         if(g_cts)
 938                 ladder_reply = strzone(getladder());
 939
 940         rankings_reply = strzone(getrankings());
 941
 942         ClientInit_Spawn();
 943         RandomSeed_Spawn();
 944         PingPLReport_Spawn();
 945
 946         CheatInit();
 947
 948         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 949
 950         // fill sv_curl_serverpackages from .serverpackage files
 951         if(autocvar_sv_curl_serverpackages_auto)
 952         {
 953                 s = "";
 954                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 955                 for(i = 0; i < n; ++i)
 956                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 957                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 958                                 s = strcat(s, " ", argv(i));
 959                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 960                 if(fd >= 0)
 961                 {
 962                         j = search_getsize(fd);
 963                         for(i = 0; i < j; ++i)
 964                                 s = strcat(s, " ", search_getfilename(fd, i));
 965                         search_end(fd);
 966                 }
 967                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 968                 if(fd >= 0)
 969                 {
 970                         j = search_getsize(fd);
 971                         for(i = 0; i < j; ++i)
 972                                 s = strcat(s, " ", search_getfilename(fd, i));
 973                         search_end(fd);
 974                 }
 975                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 976         }
 977
 978         PlayerStats_Init();
 979
 980         world_initialized = 1;
 981 }
 982
 983 void spawnfunc_light (void)
 984 {
 985         //makestatic (self); // Who the f___ did that?
 986         remove(self);
 987 }
 988
 989 string GetGametype()
 990 {
 991         return GametypeNameFromType(game);
 992 }
 993
 994 string getmapname_stored;
 995 string GetMapname()
 996 {
 997         return mapname;
 998 }
 999
1000 float Map_Count, Map_Current;
1001 string Map_Current_Name;
1002
1003 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
1004 float GetMaplistPosition()
1005 {
1006         float pos, idx;
1007         string map;
1008
1009         map = GetMapname();
1010         idx = autocvar_g_maplist_index;
1011
1012         if(idx >= 0)
1013                 if(idx < Map_Count)
1014                         if(map == argv(idx))
1015                                 return idx;
1016
1017         for(pos = 0; pos < Map_Count; ++pos)
1018                 if(map == argv(pos))
1019                         return pos;
1020
1021         // resume normal maplist rotation if current map is not in g_maplist
1022         return idx;
1023 }
1024
1025 float MapHasRightSize(string map)
1026 {
1027         float fh;
1028         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1029         if(autocvar_g_maplist_check_waypoints)
1030         {
1031                 dprint("checkwp "); dprint(map);
1032                 if(!fexists(strcat("maps/", map, ".waypoints")))
1033                 {
1034                         dprint(": no waypoints\n");
1035                         return FALSE;
1036                 }
1037                 dprint(": has waypoints\n");
1038         }
1039
1040         // open map size restriction file
1041         dprint("opensize "); dprint(map);
1042         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1043         if(fh >= 0)
1044         {
1045                 float mapmin, mapmax;
1046                 dprint(": ok, ");
1047                 mapmin = stof(fgets(fh));
1048                 mapmax = stof(fgets(fh));
1049                 fclose(fh);
1050                 if(player_count < mapmin)
1051                 {
1052                         dprint("not enough\n");
1053                         return FALSE;
1054                 }
1055                 if(player_count > mapmax)
1056                 {
1057                         dprint("too many\n");
1058                         return FALSE;
1059                 }
1060                 dprint("right size\n");
1061                 return TRUE;
1062         }
1063         dprint(": not found\n");
1064         return TRUE;
1065 }
1066
1067 string Map_Filename(float position)
1068 {
1069         return strcat("maps/", argv(position), ".bsp");
1070 }
1071
1072 string strwords(string s, float w)
1073 {
1074         float endpos;
1075         for(endpos = 0; w && endpos >= 0; --w)
1076                 endpos = strstrofs(s, " ", endpos + 1);
1077         if(endpos < 0)
1078                 return s;
1079         else
1080                 return substring(s, 0, endpos);
1081 }
1082
1083 float strhasword(string s, string w)
1084 {
1085         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1086 }
1087
1088 void Map_MarkAsRecent(string m)
1089 {
1090         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1091 }
1092
1093 float Map_IsRecent(string m)
1094 {
1095         return strhasword(autocvar_g_maplist_mostrecent, m);
1096 }
1097
1098 float Map_Check(float position, float pass)
1099 {
1100         string filename;
1101         string map_next;
1102         map_next = argv(position);
1103         if(pass <= 1)
1104         {
1105                 if(Map_IsRecent(map_next))
1106                         return 0;
1107         }
1108         filename = Map_Filename(position);
1109         if(MapInfo_CheckMap(map_next))
1110         {
1111                 if(pass == 2)
1112                         return 1;
1113                 if(MapHasRightSize(map_next))
1114                         return 1;
1115                 return 0;
1116         }
1117         else
1118                 dprint( "Couldn't select '", filename, "'..\n" );
1119
1120         return 0;
1121 }
1122
1123 void Map_Goto_SetStr(string nextmapname)
1124 {
1125         if(getmapname_stored != "")
1126                 strunzone(getmapname_stored);
1127         if(nextmapname == "")
1128                 getmapname_stored = "";
1129         else
1130                 getmapname_stored = strzone(nextmapname);
1131 }
1132
1133 void Map_Goto_SetFloat(float position)
1134 {
1135         cvar_set("g_maplist_index", ftos(position));
1136         Map_Goto_SetStr(argv(position));
1137 }
1138
1139 void Map_Goto(float reinit)
1140 {
1141         MapInfo_LoadMap(getmapname_stored, reinit);
1142 }
1143
1144 // return codes of map selectors:
1145 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1146 //   -2 = permanent failure
1147 float() MaplistMethod_Iterate = // usual method
1148 {
1149         float pass, i;
1150
1151         for(pass = 1; pass <= 2; ++pass)
1152         {
1153                 for(i = 1; i < Map_Count; ++i)
1154                 {
1155                         float mapindex;
1156                         mapindex = mod(i + Map_Current, Map_Count);
1157                         if(Map_Check(mapindex, pass))
1158                                 return mapindex;
1159                 }
1160         }
1161         return -1;
1162 }
1163
1164 float() MaplistMethod_Repeat = // fallback method
1165 {
1166         if(Map_Check(Map_Current, 2))
1167                 return Map_Current;
1168         return -2;
1169 }
1170
1171 float() MaplistMethod_Random = // random map selection
1172 {
1173         float i, imax;
1174
1175         imax = 42;
1176
1177         for(i = 0; i <= imax; ++i)
1178         {
1179                 float mapindex;
1180                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1181                 if(Map_Check(mapindex, 1))
1182                         return mapindex;
1183         }
1184         return -1;
1185 }
1186
1187 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1188 // the exponent sets a bias on the map selection:
1189 // the higher the exponent, the less likely "shortly repeated" same maps are
1190 {
1191         float i, j, imax, insertpos;
1192
1193         imax = 42;
1194
1195         for(i = 0; i <= imax; ++i)
1196         {
1197                 string newlist;
1198
1199                 // now reinsert this at another position
1200                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1201                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1202                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1203                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1204
1205                 // insert the current map there
1206                 newlist = "";
1207                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1208                         newlist = strcat(newlist, " ", argv(j));
1209                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1210                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1211                         newlist = strcat(newlist, " ", argv(j));
1212                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1213                 cvar_set("g_maplist", newlist);
1214                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1215
1216                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1217                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1218                 if(Map_Check(Map_Current, 1))
1219                         return Map_Current;
1220         }
1221         return -1;
1222 }
1223
1224 void Maplist_Init()
1225 {
1226         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1227         if(Map_Count == 0)
1228         {
1229                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1230                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1231                 if(autocvar_g_maplist_shuffle)
1232                         ShuffleMaplist();
1233                 localcmd("\nmenu_cmd sync\n");
1234                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1235         }
1236         if(Map_Count == 0)
1237                 error("empty maplist, cannot select a new map");
1238         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1239
1240         if(Map_Current_Name)
1241                 strunzone(Map_Current_Name);
1242         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1243         // this may or may not be correct, but who cares, in the worst case a map
1244         // isn't chosen in the first pass that should have been
1245 }
1246
1247 string GetNextMap()
1248 {
1249         float nextMap;
1250
1251         Maplist_Init();
1252         nextMap = -1;
1253
1254         if(nextMap == -1)
1255                 if(autocvar_g_maplist_shuffle > 0)
1256                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1257
1258         if(nextMap == -1)
1259                 if(autocvar_g_maplist_selectrandom)
1260                         nextMap = MaplistMethod_Random();
1261
1262         if(nextMap == -1)
1263                 nextMap = MaplistMethod_Iterate();
1264
1265         if(nextMap == -1)
1266                 nextMap = MaplistMethod_Repeat();
1267
1268         if(nextMap >= 0)
1269         {
1270                 Map_Goto_SetFloat(nextMap);
1271                 return getmapname_stored;
1272         }
1273
1274         return "";
1275 }
1276
1277 float DoNextMapOverride(float reinit)
1278 {
1279         if(autocvar_g_campaign)
1280         {
1281                 CampaignPostIntermission();
1282                 alreadychangedlevel = TRUE;
1283                 return TRUE;
1284         }
1285         if(autocvar_quit_when_empty)
1286         {
1287                 if(player_count <= currentbots)
1288                 {
1289                         localcmd("quit\n");
1290                         alreadychangedlevel = TRUE;
1291                         return TRUE;
1292                 }
1293         }
1294         if(autocvar_quit_and_redirect != "")
1295         {
1296                 redirection_target = strzone(autocvar_quit_and_redirect);
1297                 alreadychangedlevel = TRUE;
1298                 return TRUE;
1299         }
1300         if (autocvar_samelevel) // if samelevel is set, stay on same level
1301         {
1302                 localcmd("restart\n");
1303                 alreadychangedlevel = TRUE;
1304                 return TRUE;
1305         }
1306         if(autocvar_nextmap != "")
1307                 if(MapInfo_CheckMap(autocvar_nextmap))
1308                 {
1309                         Map_Goto_SetStr(autocvar_nextmap);
1310                         Map_Goto(reinit);
1311                         alreadychangedlevel = TRUE;
1312                         return TRUE;
1313                 }
1314         if(autocvar_lastlevel)
1315         {
1316                 cvar_settemp_restore();
1317                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1318                 alreadychangedlevel = TRUE;
1319                 return TRUE;
1320         }
1321         return FALSE;
1322 }
1323
1324 void GotoNextMap(float reinit)
1325 {
1326         //string nextmap;
1327         //float n, nummaps;
1328         //string s;
1329         if (alreadychangedlevel)
1330                 return;
1331         alreadychangedlevel = TRUE;
1332
1333         {
1334                 string nextMap;
1335                 float allowReset;
1336
1337                 for(allowReset = 1; allowReset >= 0; --allowReset)
1338                 {
1339                         nextMap = GetNextMap();
1340                         if(nextMap != "")
1341                                 break;
1342
1343                         if(allowReset)
1344                         {
1345                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1346                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1347                                 if(autocvar_g_maplist_shuffle)
1348                                         ShuffleMaplist();
1349                                 localcmd("\nmenu_cmd sync\n");
1350                         }
1351                         else
1352                         {
1353                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1354                         }
1355                 }
1356                 Map_Goto(reinit);
1357         }
1358 }
1359
1360
1361 /*
1362 ============
1363 IntermissionThink
1364
1365 When the player presses attack or jump, change to the next level
1366 ============
1367 */
1368 .float autoscreenshot;
1369 void() MapVote_Start;
1370 void() MapVote_Think;
1371 float mapvote_initialized;
1372 void IntermissionThink()
1373 {
1374         FixIntermissionClient(self);
1375
1376         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1377                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1378         {
1379                 self.autoscreenshot = -1;
1380                 if(clienttype(self) == CLIENTTYPE_REAL)
1381                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1382                 return;
1383         }
1384
1385         if (time < intermission_exittime)
1386                 return;
1387
1388         if(!mapvote_initialized)
1389                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1390                         return;
1391
1392         MapVote_Start();
1393 }
1394
1395 /*
1396 ============
1397 FindIntermission
1398
1399 Returns the entity to view from
1400 ============
1401 */
1402 /*
1403 entity FindIntermission()
1404 {
1405         local   entity spot;
1406         local   float cyc;
1407
1408 // look for info_intermission first
1409         spot = find (world, classname, "info_intermission");
1410         if (spot)
1411         {       // pick a random one
1412                 cyc = random() * 4;
1413                 while (cyc > 1)
1414                 {
1415                         spot = find (spot, classname, "info_intermission");
1416                         if (!spot)
1417                                 spot = find (spot, classname, "info_intermission");
1418                         cyc = cyc - 1;
1419                 }
1420                 return spot;
1421         }
1422
1423 // then look for the start position
1424         spot = find (world, classname, "info_player_start");
1425         if (spot)
1426                 return spot;
1427
1428 // testinfo_player_start is only found in regioned levels
1429         spot = find (world, classname, "testplayerstart");
1430         if (spot)
1431                 return spot;
1432
1433 // then look for the start position
1434         spot = find (world, classname, "info_player_deathmatch");
1435         if (spot)
1436                 return spot;
1437
1438         //objerror ("FindIntermission: no spot");
1439         return world;
1440 }
1441 */
1442
1443 /*
1444 ===============================================================================
1445
1446 RULES
1447
1448 ===============================================================================
1449 */
1450
1451 void DumpStats(float final)
1452 {
1453         float file;
1454         string s;
1455         float to_console;
1456         float to_eventlog;
1457         float to_file;
1458         float i;
1459
1460         to_console = autocvar_sv_logscores_console;
1461         to_eventlog = autocvar_sv_eventlog;
1462         to_file = autocvar_sv_logscores_file;
1463
1464         if(!final)
1465         {
1466                 to_console = TRUE; // always print printstats replies
1467                 to_eventlog = FALSE; // but never print them to the event log
1468         }
1469
1470         if(to_eventlog)
1471                 if(autocvar_sv_eventlog_console)
1472                         to_console = FALSE; // otherwise we get the output twice
1473
1474         if(final)
1475                 s = ":scores:";
1476         else
1477                 s = ":status:";
1478         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1479
1480         if(to_console)
1481                 print(s, "\n");
1482         if(to_eventlog)
1483                 GameLogEcho(s);
1484         if(to_file)
1485         {
1486                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1487                 if(file == -1)
1488                         to_file = FALSE;
1489                 else
1490                         fputs(file, strcat(s, "\n"));
1491         }
1492
1493         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1494         if(to_console)
1495                 print(s, "\n");
1496         if(to_eventlog)
1497                 GameLogEcho(s);
1498         if(to_file)
1499                 fputs(file, strcat(s, "\n"));
1500
1501         FOR_EACH_CLIENT(other)
1502         {
1503                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1504                 {
1505                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1506                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1507                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1508                                 s = strcat(s, ftos(other.team), ":");
1509                         else
1510                                 s = strcat(s, "spectator:");
1511
1512                         if(to_console)
1513                                 print(s, other.netname, "\n");
1514                         if(to_eventlog)
1515                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1516                         if(to_file)
1517                                 fputs(file, strcat(s, other.netname, "\n"));
1518                 }
1519         }
1520
1521         if(teamplay)
1522         {
1523                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1524                 if(to_console)
1525                         print(s, "\n");
1526                 if(to_eventlog)
1527                         GameLogEcho(s);
1528                 if(to_file)
1529                         fputs(file, strcat(s, "\n"));
1530
1531                 for(i = 1; i < 16; ++i)
1532                 {
1533                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1534                         s = strcat(s, ":", ftos(i));
1535                         if(to_console)
1536                                 print(s, "\n");
1537                         if(to_eventlog)
1538                                 GameLogEcho(s);
1539                         if(to_file)
1540                                 fputs(file, strcat(s, "\n"));
1541                 }
1542         }
1543
1544         if(to_console)
1545                 print(":end\n");
1546         if(to_eventlog)
1547                 GameLogEcho(":end");
1548         if(to_file)
1549         {
1550                 fputs(file, ":end\n");
1551                 fclose(file);
1552         }
1553 }
1554
1555 void FixIntermissionClient(entity e)
1556 {
1557         string s;
1558         if(!e.autoscreenshot) // initial call
1559         {
1560                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1561                 e.health = -2342;
1562                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1563                 e.solid = SOLID_NOT;
1564                 e.movetype = MOVETYPE_NONE;
1565                 e.takedamage = DAMAGE_NO;
1566                 if(e.weaponentity)
1567                 {
1568                         e.weaponentity.effects = EF_NODRAW;
1569                         if (e.weaponentity.weaponentity)
1570                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1571                 }
1572                 if(clienttype(e) == CLIENTTYPE_REAL)
1573                 {
1574                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1575                         s = autocvar_sv_intermission_cdtrack;
1576                         if(s != "")
1577                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1578                         msg_entity = e;
1579                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1580                 }
1581         }
1582 }
1583
1584
1585 /*
1586 go to the next level for deathmatch
1587 only called if a time or frag limit has expired
1588 */
1589 void NextLevel()
1590 {
1591         gameover = TRUE;
1592
1593         intermission_running = 1;
1594
1595 // enforce a wait time before allowing changelevel
1596         if(player_count > 0)
1597                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1598         else
1599                 intermission_exittime = -1;
1600
1601         /*
1602         WriteByte (MSG_ALL, SVC_CDTRACK);
1603         WriteByte (MSG_ALL, 3);
1604         WriteByte (MSG_ALL, 3);
1605         // done in FixIntermission
1606         */
1607
1608         //pos = FindIntermission ();
1609
1610         VoteReset();
1611
1612         DumpStats(TRUE);
1613
1614         // send statistics
1615         entity e;
1616         PlayerStats_EndMatch(1);
1617         FOR_EACH_CLIENT(e)
1618                 PlayerStats_AddGlobalInfo(e);
1619         PlayerStats_Shutdown();
1620         WeaponStats_Shutdown();
1621
1622         if(autocvar_sv_eventlog)
1623                 GameLogEcho(":gameover");
1624
1625         GameLogClose();
1626
1627         FOR_EACH_PLAYER(other) {
1628                 FixIntermissionClient(other);
1629                 if(other.winning)
1630                         bprint(other.netname, " ^7wins.\n");
1631         }
1632
1633         if(autocvar_g_campaign)
1634                 CampaignPreIntermission();
1635
1636         localcmd("\nsv_hook_gameend\n");
1637 }
1638
1639 /*
1640 ============
1641 CheckRules_Player
1642
1643 Exit deathmatch games upon conditions
1644 ============
1645 */
1646 void CheckRules_Player()
1647 {
1648         if (gameover)   // someone else quit the game already
1649                 return;
1650
1651         if(self.deadflag == DEAD_NO)
1652                 self.play_time += frametime;
1653
1654         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1655         //   (div0: and that in CheckRules_World please)
1656 }
1657
1658 float checkrules_equality;
1659 float checkrules_suddendeathwarning;
1660 float checkrules_suddendeathend;
1661 float checkrules_overtimesadded; //how many overtimes have been already added
1662
1663 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1664 float WINNING_YES = 1; // winner found
1665 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1666 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1667
1668 float InitiateSuddenDeath()
1669 {
1670         // Check first whether normal overtimes could be added before initiating suddendeath mode
1671         // - for this timelimit_overtime needs to be >0 of course
1672         // - also check the winning condition calculated in the previous frame and only add normal overtime
1673         //   again, if at the point at which timelimit would be extended again, still no winner was found
1674         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1675         {
1676                 return 1; // need to call InitiateOvertime later
1677         }
1678         else
1679         {
1680                 if(!checkrules_suddendeathend)
1681                 {
1682                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1683                         if(g_race && !g_race_qualifying)
1684                                 race_StartCompleting();
1685                 }
1686                 return 0;
1687         }
1688 }
1689
1690 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1691 {
1692         ++checkrules_overtimesadded;
1693         //add one more overtime by simply extending the timelimit
1694         float tl;
1695         tl = autocvar_timelimit;
1696         tl += autocvar_timelimit_overtime;
1697         cvar_set("timelimit", ftos(tl));
1698         string minutesPlural;
1699         if (autocvar_timelimit_overtime == 1)
1700                 minutesPlural = " ^3minute";
1701         else
1702                 minutesPlural = " ^3minutes";
1703
1704         bcenterprint(
1705                 strcat(
1706                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1707                         ftos(autocvar_timelimit_overtime),
1708                         minutesPlural,
1709                         " to the game!"
1710                 )
1711         );
1712 }
1713
1714 float GetWinningCode(float fraglimitreached, float equality)
1715 {
1716         if(autocvar_g_campaign == 1)
1717                 if(fraglimitreached)
1718                         return WINNING_YES;
1719                 else
1720                         return WINNING_NO;
1721
1722         else
1723                 if(equality)
1724                         if(fraglimitreached)
1725                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1726                         else
1727                                 return WINNING_NEVER;
1728                 else
1729                         if(fraglimitreached)
1730                                 return WINNING_YES;
1731                         else
1732                                 return WINNING_NO;
1733 }
1734
1735 // set the .winning flag for exactly those players with a given field value
1736 void SetWinners(.float field, float value)
1737 {
1738         entity head;
1739         FOR_EACH_PLAYER(head)
1740                 head.winning = (head.field == value);
1741 }
1742
1743 // set the .winning flag for those players with a given field value
1744 void AddWinners(.float field, float value)
1745 {
1746         entity head;
1747         FOR_EACH_PLAYER(head)
1748                 if(head.field == value)
1749                         head.winning = 1;
1750 }
1751
1752 // clear the .winning flags
1753 void ClearWinners(void)
1754 {
1755         entity head;
1756         FOR_EACH_PLAYER(head)
1757                 head.winning = 0;
1758 }
1759
1760 // Onslaught winning condition:
1761 // game terminates if only one team has a working generator (or none)
1762 float WinningCondition_Onslaught()
1763 {
1764         entity head;
1765         float t1, t2, t3, t4;
1766
1767         WinningConditionHelper(); // set worldstatus
1768
1769         if(inWarmupStage)
1770                 return WINNING_NO;
1771
1772         // first check if the game has ended
1773         t1 = t2 = t3 = t4 = 0;
1774         head = find(world, classname, "onslaught_generator");
1775         while (head)
1776         {
1777                 if (head.health > 0)
1778                 {
1779                         if (head.team == COLOR_TEAM1) t1 = 1;
1780                         if (head.team == COLOR_TEAM2) t2 = 1;
1781                         if (head.team == COLOR_TEAM3) t3 = 1;
1782                         if (head.team == COLOR_TEAM4) t4 = 1;
1783                 }
1784                 head = find(head, classname, "onslaught_generator");
1785         }
1786         if (t1 + t2 + t3 + t4 < 2)
1787         {
1788                 // game over, only one team remains (or none)
1789                 ClearWinners();
1790                 if (t1) SetWinners(team, COLOR_TEAM1);
1791                 if (t2) SetWinners(team, COLOR_TEAM2);
1792                 if (t3) SetWinners(team, COLOR_TEAM3);
1793                 if (t4) SetWinners(team, COLOR_TEAM4);
1794                 dprint("Have a winner, ending game.\n");
1795                 return WINNING_YES;
1796         }
1797
1798         // Two or more teams remain
1799         return WINNING_NO;
1800 }
1801
1802 float LMS_NewPlayerLives()
1803 {
1804         float fl;
1805         fl = autocvar_fraglimit;
1806         if(fl == 0)
1807                 fl = 999;
1808
1809         // first player has left the game for dying too much? Nobody else can get in.
1810         if(lms_lowest_lives < 1)
1811                 return 0;
1812
1813         if(!autocvar_g_lms_join_anytime)
1814                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1815                         return 0;
1816
1817         return bound(1, lms_lowest_lives, fl);
1818 }
1819
1820 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1821 // they win. Otherwise the defending team wins once the timelimit passes.
1822 void assault_new_round();
1823 float WinningCondition_Assault()
1824 {
1825         float status;
1826
1827         WinningConditionHelper(); // set worldstatus
1828
1829         status = WINNING_NO;
1830         // as the timelimit has not yet passed just assume the defending team will win
1831         if(assault_attacker_team == COLOR_TEAM1)
1832         {
1833                 SetWinners(team, COLOR_TEAM2);
1834         }
1835         else
1836         {
1837                 SetWinners(team, COLOR_TEAM1);
1838         }
1839
1840         entity ent;
1841         ent = find(world, classname, "target_assault_roundend");
1842         if(ent)
1843         {
1844                 if(ent.winning) // round end has been triggered by attacking team
1845                 {
1846                         bprint("ASSAULT: round completed...\n");
1847                         SetWinners(team, assault_attacker_team);
1848
1849                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1850
1851                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1852                         {
1853                                 status = WINNING_YES;
1854                         }
1855                         else
1856                         {
1857                                 entity oldself;
1858                                 oldself = self;
1859                                 self = ent;
1860                                 assault_new_round();
1861                                 self = oldself;
1862                         }
1863                 }
1864         }
1865
1866         return status;
1867 }
1868
1869 // LMS winning condition: game terminates if and only if there's at most one
1870 // one player who's living lives. Top two scores being equal cancels the time
1871 // limit.
1872 float WinningCondition_LMS()
1873 {
1874         entity head, head2;
1875         float have_player;
1876         float have_players;
1877         float l;
1878
1879         have_player = FALSE;
1880         have_players = FALSE;
1881         l = LMS_NewPlayerLives();
1882
1883         head = find(world, classname, "player");
1884         if(head)
1885                 have_player = TRUE;
1886         head2 = find(head, classname, "player");
1887         if(head2)
1888                 have_players = TRUE;
1889
1890         if(have_player)
1891         {
1892                 // we have at least one player
1893                 if(have_players)
1894                 {
1895                         // two or more active players - continue with the game
1896                 }
1897                 else
1898                 {
1899                         // exactly one player?
1900
1901                         ClearWinners();
1902                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1903
1904                         if(l)
1905                         {
1906                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1907                                 return WINNING_NO;
1908                         }
1909                         else
1910                         {
1911                                 // a winner!
1912                                 // and assign him his first place
1913                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1914                                 return WINNING_YES;
1915                         }
1916                 }
1917         }
1918         else
1919         {
1920                 // nobody is playing at all...
1921                 if(l)
1922                 {
1923                         // wait for players...
1924                 }
1925                 else
1926                 {
1927                         // SNAFU (maybe a draw game?)
1928                         ClearWinners();
1929                         dprint("No players, ending game.\n");
1930                         return WINNING_YES;
1931                 }
1932         }
1933
1934         // When we get here, we have at least two players who are actually LIVING,
1935         // now check if the top two players have equal score.
1936         WinningConditionHelper();
1937
1938         ClearWinners();
1939         if(WinningConditionHelper_winner)
1940                 WinningConditionHelper_winner.winning = TRUE;
1941         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1942                 return WINNING_NEVER;
1943
1944         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1945         return WINNING_NO;
1946 }
1947
1948 void ShuffleMaplist()
1949 {
1950         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1951 }
1952
1953 float leaderfrags;
1954 float WinningCondition_Scores(float limit, float leadlimit)
1955 {
1956         float limitreached;
1957
1958         // TODO make everything use THIS winning condition (except LMS)
1959         WinningConditionHelper();
1960
1961         if(teamplay)
1962         {
1963                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1964                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1965                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1966                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1967         }
1968
1969         ClearWinners();
1970         if(WinningConditionHelper_winner)
1971                 WinningConditionHelper_winner.winning = 1;
1972         if(WinningConditionHelper_winnerteam >= 0)
1973                 SetWinners(team, WinningConditionHelper_winnerteam);
1974
1975         if(WinningConditionHelper_lowerisbetter)
1976         {
1977                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1978                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1979                 limit = -limit;
1980         }
1981
1982         if(WinningConditionHelper_zeroisworst)
1983                 leadlimit = 0; // not supported in this mode
1984
1985         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1986         // these modes always score in increments of 1, thus this makes sense
1987         {
1988                 if(leaderfrags != WinningConditionHelper_topscore)
1989                 {
1990                         leaderfrags = WinningConditionHelper_topscore;
1991
1992                         if (limit)
1993                         if (leaderfrags == limit - 1)
1994                                 Announce("1fragleft");
1995                         else if (leaderfrags == limit - 2)
1996                                 Announce("2fragsleft");
1997                         else if (leaderfrags == limit - 3)
1998                                 Announce("3fragsleft");
1999                 }
2000         }
2001
2002         limitreached = FALSE;
2003         if(limit)
2004                 if(WinningConditionHelper_topscore >= limit)
2005                         limitreached = TRUE;
2006         if(leadlimit)
2007         {
2008                 float leadlimitreached;
2009                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2010                 if(autocvar_leadlimit_and_fraglimit)
2011                         limitreached = (limitreached && leadlimitreached);
2012                 else
2013                         limitreached = (limitreached || leadlimitreached);
2014         }
2015
2016         return GetWinningCode(
2017                 WinningConditionHelper_topscore && limitreached,
2018                 WinningConditionHelper_equality
2019         );
2020 }
2021
2022 float WinningCondition_Race(float fraglimit)
2023 {
2024         float wc;
2025         entity p;
2026         float n, c;
2027
2028         n = 0;
2029         c = 0;
2030         FOR_EACH_PLAYER(p)
2031         {
2032                 ++n;
2033                 if(p.race_completed)
2034                         ++c;
2035         }
2036         if(n && (n == c))
2037                 return WINNING_YES;
2038         wc = WinningCondition_Scores(fraglimit, 0);
2039
2040         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2041         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2042         // do NOT support equality when the laps are all raced!
2043                 return WINNING_STARTSUDDENDEATHOVERTIME;
2044         else
2045                 return WINNING_NEVER;
2046         return wc;
2047 }
2048
2049 void ReadyRestart();
2050 float WinningCondition_QualifyingThenRace(float limit)
2051 {
2052         float wc;
2053         wc = WinningCondition_Scores(limit, 0);
2054
2055         // NEVER initiate overtime
2056         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2057         {
2058                 return WINNING_YES;
2059         }
2060
2061         return wc;
2062 }
2063
2064 float WinningCondition_RanOutOfSpawns()
2065 {
2066         entity head;
2067
2068         if(have_team_spawns <= 0)
2069                 return WINNING_NO;
2070
2071         if(autocvar_g_spawn_useallspawns <= 0)
2072                 return WINNING_NO;
2073
2074         if(!some_spawn_has_been_used)
2075                 return WINNING_NO;
2076
2077         team1_score = team2_score = team3_score = team4_score = 0;
2078
2079         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2080         {
2081                 if(head.team == COLOR_TEAM1)
2082                         team1_score = 1;
2083                 else if(head.team == COLOR_TEAM2)
2084                         team2_score = 1;
2085                 else if(head.team == COLOR_TEAM3)
2086                         team3_score = 1;
2087                 else if(head.team == COLOR_TEAM4)
2088                         team4_score = 1;
2089         }
2090
2091         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2092         {
2093                 if(head.team == COLOR_TEAM1)
2094                         team1_score = 1;
2095                 else if(head.team == COLOR_TEAM2)
2096                         team2_score = 1;
2097                 else if(head.team == COLOR_TEAM3)
2098                         team3_score = 1;
2099                 else if(head.team == COLOR_TEAM4)
2100                         team4_score = 1;
2101         }
2102
2103         ClearWinners();
2104         if(team1_score + team2_score + team3_score + team4_score == 0)
2105         {
2106                 checkrules_equality = TRUE;
2107                 return WINNING_YES;
2108         }
2109         else if(team1_score + team2_score + team3_score + team4_score == 1)
2110         {
2111                 float t, i;
2112                 if(team1_score) t = COLOR_TEAM1;
2113                 if(team2_score) t = COLOR_TEAM2;
2114                 if(team3_score) t = COLOR_TEAM3;
2115                 if(team4_score) t = COLOR_TEAM4;
2116                 CheckAllowedTeams(world);
2117                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2118                 {
2119                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2120                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2121                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2122                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2123                 }
2124
2125                 AddWinners(team, t);
2126                 return WINNING_YES;
2127         }
2128         else
2129                 return WINNING_NO;
2130 }
2131
2132 /*
2133 ============
2134 CheckRules_World
2135
2136 Exit deathmatch games upon conditions
2137 ============
2138 */
2139 void CheckRules_World()
2140 {
2141         float timelimit;
2142         float fraglimit;
2143         float leadlimit;
2144
2145         VoteThink();
2146         MapVote_Think();
2147
2148         SetDefaultAlpha();
2149
2150         /*
2151         MapVote_Think should now do that part
2152         if (intermission_running)
2153                 if (time >= intermission_exittime + 60)
2154                 {
2155                         if(!DoNextMapOverride())
2156                                 GotoNextMap();
2157                         return;
2158                 }
2159         */
2160
2161         if (gameover)   // someone else quit the game already
2162         {
2163                 if(player_count == 0) // Nobody there? Then let's go to the next map
2164                         MapVote_Start();
2165                         // this will actually check the player count in the next frame
2166                         // again, but this shouldn't hurt
2167                 return;
2168         }
2169
2170         timelimit = autocvar_timelimit * 60;
2171         fraglimit = autocvar_fraglimit;
2172         leadlimit = autocvar_leadlimit;
2173
2174         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2175         {
2176                 if(timelimit > 0)
2177                         timelimit = 0; // timelimit is not made for warmup
2178                 if(fraglimit > 0)
2179                         fraglimit = 0; // no fraglimit for now
2180                 leadlimit = 0; // no leadlimit for now
2181         }
2182
2183         if(g_onslaught)
2184                 timelimit = 0; // ONS has its own overtime rule
2185
2186         if(timelimit > 0)
2187         {
2188                 timelimit += game_starttime;
2189         }
2190         else if (timelimit < 0)
2191         {
2192                 // endmatch
2193                 NextLevel();
2194                 return;
2195         }
2196
2197         float wantovertime;
2198         wantovertime = 0;
2199
2200         if(checkrules_suddendeathend)
2201         {
2202                 if(!checkrules_suddendeathwarning)
2203                 {
2204                         checkrules_suddendeathwarning = TRUE;
2205                         if(g_race && !g_race_qualifying)
2206                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2207                         else
2208                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2209                 }
2210         }
2211         else
2212         {
2213                 if (timelimit && time >= timelimit)
2214                 {
2215                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2216                         {
2217                                 float totalplayers;
2218                                 float playerswithlaps;
2219                                 float readyplayers;
2220                                 entity head;
2221                                 totalplayers = playerswithlaps = readyplayers = 0;
2222                                 FOR_EACH_PLAYER(head)
2223                                 {
2224                                         ++totalplayers;
2225                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2226                                                 ++playerswithlaps;
2227                                         if(head.ready)
2228                                                 ++readyplayers;
2229                                 }
2230
2231                                 // at least 2 of the players have completed a lap: start the RACE
2232                                 // otherwise, the players should end the qualifying on their own
2233                                 if(readyplayers || playerswithlaps >= 2)
2234                                 {
2235                                         checkrules_suddendeathend = 0;
2236                                         ReadyRestart(); // go to race
2237                                         return;
2238                                 }
2239                                 else
2240                                         wantovertime |= InitiateSuddenDeath();
2241                         }
2242                         else
2243                                 wantovertime |= InitiateSuddenDeath();
2244                 }
2245         }
2246
2247         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2248         {
2249                 NextLevel();
2250                 return;
2251         }
2252
2253         float checkrules_status;
2254         checkrules_status = WinningCondition_RanOutOfSpawns();
2255         if(checkrules_status == WINNING_YES)
2256         {
2257                 bprint("Hey! Someone ran out of spawns!\n");
2258         }
2259         else if(g_race && !g_race_qualifying && timelimit >= 0)
2260         {
2261                 checkrules_status = WinningCondition_Race(fraglimit);
2262                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2263         }
2264         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2265         {
2266                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2267                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2268         }
2269         else if(g_assault)
2270         {
2271                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2272         }
2273         else if(g_lms)
2274         {
2275                 checkrules_status = WinningCondition_LMS();
2276         }
2277         else if (g_onslaught)
2278         {
2279                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2280         }
2281         else
2282         {
2283                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2284                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2285         }
2286
2287         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2288         {
2289                 checkrules_status = WINNING_NEVER;
2290                 checkrules_overtimesadded = -1;
2291                 wantovertime |= InitiateSuddenDeath();
2292         }
2293
2294         if(checkrules_status == WINNING_NEVER)
2295                 // equality cases! Nobody wins if the overtime ends in a draw.
2296                 ClearWinners();
2297
2298         if(wantovertime)
2299         {
2300                 if(checkrules_status == WINNING_NEVER)
2301                         InitiateOvertime();
2302                 else
2303                         checkrules_status = WINNING_YES;
2304         }
2305
2306         if(checkrules_suddendeathend)
2307                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2308                         checkrules_status = WINNING_YES;
2309
2310         if(checkrules_status == WINNING_YES)
2311         {
2312                 //print("WINNING\n");
2313                 NextLevel();
2314         }
2315 }
2316
2317 float mapvote_nextthink;
2318 float mapvote_initialized;
2319 float mapvote_keeptwotime;
2320 float mapvote_timeout;
2321 string mapvote_message;
2322 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2323 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2324 float mapvote_screenshot_dirs_count;
2325
2326 float mapvote_count;
2327 float mapvote_count_real;
2328 string mapvote_maps[MAPVOTE_COUNT];
2329 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2330 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2331 float mapvote_maps_suggested[MAPVOTE_COUNT];
2332 string mapvote_suggestions[MAPVOTE_COUNT];
2333 float mapvote_suggestion_ptr;
2334 float mapvote_voters;
2335 float mapvote_votes[MAPVOTE_COUNT];
2336 float mapvote_run;
2337 float mapvote_detail;
2338 float mapvote_abstain;
2339 .float mapvote;
2340
2341 void MapVote_ClearAllVotes()
2342 {
2343         FOR_EACH_CLIENT(other)
2344                 other.mapvote = 0;
2345 }
2346
2347 string MapVote_Suggest(string m)
2348 {
2349         float i;
2350         if(m == "")
2351                 return "That's not how to use this command.";
2352         if(!autocvar_g_maplist_votable_suggestions)
2353                 return "Suggestions are not accepted on this server.";
2354         if(mapvote_initialized)
2355                 return "Can't suggest - voting is already in progress!";
2356         m = MapInfo_FixName(m);
2357         if(!m)
2358                 return "The map you suggested is not available on this server.";
2359         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2360                 if(Map_IsRecent(m))
2361                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2362
2363         if(!MapInfo_CheckMap(m))
2364                 return "The map you suggested does not support the current game mode.";
2365         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2366                 if(mapvote_suggestions[i] == m)
2367                         return "This map was already suggested.";
2368         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2369         {
2370                 i = floor(random() * mapvote_suggestion_ptr);
2371         }
2372         else
2373         {
2374                 i = mapvote_suggestion_ptr;
2375                 mapvote_suggestion_ptr += 1;
2376         }
2377         if(mapvote_suggestions[i] != "")
2378                 strunzone(mapvote_suggestions[i]);
2379         mapvote_suggestions[i] = strzone(m);
2380         if(autocvar_sv_eventlog)
2381                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2382         return strcat("Suggestion of ", m, " accepted.");
2383 }
2384
2385 void MapVote_AddVotable(string nextMap, float isSuggestion)
2386 {
2387         float j, i, o;
2388         string pakfile, mapfile;
2389
2390         if(nextMap == "")
2391                 return;
2392         for(j = 0; j < mapvote_count; ++j)
2393                 if(mapvote_maps[j] == nextMap)
2394                         return;
2395         // suggestions might be no longer valid/allowed after gametype switch!
2396         if(isSuggestion)
2397                 if(!MapInfo_CheckMap(nextMap))
2398                         return;
2399         mapvote_maps[mapvote_count] = strzone(nextMap);
2400         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2401
2402         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2403         {
2404                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2405                 pakfile = whichpack(strcat(mapfile, ".tga"));
2406                 if(pakfile == "")
2407                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2408                 if(pakfile == "")
2409                         pakfile = whichpack(strcat(mapfile, ".png"));
2410                 if(pakfile != "")
2411                         break;
2412         }
2413         if(i >= mapvote_screenshot_dirs_count)
2414                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2415         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2416                 pakfile = substring(pakfile, o, -1);
2417
2418         mapvote_maps_screenshot_dir[mapvote_count] = i;
2419         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2420
2421         mapvote_count += 1;
2422 }
2423
2424 void MapVote_Spawn();
2425 void MapVote_Init()
2426 {
2427         float i;
2428         float nmax, smax;
2429
2430         MapVote_ClearAllVotes();
2431
2432         mapvote_count = 0;
2433         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2434         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2435
2436         if(mapvote_abstain)
2437                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2438         else
2439                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2440         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2441
2442         // we need this for AddVotable, as that cycles through the screenshot dirs
2443         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2444         if(mapvote_screenshot_dirs_count == 0)
2445                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2446         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2447         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2448                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2449
2450         if(mapvote_suggestion_ptr)
2451                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2452                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2453
2454         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2455                 MapVote_AddVotable(GetNextMap(), FALSE);
2456
2457         if(mapvote_count == 0)
2458         {
2459                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2460                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2461                 if(autocvar_g_maplist_shuffle)
2462                         ShuffleMaplist();
2463                 localcmd("\nmenu_cmd sync\n");
2464                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2465                         MapVote_AddVotable(GetNextMap(), FALSE);
2466         }
2467
2468         mapvote_count_real = mapvote_count;
2469         if(mapvote_abstain)
2470                 MapVote_AddVotable("don't care", 0);
2471
2472         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2473
2474         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2475         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2476         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2477                 mapvote_keeptwotime = 0;
2478         mapvote_message = "Choose a map and press its key!";
2479
2480         MapVote_Spawn();
2481 }
2482
2483 void MapVote_SendPicture(float id)
2484 {
2485         msg_entity = self;
2486         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2487         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2488         WriteByte(MSG_ONE, id);
2489         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2490 }
2491
2492 float GameCommand_MapVote(string cmd)
2493 {
2494         if(!intermission_running)
2495                 return FALSE;
2496
2497         if(cmd == "mv_getpic")
2498         {
2499                 MapVote_SendPicture(stof(argv(1)));
2500                 return TRUE;
2501         }
2502
2503         return FALSE;
2504 }
2505
2506 float MapVote_GetMapMask()
2507 {
2508         float mask, i, power;
2509         mask = 0;
2510         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2511                 if(mapvote_maps[i] != "")
2512                         mask |= power;
2513         return mask;
2514 }
2515
2516 entity mapvote_ent;
2517 float MapVote_SendEntity(entity to, float sf)
2518 {
2519         float i;
2520
2521         if(sf & 1)
2522                 sf &~= 2; // if we send 1, we don't need to also send 2
2523
2524         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2525         WriteByte(MSG_ENTITY, sf);
2526
2527         if(sf & 1)
2528         {
2529                 // flag 1 == initialization
2530                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2531                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2532                 WriteString(MSG_ENTITY, "");
2533                 WriteByte(MSG_ENTITY, mapvote_count);
2534                 WriteByte(MSG_ENTITY, mapvote_abstain);
2535                 WriteByte(MSG_ENTITY, mapvote_detail);
2536                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2537                 if(mapvote_count <= 8)
2538                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2539                 else
2540                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2541                 for(i = 0; i < mapvote_count; ++i)
2542                         if(mapvote_maps[i] != "")
2543                         {
2544                                 if(mapvote_abstain && i == mapvote_count - 1)
2545                                 {
2546                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2547                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2548                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2549                                 }
2550                                 else
2551                                 {
2552                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2553                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2554                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2555                                 }
2556                         }
2557         }
2558
2559         if(sf & 2)
2560         {
2561                 // flag 2 == update of mask
2562                 if(mapvote_count <= 8)
2563                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2564                 else
2565                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2566         }
2567
2568         if(sf & 4)
2569         {
2570                 if(mapvote_detail)
2571                         for(i = 0; i < mapvote_count; ++i)
2572                                 if(mapvote_maps[i] != "")
2573                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2574
2575                 WriteByte(MSG_ENTITY, to.mapvote);
2576         }
2577
2578         return TRUE;
2579 }
2580
2581 void MapVote_Spawn()
2582 {
2583         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2584 }
2585
2586 void MapVote_TouchMask()
2587 {
2588         mapvote_ent.SendFlags |= 2;
2589 }
2590
2591 void MapVote_TouchVotes(entity voter)
2592 {
2593         mapvote_ent.SendFlags |= 4;
2594 }
2595
2596 float MapVote_Finished(float mappos)
2597 {
2598         string result;
2599         float i;
2600         float didntvote;
2601
2602         if(autocvar_sv_eventlog)
2603         {
2604                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2605                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2606                 didntvote = mapvote_voters;
2607                 for(i = 0; i < mapvote_count; ++i)
2608                         if(mapvote_maps[i] != "")
2609                         {
2610                                 didntvote -= mapvote_votes[i];
2611                                 if(i != mappos)
2612                                 {
2613                                         result = strcat(result, ":", mapvote_maps[i]);
2614                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2615                                 }
2616                         }
2617                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2618
2619                 GameLogEcho(result);
2620                 if(mapvote_maps_suggested[mappos])
2621                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2622         }
2623
2624         FOR_EACH_REALCLIENT(other)
2625                 FixClientCvars(other);
2626
2627         Map_Goto_SetStr(mapvote_maps[mappos]);
2628         Map_Goto(0);
2629         alreadychangedlevel = TRUE;
2630         return TRUE;
2631 }
2632 void MapVote_CheckRules_1()
2633 {
2634         float i;
2635
2636         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2637         {
2638                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2639                 mapvote_votes[i] = 0;
2640         }
2641
2642         mapvote_voters = 0;
2643         FOR_EACH_REALCLIENT(other)
2644         {
2645                 ++mapvote_voters;
2646                 if(other.mapvote)
2647                 {
2648                         i = other.mapvote - 1;
2649                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2650                         mapvote_votes[i] = mapvote_votes[i] + 1;
2651                 }
2652         }
2653 }
2654
2655 float MapVote_CheckRules_2()
2656 {
2657         float i;
2658         float firstPlace, secondPlace;
2659         float firstPlaceVotes, secondPlaceVotes;
2660         float mapvote_voters_real;
2661         string result;
2662
2663         if(mapvote_count_real == 1)
2664                 return MapVote_Finished(0);
2665
2666         mapvote_voters_real = mapvote_voters;
2667         if(mapvote_abstain)
2668                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2669
2670         RandomSelection_Init();
2671         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2672                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2673         firstPlace = RandomSelection_chosen_float;
2674         firstPlaceVotes = RandomSelection_best_priority;
2675         //dprint("First place: ", ftos(firstPlace), "\n");
2676         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2677
2678         RandomSelection_Init();
2679         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2680                 if(i != firstPlace)
2681                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2682         secondPlace = RandomSelection_chosen_float;
2683         secondPlaceVotes = RandomSelection_best_priority;
2684         //dprint("Second place: ", ftos(secondPlace), "\n");
2685         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2686
2687         if(firstPlace == -1)
2688                 error("No first place in map vote... WTF?");
2689
2690         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2691                 return MapVote_Finished(firstPlace);
2692
2693         if(mapvote_keeptwotime)
2694                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2695                 {
2696                         float didntvote;
2697                         MapVote_TouchMask();
2698                         mapvote_message = "Now decide between the TOP TWO!";
2699                         mapvote_keeptwotime = 0;
2700                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2701                         result = strcat(result, ":", ftos(firstPlaceVotes));
2702                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2703                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2704                         didntvote = mapvote_voters;
2705                         for(i = 0; i < mapvote_count; ++i)
2706                                 if(mapvote_maps[i] != "")
2707                                 {
2708                                         didntvote -= mapvote_votes[i];
2709                                         if(i != firstPlace)
2710                                                 if(i != secondPlace)
2711                                                 {
2712                                                         result = strcat(result, ":", mapvote_maps[i]);
2713                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2714                                                         if(i < mapvote_count_real)
2715                                                         {
2716                                                                 strunzone(mapvote_maps[i]);
2717                                                                 mapvote_maps[i] = "";
2718                                                                 strunzone(mapvote_maps_pakfile[i]);
2719                                                                 mapvote_maps_pakfile[i] = "";
2720                                                         }
2721                                                 }
2722                                 }
2723                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2724                         if(autocvar_sv_eventlog)
2725                                 GameLogEcho(result);
2726                 }
2727
2728         return FALSE;
2729 }
2730 void MapVote_Tick()
2731 {
2732         float keeptwo;
2733         float totalvotes;
2734
2735         keeptwo = mapvote_keeptwotime;
2736         MapVote_CheckRules_1(); // count
2737         if(MapVote_CheckRules_2()) // decide
2738                 return;
2739
2740         totalvotes = 0;
2741         FOR_EACH_REALCLIENT(other)
2742         {
2743                 // hide scoreboard again
2744                 if(other.health != 2342)
2745                 {
2746                         other.health = 2342;
2747                         other.impulse = 0;
2748                         if(clienttype(other) == CLIENTTYPE_REAL)
2749                         {
2750                                 msg_entity = other;
2751                                 WriteByte(MSG_ONE, SVC_FINALE);
2752                                 WriteString(MSG_ONE, "");
2753                         }
2754                 }
2755
2756                 // clear possibly invalid votes
2757                 if(mapvote_maps[other.mapvote - 1] == "")
2758                         other.mapvote = 0;
2759                 // use impulses as new vote
2760                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2761                         if(mapvote_maps[other.impulse - 1] != "")
2762                         {
2763                                 other.mapvote = other.impulse;
2764                                 MapVote_TouchVotes(other);
2765                         }
2766                 other.impulse = 0;
2767
2768                 if(other.mapvote)
2769                         ++totalvotes;
2770         }
2771
2772         MapVote_CheckRules_1(); // just count
2773 }
2774 void MapVote_Start()
2775 {
2776         if(mapvote_run)
2777                 return;
2778
2779         // wait for stats to be sent first
2780         if(!playerstats_waitforme)
2781                 return;
2782
2783         MapInfo_Enumerate();
2784         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2785                 mapvote_run = TRUE;
2786 }
2787 void MapVote_Think()
2788 {
2789         if(!mapvote_run)
2790                 return;
2791
2792         if(alreadychangedlevel)
2793                 return;
2794
2795         if(time < mapvote_nextthink)
2796                 return;
2797         //dprint("tick\n");
2798
2799         mapvote_nextthink = time + 0.5;
2800
2801         if(!mapvote_initialized)
2802         {
2803                 if(autocvar_rescan_pending == 1)
2804                 {
2805                         cvar_set("rescan_pending", "2");
2806                         localcmd("fs_rescan\nrescan_pending 3\n");
2807                         return;
2808                 }
2809                 else if(autocvar_rescan_pending == 2)
2810                 {
2811                         return;
2812                 }
2813                 else if(autocvar_rescan_pending == 3)
2814                 {
2815                         // now build missing mapinfo files
2816                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2817                                 return;
2818
2819                         // we're done, start the timer
2820                         cvar_set("rescan_pending", "0");
2821                 }
2822
2823                 mapvote_initialized = TRUE;
2824                 if(DoNextMapOverride(0))
2825                         return;
2826                 if(!autocvar_g_maplist_votable || player_count <= 0)
2827                 {
2828                         GotoNextMap(0);
2829                         return;
2830                 }
2831                 MapVote_Init();
2832         }
2833
2834         MapVote_Tick();
2835 }
2836
2837 string GotoMap(string m)
2838 {
2839         if(!MapInfo_CheckMap(m))
2840                 return "The map you chose is not available on this server.";
2841         cvar_set("nextmap", m);
2842         cvar_set("timelimit", "-1");
2843         if(mapvote_initialized || alreadychangedlevel)
2844         {
2845                 if(DoNextMapOverride(0))
2846                         return "Map switch initiated.";
2847                 else
2848                         return "Hm... no. For some reason I like THIS map more.";
2849         }
2850         else
2851                 return "Map switch will happen after scoreboard.";
2852 }
2853
2854
2855 void EndFrame()
2856 {
2857         float altime;
2858         FOR_EACH_REALCLIENT(self)
2859         {
2860                 if(self.classname == "spectator")
2861                 {
2862                         if(self.enemy.typehitsound)
2863                                 self.typehit_time = time;
2864                         else if(self.enemy.hitsound)
2865                                 self.hit_time = time;
2866                 }
2867                 else
2868                 {
2869                         if(self.typehitsound)
2870                                 self.typehit_time = time;
2871                         else if(self.hitsound)
2872                                 self.hit_time = time;
2873                 }
2874         }
2875         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2876         // add 1 frametime because after this, engine SV_Physics
2877         // increases time by a frametime and then networks the frame
2878         // add another frametime because client shows everything with
2879         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2880         // needed!
2881         FOR_EACH_CLIENT(self)
2882         {
2883                 self.hitsound = FALSE;
2884                 self.typehitsound = FALSE;
2885                 antilag_record(self, altime);
2886         }
2887 }
2888
2889
2890 /*
2891  * RedirectionThink:
2892  * returns TRUE if redirecting
2893  */
2894 float redirection_timeout;
2895 float redirection_nextthink;
2896 float RedirectionThink()
2897 {
2898         float clients_found;
2899
2900         if(redirection_target == "")
2901                 return FALSE;
2902
2903         if(!redirection_timeout)
2904         {
2905                 cvar_set("sv_public", "-2");
2906                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2907                 if(redirection_target == "self")
2908                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2909                 else
2910                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2911         }
2912
2913         if(time < redirection_nextthink)
2914                 return TRUE;
2915
2916         redirection_nextthink = time + 1;
2917
2918         clients_found = 0;
2919         FOR_EACH_REALCLIENT(self)
2920         {
2921                 print("Redirecting: sending connect command to ", self.netname, "\n");
2922                 if(redirection_target == "self")
2923                         stuffcmd(self, "\ndisconnect; reconnect\n");
2924                 else
2925                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2926                 ++clients_found;
2927         }
2928
2929         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2930
2931         if(time > redirection_timeout || clients_found == 0)
2932                 localcmd("\nwait; wait; wait; quit\n");
2933
2934         return TRUE;
2935 }
2936
2937 void TargetMusic_RestoreGame();
2938 void RestoreGame()
2939 {
2940         // Loaded from a save game
2941         // some things then break, so let's work around them...
2942
2943         // Progs DB (capture records)
2944         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2945
2946         // Mapinfo
2947         MapInfo_Shutdown();
2948         MapInfo_Enumerate();
2949         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2950         WeaponStats_Init();
2951
2952         TargetMusic_RestoreGame();
2953 }
2954
2955 void Shutdown()
2956 {
2957         entity e;
2958
2959         gameover = 2;
2960
2961         if(world_initialized > 0)
2962         {
2963                 world_initialized = 0;
2964                 print("Saving persistent data...\n");
2965                 Ban_SaveBans();
2966
2967                 PlayerStats_EndMatch(0);
2968                 FOR_EACH_CLIENT(e)
2969                         PlayerStats_AddGlobalInfo(e);
2970                 PlayerStats_Shutdown();
2971
2972                 if(!cheatcount_total)
2973                 {
2974                         if(autocvar_sv_db_saveasdump)
2975                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2976                         else
2977                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2978                 }
2979                 if(autocvar_developer)
2980                 {
2981                         if(autocvar_sv_db_saveasdump)
2982                                 db_dump(TemporaryDB, "server-temp.db");
2983                         else
2984                                 db_save(TemporaryDB, "server-temp.db");
2985                 }
2986                 CheatShutdown(); // must be after cheatcount check
2987                 db_close(ServerProgsDB);
2988                 db_close(TemporaryDB);
2989                 print("done!\n");
2990                 // tell the bot system the game is ending now
2991                 bot_endgame();
2992
2993                 WeaponStats_Shutdown();
2994                 MapInfo_Shutdown();
2995         }
2996         else if(world_initialized == 0)
2997         {
2998                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2999         }
3000 }