qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         Nagger_Init();
 761
 762         // freeze attacks
 763         addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, revive_progress);
 764
 765         // physics
 766         Physics_AddStats();
 767
 768         next_pingtime = time + 5;
 769
 770         detect_maptype();
 771
 772         // set up information replies for clients and server to use
 773         maplist_reply = strzone(getmaplist());
 774         lsmaps_reply = strzone(getlsmaps());
 775         monsterlist_reply = strzone(getmonsterlist());
 776         for(int i = 0; i < 10; ++i)
 777         {
 778                 s = getrecords(i);
 779                 if (s)
 780                         records_reply[i] = strzone(s);
 781         }
 782         ladder_reply = strzone(getladder());
 783         rankings_reply = strzone(getrankings());
 784
 785         // begin other init
 786         ClientInit_Spawn();
 787         RandomSeed_Spawn();
 788         PingPLReport_Spawn();
 789
 790         CheatInit();
 791
 792         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 793
 794         // fill sv_curl_serverpackages from .serverpackage files
 795         if(autocvar_sv_curl_serverpackages_auto)
 796         {
 797                 s = "";
 798                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 799                 for(int i = 0; i < n; ++i)
 800                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 801                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 802                                 s = strcat(s, " ", argv(i));
 803                 fd = search_begin("*-serverpackage.txt", true, false);
 804                 if(fd >= 0)
 805                 {
 806                         j = search_getsize(fd);
 807                         for(int i = 0; i < j; ++i)
 808                                 s = strcat(s, " ", search_getfilename(fd, i));
 809                         search_end(fd);
 810                 }
 811                 fd = search_begin("*.serverpackage", true, false);
 812                 if(fd >= 0)
 813                 {
 814                         j = search_getsize(fd);
 815                         for(int i = 0; i < j; ++i)
 816                                 s = strcat(s, " ", search_getfilename(fd, i));
 817                         search_end(fd);
 818                 }
 819                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 820         }
 821
 822         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 823         modname = "Xonotic";
 824         // physics/balance/config changes that count as mod
 825         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 826                 modname = cvar_string("g_mod_physics");
 827         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 828                 modname = cvar_string("g_mod_balance");
 829         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 830                 modname = cvar_string("g_mod_config");
 831         // extra mutators that deserve to count as mod
 832         MUTATOR_CALLHOOK(SetModname);
 833
 834         // save it for later
 835         modname = strzone(modname);
 836
 837         WinningConditionHelper(); // set worldstatus
 838
 839         world_initialized = 1;
 840 }
 841
 842 spawnfunc(light)
 843 {
 844         //makestatic (self); // Who the f___ did that?
 845         remove(self);
 846 }
 847
 848 string GetGametype()
 849 {
 850         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 851 }
 852
 853 string GetMapname()
 854 {
 855         return mapname;
 856 }
 857
 858 float Map_Count, Map_Current;
 859 string Map_Current_Name;
 860
 861 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 862 float GetMaplistPosition()
 863 {
 864         float pos, idx;
 865         string map;
 866
 867         map = GetMapname();
 868         idx = autocvar_g_maplist_index;
 869
 870         if(idx >= 0)
 871                 if(idx < Map_Count)
 872                         if(map == argv(idx))
 873                                 return idx;
 874
 875         for(pos = 0; pos < Map_Count; ++pos)
 876                 if(map == argv(pos))
 877                         return pos;
 878
 879         // resume normal maplist rotation if current map is not in g_maplist
 880         return idx;
 881 }
 882
 883 float MapHasRightSize(string map)
 884 {
 885         float fh;
 886         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 887         if(autocvar_g_maplist_check_waypoints)
 888         {
 889                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 890                 if(!fexists(strcat("maps/", map, ".waypoints")))
 891                 {
 892                         LOG_TRACE(": no waypoints\n");
 893                         return false;
 894                 }
 895                 LOG_TRACE(": has waypoints\n");
 896         }
 897
 898         // open map size restriction file
 899         LOG_TRACE("opensize "); LOG_TRACE(map);
 900         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 901         if(fh >= 0)
 902         {
 903                 float mapmin, mapmax;
 904                 LOG_TRACE(": ok, ");
 905                 mapmin = stof(fgets(fh));
 906                 mapmax = stof(fgets(fh));
 907                 fclose(fh);
 908                 if(player_count < mapmin)
 909                 {
 910                         LOG_TRACE("not enough\n");
 911                         return false;
 912                 }
 913                 if(player_count > mapmax)
 914                 {
 915                         LOG_TRACE("too many\n");
 916                         return false;
 917                 }
 918                 LOG_TRACE("right size\n");
 919                 return true;
 920         }
 921         LOG_TRACE(": not found\n");
 922         return true;
 923 }
 924
 925 string Map_Filename(float position)
 926 {
 927         return strcat("maps/", argv(position), ".bsp");
 928 }
 929
 930 void Map_MarkAsRecent(string m)
 931 {
 932         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 933 }
 934
 935 float Map_IsRecent(string m)
 936 {
 937         return strhasword(autocvar_g_maplist_mostrecent, m);
 938 }
 939
 940 float Map_Check(float position, float pass)
 941 {
 942         string filename;
 943         string map_next;
 944         map_next = argv(position);
 945         if(pass <= 1)
 946         {
 947                 if(Map_IsRecent(map_next))
 948                         return 0;
 949         }
 950         filename = Map_Filename(position);
 951         if(MapInfo_CheckMap(map_next))
 952         {
 953                 if(pass == 2)
 954                         return 1;
 955                 if(MapHasRightSize(map_next))
 956                         return 1;
 957                 return 0;
 958         }
 959         else
 960                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
 961
 962         return 0;
 963 }
 964
 965 void Map_Goto_SetStr(string nextmapname)
 966 {
 967         if(getmapname_stored != "")
 968                 strunzone(getmapname_stored);
 969         if(nextmapname == "")
 970                 getmapname_stored = "";
 971         else
 972                 getmapname_stored = strzone(nextmapname);
 973 }
 974
 975 void Map_Goto_SetFloat(float position)
 976 {
 977         cvar_set("g_maplist_index", ftos(position));
 978         Map_Goto_SetStr(argv(position));
 979 }
 980
 981 void Map_Goto(float reinit)
 982 {
 983         MapInfo_LoadMap(getmapname_stored, reinit);
 984 }
 985
 986 // return codes of map selectors:
 987 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 988 //   -2 = permanent failure
 989 float() MaplistMethod_Iterate = // usual method
 990 {
 991         float pass, i;
 992
 993         LOG_TRACE("Trying MaplistMethod_Iterate\n");
 994
 995         for(pass = 1; pass <= 2; ++pass)
 996         {
 997                 for(i = 1; i < Map_Count; ++i)
 998                 {
 999                         float mapindex;
1000                         mapindex = (i + Map_Current) % Map_Count;
1001                         if(Map_Check(mapindex, pass))
1002                                 return mapindex;
1003                 }
1004         }
1005         return -1;
1006 }
1007
1008 float() MaplistMethod_Repeat = // fallback method
1009 {
1010         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1011
1012         if(Map_Check(Map_Current, 2))
1013                 return Map_Current;
1014         return -2;
1015 }
1016
1017 float() MaplistMethod_Random = // random map selection
1018 {
1019         float i, imax;
1020
1021         LOG_TRACE("Trying MaplistMethod_Random\n");
1022
1023         imax = 42;
1024
1025         for(i = 0; i <= imax; ++i)
1026         {
1027                 float mapindex;
1028                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1029                 if(Map_Check(mapindex, 1))
1030                         return mapindex;
1031         }
1032         return -1;
1033 }
1034
1035 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1036 // the exponent sets a bias on the map selection:
1037 // the higher the exponent, the less likely "shortly repeated" same maps are
1038 {
1039         float i, j, imax, insertpos;
1040
1041         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1042
1043         imax = 42;
1044
1045         for(i = 0; i <= imax; ++i)
1046         {
1047                 string newlist;
1048
1049                 // now reinsert this at another position
1050                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1051                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1052                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1053                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1054
1055                 // insert the current map there
1056                 newlist = "";
1057                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1058                         newlist = strcat(newlist, " ", argv(j));
1059                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1060                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1061                         newlist = strcat(newlist, " ", argv(j));
1062                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1063                 cvar_set("g_maplist", newlist);
1064                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1065
1066                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1067                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1068                 if(Map_Check(Map_Current, 1))
1069                         return Map_Current;
1070         }
1071         return -1;
1072 }
1073
1074 void Maplist_Init()
1075 {
1076         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1077         float i;
1078         for (i = 0; i < Map_Count; ++i)
1079                 if (Map_Check(i, 2))
1080                         break;
1081         if (i == Map_Count)
1082         {
1083                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1084                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1085                 if(autocvar_g_maplist_shuffle)
1086                         ShuffleMaplist();
1087                 localcmd("\nmenu_cmd sync\n");
1088                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1089         }
1090         if(Map_Count == 0)
1091                 error("empty maplist, cannot select a new map");
1092         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1093
1094         if(Map_Current_Name)
1095                 strunzone(Map_Current_Name);
1096         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1097         // this may or may not be correct, but who cares, in the worst case a map
1098         // isn't chosen in the first pass that should have been
1099 }
1100
1101 string GetNextMap()
1102 {
1103         float nextMap;
1104
1105         Maplist_Init();
1106         nextMap = -1;
1107
1108         if(nextMap == -1)
1109                 if(autocvar_g_maplist_shuffle > 0)
1110                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1111
1112         if(nextMap == -1)
1113                 if(autocvar_g_maplist_selectrandom)
1114                         nextMap = MaplistMethod_Random();
1115
1116         if(nextMap == -1)
1117                 nextMap = MaplistMethod_Iterate();
1118
1119         if(nextMap == -1)
1120                 nextMap = MaplistMethod_Repeat();
1121
1122         if(nextMap >= 0)
1123         {
1124                 Map_Goto_SetFloat(nextMap);
1125                 return getmapname_stored;
1126         }
1127
1128         return "";
1129 }
1130
1131 float DoNextMapOverride(float reinit)
1132 {
1133         if(autocvar_g_campaign)
1134         {
1135                 CampaignPostIntermission();
1136                 alreadychangedlevel = true;
1137                 return true;
1138         }
1139         if(autocvar_quit_when_empty)
1140         {
1141                 if(player_count <= currentbots)
1142                 {
1143                         localcmd("quit\n");
1144                         alreadychangedlevel = true;
1145                         return true;
1146                 }
1147         }
1148         if(autocvar_quit_and_redirect != "")
1149         {
1150                 redirection_target = strzone(autocvar_quit_and_redirect);
1151                 alreadychangedlevel = true;
1152                 return true;
1153         }
1154         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1155         {
1156                 localcmd("restart\n");
1157                 alreadychangedlevel = true;
1158                 return true;
1159         }
1160         if(autocvar_nextmap != "")
1161         {
1162                 string m;
1163                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1164                 cvar_set("nextmap",m);
1165
1166                 if(!m || gametypevote)
1167                         return false;
1168                 if(autocvar_sv_vote_gametype)
1169                 {
1170                         Map_Goto_SetStr(m);
1171                         return false;
1172                 }
1173
1174                 if(MapInfo_CheckMap(m))
1175                 {
1176                         Map_Goto_SetStr(m);
1177                         Map_Goto(reinit);
1178                         alreadychangedlevel = true;
1179                         return true;
1180                 }
1181         }
1182         if(!reinit && autocvar_lastlevel)
1183         {
1184                 cvar_settemp_restore();
1185                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1186                 alreadychangedlevel = true;
1187                 return true;
1188         }
1189         return false;
1190 }
1191
1192 void GotoNextMap(float reinit)
1193 {
1194         //string nextmap;
1195         //float n, nummaps;
1196         //string s;
1197         if (alreadychangedlevel)
1198                 return;
1199         alreadychangedlevel = true;
1200
1201         string nextMap;
1202
1203         nextMap = GetNextMap();
1204         if(nextMap == "")
1205                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1206         Map_Goto(reinit);
1207 }
1208
1209
1210 /*
1211 ============
1212 IntermissionThink
1213
1214 When the player presses attack or jump, change to the next level
1215 ============
1216 */
1217 .float autoscreenshot;
1218 void IntermissionThink()
1219 {SELFPARAM();
1220         FixIntermissionClient(self);
1221
1222         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1223         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1224
1225         if( (server_screenshot || client_screenshot)
1226                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1227         {
1228                 self.autoscreenshot = -1;
1229                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1230                 return;
1231         }
1232
1233         if (time < intermission_exittime)
1234                 return;
1235
1236         if(!mapvote_initialized)
1237                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1238                         return;
1239
1240         MapVote_Start();
1241 }
1242
1243 /*
1244 ============
1245 FindIntermission
1246
1247 Returns the entity to view from
1248 ============
1249 */
1250 /*
1251 entity FindIntermission()
1252 {
1253         local   entity spot;
1254         local   float cyc;
1255
1256 // look for info_intermission first
1257         spot = find (world, classname, "info_intermission");
1258         if (spot)
1259         {       // pick a random one
1260                 cyc = random() * 4;
1261                 while (cyc > 1)
1262                 {
1263                         spot = find (spot, classname, "info_intermission");
1264                         if (!spot)
1265                                 spot = find (spot, classname, "info_intermission");
1266                         cyc = cyc - 1;
1267                 }
1268                 return spot;
1269         }
1270
1271 // then look for the start position
1272         spot = find (world, classname, "info_player_start");
1273         if (spot)
1274                 return spot;
1275
1276 // testinfo_player_start is only found in regioned levels
1277         spot = find (world, classname, "testplayerstart");
1278         if (spot)
1279                 return spot;
1280
1281 // then look for the start position
1282         spot = find (world, classname, "info_player_deathmatch");
1283         if (spot)
1284                 return spot;
1285
1286         //objerror ("FindIntermission: no spot");
1287         return world;
1288 }
1289 */
1290
1291 /*
1292 ===============================================================================
1293
1294 RULES
1295
1296 ===============================================================================
1297 */
1298
1299 void DumpStats(float final)
1300 {
1301         float file;
1302         string s;
1303         float to_console;
1304         float to_eventlog;
1305         float to_file;
1306         float i;
1307
1308         to_console = autocvar_sv_logscores_console;
1309         to_eventlog = autocvar_sv_eventlog;
1310         to_file = autocvar_sv_logscores_file;
1311
1312         if(!final)
1313         {
1314                 to_console = true; // always print printstats replies
1315                 to_eventlog = false; // but never print them to the event log
1316         }
1317
1318         if(to_eventlog)
1319                 if(autocvar_sv_eventlog_console)
1320                         to_console = false; // otherwise we get the output twice
1321
1322         if(final)
1323                 s = ":scores:";
1324         else
1325                 s = ":status:";
1326         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1327
1328         if(to_console)
1329                 LOG_INFO(s, "\n");
1330         if(to_eventlog)
1331                 GameLogEcho(s);
1332
1333         file = -1;
1334         if(to_file)
1335         {
1336                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1337                 if(file == -1)
1338                         to_file = false;
1339                 else
1340                         fputs(file, strcat(s, "\n"));
1341         }
1342
1343         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1344         if(to_console)
1345                 LOG_INFO(s, "\n");
1346         if(to_eventlog)
1347                 GameLogEcho(s);
1348         if(to_file)
1349                 fputs(file, strcat(s, "\n"));
1350
1351         FOR_EACH_CLIENT(other)
1352         {
1353                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1354                 {
1355                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1356                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1357                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1358                                 s = strcat(s, ftos(other.team), ":");
1359                         else
1360                                 s = strcat(s, "spectator:");
1361
1362                         if(to_console)
1363                                 LOG_INFO(s, other.netname, "\n");
1364                         if(to_eventlog)
1365                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1366                         if(to_file)
1367                                 fputs(file, strcat(s, other.netname, "\n"));
1368                 }
1369         }
1370
1371         if(teamplay)
1372         {
1373                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1374                 if(to_console)
1375                         LOG_INFO(s, "\n");
1376                 if(to_eventlog)
1377                         GameLogEcho(s);
1378                 if(to_file)
1379                         fputs(file, strcat(s, "\n"));
1380
1381                 for(i = 1; i < 16; ++i)
1382                 {
1383                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1384                         s = strcat(s, ":", ftos(i));
1385                         if(to_console)
1386                                 LOG_INFO(s, "\n");
1387                         if(to_eventlog)
1388                                 GameLogEcho(s);
1389                         if(to_file)
1390                                 fputs(file, strcat(s, "\n"));
1391                 }
1392         }
1393
1394         if(to_console)
1395                 LOG_INFO(":end\n");
1396         if(to_eventlog)
1397                 GameLogEcho(":end");
1398         if(to_file)
1399         {
1400                 fputs(file, ":end\n");
1401                 fclose(file);
1402         }
1403 }
1404
1405 void FixIntermissionClient(entity e)
1406 {
1407         string s;
1408         if(!e.autoscreenshot) // initial call
1409         {
1410                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1411                 e.health = -2342;
1412                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1413                 e.solid = SOLID_NOT;
1414                 e.movetype = MOVETYPE_NONE;
1415                 e.takedamage = DAMAGE_NO;
1416                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1417                 {
1418                     .entity weaponentity = weaponentities[slot];
1419                         if(e.(weaponentity))
1420                         {
1421                                 e.(weaponentity).effects = EF_NODRAW;
1422                                 if (e.(weaponentity).(weaponentity))
1423                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1424                         }
1425                 }
1426                 if(IS_REAL_CLIENT(e))
1427                 {
1428                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1429                         s = autocvar_sv_intermission_cdtrack;
1430                         if(s != "")
1431                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1432                         msg_entity = e;
1433                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1434                 }
1435         }
1436 }
1437
1438 /*
1439 go to the next level for deathmatch
1440 only called if a time or frag limit has expired
1441 */
1442 void NextLevel()
1443 {
1444         gameover = true;
1445
1446         intermission_running = 1;
1447
1448 // enforce a wait time before allowing changelevel
1449         if(player_count > 0)
1450                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1451         else
1452                 intermission_exittime = -1;
1453
1454         /*
1455         WriteByte (MSG_ALL, SVC_CDTRACK);
1456         WriteByte (MSG_ALL, 3);
1457         WriteByte (MSG_ALL, 3);
1458         // done in FixIntermission
1459         */
1460
1461         //pos = FindIntermission ();
1462
1463         VoteReset();
1464
1465         DumpStats(true);
1466
1467         // send statistics
1468         PlayerStats_GameReport(true);
1469         WeaponStats_Shutdown();
1470
1471         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1472
1473         if(autocvar_sv_eventlog)
1474                 GameLogEcho(":gameover");
1475
1476         GameLogClose();
1477
1478         FOR_EACH_PLAYER(other) {
1479                 FixIntermissionClient(other);
1480                 if(other.winning)
1481                         bprint(other.netname, " ^7wins.\n");
1482         }
1483
1484         entity oldself = self;
1485         target_music_kill();
1486         self = oldself;
1487
1488         if(autocvar_g_campaign)
1489                 CampaignPreIntermission();
1490
1491         MUTATOR_CALLHOOK(MatchEnd);
1492
1493         localcmd("\nsv_hook_gameend\n");
1494 }
1495
1496 /*
1497 ============
1498 CheckRules_Player
1499
1500 Exit deathmatch games upon conditions
1501 ============
1502 */
1503 void CheckRules_Player()
1504 {SELFPARAM();
1505         if (gameover)   // someone else quit the game already
1506                 return;
1507
1508         if(self.deadflag == DEAD_NO)
1509                 self.play_time += frametime;
1510
1511         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1512         //   (div0: and that in CheckRules_World please)
1513 }
1514
1515
1516 float InitiateSuddenDeath()
1517 {
1518         // Check first whether normal overtimes could be added before initiating suddendeath mode
1519         // - for this timelimit_overtime needs to be >0 of course
1520         // - also check the winning condition calculated in the previous frame and only add normal overtime
1521         //   again, if at the point at which timelimit would be extended again, still no winner was found
1522         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1523         {
1524                 return 1; // need to call InitiateOvertime later
1525         }
1526         else
1527         {
1528                 if(!checkrules_suddendeathend)
1529                 {
1530                         if(autocvar_g_campaign)
1531                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1532                         else
1533                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1534                         if(g_race && !g_race_qualifying)
1535                                 race_StartCompleting();
1536                 }
1537                 return 0;
1538         }
1539 }
1540
1541 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1542 {
1543         ++checkrules_overtimesadded;
1544         //add one more overtime by simply extending the timelimit
1545         float tl;
1546         tl = autocvar_timelimit;
1547         tl += autocvar_timelimit_overtime;
1548         cvar_set("timelimit", ftos(tl));
1549
1550         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1551 }
1552
1553 float GetWinningCode(float fraglimitreached, float equality)
1554 {
1555         if(autocvar_g_campaign == 1)
1556                 if(fraglimitreached)
1557                         return WINNING_YES;
1558                 else
1559                         return WINNING_NO;
1560
1561         else
1562                 if(equality)
1563                         if(fraglimitreached)
1564                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1565                         else
1566                                 return WINNING_NEVER;
1567                 else
1568                         if(fraglimitreached)
1569                                 return WINNING_YES;
1570                         else
1571                                 return WINNING_NO;
1572 }
1573
1574 // set the .winning flag for exactly those players with a given field value
1575 void SetWinners(.float field, float value)
1576 {
1577         entity head;
1578         FOR_EACH_PLAYER(head)
1579                 head.winning = (head.(field) == value);
1580 }
1581
1582 // set the .winning flag for those players with a given field value
1583 void AddWinners(.float field, float value)
1584 {
1585         entity head;
1586         FOR_EACH_PLAYER(head)
1587                 if (head.(field) == value)
1588                         head.winning = 1;
1589 }
1590
1591 // clear the .winning flags
1592 void ClearWinners()
1593 {
1594         entity head;
1595         FOR_EACH_PLAYER(head)
1596                 head.winning = 0;
1597 }
1598
1599 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1600 // they win. Otherwise the defending team wins once the timelimit passes.
1601 void assault_new_round();
1602 float WinningCondition_Assault()
1603 {SELFPARAM();
1604         float status;
1605
1606         WinningConditionHelper(); // set worldstatus
1607
1608         status = WINNING_NO;
1609         // as the timelimit has not yet passed just assume the defending team will win
1610         if(assault_attacker_team == NUM_TEAM_1)
1611         {
1612                 SetWinners(team, NUM_TEAM_2);
1613         }
1614         else
1615         {
1616                 SetWinners(team, NUM_TEAM_1);
1617         }
1618
1619         entity ent;
1620         ent = find(world, classname, "target_assault_roundend");
1621         if(ent)
1622         {
1623                 if(ent.winning) // round end has been triggered by attacking team
1624                 {
1625                         bprint("ASSAULT: round completed...\n");
1626                         SetWinners(team, assault_attacker_team);
1627
1628                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1629
1630                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1631                         {
1632                                 status = WINNING_YES;
1633                         }
1634                         else
1635                         {
1636                                 WITH(entity, self, ent, assault_new_round());
1637                         }
1638                 }
1639         }
1640
1641         return status;
1642 }
1643
1644 void ShuffleMaplist()
1645 {
1646         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1647 }
1648
1649 float leaderfrags;
1650 float WinningCondition_Scores(float limit, float leadlimit)
1651 {
1652         float limitreached;
1653
1654         // TODO make everything use THIS winning condition (except LMS)
1655         WinningConditionHelper();
1656
1657         if(teamplay)
1658         {
1659                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1660                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1661                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1662                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1663         }
1664
1665         ClearWinners();
1666         if(WinningConditionHelper_winner)
1667                 WinningConditionHelper_winner.winning = 1;
1668         if(WinningConditionHelper_winnerteam >= 0)
1669                 SetWinners(team, WinningConditionHelper_winnerteam);
1670
1671         if(WinningConditionHelper_lowerisbetter)
1672         {
1673                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1674                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1675                 limit = -limit;
1676         }
1677
1678         if(WinningConditionHelper_zeroisworst)
1679                 leadlimit = 0; // not supported in this mode
1680
1681         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1682         // these modes always score in increments of 1, thus this makes sense
1683         {
1684                 if(leaderfrags != WinningConditionHelper_topscore)
1685                 {
1686                         leaderfrags = WinningConditionHelper_topscore;
1687
1688                         if (limit)
1689                         if (leaderfrags == limit - 1)
1690                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1691                         else if (leaderfrags == limit - 2)
1692                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1693                         else if (leaderfrags == limit - 3)
1694                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1695                 }
1696         }
1697
1698         limitreached = false;
1699         if(limit)
1700                 if(WinningConditionHelper_topscore >= limit)
1701                         limitreached = true;
1702         if(leadlimit)
1703         {
1704                 float leadlimitreached;
1705                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1706                 if(autocvar_leadlimit_and_fraglimit)
1707                         limitreached = (limitreached && leadlimitreached);
1708                 else
1709                         limitreached = (limitreached || leadlimitreached);
1710         }
1711
1712         if(limit)
1713                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1714
1715         return GetWinningCode(
1716                 WinningConditionHelper_topscore && limitreached,
1717                 WinningConditionHelper_equality
1718         );
1719 }
1720
1721 float WinningCondition_Race(float fraglimit)
1722 {
1723         float wc;
1724         entity p;
1725         float n, c;
1726
1727         n = 0;
1728         c = 0;
1729         FOR_EACH_PLAYER(p)
1730         {
1731                 ++n;
1732                 if(p.race_completed)
1733                         ++c;
1734         }
1735         if(n && (n == c))
1736                 return WINNING_YES;
1737         wc = WinningCondition_Scores(fraglimit, 0);
1738
1739         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1740         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1741         // do NOT support equality when the laps are all raced!
1742                 return WINNING_STARTSUDDENDEATHOVERTIME;
1743         else
1744                 return WINNING_NEVER;
1745 }
1746
1747 float WinningCondition_QualifyingThenRace(float limit)
1748 {
1749         float wc;
1750         wc = WinningCondition_Scores(limit, 0);
1751
1752         // NEVER initiate overtime
1753         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1754         {
1755                 return WINNING_YES;
1756         }
1757
1758         return wc;
1759 }
1760
1761 float WinningCondition_RanOutOfSpawns()
1762 {
1763         entity head;
1764
1765         if(have_team_spawns <= 0)
1766                 return WINNING_NO;
1767
1768         if(!autocvar_g_spawn_useallspawns)
1769                 return WINNING_NO;
1770
1771         if(!some_spawn_has_been_used)
1772                 return WINNING_NO;
1773
1774         team1_score = team2_score = team3_score = team4_score = 0;
1775
1776         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1777         {
1778                 if(head.team == NUM_TEAM_1)
1779                         team1_score = 1;
1780                 else if(head.team == NUM_TEAM_2)
1781                         team2_score = 1;
1782                 else if(head.team == NUM_TEAM_3)
1783                         team3_score = 1;
1784                 else if(head.team == NUM_TEAM_4)
1785                         team4_score = 1;
1786         }
1787
1788         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1789         {
1790                 if(head.team == NUM_TEAM_1)
1791                         team1_score = 1;
1792                 else if(head.team == NUM_TEAM_2)
1793                         team2_score = 1;
1794                 else if(head.team == NUM_TEAM_3)
1795                         team3_score = 1;
1796                 else if(head.team == NUM_TEAM_4)
1797                         team4_score = 1;
1798         }
1799
1800         ClearWinners();
1801         if(team1_score + team2_score + team3_score + team4_score == 0)
1802         {
1803                 checkrules_equality = true;
1804                 return WINNING_YES;
1805         }
1806         else if(team1_score + team2_score + team3_score + team4_score == 1)
1807         {
1808                 float t, i;
1809                 if(team1_score)
1810                         t = NUM_TEAM_1;
1811                 else if(team2_score)
1812                         t = NUM_TEAM_2;
1813                 else if(team3_score)
1814                         t = NUM_TEAM_3;
1815                 else // if(team4_score)
1816                         t = NUM_TEAM_4;
1817                 CheckAllowedTeams(world);
1818                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1819                 {
1820                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1821                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1822                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1823                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1824                 }
1825
1826                 AddWinners(team, t);
1827                 return WINNING_YES;
1828         }
1829         else
1830                 return WINNING_NO;
1831 }
1832
1833 /*
1834 ============
1835 CheckRules_World
1836
1837 Exit deathmatch games upon conditions
1838 ============
1839 */
1840 void CheckRules_World()
1841 {
1842         float timelimit;
1843         float fraglimit;
1844         float leadlimit;
1845
1846         VoteThink();
1847         MapVote_Think();
1848
1849         SetDefaultAlpha();
1850
1851         if (gameover)   // someone else quit the game already
1852         {
1853                 if(player_count == 0) // Nobody there? Then let's go to the next map
1854                         MapVote_Start();
1855                         // this will actually check the player count in the next frame
1856                         // again, but this shouldn't hurt
1857                 return;
1858         }
1859
1860         timelimit = autocvar_timelimit * 60;
1861         fraglimit = autocvar_fraglimit;
1862         leadlimit = autocvar_leadlimit;
1863
1864         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1865         {
1866                 if(timelimit > 0)
1867                         timelimit = 0; // timelimit is not made for warmup
1868                 if(fraglimit > 0)
1869                         fraglimit = 0; // no fraglimit for now
1870                 leadlimit = 0; // no leadlimit for now
1871         }
1872
1873         if(timelimit > 0)
1874         {
1875                 timelimit += game_starttime;
1876         }
1877         else if (timelimit < 0)
1878         {
1879                 // endmatch
1880                 NextLevel();
1881                 return;
1882         }
1883
1884         float wantovertime;
1885         wantovertime = 0;
1886
1887         if(timelimit > game_starttime)
1888                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1889         else
1890                 game_completion_ratio = 0;
1891
1892         if(checkrules_suddendeathend)
1893         {
1894                 if(!checkrules_suddendeathwarning)
1895                 {
1896                         checkrules_suddendeathwarning = true;
1897                         if(g_race && !g_race_qualifying)
1898                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1899                         else
1900                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1901                 }
1902         }
1903         else
1904         {
1905                 if (timelimit && time >= timelimit)
1906                 {
1907                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1908                         {
1909                                 float totalplayers;
1910                                 float playerswithlaps;
1911                                 float readyplayers;
1912                                 entity head;
1913                                 totalplayers = playerswithlaps = readyplayers = 0;
1914                                 FOR_EACH_PLAYER(head)
1915                                 {
1916                                         ++totalplayers;
1917                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1918                                                 ++playerswithlaps;
1919                                         if(head.ready)
1920                                                 ++readyplayers;
1921                                 }
1922
1923                                 // at least 2 of the players have completed a lap: start the RACE
1924                                 // otherwise, the players should end the qualifying on their own
1925                                 if(readyplayers || playerswithlaps >= 2)
1926                                 {
1927                                         checkrules_suddendeathend = 0;
1928                                         ReadyRestart(); // go to race
1929                                         return;
1930                                 }
1931                                 else
1932                                         wantovertime |= InitiateSuddenDeath();
1933                         }
1934                         else
1935                                 wantovertime |= InitiateSuddenDeath();
1936                 }
1937         }
1938
1939         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1940         {
1941                 NextLevel();
1942                 return;
1943         }
1944
1945         int checkrules_status = WinningCondition_RanOutOfSpawns();
1946         if(checkrules_status == WINNING_YES)
1947                 bprint("Hey! Someone ran out of spawns!\n");
1948         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1949                 checkrules_status = ret_float;
1950         else
1951                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1952
1953         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1954         {
1955                 checkrules_status = WINNING_NEVER;
1956                 checkrules_overtimesadded = -1;
1957                 wantovertime |= InitiateSuddenDeath();
1958         }
1959
1960         if(checkrules_status == WINNING_NEVER)
1961                 // equality cases! Nobody wins if the overtime ends in a draw.
1962                 ClearWinners();
1963
1964         if(wantovertime)
1965         {
1966                 if(checkrules_status == WINNING_NEVER)
1967                         InitiateOvertime();
1968                 else
1969                         checkrules_status = WINNING_YES;
1970         }
1971
1972         if(checkrules_suddendeathend)
1973                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1974                         checkrules_status = WINNING_YES;
1975
1976         if(checkrules_status == WINNING_YES)
1977         {
1978                 //print("WINNING\n");
1979                 NextLevel();
1980         }
1981 }
1982
1983 string GotoMap(string m)
1984 {
1985         m = GameTypeVote_MapInfo_FixName(m);
1986         if (!m)
1987                 return "The map you suggested is not available on this server.";
1988         if (!autocvar_sv_vote_gametype)
1989         if(!MapInfo_CheckMap(m))
1990                 return "The map you suggested does not support the current game mode.";
1991         cvar_set("nextmap", m);
1992         cvar_set("timelimit", "-1");
1993         if(mapvote_initialized || alreadychangedlevel)
1994         {
1995                 if(DoNextMapOverride(0))
1996                         return "Map switch initiated.";
1997                 else
1998                         return "Hm... no. For some reason I like THIS map more.";
1999         }
2000         else
2001                 return "Map switch will happen after scoreboard.";
2002 }
2003
2004
2005 void EndFrame()
2006 {SELFPARAM();
2007         anticheat_endframe();
2008
2009         float altime;
2010         entity e_;
2011         FOR_EACH_REALCLIENT(e_)
2012         {
2013                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2014                 if(e.typehitsound)
2015                         e_.typehit_time = time;
2016                 else if(e.damage_dealt)
2017                 {
2018                         e_.hit_time = time;
2019                         e_.damage_dealt_total += ceil(e.damage_dealt);
2020                 }
2021         }
2022         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2023         // add 1 frametime because after this, engine SV_Physics
2024         // increases time by a frametime and then networks the frame
2025         // add another frametime because client shows everything with
2026         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2027         // needed!
2028         FOR_EACH_CLIENT(e_)
2029         {
2030                 e_.typehitsound = false;
2031                 e_.damage_dealt = 0;
2032                 setself(e_);
2033                 antilag_record(e_, altime);
2034         }
2035         FOR_EACH_MONSTER(e_)
2036         {
2037                 setself(e_);
2038                 antilag_record(e_, altime);
2039         }
2040 }
2041
2042
2043 /*
2044  * RedirectionThink:
2045  * returns true if redirecting
2046  */
2047 float redirection_timeout;
2048 float redirection_nextthink;
2049 float RedirectionThink()
2050 {SELFPARAM();
2051         float clients_found;
2052
2053         if(redirection_target == "")
2054                 return false;
2055
2056         if(!redirection_timeout)
2057         {
2058                 cvar_set("sv_public", "-2");
2059                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2060                 if(redirection_target == "self")
2061                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2062                 else
2063                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2064         }
2065
2066         if(time < redirection_nextthink)
2067                 return true;
2068
2069         redirection_nextthink = time + 1;
2070
2071         clients_found = 0;
2072         entity e;
2073         FOR_EACH_REALCLIENT(e)
2074         {
2075                 setself(e);
2076                 // TODO add timer
2077                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2078                 if(redirection_target == "self")
2079                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2080                 else
2081                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2082                 ++clients_found;
2083         }
2084
2085         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2086
2087         if(time > redirection_timeout || clients_found == 0)
2088                 localcmd("\nwait; wait; wait; quit\n");
2089
2090         return true;
2091 }
2092
2093 void TargetMusic_RestoreGame();
2094 void RestoreGame()
2095 {
2096         // Loaded from a save game
2097         // some things then break, so let's work around them...
2098
2099         // Progs DB (capture records)
2100         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2101
2102         // Mapinfo
2103         MapInfo_Shutdown();
2104         MapInfo_Enumerate();
2105         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2106         WeaponStats_Init();
2107
2108         TargetMusic_RestoreGame();
2109 }
2110
2111 void Shutdown()
2112 {
2113         gameover = 2;
2114
2115         if(world_initialized > 0)
2116         {
2117                 world_initialized = 0;
2118                 LOG_INFO("Saving persistent data...\n");
2119                 Ban_SaveBans();
2120
2121                 // playerstats with unfinished match
2122                 PlayerStats_GameReport(false);
2123
2124                 if(!cheatcount_total)
2125                 {
2126                         if(autocvar_sv_db_saveasdump)
2127                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2128                         else
2129                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2130                 }
2131                 if(autocvar_developer)
2132                 {
2133                         if(autocvar_sv_db_saveasdump)
2134                                 db_dump(TemporaryDB, "server-temp.db");
2135                         else
2136                                 db_save(TemporaryDB, "server-temp.db");
2137                 }
2138                 CheatShutdown(); // must be after cheatcount check
2139                 db_close(ServerProgsDB);
2140                 db_close(TemporaryDB);
2141                 LOG_INFO("done!\n");
2142                 // tell the bot system the game is ending now
2143                 bot_endgame();
2144
2145                 WeaponStats_Shutdown();
2146                 MapInfo_Shutdown();
2147         }
2148         else if(world_initialized == 0)
2149         {
2150                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2151         }
2152 }