data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
   2 .float hold_BUTTON_ATCK; // marks the bot holding the fire button after having decided on his prey
   3
   4 float Swallow_condition_check_bot(entity prey)
   5 {
   6         // checks the necessary conditions for a bot to swallow a player
   7
   8         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
   9         if(time >= prey.spawnshieldtime) // spawn shield means you are invincible
  10         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
  11         if(self.health > cvar("g_balance_vore_kick_damage_max")) // explained below
  12                 return TRUE;
  13         return FALSE;
  14 }
  15
  16 .float decide_swallow, decide_pred, decide_prey;
  17 void Vore_AI_Teamheal(entity prey)
  18 {
  19         // allows bots to use the teamheal feature and heal damaged team mates
  20         // the prey entity is only used when it's available (a player is detected in range)
  21
  22         entity head;
  23
  24         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
  25                 return;
  26         if(self.deadflag != DEAD_NO || self.stat_eaten || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
  27         {
  28                 self.status_teamhealing = 0;
  29                 return;
  30         }
  31
  32         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
  33         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
  34         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
  35         if(self.status_teamhealing > 1)
  36         if(Swallow_condition_check_bot(prey))
  37         if(prey.team != self.team)
  38         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
  39                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  40
  41         // decide if we can teamheal or not
  42         if(self.stomach_load)
  43         {
  44                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
  45
  46                 FOR_EACH_PLAYER(head)
  47                 {
  48                         if(head.predator == self)
  49                         if(head.team != self.team)
  50                         {
  51                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
  52                                 return;
  53                         }
  54                 }
  55         }
  56         else
  57                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
  58
  59         // now that we're decided if we can teamheal or not, lets go ahead and do so
  60
  61         // if we are holding a team mate that's been healed to the limit, we can release them
  62         if not(cvar("bot_ai_vore_keepinstomach"))
  63         FOR_EACH_PLAYER(head)
  64         {
  65                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
  66                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  67                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
  68         }
  69
  70         // check if we can heal a team mate we come across, and if so swallow them
  71         if(prey.team == self.team)
  72         if(Swallow_condition_check_bot(prey))
  73         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  74         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
  75         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  76         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's firing
  77         {
  78                 if(time > self.decide_swallow)
  79                 {
  80                         if(skill >= random() * 10) // there are 10 bot skill steps
  81                                 self.hold_BUTTON_ATCK = TRUE; // swallow the team mate
  82                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
  83                 }
  84         }
  85         else
  86                 self.hold_BUTTON_ATCK = FALSE;
  87 }
  88
  89 void Vore_AI()
  90 {
  91         // main vore AI code
  92
  93         if(!cvar("g_vore")) // the vore system is disabled
  94                 return;
  95         if(self.deadflag != DEAD_NO || cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
  96                 return;
  97
  98         float randomtry;
  99         randomtry = random() * 10; // there are 10 bot skill steps
 100
 101 // --------------------------------
 102 // Predator bot behavior:
 103 // --------------------------------
 104
 105         if(!self.stat_eaten)
 106         {
 107                 // finding and swallowing a player
 108
 109                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
 110                 // this only does the aiming, checking and swallowing is handled below
 111                 entity head;
 112                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
 113                 while(head)
 114                 {
 115                         if(Swallow_condition_check_bot(head))
 116                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
 117                         head = head.chain;
 118                 }
 119
 120                 // now do the actual checking and swallowing
 121                 entity prey;
 122                 float decide_pred_time, fear;
 123
 124                 prey = Swallow_player_check();
 125                 fear = 1;
 126
 127                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
 128                 Vore_AI_Teamheal(prey);
 129                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 130                         return;
 131
 132                 if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 133                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
 134                 if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 135                         fear += cvar("bot_ai_vore_fear") * self.bot_vorefear;
 136                 fear += self.stomach_load; // the bigger our stomach, the less we want to put someone else in there
 137                 if(cvar("g_healthsize"))
 138                         fear *= (prey.scale / self.scale); // predators fear larger prey and are courageous toward smaller prey
 139                 if(prey.stomach_load)
 140                         fear *= prey.stomach_load; // predators fear prey that have a large stomach
 141
 142                 // when a bot is being swallowed, he will try to swallow the enemy back in defense, forgetting about fear
 143                 if(self.swallow_progress_prey)
 144                         fear /= self.swallow_progress_prey * skill;
 145
 146                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
 147
 148                 if(Swallow_condition_check_bot(prey))
 149                 {
 150                         if(time > self.decide_swallow)
 151                         {
 152                                 // the greater the skill, the higher the chance bots will swallow someone each attempt
 153                                 if(skill / fear >= randomtry)
 154                                 if not(teams_matter && prey.team == self.team)
 155                                 {
 156                                         self.hold_BUTTON_ATCK = TRUE; // swallow
 157                                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 158                                 }
 159                                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
 160                         }
 161                 }
 162                 else
 163                         self.hold_BUTTON_ATCK = FALSE;
 164
 165                 // if the bot is holding the firing button, apply that to the actual fire key
 166                 if(self.hold_BUTTON_ATCK)
 167                         self.BUTTON_ATCK = TRUE;
 168
 169                 // deciding what to do with a victim:
 170
 171                 if(self.stomach_load && time > self.decide_pred)
 172                 {
 173                         // if the predator's health is smaller than the maximum damage a stomach kick can do, regurgitate the player(s)
 174                         // otherwise the predator is putting himself at risk by keeping you inside
 175                         // TODO: make bots also know the amount of damage boost a melee attack can do
 176                         if(self.health <= cvar("g_balance_vore_kick_damage_max"))
 177                                 self.BUTTON_REGURGITATE = TRUE;
 178
 179                         else if(!self.digesting && cvar("g_vore_digestion"))
 180                         {
 181                                 // the higher the skill, the faster bots will start to digest
 182                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 183                                 if(skill >= randomtry)
 184                                         self.BUTTON_DIGEST = TRUE; // digest
 185
 186                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 187                         }
 188                 }
 189         }
 190
 191 // --------------------------------
 192 // Prey bot behavior:
 193 // --------------------------------
 194
 195         // while being swallowed, smart bots know to keep jumping to make it harder to be caught
 196         // TODO: Don't do this if the predator is a team mate
 197         if(self.swallow_progress_prey)
 198         if(self.swallow_progress_prey * 10 >= 10 - skill) // 10 skill steps
 199                 self.BUTTON_JUMP = TRUE;
 200
 201         if(self.stat_eaten && time > self.decide_prey)
 202         {
 203                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
 204
 205                 float decide_prey_time;
 206                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
 207
 208                 if(cvar("g_vore_kick"))
 209                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 210                 if not(teams_matter && self.team == self.predator.team)
 211                 {
 212                         // the higher the skill, the more the bot will kick in your stomack
 213                         if(skill >= randomtry)
 214                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
 215                                 self.BUTTON_ATCK = TRUE; // kick
 216                 }
 217
 218                 // if a bot can willingly leave the predator, do so unless there's a reason not to
 219                 if(self.stat_canleave)
 220                 {
 221                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
 222                                 self.BUTTON_JUMP = TRUE; // leave
 223                         else if not(g_rpg && cvar("g_rpg_botattack") < 2)
 224                         {
 225                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
 226                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
 227                                         self.BUTTON_JUMP = TRUE; // leave
 228                         }
 229                 }
 230
 231                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
 232         }
 233 }