qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_autoscreenshot");
 290                 BADCVAR("sv_heartbeatperiod");
 291                 BADCVAR("sv_vote_master_password");
 292                 BADCVAR("sys_colortranslation");
 293                 BADCVAR("sys_specialcharactertranslation");
 294                 BADCVAR("timeformat");
 295                 BADCVAR("timestamps");
 296                 BADPREFIX("developer_");
 297                 BADPREFIX("g_ban_");
 298                 BADPREFIX("g_banned_list");
 299                 BADPREFIX("g_chat_flood_");
 300                 BADPREFIX("g_playerstats_");
 301                 BADPREFIX("g_voice_flood_");
 302                 BADPREFIX("rcon_");
 303                 BADPREFIX("settemp_");
 304                 BADPREFIX("sv_allowdownloads_");
 305                 BADPREFIX("sv_autodemo");
 306                 BADPREFIX("sv_curl_");
 307                 BADPREFIX("sv_eventlog");
 308                 BADPREFIX("sv_logscores_");
 309                 BADPREFIX("sv_master");
 310                 BADPREFIX("sv_weaponstats_");
 311                 BADPREFIX("sv_waypointsprite_");
 312                 BADCVAR("rescan_pending");
 313
 314                 // these can contain player IDs, so better hide
 315                 BADPREFIX("g_forced_team_");
 316
 317                 // mapinfo
 318                 BADCVAR("fraglimit");
 319                 BADCVAR("g_arena");
 320                 BADCVAR("g_assault");
 321                 BADCVAR("g_ca");
 322                 BADCVAR("g_ctf");
 323                 BADCVAR("g_cts");
 324                 BADCVAR("g_dm");
 325                 BADCVAR("g_domination");
 326                 BADCVAR("g_domination_default_teams");
 327                 BADCVAR("g_freezetag");
 328                 BADCVAR("g_keepaway");
 329                 BADCVAR("g_keyhunt");
 330                 BADCVAR("g_keyhunt_teams");
 331                 BADCVAR("g_keyhunt_teams");
 332                 BADCVAR("g_lms");
 333                 BADCVAR("g_nexball");
 334                 BADCVAR("g_onslaught");
 335                 BADCVAR("g_race");
 336                 BADCVAR("g_race_qualifying_timelimit");
 337                 BADCVAR("g_runematch");
 338                 BADCVAR("g_tdm");
 339                 BADCVAR("g_tdm_teams");
 340                 BADCVAR("leadlimit");
 341                 BADCVAR("nextmap");
 342                 BADCVAR("teamplay");
 343                 BADCVAR("timelimit");
 344
 345                 // long
 346                 BADCVAR("hostname");
 347                 BADCVAR("g_maplist");
 348                 BADCVAR("g_maplist_mostrecent");
 349                 BADCVAR("sv_motd");
 350
 351                 v = cvar_string(k);
 352                 d = cvar_defstring(k);
 353                 if(v == d)
 354                         continue;
 355
 356                 if(adding)
 357                 {
 358                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 359                         if(strlen(cvar_changes) > 16384)
 360                         {
 361                                 cvar_changes = "// too many settings have been changed to show them here\n";
 362                                 adding = 0;
 363                         }
 364                 }
 365
 366                 // now check if the changes are actually gameplay relevant
 367
 368                 // does nothing visible
 369                 BADCVAR("captureleadlimit_override");
 370                 BADCVAR("g_arena_point_leadlimit");
 371                 BADCVAR("g_balance_kill_delay");
 372                 BADCVAR("g_ca_point_leadlimit");
 373                 BADCVAR("g_ctf_captimerecord_always");
 374                 BADCVAR("g_ctf_capture_leadlimit");
 375                 BADCVAR("g_ctf_flag_capture_effects");
 376                 BADCVAR("g_ctf_flag_glowtrails");
 377                 BADCVAR("g_ctf_flag_pickup_effects");
 378                 BADCVAR("g_domination_point_leadlimit");
 379                 BADCVAR("g_forced_respawn");
 380                 BADCVAR("g_keyhunt_point_leadlimit");
 381                 BADCVAR("g_nexball_goalleadlimit");
 382                 BADCVAR("g_runematch_point_leadlimit");
 383                 BADCVAR("leadlimit_and_fraglimit");
 384                 BADCVAR("leadlimit_override");
 385                 BADCVAR("pausable");
 386                 BADCVAR("sv_allow_fullbright");
 387                 BADCVAR("sv_checkforpacketsduringsleep");
 388                 BADCVAR("sv_timeout");
 389                 BADCVAR("welcome_message_time");
 390                 BADPREFIX("crypto_");
 391                 BADPREFIX("g_chat_");
 392                 BADPREFIX("g_ctf_captimerecord_");
 393                 BADPREFIX("g_maplist_votable_");
 394                 BADPREFIX("net_");
 395                 BADPREFIX("prvm_");
 396                 BADPREFIX("skill_");
 397                 BADPREFIX("sv_cullentities_");
 398                 BADPREFIX("sv_fraginfo_");
 399                 BADPREFIX("sv_maxidle_");
 400                 BADPREFIX("sv_vote_");
 401                 BADPREFIX("timelimit_");
 402                 BADCVAR("gameversion");
 403                 BADPREFIX("gameversion_");
 404                 BADCVAR("sv_namechangetimer");
 405
 406                 // allowed changes to server admins (please sync this to server.cfg)
 407                 // vi commands:
 408                 //   :/"impure"/,$d
 409                 //   :g!,^\/\/[^ /],d
 410                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 411                 //   :%!sort
 412                 // yes, this does contain some redundant stuff, don't really care
 413                 BADCVAR("bot_config_file");
 414                 BADCVAR("bot_number");
 415                 BADCVAR("bot_prefix");
 416                 BADCVAR("bot_suffix");
 417                 BADCVAR("capturelimit_override");
 418                 BADCVAR("fraglimit_override");
 419                 BADCVAR("gametype");
 420                 BADCVAR("g_antilag");
 421                 BADCVAR("g_balance_teams");
 422                 BADCVAR("g_balance_teams_force");
 423                 BADCVAR("g_ban_sync_trusted_servers");
 424                 BADCVAR("g_ban_sync_uri");
 425                 BADCVAR("g_ctf_capture_limit");
 426                 BADCVAR("g_ctf_ignore_frags");
 427                 BADCVAR("g_ctf_win_mode");
 428                 BADCVAR("g_domination_point_limit");
 429                 BADCVAR("g_friendlyfire");
 430                 BADCVAR("g_fullbrightitems");
 431                 BADCVAR("g_fullbrightplayers");
 432                 BADCVAR("g_keyhunt_point_limit");
 433                 BADCVAR("g_keyhunt_teams_override");
 434                 BADCVAR("g_lms_lives_override");
 435                 BADCVAR("g_maplist");
 436                 BADCVAR("g_maplist_check_waypoints");
 437                 BADCVAR("g_maplist_mostrecent_count");
 438                 BADCVAR("g_maplist_shuffle");
 439                 BADCVAR("g_maplist_votable");
 440                 BADCVAR("g_maplist_votable_abstain");
 441                 BADCVAR("g_maplist_votable_nodetail");
 442                 BADCVAR("g_maplist_votable_suggestions");
 443                 BADCVAR("g_maxplayers");
 444                 BADCVAR("g_minstagib");
 445                 BADCVAR("g_mirrordamage");
 446                 BADCVAR("g_nexball_goallimit");
 447                 BADCVAR("g_powerups");
 448                 BADCVAR("g_runematch_point_limit");
 449                 BADCVAR("g_start_delay");
 450                 BADCVAR("g_warmup");
 451                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 452                 BADCVAR("hostname");
 453                 BADCVAR("log_file");
 454                 BADCVAR("maxplayers");
 455                 BADCVAR("minplayers");
 456                 BADCVAR("net_address");
 457                 BADCVAR("port");
 458                 BADCVAR("rcon_password");
 459                 BADCVAR("rcon_restricted_commands");
 460                 BADCVAR("rcon_restricted_password");
 461                 BADCVAR("skill");
 462                 BADCVAR("sv_adminnick");
 463                 BADCVAR("sv_autoscreenshot");
 464                 BADCVAR("sv_autotaunt");
 465                 BADCVAR("sv_curl_defaulturl");
 466                 BADCVAR("sv_defaultcharacter");
 467                 BADCVAR("sv_defaultplayercolors");
 468                 BADCVAR("sv_defaultplayermodel");
 469                 BADCVAR("sv_defaultplayerskin");
 470                 BADCVAR("sv_maxidle");
 471                 BADCVAR("sv_maxrate");
 472                 BADCVAR("sv_motd");
 473                 BADCVAR("sv_public");
 474                 BADCVAR("sv_ready_restart");
 475                 BADCVAR("sv_status_privacy");
 476                 BADCVAR("sv_taunt");
 477                 BADCVAR("sv_vote_call");
 478                 BADCVAR("sv_vote_commands");
 479                 BADCVAR("sv_vote_majority_factor");
 480                 BADCVAR("sv_vote_master");
 481                 BADCVAR("sv_vote_master_commands");
 482                 BADCVAR("sv_vote_master_password");
 483                 BADCVAR("sv_vote_simple_majority_factor");
 484                 BADCVAR("sys_ticrate");
 485                 BADCVAR("teamplay_mode");
 486                 BADCVAR("timelimit_override");
 487                 BADPREFIX("g_warmup_");
 488                 BADPREFIX("sv_ready_restart_");
 489
 490                 if(autocvar_g_minstagib)
 491                 {
 492                         BADCVAR("g_grappling_hook");
 493                         BADCVAR("g_jetpack");
 494                 }
 495 #undef BADPREFIX
 496 #undef BADCVAR
 497
 498                 if(pureadding)
 499                 {
 500                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 501                         if(strlen(cvar_purechanges) > 16384)
 502                         {
 503                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 504                                 pureadding = 0;
 505                         }
 506                 }
 507                 ++cvar_purechanges_count;
 508                 // WARNING: this variable is used for the server list
 509                 // NEVER dare to skip this code!
 510                 // Hacks to intentionally appearing as "pure server" even though you DO have
 511                 // modified settings may be punished by removal from the server list.
 512                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 513                 // though.
 514         }
 515         buf_del(h);
 516         if(cvar_changes == "")
 517                 cvar_changes = "// this server runs at default server settings\n";
 518         else
 519                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 520         cvar_changes = strzone(cvar_changes);
 521         if(cvar_purechanges == "")
 522                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 523         else
 524                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 525         cvar_purechanges = strzone(cvar_purechanges);
 526 }
 527
 528 void detect_maptype()
 529 {
 530 #if 0
 531         vector o, v;
 532         float i;
 533
 534         for(;;)
 535         {
 536                 o = world.mins;
 537                 o_x += random() * (world.maxs_x - world.mins_x);
 538                 o_y += random() * (world.maxs_y - world.mins_y);
 539                 o_z += random() * (world.maxs_z - world.mins_z);
 540
 541                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 542                 if(trace_fraction == 1)
 543                         continue;
 544
 545                 v = trace_endpos;
 546
 547                 for(i = 0; i < 64; i += 4)
 548                 {
 549                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 550         if(trace_fraction == 1)
 551                 continue;
 552                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 553                 }
 554
 555                 break;
 556         }
 557 #endif
 558 }
 559
 560 entity randomseed;
 561 float RandomSeed_Send(entity to, float sf)
 562 {
 563         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 564         WriteShort(MSG_ENTITY, self.cnt);
 565         return TRUE;
 566 }
 567 void RandomSeed_Think()
 568 {
 569         self.cnt = bound(0, floor(random() * 65536), 65535);
 570         self.nextthink = time + 5;
 571
 572         self.SendFlags |= 1;
 573 }
 574 void RandomSeed_Spawn()
 575 {
 576         randomseed = spawn();
 577         randomseed.think = RandomSeed_Think;
 578         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 579
 580         entity oldself;
 581         oldself = self;
 582         self = randomseed;
 583         self.think(); // sets random seed and nextthink
 584         self = oldself;
 585 }
 586
 587 void spawnfunc___init_dedicated_server(void)
 588 {
 589         // handler for _init/_init map (only for dedicated server initialization)
 590
 591         world_initialized = -1; // don't complain
 592         cvar = cvar_normal;
 593         cvar_string = cvar_string_normal;
 594         cvar_set = cvar_set_normal;
 595
 596         remove = remove_unsafely;
 597
 598         entity e;
 599         e = spawn();
 600         e.think = GotoFirstMap;
 601         e.nextthink = time; // this is usually 1 at this point
 602
 603         e = spawn();
 604         e.classname = "info_player_deathmatch"; // safeguard against player joining
 605
 606         self.classname = "worldspawn"; // safeguard against various stuff ;)
 607
 608         MapInfo_Enumerate();
 609         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 610 }
 611
 612 void Map_MarkAsRecent(string m);
 613 float world_already_spawned;
 614 void RegisterWeapons();
 615 void Nagger_Init();
 616 void ClientInit_Spawn();
 617 void WeaponStats_Init();
 618 void WeaponStats_Shutdown();
 619 void spawnfunc_worldspawn (void)
 620 {
 621         float fd, l, i, j, n;
 622         string s, col;
 623
 624         cvar = cvar_normal;
 625         cvar_string = cvar_string_normal;
 626         cvar_set = cvar_set_normal;
 627
 628         if(world_already_spawned)
 629                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 630         world_already_spawned = TRUE;
 631
 632         remove = remove_safely; // during spawning, watch what you remove!
 633
 634         check_unacceptable_compiler_bugs();
 635
 636         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 637
 638         compressShortVector_init();
 639
 640         allowed_to_spawn = TRUE;
 641
 642         entity head;
 643         head = nextent(world);
 644         maxclients = 0;
 645         while(head)
 646         {
 647                 ++maxclients;
 648                 head = nextent(head);
 649         }
 650
 651         // needs to be done so early as they would still spawn
 652         RegisterWeapons();
 653
 654         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 655
 656         TemporaryDB = db_create();
 657
 658         // 0 normal
 659         lightstyle(0, "m");
 660
 661         // 1 FLICKER (first variety)
 662         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 663
 664         // 2 SLOW STRONG PULSE
 665         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 666
 667         // 3 CANDLE (first variety)
 668         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 669
 670         // 4 FAST STROBE
 671         lightstyle(4, "mamamamamama");
 672
 673         // 5 GENTLE PULSE 1
 674         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 675
 676         // 6 FLICKER (second variety)
 677         lightstyle(6, "nmonqnmomnmomomno");
 678
 679         // 7 CANDLE (second variety)
 680         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 681
 682         // 8 CANDLE (third variety)
 683         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 684
 685         // 9 SLOW STROBE (fourth variety)
 686         lightstyle(9, "aaaaaaaazzzzzzzz");
 687
 688         // 10 FLUORESCENT FLICKER
 689         lightstyle(10, "mmamammmmammamamaaamammma");
 690
 691         // 11 SLOW PULSE NOT FADE TO BLACK
 692         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 693
 694         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 695
 696         // 63 testing
 697         lightstyle(63, "a");
 698
 699         if(autocvar_g_campaign)
 700                 CampaignPreInit();
 701
 702         Map_MarkAsRecent(mapname);
 703
 704         precache_model ("null"); // we need this one before InitGameplayMode
 705         InitGameplayMode();
 706         readlevelcvars();
 707         GrappleHookInit();
 708         ElectroInit();
 709         LaserInit();
 710
 711         player_count = 0;
 712         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 713         if(bot_waypoints_for_items == 1)
 714                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 715                         bot_waypoints_for_items = 0;
 716
 717         precache();
 718
 719         WaypointSprite_Init();
 720
 721         //if (g_domination)
 722         //      dom_init();
 723
 724         GameLogInit(); // prepare everything
 725         // NOTE for matchid:
 726         // changing the logic generating it is okay. But:
 727         // it HAS to stay <= 64 chars
 728         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 729         if(autocvar_sv_eventlog)
 730         {
 731                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 732                 matchid = strzone(s);
 733
 734                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 735                 s = ":gameinfo:mutators:LIST";
 736
 737                 ret_string = s;
 738                 MUTATOR_CALLHOOK(BuildMutatorsString);
 739                 s = ret_string;
 740
 741                 // simple, probably not good in the mutator system
 742                 if(autocvar_g_grappling_hook)
 743                         s = strcat(s, ":grappling_hook");
 744
 745                 // initialiation stuff, not good in the mutator system
 746                 if(!autocvar_g_use_ammunition)
 747                         s = strcat(s, ":no_use_ammunition");
 748
 749                 // initialiation stuff, not good in the mutator system
 750                 if(autocvar_g_pickup_items == 0)
 751                         s = strcat(s, ":no_pickup_items");
 752                 if(autocvar_g_pickup_items > 0)
 753                         s = strcat(s, ":pickup_items");
 754
 755                 // initialiation stuff, not good in the mutator system
 756                 if(autocvar_g_weaponarena != "0")
 757                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 758
 759                 // TODO to mutator system
 760                 if(autocvar_g_norecoil)
 761                         s = strcat(s, ":norecoil");
 762
 763                 // TODO to mutator system
 764                 if(autocvar_g_midair)
 765                         s = strcat(s, ":midair");
 766
 767                 // TODO to mutator system
 768                 if(autocvar_g_minstagib)
 769                         s = strcat(s, ":minstagib");
 770
 771                 // TODO to mutator system
 772                 if(autocvar_g_powerups == 0)
 773                         s = strcat(s, ":no_powerups");
 774                 if(autocvar_g_powerups > 0)
 775                         s = strcat(s, ":powerups");
 776
 777                 GameLogEcho(s);
 778                 GameLogEcho(":gameinfo:end");
 779         }
 780         else
 781                 matchid = strzone(ftos(random()));
 782
 783         cvar_set("nextmap", "");
 784
 785         SetDefaultAlpha();
 786
 787         if(autocvar_g_campaign)
 788                 CampaignPostInit();
 789
 790         fteqcc_testbugs();
 791
 792         Ban_LoadBans();
 793
 794         MapInfo_Enumerate();
 795         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 796
 797         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 798         {
 799                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 800                 if(fd != -1)
 801                 {
 802                         while((s = fgets(fd)))
 803                         {
 804                                 l = tokenize_console(s);
 805                                 if(l < 2)
 806                                         continue;
 807                                 if(argv(0) == "cd")
 808                                 {
 809                                         print("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 810                                         print("  cdtrack ", argv(2), "\n");
 811                                 }
 812                                 else if(argv(0) == "fog")
 813                                 {
 814                                         print("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 815                                         print("  \"fog\" \"", s, "\"\n");
 816                                 }
 817                                 else if(argv(0) == "set")
 818                                 {
 819                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 820                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 821                                 }
 822                                 else if(argv(0) != "//")
 823                                 {
 824                                         print("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 825                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 826                                 }
 827                         }
 828                         fclose(fd);
 829                 }
 830         }
 831
 832         WeaponStats_Init();
 833
 834         addstat(STAT_WEAPONS, AS_INT, weapons);
 835         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 836         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 837         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 838         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 839         Nagger_Init();
 840
 841         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 842         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 843         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 844         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 845         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 846         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 847         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 848         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 849         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 850         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 851         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 852         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 853
 854         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 855         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 856
 857         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 858
 859         if(g_ca || g_freezetag)
 860         {
 861                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 862                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 863                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 864                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 865         }
 866         if(g_freezetag)
 867         {
 868                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 869                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 870         }
 871
 872         // g_movementspeed hack
 873         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 874         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 875         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 876         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 877
 878         // secrets
 879         addstat(STAT_SECRETS_TOTAL, AS_FLOAT, stat_secrets_total);
 880         addstat(STAT_SECRETS_FOUND, AS_FLOAT, stat_secrets_found);
 881
 882         next_pingtime = time + 5;
 883
 884         detect_maptype();
 885
 886         lsmaps_reply = "^7Maps available: ";
 887         lsnewmaps_reply = "^7Maps without a record set: ";
 888         for(i = 0, j = 0; i < MapInfo_count; ++i)
 889         {
 890                 if(MapInfo_Get_ByID(i))
 891                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 892                         {
 893                                 if(mod(i, 2))
 894                                         col = "^2";
 895                                 else
 896                                         col = "^3";
 897                                 ++j;
 898                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 899                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 900                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 901                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 902                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 903                         }
 904         }
 905         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 906         if (!g_race && !g_cts)
 907                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 908         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 909
 910         maplist_reply = "^7Maps in list: ";
 911         n = tokenize_console(autocvar_g_maplist);
 912         for(i = 0, j = 0; i < n; ++i)
 913         {
 914                 if(MapInfo_CheckMap(argv(i)))
 915                 {
 916                         if(mod(j, 2))
 917                                 col = "^2";
 918                         else
 919                                 col = "^3";
 920                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 921                         ++j;
 922                 }
 923         }
 924         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 925         MapInfo_ClearTemps();
 926
 927         for(i = 0; i < 10; ++i)
 928         {
 929                 records_reply[i] = strzone(getrecords(i));
 930         }
 931         if(g_cts)
 932                 ladder_reply = strzone(getladder());
 933
 934         rankings_reply = strzone(getrankings());
 935
 936         ClientInit_Spawn();
 937         RandomSeed_Spawn();
 938         PingPLReport_Spawn();
 939
 940         CheatInit();
 941
 942         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 943
 944         // fill sv_curl_serverpackages from .serverpackage files
 945         if(autocvar_sv_curl_serverpackages_auto)
 946         {
 947                 s = "";
 948                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 949                 for(i = 0; i < n; ++i)
 950                         if(substring(argv(i), -14, -1) != "-serverpackage.txt")
 951                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 952                                 s = strcat(s, " ", argv(i));
 953                 fd = search_begin("*-serverpackage.txt", TRUE, FALSE);
 954                 if(fd >= 0)
 955                 {
 956                         j = search_getsize(fd);
 957                         for(i = 0; i < j; ++i)
 958                                 s = strcat(s, " ", search_getfilename(fd, i));
 959                         search_end(fd);
 960                 }
 961                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 962                 if(fd >= 0)
 963                 {
 964                         j = search_getsize(fd);
 965                         for(i = 0; i < j; ++i)
 966                                 s = strcat(s, " ", search_getfilename(fd, i));
 967                         search_end(fd);
 968                 }
 969                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 970         }
 971
 972         PlayerStats_Init();
 973
 974         world_initialized = 1;
 975 }
 976
 977 void spawnfunc_light (void)
 978 {
 979         //makestatic (self); // Who the f___ did that?
 980         remove(self);
 981 }
 982
 983 string GetGametype()
 984 {
 985         return GametypeNameFromType(game);
 986 }
 987
 988 string getmapname_stored;
 989 string GetMapname()
 990 {
 991         return mapname;
 992 }
 993
 994 float Map_Count, Map_Current;
 995 string Map_Current_Name;
 996
 997 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 998 float GetMaplistPosition()
 999 {
1000         float pos, idx;
1001         string map;
1002
1003         map = GetMapname();
1004         idx = autocvar_g_maplist_index;
1005
1006         if(idx >= 0)
1007                 if(idx < Map_Count)
1008                         if(map == argv(idx))
1009                                 return idx;
1010
1011         for(pos = 0; pos < Map_Count; ++pos)
1012                 if(map == argv(pos))
1013                         return pos;
1014
1015         // resume normal maplist rotation if current map is not in g_maplist
1016         return idx;
1017 }
1018
1019 float MapHasRightSize(string map)
1020 {
1021         float fh;
1022         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
1023         if(autocvar_g_maplist_check_waypoints)
1024         {
1025                 dprint("checkwp "); dprint(map);
1026                 if(!fexists(strcat("maps/", map, ".waypoints")))
1027                 {
1028                         dprint(": no waypoints\n");
1029                         return FALSE;
1030                 }
1031                 dprint(": has waypoints\n");
1032         }
1033
1034         // open map size restriction file
1035         dprint("opensize "); dprint(map);
1036         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1037         if(fh >= 0)
1038         {
1039                 float mapmin, mapmax;
1040                 dprint(": ok, ");
1041                 mapmin = stof(fgets(fh));
1042                 mapmax = stof(fgets(fh));
1043                 fclose(fh);
1044                 if(player_count < mapmin)
1045                 {
1046                         dprint("not enough\n");
1047                         return FALSE;
1048                 }
1049                 if(player_count > mapmax)
1050                 {
1051                         dprint("too many\n");
1052                         return FALSE;
1053                 }
1054                 dprint("right size\n");
1055                 return TRUE;
1056         }
1057         dprint(": not found\n");
1058         return TRUE;
1059 }
1060
1061 string Map_Filename(float position)
1062 {
1063         return strcat("maps/", argv(position), ".bsp");
1064 }
1065
1066 string strwords(string s, float w)
1067 {
1068         float endpos;
1069         for(endpos = 0; w && endpos >= 0; --w)
1070                 endpos = strstrofs(s, " ", endpos + 1);
1071         if(endpos < 0)
1072                 return s;
1073         else
1074                 return substring(s, 0, endpos);
1075 }
1076
1077 float strhasword(string s, string w)
1078 {
1079         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1080 }
1081
1082 void Map_MarkAsRecent(string m)
1083 {
1084         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1085 }
1086
1087 float Map_IsRecent(string m)
1088 {
1089         return strhasword(autocvar_g_maplist_mostrecent, m);
1090 }
1091
1092 float Map_Check(float position, float pass)
1093 {
1094         string filename;
1095         string map_next;
1096         map_next = argv(position);
1097         if(pass <= 1)
1098         {
1099                 if(Map_IsRecent(map_next))
1100                         return 0;
1101         }
1102         filename = Map_Filename(position);
1103         if(MapInfo_CheckMap(map_next))
1104         {
1105                 if(pass == 2)
1106                         return 1;
1107                 if(MapHasRightSize(map_next))
1108                         return 1;
1109                 return 0;
1110         }
1111         else
1112                 dprint( "Couldn't select '", filename, "'..\n" );
1113
1114         return 0;
1115 }
1116
1117 void Map_Goto_SetStr(string nextmapname)
1118 {
1119         if(getmapname_stored != "")
1120                 strunzone(getmapname_stored);
1121         if(nextmapname == "")
1122                 getmapname_stored = "";
1123         else
1124                 getmapname_stored = strzone(nextmapname);
1125 }
1126
1127 void Map_Goto_SetFloat(float position)
1128 {
1129         cvar_set("g_maplist_index", ftos(position));
1130         Map_Goto_SetStr(argv(position));
1131 }
1132
1133 void GameResetCfg()
1134 {
1135         // settings persist, except...
1136         localcmd("\nsettemp_restore\n");
1137 }
1138
1139 void Map_Goto()
1140 {
1141         GameResetCfg();
1142         MapInfo_LoadMap(getmapname_stored);
1143 }
1144
1145 // return codes of map selectors:
1146 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1147 //   -2 = permanent failure
1148 float() MaplistMethod_Iterate = // usual method
1149 {
1150         float pass, i;
1151
1152         for(pass = 1; pass <= 2; ++pass)
1153         {
1154                 for(i = 1; i < Map_Count; ++i)
1155                 {
1156                         float mapindex;
1157                         mapindex = mod(i + Map_Current, Map_Count);
1158                         if(Map_Check(mapindex, pass))
1159                                 return mapindex;
1160                 }
1161         }
1162         return -1;
1163 }
1164
1165 float() MaplistMethod_Repeat = // fallback method
1166 {
1167         if(Map_Check(Map_Current, 2))
1168                 return Map_Current;
1169         return -2;
1170 }
1171
1172 float() MaplistMethod_Random = // random map selection
1173 {
1174         float i, imax;
1175
1176         imax = 42;
1177
1178         for(i = 0; i <= imax; ++i)
1179         {
1180                 float mapindex;
1181                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1182                 if(Map_Check(mapindex, 1))
1183                         return mapindex;
1184         }
1185         return -1;
1186 }
1187
1188 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1189 // the exponent sets a bias on the map selection:
1190 // the higher the exponent, the less likely "shortly repeated" same maps are
1191 {
1192         float i, j, imax, insertpos;
1193
1194         imax = 42;
1195
1196         for(i = 0; i <= imax; ++i)
1197         {
1198                 string newlist;
1199
1200                 // now reinsert this at another position
1201                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1202                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1203                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1204                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1205
1206                 // insert the current map there
1207                 newlist = "";
1208                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1209                         newlist = strcat(newlist, " ", argv(j));
1210                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1211                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1212                         newlist = strcat(newlist, " ", argv(j));
1213                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1214                 cvar_set("g_maplist", newlist);
1215                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1216
1217                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1218                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1219                 if(Map_Check(Map_Current, 1))
1220                         return Map_Current;
1221         }
1222         return -1;
1223 }
1224
1225 void Maplist_Init()
1226 {
1227         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1228         if(Map_Count == 0)
1229         {
1230                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1231                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1232                 if(autocvar_g_maplist_shuffle)
1233                         ShuffleMaplist();
1234                 localcmd("\nmenu_cmd sync\n");
1235                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1236         }
1237         if(Map_Count == 0)
1238                 error("empty maplist, cannot select a new map");
1239         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1240
1241         if(Map_Current_Name)
1242                 strunzone(Map_Current_Name);
1243         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1244         // this may or may not be correct, but who cares, in the worst case a map
1245         // isn't chosen in the first pass that should have been
1246 }
1247
1248 string GetNextMap()
1249 {
1250         float nextMap;
1251
1252         Maplist_Init();
1253         nextMap = -1;
1254
1255         if(nextMap == -1)
1256                 if(autocvar_g_maplist_shuffle > 0)
1257                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1258
1259         if(nextMap == -1)
1260                 if(autocvar_g_maplist_selectrandom)
1261                         nextMap = MaplistMethod_Random();
1262
1263         if(nextMap == -1)
1264                 nextMap = MaplistMethod_Iterate();
1265
1266         if(nextMap == -1)
1267                 nextMap = MaplistMethod_Repeat();
1268
1269         if(nextMap >= 0)
1270         {
1271                 Map_Goto_SetFloat(nextMap);
1272                 return getmapname_stored;
1273         }
1274
1275         return "";
1276 }
1277
1278 float DoNextMapOverride()
1279 {
1280         if(autocvar_g_campaign)
1281         {
1282                 CampaignPostIntermission();
1283                 alreadychangedlevel = TRUE;
1284                 return TRUE;
1285         }
1286         if(autocvar_quit_when_empty)
1287         {
1288                 if(player_count <= currentbots)
1289                 {
1290                         localcmd("quit\n");
1291                         alreadychangedlevel = TRUE;
1292                         return TRUE;
1293                 }
1294         }
1295         if(autocvar_quit_and_redirect != "")
1296         {
1297                 redirection_target = strzone(autocvar_quit_and_redirect);
1298                 alreadychangedlevel = TRUE;
1299                 return TRUE;
1300         }
1301         if (autocvar_samelevel) // if samelevel is set, stay on same level
1302         {
1303                 localcmd("restart\n");
1304                 alreadychangedlevel = TRUE;
1305                 return TRUE;
1306         }
1307         if(autocvar_nextmap != "")
1308                 if(MapInfo_CheckMap(autocvar_nextmap))
1309                 {
1310                         Map_Goto_SetStr(autocvar_nextmap);
1311                         Map_Goto();
1312                         alreadychangedlevel = TRUE;
1313                         return TRUE;
1314                 }
1315         if(autocvar_lastlevel)
1316         {
1317                 GameResetCfg();
1318                 localcmd("set lastlevel 0\ntogglemenu\n");
1319                 alreadychangedlevel = TRUE;
1320                 return TRUE;
1321         }
1322         return FALSE;
1323 }
1324
1325 void GotoNextMap()
1326 {
1327         //string nextmap;
1328         //float n, nummaps;
1329         //string s;
1330         if (alreadychangedlevel)
1331                 return;
1332         alreadychangedlevel = TRUE;
1333
1334         {
1335                 string nextMap;
1336                 float allowReset;
1337
1338                 for(allowReset = 1; allowReset >= 0; --allowReset)
1339                 {
1340                         nextMap = GetNextMap();
1341                         if(nextMap != "")
1342                                 break;
1343
1344                         if(allowReset)
1345                         {
1346                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1347                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1348                                 if(autocvar_g_maplist_shuffle)
1349                                         ShuffleMaplist();
1350                                 localcmd("\nmenu_cmd sync\n");
1351                         }
1352                         else
1353                         {
1354                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1355                         }
1356                 }
1357                 Map_Goto();
1358         }
1359 }
1360
1361
1362 /*
1363 ============
1364 IntermissionThink
1365
1366 When the player presses attack or jump, change to the next level
1367 ============
1368 */
1369 .float autoscreenshot;
1370 void() MapVote_Start;
1371 void() MapVote_Think;
1372 float mapvote_initialized;
1373 void IntermissionThink()
1374 {
1375         FixIntermissionClient(self);
1376
1377         if( (autocvar_sv_autoscreenshot || self.cvar_cl_autoscreenshot)
1378                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1379         {
1380                 self.autoscreenshot = -1;
1381                 if(clienttype(self) == CLIENTTYPE_REAL)
1382                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1383                 return;
1384         }
1385
1386         if (time < intermission_exittime)
1387                 return;
1388
1389         if(!mapvote_initialized)
1390                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1391                         return;
1392
1393         MapVote_Start();
1394 }
1395
1396 /*
1397 ============
1398 FindIntermission
1399
1400 Returns the entity to view from
1401 ============
1402 */
1403 /*
1404 entity FindIntermission()
1405 {
1406         local   entity spot;
1407         local   float cyc;
1408
1409 // look for info_intermission first
1410         spot = find (world, classname, "info_intermission");
1411         if (spot)
1412         {       // pick a random one
1413                 cyc = random() * 4;
1414                 while (cyc > 1)
1415                 {
1416                         spot = find (spot, classname, "info_intermission");
1417                         if (!spot)
1418                                 spot = find (spot, classname, "info_intermission");
1419                         cyc = cyc - 1;
1420                 }
1421                 return spot;
1422         }
1423
1424 // then look for the start position
1425         spot = find (world, classname, "info_player_start");
1426         if (spot)
1427                 return spot;
1428
1429 // testinfo_player_start is only found in regioned levels
1430         spot = find (world, classname, "testplayerstart");
1431         if (spot)
1432                 return spot;
1433
1434 // then look for the start position
1435         spot = find (world, classname, "info_player_deathmatch");
1436         if (spot)
1437                 return spot;
1438
1439         //objerror ("FindIntermission: no spot");
1440         return world;
1441 }
1442 */
1443
1444 /*
1445 ===============================================================================
1446
1447 RULES
1448
1449 ===============================================================================
1450 */
1451
1452 void DumpStats(float final)
1453 {
1454         float file;
1455         string s;
1456         float to_console;
1457         float to_eventlog;
1458         float to_file;
1459         float i;
1460
1461         to_console = autocvar_sv_logscores_console;
1462         to_eventlog = autocvar_sv_eventlog;
1463         to_file = autocvar_sv_logscores_file;
1464
1465         if(!final)
1466         {
1467                 to_console = TRUE; // always print printstats replies
1468                 to_eventlog = FALSE; // but never print them to the event log
1469         }
1470
1471         if(to_eventlog)
1472                 if(autocvar_sv_eventlog_console)
1473                         to_console = FALSE; // otherwise we get the output twice
1474
1475         if(final)
1476                 s = ":scores:";
1477         else
1478                 s = ":status:";
1479         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1480
1481         if(to_console)
1482                 print(s, "\n");
1483         if(to_eventlog)
1484                 GameLogEcho(s);
1485         if(to_file)
1486         {
1487                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1488                 if(file == -1)
1489                         to_file = FALSE;
1490                 else
1491                         fputs(file, strcat(s, "\n"));
1492         }
1493
1494         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1495         if(to_console)
1496                 print(s, "\n");
1497         if(to_eventlog)
1498                 GameLogEcho(s);
1499         if(to_file)
1500                 fputs(file, strcat(s, "\n"));
1501
1502         FOR_EACH_CLIENT(other)
1503         {
1504                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1505                 {
1506                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1507                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1508                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1509                                 s = strcat(s, ftos(other.team), ":");
1510                         else
1511                                 s = strcat(s, "spectator:");
1512
1513                         if(to_console)
1514                                 print(s, other.netname, "\n");
1515                         if(to_eventlog)
1516                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1517                         if(to_file)
1518                                 fputs(file, strcat(s, other.netname, "\n"));
1519                 }
1520         }
1521
1522         if(teamplay)
1523         {
1524                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1525                 if(to_console)
1526                         print(s, "\n");
1527                 if(to_eventlog)
1528                         GameLogEcho(s);
1529                 if(to_file)
1530                         fputs(file, strcat(s, "\n"));
1531
1532                 for(i = 1; i < 16; ++i)
1533                 {
1534                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1535                         s = strcat(s, ":", ftos(i));
1536                         if(to_console)
1537                                 print(s, "\n");
1538                         if(to_eventlog)
1539                                 GameLogEcho(s);
1540                         if(to_file)
1541                                 fputs(file, strcat(s, "\n"));
1542                 }
1543         }
1544
1545         if(to_console)
1546                 print(":end\n");
1547         if(to_eventlog)
1548                 GameLogEcho(":end");
1549         if(to_file)
1550         {
1551                 fputs(file, ":end\n");
1552                 fclose(file);
1553         }
1554 }
1555
1556 void FixIntermissionClient(entity e)
1557 {
1558         string s;
1559         if(!e.autoscreenshot) // initial call
1560         {
1561                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1562                 e.health = -2342;
1563                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1564                 e.solid = SOLID_NOT;
1565                 e.movetype = MOVETYPE_NONE;
1566                 e.takedamage = DAMAGE_NO;
1567                 if(e.weaponentity)
1568                 {
1569                         e.weaponentity.effects = EF_NODRAW;
1570                         if (e.weaponentity.weaponentity)
1571                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1572                 }
1573                 if(clienttype(e) == CLIENTTYPE_REAL)
1574                 {
1575                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1576                         s = autocvar_sv_intermission_cdtrack;
1577                         if(s != "")
1578                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1579                         msg_entity = e;
1580                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1581                 }
1582         }
1583 }
1584
1585
1586 /*
1587 go to the next level for deathmatch
1588 only called if a time or frag limit has expired
1589 */
1590 void NextLevel()
1591 {
1592         gameover = TRUE;
1593
1594         intermission_running = 1;
1595
1596 // enforce a wait time before allowing changelevel
1597         if(player_count > 0)
1598                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1599         else
1600                 intermission_exittime = -1;
1601
1602         /*
1603         WriteByte (MSG_ALL, SVC_CDTRACK);
1604         WriteByte (MSG_ALL, 3);
1605         WriteByte (MSG_ALL, 3);
1606         // done in FixIntermission
1607         */
1608
1609         //pos = FindIntermission ();
1610
1611         VoteReset();
1612
1613         DumpStats(TRUE);
1614
1615         // send statistics
1616         entity e;
1617         PlayerStats_EndMatch(1);
1618         FOR_EACH_CLIENT(e)
1619                 PlayerStats_AddGlobalInfo(e);
1620         PlayerStats_Shutdown();
1621         WeaponStats_Shutdown();
1622
1623         if(autocvar_sv_eventlog)
1624                 GameLogEcho(":gameover");
1625
1626         GameLogClose();
1627
1628         FOR_EACH_PLAYER(other) {
1629                 FixIntermissionClient(other);
1630                 if(other.winning)
1631                         bprint(other.netname, " ^7wins.\n");
1632         }
1633
1634         if(autocvar_g_campaign)
1635                 CampaignPreIntermission();
1636
1637         localcmd("\nsv_hook_gameend\n");
1638 }
1639
1640 /*
1641 ============
1642 CheckRules_Player
1643
1644 Exit deathmatch games upon conditions
1645 ============
1646 */
1647 void CheckRules_Player()
1648 {
1649         if (gameover)   // someone else quit the game already
1650                 return;
1651
1652         if(self.deadflag == DEAD_NO)
1653                 self.play_time += frametime;
1654
1655         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1656         //   (div0: and that in CheckRules_World please)
1657 }
1658
1659 float checkrules_equality;
1660 float checkrules_suddendeathwarning;
1661 float checkrules_suddendeathend;
1662 float checkrules_overtimesadded; //how many overtimes have been already added
1663
1664 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1665 float WINNING_YES = 1; // winner found
1666 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1667 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1668
1669 float InitiateSuddenDeath()
1670 {
1671         // Check first whether normal overtimes could be added before initiating suddendeath mode
1672         // - for this timelimit_overtime needs to be >0 of course
1673         // - also check the winning condition calculated in the previous frame and only add normal overtime
1674         //   again, if at the point at which timelimit would be extended again, still no winner was found
1675         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1676         {
1677                 return 1; // need to call InitiateOvertime later
1678         }
1679         else
1680         {
1681                 if(!checkrules_suddendeathend)
1682                 {
1683                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1684                         if(g_race && !g_race_qualifying)
1685                                 race_StartCompleting();
1686                 }
1687                 return 0;
1688         }
1689 }
1690
1691 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1692 {
1693         ++checkrules_overtimesadded;
1694         //add one more overtime by simply extending the timelimit
1695         float tl;
1696         tl = autocvar_timelimit;
1697         tl += autocvar_timelimit_overtime;
1698         cvar_set("timelimit", ftos(tl));
1699         string minutesPlural;
1700         if (autocvar_timelimit_overtime == 1)
1701                 minutesPlural = " ^3minute";
1702         else
1703                 minutesPlural = " ^3minutes";
1704
1705         bcenterprint(
1706                 strcat(
1707                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1708                         ftos(autocvar_timelimit_overtime),
1709                         minutesPlural,
1710                         " to the game!"
1711                 )
1712         );
1713 }
1714
1715 float GetWinningCode(float fraglimitreached, float equality)
1716 {
1717         if(autocvar_g_campaign == 1)
1718                 if(fraglimitreached)
1719                         return WINNING_YES;
1720                 else
1721                         return WINNING_NO;
1722
1723         else
1724                 if(equality)
1725                         if(fraglimitreached)
1726                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1727                         else
1728                                 return WINNING_NEVER;
1729                 else
1730                         if(fraglimitreached)
1731                                 return WINNING_YES;
1732                         else
1733                                 return WINNING_NO;
1734 }
1735
1736 // set the .winning flag for exactly those players with a given field value
1737 void SetWinners(.float field, float value)
1738 {
1739         entity head;
1740         FOR_EACH_PLAYER(head)
1741                 head.winning = (head.field == value);
1742 }
1743
1744 // set the .winning flag for those players with a given field value
1745 void AddWinners(.float field, float value)
1746 {
1747         entity head;
1748         FOR_EACH_PLAYER(head)
1749                 if(head.field == value)
1750                         head.winning = 1;
1751 }
1752
1753 // clear the .winning flags
1754 void ClearWinners(void)
1755 {
1756         entity head;
1757         FOR_EACH_PLAYER(head)
1758                 head.winning = 0;
1759 }
1760
1761 // Onslaught winning condition:
1762 // game terminates if only one team has a working generator (or none)
1763 float WinningCondition_Onslaught()
1764 {
1765         entity head;
1766         float t1, t2, t3, t4;
1767
1768         WinningConditionHelper(); // set worldstatus
1769
1770         if(inWarmupStage)
1771                 return WINNING_NO;
1772
1773         // first check if the game has ended
1774         t1 = t2 = t3 = t4 = 0;
1775         head = find(world, classname, "onslaught_generator");
1776         while (head)
1777         {
1778                 if (head.health > 0)
1779                 {
1780                         if (head.team == COLOR_TEAM1) t1 = 1;
1781                         if (head.team == COLOR_TEAM2) t2 = 1;
1782                         if (head.team == COLOR_TEAM3) t3 = 1;
1783                         if (head.team == COLOR_TEAM4) t4 = 1;
1784                 }
1785                 head = find(head, classname, "onslaught_generator");
1786         }
1787         if (t1 + t2 + t3 + t4 < 2)
1788         {
1789                 // game over, only one team remains (or none)
1790                 ClearWinners();
1791                 if (t1) SetWinners(team, COLOR_TEAM1);
1792                 if (t2) SetWinners(team, COLOR_TEAM2);
1793                 if (t3) SetWinners(team, COLOR_TEAM3);
1794                 if (t4) SetWinners(team, COLOR_TEAM4);
1795                 dprint("Have a winner, ending game.\n");
1796                 return WINNING_YES;
1797         }
1798
1799         // Two or more teams remain
1800         return WINNING_NO;
1801 }
1802
1803 float LMS_NewPlayerLives()
1804 {
1805         float fl;
1806         fl = autocvar_fraglimit;
1807         if(fl == 0)
1808                 fl = 999;
1809
1810         // first player has left the game for dying too much? Nobody else can get in.
1811         if(lms_lowest_lives < 1)
1812                 return 0;
1813
1814         if(!autocvar_g_lms_join_anytime)
1815                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1816                         return 0;
1817
1818         return bound(1, lms_lowest_lives, fl);
1819 }
1820
1821 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1822 // they win. Otherwise the defending team wins once the timelimit passes.
1823 void assault_new_round();
1824 float WinningCondition_Assault()
1825 {
1826         float status;
1827
1828         WinningConditionHelper(); // set worldstatus
1829
1830         status = WINNING_NO;
1831         // as the timelimit has not yet passed just assume the defending team will win
1832         if(assault_attacker_team == COLOR_TEAM1)
1833         {
1834                 SetWinners(team, COLOR_TEAM2);
1835         }
1836         else
1837         {
1838                 SetWinners(team, COLOR_TEAM1);
1839         }
1840
1841         entity ent;
1842         ent = find(world, classname, "target_assault_roundend");
1843         if(ent)
1844         {
1845                 if(ent.winning) // round end has been triggered by attacking team
1846                 {
1847                         bprint("ASSAULT: round completed...\n");
1848                         SetWinners(team, assault_attacker_team);
1849
1850                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1851
1852                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1853                         {
1854                                 status = WINNING_YES;
1855                         }
1856                         else
1857                         {
1858                                 entity oldself;
1859                                 oldself = self;
1860                                 self = ent;
1861                                 assault_new_round();
1862                                 self = oldself;
1863                         }
1864                 }
1865         }
1866
1867         return status;
1868 }
1869
1870 // LMS winning condition: game terminates if and only if there's at most one
1871 // one player who's living lives. Top two scores being equal cancels the time
1872 // limit.
1873 float WinningCondition_LMS()
1874 {
1875         entity head, head2;
1876         float have_player;
1877         float have_players;
1878         float l;
1879
1880         have_player = FALSE;
1881         have_players = FALSE;
1882         l = LMS_NewPlayerLives();
1883
1884         head = find(world, classname, "player");
1885         if(head)
1886                 have_player = TRUE;
1887         head2 = find(head, classname, "player");
1888         if(head2)
1889                 have_players = TRUE;
1890
1891         if(have_player)
1892         {
1893                 // we have at least one player
1894                 if(have_players)
1895                 {
1896                         // two or more active players - continue with the game
1897                 }
1898                 else
1899                 {
1900                         // exactly one player?
1901
1902                         ClearWinners();
1903                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1904
1905                         if(l)
1906                         {
1907                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1908                                 return WINNING_NO;
1909                         }
1910                         else
1911                         {
1912                                 // a winner!
1913                                 // and assign him his first place
1914                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1915                                 return WINNING_YES;
1916                         }
1917                 }
1918         }
1919         else
1920         {
1921                 // nobody is playing at all...
1922                 if(l)
1923                 {
1924                         // wait for players...
1925                 }
1926                 else
1927                 {
1928                         // SNAFU (maybe a draw game?)
1929                         ClearWinners();
1930                         dprint("No players, ending game.\n");
1931                         return WINNING_YES;
1932                 }
1933         }
1934
1935         // When we get here, we have at least two players who are actually LIVING,
1936         // now check if the top two players have equal score.
1937         WinningConditionHelper();
1938
1939         ClearWinners();
1940         if(WinningConditionHelper_winner)
1941                 WinningConditionHelper_winner.winning = TRUE;
1942         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1943                 return WINNING_NEVER;
1944
1945         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1946         return WINNING_NO;
1947 }
1948
1949 void ShuffleMaplist()
1950 {
1951         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1952 }
1953
1954 float leaderfrags;
1955 float WinningCondition_Scores(float limit, float leadlimit)
1956 {
1957         float limitreached;
1958
1959         // TODO make everything use THIS winning condition (except LMS)
1960         WinningConditionHelper();
1961
1962         if(teamplay)
1963         {
1964                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1965                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1966                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1967                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1968         }
1969
1970         ClearWinners();
1971         if(WinningConditionHelper_winner)
1972                 WinningConditionHelper_winner.winning = 1;
1973         if(WinningConditionHelper_winnerteam >= 0)
1974                 SetWinners(team, WinningConditionHelper_winnerteam);
1975
1976         if(WinningConditionHelper_lowerisbetter)
1977         {
1978                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1979                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1980                 limit = -limit;
1981         }
1982
1983         if(WinningConditionHelper_zeroisworst)
1984                 leadlimit = 0; // not supported in this mode
1985
1986         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1987         // these modes always score in increments of 1, thus this makes sense
1988         {
1989                 if(leaderfrags != WinningConditionHelper_topscore)
1990                 {
1991                         leaderfrags = WinningConditionHelper_topscore;
1992
1993                         if (limit)
1994                         if (leaderfrags == limit - 1)
1995                                 Announce("1fragleft");
1996                         else if (leaderfrags == limit - 2)
1997                                 Announce("2fragsleft");
1998                         else if (leaderfrags == limit - 3)
1999                                 Announce("3fragsleft");
2000                 }
2001         }
2002
2003         limitreached = FALSE;
2004         if(limit)
2005                 if(WinningConditionHelper_topscore >= limit)
2006                         limitreached = TRUE;
2007         if(leadlimit)
2008         {
2009                 float leadlimitreached;
2010                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
2011                 if(autocvar_leadlimit_and_fraglimit)
2012                         limitreached = (limitreached && leadlimitreached);
2013                 else
2014                         limitreached = (limitreached || leadlimitreached);
2015         }
2016
2017         return GetWinningCode(
2018                 WinningConditionHelper_topscore && limitreached,
2019                 WinningConditionHelper_equality
2020         );
2021 }
2022
2023 float WinningCondition_Race(float fraglimit)
2024 {
2025         float wc;
2026         entity p;
2027         float n, c;
2028
2029         n = 0;
2030         c = 0;
2031         FOR_EACH_PLAYER(p)
2032         {
2033                 ++n;
2034                 if(p.race_completed)
2035                         ++c;
2036         }
2037         if(n && (n == c))
2038                 return WINNING_YES;
2039         wc = WinningCondition_Scores(fraglimit, 0);
2040
2041         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2042         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2043         // do NOT support equality when the laps are all raced!
2044                 return WINNING_STARTSUDDENDEATHOVERTIME;
2045         else
2046                 return WINNING_NEVER;
2047         return wc;
2048 }
2049
2050 void ReadyRestart();
2051 float WinningCondition_QualifyingThenRace(float limit)
2052 {
2053         float wc;
2054         wc = WinningCondition_Scores(limit, 0);
2055
2056         // NEVER initiate overtime
2057         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2058         {
2059                 return WINNING_YES;
2060         }
2061
2062         return wc;
2063 }
2064
2065 float WinningCondition_RanOutOfSpawns()
2066 {
2067         entity head;
2068
2069         if(have_team_spawns <= 0)
2070                 return WINNING_NO;
2071
2072         if(autocvar_g_spawn_useallspawns <= 0)
2073                 return WINNING_NO;
2074
2075         if(!some_spawn_has_been_used)
2076                 return WINNING_NO;
2077
2078         team1_score = team2_score = team3_score = team4_score = 0;
2079
2080         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2081         {
2082                 if(head.team == COLOR_TEAM1)
2083                         team1_score = 1;
2084                 else if(head.team == COLOR_TEAM2)
2085                         team2_score = 1;
2086                 else if(head.team == COLOR_TEAM3)
2087                         team3_score = 1;
2088                 else if(head.team == COLOR_TEAM4)
2089                         team4_score = 1;
2090         }
2091
2092         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2093         {
2094                 if(head.team == COLOR_TEAM1)
2095                         team1_score = 1;
2096                 else if(head.team == COLOR_TEAM2)
2097                         team2_score = 1;
2098                 else if(head.team == COLOR_TEAM3)
2099                         team3_score = 1;
2100                 else if(head.team == COLOR_TEAM4)
2101                         team4_score = 1;
2102         }
2103
2104         ClearWinners();
2105         if(team1_score + team2_score + team3_score + team4_score == 0)
2106         {
2107                 checkrules_equality = TRUE;
2108                 return WINNING_YES;
2109         }
2110         else if(team1_score + team2_score + team3_score + team4_score == 1)
2111         {
2112                 float t, i;
2113                 if(team1_score) t = COLOR_TEAM1;
2114                 if(team2_score) t = COLOR_TEAM2;
2115                 if(team3_score) t = COLOR_TEAM3;
2116                 if(team4_score) t = COLOR_TEAM4;
2117                 CheckAllowedTeams(world);
2118                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2119                 {
2120                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2121                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2122                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2123                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2124                 }
2125
2126                 AddWinners(team, t);
2127                 return WINNING_YES;
2128         }
2129         else
2130                 return WINNING_NO;
2131 }
2132
2133 /*
2134 ============
2135 CheckRules_World
2136
2137 Exit deathmatch games upon conditions
2138 ============
2139 */
2140 void CheckRules_World()
2141 {
2142         float timelimit;
2143         float fraglimit;
2144         float leadlimit;
2145
2146         VoteThink();
2147         MapVote_Think();
2148
2149         SetDefaultAlpha();
2150
2151         /*
2152         MapVote_Think should now do that part
2153         if (intermission_running)
2154                 if (time >= intermission_exittime + 60)
2155                 {
2156                         if(!DoNextMapOverride())
2157                                 GotoNextMap();
2158                         return;
2159                 }
2160         */
2161
2162         if (gameover)   // someone else quit the game already
2163         {
2164                 if(player_count == 0) // Nobody there? Then let's go to the next map
2165                         MapVote_Start();
2166                         // this will actually check the player count in the next frame
2167                         // again, but this shouldn't hurt
2168                 return;
2169         }
2170
2171         timelimit = autocvar_timelimit * 60;
2172         fraglimit = autocvar_fraglimit;
2173         leadlimit = autocvar_leadlimit;
2174
2175         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2176         {
2177                 if(timelimit > 0)
2178                         timelimit = 0; // timelimit is not made for warmup
2179                 if(fraglimit > 0)
2180                         fraglimit = 0; // no fraglimit for now
2181                 leadlimit = 0; // no leadlimit for now
2182         }
2183
2184         if(g_onslaught)
2185                 timelimit = 0; // ONS has its own overtime rule
2186
2187         if(timelimit > 0)
2188         {
2189                 timelimit += game_starttime;
2190         }
2191         else if (timelimit < 0)
2192         {
2193                 // endmatch
2194                 NextLevel();
2195                 return;
2196         }
2197
2198         float wantovertime;
2199         wantovertime = 0;
2200
2201         if(checkrules_suddendeathend)
2202         {
2203                 if(!checkrules_suddendeathwarning)
2204                 {
2205                         checkrules_suddendeathwarning = TRUE;
2206                         if(g_race && !g_race_qualifying)
2207                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2208                         else
2209                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2210                 }
2211         }
2212         else
2213         {
2214                 if (timelimit && time >= timelimit)
2215                 {
2216                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2217                         {
2218                                 float totalplayers;
2219                                 float playerswithlaps;
2220                                 float readyplayers;
2221                                 entity head;
2222                                 totalplayers = playerswithlaps = readyplayers = 0;
2223                                 FOR_EACH_PLAYER(head)
2224                                 {
2225                                         ++totalplayers;
2226                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2227                                                 ++playerswithlaps;
2228                                         if(head.ready)
2229                                                 ++readyplayers;
2230                                 }
2231
2232                                 // at least 2 of the players have completed a lap: start the RACE
2233                                 // otherwise, the players should end the qualifying on their own
2234                                 if(readyplayers || playerswithlaps >= 2)
2235                                 {
2236                                         checkrules_suddendeathend = 0;
2237                                         ReadyRestart(); // go to race
2238                                         return;
2239                                 }
2240                                 else
2241                                         wantovertime |= InitiateSuddenDeath();
2242                         }
2243                         else
2244                                 wantovertime |= InitiateSuddenDeath();
2245                 }
2246         }
2247
2248         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2249         {
2250                 NextLevel();
2251                 return;
2252         }
2253
2254         float checkrules_status;
2255         checkrules_status = WinningCondition_RanOutOfSpawns();
2256         if(checkrules_status == WINNING_YES)
2257         {
2258                 bprint("Hey! Someone ran out of spawns!\n");
2259         }
2260         else if(g_race && !g_race_qualifying && timelimit >= 0)
2261         {
2262                 checkrules_status = WinningCondition_Race(fraglimit);
2263                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2264         }
2265         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2266         {
2267                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2268                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2269         }
2270         else if(g_assault)
2271         {
2272                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2273         }
2274         else if(g_lms)
2275         {
2276                 checkrules_status = WinningCondition_LMS();
2277         }
2278         else if (g_onslaught)
2279         {
2280                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2281         }
2282         else
2283         {
2284                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2285                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2286         }
2287
2288         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2289         {
2290                 checkrules_status = WINNING_NEVER;
2291                 checkrules_overtimesadded = -1;
2292                 wantovertime |= InitiateSuddenDeath();
2293         }
2294
2295         if(checkrules_status == WINNING_NEVER)
2296                 // equality cases! Nobody wins if the overtime ends in a draw.
2297                 ClearWinners();
2298
2299         if(wantovertime)
2300         {
2301                 if(checkrules_status == WINNING_NEVER)
2302                         InitiateOvertime();
2303                 else
2304                         checkrules_status = WINNING_YES;
2305         }
2306
2307         if(checkrules_suddendeathend)
2308                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2309                         checkrules_status = WINNING_YES;
2310
2311         if(checkrules_status == WINNING_YES)
2312         {
2313                 //print("WINNING\n");
2314                 NextLevel();
2315         }
2316 }
2317
2318 float mapvote_nextthink;
2319 float mapvote_initialized;
2320 float mapvote_keeptwotime;
2321 float mapvote_timeout;
2322 string mapvote_message;
2323 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2324 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2325 float mapvote_screenshot_dirs_count;
2326
2327 float mapvote_count;
2328 float mapvote_count_real;
2329 string mapvote_maps[MAPVOTE_COUNT];
2330 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2331 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2332 float mapvote_maps_suggested[MAPVOTE_COUNT];
2333 string mapvote_suggestions[MAPVOTE_COUNT];
2334 float mapvote_suggestion_ptr;
2335 float mapvote_voters;
2336 float mapvote_votes[MAPVOTE_COUNT];
2337 float mapvote_run;
2338 float mapvote_detail;
2339 float mapvote_abstain;
2340 .float mapvote;
2341
2342 void MapVote_ClearAllVotes()
2343 {
2344         FOR_EACH_CLIENT(other)
2345                 other.mapvote = 0;
2346 }
2347
2348 string MapVote_Suggest(string m)
2349 {
2350         float i;
2351         if(m == "")
2352                 return "That's not how to use this command.";
2353         if(!autocvar_g_maplist_votable_suggestions)
2354                 return "Suggestions are not accepted on this server.";
2355         if(mapvote_initialized)
2356                 return "Can't suggest - voting is already in progress!";
2357         m = MapInfo_FixName(m);
2358         if(!m)
2359                 return "The map you suggested is not available on this server.";
2360         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2361                 if(Map_IsRecent(m))
2362                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2363
2364         if(!MapInfo_CheckMap(m))
2365                 return "The map you suggested does not support the current game mode.";
2366         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2367                 if(mapvote_suggestions[i] == m)
2368                         return "This map was already suggested.";
2369         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2370         {
2371                 i = floor(random() * mapvote_suggestion_ptr);
2372         }
2373         else
2374         {
2375                 i = mapvote_suggestion_ptr;
2376                 mapvote_suggestion_ptr += 1;
2377         }
2378         if(mapvote_suggestions[i] != "")
2379                 strunzone(mapvote_suggestions[i]);
2380         mapvote_suggestions[i] = strzone(m);
2381         if(autocvar_sv_eventlog)
2382                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2383         return strcat("Suggestion of ", m, " accepted.");
2384 }
2385
2386 void MapVote_AddVotable(string nextMap, float isSuggestion)
2387 {
2388         float j, i, o;
2389         string pakfile, mapfile;
2390
2391         if(nextMap == "")
2392                 return;
2393         for(j = 0; j < mapvote_count; ++j)
2394                 if(mapvote_maps[j] == nextMap)
2395                         return;
2396         // suggestions might be no longer valid/allowed after gametype switch!
2397         if(isSuggestion)
2398                 if(!MapInfo_CheckMap(nextMap))
2399                         return;
2400         mapvote_maps[mapvote_count] = strzone(nextMap);
2401         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2402
2403         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2404         {
2405                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2406                 pakfile = whichpack(strcat(mapfile, ".tga"));
2407                 if(pakfile == "")
2408                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2409                 if(pakfile == "")
2410                         pakfile = whichpack(strcat(mapfile, ".png"));
2411                 if(pakfile != "")
2412                         break;
2413         }
2414         if(i >= mapvote_screenshot_dirs_count)
2415                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2416         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2417                 pakfile = substring(pakfile, o, -1);
2418
2419         mapvote_maps_screenshot_dir[mapvote_count] = i;
2420         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2421
2422         mapvote_count += 1;
2423 }
2424
2425 void MapVote_Spawn();
2426 void MapVote_Init()
2427 {
2428         float i;
2429         float nmax, smax;
2430
2431         MapVote_ClearAllVotes();
2432
2433         mapvote_count = 0;
2434         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2435         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2436
2437         if(mapvote_abstain)
2438                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2439         else
2440                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2441         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2442
2443         // we need this for AddVotable, as that cycles through the screenshot dirs
2444         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2445         if(mapvote_screenshot_dirs_count == 0)
2446                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2447         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2448         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2449                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2450
2451         if(mapvote_suggestion_ptr)
2452                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2453                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2454
2455         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2456                 MapVote_AddVotable(GetNextMap(), FALSE);
2457
2458         if(mapvote_count == 0)
2459         {
2460                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2461                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2462                 if(autocvar_g_maplist_shuffle)
2463                         ShuffleMaplist();
2464                 localcmd("\nmenu_cmd sync\n");
2465                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2466                         MapVote_AddVotable(GetNextMap(), FALSE);
2467         }
2468
2469         mapvote_count_real = mapvote_count;
2470         if(mapvote_abstain)
2471                 MapVote_AddVotable("don't care", 0);
2472
2473         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2474
2475         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2476         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2477         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2478                 mapvote_keeptwotime = 0;
2479         mapvote_message = "Choose a map and press its key!";
2480
2481         MapVote_Spawn();
2482 }
2483
2484 void MapVote_SendPicture(float id)
2485 {
2486         msg_entity = self;
2487         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2488         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2489         WriteByte(MSG_ONE, id);
2490         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2491 }
2492
2493 float GameCommand_MapVote(string cmd)
2494 {
2495         if(!intermission_running)
2496                 return FALSE;
2497
2498         if(cmd == "mv_getpic")
2499         {
2500                 MapVote_SendPicture(stof(argv(1)));
2501                 return TRUE;
2502         }
2503
2504         return FALSE;
2505 }
2506
2507 float MapVote_GetMapMask()
2508 {
2509         float mask, i, power;
2510         mask = 0;
2511         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2512                 if(mapvote_maps[i] != "")
2513                         mask |= power;
2514         return mask;
2515 }
2516
2517 entity mapvote_ent;
2518 float MapVote_SendEntity(entity to, float sf)
2519 {
2520         float i;
2521
2522         if(sf & 1)
2523                 sf &~= 2; // if we send 1, we don't need to also send 2
2524
2525         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2526         WriteByte(MSG_ENTITY, sf);
2527
2528         if(sf & 1)
2529         {
2530                 // flag 1 == initialization
2531                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2532                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2533                 WriteString(MSG_ENTITY, "");
2534                 WriteByte(MSG_ENTITY, mapvote_count);
2535                 WriteByte(MSG_ENTITY, mapvote_abstain);
2536                 WriteByte(MSG_ENTITY, mapvote_detail);
2537                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2538                 if(mapvote_count <= 8)
2539                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2540                 else
2541                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2542                 for(i = 0; i < mapvote_count; ++i)
2543                         if(mapvote_maps[i] != "")
2544                         {
2545                                 if(mapvote_abstain && i == mapvote_count - 1)
2546                                 {
2547                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2548                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2549                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2550                                 }
2551                                 else
2552                                 {
2553                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2554                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2555                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2556                                 }
2557                         }
2558         }
2559
2560         if(sf & 2)
2561         {
2562                 // flag 2 == update of mask
2563                 if(mapvote_count <= 8)
2564                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2565                 else
2566                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2567         }
2568
2569         if(sf & 4)
2570         {
2571                 if(mapvote_detail)
2572                         for(i = 0; i < mapvote_count; ++i)
2573                                 if(mapvote_maps[i] != "")
2574                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2575
2576                 WriteByte(MSG_ENTITY, to.mapvote);
2577         }
2578
2579         return TRUE;
2580 }
2581
2582 void MapVote_Spawn()
2583 {
2584         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2585 }
2586
2587 void MapVote_TouchMask()
2588 {
2589         mapvote_ent.SendFlags |= 2;
2590 }
2591
2592 void MapVote_TouchVotes(entity voter)
2593 {
2594         mapvote_ent.SendFlags |= 4;
2595 }
2596
2597 float MapVote_Finished(float mappos)
2598 {
2599         string result;
2600         float i;
2601         float didntvote;
2602
2603         if(autocvar_sv_eventlog)
2604         {
2605                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2606                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2607                 didntvote = mapvote_voters;
2608                 for(i = 0; i < mapvote_count; ++i)
2609                         if(mapvote_maps[i] != "")
2610                         {
2611                                 didntvote -= mapvote_votes[i];
2612                                 if(i != mappos)
2613                                 {
2614                                         result = strcat(result, ":", mapvote_maps[i]);
2615                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2616                                 }
2617                         }
2618                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2619
2620                 GameLogEcho(result);
2621                 if(mapvote_maps_suggested[mappos])
2622                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2623         }
2624
2625         FOR_EACH_REALCLIENT(other)
2626                 FixClientCvars(other);
2627
2628         Map_Goto_SetStr(mapvote_maps[mappos]);
2629         Map_Goto();
2630         alreadychangedlevel = TRUE;
2631         return TRUE;
2632 }
2633 void MapVote_CheckRules_1()
2634 {
2635         float i;
2636
2637         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2638         {
2639                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2640                 mapvote_votes[i] = 0;
2641         }
2642
2643         mapvote_voters = 0;
2644         FOR_EACH_REALCLIENT(other)
2645         {
2646                 ++mapvote_voters;
2647                 if(other.mapvote)
2648                 {
2649                         i = other.mapvote - 1;
2650                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2651                         mapvote_votes[i] = mapvote_votes[i] + 1;
2652                 }
2653         }
2654 }
2655
2656 float MapVote_CheckRules_2()
2657 {
2658         float i;
2659         float firstPlace, secondPlace;
2660         float firstPlaceVotes, secondPlaceVotes;
2661         float mapvote_voters_real;
2662         string result;
2663
2664         if(mapvote_count_real == 1)
2665                 return MapVote_Finished(0);
2666
2667         mapvote_voters_real = mapvote_voters;
2668         if(mapvote_abstain)
2669                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2670
2671         RandomSelection_Init();
2672         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2673                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2674         firstPlace = RandomSelection_chosen_float;
2675         firstPlaceVotes = RandomSelection_best_priority;
2676         //dprint("First place: ", ftos(firstPlace), "\n");
2677         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2678
2679         RandomSelection_Init();
2680         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2681                 if(i != firstPlace)
2682                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2683         secondPlace = RandomSelection_chosen_float;
2684         secondPlaceVotes = RandomSelection_best_priority;
2685         //dprint("Second place: ", ftos(secondPlace), "\n");
2686         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2687
2688         if(firstPlace == -1)
2689                 error("No first place in map vote... WTF?");
2690
2691         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2692                 return MapVote_Finished(firstPlace);
2693
2694         if(mapvote_keeptwotime)
2695                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2696                 {
2697                         float didntvote;
2698                         MapVote_TouchMask();
2699                         mapvote_message = "Now decide between the TOP TWO!";
2700                         mapvote_keeptwotime = 0;
2701                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2702                         result = strcat(result, ":", ftos(firstPlaceVotes));
2703                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2704                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2705                         didntvote = mapvote_voters;
2706                         for(i = 0; i < mapvote_count; ++i)
2707                                 if(mapvote_maps[i] != "")
2708                                 {
2709                                         didntvote -= mapvote_votes[i];
2710                                         if(i != firstPlace)
2711                                                 if(i != secondPlace)
2712                                                 {
2713                                                         result = strcat(result, ":", mapvote_maps[i]);
2714                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2715                                                         if(i < mapvote_count_real)
2716                                                         {
2717                                                                 strunzone(mapvote_maps[i]);
2718                                                                 mapvote_maps[i] = "";
2719                                                                 strunzone(mapvote_maps_pakfile[i]);
2720                                                                 mapvote_maps_pakfile[i] = "";
2721                                                         }
2722                                                 }
2723                                 }
2724                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2725                         if(autocvar_sv_eventlog)
2726                                 GameLogEcho(result);
2727                 }
2728
2729         return FALSE;
2730 }
2731 void MapVote_Tick()
2732 {
2733         float keeptwo;
2734         float totalvotes;
2735
2736         keeptwo = mapvote_keeptwotime;
2737         MapVote_CheckRules_1(); // count
2738         if(MapVote_CheckRules_2()) // decide
2739                 return;
2740
2741         totalvotes = 0;
2742         FOR_EACH_REALCLIENT(other)
2743         {
2744                 // hide scoreboard again
2745                 if(other.health != 2342)
2746                 {
2747                         other.health = 2342;
2748                         other.impulse = 0;
2749                         if(clienttype(other) == CLIENTTYPE_REAL)
2750                         {
2751                                 msg_entity = other;
2752                                 WriteByte(MSG_ONE, SVC_FINALE);
2753                                 WriteString(MSG_ONE, "");
2754                         }
2755                 }
2756
2757                 // clear possibly invalid votes
2758                 if(mapvote_maps[other.mapvote - 1] == "")
2759                         other.mapvote = 0;
2760                 // use impulses as new vote
2761                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2762                         if(mapvote_maps[other.impulse - 1] != "")
2763                         {
2764                                 other.mapvote = other.impulse;
2765                                 MapVote_TouchVotes(other);
2766                         }
2767                 other.impulse = 0;
2768
2769                 if(other.mapvote)
2770                         ++totalvotes;
2771         }
2772
2773         MapVote_CheckRules_1(); // just count
2774 }
2775 void MapVote_Start()
2776 {
2777         if(mapvote_run)
2778                 return;
2779
2780         // wait for stats to be sent first
2781         if(!playerstats_waitforme)
2782                 return;
2783
2784         MapInfo_Enumerate();
2785         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2786                 mapvote_run = TRUE;
2787 }
2788 void MapVote_Think()
2789 {
2790         if(!mapvote_run)
2791                 return;
2792
2793         if(alreadychangedlevel)
2794                 return;
2795
2796         if(time < mapvote_nextthink)
2797                 return;
2798         //dprint("tick\n");
2799
2800         mapvote_nextthink = time + 0.5;
2801
2802         if(!mapvote_initialized)
2803         {
2804                 if(autocvar_rescan_pending == 1)
2805                 {
2806                         cvar_set("rescan_pending", "2");
2807                         localcmd("fs_rescan\nrescan_pending 3\n");
2808                         return;
2809                 }
2810                 else if(autocvar_rescan_pending == 2)
2811                 {
2812                         return;
2813                 }
2814                 else if(autocvar_rescan_pending == 3)
2815                 {
2816                         // now build missing mapinfo files
2817                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2818                                 return;
2819
2820                         // we're done, start the timer
2821                         cvar_set("rescan_pending", "0");
2822                 }
2823
2824                 mapvote_initialized = TRUE;
2825                 if(DoNextMapOverride())
2826                         return;
2827                 if(!autocvar_g_maplist_votable || player_count <= 0)
2828                 {
2829                         GotoNextMap();
2830                         return;
2831                 }
2832                 MapVote_Init();
2833         }
2834
2835         MapVote_Tick();
2836 }
2837
2838 string GotoMap(string m)
2839 {
2840         if(!MapInfo_CheckMap(m))
2841                 return "The map you chose is not available on this server.";
2842         cvar_set("nextmap", m);
2843         cvar_set("timelimit", "-1");
2844         if(mapvote_initialized || alreadychangedlevel)
2845         {
2846                 if(DoNextMapOverride())
2847                         return "Map switch initiated.";
2848                 else
2849                         return "Hm... no. For some reason I like THIS map more.";
2850         }
2851         else
2852                 return "Map switch will happen after scoreboard.";
2853 }
2854
2855
2856 void EndFrame()
2857 {
2858         float altime;
2859         FOR_EACH_REALCLIENT(self)
2860         {
2861                 if(self.classname == "spectator")
2862                 {
2863                         if(self.enemy.typehitsound)
2864                                 self.typehit_time = time;
2865                         else if(self.enemy.hitsound)
2866                                 self.hit_time = time;
2867                 }
2868                 else
2869                 {
2870                         if(self.typehitsound)
2871                                 self.typehit_time = time;
2872                         else if(self.hitsound)
2873                                 self.hit_time = time;
2874                 }
2875         }
2876         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2877         // add 1 frametime because after this, engine SV_Physics
2878         // increases time by a frametime and then networks the frame
2879         // add another frametime because client shows everything with
2880         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2881         // needed!
2882         FOR_EACH_CLIENT(self)
2883         {
2884                 self.hitsound = FALSE;
2885                 self.typehitsound = FALSE;
2886                 antilag_record(self, altime);
2887         }
2888 }
2889
2890
2891 /*
2892  * RedirectionThink:
2893  * returns TRUE if redirecting
2894  */
2895 float redirection_timeout;
2896 float redirection_nextthink;
2897 float RedirectionThink()
2898 {
2899         float clients_found;
2900
2901         if(redirection_target == "")
2902                 return FALSE;
2903
2904         if(!redirection_timeout)
2905         {
2906                 cvar_set("sv_public", "-2");
2907                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2908                 if(redirection_target == "self")
2909                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2910                 else
2911                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2912         }
2913
2914         if(time < redirection_nextthink)
2915                 return TRUE;
2916
2917         redirection_nextthink = time + 1;
2918
2919         clients_found = 0;
2920         FOR_EACH_REALCLIENT(self)
2921         {
2922                 print("Redirecting: sending connect command to ", self.netname, "\n");
2923                 if(redirection_target == "self")
2924                         stuffcmd(self, "\ndisconnect; reconnect\n");
2925                 else
2926                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2927                 ++clients_found;
2928         }
2929
2930         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2931
2932         if(time > redirection_timeout || clients_found == 0)
2933                 localcmd("\nwait; wait; wait; quit\n");
2934
2935         return TRUE;
2936 }
2937
2938 void TargetMusic_RestoreGame();
2939 void RestoreGame()
2940 {
2941         // Loaded from a save game
2942         // some things then break, so let's work around them...
2943
2944         // Progs DB (capture records)
2945         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2946
2947         // Mapinfo
2948         MapInfo_Shutdown();
2949         MapInfo_Enumerate();
2950         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2951         WeaponStats_Init();
2952
2953         TargetMusic_RestoreGame();
2954 }
2955
2956 void SV_Shutdown()
2957 {
2958         entity e;
2959
2960         if(gameover > 1) // shutting down already?
2961                 return;
2962
2963         gameover = 2; // 2 = server shutting down
2964
2965         if(world_initialized > 0)
2966         {
2967                 world_initialized = 0;
2968                 print("Saving persistent data...\n");
2969                 Ban_SaveBans();
2970
2971                 PlayerStats_EndMatch(0);
2972                 FOR_EACH_CLIENT(e)
2973                         PlayerStats_AddGlobalInfo(e);
2974                 PlayerStats_Shutdown();
2975
2976                 if(!cheatcount_total)
2977                 {
2978                         if(autocvar_sv_db_saveasdump)
2979                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2980                         else
2981                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2982                 }
2983                 if(autocvar_developer)
2984                 {
2985                         if(autocvar_sv_db_saveasdump)
2986                                 db_dump(TemporaryDB, "server-temp.db");
2987                         else
2988                                 db_save(TemporaryDB, "server-temp.db");
2989                 }
2990                 CheatShutdown(); // must be after cheatcount check
2991                 db_close(ServerProgsDB);
2992                 db_close(TemporaryDB);
2993                 print("done!\n");
2994                 // tell the bot system the game is ending now
2995                 bot_endgame();
2996
2997                 WeaponStats_Shutdown();
2998                 MapInfo_Shutdown();
2999         }
3000         else if(world_initialized == 0)
3001         {
3002                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
3003         }
3004 }