qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/api.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/_mod.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/constants.qh"
  22 #include <common/net_linked.qh>
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/gamemodes/sv_rules.qh"
  25 #include "../common/mapinfo.qh"
  26 #include "../common/monsters/_mod.qh"
  27 #include "../common/monsters/sv_monsters.qh"
  28 #include "../common/vehicles/all.qh"
  29 #include "../common/notifications/all.qh"
  30 #include "../common/physics/player.qh"
  31 #include "../common/playerstats.qh"
  32 #include "../common/stats.qh"
  33 #include "../common/teams.qh"
  34 #include "../common/mapobjects/trigger/secret.qh"
  35 #include "../common/mapobjects/target/music.qh"
  36 #include "../common/util.qh"
  37 #include "../common/items/_mod.qh"
  38 #include <common/weapons/_all.qh>
  39 #include "../common/state.qh"
  40
  41 const float LATENCY_THINKRATE = 10;
  42 .float latency_sum;
  43 .float latency_cnt;
  44 .float latency_time;
  45 entity pingplreport;
  46 void PingPLReport_Think(entity this)
  47 {
  48         float delta;
  49         entity e;
  50
  51         delta = 3 / maxclients;
  52         if(delta < sys_frametime)
  53                 delta = 0;
  54         this.nextthink = time + delta;
  55
  56         e = edict_num(this.cnt + 1);
  57         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  58         {
  59                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  60                 WriteByte(MSG_BROADCAST, this.cnt);
  61                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 65535));
  62                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  63                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  64
  65                 // record latency times for clients throughout the match so we can report it to playerstats
  66                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  67                 {
  68                         CS(e).latency_sum += CS(e).ping;
  69                         CS(e).latency_cnt += 1;
  70                         CS(e).latency_time = time;
  71                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  72                 }
  73         }
  74         else
  75         {
  76                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  77                 WriteByte(MSG_BROADCAST, this.cnt);
  78                 WriteShort(MSG_BROADCAST, 0);
  79                 WriteByte(MSG_BROADCAST, 0);
  80                 WriteByte(MSG_BROADCAST, 0);
  81         }
  82         this.cnt = (this.cnt + 1) % maxclients;
  83 }
  84 void PingPLReport_Spawn()
  85 {
  86         pingplreport = new_pure(pingplreport);
  87         setthink(pingplreport, PingPLReport_Think);
  88         pingplreport.nextthink = time;
  89 }
  90
  91 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  92 string redirection_target;
  93 float world_initialized;
  94
  95 string GetGametype();
  96 void ShuffleMaplist();
  97
  98 void SetDefaultAlpha()
  99 {
 100         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 101         {
 102                 default_player_alpha = autocvar_g_player_alpha;
 103                 if(default_player_alpha == 0)
 104                         default_player_alpha = 1;
 105                 default_weapon_alpha = default_player_alpha;
 106         }
 107 }
 108
 109 void GotoFirstMap(entity this)
 110 {
 111         float n;
 112         if(autocvar__sv_init)
 113         {
 114                 // cvar_set("_sv_init", "0");
 115                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 116                 // to this "init" map on a dedicated server will cause no permanent
 117                 // harm
 118                 if(autocvar_g_maplist_shuffle)
 119                         ShuffleMaplist();
 120                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 121                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 122
 123                 MapInfo_Enumerate();
 124                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 125
 126                 if(!DoNextMapOverride(1))
 127                         GotoNextMap(1);
 128
 129                 return;
 130         }
 131
 132         if(time < 5)
 133         {
 134                 this.nextthink = time;
 135         }
 136         else
 137         {
 138                 this.nextthink = time + 1;
 139                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 140         }
 141 }
 142
 143 void cvar_changes_init()
 144 {
 145         float h;
 146         string k, v, d;
 147         float n, i, adding, pureadding;
 148
 149         strfree(cvar_changes);
 150         strfree(cvar_purechanges);
 151         cvar_purechanges_count = 0;
 152
 153         h = buf_create();
 154         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 155         n = buf_getsize(h);
 156
 157         adding = true;
 158         pureadding = true;
 159
 160         for(i = 0; i < n; ++i)
 161         {
 162                 k = bufstr_get(h, i);
 163
 164 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 165 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 166 #define BADCVAR(p) if(k == p) continue
 167
 168                 // general excludes and namespaces for server admin used cvars
 169                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 170
 171                 // internal
 172                 BADPREFIX("csqc_");
 173                 BADPREFIX("cvar_check_");
 174                 BADCVAR("gamecfg");
 175                 BADCVAR("g_configversion");
 176                 BADCVAR("halflifebsp");
 177                 BADCVAR("sv_mapformat_is_quake2");
 178                 BADCVAR("sv_mapformat_is_quake3");
 179                 BADPREFIX("sv_world");
 180
 181                 // client
 182                 BADPREFIX("chase_");
 183                 BADPREFIX("cl_");
 184                 BADPREFIX("con_");
 185                 BADPREFIX("scoreboard_");
 186                 BADPREFIX("g_campaign");
 187                 BADPREFIX("g_waypointsprite_");
 188                 BADPREFIX("gl_");
 189                 BADPREFIX("joy");
 190                 BADPREFIX("hud_");
 191                 BADPREFIX("m_");
 192                 BADPREFIX("menu_");
 193                 BADPREFIX("net_slist_");
 194                 BADPREFIX("r_");
 195                 BADPREFIX("sbar_");
 196                 BADPREFIX("scr_");
 197                 BADPREFIX("snd_");
 198                 BADPREFIX("show");
 199                 BADPREFIX("sensitivity");
 200                 BADPREFIX("userbind");
 201                 BADPREFIX("v_");
 202                 BADPREFIX("vid_");
 203                 BADPREFIX("crosshair");
 204                 BADCVAR("mod_q3bsp_lightmapmergepower");
 205                 BADCVAR("mod_q3bsp_nolightmaps");
 206                 BADCVAR("fov");
 207                 BADCVAR("mastervolume");
 208                 BADCVAR("volume");
 209                 BADCVAR("bgmvolume");
 210                 BADCVAR("in_pitch_min");
 211                 BADCVAR("in_pitch_max");
 212
 213                 // private
 214                 BADCVAR("developer");
 215                 BADCVAR("log_dest_udp");
 216                 BADCVAR("net_address");
 217                 BADCVAR("net_address_ipv6");
 218                 BADCVAR("port");
 219                 BADCVAR("savedgamecfg");
 220                 BADCVAR("serverconfig");
 221                 BADCVAR("sv_autoscreenshot");
 222                 BADCVAR("sv_heartbeatperiod");
 223                 BADCVAR("sv_vote_master_password");
 224                 BADCVAR("sys_colortranslation");
 225                 BADCVAR("sys_specialcharactertranslation");
 226                 BADCVAR("timeformat");
 227                 BADCVAR("timestamps");
 228                 BADCVAR("g_require_stats");
 229                 BADPREFIX("developer_");
 230                 BADPREFIX("g_ban_");
 231                 BADPREFIX("g_banned_list");
 232                 BADPREFIX("g_require_stats_");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_voice_flood_");
 237                 BADPREFIX("log_file");
 238                 BADPREFIX("quit_");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252                 BADCVAR("sv_muteban_list");
 253                 BADCVAR("sv_voteban_list");
 254                 BADCVAR("sv_allow_customplayermodels_idlist");
 255                 BADCVAR("sv_allow_customplayermodels_speciallist");
 256
 257                 // mapinfo
 258                 BADCVAR("fraglimit");
 259                 BADCVAR("g_arena");
 260                 BADCVAR("g_assault");
 261                 BADCVAR("g_ca");
 262                 BADCVAR("g_ca_teams");
 263                 BADCVAR("g_conquest");
 264                 BADCVAR("g_ctf");
 265                 BADCVAR("g_cts");
 266                 BADCVAR("g_dotc");
 267                 BADCVAR("g_dm");
 268                 BADCVAR("g_domination");
 269                 BADCVAR("g_domination_default_teams");
 270                 BADCVAR("g_freezetag");
 271                 BADCVAR("g_freezetag_teams");
 272                 BADCVAR("g_invasion_teams");
 273                 BADCVAR("g_invasion_type");
 274                 BADCVAR("g_jailbreak");
 275                 BADCVAR("g_jailbreak_teams");
 276                 BADCVAR("g_keepaway");
 277                 BADCVAR("g_keyhunt");
 278                 BADCVAR("g_keyhunt_teams");
 279                 BADCVAR("g_lms");
 280                 BADCVAR("g_nexball");
 281                 BADCVAR("g_onslaught");
 282                 BADCVAR("g_race");
 283                 BADCVAR("g_race_laps_limit");
 284                 BADCVAR("g_race_qualifying_timelimit");
 285                 BADCVAR("g_race_qualifying_timelimit_override");
 286                 BADCVAR("g_runematch");
 287                 BADCVAR("g_snafu");
 288                 BADCVAR("g_tdm");
 289                 BADCVAR("g_tdm_teams");
 290                 BADCVAR("g_vip");
 291                 BADCVAR("leadlimit");
 292                 BADCVAR("nextmap");
 293                 BADCVAR("teamplay");
 294                 BADCVAR("timelimit");
 295                 BADCVAR("g_mapinfo_ignore_warnings");
 296
 297                 // long
 298                 BADCVAR("hostname");
 299                 BADCVAR("g_maplist");
 300                 BADCVAR("g_maplist_mostrecent");
 301                 BADCVAR("sv_motd");
 302
 303                 v = cvar_string(k);
 304                 d = cvar_defstring(k);
 305                 if(v == d)
 306                         continue;
 307
 308                 if(adding)
 309                 {
 310                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 311                         if(strlen(cvar_changes) > 16384)
 312                         {
 313                                 cvar_changes = "// too many settings have been changed to show them here\n";
 314                                 adding = 0;
 315                         }
 316                 }
 317
 318                 // now check if the changes are actually gameplay relevant
 319
 320                 // does nothing gameplay relevant
 321                 BADCVAR("captureleadlimit_override");
 322                 BADCVAR("condump_stripcolors");
 323                 BADCVAR("gameversion");
 324                 BADCVAR("g_allow_oldvortexbeam");
 325                 BADCVAR("g_balance_kill_delay");
 326                 BADCVAR("g_buffs_pickup_anyway");
 327                 BADCVAR("g_buffs_randomize");
 328                 BADCVAR("g_campcheck_distance");
 329                 BADCVAR("g_ca_point_leadlimit");
 330                 BADCVAR("g_ca_point_limit");
 331                 BADCVAR("g_ctf_captimerecord_always");
 332                 BADCVAR("g_ctf_flag_glowtrails");
 333                 BADCVAR("g_ctf_flag_pickup_verbosename");
 334                 BADCVAR("g_domination_point_leadlimit");
 335                 BADCVAR("g_forced_respawn");
 336                 BADCVAR("g_freezetag_point_leadlimit");
 337                 BADCVAR("g_freezetag_point_limit");
 338                 BADCVAR("g_hats");
 339                 BADCVAR("g_invasion_point_limit");
 340                 BADCVAR("g_jump_grunt");
 341                 BADCVAR("g_keyhunt_point_leadlimit");
 342                 BADCVAR("g_nexball_goalleadlimit");
 343                 BADCVAR("g_new_toys_use_pickupsound");
 344                 BADCVAR("g_physics_predictall");
 345                 BADCVAR("g_piggyback");
 346                 BADCVAR("g_playerclip_collisions");
 347                 BADCVAR("g_tdm_point_leadlimit");
 348                 BADCVAR("g_tdm_point_limit");
 349                 BADCVAR("leadlimit_and_fraglimit");
 350                 BADCVAR("leadlimit_override");
 351                 BADCVAR("pausable");
 352                 BADCVAR("sv_checkforpacketsduringsleep");
 353                 BADCVAR("sv_damagetext");
 354                 BADCVAR("sv_db_saveasdump");
 355                 BADCVAR("sv_intermission_cdtrack");
 356                 BADCVAR("sv_minigames");
 357                 BADCVAR("sv_namechangetimer");
 358                 BADCVAR("sv_precacheplayermodels");
 359                 BADCVAR("sv_stepheight");
 360                 BADCVAR("sv_timeout");
 361                 BADCVAR("sv_weapons_modeloverride");
 362                 BADPREFIX("crypto_");
 363                 BADPREFIX("gameversion_");
 364                 BADPREFIX("g_chat_");
 365                 BADPREFIX("g_ctf_captimerecord_");
 366                 BADPREFIX("g_maplist_");
 367                 BADPREFIX("g_mod_");
 368                 BADPREFIX("g_respawn_");
 369                 BADPREFIX("net_");
 370                 BADPREFIX("notification_");
 371                 BADPREFIX("prvm_");
 372                 BADPREFIX("skill_");
 373                 BADPREFIX("sv_allow_");
 374                 BADPREFIX("sv_cullentities_");
 375                 BADPREFIX("sv_maxidle_");
 376                 BADPREFIX("sv_minigames_");
 377                 BADPREFIX("sv_radio_");
 378                 BADPREFIX("sv_timeout_");
 379                 BADPREFIX("sv_vote_");
 380                 BADPREFIX("timelimit_");
 381
 382                 // allowed changes to server admins (please sync this to server.cfg)
 383                 // vi commands:
 384                 //   :/"impure"/,$d
 385                 //   :g!,^\/\/[^ /],d
 386                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 387                 //   :%!sort
 388                 // yes, this does contain some redundant stuff, don't really care
 389                 BADCVAR("bot_config_file");
 390                 BADCVAR("bot_number");
 391                 BADCVAR("bot_prefix");
 392                 BADCVAR("bot_suffix");
 393                 BADCVAR("capturelimit_override");
 394                 BADCVAR("fraglimit_override");
 395                 BADCVAR("gametype");
 396                 BADCVAR("g_antilag");
 397                 BADCVAR("g_balance_teams");
 398                 BADCVAR("g_balance_teams_prevent_imbalance");
 399                 BADCVAR("g_balance_teams_scorefactor");
 400                 BADCVAR("g_ban_sync_trusted_servers");
 401                 BADCVAR("g_ban_sync_uri");
 402                 BADCVAR("g_buffs");
 403                 BADCVAR("g_ca_teams_override");
 404                 BADCVAR("g_ctf_ignore_frags");
 405                 BADCVAR("g_ctf_leaderboard");
 406                 BADCVAR("g_domination_point_limit");
 407                 BADCVAR("g_domination_teams_override");
 408                 BADCVAR("g_freezetag_teams_override");
 409                 BADCVAR("g_friendlyfire");
 410                 BADCVAR("g_fullbrightitems");
 411                 BADCVAR("g_fullbrightplayers");
 412                 BADCVAR("g_keyhunt_point_limit");
 413                 BADCVAR("g_keyhunt_teams_override");
 414                 BADCVAR("g_lms_lives_override");
 415                 BADCVAR("g_maplist");
 416                 BADCVAR("g_maxplayers");
 417                 BADCVAR("g_mirrordamage");
 418                 BADCVAR("g_nexball_goallimit");
 419                 BADCVAR("g_norecoil");
 420                 BADCVAR("g_physics_clientselect");
 421                 BADCVAR("g_pinata");
 422                 BADCVAR("g_powerups");
 423                 BADCVAR("g_spawnshieldtime");
 424                 BADCVAR("g_start_delay");
 425                 BADCVAR("g_superspectate");
 426                 BADCVAR("g_tdm_teams_override");
 427                 BADCVAR("g_warmup");
 428                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 429                 BADCVAR("hostname");
 430                 BADCVAR("log_file");
 431                 BADCVAR("maxplayers");
 432                 BADCVAR("minplayers");
 433                 BADCVAR("net_address");
 434                 BADCVAR("port");
 435                 BADCVAR("rcon_password");
 436                 BADCVAR("rcon_restricted_commands");
 437                 BADCVAR("rcon_restricted_password");
 438                 BADCVAR("skill");
 439                 BADCVAR("sv_adminnick");
 440                 BADCVAR("sv_autoscreenshot");
 441                 BADCVAR("sv_autotaunt");
 442                 BADCVAR("sv_curl_defaulturl");
 443                 BADCVAR("sv_defaultcharacter");
 444                 BADCVAR("sv_defaultcharacterskin");
 445                 BADCVAR("sv_defaultplayercolors");
 446                 BADCVAR("sv_defaultplayermodel");
 447                 BADCVAR("sv_defaultplayerskin");
 448                 BADCVAR("sv_maxidle");
 449                 BADCVAR("sv_maxrate");
 450                 BADCVAR("sv_motd");
 451                 BADCVAR("sv_public");
 452                 BADCVAR("sv_ready_restart");
 453                 BADCVAR("sv_status_privacy");
 454                 BADCVAR("sv_taunt");
 455                 BADCVAR("sv_vote_call");
 456                 BADCVAR("sv_vote_commands");
 457                 BADCVAR("sv_vote_majority_factor");
 458                 BADCVAR("sv_vote_master");
 459                 BADCVAR("sv_vote_master_commands");
 460                 BADCVAR("sv_vote_master_password");
 461                 BADCVAR("sv_vote_simple_majority_factor");
 462                 BADCVAR("teamplay_mode");
 463                 BADCVAR("timelimit_override");
 464                 BADPREFIX("g_warmup_");
 465                 BADPREFIX("sv_info_");
 466                 BADPREFIX("sv_ready_restart_");
 467
 468                 // mutators that announce themselves properly to the server browser
 469                 BADCVAR("g_instagib");
 470                 BADCVAR("g_new_toys");
 471                 BADCVAR("g_nix");
 472                 BADCVAR("g_grappling_hook");
 473                 BADCVAR("g_jetpack");
 474
 475 #undef BADPRESUFFIX
 476 #undef BADPREFIX
 477 #undef BADCVAR
 478
 479                 if(pureadding)
 480                 {
 481                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 482                         if(strlen(cvar_purechanges) > 16384)
 483                         {
 484                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 485                                 pureadding = 0;
 486                         }
 487                 }
 488                 ++cvar_purechanges_count;
 489                 // WARNING: this variable is used for the server list
 490                 // NEVER dare to skip this code!
 491                 // Hacks to intentionally appearing as "pure server" even though you DO have
 492                 // modified settings may be punished by removal from the server list.
 493                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 494                 // though.
 495         }
 496         buf_del(h);
 497         if(cvar_changes == "")
 498                 cvar_changes = "// this server runs at default server settings\n";
 499         else
 500                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 501         cvar_changes = strzone(cvar_changes);
 502         if(cvar_purechanges == "")
 503                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 504         else
 505                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 506         cvar_purechanges = strzone(cvar_purechanges);
 507 }
 508
 509 entity randomseed;
 510 bool RandomSeed_Send(entity this, entity to, int sf)
 511 {
 512         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 513         WriteShort(MSG_ENTITY, this.cnt);
 514         return true;
 515 }
 516 void RandomSeed_Think(entity this)
 517 {
 518         this.cnt = bound(0, floor(random() * 65536), 65535);
 519         this.nextthink = time + 5;
 520
 521         this.SendFlags |= 1;
 522 }
 523 void RandomSeed_Spawn()
 524 {
 525         randomseed = new_pure(randomseed);
 526         setthink(randomseed, RandomSeed_Think);
 527         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 528
 529         getthink(randomseed)(randomseed); // sets random seed and nextthink
 530 }
 531
 532 spawnfunc(__init_dedicated_server)
 533 {
 534         // handler for _init/_init map (only for dedicated server initialization)
 535
 536         world_initialized = -1; // don't complain
 537         cvar = cvar_normal;
 538         cvar_string = cvar_string_normal;
 539         cvar_set = cvar_set_normal;
 540
 541         delete_fn = remove_unsafely;
 542
 543         entity e = spawn();
 544         setthink(e, GotoFirstMap);
 545         e.nextthink = time; // this is usually 1 at this point
 546
 547         e = new(info_player_deathmatch);  // safeguard against player joining
 548
 549     // assign reflectively to avoid "assignment to world" warning
 550     for (int i = 0, n = numentityfields(); i < n; ++i) {
 551         string k = entityfieldname(i);
 552         if (k == "classname") {
 553             // safeguard against various stuff ;)
 554             putentityfieldstring(i, this, "worldspawn");
 555             break;
 556         }
 557     }
 558
 559         // needs to be done so early because of the constants they create
 560         static_init();
 561         static_init_late();
 562         static_init_precache();
 563
 564         IL_PUSH(g_spawnpoints, e); // just incase
 565
 566         MapInfo_Enumerate();
 567         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 568 }
 569
 570 void __init_dedicated_server_shutdown() {
 571         MapInfo_Shutdown();
 572 }
 573
 574 STATIC_INIT_EARLY(maxclients)
 575 {
 576         maxclients = 0;
 577         for (entity head = nextent(NULL); head; head = nextent(head)) {
 578                 ++maxclients;
 579         }
 580 }
 581
 582 void Map_MarkAsRecent(string m);
 583 float world_already_spawned;
 584 void Nagger_Init();
 585 void ClientInit_Spawn();
 586 void WeaponStats_Init();
 587 void WeaponStats_Shutdown();
 588 spawnfunc(worldspawn)
 589 {
 590         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 591
 592     bool wantrestart = false;
 593         {
 594                 if (!server_is_dedicated)
 595                 {
 596                         // force unloading of server pk3 files when starting a listen server
 597                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 598                         // restore csqc_progname too
 599                         string expect = "csprogs.dat";
 600                         wantrestart = cvar_string_normal("csqc_progname") != expect;
 601                         cvar_set_normal("csqc_progname", expect);
 602                 }
 603                 else
 604                 {
 605                         // Try to use versioned csprogs from pk3
 606                         // Only ever use versioned csprogs.dat files on dedicated servers;
 607                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 608                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 609                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 610                         string select = "csprogs.dat";
 611                         if (fexists(pk3csprogs)) select = pk3csprogs;
 612                         if (cvar_string_normal("csqc_progname") != select)
 613                         {
 614                                 cvar_set_normal("csqc_progname", select);
 615                                 wantrestart = true;
 616                         }
 617                         // Check for updates on startup
 618                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 619                         int sentinel = fopen("progs.txt", FILE_READ);
 620                         if (sentinel >= 0)
 621                         {
 622                                 string switchversion = fgets(sentinel);
 623                                 fclose(sentinel);
 624                                 if (switchversion != "" && switchversion != WATERMARK)
 625                                 {
 626                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 627                                         // if it doesn't exist, assume either:
 628                                         //   a) the current program was overwritten
 629                                         //   b) this is a client only update
 630                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 631                                         if (fexists(newprogs))
 632                                         {
 633                                                 cvar_set_normal("sv_progs", newprogs);
 634                                                 wantrestart = true;
 635                                         }
 636                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 637                                         if (fexists(newcsprogs))
 638                                         {
 639                                                 cvar_set_normal("csqc_progname", newcsprogs);
 640                                                 wantrestart = true;
 641                                         }
 642                                 }
 643                         }
 644                 }
 645                 if (wantrestart)
 646                 {
 647                         LOG_INFOF("Restart requested");
 648                         changelevel(mapname);
 649                         // let initialization continue, shutdown depends on it
 650                 }
 651         }
 652
 653         cvar = cvar_normal;
 654         cvar_string = cvar_string_normal;
 655         cvar_set = cvar_set_normal;
 656
 657         if(world_already_spawned)
 658                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 659         world_already_spawned = true;
 660
 661         delete_fn = remove_safely; // during spawning, watch what you remove!
 662
 663         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 664
 665         // needs to be done so early because of the constants they create
 666         static_init();
 667
 668         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 669
 670         TemporaryDB = db_create();
 671
 672         // 0 normal
 673         lightstyle(0, "m");
 674
 675         // 1 FLICKER (first variety)
 676         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 677
 678         // 2 SLOW STRONG PULSE
 679         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 680
 681         // 3 CANDLE (first variety)
 682         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 683
 684         // 4 FAST STROBE
 685         lightstyle(4, "mamamamamama");
 686
 687         // 5 GENTLE PULSE 1
 688         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 689
 690         // 6 FLICKER (second variety)
 691         lightstyle(6, "nmonqnmomnmomomno");
 692
 693         // 7 CANDLE (second variety)
 694         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 695
 696         // 8 CANDLE (third variety)
 697         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 698
 699         // 9 SLOW STROBE (fourth variety)
 700         lightstyle(9, "aaaaaaaazzzzzzzz");
 701
 702         // 10 FLUORESCENT FLICKER
 703         lightstyle(10, "mmamammmmammamamaaamammma");
 704
 705         // 11 SLOW PULSE NOT FADE TO BLACK
 706         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 707
 708         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 709
 710         // 63 testing
 711         lightstyle(63, "a");
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPreInit();
 715
 716         Map_MarkAsRecent(mapname);
 717
 718         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 719
 720         InitGameplayMode();
 721         static_init_late();
 722         static_init_precache();
 723         readlevelcvars();
 724         GrappleHookInit();
 725
 726     GameRules_limit_fallbacks();
 727
 728         if(warmup_limit == 0)
 729                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 730
 731         player_count = 0;
 732         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 733         if(bot_waypoints_for_items == 1)
 734                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 735                         bot_waypoints_for_items = 0;
 736
 737         precache();
 738
 739         WaypointSprite_Init();
 740
 741         GameLogInit(); // prepare everything
 742         // NOTE for matchid:
 743         // changing the logic generating it is okay. But:
 744         // it HAS to stay <= 64 chars
 745         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 746         if(autocvar_sv_eventlog)
 747         {
 748                 string s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 749                 matchid = strzone(s);
 750
 751                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 752                 s = ":gameinfo:mutators:LIST";
 753
 754                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 755                 s = M_ARGV(0, string);
 756
 757                 // initialiation stuff, not good in the mutator system
 758                 if(!autocvar_g_use_ammunition)
 759                         s = strcat(s, ":no_use_ammunition");
 760
 761                 // initialiation stuff, not good in the mutator system
 762                 if(autocvar_g_pickup_items == 0)
 763                         s = strcat(s, ":no_pickup_items");
 764                 if(autocvar_g_pickup_items > 0)
 765                         s = strcat(s, ":pickup_items");
 766
 767                 // initialiation stuff, not good in the mutator system
 768                 if(autocvar_g_weaponarena != "0")
 769                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 770
 771                 // TODO to mutator system
 772                 if(autocvar_g_norecoil)
 773                         s = strcat(s, ":norecoil");
 774
 775                 // TODO to mutator system
 776                 if(autocvar_g_powerups == 0)
 777                         s = strcat(s, ":no_powerups");
 778                 if(autocvar_g_powerups > 0)
 779                         s = strcat(s, ":powerups");
 780
 781                 GameLogEcho(s);
 782                 GameLogEcho(":gameinfo:end");
 783         }
 784         else
 785                 matchid = strzone(ftos(random()));
 786
 787         cvar_set("nextmap", "");
 788
 789         SetDefaultAlpha();
 790
 791         if(autocvar_g_campaign)
 792                 CampaignPostInit();
 793
 794         Ban_LoadBans();
 795
 796         MapInfo_Enumerate();
 797         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 798
 799         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 800         {
 801                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 802                 if(fd != -1)
 803                 {
 804                         string s;
 805                         while((s = fgets(fd)))
 806                         {
 807                                 int l = tokenize_console(s);
 808                                 if(l < 2)
 809                                         continue;
 810                                 if(argv(0) == "cd")
 811                                 {
 812                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 813                                         LOG_INFO("  cdtrack ", argv(2));
 814                                 }
 815                                 else if(argv(0) == "fog")
 816                                 {
 817                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 818                                         LOG_INFO("  \"fog\" \"", s, "\"");
 819                                 }
 820                                 else if(argv(0) == "set")
 821                                 {
 822                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 823                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 824                                 }
 825                                 else if(argv(0) != "//")
 826                                 {
 827                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 828                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 829                                 }
 830                         }
 831                         fclose(fd);
 832                 }
 833         }
 834
 835         WeaponStats_Init();
 836
 837         Nagger_Init();
 838
 839         next_pingtime = time + 5;
 840
 841         // set up information replies for clients and server to use
 842         maplist_reply = strzone(getmaplist());
 843         lsmaps_reply = strzone(getlsmaps());
 844         monsterlist_reply = strzone(getmonsterlist());
 845         for(int i = 0; i < 10; ++i)
 846         {
 847                 string s = getrecords(i);
 848                 if (s)
 849                         records_reply[i] = strzone(s);
 850         }
 851         ladder_reply = strzone(getladder());
 852         rankings_reply = strzone(getrankings());
 853
 854         // begin other init
 855         ClientInit_Spawn();
 856         RandomSeed_Spawn();
 857         PingPLReport_Spawn();
 858
 859         CheatInit();
 860
 861         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 862
 863         // fill sv_curl_serverpackages from .serverpackage files
 864         if (autocvar_sv_curl_serverpackages_auto)
 865         {
 866                 string s = "csprogs-" WATERMARK ".txt";
 867                 // remove automatically managed files from the list to prevent duplicates
 868                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 869                 {
 870                         string pkg = argv(i);
 871                         if (startsWith(pkg, "csprogs-")) continue;
 872                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 873                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 874                         s = cons(s, pkg);
 875                 }
 876                 // add automatically managed files to the list
 877                 #define X(match) MACRO_BEGIN { \
 878                         int fd = search_begin(match, true, false); \
 879                         if (fd >= 0) \
 880                         { \
 881                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 882                                 { \
 883                                         s = cons(s, search_getfilename(fd, i)); \
 884                                 } \
 885                                 search_end(fd); \
 886                         } \
 887                 } MACRO_END
 888                 X("*-serverpackage.txt");
 889                 X("*.serverpackage");
 890                 #undef X
 891                 cvar_set("sv_curl_serverpackages", s);
 892         }
 893
 894         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 895         modname = "Xonotic";
 896         // physics/balance/config changes that count as mod
 897         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 898                 modname = cvar_string("g_mod_physics");
 899         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 900                 modname = cvar_string("g_mod_balance");
 901         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 902                 modname = cvar_string("g_mod_config");
 903         // extra mutators that deserve to count as mod
 904         MUTATOR_CALLHOOK(SetModname, modname);
 905         modname = M_ARGV(0, string);
 906
 907         // save it for later
 908         modname = strzone(modname);
 909
 910         WinningConditionHelper(this); // set worldstatus
 911
 912         world_initialized = 1;
 913         __spawnfunc_spawn_all();
 914 }
 915
 916 spawnfunc(light)
 917 {
 918         //makestatic (this); // Who the f___ did that?
 919         delete(this);
 920 }
 921
 922 string GetGametype()
 923 {
 924         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 925 }
 926
 927 string GetMapname()
 928 {
 929         return mapname;
 930 }
 931
 932 float Map_Count, Map_Current;
 933 string Map_Current_Name;
 934
 935 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 936 float GetMaplistPosition()
 937 {
 938         float pos, idx;
 939         string map;
 940
 941         map = GetMapname();
 942         idx = autocvar_g_maplist_index;
 943
 944         if(idx >= 0)
 945                 if(idx < Map_Count)
 946                         if(map == argv(idx))
 947                                 return idx;
 948
 949         for(pos = 0; pos < Map_Count; ++pos)
 950                 if(map == argv(pos))
 951                         return pos;
 952
 953         // resume normal maplist rotation if current map is not in g_maplist
 954         return idx;
 955 }
 956
 957 bool MapHasRightSize(string map)
 958 {
 959         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 960         if(autocvar_g_maplist_check_waypoints)
 961         {
 962                 string checkwp_msg = strcat("checkwp ", map);
 963                 if(!fexists(strcat("maps/", map, ".waypoints")))
 964                 {
 965                         LOG_TRACE(checkwp_msg, ": no waypoints");
 966                         return false;
 967                 }
 968                 LOG_TRACE(checkwp_msg, ": has waypoints");
 969         }
 970
 971         // open map size restriction file
 972         string opensize_msg = strcat("opensize ", map);
 973         float fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 974         if(fh >= 0)
 975         {
 976                 opensize_msg = strcat(opensize_msg, ": ok, ");
 977                 int mapmin = stoi(fgets(fh));
 978                 int mapmax = stoi(fgets(fh));
 979                 fclose(fh);
 980                 if(player_count < mapmin)
 981                 {
 982                         LOG_TRACE(opensize_msg, "not enough");
 983                         return false;
 984                 }
 985                 if(mapmax && player_count > mapmax)
 986                 {
 987                         LOG_TRACE(opensize_msg, "too many");
 988                         return false;
 989                 }
 990                 LOG_TRACE(opensize_msg, "right size");
 991                 return true;
 992         }
 993         LOG_TRACE(opensize_msg, ": not found");
 994         return true;
 995 }
 996
 997 string Map_Filename(float position)
 998 {
 999         return strcat("maps/", argv(position), ".bsp");
1000 }
1001
1002 void Map_MarkAsRecent(string m)
1003 {
1004         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1005 }
1006
1007 float Map_IsRecent(string m)
1008 {
1009         return strhasword(autocvar_g_maplist_mostrecent, m);
1010 }
1011
1012 float Map_Check(float position, float pass)
1013 {
1014         string filename;
1015         string map_next;
1016         map_next = argv(position);
1017         if(pass <= 1)
1018         {
1019                 if(Map_IsRecent(map_next))
1020                         return 0;
1021         }
1022         filename = Map_Filename(position);
1023         if(MapInfo_CheckMap(map_next))
1024         {
1025                 if(pass == 2)
1026                         return 1;
1027                 if(MapHasRightSize(map_next))
1028                         return 1;
1029                 return 0;
1030         }
1031         else
1032                 LOG_DEBUG( "Couldn't select '", filename, "'..." );
1033
1034         return 0;
1035 }
1036
1037 void Map_Goto_SetStr(string nextmapname)
1038 {
1039         if(getmapname_stored != "")
1040                 strunzone(getmapname_stored);
1041         if(nextmapname == "")
1042                 getmapname_stored = "";
1043         else
1044                 getmapname_stored = strzone(nextmapname);
1045 }
1046
1047 void Map_Goto_SetFloat(float position)
1048 {
1049         cvar_set("g_maplist_index", ftos(position));
1050         Map_Goto_SetStr(argv(position));
1051 }
1052
1053 void Map_Goto(float reinit)
1054 {
1055         MapInfo_LoadMap(getmapname_stored, reinit);
1056 }
1057
1058 // return codes of map selectors:
1059 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1060 //   -2 = permanent failure
1061 float() MaplistMethod_Iterate = // usual method
1062 {
1063         float pass, i;
1064
1065         LOG_TRACE("Trying MaplistMethod_Iterate");
1066
1067         for(pass = 1; pass <= 2; ++pass)
1068         {
1069                 for(i = 1; i < Map_Count; ++i)
1070                 {
1071                         float mapindex;
1072                         mapindex = (i + Map_Current) % Map_Count;
1073                         if(Map_Check(mapindex, pass))
1074                                 return mapindex;
1075                 }
1076         }
1077         return -1;
1078 }
1079
1080 float() MaplistMethod_Repeat = // fallback method
1081 {
1082         LOG_TRACE("Trying MaplistMethod_Repeat");
1083
1084         if(Map_Check(Map_Current, 2))
1085                 return Map_Current;
1086         return -2;
1087 }
1088
1089 float() MaplistMethod_Random = // random map selection
1090 {
1091         float i, imax;
1092
1093         LOG_TRACE("Trying MaplistMethod_Random");
1094
1095         imax = 42;
1096
1097         for(i = 0; i <= imax; ++i)
1098         {
1099                 float mapindex;
1100                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1101                 if(Map_Check(mapindex, 1))
1102                         return mapindex;
1103         }
1104         return -1;
1105 }
1106
1107 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1108 // the exponent sets a bias on the map selection:
1109 // the higher the exponent, the less likely "shortly repeated" same maps are
1110 {
1111         float i, j, imax, insertpos;
1112
1113         LOG_TRACE("Trying MaplistMethod_Shuffle");
1114
1115         imax = 42;
1116
1117         for(i = 0; i <= imax; ++i)
1118         {
1119                 string newlist;
1120
1121                 // now reinsert this at another position
1122                 insertpos = (random() ** (1 / exponent));       // ]0, 1]
1123                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1124                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1125                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos));
1126
1127                 // insert the current map there
1128                 newlist = "";
1129                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1130                         newlist = strcat(newlist, " ", argv(j));
1131                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1132                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1133                         newlist = strcat(newlist, " ", argv(j));
1134                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1135                 cvar_set("g_maplist", newlist);
1136                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1137
1138                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1139                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1140                 if(Map_Check(Map_Current, 1))
1141                         return Map_Current;
1142         }
1143         return -1;
1144 }
1145
1146 void Maplist_Init()
1147 {
1148         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1149         float i;
1150         for (i = 0; i < Map_Count; ++i)
1151                 if (Map_Check(i, 2))
1152                         break;
1153         if (i == Map_Count)
1154         {
1155                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1156                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1157                 if(autocvar_g_maplist_shuffle)
1158                         ShuffleMaplist();
1159                 localcmd("\nmenu_cmd sync\n");
1160                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1161         }
1162         if(Map_Count == 0)
1163                 error("empty maplist, cannot select a new map");
1164         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1165
1166         strcpy(Map_Current_Name, argv(Map_Current)); // will be automatically freed on exit thanks to DP
1167         // this may or may not be correct, but who cares, in the worst case a map
1168         // isn't chosen in the first pass that should have been
1169 }
1170
1171 string GetNextMap()
1172 {
1173         float nextMap;
1174
1175         Maplist_Init();
1176         nextMap = -1;
1177
1178         if(nextMap == -1)
1179                 if(autocvar_g_maplist_shuffle > 0)
1180                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1181
1182         if(nextMap == -1)
1183                 if(autocvar_g_maplist_selectrandom)
1184                         nextMap = MaplistMethod_Random();
1185
1186         if(nextMap == -1)
1187                 nextMap = MaplistMethod_Iterate();
1188
1189         if(nextMap == -1)
1190                 nextMap = MaplistMethod_Repeat();
1191
1192         if(nextMap >= 0)
1193         {
1194                 Map_Goto_SetFloat(nextMap);
1195                 return getmapname_stored;
1196         }
1197
1198         return "";
1199 }
1200
1201 float DoNextMapOverride(float reinit)
1202 {
1203         if(autocvar_g_campaign)
1204         {
1205                 CampaignPostIntermission();
1206                 alreadychangedlevel = true;
1207                 return true;
1208         }
1209         if(autocvar_quit_when_empty)
1210         {
1211                 if(player_count <= currentbots)
1212                 {
1213                         localcmd("quit\n");
1214                         alreadychangedlevel = true;
1215                         return true;
1216                 }
1217         }
1218         if(autocvar_quit_and_redirect != "")
1219         {
1220                 redirection_target = strzone(autocvar_quit_and_redirect);
1221                 alreadychangedlevel = true;
1222                 return true;
1223         }
1224         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1225         {
1226                 localcmd("restart\n");
1227                 alreadychangedlevel = true;
1228                 return true;
1229         }
1230         if(autocvar_nextmap != "")
1231         {
1232                 string m;
1233                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1234                 cvar_set("nextmap",m);
1235
1236                 if(!m || gametypevote)
1237                         return false;
1238                 if(autocvar_sv_vote_gametype)
1239                 {
1240                         Map_Goto_SetStr(m);
1241                         return false;
1242                 }
1243
1244                 if(MapInfo_CheckMap(m))
1245                 {
1246                         Map_Goto_SetStr(m);
1247                         Map_Goto(reinit);
1248                         alreadychangedlevel = true;
1249                         return true;
1250                 }
1251         }
1252         if(!reinit && autocvar_lastlevel)
1253         {
1254                 cvar_settemp_restore();
1255                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1256                 alreadychangedlevel = true;
1257                 return true;
1258         }
1259         return false;
1260 }
1261
1262 void GotoNextMap(float reinit)
1263 {
1264         //string nextmap;
1265         //float n, nummaps;
1266         //string s;
1267         if (alreadychangedlevel)
1268                 return;
1269         alreadychangedlevel = true;
1270
1271         string nextMap;
1272
1273         nextMap = GetNextMap();
1274         if(nextMap == "")
1275                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1276         Map_Goto(reinit);
1277 }
1278
1279
1280 /*
1281 ============
1282 IntermissionThink
1283
1284 When the player presses attack or jump, change to the next level
1285 ============
1286 */
1287 .float autoscreenshot;
1288 void IntermissionThink(entity this)
1289 {
1290         FixIntermissionClient(this);
1291
1292         float server_screenshot = (autocvar_sv_autoscreenshot && CS(this).cvar_cl_autoscreenshot);
1293         float client_screenshot = (CS(this).cvar_cl_autoscreenshot == 2);
1294
1295         if( (server_screenshot || client_screenshot)
1296                 && ((this.autoscreenshot > 0) && (time > this.autoscreenshot)) )
1297         {
1298                 this.autoscreenshot = -1;
1299                 if(IS_REAL_CLIENT(this)) { stuffcmd(this, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1300                 return;
1301         }
1302
1303         if (time < intermission_exittime)
1304                 return;
1305
1306         if(!mapvote_initialized)
1307                 if (time < intermission_exittime + 10 && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this)))
1308                         return;
1309
1310         MapVote_Start();
1311 }
1312
1313 /*
1314 ============
1315 FindIntermission
1316
1317 Returns the entity to view from
1318 ============
1319 */
1320 /*
1321 entity FindIntermission()
1322 {
1323         local   entity spot;
1324         local   float cyc;
1325
1326 // look for info_intermission first
1327         spot = find(NULL, classname, "info_intermission");
1328         if (spot)
1329         {       // pick a random one
1330                 cyc = random() * 4;
1331                 while (cyc > 1)
1332                 {
1333                         spot = find(spot, classname, "info_intermission");
1334                         if (!spot)
1335                                 spot = find(spot, classname, "info_intermission");
1336                         cyc = cyc - 1;
1337                 }
1338                 return spot;
1339         }
1340
1341 // then look for the start position
1342         spot = find(NULL, classname, "info_player_start");
1343         if (spot)
1344                 return spot;
1345
1346 // testinfo_player_start is only found in regioned levels
1347         spot = find(NULL, classname, "testplayerstart");
1348         if (spot)
1349                 return spot;
1350
1351 // then look for the start position
1352         spot = find(NULL, classname, "info_player_deathmatch");
1353         if (spot)
1354                 return spot;
1355
1356         //objerror ("FindIntermission: no spot");
1357         return NULL;
1358 }
1359 */
1360
1361 /*
1362 ===============================================================================
1363
1364 RULES
1365
1366 ===============================================================================
1367 */
1368
1369 void DumpStats(float final)
1370 {
1371         float file;
1372         string s;
1373         float to_console;
1374         float to_eventlog;
1375         float to_file;
1376         float i;
1377
1378         to_console = autocvar_sv_logscores_console;
1379         to_eventlog = autocvar_sv_eventlog;
1380         to_file = autocvar_sv_logscores_file;
1381
1382         if(!final)
1383         {
1384                 to_console = true; // always print printstats replies
1385                 to_eventlog = false; // but never print them to the event log
1386         }
1387
1388         if(to_eventlog)
1389                 if(autocvar_sv_eventlog_console)
1390                         to_console = false; // otherwise we get the output twice
1391
1392         if(final)
1393                 s = ":scores:";
1394         else
1395                 s = ":status:";
1396         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1397
1398         if(to_console)
1399                 LOG_INFO(s);
1400         if(to_eventlog)
1401                 GameLogEcho(s);
1402
1403         file = -1;
1404         if(to_file)
1405         {
1406                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1407                 if(file == -1)
1408                         to_file = false;
1409                 else
1410                         fputs(file, strcat(s, "\n"));
1411         }
1412
1413         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1414         if(to_console)
1415                 LOG_INFO(s);
1416         if(to_eventlog)
1417                 GameLogEcho(s);
1418         if(to_file)
1419                 fputs(file, strcat(s, "\n"));
1420
1421         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1422                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1423                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1424                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1425                         s = strcat(s, ftos(it.team), ":");
1426                 else
1427                         s = strcat(s, "spectator:");
1428
1429                 if(to_console)
1430                         LOG_INFO(s, playername(it, false));
1431                 if(to_eventlog)
1432                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it, false)));
1433                 if(to_file)
1434                         fputs(file, strcat(s, playername(it, false), "\n"));
1435         });
1436
1437         if(teamplay)
1438         {
1439                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1440                 if(to_console)
1441                         LOG_INFO(s);
1442                 if(to_eventlog)
1443                         GameLogEcho(s);
1444                 if(to_file)
1445                         fputs(file, strcat(s, "\n"));
1446
1447                 for(i = 1; i < 16; ++i)
1448                 {
1449                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1450                         s = strcat(s, ":", ftos(i));
1451                         if(to_console)
1452                                 LOG_INFO(s);
1453                         if(to_eventlog)
1454                                 GameLogEcho(s);
1455                         if(to_file)
1456                                 fputs(file, strcat(s, "\n"));
1457                 }
1458         }
1459
1460         if(to_console)
1461                 LOG_INFO(":end");
1462         if(to_eventlog)
1463                 GameLogEcho(":end");
1464         if(to_file)
1465         {
1466                 fputs(file, ":end\n");
1467                 fclose(file);
1468         }
1469 }
1470
1471 void FixIntermissionClient(entity e)
1472 {
1473         if(!e.autoscreenshot) // initial call
1474         {
1475                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1476                 e.health = -2342;
1477                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1478                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1479                 {
1480                     .entity weaponentity = weaponentities[slot];
1481                         if(e.(weaponentity))
1482                         {
1483                                 e.(weaponentity).effects = EF_NODRAW;
1484                                 if (e.(weaponentity).weaponchild)
1485                                         e.(weaponentity).weaponchild.effects = EF_NODRAW;
1486                         }
1487                 }
1488                 if(IS_REAL_CLIENT(e))
1489                 {
1490                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1491                         RandomSelection_Init();
1492                         FOREACH_WORD(autocvar_sv_intermission_cdtrack, true, {
1493                                 RandomSelection_AddString(it, 1, 1);
1494                         });
1495                         if (RandomSelection_chosen_string != "")
1496                         {
1497                                 stuffcmd(e, sprintf("\ncd loop %s\n", RandomSelection_chosen_string));
1498                         }
1499                         msg_entity = e;
1500                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1501                 }
1502         }
1503 }
1504
1505 /*
1506 go to the next level for deathmatch
1507 only called if a time or frag limit has expired
1508 */
1509 void NextLevel()
1510 {
1511         game_stopped = true;
1512         intermission_running = 1; // game over
1513
1514         // enforce a wait time before allowing changelevel
1515         if(player_count > 0)
1516                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1517         else
1518                 intermission_exittime = -1;
1519
1520         /*
1521         WriteByte (MSG_ALL, SVC_CDTRACK);
1522         WriteByte (MSG_ALL, 3);
1523         WriteByte (MSG_ALL, 3);
1524         // done in FixIntermission
1525         */
1526
1527         //pos = FindIntermission ();
1528
1529         VoteReset();
1530
1531         DumpStats(true);
1532
1533         // send statistics
1534         PlayerStats_GameReport(true);
1535         WeaponStats_Shutdown();
1536
1537         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1538
1539         if(autocvar_sv_eventlog)
1540                 GameLogEcho(":gameover");
1541
1542         GameLogClose();
1543
1544         FOREACH_CLIENT(IS_PLAYER(it), {
1545                 FixIntermissionClient(it);
1546                 if(it.winning)
1547                         bprint(playername(it, false), " ^7wins.\n");
1548         });
1549
1550         target_music_kill();
1551
1552         if(autocvar_g_campaign)
1553                 CampaignPreIntermission();
1554
1555         MUTATOR_CALLHOOK(MatchEnd);
1556
1557         localcmd("\nsv_hook_gameend\n");
1558 }
1559
1560
1561 float InitiateSuddenDeath()
1562 {
1563         // Check first whether normal overtimes could be added before initiating suddendeath mode
1564         // - for this timelimit_overtime needs to be >0 of course
1565         // - also check the winning condition calculated in the previous frame and only add normal overtime
1566         //   again, if at the point at which timelimit would be extended again, still no winner was found
1567         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1568         {
1569                 return 1; // need to call InitiateOvertime later
1570         }
1571         else
1572         {
1573                 if(!checkrules_suddendeathend)
1574                 {
1575                         if(autocvar_g_campaign)
1576                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1577                         else
1578                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1579                         if(g_race && !g_race_qualifying)
1580                                 race_StartCompleting();
1581                 }
1582                 return 0;
1583         }
1584 }
1585
1586 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1587 {
1588         ++checkrules_overtimesadded;
1589         //add one more overtime by simply extending the timelimit
1590         float tl;
1591         tl = autocvar_timelimit;
1592         tl += autocvar_timelimit_overtime;
1593         cvar_set("timelimit", ftos(tl));
1594
1595         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1596 }
1597
1598 float GetWinningCode(float fraglimitreached, float equality)
1599 {
1600         if(autocvar_g_campaign == 1)
1601                 if(fraglimitreached)
1602                         return WINNING_YES;
1603                 else
1604                         return WINNING_NO;
1605
1606         else
1607                 if(equality)
1608                         if(fraglimitreached)
1609                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1610                         else
1611                                 return WINNING_NEVER;
1612                 else
1613                         if(fraglimitreached)
1614                                 return WINNING_YES;
1615                         else
1616                                 return WINNING_NO;
1617 }
1618
1619 // set the .winning flag for exactly those players with a given field value
1620 void SetWinners(.float field, float value)
1621 {
1622         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1623 }
1624
1625 // set the .winning flag for those players with a given field value
1626 void AddWinners(.float field, float value)
1627 {
1628         FOREACH_CLIENT(IS_PLAYER(it), {
1629                 if(it.(field) == value)
1630                         it.winning = 1;
1631         });
1632 }
1633
1634 // clear the .winning flags
1635 void ClearWinners()
1636 {
1637         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1638 }
1639
1640 void ShuffleMaplist()
1641 {
1642         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1643 }
1644
1645 float leaderfrags;
1646 float WinningCondition_Scores(float limit, float leadlimit)
1647 {
1648         float limitreached;
1649
1650         // TODO make everything use THIS winning condition (except LMS)
1651         WinningConditionHelper(NULL);
1652
1653         if(teamplay)
1654         {
1655                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1656                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1657                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1658                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1659         }
1660
1661         ClearWinners();
1662         if(WinningConditionHelper_winner)
1663                 WinningConditionHelper_winner.winning = 1;
1664         if(WinningConditionHelper_winnerteam >= 0)
1665                 SetWinners(team, WinningConditionHelper_winnerteam);
1666
1667         if(WinningConditionHelper_lowerisbetter)
1668         {
1669                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1670                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1671                 limit = -limit;
1672         }
1673
1674         if(WinningConditionHelper_zeroisworst)
1675                 leadlimit = 0; // not supported in this mode
1676
1677         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1678         // these modes always score in increments of 1, thus this makes sense
1679         {
1680                 if(leaderfrags != WinningConditionHelper_topscore)
1681                 {
1682                         leaderfrags = WinningConditionHelper_topscore;
1683
1684                         if (limit)
1685                         if (leaderfrags == limit - 1)
1686                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1687                         else if (leaderfrags == limit - 2)
1688                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1689                         else if (leaderfrags == limit - 3)
1690                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1691                 }
1692         }
1693
1694         limitreached = false;
1695         if(limit)
1696                 if(WinningConditionHelper_topscore >= limit)
1697                         limitreached = true;
1698         if(leadlimit)
1699         {
1700                 float leadlimitreached;
1701                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1702                 if(autocvar_leadlimit_and_fraglimit)
1703                         limitreached = (limitreached && leadlimitreached);
1704                 else
1705                         limitreached = (limitreached || leadlimitreached);
1706         }
1707
1708         if(limit)
1709                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1710
1711         return GetWinningCode(
1712                 WinningConditionHelper_topscore && limitreached,
1713                 WinningConditionHelper_equality
1714         );
1715 }
1716
1717 float WinningCondition_RanOutOfSpawns()
1718 {
1719         if(have_team_spawns <= 0)
1720                 return WINNING_NO;
1721
1722         if(!autocvar_g_spawn_useallspawns)
1723                 return WINNING_NO;
1724
1725         if(!some_spawn_has_been_used)
1726                 return WINNING_NO;
1727
1728         team1_score = team2_score = team3_score = team4_score = 0;
1729
1730         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
1731                 switch(it.team)
1732                 {
1733                         case NUM_TEAM_1: team1_score = 1; break;
1734                         case NUM_TEAM_2: team2_score = 1; break;
1735                         case NUM_TEAM_3: team3_score = 1; break;
1736                         case NUM_TEAM_4: team4_score = 1; break;
1737                 }
1738         });
1739
1740         IL_EACH(g_spawnpoints, true,
1741         {
1742                 switch(it.team)
1743                 {
1744                         case NUM_TEAM_1: team1_score = 1; break;
1745                         case NUM_TEAM_2: team2_score = 1; break;
1746                         case NUM_TEAM_3: team3_score = 1; break;
1747                         case NUM_TEAM_4: team4_score = 1; break;
1748                 }
1749         });
1750
1751         ClearWinners();
1752         if(team1_score + team2_score + team3_score + team4_score == 0)
1753         {
1754                 checkrules_equality = true;
1755                 return WINNING_YES;
1756         }
1757         else if(team1_score + team2_score + team3_score + team4_score == 1)
1758         {
1759                 float t, i;
1760                 if(team1_score)
1761                         t = NUM_TEAM_1;
1762                 else if(team2_score)
1763                         t = NUM_TEAM_2;
1764                 else if(team3_score)
1765                         t = NUM_TEAM_3;
1766                 else // if(team4_score)
1767                         t = NUM_TEAM_4;
1768                 CheckAllowedTeams(NULL);
1769                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1770                 {
1771                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1772                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1773                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1774                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1775                 }
1776
1777                 AddWinners(team, t);
1778                 return WINNING_YES;
1779         }
1780         else
1781                 return WINNING_NO;
1782 }
1783
1784 /*
1785 ============
1786 CheckRules_World
1787
1788 Exit deathmatch games upon conditions
1789 ============
1790 */
1791 void CheckRules_World()
1792 {
1793         float timelimit;
1794         float fraglimit;
1795         float leadlimit;
1796
1797         VoteThink();
1798         MapVote_Think();
1799
1800         SetDefaultAlpha();
1801
1802         if (intermission_running) // someone else quit the game already
1803         {
1804                 if(player_count == 0) // Nobody there? Then let's go to the next map
1805                         MapVote_Start();
1806                         // this will actually check the player count in the next frame
1807                         // again, but this shouldn't hurt
1808                 return;
1809         }
1810
1811         timelimit = autocvar_timelimit * 60;
1812         fraglimit = autocvar_fraglimit;
1813         leadlimit = autocvar_leadlimit;
1814
1815         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1816         {
1817                 if(timelimit > 0)
1818                         timelimit = 0; // timelimit is not made for warmup
1819                 if(fraglimit > 0)
1820                         fraglimit = 0; // no fraglimit for now
1821                 leadlimit = 0; // no leadlimit for now
1822         }
1823
1824         if(timelimit > 0)
1825         {
1826                 timelimit += game_starttime;
1827         }
1828         else if (timelimit < 0)
1829         {
1830                 // endmatch
1831                 NextLevel();
1832                 return;
1833         }
1834
1835         float wantovertime;
1836         wantovertime = 0;
1837
1838         if(timelimit > game_starttime)
1839                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1840         else
1841                 game_completion_ratio = 0;
1842
1843         if(checkrules_suddendeathend)
1844         {
1845                 if(!checkrules_suddendeathwarning)
1846                 {
1847                         checkrules_suddendeathwarning = true;
1848                         if(g_race && !g_race_qualifying)
1849                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1850                         else
1851                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1852                 }
1853         }
1854         else
1855         {
1856                 if (timelimit && time >= timelimit)
1857                 {
1858                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1859                         {
1860                                 float totalplayers;
1861                                 float playerswithlaps;
1862                                 float readyplayers;
1863                                 totalplayers = playerswithlaps = readyplayers = 0;
1864                                 FOREACH_CLIENT(IS_PLAYER(it), {
1865                                         ++totalplayers;
1866                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1867                                                 ++playerswithlaps;
1868                                         if(it.ready)
1869                                                 ++readyplayers;
1870                                 });
1871
1872                                 // at least 2 of the players have completed a lap: start the RACE
1873                                 // otherwise, the players should end the qualifying on their own
1874                                 if(readyplayers || playerswithlaps >= 2)
1875                                 {
1876                                         checkrules_suddendeathend = 0;
1877                                         ReadyRestart(); // go to race
1878                                         return;
1879                                 }
1880                                 else
1881                                         wantovertime |= InitiateSuddenDeath();
1882                         }
1883                         else
1884                                 wantovertime |= InitiateSuddenDeath();
1885                 }
1886         }
1887
1888         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1889         {
1890                 NextLevel();
1891                 return;
1892         }
1893
1894         int checkrules_status = WinningCondition_RanOutOfSpawns();
1895         if(checkrules_status == WINNING_YES)
1896                 bprint("Hey! Someone ran out of spawns!\n");
1897         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1898                 checkrules_status = M_ARGV(0, float);
1899         else
1900                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1901
1902         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1903         {
1904                 checkrules_status = WINNING_NEVER;
1905                 checkrules_overtimesadded = -1;
1906                 wantovertime |= InitiateSuddenDeath();
1907         }
1908
1909         if(checkrules_status == WINNING_NEVER)
1910                 // equality cases! Nobody wins if the overtime ends in a draw.
1911                 ClearWinners();
1912
1913         if(wantovertime)
1914         {
1915                 if(checkrules_status == WINNING_NEVER)
1916                         InitiateOvertime();
1917                 else
1918                         checkrules_status = WINNING_YES;
1919         }
1920
1921         if(checkrules_suddendeathend)
1922                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1923                         checkrules_status = WINNING_YES;
1924
1925         if(checkrules_status == WINNING_YES)
1926         {
1927                 //print("WINNING\n");
1928                 NextLevel();
1929         }
1930 }
1931
1932 string GotoMap(string m)
1933 {
1934         m = GameTypeVote_MapInfo_FixName(m);
1935         if (!m)
1936                 return "The map you suggested is not available on this server.";
1937         if (!autocvar_sv_vote_gametype)
1938         if(!MapInfo_CheckMap(m))
1939                 return "The map you suggested does not support the current game mode.";
1940         cvar_set("nextmap", m);
1941         cvar_set("timelimit", "-1");
1942         if(mapvote_initialized || alreadychangedlevel)
1943         {
1944                 if(DoNextMapOverride(0))
1945                         return "Map switch initiated.";
1946                 else
1947                         return "Hm... no. For some reason I like THIS map more.";
1948         }
1949         else
1950                 return "Map switch will happen after scoreboard.";
1951 }
1952
1953 bool autocvar_sv_gameplayfix_multiplethinksperframe;
1954 void RunThink(entity this)
1955 {
1956         // don't let things stay in the past.
1957         // it is possible to start that way by a trigger with a local time.
1958         if(this.nextthink <= 0 || this.nextthink > time + frametime)
1959                 return;
1960
1961         float oldtime = time; // do we need to save this?
1962
1963         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
1964         {
1965                 time = max(oldtime, this.nextthink);
1966                 this.nextthink = 0;
1967
1968                 if(getthink(this))
1969                         getthink(this)(this);
1970                 // mods often set nextthink to time to cause a think every frame,
1971                 // we don't want to loop in that case, so exit if the new nextthink is
1972                 // <= the time the qc was told, also exit if it is past the end of the
1973                 // frame
1974                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
1975                         break;
1976         }
1977
1978         time = oldtime;
1979 }
1980
1981 bool autocvar_sv_freezenonclients;
1982 bool autocvar_sv_gameplayfix_delayprojectiles;
1983 void Physics_Frame()
1984 {
1985         if(autocvar_sv_freezenonclients)
1986                 return;
1987
1988         FOREACH_ENTITY_FLOAT(pure_data, false,
1989         {
1990                 if(IS_CLIENT(it) || it.classname == "" || it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH || it.move_movetype == MOVETYPE_PHYSICS)
1991                         continue;
1992
1993                 //set_movetype(it, it.move_movetype);
1994                 // inline the set_movetype function, since this is called a lot
1995                 it.movetype = (it.move_qcphysics) ? MOVETYPE_NONE : it.move_movetype;
1996
1997                 if(it.move_movetype == MOVETYPE_NONE)
1998                         continue;
1999
2000                 if(it.move_qcphysics)
2001                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2002
2003                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2004                 {
2005                         // handle thinking here
2006                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2007                                 RunThink(it);
2008                 }
2009         });
2010
2011         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2012                 return;
2013
2014         FOREACH_ENTITY_FLOAT(move_qcphysics, true,
2015         {
2016                 if(IS_CLIENT(it) || is_pure(it) || it.classname == "" || it.move_movetype == MOVETYPE_NONE)
2017                         continue;
2018                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2019         });
2020 }
2021
2022 void systems_update();
2023 void EndFrame()
2024 {
2025         anticheat_endframe();
2026
2027         Physics_Frame();
2028
2029         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2030                 entity e = IS_SPEC(it) ? it.enemy : it;
2031                 if (e.typehitsound) {
2032                         STAT(TYPEHIT_TIME, it) = time;
2033                 } else if (e.killsound) {
2034                         STAT(KILL_TIME, it) = time;
2035                 } else if (e.damage_dealt) {
2036                         STAT(HIT_TIME, it) = time;
2037                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2038                 }
2039         });
2040         // add 1 frametime because after this, engine SV_Physics
2041         // increases time by a frametime and then networks the frame
2042         // add another frametime because client shows everything with
2043         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2044         // needed!
2045         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2046         FOREACH_CLIENT(true, {
2047                 it.typehitsound = false;
2048                 it.damage_dealt = 0;
2049                 it.killsound = false;
2050                 antilag_record(it, CS(it), altime);
2051         });
2052         IL_EACH(g_monsters, true,
2053         {
2054                 antilag_record(it, it, altime);
2055         });
2056         IL_EACH(g_projectiles, it.classname == "nade",
2057         {
2058                 antilag_record(it, it, altime);
2059         });
2060         systems_update();
2061         IL_ENDFRAME();
2062 }
2063
2064
2065 /*
2066  * RedirectionThink:
2067  * returns true if redirecting
2068  */
2069 float redirection_timeout;
2070 float redirection_nextthink;
2071 float RedirectionThink()
2072 {
2073         float clients_found;
2074
2075         if(redirection_target == "")
2076                 return false;
2077
2078         if(!redirection_timeout)
2079         {
2080                 cvar_set("sv_public", "-2");
2081                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2082                 if(redirection_target == "self")
2083                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2084                 else
2085                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2086         }
2087
2088         if(time < redirection_nextthink)
2089                 return true;
2090
2091         redirection_nextthink = time + 1;
2092
2093         clients_found = 0;
2094         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2095                 // TODO add timer
2096                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2097                 if(redirection_target == "self")
2098                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2099                 else
2100                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2101                 ++clients_found;
2102         });
2103
2104         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2105
2106         if(time > redirection_timeout || clients_found == 0)
2107                 localcmd("\nwait; wait; wait; quit\n");
2108
2109         return true;
2110 }
2111
2112 void TargetMusic_RestoreGame();
2113 void RestoreGame()
2114 {
2115         // Loaded from a save game
2116         // some things then break, so let's work around them...
2117
2118         // Progs DB (capture records)
2119         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2120
2121         // Mapinfo
2122         MapInfo_Shutdown();
2123         MapInfo_Enumerate();
2124         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2125         WeaponStats_Init();
2126
2127         TargetMusic_RestoreGame();
2128 }
2129
2130 void Shutdown()
2131 {
2132         game_stopped = 2;
2133
2134         if(world_initialized > 0)
2135         {
2136                 world_initialized = 0;
2137                 LOG_TRACE("Saving persistent data...");
2138                 Ban_SaveBans();
2139
2140                 // playerstats with unfinished match
2141                 PlayerStats_GameReport(false);
2142
2143                 if(!cheatcount_total)
2144                 {
2145                         if(autocvar_sv_db_saveasdump)
2146                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2147                         else
2148                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2149                 }
2150                 if(autocvar_developer)
2151                 {
2152                         if(autocvar_sv_db_saveasdump)
2153                                 db_dump(TemporaryDB, "server-temp.db");
2154                         else
2155                                 db_save(TemporaryDB, "server-temp.db");
2156                 }
2157                 CheatShutdown(); // must be after cheatcount check
2158                 db_close(ServerProgsDB);
2159                 db_close(TemporaryDB);
2160                 LOG_TRACE("Saving persistent data... done!");
2161                 // tell the bot system the game is ending now
2162                 bot_endgame();
2163
2164                 WeaponStats_Shutdown();
2165                 MapInfo_Shutdown();
2166         }
2167         else if(world_initialized == 0)
2168         {
2169                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2170         }
2171         else
2172         {
2173                 __init_dedicated_server_shutdown();
2174         }
2175 }