data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 \r
   9 entity Swallow_player_check()\r
  10 {\r
  11         // check if we can swallow a player instead of firing our weapon\r
  12 \r
  13         float swallow_range;\r
  14         vector vore_w_shotorg, vore_w_shotdir;\r
  15 \r
  16         swallow_range = cvar("g_balance_vore_swallow_range");\r
  17         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  18                 swallow_range *= self.scale;\r
  19         makevectors(self.angles);\r
  20         vore_w_shotorg = self.origin;\r
  21         vore_w_shotdir = v_forward;\r
  22 \r
  23         if(self.antilag_debug)\r
  24                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  25         else\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  27         if(trace_fraction < 1)\r
  28         if(trace_ent.classname == "player")\r
  29                 return trace_ent;\r
  30         return world;\r
  31 }\r
  32 \r
  33 float Swallow_condition_check(entity prey)\r
  34 {\r
  35         // checks the necessary conditions for swallowing a player\r
  36 \r
  37         if(prey != self)\r
  38         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  39         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  40         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  41         {\r
  42                 float prey_mass;\r
  43                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  44                 if(cvar("g_healthsize"))\r
  45                         prey_mass *= prey.scale;\r
  46 \r
  47                 string swallow_complain;\r
  48                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  49                         swallow_complain = "You cannot swallow your team mates\n";\r
  50                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  51                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  52                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  53                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  54                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  55                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  56                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  57                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  58 \r
  59                 if(swallow_complain != "")\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, swallow_complain);\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Stomach_TeamMates_check(entity pred)\r
  75 {\r
  76         // checks if a player's stomach contains any team mates\r
  77 \r
  78         entity head;\r
  79         if(teams_matter)\r
  80         {\r
  81                 FOR_EACH_PLAYER(head)\r
  82                 {\r
  83                         if(head.predator == pred && head.team == pred.team)\r
  84                                 return TRUE;\r
  85                 }\r
  86         }\r
  87         return FALSE;\r
  88 }\r
  89 \r
  90 float Stomach_HasLivePrey(entity pred)\r
  91 {\r
  92         entity head;\r
  93         FOR_EACH_PLAYER(head)\r
  94         {\r
  95                 if(head.predator == pred)\r
  96                 if(head.deadflag == DEAD_NO)\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 float Vore_CanLeave()\r
 103 {\r
 104         if(self.stat_eaten)\r
 105         {\r
 106                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 107                         return TRUE;\r
 108                 if(teams_matter && self.team == self.predator.team)\r
 109                         return TRUE;\r
 110                 if(g_rpg && cvar("g_rpg_canleave"))\r
 111                         return TRUE;\r
 112         }\r
 113         return FALSE;\r
 114 }\r
 115 \r
 116 // position the camera properly for prey\r
 117 void Vore_SetPreyPositions(entity pred)\r
 118 {\r
 119         // pred is the predator and head is the prey\r
 120 \r
 121         local entity head;\r
 122 \r
 123         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 124         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == pred)\r
 128                 {\r
 129                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 130                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 131                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 133                 }\r
 134         }\r
 135 }\r
 136 \r
 137 .float gurgle_oldstomachload;\r
 138 void Vore_GurgleSound()\r
 139 {\r
 140         if(time > self.gurglesound_finished || (self.gurgle_oldstomachload != self.stomach_load && !self.digesting))\r
 141         {\r
 142                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE, VOL_BASE);\r
 143 \r
 144                 // yes, hard coded sound length. I know it's bad but what can I do?\r
 145                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 146                         self.gurglesound_finished = time + 11 * pow(self.scale, -cvar("g_healthsize_pitch")); // modified sound pitch, based on player scale\r
 147                 else\r
 148                         self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 149 \r
 150                 self.gurgle_oldstomachload = self.stomach_load;\r
 151         }\r
 152 }\r
 153 \r
 154 void Vore_AutoDigest(entity e)\r
 155 {\r
 156         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 157 \r
 158         if(!cvar("g_vore_digestion") || e.digesting)\r
 159                 return;\r
 160         if(g_rpg)\r
 161                 return; // RPG is choice based, so don't do things automatically there\r
 162         if(e.stomach_load)\r
 163                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 164         if(clienttype(e) != CLIENTTYPE_REAL)\r
 165                 return; // this feature is only for players, not bots\r
 166         if(Stomach_TeamMates_check(e))\r
 167                 return; // never begin automatic digestion if we've swallowed a team mate\r
 168 \r
 169         e.digesting = TRUE;\r
 170 }\r
 171 \r
 172 void Vore_StomachLoad_Apply()\r
 173 {\r
 174         // apply stomach weight that makes you heavier and larger the more you eat\r
 175         // slowing the player is done in cl_physics.qc\r
 176         if(self.classname != "player")\r
 177                 return;\r
 178 \r
 179         entity e;\r
 180         float prey_mass, final_load;\r
 181 \r
 182         // apply the stomach capacity of the predator\r
 183         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 184         if(cvar("g_healthsize"))\r
 185                 self.stomach_maxload *= self.scale;\r
 186         self.stomach_maxload = ceil(self.stomach_maxload);\r
 187 \r
 188         FOR_EACH_PLAYER(e)\r
 189         {\r
 190                 if(e.predator == self)\r
 191                 {\r
 192                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 193                         if(cvar("g_healthsize"))\r
 194                                 prey_mass *= e.scale;\r
 195                         final_load += ceil(prey_mass);\r
 196                         if(self.cvar_cl_vore_autodigest > 1)\r
 197                                 Vore_AutoDigest(self);\r
 198                 }\r
 199         }\r
 200         for(e = world; (e = find(e, classname, "consumable")); )\r
 201         {\r
 202                 if(e.predator == self)\r
 203                 {\r
 204                         final_load += ceil(e.dmg);\r
 205                         if(self.cvar_cl_vore_autodigest > 0)\r
 206                                 Vore_AutoDigest(self);\r
 207                 }\r
 208         }\r
 209         self.stomach_load = final_load;\r
 210 \r
 211         // apply weight\r
 212         self.gravity = 1 * (cvar("g_healthsize") ? pow(self.scale, cvar("g_healthsize_weight")) : 1) + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 213         if(!self.gravity && self.stomach_load)\r
 214                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 215 }\r
 216 \r
 217 .entity swallow_model;\r
 218 float Vore_GulletModel_CustomizeEntityForClient()\r
 219 {\r
 220         // use the same system as the weapon model\r
 221 \r
 222         self.viewmodelforclient = self.owner;\r
 223         self.alpha = self.owner.cvar_cl_vore_gulletmodel;\r
 224 \r
 225         if(other.classname == "spectator")\r
 226         if(other.enemy == self.owner)\r
 227         {\r
 228                 self.viewmodelforclient = other;\r
 229                 self.alpha = other.cvar_cl_vore_gulletmodel;\r
 230         }\r
 231 \r
 232         return TRUE;\r
 233 }\r
 234 \r
 235 void Vore_GulletModel_Think()\r
 236 {\r
 237         // update the position of the swallow model to match our swallow progress\r
 238         float dist;\r
 239         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 240         if(cvar("g_healthsize"))\r
 241                 dist *= self.scale;\r
 242         self.view_ofs = '1 0 0' * dist;\r
 243 \r
 244         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 245         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 246         {\r
 247                 remove(self.owner.swallow_model);\r
 248                 self.owner.swallow_model = world;\r
 249                 return;\r
 250         }\r
 251 \r
 252         // properties that should update whenever possible, but when the predator is not available\r
 253         self.nextthink = time;\r
 254 }\r
 255 \r
 256 void Vore_GulletModel_Update(entity prey, entity pred)\r
 257 {\r
 258         // if we don't have a swallow model already, spawn one\r
 259         if(!prey.swallow_model)\r
 260         {\r
 261                 prey.swallow_model = spawn();\r
 262                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 263                 prey.swallow_model.solid = SOLID_NOT;\r
 264                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 265                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 266                 prey.swallow_model.owner = prey;\r
 267                 prey.swallow_model.customizeentityforclient = Vore_GulletModel_CustomizeEntityForClient;\r
 268                 prey.swallow_model.think = Vore_GulletModel_Think;\r
 269                 prey.swallow_model.nextthink = time;\r
 270         }\r
 271 \r
 272         // properties that should update whenever possible, but when the predator is available\r
 273         string player_gulletmodel;\r
 274         player_gulletmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_gullet.iqm"); // 4 is the extension length\r
 275         if(prey.swallow_model.model != player_gulletmodel) // player model can be changed while the predator is active\r
 276                 setmodel(prey.swallow_model, player_gulletmodel);\r
 277         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 278                 prey.swallow_model.skin = pred.skin;\r
 279         if(cvar("g_healthsize"))\r
 280                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 281         if(prey.swallow_model.enemy != pred)\r
 282                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 283         if(prey.swallow_model.colormap != pred.colormap)\r
 284                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 285         if(prey.swallow_model.glowmod != pred.glowmod)\r
 286                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 287 }\r
 288 \r
 289 .entity pusher;\r
 290 .float pushltime;\r
 291 void Vore_Swallow(entity e)\r
 292 {\r
 293         // this player is being swallowed by another player, apply the proper changes\r
 294 \r
 295         e.vore_oldmovetype = e.movetype;\r
 296         e.vore_oldsolid = e.solid;\r
 297         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 298 \r
 299         e.predator = self;\r
 300         setorigin(e, e.predator.origin);\r
 301         e.velocity = '0 0 0';\r
 302         e.punchangle = '0 0 0';\r
 303         e.movetype = MOVETYPE_FOLLOW;\r
 304         e.solid = SOLID_NOT;\r
 305         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 306 \r
 307         float scalediff;\r
 308         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 309 \r
 310         // drop keys (KH) and flags (CTF) when we get swallowed\r
 311         kh_Key_DropAll(e, FALSE);\r
 312         if(e.flagcarried)\r
 313                 DropFlag(e.flagcarried, world, e.predator);\r
 314 \r
 315         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 316                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 317 \r
 318         if(teams_matter && e.team == e.predator.team)\r
 319         {\r
 320                 if(cvar("g_vore_kick"))\r
 321                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 322                 if(cvar("g_vore_digestion"))\r
 323                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 324         }\r
 325 \r
 326         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 327         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 328         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 329         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 330         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_swallow_predator_punchangle") * scalediff;\r
 331         e.predator.regurgitate_prepare = 0;\r
 332         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 333         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 334         Vore_SetPreyPositions(e.predator);\r
 335 \r
 336         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 337         e.predator.weapon_delay = time + button_delay_time;\r
 338         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 339         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 340         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 341 }\r
 342 \r
 343 void Vore_SwallowStep(entity e)\r
 344 {\r
 345         if(!cvar("g_balance_vore_swallow_speed_fill_player"))\r
 346         {\r
 347                 Vore_Swallow(e);\r
 348                 return;\r
 349         }\r
 350 \r
 351         // when the predator starts swallowing, play his grab sound\r
 352         if(!self.swallow_progress_pred)\r
 353                 PlayerSound(self, playersound_grab, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 354 \r
 355         // apply prey orientation\r
 356         if(cvar("g_balance_vore_swallow_prey_orient"))\r
 357         {\r
 358                 e.punchangle = self.angles - e.angles;\r
 359                 e.punchangle_speed = cvar("g_balance_vore_swallow_prey_orient_speed") * (1 - e.swallow_progress_prey);\r
 360         }\r
 361 \r
 362         Vore_GulletModel_Update(e, self);\r
 363 \r
 364         // increase the progress value until it reaches 1, then swallow the player\r
 365         if(e.swallow_progress_prey < 1)\r
 366         {\r
 367                 float fill;\r
 368                 fill = cvar("g_balance_vore_swallow_speed_fill_player") * frametime;\r
 369                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff_player")) // fill rate depends on predator size compared to prey size\r
 370                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff_player"));\r
 371                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 372                         fill *= (1 - ((e.stomach_load / e.stomach_maxload) * bound(0, cvar("g_balance_vore_swallow_speed_fill_stomachload"), 1)));\r
 373 \r
 374                 // skill-based speed offset for bots\r
 375                 if(skill && cvar("skill_offset"))\r
 376                 {\r
 377                         float ofs;\r
 378                         ofs = pow(skill / cvar("skill_offset_center"), cvar("skill_offset"));\r
 379                         if(clienttype(self) == CLIENTTYPE_BOT)\r
 380                                 fill *= ofs;\r
 381                         if(clienttype(e) == CLIENTTYPE_BOT)\r
 382                                 fill /= ofs;\r
 383                 }\r
 384 \r
 385                 e.swallow_progress_prey += fill;\r
 386         }\r
 387         else\r
 388         {\r
 389                 Vore_Swallow(e);\r
 390                 e.swallow_progress_prey = 0;\r
 391         }\r
 392 \r
 393         // the predator's progress is how much the prey got swallowed\r
 394         self.swallow_progress_pred = e.swallow_progress_prey;\r
 395 }\r
 396 \r
 397 void Vore_Regurgitate(entity e)\r
 398 {\r
 399         // this player is being regurgitated by their predator, apply the proper changes\r
 400 \r
 401         e.movetype = e.vore_oldmovetype;\r
 402         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 403                 e.solid = e.vore_oldsolid;\r
 404         e.view_ofs_z = PL_VIEW_OFS_z;\r
 405         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 406 \r
 407         // if the prey has been fully digested, silently detach them\r
 408         if(cvar("g_balance_vore_regurgitate_death_silent"))\r
 409         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 410         {\r
 411                 e.predator = world;\r
 412                 e.modelindex = 0; // hide the dead body\r
 413                 return;\r
 414         }\r
 415 \r
 416         float scalediff;\r
 417         scalediff = cvar("g_healthsize") ? e.scale / e.predator.scale : 1; // the tighter the gut, the greater the effect\r
 418 \r
 419         // apply velocities\r
 420         makevectors(e.predator.v_angle);\r
 421         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force") * scalediff;\r
 422         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce") * scalediff;\r
 423         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 424         e.pushltime = time + cvar("g_maxpushtime");\r
 425 \r
 426         // apply prey orientation\r
 427         if(cvar("g_balance_vore_swallow_prey_orient"))\r
 428         {\r
 429                 e.punchangle = e.predator.angles - e.angles;\r
 430                 e.punchangle_speed = cvar("g_balance_vore_swallow_prey_orient_speed") * (1 - e.swallow_progress_prey);\r
 431         }\r
 432 \r
 433         // if the dead body of the prey is below gibbing health, gib it\r
 434         e.stat_eaten = 0; // necessary for gibs to show\r
 435         PlayerGib(e, e.predator);\r
 436 \r
 437         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 438         if(cvar("g_balance_vore_swallow_speed_fill_player") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 439         {\r
 440                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 441                 Vore_GulletModel_Update(e, e.predator);\r
 442         }\r
 443 \r
 444         // apply regurgitation damage to the predator\r
 445         if(cvar("g_balance_vore_regurgitate_damage"))\r
 446         {\r
 447                 float regurgitate_dmg;\r
 448                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 449                 if(cvar("g_healthsize"))\r
 450                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 451                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 452         }\r
 453 \r
 454         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 455         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 456         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', floor(scalediff * PARTICLE_MULTIPLIER));\r
 457         e.predator.punchangle_x = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 458         e.predator.punchangle_y = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 459         e.predator.punchangle_z = crandom() * cvar("g_balance_vore_regurgitate_predator_punchangle") * scalediff;\r
 460         e.predator.regurgitate_prepare = 0;\r
 461         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 462         Vore_SetPreyPositions(e.predator);\r
 463 \r
 464         // block firing for a small amount of time, or we'll be firing the next frame\r
 465         e.weapon_delay = time + button_delay_time;\r
 466         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 467         e.predator = world;\r
 468 }\r
 469 \r
 470 void Vore_Disconnect(float consumables)\r
 471 {\r
 472         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 473         entity e;\r
 474 \r
 475         // prey disconnects or goes spectating while inside someone's belly\r
 476         if(self.stat_eaten)\r
 477                 Vore_Regurgitate(self);\r
 478 \r
 479         // pred disconnects or goes spectating with players in their belly\r
 480         entity head;\r
 481         FOR_EACH_PLAYER(head)\r
 482         {\r
 483                 if(head.predator == self)\r
 484                         Vore_Regurgitate(head);\r
 485         }\r
 486         // remove consumable items when we disconnect\r
 487         if(consumables)\r
 488         {\r
 489                 for(e = world; (e = find(e, classname, "consumable")); )\r
 490                 {\r
 491                         if(e.predator == self)\r
 492                                 Item_Consumable_Remove(e, TRUE);\r
 493                 }\r
 494         }\r
 495 \r
 496         self.stomach_load = self.gravity = 0; // prevents a bug\r
 497         Vore_GurgleSound(); // stop the gurgling sound\r
 498 }\r
 499 \r
 500 .float digestion_step;\r
 501 void Vore_Digest()\r
 502 {\r
 503         // apply digestion to prey\r
 504 \r
 505         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 506         {\r
 507                 self.predator.digesting = FALSE;\r
 508                 return;\r
 509         }\r
 510         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 511                 return;\r
 512 \r
 513         if(time > self.digestion_step)\r
 514         {\r
 515                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 516                 float damage, damage_offset;\r
 517 \r
 518                 damage_offset = 1;\r
 519                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 520                         damage_offset /= (1 - (self.predator.stomach_load / self.predator.stomach_maxload) * bound(0, cvar("g_balance_vore_digestion_distribute"), 1));\r
 521                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 522                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 523 \r
 524                 if(self.deadflag != DEAD_NO)\r
 525                         damage = cvar("g_balance_vore_digestion_damage_death") / damage_offset;\r
 526                 else\r
 527                         damage = cvar("g_balance_vore_digestion_damage") / damage_offset;\r
 528 \r
 529                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 530                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 531                 {\r
 532                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 533                         self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 534                 }\r
 535 \r
 536                 self.digestion_step = time + vore_steptime;\r
 537         }\r
 538 \r
 539         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 540                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 541 }\r
 542 \r
 543 .float teamheal_step;\r
 544 void Vore_Teamheal()\r
 545 {\r
 546         // apply teamheal\r
 547 \r
 548         if(self.deadflag != DEAD_NO)\r
 549                 return;\r
 550 \r
 551         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 552         if(time > self.teamheal_step)\r
 553         {\r
 554                 self.health += cvar("g_balance_vore_teamheal");\r
 555                 self.teamheal_step = time + vore_steptime;\r
 556 \r
 557                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 558                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 559                 {\r
 560                         play2(self, "misc/beep.wav");\r
 561                         play2(self.predator, "misc/beep.wav");\r
 562                 }\r
 563         }\r
 564 }\r
 565 \r
 566 .float kick_pressed;\r
 567 void Vore_StomachKick()\r
 568 {\r
 569         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 570 \r
 571         if(self.deadflag != DEAD_NO)\r
 572                 return;\r
 573 \r
 574         float scalediff;\r
 575         scalediff = pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 576 \r
 577         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 578         {\r
 579                 float damage, vol, pitch;\r
 580                 vector force;\r
 581                 damage = cvar("g_balance_vore_kick_damage");\r
 582                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 583                 vol = VOL_BASE;\r
 584 \r
 585                 // modified sound pitch, based on player scale\r
 586                 if(cvar("g_healthsize") && cvar("g_healthsize_pitch"))\r
 587                         pitch = pow(self.predator.scale, -cvar("g_healthsize_pitch"));\r
 588 \r
 589                 // apply player scale to the damage / force of the kick\r
 590                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 591                 {\r
 592                         damage *= scalediff;\r
 593                         force *= scalediff;\r
 594                         vol *= scalediff; // kick sound volume based on the same scale\r
 595                 }\r
 596                 vol = bound(0, vol, 1);\r
 597 \r
 598                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 599                 sound7(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM, 100 * pitch, 0);\r
 600                 self.predator.punchangle_x = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 601                 self.predator.punchangle_y = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 602                 self.predator.punchangle_z = crandom() * cvar("g_balance_vore_kick_predator_punchangle") * scalediff;\r
 603                 self.punchangle_x = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 604                 self.punchangle_y = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 605                 self.punchangle_z = crandom() * cvar("g_balance_vore_kick_prey_punchangle") * scalediff;\r
 606 \r
 607                 // abort the predator's scheduled regurgitation\r
 608                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 609                         self.predator.regurgitate_prepare = 0;\r
 610 \r
 611                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 612                 if(cvar("g_balance_vore_kick_repress"))\r
 613                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 614                         self.kick_pressed = TRUE;\r
 615         }\r
 616 }\r
 617 \r
 618 void Vore_StomachLeave()\r
 619 {\r
 620         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 621 \r
 622         if(self.deadflag != DEAD_NO)\r
 623                 return;\r
 624 \r
 625         if(Vore_CanLeave())\r
 626                 Vore_Regurgitate(self);\r
 627         else if(time > self.complain_vore)\r
 628         {\r
 629                 play2(self, "misc/forbidden.wav");\r
 630                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 631                 self.complain_vore = time + complain_delay_time;\r
 632         }\r
 633 }\r
 634 \r
 635 void Vore_AutoTaunt()\r
 636 {\r
 637         // triggers ambient vore taunts, for both pred and prey\r
 638 \r
 639         float taunt_time;\r
 640 \r
 641         // predator taunts\r
 642         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 643         {\r
 644                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 645                 {\r
 646                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 647                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 648                 }\r
 649         }\r
 650         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 651         {\r
 652                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 653                 SetAutoTaunt(self, 0, 0);\r
 654         }\r
 655 \r
 656         // prey taunts\r
 657         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 658         {\r
 659                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 660                 {\r
 661                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 662                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 663                 }\r
 664         }\r
 665         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 666         {\r
 667                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 668                 SetAutoTaunt(self, 0, 0);\r
 669         }\r
 670 }\r
 671 \r
 672 void Vore_SetSbarRings()\r
 673 {\r
 674         // first clear the ring stats, then configure them if needed\r
 675         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 676         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 677 \r
 678         if(self.stat_eaten)\r
 679         {\r
 680                 if(time <= self.stomachkick_delay)\r
 681                 {\r
 682                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 683                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 684                 }\r
 685         }\r
 686         else\r
 687         {\r
 688                 if(self.swallow_progress_pred)\r
 689                 {\r
 690                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 691                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 692                 }\r
 693                 else if(time <= self.action_delay)\r
 694                 {\r
 695                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 696                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 697                 }\r
 698 \r
 699                 if(self.swallow_progress_prey)\r
 700                 {\r
 701                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 702                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 703                 }\r
 704                 else if(time <= self.regurgitate_prepare)\r
 705                 {\r
 706                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 707                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 708                 }\r
 709         }\r
 710 }\r
 711 \r
 712 .float regurgitatecolor_particles_tick;\r
 713 void Vore()\r
 714 {\r
 715         // main vore code, this is where it all happens\r
 716 \r
 717         Vore_AutoTaunt();\r
 718 \r
 719         if(!self.stat_eaten)\r
 720         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 721         if(self.colormod)\r
 722         if(self.colormod != '1 1 1')\r
 723         {\r
 724                 // slowly wash stomach fluids off players once they're out of the stomach\r
 725                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 726                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 727                 {\r
 728                         float goo_fade;\r
 729                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 730                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 731 \r
 732                         self.colormod_x += goo_fade;\r
 733                         if(self.colormod_x > 1)\r
 734                                 self.colormod_x = 1;\r
 735                         self.colormod_y += goo_fade;\r
 736                         if(self.colormod_y > 1)\r
 737                                 self.colormod_y = 1;\r
 738                         self.colormod_z += goo_fade;\r
 739                         if(self.colormod_z > 1)\r
 740                                 self.colormod_z = 1;\r
 741                 }\r
 742 \r
 743                 // constant particles falling off dirty players\r
 744                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 745                 if(self.regurgitatecolor_particles_tick < time)\r
 746                 {\r
 747                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', floor((cvar("g_healthsize") ? self.scale : 1) * PARTICLE_MULTIPLIER));\r
 748                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 749                 }\r
 750         }\r
 751 \r
 752         // set all vore stats\r
 753         Vore_SetSbarRings();\r
 754         if(self.predator.classname == "player")\r
 755         {\r
 756                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 757                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 758                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 759                 self.stat_eaten = num_for_edict(self.predator);\r
 760         }\r
 761         else\r
 762         {\r
 763                 self.stat_stomachload = self.stomach_load;\r
 764                 self.stat_stomachmaxload = self.stomach_maxload;\r
 765                 self.stat_digesting = self.digesting;\r
 766                 self.stat_eaten = 0;\r
 767         }\r
 768         self.stat_canleave = Vore_CanLeave();\r
 769 \r
 770         // don't allow a player inside a player inside another player :)\r
 771         // prevent this by checking if such has happened, and taking the proper measures\r
 772         // this code has a high priority and must not be stopped by any delay, so run it here\r
 773         if(self.predator.stat_eaten)\r
 774                 Vore_Regurgitate(self);\r
 775 \r
 776         // the swallow progress of prey and preds idly decrease by this amount\r
 777         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 778         {\r
 779                 if(self.swallow_progress_pred)\r
 780                 {\r
 781                         float speed = cvar("g_balance_vore_swallow_speed_decrease");\r
 782                         if(cvar("g_balance_vore_swallow_speed_decrease_even"))\r
 783                                 speed += self.swallow_progress_prey * cvar("g_balance_vore_swallow_speed_decrease_even");\r
 784                         self.swallow_progress_pred = max(0, self.swallow_progress_pred - speed * frametime);\r
 785                 }\r
 786                 if(self.swallow_progress_prey)\r
 787                 {\r
 788                         float speed = cvar("g_balance_vore_swallow_speed_decrease");\r
 789                         if(cvar("g_balance_vore_swallow_speed_decrease_even"))\r
 790                                 speed += self.swallow_progress_pred * cvar("g_balance_vore_swallow_speed_decrease_even");\r
 791                         self.swallow_progress_prey = max(0, self.swallow_progress_prey - cvar("g_balance_vore_swallow_speed_decrease") * frametime);\r
 792                 }\r
 793         }\r
 794 \r
 795         // set the predator's stomach load and capacity\r
 796         Vore_StomachLoad_Apply();\r
 797 \r
 798         // apply delays and skip the vore system under some circumstances\r
 799         if(!cvar("g_vore")) // the vore system is disabled\r
 800         {\r
 801                 Vore_Disconnect(TRUE);\r
 802                 return;\r
 803         }\r
 804         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 805         {\r
 806                 Vore_Disconnect(FALSE);\r
 807                 return;\r
 808         }\r
 809         if(self.spectatee_status)\r
 810                 return;\r
 811         if(time < self.system_delay)\r
 812                 return;\r
 813 \r
 814 // --------------------------------\r
 815 // Code that addresses predators:\r
 816 // --------------------------------\r
 817 \r
 818         entity prey;\r
 819         prey = Swallow_player_check();\r
 820 \r
 821         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 822         self.stat_canswallow = 0;\r
 823         if(Swallow_condition_check(prey))\r
 824         {\r
 825                 // canswallow stat, used by the HUD\r
 826                 if(teams_matter && prey.team == self.team)\r
 827                         self.stat_canswallow = 2;\r
 828                 else\r
 829                         self.stat_canswallow = 1;\r
 830 \r
 831                 if(self.BUTTON_ATCK)\r
 832                         Vore_SwallowStep(prey);\r
 833         }\r
 834         else if(prey != world)\r
 835                 self.stat_canswallow = -1;\r
 836 \r
 837         // toggle digestion, if the player has someone in their stomach\r
 838         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 839         {\r
 840                 if(self.stomach_load)\r
 841                 {\r
 842                         if(time > self.digest_button_delay_time)\r
 843                         {\r
 844                                 self.digesting = !self.digesting;\r
 845                                 self.digest_button_delay_time = time + button_delay_time;\r
 846                         }\r
 847                 }\r
 848                 else if(time > self.complain_vore)\r
 849                 {\r
 850                         play2(self, "misc/forbidden.wav");\r
 851                         sprint(self, "There is nothing to digest\n");\r
 852                         self.complain_vore = time + complain_delay_time;\r
 853                 }\r
 854         }\r
 855         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 856                 self.digesting = FALSE;\r
 857 \r
 858         // predator wishes to regurgitate his prey\r
 859         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 860         if(!self.regurgitate_prepare)\r
 861         {\r
 862                 if(self.stomach_load)\r
 863                 {\r
 864                         if(time > self.regurgitate_button_delay_time)\r
 865                         {\r
 866                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 867                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 868                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 869                                 self.punchangle_x = cvar("g_balance_vore_regurgitate_predator_prepare_punchangle");\r
 870                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 871                         }\r
 872                 }\r
 873                 else if(time > self.complain_vore)\r
 874                 {\r
 875                         play2(self, "misc/forbidden.wav");\r
 876                         sprint(self, "There is nothing to regurgitate\n");\r
 877                         self.complain_vore = time + complain_delay_time;\r
 878                 }\r
 879         }\r
 880 \r
 881         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 882         {\r
 883                 self.regurgitate_prepare = -1;\r
 884                 return;\r
 885         }\r
 886         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load)\r
 887         if(vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 888         {\r
 889                 self.regurgitate_prepare = -1;\r
 890                 return;\r
 891         }\r
 892 \r
 893         if (self.digesting && self.digestsound_finished < time)\r
 894         {\r
 895                 PlayerSound (self, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 896                 self.digestsound_finished = time + 0.5;\r
 897         }\r
 898         if(cvar("g_vore_gurglesound"))\r
 899                 Vore_GurgleSound();\r
 900 \r
 901 // --------------------------------\r
 902 // Code that addresses the prey:\r
 903 // --------------------------------\r
 904 \r
 905         if(!self.stat_eaten)\r
 906                 return;\r
 907 \r
 908         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 909                 self.health = cvar("g_balance_vore_digestion_limit");\r
 910 \r
 911         // automatically regurgitate prey that has reached their digestion limit\r
 912         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 913         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 914         {\r
 915                 Vore_Regurgitate(self);\r
 916                 return;\r
 917         }\r
 918 \r
 919         // do we stick around inside dead furries? x_x\r
 920         if(self.predator.deadflag != DEAD_NO)\r
 921         {\r
 922                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 923                 {\r
 924                         Vore_Regurgitate(self);\r
 925                         return;\r
 926                 }\r
 927                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 928                         self.predator.regurgitate_prepare = 0;\r
 929         }\r
 930 \r
 931         // apply delayed regurgitating if it was scheduled\r
 932         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 933         {\r
 934                 Vore_Regurgitate(self);\r
 935                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 936         }\r
 937 \r
 938         // execute digesting and team healing\r
 939         if(self.predator.digesting == TRUE)\r
 940                 Vore_Digest();\r
 941         if(teams_matter && self.team == self.predator.team)\r
 942         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 943                 Vore_Teamheal();\r
 944 \r
 945         // execute prey commands\r
 946         if(self.BUTTON_ATCK)\r
 947         {\r
 948                 if(cvar("g_vore_kick"))\r
 949                         Vore_StomachKick();\r
 950         }\r
 951         else\r
 952                 self.kick_pressed = FALSE;\r
 953         if(self.BUTTON_JUMP)\r
 954                 Vore_StomachLeave();\r
 955 \r
 956         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 957         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 958         kh_Key_DropAll(self, FALSE);\r
 959 \r
 960         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 961         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 962 }\r