qcsrc/server/g_world.qc

   1 #include "g_world.qh"
   2
   3 #include "anticheat.qh"
   4 #include "antilag.qh"
   5 #include "bot/bot.qh"
   6 #include "campaign.qh"
   7 #include "cheats.qh"
   8 #include "cl_client.qh"
   9 #include "command/common.qh"
  10 #include "command/getreplies.qh"
  11 #include "command/sv_cmd.qh"
  12 #include "command/vote.qh"
  13 #include "g_hook.qh"
  14 #include "ipban.qh"
  15 #include "mapvoting.qh"
  16 #include "mutators/all.qh"
  17 #include "race.qh"
  18 #include "scores.qh"
  19 #include "teamplay.qh"
  20 #include "weapons/weaponstats.qh"
  21 #include "../common/buffs/all.qh"
  22 #include "../common/constants.qh"
  23 #include "../common/deathtypes/all.qh"
  24 #include "../common/mapinfo.qh"
  25 #include "../common/monsters/all.qh"
  26 #include "../common/monsters/sv_monsters.qh"
  27 #include "../common/vehicles/all.qh"
  28 #include "../common/notifications.qh"
  29 #include "../common/physics.qh"
  30 #include "../common/playerstats.qh"
  31 #include "../common/stats.qh"
  32 #include "../common/teams.qh"
  33 #include "../common/triggers/trigger/secret.qh"
  34 #include "../common/triggers/target/music.qh"
  35 #include "../common/util.qh"
  36 #include "../common/items/all.qh"
  37 #include "../common/weapons/all.qh"
  38
  39 const float LATENCY_THINKRATE = 10;
  40 .float latency_sum;
  41 .float latency_cnt;
  42 .float latency_time;
  43 entity pingplreport;
  44 void PingPLReport_Think()
  45 {SELFPARAM();
  46         float delta;
  47         entity e;
  48
  49         delta = 3 / maxclients;
  50         if(delta < sys_frametime)
  51                 delta = 0;
  52         self.nextthink = time + delta;
  53
  54         e = edict_num(self.cnt + 1);
  55         if(IS_REAL_CLIENT(e))
  56         {
  57                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  58                 WriteByte(MSG_BROADCAST, self.cnt);
  59                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  60                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  61                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  62
  63                 // record latency times for clients throughout the match so we can report it to playerstats
  64                 if(time > (e.latency_time + LATENCY_THINKRATE))
  65                 {
  66                         e.latency_sum += e.ping;
  67                         e.latency_cnt += 1;
  68                         e.latency_time = time;
  69                         //print("sum: ", ftos(e.latency_sum), ", cnt: ", ftos(e.latency_cnt), ", avg: ", ftos(e.latency_sum / e.latency_cnt), ".\n");
  70                 }
  71         }
  72         else
  73         {
  74                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  75                 WriteByte(MSG_BROADCAST, self.cnt);
  76                 WriteShort(MSG_BROADCAST, 0);
  77                 WriteByte(MSG_BROADCAST, 0);
  78                 WriteByte(MSG_BROADCAST, 0);
  79         }
  80         self.cnt = (self.cnt + 1) % maxclients;
  81 }
  82 void PingPLReport_Spawn()
  83 {
  84         pingplreport = new(pingplreport);
  85         make_pure(pingplreport);
  86         pingplreport.think = PingPLReport_Think;
  87         pingplreport.nextthink = time;
  88 }
  89
  90 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  91 string redirection_target;
  92 float world_initialized;
  93
  94 string GetGametype();
  95 void ShuffleMaplist();
  96
  97 void SetDefaultAlpha()
  98 {
  99         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 100         {
 101                 default_player_alpha = autocvar_g_player_alpha;
 102                 if(default_player_alpha == 0)
 103                         default_player_alpha = 1;
 104                 default_weapon_alpha = default_player_alpha;
 105         }
 106 }
 107
 108 void GotoFirstMap()
 109 {SELFPARAM();
 110         float n;
 111         if(autocvar__sv_init)
 112         {
 113                 // cvar_set("_sv_init", "0");
 114                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 115                 // to this "init" map on a dedicated server will cause no permanent
 116                 // harm
 117                 if(autocvar_g_maplist_shuffle)
 118                         ShuffleMaplist();
 119                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 120                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 121
 122                 MapInfo_Enumerate();
 123                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 124
 125                 if(!DoNextMapOverride(1))
 126                         GotoNextMap(1);
 127
 128                 return;
 129         }
 130
 131         if(time < 5)
 132         {
 133                 self.nextthink = time;
 134         }
 135         else
 136         {
 137                 self.nextthink = time + 1;
 138                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 139         }
 140 }
 141
 142 void cvar_changes_init()
 143 {
 144         float h;
 145         string k, v, d;
 146         float n, i, adding, pureadding;
 147
 148         if(cvar_changes)
 149                 strunzone(cvar_changes);
 150         cvar_changes = string_null;
 151         if(cvar_purechanges)
 152                 strunzone(cvar_purechanges);
 153         cvar_purechanges = string_null;
 154         cvar_purechanges_count = 0;
 155
 156         h = buf_create();
 157         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 158         n = buf_getsize(h);
 159
 160         adding = true;
 161         pureadding = true;
 162
 163         for(i = 0; i < n; ++i)
 164         {
 165                 k = bufstr_get(h, i);
 166
 167 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 168 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 169 #define BADCVAR(p) if(k == p) continue
 170
 171                 // general excludes and namespaces for server admin used cvars
 172                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 173
 174                 // internal
 175                 BADPREFIX("csqc_");
 176                 BADPREFIX("cvar_check_");
 177                 BADCVAR("gamecfg");
 178                 BADCVAR("g_configversion");
 179                 BADCVAR("g_maplist_index");
 180                 BADCVAR("halflifebsp");
 181                 BADCVAR("sv_mapformat_is_quake2");
 182                 BADCVAR("sv_mapformat_is_quake3");
 183                 BADPREFIX("sv_world");
 184
 185                 // client
 186                 BADPREFIX("chase_");
 187                 BADPREFIX("cl_");
 188                 BADPREFIX("con_");
 189                 BADPREFIX("scoreboard_");
 190                 BADPREFIX("g_campaign");
 191                 BADPREFIX("g_waypointsprite_");
 192                 BADPREFIX("gl_");
 193                 BADPREFIX("joy");
 194                 BADPREFIX("hud_");
 195                 BADPREFIX("m_");
 196                 BADPREFIX("menu_");
 197                 BADPREFIX("net_slist_");
 198                 BADPREFIX("r_");
 199                 BADPREFIX("sbar_");
 200                 BADPREFIX("scr_");
 201                 BADPREFIX("snd_");
 202                 BADPREFIX("show");
 203                 BADPREFIX("sensitivity");
 204                 BADPREFIX("userbind");
 205                 BADPREFIX("v_");
 206                 BADPREFIX("vid_");
 207                 BADPREFIX("crosshair");
 208                 BADCVAR("mod_q3bsp_lightmapmergepower");
 209                 BADCVAR("mod_q3bsp_nolightmaps");
 210                 BADCVAR("fov");
 211                 BADCVAR("mastervolume");
 212                 BADCVAR("volume");
 213                 BADCVAR("bgmvolume");
 214
 215                 // private
 216                 BADCVAR("developer");
 217                 BADCVAR("log_dest_udp");
 218                 BADCVAR("net_address");
 219                 BADCVAR("net_address_ipv6");
 220                 BADCVAR("port");
 221                 BADCVAR("savedgamecfg");
 222                 BADCVAR("serverconfig");
 223                 BADCVAR("sv_autoscreenshot");
 224                 BADCVAR("sv_heartbeatperiod");
 225                 BADCVAR("sv_vote_master_password");
 226                 BADCVAR("sys_colortranslation");
 227                 BADCVAR("sys_specialcharactertranslation");
 228                 BADCVAR("timeformat");
 229                 BADCVAR("timestamps");
 230                 BADPREFIX("developer_");
 231                 BADPREFIX("g_ban_");
 232                 BADPREFIX("g_banned_list");
 233                 BADPREFIX("g_chat_flood_");
 234                 BADPREFIX("g_ghost_items");
 235                 BADPREFIX("g_playerstats_");
 236                 BADPREFIX("g_respawn_ghosts");
 237                 BADPREFIX("g_voice_flood_");
 238                 BADPREFIX("log_file");
 239                 BADPREFIX("rcon_");
 240                 BADPREFIX("sv_allowdownloads");
 241                 BADPREFIX("sv_autodemo");
 242                 BADPREFIX("sv_curl_");
 243                 BADPREFIX("sv_eventlog");
 244                 BADPREFIX("sv_logscores_");
 245                 BADPREFIX("sv_master");
 246                 BADPREFIX("sv_weaponstats_");
 247                 BADPREFIX("sv_waypointsprite_");
 248                 BADCVAR("rescan_pending");
 249
 250                 // these can contain player IDs, so better hide
 251                 BADPREFIX("g_forced_team_");
 252
 253                 // mapinfo
 254                 BADCVAR("fraglimit");
 255                 BADCVAR("g_assault");
 256                 BADCVAR("g_ca");
 257                 BADCVAR("g_ca_teams");
 258                 BADCVAR("g_ctf");
 259                 BADCVAR("g_cts");
 260                 BADCVAR("g_dm");
 261                 BADCVAR("g_domination");
 262                 BADCVAR("g_domination_default_teams");
 263                 BADCVAR("g_freezetag");
 264                 BADCVAR("g_freezetag_teams");
 265                 BADCVAR("g_invasion_teams");
 266                 BADCVAR("g_keepaway");
 267                 BADCVAR("g_keyhunt");
 268                 BADCVAR("g_keyhunt_teams");
 269                 BADCVAR("g_lms");
 270                 BADCVAR("g_nexball");
 271                 BADCVAR("g_onslaught");
 272                 BADCVAR("g_race");
 273                 BADCVAR("g_race_qualifying_timelimit");
 274                 BADCVAR("g_tdm");
 275                 BADCVAR("g_tdm_teams");
 276                 BADCVAR("leadlimit");
 277                 BADCVAR("nextmap");
 278                 BADCVAR("teamplay");
 279                 BADCVAR("timelimit");
 280
 281                 // long
 282                 BADCVAR("hostname");
 283                 BADCVAR("g_maplist");
 284                 BADCVAR("g_maplist_mostrecent");
 285                 BADCVAR("sv_motd");
 286
 287                 v = cvar_string(k);
 288                 d = cvar_defstring(k);
 289                 if(v == d)
 290                         continue;
 291
 292                 if(adding)
 293                 {
 294                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 295                         if(strlen(cvar_changes) > 16384)
 296                         {
 297                                 cvar_changes = "// too many settings have been changed to show them here\n";
 298                                 adding = 0;
 299                         }
 300                 }
 301
 302                 // now check if the changes are actually gameplay relevant
 303
 304                 // does nothing visible
 305                 BADCVAR("captureleadlimit_override");
 306                 BADCVAR("g_balance_kill_delay");
 307                 BADCVAR("g_ca_point_limit");
 308                 BADCVAR("g_ca_point_leadlimit");
 309                 BADCVAR("g_ctf_captimerecord_always");
 310                 BADCVAR("g_ctf_flag_glowtrails");
 311                 BADCVAR("g_ctf_flag_pickup_verbosename");
 312                 BADCVAR("g_domination_point_leadlimit");
 313                 BADCVAR("g_forced_respawn");
 314                 BADCVAR("g_freezetag_point_limit");
 315                 BADCVAR("g_freezetag_point_leadlimit");
 316                 BADCVAR("g_keyhunt_point_leadlimit");
 317                 BADPREFIX("g_mod_");
 318                 BADCVAR("g_invasion_point_limit");
 319                 BADCVAR("g_nexball_goalleadlimit");
 320                 BADCVAR("g_tdm_point_limit");
 321                 BADCVAR("g_tdm_point_leadlimit");
 322                 BADCVAR("leadlimit_and_fraglimit");
 323                 BADCVAR("leadlimit_override");
 324                 BADCVAR("pausable");
 325                 BADCVAR("sv_allow_fullbright");
 326                 BADCVAR("sv_checkforpacketsduringsleep");
 327                 BADCVAR("sv_timeout");
 328                 BADPREFIX("sv_timeout_");
 329                 BADPREFIX("crypto_");
 330                 BADPREFIX("g_chat_");
 331                 BADPREFIX("g_ctf_captimerecord_");
 332                 BADPREFIX("g_maplist_votable_");
 333                 BADPREFIX("net_");
 334                 BADPREFIX("prvm_");
 335                 BADPREFIX("skill_");
 336                 BADPREFIX("sv_cullentities_");
 337                 BADPREFIX("sv_maxidle_");
 338                 BADPREFIX("sv_vote_");
 339                 BADPREFIX("timelimit_");
 340                 BADCVAR("gameversion");
 341                 BADPREFIX("gameversion_");
 342                 BADCVAR("sv_minigames");
 343                 BADPREFIX("sv_minigames_");
 344                 BADCVAR("sv_namechangetimer");
 345
 346                 // allowed changes to server admins (please sync this to server.cfg)
 347                 // vi commands:
 348                 //   :/"impure"/,$d
 349                 //   :g!,^\/\/[^ /],d
 350                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 351                 //   :%!sort
 352                 // yes, this does contain some redundant stuff, don't really care
 353                 BADCVAR("bot_config_file");
 354                 BADCVAR("bot_number");
 355                 BADCVAR("bot_prefix");
 356                 BADCVAR("bot_suffix");
 357                 BADCVAR("capturelimit_override");
 358                 BADCVAR("fraglimit_override");
 359                 BADCVAR("gametype");
 360                 BADCVAR("g_antilag");
 361                 BADCVAR("g_balance_teams");
 362                 BADCVAR("g_balance_teams_prevent_imbalance");
 363                 BADCVAR("g_balance_teams_scorefactor");
 364                 BADCVAR("g_ban_sync_trusted_servers");
 365                 BADCVAR("g_ban_sync_uri");
 366                 BADCVAR("g_ca_teams_override");
 367                 BADCVAR("g_ctf_ignore_frags");
 368                 BADCVAR("g_domination_point_limit");
 369                 BADCVAR("g_domination_teams_override");
 370                 BADCVAR("g_freezetag_teams_override");
 371                 BADCVAR("g_friendlyfire");
 372                 BADCVAR("g_fullbrightitems");
 373                 BADCVAR("g_fullbrightplayers");
 374                 BADCVAR("g_keyhunt_point_limit");
 375                 BADCVAR("g_keyhunt_teams_override");
 376                 BADCVAR("g_lms_lives_override");
 377                 BADCVAR("g_maplist");
 378                 BADCVAR("g_maplist_check_waypoints");
 379                 BADCVAR("g_maplist_mostrecent_count");
 380                 BADCVAR("g_maplist_shuffle");
 381                 BADCVAR("g_maplist_votable");
 382                 BADCVAR("g_maplist_votable_abstain");
 383                 BADCVAR("g_maplist_votable_nodetail");
 384                 BADCVAR("g_maplist_votable_suggestions");
 385                 BADCVAR("g_maxplayers");
 386                 BADCVAR("g_mirrordamage");
 387                 BADCVAR("g_nexball_goallimit");
 388                 BADCVAR("g_powerups");
 389                 BADCVAR("g_start_delay");
 390                 BADCVAR("g_tdm_teams_override");
 391                 BADCVAR("g_warmup");
 392                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 393                 BADCVAR("hostname");
 394                 BADCVAR("log_file");
 395                 BADCVAR("maxplayers");
 396                 BADCVAR("minplayers");
 397                 BADCVAR("net_address");
 398                 BADCVAR("port");
 399                 BADCVAR("rcon_password");
 400                 BADCVAR("rcon_restricted_commands");
 401                 BADCVAR("rcon_restricted_password");
 402                 BADCVAR("skill");
 403                 BADCVAR("sv_adminnick");
 404                 BADCVAR("sv_autoscreenshot");
 405                 BADCVAR("sv_autotaunt");
 406                 BADCVAR("sv_curl_defaulturl");
 407                 BADCVAR("sv_defaultcharacter");
 408                 BADCVAR("sv_defaultplayercolors");
 409                 BADCVAR("sv_defaultplayermodel");
 410                 BADCVAR("sv_defaultplayerskin");
 411                 BADCVAR("sv_maxidle");
 412                 BADCVAR("sv_maxrate");
 413                 BADCVAR("sv_motd");
 414                 BADCVAR("sv_public");
 415                 BADCVAR("sv_ready_restart");
 416                 BADCVAR("sv_status_privacy");
 417                 BADCVAR("sv_taunt");
 418                 BADCVAR("sv_vote_call");
 419                 BADCVAR("sv_vote_commands");
 420                 BADCVAR("sv_vote_majority_factor");
 421                 BADCVAR("sv_vote_master");
 422                 BADCVAR("sv_vote_master_commands");
 423                 BADCVAR("sv_vote_master_password");
 424                 BADCVAR("sv_vote_simple_majority_factor");
 425                 BADCVAR("teamplay_mode");
 426                 BADCVAR("timelimit_override");
 427                 BADCVAR("g_spawnshieldtime");
 428                 BADPREFIX("g_warmup_");
 429                 BADPREFIX("sv_ready_restart_");
 430
 431                 // mutators that announce themselves properly to the server browser
 432                 BADCVAR("g_instagib");
 433                 BADCVAR("g_new_toys");
 434                 BADCVAR("g_nix");
 435                 BADCVAR("g_grappling_hook");
 436                 BADCVAR("g_jetpack");
 437
 438 #undef BADPREFIX
 439 #undef BADCVAR
 440
 441                 if(pureadding)
 442                 {
 443                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 444                         if(strlen(cvar_purechanges) > 16384)
 445                         {
 446                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 447                                 pureadding = 0;
 448                         }
 449                 }
 450                 ++cvar_purechanges_count;
 451                 // WARNING: this variable is used for the server list
 452                 // NEVER dare to skip this code!
 453                 // Hacks to intentionally appearing as "pure server" even though you DO have
 454                 // modified settings may be punished by removal from the server list.
 455                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 456                 // though.
 457         }
 458         buf_del(h);
 459         if(cvar_changes == "")
 460                 cvar_changes = "// this server runs at default server settings\n";
 461         else
 462                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 463         cvar_changes = strzone(cvar_changes);
 464         if(cvar_purechanges == "")
 465                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 466         else
 467                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 468         cvar_purechanges = strzone(cvar_purechanges);
 469 }
 470
 471 void detect_maptype()
 472 {
 473 #if 0
 474         vector o, v;
 475         float i;
 476
 477         for (;;)
 478         {
 479                 o = world.mins;
 480                 o.x += random() * (world.maxs.x - world.mins.x);
 481                 o.y += random() * (world.maxs.y - world.mins.y);
 482                 o.z += random() * (world.maxs.z - world.mins.z);
 483
 484                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 485                 if(trace_fraction == 1)
 486                         continue;
 487
 488                 v = trace_endpos;
 489
 490                 for(i = 0; i < 64; i += 4)
 491                 {
 492                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 493         if(trace_fraction == 1)
 494                 continue;
 495                         LOG_INFO(ftos(i), " -> ", vtos(trace_endpos), "\n");
 496                 }
 497
 498                 break;
 499         }
 500 #endif
 501 }
 502
 503 entity randomseed;
 504 bool RandomSeed_Send(entity this, entity to, int sf)
 505 {
 506         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 507         WriteShort(MSG_ENTITY, self.cnt);
 508         return true;
 509 }
 510 void RandomSeed_Think()
 511 {SELFPARAM();
 512         self.cnt = bound(0, floor(random() * 65536), 65535);
 513         self.nextthink = time + 5;
 514
 515         self.SendFlags |= 1;
 516 }
 517 void RandomSeed_Spawn()
 518 {SELFPARAM();
 519         randomseed = new(randomseed);
 520         make_pure(randomseed);
 521         randomseed.think = RandomSeed_Think;
 522         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 523
 524         WITH(entity, self, randomseed, randomseed.think()); // sets random seed and nextthink
 525 }
 526
 527 spawnfunc(__init_dedicated_server)
 528 {
 529         // handler for _init/_init map (only for dedicated server initialization)
 530
 531         world_initialized = -1; // don't complain
 532         cvar = cvar_normal;
 533         cvar_string = cvar_string_normal;
 534         cvar_set = cvar_set_normal;
 535
 536         remove = remove_unsafely;
 537
 538         entity e = spawn();
 539         e.think = GotoFirstMap;
 540         e.nextthink = time; // this is usually 1 at this point
 541
 542         e = new(info_player_deathmatch);  // safeguard against player joining
 543
 544         self.classname = "worldspawn"; // safeguard against various stuff ;)
 545
 546         // needs to be done so early because of the constants they create
 547         static_init();
 548         static_init_late();
 549         static_init_precache();
 550
 551         MapInfo_Enumerate();
 552         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 553 }
 554
 555 void Map_MarkAsRecent(string m);
 556 float world_already_spawned;
 557 void Nagger_Init();
 558 void ClientInit_Spawn();
 559 void WeaponStats_Init();
 560 void WeaponStats_Shutdown();
 561 void Physics_AddStats();
 562 spawnfunc(worldspawn)
 563 {
 564         float fd, l, j, n;
 565         string s;
 566
 567         cvar = cvar_normal;
 568         cvar_string = cvar_string_normal;
 569         cvar_set = cvar_set_normal;
 570
 571         if(world_already_spawned)
 572                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 573         world_already_spawned = true;
 574
 575         remove = remove_safely; // during spawning, watch what you remove!
 576
 577         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 578
 579         compressShortVector_init();
 580
 581         entity head;
 582         head = nextent(world);
 583         maxclients = 0;
 584         while(head)
 585         {
 586                 ++maxclients;
 587                 head = nextent(head);
 588         }
 589
 590         server_is_dedicated = (stof(cvar_defstring("is_dedicated")) ? true : false);
 591
 592         // needs to be done so early because of the constants they create
 593         static_init();
 594
 595         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 596
 597         TemporaryDB = db_create();
 598
 599         // 0 normal
 600         lightstyle(0, "m");
 601
 602         // 1 FLICKER (first variety)
 603         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 604
 605         // 2 SLOW STRONG PULSE
 606         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 607
 608         // 3 CANDLE (first variety)
 609         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 610
 611         // 4 FAST STROBE
 612         lightstyle(4, "mamamamamama");
 613
 614         // 5 GENTLE PULSE 1
 615         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 616
 617         // 6 FLICKER (second variety)
 618         lightstyle(6, "nmonqnmomnmomomno");
 619
 620         // 7 CANDLE (second variety)
 621         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 622
 623         // 8 CANDLE (third variety)
 624         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 625
 626         // 9 SLOW STROBE (fourth variety)
 627         lightstyle(9, "aaaaaaaazzzzzzzz");
 628
 629         // 10 FLUORESCENT FLICKER
 630         lightstyle(10, "mmamammmmammamamaaamammma");
 631
 632         // 11 SLOW PULSE NOT FADE TO BLACK
 633         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 634
 635         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 636
 637         // 63 testing
 638         lightstyle(63, "a");
 639
 640         if(autocvar_g_campaign)
 641                 CampaignPreInit();
 642
 643         Map_MarkAsRecent(mapname);
 644
 645         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 646
 647         InitGameplayMode();
 648         static_init_late();
 649         static_init_precache();
 650         readlevelcvars();
 651         GrappleHookInit();
 652
 653         player_count = 0;
 654         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 655         if(bot_waypoints_for_items == 1)
 656                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 657                         bot_waypoints_for_items = 0;
 658
 659         precache();
 660
 661         WaypointSprite_Init();
 662
 663         GameLogInit(); // prepare everything
 664         // NOTE for matchid:
 665         // changing the logic generating it is okay. But:
 666         // it HAS to stay <= 64 chars
 667         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 668         if(autocvar_sv_eventlog)
 669         {
 670                 s = sprintf("%d.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 671                 matchid = strzone(s);
 672
 673                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 674                 s = ":gameinfo:mutators:LIST";
 675
 676                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 677                 s = ret_string;
 678
 679                 // initialiation stuff, not good in the mutator system
 680                 if(!autocvar_g_use_ammunition)
 681                         s = strcat(s, ":no_use_ammunition");
 682
 683                 // initialiation stuff, not good in the mutator system
 684                 if(autocvar_g_pickup_items == 0)
 685                         s = strcat(s, ":no_pickup_items");
 686                 if(autocvar_g_pickup_items > 0)
 687                         s = strcat(s, ":pickup_items");
 688
 689                 // initialiation stuff, not good in the mutator system
 690                 if(autocvar_g_weaponarena != "0")
 691                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 692
 693                 // TODO to mutator system
 694                 if(autocvar_g_norecoil)
 695                         s = strcat(s, ":norecoil");
 696
 697                 // TODO to mutator system
 698                 if(autocvar_g_powerups == 0)
 699                         s = strcat(s, ":no_powerups");
 700                 if(autocvar_g_powerups > 0)
 701                         s = strcat(s, ":powerups");
 702
 703                 GameLogEcho(s);
 704                 GameLogEcho(":gameinfo:end");
 705         }
 706         else
 707                 matchid = strzone(ftos(random()));
 708
 709         cvar_set("nextmap", "");
 710
 711         SetDefaultAlpha();
 712
 713         if(autocvar_g_campaign)
 714                 CampaignPostInit();
 715
 716         Ban_LoadBans();
 717
 718         MapInfo_Enumerate();
 719         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 720
 721         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 722         {
 723                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 724                 if(fd != -1)
 725                 {
 726                         while((s = fgets(fd)))
 727                         {
 728                                 l = tokenize_console(s);
 729                                 if(l < 2)
 730                                         continue;
 731                                 if(argv(0) == "cd")
 732                                 {
 733                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 734                                         LOG_INFO("  cdtrack ", argv(2), "\n");
 735                                 }
 736                                 else if(argv(0) == "fog")
 737                                 {
 738                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 739                                         LOG_INFO("  \"fog\" \"", s, "\"\n");
 740                                 }
 741                                 else if(argv(0) == "set")
 742                                 {
 743                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 744                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 745                                 }
 746                                 else if(argv(0) != "//")
 747                                 {
 748                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 749                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 750                                 }
 751                         }
 752                         fclose(fd);
 753                 }
 754         }
 755
 756         WeaponStats_Init();
 757
 758         WepSet_AddStat();
 759         WepSet_AddStat_InMap();
 760         Nagger_Init();
 761
 762         // physics
 763         Physics_AddStats();
 764
 765         next_pingtime = time + 5;
 766
 767         detect_maptype();
 768
 769         // set up information replies for clients and server to use
 770         maplist_reply = strzone(getmaplist());
 771         lsmaps_reply = strzone(getlsmaps());
 772         monsterlist_reply = strzone(getmonsterlist());
 773         for(int i = 0; i < 10; ++i)
 774         {
 775                 s = getrecords(i);
 776                 if (s)
 777                         records_reply[i] = strzone(s);
 778         }
 779         ladder_reply = strzone(getladder());
 780         rankings_reply = strzone(getrankings());
 781
 782         // begin other init
 783         ClientInit_Spawn();
 784         RandomSeed_Spawn();
 785         PingPLReport_Spawn();
 786
 787         CheatInit();
 788
 789         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 790
 791         // fill sv_curl_serverpackages from .serverpackage files
 792         if(autocvar_sv_curl_serverpackages_auto)
 793         {
 794                 s = "";
 795                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 796                 for(int i = 0; i < n; ++i)
 797                         if(substring(argv(i), -18, -1) != "-serverpackage.txt")
 798                         if(substring(argv(i), -14, -1) != ".serverpackage") // OLD legacy
 799                                 s = strcat(s, " ", argv(i));
 800                 fd = search_begin("*-serverpackage.txt", true, false);
 801                 if(fd >= 0)
 802                 {
 803                         j = search_getsize(fd);
 804                         for(int i = 0; i < j; ++i)
 805                                 s = strcat(s, " ", search_getfilename(fd, i));
 806                         search_end(fd);
 807                 }
 808                 fd = search_begin("*.serverpackage", true, false);
 809                 if(fd >= 0)
 810                 {
 811                         j = search_getsize(fd);
 812                         for(int i = 0; i < j; ++i)
 813                                 s = strcat(s, " ", search_getfilename(fd, i));
 814                         search_end(fd);
 815                 }
 816                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 817         }
 818
 819         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
 820         modname = "Xonotic";
 821         // physics/balance/config changes that count as mod
 822         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
 823                 modname = cvar_string("g_mod_physics");
 824         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance"))
 825                 modname = cvar_string("g_mod_balance");
 826         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
 827                 modname = cvar_string("g_mod_config");
 828         // extra mutators that deserve to count as mod
 829         MUTATOR_CALLHOOK(SetModname);
 830
 831         // save it for later
 832         modname = strzone(modname);
 833
 834         WinningConditionHelper(); // set worldstatus
 835
 836         world_initialized = 1;
 837 }
 838
 839 spawnfunc(light)
 840 {
 841         //makestatic (self); // Who the f___ did that?
 842         remove(self);
 843 }
 844
 845 string GetGametype()
 846 {
 847         return MapInfo_Type_ToString(MapInfo_LoadedGametype);
 848 }
 849
 850 string GetMapname()
 851 {
 852         return mapname;
 853 }
 854
 855 float Map_Count, Map_Current;
 856 string Map_Current_Name;
 857
 858 // NOTE: this now expects the map list to be already tokenized and the count in Map_Count
 859 float GetMaplistPosition()
 860 {
 861         float pos, idx;
 862         string map;
 863
 864         map = GetMapname();
 865         idx = autocvar_g_maplist_index;
 866
 867         if(idx >= 0)
 868                 if(idx < Map_Count)
 869                         if(map == argv(idx))
 870                                 return idx;
 871
 872         for(pos = 0; pos < Map_Count; ++pos)
 873                 if(map == argv(pos))
 874                         return pos;
 875
 876         // resume normal maplist rotation if current map is not in g_maplist
 877         return idx;
 878 }
 879
 880 float MapHasRightSize(string map)
 881 {
 882         float fh;
 883         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 884         if(autocvar_g_maplist_check_waypoints)
 885         {
 886                 LOG_TRACE("checkwp "); LOG_TRACE(map);
 887                 if(!fexists(strcat("maps/", map, ".waypoints")))
 888                 {
 889                         LOG_TRACE(": no waypoints\n");
 890                         return false;
 891                 }
 892                 LOG_TRACE(": has waypoints\n");
 893         }
 894
 895         // open map size restriction file
 896         LOG_TRACE("opensize "); LOG_TRACE(map);
 897         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 898         if(fh >= 0)
 899         {
 900                 float mapmin, mapmax;
 901                 LOG_TRACE(": ok, ");
 902                 mapmin = stof(fgets(fh));
 903                 mapmax = stof(fgets(fh));
 904                 fclose(fh);
 905                 if(player_count < mapmin)
 906                 {
 907                         LOG_TRACE("not enough\n");
 908                         return false;
 909                 }
 910                 if(player_count > mapmax)
 911                 {
 912                         LOG_TRACE("too many\n");
 913                         return false;
 914                 }
 915                 LOG_TRACE("right size\n");
 916                 return true;
 917         }
 918         LOG_TRACE(": not found\n");
 919         return true;
 920 }
 921
 922 string Map_Filename(float position)
 923 {
 924         return strcat("maps/", argv(position), ".bsp");
 925 }
 926
 927 void Map_MarkAsRecent(string m)
 928 {
 929         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
 930 }
 931
 932 float Map_IsRecent(string m)
 933 {
 934         return strhasword(autocvar_g_maplist_mostrecent, m);
 935 }
 936
 937 float Map_Check(float position, float pass)
 938 {
 939         string filename;
 940         string map_next;
 941         map_next = argv(position);
 942         if(pass <= 1)
 943         {
 944                 if(Map_IsRecent(map_next))
 945                         return 0;
 946         }
 947         filename = Map_Filename(position);
 948         if(MapInfo_CheckMap(map_next))
 949         {
 950                 if(pass == 2)
 951                         return 1;
 952                 if(MapHasRightSize(map_next))
 953                         return 1;
 954                 return 0;
 955         }
 956         else
 957                 LOG_TRACE( "Couldn't select '", filename, "'..\n" );
 958
 959         return 0;
 960 }
 961
 962 void Map_Goto_SetStr(string nextmapname)
 963 {
 964         if(getmapname_stored != "")
 965                 strunzone(getmapname_stored);
 966         if(nextmapname == "")
 967                 getmapname_stored = "";
 968         else
 969                 getmapname_stored = strzone(nextmapname);
 970 }
 971
 972 void Map_Goto_SetFloat(float position)
 973 {
 974         cvar_set("g_maplist_index", ftos(position));
 975         Map_Goto_SetStr(argv(position));
 976 }
 977
 978 void Map_Goto(float reinit)
 979 {
 980         MapInfo_LoadMap(getmapname_stored, reinit);
 981 }
 982
 983 // return codes of map selectors:
 984 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 985 //   -2 = permanent failure
 986 float() MaplistMethod_Iterate = // usual method
 987 {
 988         float pass, i;
 989
 990         LOG_TRACE("Trying MaplistMethod_Iterate\n");
 991
 992         for(pass = 1; pass <= 2; ++pass)
 993         {
 994                 for(i = 1; i < Map_Count; ++i)
 995                 {
 996                         float mapindex;
 997                         mapindex = (i + Map_Current) % Map_Count;
 998                         if(Map_Check(mapindex, pass))
 999                                 return mapindex;
1000                 }
1001         }
1002         return -1;
1003 }
1004
1005 float() MaplistMethod_Repeat = // fallback method
1006 {
1007         LOG_TRACE("Trying MaplistMethod_Repeat\n");
1008
1009         if(Map_Check(Map_Current, 2))
1010                 return Map_Current;
1011         return -2;
1012 }
1013
1014 float() MaplistMethod_Random = // random map selection
1015 {
1016         float i, imax;
1017
1018         LOG_TRACE("Trying MaplistMethod_Random\n");
1019
1020         imax = 42;
1021
1022         for(i = 0; i <= imax; ++i)
1023         {
1024                 float mapindex;
1025                 mapindex = (Map_Current + floor(random() * (Map_Count - 1) + 1)) % Map_Count; // any OTHER map
1026                 if(Map_Check(mapindex, 1))
1027                         return mapindex;
1028         }
1029         return -1;
1030 }
1031
1032 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1033 // the exponent sets a bias on the map selection:
1034 // the higher the exponent, the less likely "shortly repeated" same maps are
1035 {
1036         float i, j, imax, insertpos;
1037
1038         LOG_TRACE("Trying MaplistMethod_Shuffle\n");
1039
1040         imax = 42;
1041
1042         for(i = 0; i <= imax; ++i)
1043         {
1044                 string newlist;
1045
1046                 // now reinsert this at another position
1047                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1048                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1049                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1050                 LOG_TRACE("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1051
1052                 // insert the current map there
1053                 newlist = "";
1054                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1055                         newlist = strcat(newlist, " ", argv(j));
1056                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1057                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1058                         newlist = strcat(newlist, " ", argv(j));
1059                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1060                 cvar_set("g_maplist", newlist);
1061                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1062
1063                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1064                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1065                 if(Map_Check(Map_Current, 1))
1066                         return Map_Current;
1067         }
1068         return -1;
1069 }
1070
1071 void Maplist_Init()
1072 {
1073         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1074         float i;
1075         for (i = 0; i < Map_Count; ++i)
1076                 if (Map_Check(i, 2))
1077                         break;
1078         if (i == Map_Count)
1079         {
1080                 bprint( "Maplist contains no usable maps!  Resetting it to default map list.\n" );
1081                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags() | MAPINFO_FLAG_NOAUTOMAPLIST));
1082                 if(autocvar_g_maplist_shuffle)
1083                         ShuffleMaplist();
1084                 localcmd("\nmenu_cmd sync\n");
1085                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1086         }
1087         if(Map_Count == 0)
1088                 error("empty maplist, cannot select a new map");
1089         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1090
1091         if(Map_Current_Name)
1092                 strunzone(Map_Current_Name);
1093         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1094         // this may or may not be correct, but who cares, in the worst case a map
1095         // isn't chosen in the first pass that should have been
1096 }
1097
1098 string GetNextMap()
1099 {
1100         float nextMap;
1101
1102         Maplist_Init();
1103         nextMap = -1;
1104
1105         if(nextMap == -1)
1106                 if(autocvar_g_maplist_shuffle > 0)
1107                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1108
1109         if(nextMap == -1)
1110                 if(autocvar_g_maplist_selectrandom)
1111                         nextMap = MaplistMethod_Random();
1112
1113         if(nextMap == -1)
1114                 nextMap = MaplistMethod_Iterate();
1115
1116         if(nextMap == -1)
1117                 nextMap = MaplistMethod_Repeat();
1118
1119         if(nextMap >= 0)
1120         {
1121                 Map_Goto_SetFloat(nextMap);
1122                 return getmapname_stored;
1123         }
1124
1125         return "";
1126 }
1127
1128 float DoNextMapOverride(float reinit)
1129 {
1130         if(autocvar_g_campaign)
1131         {
1132                 CampaignPostIntermission();
1133                 alreadychangedlevel = true;
1134                 return true;
1135         }
1136         if(autocvar_quit_when_empty)
1137         {
1138                 if(player_count <= currentbots)
1139                 {
1140                         localcmd("quit\n");
1141                         alreadychangedlevel = true;
1142                         return true;
1143                 }
1144         }
1145         if(autocvar_quit_and_redirect != "")
1146         {
1147                 redirection_target = strzone(autocvar_quit_and_redirect);
1148                 alreadychangedlevel = true;
1149                 return true;
1150         }
1151         if (!reinit && autocvar_samelevel) // if samelevel is set, stay on same level
1152         {
1153                 localcmd("restart\n");
1154                 alreadychangedlevel = true;
1155                 return true;
1156         }
1157         if(autocvar_nextmap != "")
1158         {
1159                 string m;
1160                 m = GameTypeVote_MapInfo_FixName(autocvar_nextmap);
1161                 cvar_set("nextmap",m);
1162
1163                 if(!m || gametypevote)
1164                         return false;
1165                 if(autocvar_sv_vote_gametype)
1166                 {
1167                         Map_Goto_SetStr(m);
1168                         return false;
1169                 }
1170
1171                 if(MapInfo_CheckMap(m))
1172                 {
1173                         Map_Goto_SetStr(m);
1174                         Map_Goto(reinit);
1175                         alreadychangedlevel = true;
1176                         return true;
1177                 }
1178         }
1179         if(!reinit && autocvar_lastlevel)
1180         {
1181                 cvar_settemp_restore();
1182                 localcmd("set lastlevel 0\ntogglemenu 1\n");
1183                 alreadychangedlevel = true;
1184                 return true;
1185         }
1186         return false;
1187 }
1188
1189 void GotoNextMap(float reinit)
1190 {
1191         //string nextmap;
1192         //float n, nummaps;
1193         //string s;
1194         if (alreadychangedlevel)
1195                 return;
1196         alreadychangedlevel = true;
1197
1198         string nextMap;
1199
1200         nextMap = GetNextMap();
1201         if(nextMap == "")
1202                 error("Everything is broken - cannot find a next map. Please report this to the developers.");
1203         Map_Goto(reinit);
1204 }
1205
1206
1207 /*
1208 ============
1209 IntermissionThink
1210
1211 When the player presses attack or jump, change to the next level
1212 ============
1213 */
1214 .float autoscreenshot;
1215 void IntermissionThink()
1216 {SELFPARAM();
1217         FixIntermissionClient(self);
1218
1219         float server_screenshot = (autocvar_sv_autoscreenshot && self.cvar_cl_autoscreenshot);
1220         float client_screenshot = (self.cvar_cl_autoscreenshot == 2);
1221
1222         if( (server_screenshot || client_screenshot)
1223                 && ((self.autoscreenshot > 0) && (time > self.autoscreenshot)) )
1224         {
1225                 self.autoscreenshot = -1;
1226                 if(IS_REAL_CLIENT(self)) { stuffcmd(self, sprintf("\nscreenshot screenshots/autoscreenshot/%s-%s.jpg; echo \"^5A screenshot has been taken at request of the server.\"\n", GetMapname(), strftime(false, "%s"))); }
1227                 return;
1228         }
1229
1230         if (time < intermission_exittime)
1231                 return;
1232
1233         if(!mapvote_initialized)
1234                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1235                         return;
1236
1237         MapVote_Start();
1238 }
1239
1240 /*
1241 ============
1242 FindIntermission
1243
1244 Returns the entity to view from
1245 ============
1246 */
1247 /*
1248 entity FindIntermission()
1249 {
1250         local   entity spot;
1251         local   float cyc;
1252
1253 // look for info_intermission first
1254         spot = find (world, classname, "info_intermission");
1255         if (spot)
1256         {       // pick a random one
1257                 cyc = random() * 4;
1258                 while (cyc > 1)
1259                 {
1260                         spot = find (spot, classname, "info_intermission");
1261                         if (!spot)
1262                                 spot = find (spot, classname, "info_intermission");
1263                         cyc = cyc - 1;
1264                 }
1265                 return spot;
1266         }
1267
1268 // then look for the start position
1269         spot = find (world, classname, "info_player_start");
1270         if (spot)
1271                 return spot;
1272
1273 // testinfo_player_start is only found in regioned levels
1274         spot = find (world, classname, "testplayerstart");
1275         if (spot)
1276                 return spot;
1277
1278 // then look for the start position
1279         spot = find (world, classname, "info_player_deathmatch");
1280         if (spot)
1281                 return spot;
1282
1283         //objerror ("FindIntermission: no spot");
1284         return world;
1285 }
1286 */
1287
1288 /*
1289 ===============================================================================
1290
1291 RULES
1292
1293 ===============================================================================
1294 */
1295
1296 void DumpStats(float final)
1297 {
1298         float file;
1299         string s;
1300         float to_console;
1301         float to_eventlog;
1302         float to_file;
1303         float i;
1304
1305         to_console = autocvar_sv_logscores_console;
1306         to_eventlog = autocvar_sv_eventlog;
1307         to_file = autocvar_sv_logscores_file;
1308
1309         if(!final)
1310         {
1311                 to_console = true; // always print printstats replies
1312                 to_eventlog = false; // but never print them to the event log
1313         }
1314
1315         if(to_eventlog)
1316                 if(autocvar_sv_eventlog_console)
1317                         to_console = false; // otherwise we get the output twice
1318
1319         if(final)
1320                 s = ":scores:";
1321         else
1322                 s = ":status:";
1323         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1324
1325         if(to_console)
1326                 LOG_INFO(s, "\n");
1327         if(to_eventlog)
1328                 GameLogEcho(s);
1329
1330         file = -1;
1331         if(to_file)
1332         {
1333                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1334                 if(file == -1)
1335                         to_file = false;
1336                 else
1337                         fputs(file, strcat(s, "\n"));
1338         }
1339
1340         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1341         if(to_console)
1342                 LOG_INFO(s, "\n");
1343         if(to_eventlog)
1344                 GameLogEcho(s);
1345         if(to_file)
1346                 fputs(file, strcat(s, "\n"));
1347
1348         FOR_EACH_CLIENT(other)
1349         {
1350                 if ((IS_REAL_CLIENT(other)) || (IS_BOT_CLIENT(other) && autocvar_sv_logscores_bots))
1351                 {
1352                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1353                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1354                         if(IS_PLAYER(other) || MUTATOR_CALLHOOK(GetPlayerStatus, other, s))
1355                                 s = strcat(s, ftos(other.team), ":");
1356                         else
1357                                 s = strcat(s, "spectator:");
1358
1359                         if(to_console)
1360                                 LOG_INFO(s, other.netname, "\n");
1361                         if(to_eventlog)
1362                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1363                         if(to_file)
1364                                 fputs(file, strcat(s, other.netname, "\n"));
1365                 }
1366         }
1367
1368         if(teamplay)
1369         {
1370                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1371                 if(to_console)
1372                         LOG_INFO(s, "\n");
1373                 if(to_eventlog)
1374                         GameLogEcho(s);
1375                 if(to_file)
1376                         fputs(file, strcat(s, "\n"));
1377
1378                 for(i = 1; i < 16; ++i)
1379                 {
1380                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1381                         s = strcat(s, ":", ftos(i));
1382                         if(to_console)
1383                                 LOG_INFO(s, "\n");
1384                         if(to_eventlog)
1385                                 GameLogEcho(s);
1386                         if(to_file)
1387                                 fputs(file, strcat(s, "\n"));
1388                 }
1389         }
1390
1391         if(to_console)
1392                 LOG_INFO(":end\n");
1393         if(to_eventlog)
1394                 GameLogEcho(":end");
1395         if(to_file)
1396         {
1397                 fputs(file, ":end\n");
1398                 fclose(file);
1399         }
1400 }
1401
1402 void FixIntermissionClient(entity e)
1403 {
1404         string s;
1405         if(!e.autoscreenshot) // initial call
1406         {
1407                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1408                 e.health = -2342;
1409                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1410                 e.solid = SOLID_NOT;
1411                 e.movetype = MOVETYPE_NONE;
1412                 e.takedamage = DAMAGE_NO;
1413                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1414                 {
1415                     .entity weaponentity = weaponentities[slot];
1416                         if(e.(weaponentity))
1417                         {
1418                                 e.(weaponentity).effects = EF_NODRAW;
1419                                 if (e.(weaponentity).(weaponentity))
1420                                         e.(weaponentity).(weaponentity).effects = EF_NODRAW;
1421                         }
1422                 }
1423                 if(IS_REAL_CLIENT(e))
1424                 {
1425                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1426                         s = autocvar_sv_intermission_cdtrack;
1427                         if(s != "")
1428                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1429                         msg_entity = e;
1430                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1431                 }
1432         }
1433 }
1434
1435 /*
1436 go to the next level for deathmatch
1437 only called if a time or frag limit has expired
1438 */
1439 void NextLevel()
1440 {
1441         gameover = true;
1442
1443         intermission_running = 1;
1444
1445 // enforce a wait time before allowing changelevel
1446         if(player_count > 0)
1447                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1448         else
1449                 intermission_exittime = -1;
1450
1451         /*
1452         WriteByte (MSG_ALL, SVC_CDTRACK);
1453         WriteByte (MSG_ALL, 3);
1454         WriteByte (MSG_ALL, 3);
1455         // done in FixIntermission
1456         */
1457
1458         //pos = FindIntermission ();
1459
1460         VoteReset();
1461
1462         DumpStats(true);
1463
1464         // send statistics
1465         PlayerStats_GameReport(true);
1466         WeaponStats_Shutdown();
1467
1468         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, 0); // kill all centerprints now
1469
1470         if(autocvar_sv_eventlog)
1471                 GameLogEcho(":gameover");
1472
1473         GameLogClose();
1474
1475         FOR_EACH_PLAYER(other) {
1476                 FixIntermissionClient(other);
1477                 if(other.winning)
1478                         bprint(other.netname, " ^7wins.\n");
1479         }
1480
1481         entity oldself = self;
1482         target_music_kill();
1483         self = oldself;
1484
1485         if(autocvar_g_campaign)
1486                 CampaignPreIntermission();
1487
1488         MUTATOR_CALLHOOK(MatchEnd);
1489
1490         localcmd("\nsv_hook_gameend\n");
1491 }
1492
1493 /*
1494 ============
1495 CheckRules_Player
1496
1497 Exit deathmatch games upon conditions
1498 ============
1499 */
1500 void CheckRules_Player()
1501 {SELFPARAM();
1502         if (gameover)   // someone else quit the game already
1503                 return;
1504
1505         if(self.deadflag == DEAD_NO)
1506                 self.play_time += frametime;
1507
1508         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1509         //   (div0: and that in CheckRules_World please)
1510 }
1511
1512
1513 float InitiateSuddenDeath()
1514 {
1515         // Check first whether normal overtimes could be added before initiating suddendeath mode
1516         // - for this timelimit_overtime needs to be >0 of course
1517         // - also check the winning condition calculated in the previous frame and only add normal overtime
1518         //   again, if at the point at which timelimit would be extended again, still no winner was found
1519         if (!autocvar_g_campaign && (checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1520         {
1521                 return 1; // need to call InitiateOvertime later
1522         }
1523         else
1524         {
1525                 if(!checkrules_suddendeathend)
1526                 {
1527                         if(autocvar_g_campaign)
1528                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1529                         else
1530                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1531                         if(g_race && !g_race_qualifying)
1532                                 race_StartCompleting();
1533                 }
1534                 return 0;
1535         }
1536 }
1537
1538 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1539 {
1540         ++checkrules_overtimesadded;
1541         //add one more overtime by simply extending the timelimit
1542         float tl;
1543         tl = autocvar_timelimit;
1544         tl += autocvar_timelimit_overtime;
1545         cvar_set("timelimit", ftos(tl));
1546
1547         Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1548 }
1549
1550 float GetWinningCode(float fraglimitreached, float equality)
1551 {
1552         if(autocvar_g_campaign == 1)
1553                 if(fraglimitreached)
1554                         return WINNING_YES;
1555                 else
1556                         return WINNING_NO;
1557
1558         else
1559                 if(equality)
1560                         if(fraglimitreached)
1561                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1562                         else
1563                                 return WINNING_NEVER;
1564                 else
1565                         if(fraglimitreached)
1566                                 return WINNING_YES;
1567                         else
1568                                 return WINNING_NO;
1569 }
1570
1571 // set the .winning flag for exactly those players with a given field value
1572 void SetWinners(.float field, float value)
1573 {
1574         entity head;
1575         FOR_EACH_PLAYER(head)
1576                 head.winning = (head.(field) == value);
1577 }
1578
1579 // set the .winning flag for those players with a given field value
1580 void AddWinners(.float field, float value)
1581 {
1582         entity head;
1583         FOR_EACH_PLAYER(head)
1584                 if (head.(field) == value)
1585                         head.winning = 1;
1586 }
1587
1588 // clear the .winning flags
1589 void ClearWinners()
1590 {
1591         entity head;
1592         FOR_EACH_PLAYER(head)
1593                 head.winning = 0;
1594 }
1595
1596 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1597 // they win. Otherwise the defending team wins once the timelimit passes.
1598 void assault_new_round();
1599 float WinningCondition_Assault()
1600 {SELFPARAM();
1601         float status;
1602
1603         WinningConditionHelper(); // set worldstatus
1604
1605         status = WINNING_NO;
1606         // as the timelimit has not yet passed just assume the defending team will win
1607         if(assault_attacker_team == NUM_TEAM_1)
1608         {
1609                 SetWinners(team, NUM_TEAM_2);
1610         }
1611         else
1612         {
1613                 SetWinners(team, NUM_TEAM_1);
1614         }
1615
1616         entity ent;
1617         ent = find(world, classname, "target_assault_roundend");
1618         if(ent)
1619         {
1620                 if(ent.winning) // round end has been triggered by attacking team
1621                 {
1622                         bprint("ASSAULT: round completed...\n");
1623                         SetWinners(team, assault_attacker_team);
1624
1625                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1626
1627                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1628                         {
1629                                 status = WINNING_YES;
1630                         }
1631                         else
1632                         {
1633                                 WITH(entity, self, ent, assault_new_round());
1634                         }
1635                 }
1636         }
1637
1638         return status;
1639 }
1640
1641 void ShuffleMaplist()
1642 {
1643         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1644 }
1645
1646 float leaderfrags;
1647 float WinningCondition_Scores(float limit, float leadlimit)
1648 {
1649         float limitreached;
1650
1651         // TODO make everything use THIS winning condition (except LMS)
1652         WinningConditionHelper();
1653
1654         if(teamplay)
1655         {
1656                 team1_score = TeamScore_GetCompareValue(NUM_TEAM_1);
1657                 team2_score = TeamScore_GetCompareValue(NUM_TEAM_2);
1658                 team3_score = TeamScore_GetCompareValue(NUM_TEAM_3);
1659                 team4_score = TeamScore_GetCompareValue(NUM_TEAM_4);
1660         }
1661
1662         ClearWinners();
1663         if(WinningConditionHelper_winner)
1664                 WinningConditionHelper_winner.winning = 1;
1665         if(WinningConditionHelper_winnerteam >= 0)
1666                 SetWinners(team, WinningConditionHelper_winnerteam);
1667
1668         if(WinningConditionHelper_lowerisbetter)
1669         {
1670                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1671                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1672                 limit = -limit;
1673         }
1674
1675         if(WinningConditionHelper_zeroisworst)
1676                 leadlimit = 0; // not supported in this mode
1677
1678         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1679         // these modes always score in increments of 1, thus this makes sense
1680         {
1681                 if(leaderfrags != WinningConditionHelper_topscore)
1682                 {
1683                         leaderfrags = WinningConditionHelper_topscore;
1684
1685                         if (limit)
1686                         if (leaderfrags == limit - 1)
1687                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1688                         else if (leaderfrags == limit - 2)
1689                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1690                         else if (leaderfrags == limit - 3)
1691                                 Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1692                 }
1693         }
1694
1695         limitreached = false;
1696         if(limit)
1697                 if(WinningConditionHelper_topscore >= limit)
1698                         limitreached = true;
1699         if(leadlimit)
1700         {
1701                 float leadlimitreached;
1702                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1703                 if(autocvar_leadlimit_and_fraglimit)
1704                         limitreached = (limitreached && leadlimitreached);
1705                 else
1706                         limitreached = (limitreached || leadlimitreached);
1707         }
1708
1709         if(limit)
1710                 game_completion_ratio = max(game_completion_ratio, bound(0, WinningConditionHelper_topscore / limit, 1));
1711
1712         return GetWinningCode(
1713                 WinningConditionHelper_topscore && limitreached,
1714                 WinningConditionHelper_equality
1715         );
1716 }
1717
1718 float WinningCondition_Race(float fraglimit)
1719 {
1720         float wc;
1721         entity p;
1722         float n, c;
1723
1724         n = 0;
1725         c = 0;
1726         FOR_EACH_PLAYER(p)
1727         {
1728                 ++n;
1729                 if(p.race_completed)
1730                         ++c;
1731         }
1732         if(n && (n == c))
1733                 return WINNING_YES;
1734         wc = WinningCondition_Scores(fraglimit, 0);
1735
1736         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1737         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1738         // do NOT support equality when the laps are all raced!
1739                 return WINNING_STARTSUDDENDEATHOVERTIME;
1740         else
1741                 return WINNING_NEVER;
1742 }
1743
1744 float WinningCondition_QualifyingThenRace(float limit)
1745 {
1746         float wc;
1747         wc = WinningCondition_Scores(limit, 0);
1748
1749         // NEVER initiate overtime
1750         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1751         {
1752                 return WINNING_YES;
1753         }
1754
1755         return wc;
1756 }
1757
1758 float WinningCondition_RanOutOfSpawns()
1759 {
1760         entity head;
1761
1762         if(have_team_spawns <= 0)
1763                 return WINNING_NO;
1764
1765         if(!autocvar_g_spawn_useallspawns)
1766                 return WINNING_NO;
1767
1768         if(!some_spawn_has_been_used)
1769                 return WINNING_NO;
1770
1771         team1_score = team2_score = team3_score = team4_score = 0;
1772
1773         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1774         {
1775                 if(head.team == NUM_TEAM_1)
1776                         team1_score = 1;
1777                 else if(head.team == NUM_TEAM_2)
1778                         team2_score = 1;
1779                 else if(head.team == NUM_TEAM_3)
1780                         team3_score = 1;
1781                 else if(head.team == NUM_TEAM_4)
1782                         team4_score = 1;
1783         }
1784
1785         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1786         {
1787                 if(head.team == NUM_TEAM_1)
1788                         team1_score = 1;
1789                 else if(head.team == NUM_TEAM_2)
1790                         team2_score = 1;
1791                 else if(head.team == NUM_TEAM_3)
1792                         team3_score = 1;
1793                 else if(head.team == NUM_TEAM_4)
1794                         team4_score = 1;
1795         }
1796
1797         ClearWinners();
1798         if(team1_score + team2_score + team3_score + team4_score == 0)
1799         {
1800                 checkrules_equality = true;
1801                 return WINNING_YES;
1802         }
1803         else if(team1_score + team2_score + team3_score + team4_score == 1)
1804         {
1805                 float t, i;
1806                 if(team1_score)
1807                         t = NUM_TEAM_1;
1808                 else if(team2_score)
1809                         t = NUM_TEAM_2;
1810                 else if(team3_score)
1811                         t = NUM_TEAM_3;
1812                 else // if(team4_score)
1813                         t = NUM_TEAM_4;
1814                 CheckAllowedTeams(world);
1815                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1816                 {
1817                         if(t != NUM_TEAM_1) if(c1 >= 0) TeamScore_AddToTeam(NUM_TEAM_1, i, -1000);
1818                         if(t != NUM_TEAM_2) if(c2 >= 0) TeamScore_AddToTeam(NUM_TEAM_2, i, -1000);
1819                         if(t != NUM_TEAM_3) if(c3 >= 0) TeamScore_AddToTeam(NUM_TEAM_3, i, -1000);
1820                         if(t != NUM_TEAM_4) if(c4 >= 0) TeamScore_AddToTeam(NUM_TEAM_4, i, -1000);
1821                 }
1822
1823                 AddWinners(team, t);
1824                 return WINNING_YES;
1825         }
1826         else
1827                 return WINNING_NO;
1828 }
1829
1830 /*
1831 ============
1832 CheckRules_World
1833
1834 Exit deathmatch games upon conditions
1835 ============
1836 */
1837 void CheckRules_World()
1838 {
1839         float timelimit;
1840         float fraglimit;
1841         float leadlimit;
1842
1843         VoteThink();
1844         MapVote_Think();
1845
1846         SetDefaultAlpha();
1847
1848         if (gameover)   // someone else quit the game already
1849         {
1850                 if(player_count == 0) // Nobody there? Then let's go to the next map
1851                         MapVote_Start();
1852                         // this will actually check the player count in the next frame
1853                         // again, but this shouldn't hurt
1854                 return;
1855         }
1856
1857         timelimit = autocvar_timelimit * 60;
1858         fraglimit = autocvar_fraglimit;
1859         leadlimit = autocvar_leadlimit;
1860
1861         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1862         {
1863                 if(timelimit > 0)
1864                         timelimit = 0; // timelimit is not made for warmup
1865                 if(fraglimit > 0)
1866                         fraglimit = 0; // no fraglimit for now
1867                 leadlimit = 0; // no leadlimit for now
1868         }
1869
1870         if(timelimit > 0)
1871         {
1872                 timelimit += game_starttime;
1873         }
1874         else if (timelimit < 0)
1875         {
1876                 // endmatch
1877                 NextLevel();
1878                 return;
1879         }
1880
1881         float wantovertime;
1882         wantovertime = 0;
1883
1884         if(timelimit > game_starttime)
1885                 game_completion_ratio = (time - game_starttime) / (timelimit - game_starttime);
1886         else
1887                 game_completion_ratio = 0;
1888
1889         if(checkrules_suddendeathend)
1890         {
1891                 if(!checkrules_suddendeathwarning)
1892                 {
1893                         checkrules_suddendeathwarning = true;
1894                         if(g_race && !g_race_qualifying)
1895                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_RACE_FINISHLAP);
1896                         else
1897                                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_OVERTIME_FRAG);
1898                 }
1899         }
1900         else
1901         {
1902                 if (timelimit && time >= timelimit)
1903                 {
1904                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1905                         {
1906                                 float totalplayers;
1907                                 float playerswithlaps;
1908                                 float readyplayers;
1909                                 entity head;
1910                                 totalplayers = playerswithlaps = readyplayers = 0;
1911                                 FOR_EACH_PLAYER(head)
1912                                 {
1913                                         ++totalplayers;
1914                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1915                                                 ++playerswithlaps;
1916                                         if(head.ready)
1917                                                 ++readyplayers;
1918                                 }
1919
1920                                 // at least 2 of the players have completed a lap: start the RACE
1921                                 // otherwise, the players should end the qualifying on their own
1922                                 if(readyplayers || playerswithlaps >= 2)
1923                                 {
1924                                         checkrules_suddendeathend = 0;
1925                                         ReadyRestart(); // go to race
1926                                         return;
1927                                 }
1928                                 else
1929                                         wantovertime |= InitiateSuddenDeath();
1930                         }
1931                         else
1932                                 wantovertime |= InitiateSuddenDeath();
1933                 }
1934         }
1935
1936         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1937         {
1938                 NextLevel();
1939                 return;
1940         }
1941
1942         int checkrules_status = WinningCondition_RanOutOfSpawns();
1943         if(checkrules_status == WINNING_YES)
1944                 bprint("Hey! Someone ran out of spawns!\n");
1945         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1946                 checkrules_status = ret_float;
1947         else
1948                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1949
1950         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1951         {
1952                 checkrules_status = WINNING_NEVER;
1953                 checkrules_overtimesadded = -1;
1954                 wantovertime |= InitiateSuddenDeath();
1955         }
1956
1957         if(checkrules_status == WINNING_NEVER)
1958                 // equality cases! Nobody wins if the overtime ends in a draw.
1959                 ClearWinners();
1960
1961         if(wantovertime)
1962         {
1963                 if(checkrules_status == WINNING_NEVER)
1964                         InitiateOvertime();
1965                 else
1966                         checkrules_status = WINNING_YES;
1967         }
1968
1969         if(checkrules_suddendeathend)
1970                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1971                         checkrules_status = WINNING_YES;
1972
1973         if(checkrules_status == WINNING_YES)
1974         {
1975                 //print("WINNING\n");
1976                 NextLevel();
1977         }
1978 }
1979
1980 string GotoMap(string m)
1981 {
1982         m = GameTypeVote_MapInfo_FixName(m);
1983         if (!m)
1984                 return "The map you suggested is not available on this server.";
1985         if (!autocvar_sv_vote_gametype)
1986         if(!MapInfo_CheckMap(m))
1987                 return "The map you suggested does not support the current game mode.";
1988         cvar_set("nextmap", m);
1989         cvar_set("timelimit", "-1");
1990         if(mapvote_initialized || alreadychangedlevel)
1991         {
1992                 if(DoNextMapOverride(0))
1993                         return "Map switch initiated.";
1994                 else
1995                         return "Hm... no. For some reason I like THIS map more.";
1996         }
1997         else
1998                 return "Map switch will happen after scoreboard.";
1999 }
2000
2001
2002 void EndFrame()
2003 {SELFPARAM();
2004         anticheat_endframe();
2005
2006         float altime;
2007         entity e_;
2008         FOR_EACH_REALCLIENT(e_)
2009         {
2010                 entity e = IS_SPEC(e_) ? e_.enemy : e_;
2011                 if(e.typehitsound)
2012                         e_.typehit_time = time;
2013                 else if(e.damage_dealt)
2014                 {
2015                         e_.hit_time = time;
2016                         e_.damage_dealt_total += ceil(e.damage_dealt);
2017                 }
2018         }
2019         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2020         // add 1 frametime because after this, engine SV_Physics
2021         // increases time by a frametime and then networks the frame
2022         // add another frametime because client shows everything with
2023         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2024         // needed!
2025         FOR_EACH_CLIENT(e_)
2026         {
2027                 e_.typehitsound = false;
2028                 e_.damage_dealt = 0;
2029                 setself(e_);
2030                 antilag_record(e_, altime);
2031         }
2032         FOR_EACH_MONSTER(e_)
2033         {
2034                 setself(e_);
2035                 antilag_record(e_, altime);
2036         }
2037 }
2038
2039
2040 /*
2041  * RedirectionThink:
2042  * returns true if redirecting
2043  */
2044 float redirection_timeout;
2045 float redirection_nextthink;
2046 float RedirectionThink()
2047 {SELFPARAM();
2048         float clients_found;
2049
2050         if(redirection_target == "")
2051                 return false;
2052
2053         if(!redirection_timeout)
2054         {
2055                 cvar_set("sv_public", "-2");
2056                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2057                 if(redirection_target == "self")
2058                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2059                 else
2060                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2061         }
2062
2063         if(time < redirection_nextthink)
2064                 return true;
2065
2066         redirection_nextthink = time + 1;
2067
2068         clients_found = 0;
2069         entity e;
2070         FOR_EACH_REALCLIENT(e)
2071         {
2072                 setself(e);
2073                 // TODO add timer
2074                 LOG_INFO("Redirecting: sending connect command to ", self.netname, "\n");
2075                 if(redirection_target == "self")
2076                         stuffcmd(self, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2077                 else
2078                         stuffcmd(self, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2079                 ++clients_found;
2080         }
2081
2082         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.\n");
2083
2084         if(time > redirection_timeout || clients_found == 0)
2085                 localcmd("\nwait; wait; wait; quit\n");
2086
2087         return true;
2088 }
2089
2090 void TargetMusic_RestoreGame();
2091 void RestoreGame()
2092 {
2093         // Loaded from a save game
2094         // some things then break, so let's work around them...
2095
2096         // Progs DB (capture records)
2097         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2098
2099         // Mapinfo
2100         MapInfo_Shutdown();
2101         MapInfo_Enumerate();
2102         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2103         WeaponStats_Init();
2104
2105         TargetMusic_RestoreGame();
2106 }
2107
2108 void Shutdown()
2109 {
2110         gameover = 2;
2111
2112         if(world_initialized > 0)
2113         {
2114                 world_initialized = 0;
2115                 LOG_INFO("Saving persistent data...\n");
2116                 Ban_SaveBans();
2117
2118                 // playerstats with unfinished match
2119                 PlayerStats_GameReport(false);
2120
2121                 if(!cheatcount_total)
2122                 {
2123                         if(autocvar_sv_db_saveasdump)
2124                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2125                         else
2126                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2127                 }
2128                 if(autocvar_developer)
2129                 {
2130                         if(autocvar_sv_db_saveasdump)
2131                                 db_dump(TemporaryDB, "server-temp.db");
2132                         else
2133                                 db_save(TemporaryDB, "server-temp.db");
2134                 }
2135                 CheatShutdown(); // must be after cheatcount check
2136                 db_close(ServerProgsDB);
2137                 db_close(TemporaryDB);
2138                 LOG_INFO("done!\n");
2139                 // tell the bot system the game is ending now
2140                 bot_endgame();
2141
2142                 WeaponStats_Shutdown();
2143                 MapInfo_Shutdown();
2144         }
2145         else if(world_initialized == 0)
2146         {
2147                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data\n");
2148         }
2149 }