data/qcsrc/client/shownames.qc

   1 // self.isactive = player is in range and coordinates/status (health and armor) are up to date
   2 // self.origin = player origin TODO: should maybe move this so it's the origin of the shownames tag already in SSQC for culling?
   3 // self.healthvalue
   4 // self.armorvalue
   5 // self.eaten
   6 //
   7 const float SHOWNAMES_FADESPEED = 4;
   8 void Draw_ShowNames(entity ent)
   9 {
  10         if(!cvar("hud_shownames"))
  11                 return;
  12         if(spectatee_status < 0 && !cvar("hud_shownames_observers"))
  13                 return;
  14         if(ent.sv_entnum == player_localentnum && !cvar("chase_active"))
  15                 return;
  16         if(getstati(STAT_VORE_EATEN) && cvar("cl_vore_stomachmodel") >= 1 && !cvar("chase_active"))
  17                 return;
  18         if(ent.eaten)
  19                 return;
  20
  21         float sameteam;
  22         if(teamplay && spectatee_status >= 0)
  23         if((GetPlayerColor(player_localentnum - 1) == GetPlayerColor(ent.sv_entnum - 1)) || (GetPlayerColor(spectatee_status - 1) == GetPlayerColor(ent.sv_entnum - 1)))
  24                 sameteam = TRUE;
  25
  26         if(sameteam || (!sameteam && cvar("hud_shownames") > 1))
  27         {
  28                 ent.origin_z += cvar("hud_shownames_offset");
  29
  30                 // offset the name by player scale, decided by health
  31                 if(g_healthsize_center >= 0)
  32                         ent.origin_z -= (g_healthsize_center - bound(g_healthsize_min, ent.healthvalue, g_healthsize_max)) * cvar("hud_shownames_offset_healthsize");
  33
  34                 traceline(ent.origin, view_origin, TRUE, ent);
  35
  36                 vector o, eo;
  37                 o = project_3d_to_2d(ent.origin);
  38                 float overlap;
  39
  40                 if(cvar("hud_shownames_antioverlap"))
  41                 {
  42                         // fade tag out if another tag that is closer to you overlaps
  43                         entity e;
  44                         for(e = world; (e = find(e, classname, "shownames_tag")); )
  45                         {
  46                                 if(e == ent)
  47                                         continue;
  48                                 eo = project_3d_to_2d(e.origin);
  49                                 if not(eo_z < 0 || eo_x < 0 || eo_y < 0 || eo_x > vid_conwidth || eo_y > vid_conheight)
  50                                 {
  51                                         eo_z = 0;
  52                                         if(vlen(('1 0 0' * o_x + '0 1 0' * o_y) - eo) < cvar("hud_shownames_antioverlap_distance") && vlen(ent.origin - view_origin) > vlen(e.origin - view_origin))
  53                                         {
  54                                                 overlap = TRUE;
  55                                                 break;
  56                                         }
  57                                 }
  58                         }
  59                 }
  60
  61                 if(trace_endpos != view_origin) // out of view, fade out
  62                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  63                 else if(ent.healthvalue < 1) // dead player, fade out slowly
  64                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * 0.25 * frametime);
  65                 else if(overlap) // tag overlap detected, fade out
  66                         ent.alpha = max(0, ent.alpha - SHOWNAMES_FADESPEED * frametime);
  67                 else // fade in
  68                         ent.alpha = min(1, ent.alpha + SHOWNAMES_FADESPEED * frametime);
  69
  70                 if(!ent.alpha)
  71                         return;
  72
  73                 float dist;
  74                 dist = vlen(ent.origin - view_origin);
  75
  76                 float a;
  77                 a = cvar("hud_shownames_alpha");
  78                 a *= ent.alpha;
  79                 if(cvar("hud_shownames_maxdistance"))
  80                 {
  81                         if(dist >= cvar("hud_shownames_maxdistance"))
  82                                 return;
  83                         a *= ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  84                 }
  85
  86                 if(!a)
  87                         return;
  88
  89                 float resize;
  90                 resize = 1;
  91                 if(cvar("hud_shownames_resize")) // limit resize so its never smaller than 0.5... gets unreadable
  92                         resize = 0.5 + 0.5 * ((cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance")) - max(0, dist - cvar("hud_shownames_mindistance"))) / (cvar("hud_shownames_maxdistance") - cvar("hud_shownames_mindistance"));
  93
  94                 // draw the sprite image
  95                 if not(o_z < 0 || o_x < 0 || o_y < 0 || o_x > vid_conwidth || o_y > vid_conheight)
  96                 {
  97                         o_z = 0;
  98
  99                         vector myPos, mySize;
 100                         mySize = ('1 0 0' * cvar("hud_shownames_aspect") + '0 1 0') * cvar("hud_shownames_fontsize");
 101                         myPos = o - '0.5 0 0' * mySize_x - '0 1 0' * mySize_y;
 102
 103                         // size scaling
 104                         mySize_x *= resize;
 105                         mySize_y *= resize;
 106
 107                         myPos_x += 0.5 * (mySize_x / resize - mySize_x);
 108                         myPos_y += (mySize_y / resize - mySize_y);
 109
 110                         vector namepos; // this is where the origin of the string
 111                         float namewidth;
 112
 113                         namepos = myPos;
 114                         namewidth = mySize_x;
 115
 116                         string s;
 117                         s = GetPlayerName(ent.sv_entnum-1);
 118                         if((cvar("hud_shownames_decolorize") == 1 && teamplay) || cvar("hud_shownames_decolorize") == 2)
 119                                 s = playername(s, GetPlayerColor(ent.sv_entnum-1));
 120
 121                         drawfontscale = '1 1 0' * resize;
 122                         s = textShortenToWidth(s, namewidth, '1 1 0' * cvar("hud_shownames_fontsize"), stringwidth_colors);
 123
 124                         if(sameteam && ent.healthvalue > 0)
 125                         {
 126                                 if(cvar("hud_shownames_status") > 2 && ent.armorvalue)
 127                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7|^2*", ftos(ent.armorvalue), "^7)");
 128                                 else if(cvar("hud_shownames_status") > 1)
 129                                         s = strcat(s, "^7 (^1+", ftos(ent.healthvalue), "^7)");
 130
 131                                 // if team healing is enabled, mark the team mate as possible to heal
 132                                 if(cvar("hud_shownames_status") && ent.healthvalue < teamheal_max)
 133                                         s = strcat(s, "^7 [^5HEAL^7]");
 134                         }
 135
 136                         float width;
 137                         width = stringwidth(s, TRUE, '1 1 0' * cvar("hud_shownames_fontsize"));
 138
 139                         if (width != namewidth)
 140                                 namepos_x += (namewidth - width) / 2;
 141                         drawcolorcodedstring(namepos, s, '1 1 0' * cvar("hud_shownames_fontsize"), a, DRAWFLAG_NORMAL);
 142                         drawfontscale = '1 1 0';
 143                 }
 144         }
 145 }
 146
 147 entity shownames_ent[255];
 148 void Draw_ShowNames_All()
 149 {
 150         float i;
 151         for(i = 0; i < maxclients; ++i)
 152         {
 153                 float t;
 154                 t = GetPlayerColor(i);
 155                 if(t == COLOR_SPECTATOR)
 156                         continue;
 157
 158                 entity e;
 159                 e = shownames_ent[i];
 160                 if(!e)
 161                 {
 162                         e = spawn();
 163                         e.classname = "shownames_tag";
 164                         e.sv_entnum = i+1;
 165                         shownames_ent[i] = e;
 166                 }
 167
 168                 entity entcs;
 169                 entcs = entcs_receiver[i];
 170                 if(entcs)
 171                 {
 172                         e.healthvalue = entcs.healthvalue;
 173                         e.armorvalue = entcs.armorvalue;
 174                         e.eaten = entcs.eaten;
 175                 }
 176                 else
 177                 {
 178                         e.healthvalue = 2342;
 179                         e.armorvalue = 0;
 180                         e.eaten = 0;
 181                 }
 182
 183                 e.origin = getplayerorigin(i);
 184                 if(e.origin == GETPLAYERORIGIN_ERROR)
 185                         continue;
 186
 187                 Draw_ShowNames(e);
 188         }
 189 }