data/qcsrc/server/bot/havocbot/vore_ai.qc

   1 .float status_teamhealing; // 0 = can't team heal, 1 = can team heal, 2 = team healing right now
   2 .float hold_BUTTON_ATCK; // marks the bot holding the fire button after having decided on his prey
   3
   4 float Swallow_condition_check_bot(entity prey)
   5 {
   6         // checks the necessary conditions for a bot to swallow a player
   7
   8         float kick_dmg;
   9         if(cvar("g_vore_kick") && skill >= 7)
  10         {
  11                 kick_dmg = cvar("g_balance_vore_kick_damage");
  12                 if(cvar("g_healthsize"))
  13                         kick_dmg *= pow(prey.scale / self.scale, cvar("g_balance_vore_kick_scalediff")); // based on the damage the prey can do to us at his size
  14         }
  15
  16         if(Swallow_condition_check(prey)) // check the normal conditions of the vore system
  17         if(time >= prey.spawnshieldtime) // spawn shield means you are invincible
  18         if not(prey.BUTTON_CHAT) // don't eat players who are chatting
  19         if(self.health > kick_dmg)
  20                 return TRUE;
  21         return FALSE;
  22 }
  23
  24 .float decide_swallow, decide_pred, decide_prey;
  25 void Vore_AI_Teamheal(entity prey)
  26 {
  27         // allows bots to use the teamheal feature and heal damaged team mates
  28         // the prey entity is only used when it's available (a player is detected in range)
  29
  30         entity head;
  31
  32         if not(teams_matter && cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))
  33                 return;
  34         if(self.deadflag != DEAD_NO || self.stat_eaten || self.flagcarried || self.digesting) // a flag carrier can't waste time on team healing
  35         {
  36                 self.status_teamhealing = 0;
  37                 return;
  38         }
  39
  40         // if a teamheal is ongoing, decide whether or not to abandon it when seeing a foe we can attack
  41         // this only causes the bot to regurgitate their team mate when seeing an enemy, with the hope that our enemy will still be there once we can swallow
  42         // the higher the skill, the greater the chance a bot will abandon a team heal for an enemy
  43         if(self.status_teamhealing > 1)
  44         if(Swallow_condition_check_bot(prey))
  45         if(prey.team != self.team)
  46         if(random() * 10 < cvar("bot_ai_vore_teamhealabandon") * skill / self.bot_voreteamheal) // there are 10 bot skill steps
  47                 self.BUTTON_REGURGITATE = TRUE; // release the team mate
  48
  49         // decide if we can teamheal or not
  50         if(self.stomach_load)
  51         {
  52                 self.status_teamhealing = 2; // consider a team mate is in our stomach and we are teamhealing, until proven otherwise below
  53
  54                 FOR_EACH_PLAYER(head)
  55                 {
  56                         if(head.predator == self)
  57                         if(head.team != self.team)
  58                         {
  59                                 self.status_teamhealing = 0; // there's a foe in our stomach, we can't teamheal now
  60                                 return;
  61                         }
  62                 }
  63                 for(head = world; (head = find(head, classname, "consumable")); )
  64                 {
  65                         if(head.predator == self)
  66                         {
  67                                 self.status_teamhealing = 0; // we have consumable items, don't teamheal
  68                                 return;
  69                         }
  70                 }
  71         }
  72         else
  73                 self.status_teamhealing = 1; // if our stomach is empty, it means we can decide to teamheal
  74
  75         // now that we're decided if we can teamheal or not, lets go ahead and do so
  76
  77         // if we are holding a team mate that's been healed to the limit, we can release them
  78         if not(cvar("bot_ai_vore_keepinstomach"))
  79         FOR_EACH_PLAYER(head)
  80         {
  81                 if(head.predator == self) // head is automatically a team mate, or we wouldn't be reaching this part of the code
  82                 if(head.health >= cvar("g_balance_vore_teamheal_stable"))
  83                         self.BUTTON_REGURGITATE = TRUE; // release the team mate
  84         }
  85
  86         // check if we can heal a team mate we come across, and if so swallow them
  87         if(prey.team == self.team)
  88         if(Swallow_condition_check_bot(prey))
  89         if(prey.health < cvar("g_balance_vore_teamheal_stable"))
  90         if not(prey.digesting) // if our team mate is digesting someone, he likely wouldn't want us ruining his frag
  91         if not(prey.flagcarried) // don't eat the flag carrier and ruin his job
  92         if not(prey.BUTTON_ATCK || prey.BUTTON_ATCK2) // our team mate wouldn't want us eating him while he's attacking
  93         {
  94                 if(time > self.decide_swallow)
  95                 {
  96                         // base the decision around HOW damaged the team mate is, centered around 100 health
  97                         if(skill * (100 / prey.health) >= random() * 10) // there are 10 bot skill steps
  98                                 self.hold_BUTTON_ATCK = TRUE; // swallow the team mate
  99                         self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
 100                 }
 101         }
 102         else
 103                 self.hold_BUTTON_ATCK = FALSE;
 104 }
 105
 106 void Vore_AI()
 107 {
 108         // main vore AI code
 109         entity head;
 110
 111         if(!cvar("g_vore")) // the vore system is disabled
 112                 return;
 113         if(self.deadflag != DEAD_NO || cvar("bot_nofire") || !skill || (g_rpg && cvar("g_rpg_botattack") < 1))
 114                 return;
 115
 116         float randomtry;
 117         randomtry = random() * 10; // there are 10 bot skill steps
 118
 119 // --------------------------------
 120 // Predator bot behavior:
 121 // --------------------------------
 122
 123         if(!self.stat_eaten)
 124         {
 125                 // finding and swallowing a player
 126
 127                 // aim toward the nearest possible victim. The greater the skill, the quicker the aim
 128                 // this only does the aiming, checking and swallowing is handled below
 129                 head = findradius(self.origin, cvar("g_balance_vore_swallow_range"));
 130                 while(head)
 131                 {
 132                         if(Swallow_condition_check_bot(head))
 133                                 bot_aimdir(head.origin + head.view_ofs - self.origin - self.view_ofs, -1);
 134                         head = head.chain;
 135                 }
 136
 137                 // now do the actual checking and swallowing
 138                 entity prey;
 139                 float decide_pred_time, fear;
 140
 141                 prey = Swallow_player_check();
 142                 fear = 1;
 143
 144                 // check if we should run the Teamhealing AI rather than continuing with the normal vore AI
 145                 Vore_AI_Teamheal(prey);
 146                 if(self.status_teamhealing > 1) // if we are teamhealing, there's nothing to do from here on
 147                         return;
 148
 149                 if(prey.classname == "player" && !cvar("g_vore_reversescoring")) // when reverse scoring is on, it's in the interest of the prey to get eaten, so the predator has nothing to fear
 150                 {
 151                         if(skill >= 3) // make bots aware of this from skill 3 and up
 152                                 fear *= 1 + self.stomach_load / self.stomach_maxload; // the bigger our stomach, the less we want to put someone else in there
 153                         if(skill >= 5) // make bots aware of this from skill 5 and up
 154                                 fear *= 1 + prey.stomach_load / prey.stomach_maxload; // predators fear prey that have a large stomach
 155
 156                         if(cvar("g_healthsize"))
 157                                 fear *= (prey.scale / self.scale); // predators fear larger prey and are courageous toward smaller prey
 158                         if(prey.items & IT_STRENGTH) // avoid eating bots that have the Strenght powerup
 159                                 fear *= 2;
 160                         if(prey.items & IT_INVINCIBLE) // avoid eating bots that have the Invincible powerup
 161                                 fear *= 2;
 162
 163                         // when a bot is being swallowed, he will try to swallow the enemy back in defense, forgetting about fear
 164                         if(self.swallow_progress_prey)
 165                                 fear /= self.swallow_progress_prey * skill;
 166
 167                         fear *= cvar("bot_ai_vore_fear") * self.bot_vorefear;
 168                 }
 169
 170                 decide_pred_time = cvar("bot_ai_vore_decide_pred") / skill / self.bot_vorethinkpred;
 171
 172                 if(Swallow_condition_check_bot(prey))
 173                 {
 174                         if(time > self.decide_swallow)
 175                         {
 176                                 // the greater the skill, the higher the chance bots will swallow someone each attempt
 177                                 if(skill / fear >= randomtry)
 178                                 if not(teams_matter && prey.team == self.team)
 179                                 {
 180                                         self.hold_BUTTON_ATCK = TRUE; // swallow
 181                                         self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 182                                 }
 183                                 self.decide_swallow = time + cvar("bot_ai_vore_decide_swallow") / self.bot_vorethinkpred; // this is needed to take a proper decision, otherwise the code would execute each frame and return TRUE quickly
 184                         }
 185                 }
 186                 else
 187                         self.hold_BUTTON_ATCK = FALSE;
 188
 189                 // if the bot is holding the firing button, apply that to the actual fire key
 190                 if(self.hold_BUTTON_ATCK)
 191                         self.BUTTON_ATCK = TRUE;
 192
 193                 // deciding what to do with victims
 194                 if(self.stomach_load && time > self.decide_pred)
 195                 {
 196                         // if the predator's stomach contains only dead prey or items, and he has reached the maximum amount of health
 197                         // he can gain from digestion, there's no reason to keep dead prey or food any longer
 198                         if(skill >= 9) // such awareness comes from skill level 9 and up
 199                         {
 200                                 entity e;
 201                                 float consumables;
 202                                 for(e = world; (e = find(e, classname, "consumable")); )
 203                                 {
 204                                         if(e.predator == self)
 205                                                 consumables += e.health;
 206                                 }
 207
 208                                 if(!Stomach_HasLivePrey(self))
 209                                 if not(cvar("g_balance_vore_digestion_limit") < 0 && self.health < cvar("g_balance_vore_digestion_vampire_stable"))
 210                                 if not(consumables && self.health < max(max(g_pickup_healthsmall_max, g_pickup_healthmedium_max), max(g_pickup_healthlarge_max, g_pickup_healthmega_max)))
 211                                         self.BUTTON_REGURGITATE = TRUE;
 212                         }
 213
 214                         // if the predator's health is smaller than the damage a stomach kick can do, regurgitate the player(s)
 215                         // otherwise the predator is putting himself at risk by keeping you inside
 216                         float kick_dmg;
 217                         if(cvar("g_vore_kick") && skill >= 7) // such awareness comes from skill level 7 and up
 218                         {
 219                                 kick_dmg = cvar("g_balance_vore_kick_damage");
 220                                 if(cvar("g_healthsize"))
 221                                 {
 222                                         FOR_EACH_PLAYER(head) // count the size of all players in the stomach for accounting the danger level
 223                                         {
 224                                                 if(head.predator == self)
 225                                                 if not(teamplay && head.team == self.team) // don't count team mates
 226                                                 if(head.deadflag != DEAD_NO) // don't count dead prey
 227                                                         kick_dmg *= pow(head.scale / self.scale, cvar("g_balance_vore_kick_scalediff")); // based on the damage the prey can do to us at his size
 228                                         }
 229                                 }
 230                         }
 231
 232                         if(self.health <= kick_dmg)
 233                                 self.BUTTON_REGURGITATE = TRUE;
 234                         else if(!self.digesting && cvar("g_vore_digestion"))
 235                         {
 236                                 // the higher the skill, the faster bots will start to digest
 237                                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 238                                 if(skill >= randomtry)
 239                                         self.BUTTON_DIGEST = TRUE; // digest
 240
 241                                 self.decide_pred = time + decide_pred_time; // time before the bot decides what to do with his prey
 242                         }
 243                 }
 244         }
 245
 246 // --------------------------------
 247 // Prey bot behavior:
 248 // --------------------------------
 249
 250         if(cvar("g_vore_reversescoring")) // if reverse scoring is on, it's in the interest of the prey to get eaten, so don't fight back
 251                 return;
 252
 253         // while being swallowed, smart bots know to keep jumping to make it harder to be caught
 254         // TODO: Don't do this if the predator is a team mate
 255         if(self.swallow_progress_prey)
 256         if(self.swallow_progress_prey * 10 >= 10 - skill) // 10 skill steps
 257                 self.BUTTON_JUMP = TRUE;
 258
 259         if(self.stat_eaten && time > self.decide_prey)
 260         {
 261                 // all we can do in the stomach is kick and do some damage / try to escape, or leave if the circumstances allow it and we should
 262
 263                 float decide_prey_time;
 264                 decide_prey_time = cvar("bot_ai_vore_decide_prey") / skill / self.bot_vorethinkprey;
 265
 266                 if(cvar("g_vore_kick"))
 267                 if not(g_rpg && cvar("g_rpg_botattack") < 2)
 268                 if not(teams_matter && self.team == self.predator.team)
 269                 {
 270                         // the higher the skill, the more the bot will kick in your stomack
 271                         if(skill >= randomtry)
 272                         if not(teams_matter && self.team == self.predator.team) // if someone from the same team is in the belly, don't kick the predator
 273                                 self.BUTTON_ATCK = TRUE; // kick
 274                 }
 275
 276                 // if a bot can willingly leave the predator, do so unless there's a reason not to
 277                 if(self.stat_canleave)
 278                 {
 279                         if(self.predator.digesting) // our predator is digesting, so get out of him regardless of who he is
 280                                 self.BUTTON_JUMP = TRUE; // leave
 281                         else if not((g_rpg && cvar("g_rpg_botattack") < 2) || !cvar("g_vore_digestion")) // don't leave when gentle vore is enabled
 282                         {
 283                                 if not(teams_matter && self.team == self.predator.team && cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable")) // we are being team healed, don't leave
 284                                 if not(teams_matter && self.team == self.predator.team && cvar("bot_ai_vore_stayinstomach")) // bots are not supposed to leave a team mate's stomach automatically
 285                                         self.BUTTON_JUMP = TRUE; // leave
 286                         }
 287                 }
 288
 289                 self.decide_prey = time + decide_prey_time; // time before the bot decides what to do with their predator
 290         }
 291 }