data/qcsrc/server/bot/bot.qc

   1 #include "bot.qh"
   2 #include "aim.qh"
   3 #include "navigation.qh"
   4 #include "waypoints.qh"
   5
   6 #include "aim.qc"
   7 #include "navigation.qc"
   8 #include "waypoints.qc"
   9 #include "scripting.qc"
  10
  11 #include "havocbot/havocbot.qc"
  12
  13 entity bot_spawn()
  14 {
  15         local entity oldself, bot;
  16         bot = spawnclient();
  17         if (bot)
  18         {
  19                 currentbots = currentbots + 1;
  20                 oldself = self;
  21                 self = bot;
  22                 bot_setnameandstuff();
  23                 ClientConnect();
  24                 PutClientInServer();
  25                 self = oldself;
  26         }
  27         return bot;
  28 };
  29
  30 void bot_think()
  31 {
  32         if (self.bot_nextthink > time)
  33                 return;
  34
  35         self.flags &~= FL_GODMODE;
  36         if(cvar("bot_god"))
  37                 self.flags |= FL_GODMODE;
  38
  39         self.bot_nextthink = self.bot_nextthink + cvar("bot_ai_thinkinterval") * pow(0.5, self.bot_aiskill);
  40         //if (self.bot_painintensity > 0)
  41         //      self.bot_painintensity = self.bot_painintensity - (skill + 1) * 40 * frametime;
  42
  43         //self.bot_painintensity = self.bot_painintensity + self.bot_oldhealth - self.health;
  44         //self.bot_painintensity = bound(0, self.bot_painintensity, 100);
  45
  46         if(time < game_starttime || ((cvar("g_campaign") && !campaign_bots_may_start)))
  47         {
  48                 self.nextthink = time + 0.5;
  49                 return;
  50         }
  51
  52         if (self.fixangle)
  53         {
  54                 self.v_angle = self.angles;
  55                 self.v_angle_z = 0;
  56                 self.fixangle = FALSE;
  57         }
  58
  59         self.dmg_take = 0;
  60         self.dmg_save = 0;
  61         self.dmg_inflictor = world;
  62
  63         // calculate an aiming latency based on the skill setting
  64         // (simulated network latency + naturally delayed reflexes)
  65         //self.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  66         // minimum ping 20+10 random
  67         self.ping = bound(0,0.07 - bound(0, (skill + self.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  68         // skill 10 = ping 0.2 (adrenaline)
  69         // skill 0 = ping 0.7 (slightly drunk)
  70
  71         // clear buttons
  72         self.BUTTON_ATCK = 0;
  73         self.button1 = 0;
  74         self.BUTTON_JUMP = 0;
  75         self.BUTTON_ATCK2 = 0;
  76         self.BUTTON_ZOOM = 0;
  77         self.BUTTON_CROUCH = 0;
  78         self.BUTTON_JETPACK = 0;
  79         self.BUTTON_INFO = 0;
  80         self.button8 = 0;
  81         self.BUTTON_CHAT = 0;
  82         self.BUTTON_USE = 0;
  83         self.BUTTON_DIGEST = 0;
  84         self.BUTTON_REGURGITATE = 0;
  85
  86         // if dead, just wait until we can respawn
  87         if (self.deadflag)
  88         {
  89                 if (self.deadflag == DEAD_DEAD)
  90                 {
  91                         self.BUTTON_JUMP = 1; // press jump to respawn
  92                         self.bot_strategytime = 0;
  93                 }
  94         }
  95
  96         // now call the current bot AI (havocbot for example)
  97         self.bot_ai();
  98 };
  99
 100 void bot_setnameandstuff()
 101 {
 102         string readfile, s;
 103         float file, tokens, prio;
 104         entity p;
 105
 106         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 107         string name, prefix, suffix;
 108
 109         if(cvar("g_campaign"))
 110         {
 111                 prefix = "";
 112                 suffix = "";
 113         }
 114         else
 115         {
 116                 prefix = cvar_string("bot_prefix");
 117                 suffix = cvar_string("bot_suffix");
 118         }
 119
 120         file = fopen(cvar_string("bot_config_file"), FILE_READ);
 121
 122         if(file < 0)
 123                 print(strcat("Error: Can not open the bot configuration file '",cvar_string("bot_config_file"),"'\n"));
 124         else
 125         {
 126                 RandomSelection_Init();
 127                 for(;;)
 128                 {
 129                         readfile = fgets(file);
 130                         if(!readfile)
 131                                 break;
 132                         if(substring(readfile, 0, 2) == "//")
 133                                 continue;
 134                         if(substring(readfile, 0, 1) == "#")
 135                                 continue;
 136                         tokens = tokenizebyseparator(readfile, "\t");
 137                         s = argv(0);
 138                         prio = 1;
 139                         FOR_EACH_CLIENT(p)
 140                         {
 141                                 if(clienttype(p) == CLIENTTYPE_BOT)
 142                                 if(s == p.cleanname)
 143                                 {
 144                                         prio = 0;
 145                                         break;
 146                                 }
 147                         }
 148                         RandomSelection_Add(world, 0, readfile, 1, prio);
 149                 }
 150                 readfile = RandomSelection_chosen_string;
 151                 fclose(file);
 152         }
 153
 154         tokens = tokenizebyseparator(readfile, "\t");
 155         if(argv(0) != "") bot_name = argv(0);
 156         else bot_name = "Bot";
 157
 158         if(argv(1) != "") bot_model = argv(1);
 159         else bot_model = "";
 160
 161         if(argv(2) != "") bot_skin = argv(2);
 162         else bot_skin = "0";
 163
 164         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 165         else bot_shirt = ftos(floor(random() * 15));
 166
 167         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 168         else bot_pants = ftos(floor(random() * 15));
 169
 170         self.bot_forced_team = stof(argv(5));
 171
 172         prio = 6;
 173
 174         #define READSKILL(f,w,r) if(argv(prio) != "") self.f = stof(argv(prio)) * (w); else self.f = (!cvar("g_campaign")) * (2 * random() - 1) * (r) * (w); ++prio
 175         //print(bot_name, ": ping=", argv(9), "\n");
 176
 177         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 178         READSKILL(bot_moveskill, 2, 0); // move skill
 179         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 180
 181         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 182
 183         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 184         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 185         READSKILL(bot_rangepreference, 1, 0); // read skill
 186
 187         READSKILL(bot_aimskill, 2, 0); // aim skill
 188         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 189         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 190
 191         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 192         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 193
 194         READSKILL(bot_vorethinkpred, 1, 0.5); // vore predator skill
 195         READSKILL(bot_vorethinkprey, 1, 0.5); // vore prey skill
 196         READSKILL(bot_vorefear, 1, 0.5); // vore fear skill
 197         READSKILL(bot_voreteamheal, 1, 0.5); // vore teamheal skill
 198
 199         self.bot_config_loaded = TRUE;
 200
 201         // this is really only a default, JoinBestTeam is called later
 202         setcolor(self, stof(bot_shirt) * 16 + stof(bot_pants));
 203         self.bot_preferredcolors = self.clientcolors;
 204
 205         // pick the name
 206         if (cvar("bot_usemodelnames"))
 207                 name = bot_model;
 208         else
 209                 name = bot_name;
 210
 211         // number bots with identical names
 212         float i;
 213         i = 0;
 214         FOR_EACH_CLIENT(p)
 215         {
 216                 if(clienttype(p) == CLIENTTYPE_BOT)
 217                         if(p.cleanname == name)
 218                                 ++i;
 219         }
 220         if (i)
 221                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, "(", ftos(i), ")", suffix));
 222         else
 223                 self.netname = self.netname_freeme = strzone(strcat(prefix, name, suffix));
 224
 225         self.cleanname = strzone(name);
 226
 227         // pick the model and skin
 228         if(substring(bot_model, -4, 1) != ".")
 229                 bot_model = strcat(bot_model, ".iqm");
 230         self.playermodel = self.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 231         self.playerskin = self.playerskin_freeme = strzone(bot_skin);
 232
 233         self.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
 234         self.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
 235 };
 236
 237 void bot_custom_weapon_priority_setup()
 238 {
 239         local float tokens, i, c, w;
 240
 241         bot_custom_weapon = FALSE;
 242
 243         if(     cvar_string("bot_ai_custom_weapon_priority_far") == "" ||
 244                 cvar_string("bot_ai_custom_weapon_priority_mid") == "" ||
 245                 cvar_string("bot_ai_custom_weapon_priority_close") == "" ||
 246                 cvar_string("bot_ai_custom_weapon_priority_distances") == ""
 247         )
 248                 return;
 249
 250         // Parse distances
 251         tokens = tokenizebyseparator(cvar_string("bot_ai_custom_weapon_priority_distances")," ");
 252
 253         if (tokens!=2)
 254                 return;
 255
 256         bot_distance_far = stof(argv(0));
 257         bot_distance_close = stof(argv(1));
 258
 259         if(bot_distance_far < bot_distance_close){
 260                 bot_distance_far = stof(argv(1));
 261                 bot_distance_close = stof(argv(0));
 262         }
 263
 264         // Initialize list of weapons
 265         bot_weapons_far[0] = -1;
 266         bot_weapons_mid[0] = -1;
 267         bot_weapons_close[0] = -1;
 268
 269         // Parse far distance weapon priorities
 270         tokens = tokenizebyseparator(W_NumberWeaponOrder(cvar_string("bot_ai_custom_weapon_priority_far"))," ");
 271
 272         c = 0;
 273         for(i=0; i < tokens && c < WEP_COUNT; ++i){
 274                 w = stof(argv(i));
 275                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 276                         bot_weapons_far[c] = w;
 277                         ++c;
 278                 }
 279         }
 280         if(c < WEP_COUNT)
 281                 bot_weapons_far[c] = -1;
 282
 283         // Parse mid distance weapon priorities
 284         tokens = tokenizebyseparator(W_NumberWeaponOrder(cvar_string("bot_ai_custom_weapon_priority_mid"))," ");
 285
 286         c = 0;
 287         for(i=0; i < tokens && c < WEP_COUNT; ++i){
 288                 w = stof(argv(i));
 289                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 290                         bot_weapons_mid[c] = w;
 291                         ++c;
 292                 }
 293         }
 294         if(c < WEP_COUNT)
 295                 bot_weapons_mid[c] = -1;
 296
 297         // Parse close distance weapon priorities
 298         tokens = tokenizebyseparator(W_NumberWeaponOrder(cvar_string("bot_ai_custom_weapon_priority_close"))," ");
 299
 300         c = 0;
 301         for(i=0; i < tokens && i < WEP_COUNT; ++i){
 302                 w = stof(argv(i));
 303                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 304                         bot_weapons_close[c] = w;
 305                         ++c;
 306                 }
 307         }
 308         if(c < WEP_COUNT)
 309                 bot_weapons_close[c] = -1;
 310
 311         bot_custom_weapon = TRUE;
 312 };
 313
 314 void bot_endgame()
 315 {
 316         local entity e;
 317         //dprint("bot_endgame\n");
 318         e = bot_list;
 319         while (e)
 320         {
 321                 setcolor(e, e.bot_preferredcolors);
 322                 e = e.nextbot;
 323         }
 324         // if dynamic waypoints are ever implemented, save them here
 325 };
 326
 327 void bot_relinkplayerlist()
 328 {
 329         local entity e;
 330         local entity prevbot;
 331         player_count = 0;
 332         currentbots = 0;
 333         player_list = e = findchainflags(flags, FL_CLIENT);
 334         bot_list = world;
 335         prevbot = world;
 336         while (e)
 337         {
 338                 player_count = player_count + 1;
 339                 e.nextplayer = e.chain;
 340                 if (clienttype(e) == CLIENTTYPE_BOT)
 341                 {
 342                         if (prevbot)
 343                                 prevbot.nextbot = e;
 344                         else
 345                         {
 346                                 bot_list = e;
 347                                 bot_list.nextbot = world;
 348                         }
 349                         prevbot = e;
 350                         currentbots = currentbots + 1;
 351                 }
 352                 e = e.chain;
 353         }
 354         dprint(strcat("relink: ", ftos(currentbots), " bots seen.\n"));
 355         bot_strategytoken = bot_list;
 356         bot_strategytoken_taken = TRUE;
 357 };
 358
 359 void bot_clientdisconnect()
 360 {
 361         if (clienttype(self) != CLIENTTYPE_BOT)
 362                 return;
 363         if(self.cleanname)
 364                 strunzone(self.cleanname);
 365         if(self.netname_freeme)
 366                 strunzone(self.netname_freeme);
 367         if(self.playermodel_freeme)
 368                 strunzone(self.playermodel_freeme);
 369         if(self.playerskin_freeme)
 370                 strunzone(self.playerskin_freeme);
 371         self.cleanname = string_null;
 372         self.netname_freeme = string_null;
 373         self.playermodel_freeme = string_null;
 374         self.playerskin_freeme = string_null;
 375         remove(self.bot_cmd_current);
 376 }
 377
 378 void bot_clientconnect()
 379 {
 380         if (clienttype(self) != CLIENTTYPE_BOT)
 381                 return;
 382         self.bot_preferredcolors = self.clientcolors;
 383         self.bot_nextthink = time - random();
 384         self.lag_func = bot_lagfunc;
 385         self.isbot = TRUE;
 386         self.createdtime = self.nextthink;
 387
 388         if(!self.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 389                 bot_setnameandstuff();
 390
 391         if(self.bot_forced_team==1)
 392                 self.team = COLOR_TEAM1;
 393         else if(self.bot_forced_team==2)
 394                 self.team = COLOR_TEAM2;
 395         else if(self.bot_forced_team==3)
 396                 self.team = COLOR_TEAM3;
 397         else if(self.bot_forced_team==4)
 398                 self.team = COLOR_TEAM4;
 399         else
 400                 JoinBestTeam(self, FALSE, TRUE);
 401
 402         havocbot_setupbot();
 403 };
 404
 405 void bot_removefromlargestteam()
 406 {
 407         local float besttime, bestcount, thiscount;
 408         local entity best, head;
 409         CheckAllowedTeams(world);
 410         GetTeamCounts(world);
 411         head = findchainfloat(isbot, TRUE);
 412         if (!head)
 413                 return;
 414         best = head;
 415         besttime = head.createdtime;
 416         bestcount = 0;
 417         while (head)
 418         {
 419                 if(head.team == COLOR_TEAM1)
 420                         thiscount = c1;
 421                 else if(head.team == COLOR_TEAM2)
 422                         thiscount = c2;
 423                 else if(head.team == COLOR_TEAM3)
 424                         thiscount = c3;
 425                 else if(head.team == COLOR_TEAM4)
 426                         thiscount = c4;
 427                 else
 428                         thiscount = 0;
 429                 if (thiscount > bestcount)
 430                 {
 431                         bestcount = thiscount;
 432                         besttime = head.createdtime;
 433                         best = head;
 434                 }
 435                 else if (thiscount == bestcount && besttime < head.createdtime)
 436                 {
 437                         besttime = head.createdtime;
 438                         best = head;
 439                 }
 440                 head = head.chain;
 441         }
 442         currentbots = currentbots - 1;
 443         dropclient(best);
 444 };
 445
 446 void bot_removenewest()
 447 {
 448         local float besttime;
 449         local entity best, head;
 450
 451         if(teams_matter)
 452         {
 453                 bot_removefromlargestteam();
 454                 return;
 455         }
 456
 457         head = findchainfloat(isbot, TRUE);
 458         if (!head)
 459                 return;
 460         best = head;
 461         besttime = head.createdtime;
 462         while (head)
 463         {
 464                 if (besttime < head.createdtime)
 465                 {
 466                         besttime = head.createdtime;
 467                         best = head;
 468                 }
 469                 head = head.chain;
 470         }
 471         currentbots = currentbots - 1;
 472         dropclient(best);
 473 };
 474
 475 void autoskill(float factor)
 476 {
 477         float bestbot;
 478         float bestplayer;
 479         entity head;
 480
 481         bestbot = -1;
 482         bestplayer = -1;
 483         FOR_EACH_PLAYER(head)
 484         {
 485                 if(clienttype(head) == CLIENTTYPE_REAL)
 486                         bestplayer = max(bestplayer, head.totalfrags - head.totalfrags_lastcheck);
 487                 else
 488                         bestbot = max(bestbot, head.totalfrags - head.totalfrags_lastcheck);
 489         }
 490
 491         dprint("autoskill: best player got ", ftos(bestplayer), ", ");
 492         dprint("best bot got ", ftos(bestbot), "; ");
 493         if(bestbot < 0 || bestplayer < 0)
 494         {
 495                 dprint("not doing anything\n");
 496                 // don't return, let it reset all counters below
 497         }
 498         else if(bestbot <= bestplayer * factor - 2)
 499         {
 500                 if(cvar("skill") < 17)
 501                 {
 502                         dprint("2 frags difference, increasing skill\n");
 503                         cvar_set("skill", ftos(cvar("skill") + 1));
 504                         bprint("^2SKILL UP!^7 Now at level ", ftos(cvar("skill")), "\n");
 505                 }
 506         }
 507         else if(bestbot >= bestplayer * factor + 2)
 508         {
 509                 if(cvar("skill") > 0)
 510                 {
 511                         dprint("2 frags difference, decreasing skill\n");
 512                         cvar_set("skill", ftos(cvar("skill") - 1));
 513                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(cvar("skill")), "\n");
 514                 }
 515         }
 516         else
 517         {
 518                 dprint("not doing anything\n");
 519                 return;
 520                 // don't reset counters, wait for them to accumulate
 521         }
 522
 523         FOR_EACH_PLAYER(head)
 524                 head.totalfrags_lastcheck = head.totalfrags;
 525 }
 526
 527 void bot_serverframe()
 528 {
 529         float realplayers, bots, activerealplayers;
 530         entity head;
 531
 532         if (intermission_running)
 533                 return;
 534
 535         if (time < 2)
 536                 return;
 537
 538         stepheightvec = cvar("sv_stepheight") * '0 0 1';
 539         bot_navigation_movemode = ((cvar("bot_navigation_ignoreplayers")) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 540
 541         if(time > autoskill_nextthink)
 542         {
 543                 float a;
 544                 a = cvar("skill_auto");
 545                 if(a)
 546                         autoskill(a);
 547                 autoskill_nextthink = time + 5;
 548         }
 549
 550         activerealplayers = 0;
 551         realplayers = 0;
 552
 553         FOR_EACH_REALCLIENT(head)
 554         {
 555                 if(head.classname == "player" || g_lms || g_arena || g_ca)
 556                         ++activerealplayers;
 557                 ++realplayers;
 558         }
 559
 560         // add/remove bots if needed to make sure there are at least
 561         // minplayers+bot_number, or remove all bots if no one is playing
 562         // But don't remove bots immediately on level change, as the real players
 563         // usually haven't rejoined yet
 564         bots_would_leave = FALSE;
 565         if ((realplayers || cvar("bot_join_empty") || (currentbots > 0 && time < 5)))
 566         {
 567                 float realminplayers, minplayers;
 568                 realminplayers = cvar("minplayers");
 569                 minplayers = max(0, floor(realminplayers));
 570
 571                 float realminbots, minbots;
 572                 if(teamplay && cvar("bot_vs_human"))
 573                         realminbots = ceil(fabs(cvar("bot_vs_human")) * activerealplayers);
 574                 else
 575                         realminbots = cvar("bot_number");
 576                 minbots = max(0, floor(realminbots));
 577
 578                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 579                 if(bots > minbots)
 580                         bots_would_leave = TRUE;
 581         }
 582         else
 583         {
 584                 // if there are no players, remove bots
 585                 bots = 0;
 586         }
 587
 588         bot_ignore_bots = cvar("bot_ignore_bots");
 589
 590         // only add one bot per frame to avoid utter chaos
 591         if(time > botframe_nextthink)
 592         {
 593                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
 594                 while (currentbots < bots)
 595                 {
 596                         if (bot_spawn() == world)
 597                         {
 598                                 bprint("Can not add bot, server full.\n");
 599                                 botframe_nextthink = time + 10;
 600                                 break;
 601                         }
 602                 }
 603                 while (currentbots > bots)
 604                         bot_removenewest();
 605         }
 606
 607         if(botframe_spawnedwaypoints)
 608         {
 609                 if(cvar("waypoint_benchmark"))
 610                         localcmd("quit\n");
 611         }
 612
 613         if (currentbots > 0 || cvar("g_waypointeditor"))
 614         if (botframe_spawnedwaypoints)
 615         {
 616                 if(botframe_cachedwaypointlinks)
 617                 {
 618                         if(!botframe_loadedforcedlinks)
 619                                 waypoint_load_links_hardwired();
 620                 }
 621                 else
 622                 {
 623                         // TODO: Make this check cleaner
 624                         local entity wp = findchain(classname, "waypoint");
 625                         if(time - wp.nextthink > 10)
 626                                 waypoint_save_links();
 627                 }
 628         }
 629         else
 630         {
 631                 botframe_spawnedwaypoints = TRUE;
 632                 waypoint_loadall();
 633                 if(!waypoint_load_links())
 634                         waypoint_schedulerelinkall();
 635         }
 636
 637         if (bot_list)
 638         {
 639                 // cycle the goal token from one bot to the next each frame
 640                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 641                 //  frame, which causes choppy framerates)
 642                 if (bot_strategytoken_taken)
 643                 {
 644                         bot_strategytoken_taken = FALSE;
 645                         if (bot_strategytoken)
 646                                 bot_strategytoken = bot_strategytoken.nextbot;
 647                         if (!bot_strategytoken)
 648                                 bot_strategytoken = bot_list;
 649                 }
 650
 651                 if (botframe_nextdangertime < time)
 652                 {
 653                         local float interval;
 654                         interval = cvar("bot_ai_dangerdetectioninterval");
 655                         if (botframe_nextdangertime < time - interval * 1.5)
 656                                 botframe_nextdangertime = time;
 657                         botframe_nextdangertime = botframe_nextdangertime + interval;
 658                         botframe_updatedangerousobjects(cvar("bot_ai_dangerdetectionupdates"));
 659                 }
 660         }
 661
 662         if (cvar("g_waypointeditor"))
 663                 botframe_showwaypointlinks();
 664
 665         if(time > bot_cvar_nextthink)
 666         {
 667                 if(currentbots>0)
 668                         bot_custom_weapon_priority_setup();
 669                 bot_cvar_nextthink = time + 5;
 670         }
 671 };