data/qcsrc/server/vore.qc

   1 .float stomachkick_delay, system_delay, action_delay, digest_button_delay_time, regurgitate_button_delay_time;\r
   2 .float complain_vore;\r
   3 .float vore_oldmovetype, vore_oldsolid;\r
   4 \r
   5 const float system_delay_time = 0.1;\r
   6 const float complain_delay_time = 1;\r
   7 const float button_delay_time = 0.5;\r
   8 \r
   9 entity Swallow_player_check()\r
  10 {\r
  11         // check if we can swallow a player instead of firing our weapon\r
  12 \r
  13         float swallow_range;\r
  14         vector vore_w_shotorg, vore_w_shotdir;\r
  15 \r
  16         swallow_range = cvar("g_balance_vore_swallow_range");\r
  17         if(cvar("g_healthsize")) // we can swallow from further or closer based on our size\r
  18                 swallow_range *= self.scale;\r
  19         makevectors(self.angles);\r
  20         vore_w_shotorg = self.origin;\r
  21         vore_w_shotdir = v_forward;\r
  22 \r
  23         if(self.antilag_debug)\r
  24                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, self.antilag_debug);\r
  25         else\r
  26                 WarpZone_traceline_antilag(self, vore_w_shotorg, vore_w_shotorg + vore_w_shotdir * swallow_range, FALSE, self, ANTILAG_LATENCY(self));\r
  27         if(trace_fraction < 1)\r
  28         if(trace_ent.classname == "player")\r
  29                 return trace_ent;\r
  30         return world;\r
  31 }\r
  32 \r
  33 float Swallow_condition_check(entity prey)\r
  34 {\r
  35         // checks the necessary conditions for swallowing a player\r
  36 \r
  37         if(prey != self)\r
  38         if(prey.classname == "player" && !prey.stat_eaten && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  39         if(self.classname == "player" && !self.stat_eaten && self.deadflag == DEAD_NO) // we can't swallow players while inside someone's stomach ourselves\r
  40         if(!self.BUTTON_REGURGITATE && time > self.action_delay)\r
  41         {\r
  42                 float prey_mass;\r
  43                 prey_mass = cvar("g_balance_vore_load_prey_mass");\r
  44                 if(cvar("g_healthsize"))\r
  45                         prey_mass *= prey.scale;\r
  46 \r
  47                 string swallow_complain;\r
  48                 if(teams_matter && prey.team == self.team && !cvar("g_vore_teamvore"))\r
  49                         swallow_complain = "You cannot swallow your team mates\n";\r
  50                 else if(!cvar("g_vore_spawnshield") && prey.spawnshieldtime > time)\r
  51                         swallow_complain = "You cannot swallow someone protected by the spawn shield\n";\r
  52                 else if(self.stomach_load + prey_mass > self.stomach_maxload)\r
  53                         swallow_complain = strcat("You don't have any room to swallow this player. Their mass is ^3", ftos(prey_mass), "^7 and your remaining capacity is ^3", ftos(self.stomach_maxload - self.stomach_load), "\n");\r
  54                 else if(cvar("g_vore_biggergut") && prey.stomach_load > self.stomach_load)\r
  55                         swallow_complain = "You cannot swallow someone with a bigger stomach than yours\n";\r
  56                 else if(cvar("g_vore_biggersize") && prey.scale > self.scale)\r
  57                         swallow_complain = "You cannot swallow someone larger than you\n";\r
  58 \r
  59                 if(swallow_complain != "")\r
  60                 {\r
  61                         if(time > self.complain_vore && self.BUTTON_ATCK)\r
  62                         {\r
  63                                 play2(self, "misc/forbidden.wav");\r
  64                                 sprint(self, swallow_complain);\r
  65                                 self.complain_vore = time + complain_delay_time;\r
  66                         }\r
  67                         return FALSE;\r
  68                 }\r
  69                 return TRUE;\r
  70         }\r
  71         return FALSE;\r
  72 }\r
  73 \r
  74 float Stomach_TeamMates_check(entity pred)\r
  75 {\r
  76         // checks if a player's stomach contains any team mates\r
  77 \r
  78         entity head;\r
  79         if(teams_matter)\r
  80         {\r
  81                 FOR_EACH_PLAYER(head)\r
  82                 {\r
  83                         if(head.predator == pred && head.team == pred.team)\r
  84                                 return TRUE;\r
  85                 }\r
  86         }\r
  87         return FALSE;\r
  88 }\r
  89 \r
  90 float Stomach_HasLivePrey(entity pred)\r
  91 {\r
  92         entity head;\r
  93         FOR_EACH_PLAYER(head)\r
  94         {\r
  95                 if(head.predator == pred)\r
  96                 if(head.deadflag == DEAD_NO)\r
  97                         return TRUE;\r
  98         }\r
  99         return FALSE;\r
 100 }\r
 101 \r
 102 float Vore_CanLeave()\r
 103 {\r
 104         if(self.stat_eaten)\r
 105         {\r
 106                 if(!cvar("g_vore_kick")) // you are defenseless in the stomach if you can't kick, so allow leaving\r
 107                         return TRUE;\r
 108                 if(teams_matter && self.team == self.predator.team)\r
 109                         return TRUE;\r
 110                 if(g_rpg && cvar("g_rpg_canleave"))\r
 111                         return TRUE;\r
 112         }\r
 113         return FALSE;\r
 114 }\r
 115 \r
 116 // position the camera properly for prey\r
 117 void Vore_SetPreyPositions(entity pred)\r
 118 {\r
 119         // pred is the predator and head is the prey\r
 120 \r
 121         local entity head;\r
 122 \r
 123         // In order to allow prey to see each other in the stomach, we must position each occupant differently,\r
 124         // else all players overlap in the center. To do this, we use a random origin on all players in the same stomach.\r
 125         FOR_EACH_PLAYER(head)\r
 126         {\r
 127                 if(head.predator == pred)\r
 128                 {\r
 129                         // since prey have their predators set as an aiment, view_ofs will specify the real origin of prey, not just the view offset\r
 130                         head.view_ofs_x = PL_PREY_VIEW_OFS_x + crandom() * cvar("g_vore_neighborprey_distance");\r
 131                         head.view_ofs_y = PL_PREY_VIEW_OFS_y + crandom() * cvar("g_vore_neighborprey_distance");\r
 132                         head.view_ofs_z = PL_PREY_VIEW_OFS_z;\r
 133                 }\r
 134         }\r
 135 }\r
 136 \r
 137 .float gurgle_oldstomachload;\r
 138 void Vore_GurgleSound()\r
 139 {\r
 140         if(time > self.gurglesound_finished || (self.gurgle_oldstomachload != self.stomach_load && !self.digesting))\r
 141         {\r
 142                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 143 \r
 144                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 145                 self.gurgle_oldstomachload = self.stomach_load;\r
 146         }\r
 147 }\r
 148 \r
 149 void Vore_AutoDigest(entity e)\r
 150 {\r
 151         // if the predator has the autodigest preference enabled, begin digesting new prey automatically\r
 152 \r
 153         if(!cvar("g_vore_digestion") || e.digesting)\r
 154                 return;\r
 155         if(clienttype(e) != CLIENTTYPE_REAL)\r
 156                 return; // this feature is only for players, not bots\r
 157         if(e.stomach_load)\r
 158                 return; // don't start digestion if we already ate someone, as that means we manually disabled it after the first prey and want it off\r
 159         if(Stomach_TeamMates_check(e))\r
 160                 return; // never begin automatic digestion if we've swallowed a team mate\r
 161 \r
 162         e.digesting = TRUE;\r
 163 }\r
 164 \r
 165 void Vore_StomachLoad_Apply()\r
 166 {\r
 167         // apply stomach weight that makes you heavier and larger the more you eat\r
 168         // slowing the player is done in cl_physics.qc\r
 169         if(self.classname != "player")\r
 170                 return;\r
 171 \r
 172         entity e;\r
 173         float prey_mass, final_load;\r
 174 \r
 175         // apply the stomach capacity of the predator\r
 176         self.stomach_maxload = cvar("g_balance_vore_load_pred_capacity");\r
 177         if(cvar("g_healthsize"))\r
 178                 self.stomach_maxload *= self.scale;\r
 179         self.stomach_maxload = ceil(self.stomach_maxload);\r
 180 \r
 181         FOR_EACH_PLAYER(e)\r
 182         {\r
 183                 if(e.predator == self)\r
 184                 {\r
 185                         if(self.cvar_cl_vore_autodigest > 1)\r
 186                                 Vore_AutoDigest(self);\r
 187                         prey_mass = cvar("g_balance_vore_load_prey_mass");\r
 188                         if(cvar("g_healthsize"))\r
 189                                 prey_mass *= e.scale;\r
 190                         final_load += ceil(prey_mass);\r
 191                 }\r
 192         }\r
 193         for(e = world; (e = find(e, classname, "consumable")); )\r
 194         {\r
 195                 if(e.predator == self)\r
 196                 {\r
 197                         if(self.cvar_cl_vore_autodigest > 0)\r
 198                                 Vore_AutoDigest(self);\r
 199                         final_load += ceil(e.dmg);\r
 200                 }\r
 201         }\r
 202         self.stomach_load = final_load;\r
 203 \r
 204         // apply weight\r
 205         self.gravity = 1 + (self.stomach_load / self.stomach_maxload) * cvar("g_balance_vore_load_pred_weight");\r
 206         if(!self.gravity && self.stomach_load)\r
 207                 self.gravity = 0.00001; // 0 becomes 1 for gravity, so do this to allow 0 gravity\r
 208 }\r
 209 \r
 210 .entity swallow_model;\r
 211 float Vore_SwallowModel_CustomizeEntityForClient()\r
 212 {\r
 213         // use the same system as the weapon model\r
 214 \r
 215         self.viewmodelforclient = self.owner;\r
 216         self.alpha = self.owner.cvar_cl_vore_swallowmodel;\r
 217 \r
 218         if(other.classname == "spectator")\r
 219         if(other.enemy == self.owner)\r
 220         {\r
 221                 self.viewmodelforclient = other;\r
 222                 self.alpha = other.cvar_cl_vore_swallowmodel;\r
 223         }\r
 224 \r
 225         return TRUE;\r
 226 }\r
 227 \r
 228 void Vore_SwallowModel_Think()\r
 229 {\r
 230         // update the position of the swallow model to match our swallow progress\r
 231         float dist;\r
 232         dist = (-0.5 + self.owner.swallow_progress_prey) * cvar("g_vore_swallowmodel_range"); // the model is centered at 0.5 progress\r
 233         if(cvar("g_healthsize"))\r
 234                 dist *= self.scale;\r
 235         self.view_ofs = '1 0 0' * dist;\r
 236 \r
 237         // if our swallow progress is gone or we are dead, the swallow model also goes away\r
 238         if(!self.owner.swallow_progress_prey || self.owner.deadflag != DEAD_NO || self.owner.classname != "player")\r
 239         {\r
 240                 remove(self.owner.swallow_model);\r
 241                 self.owner.swallow_model = world;\r
 242                 return;\r
 243         }\r
 244 \r
 245         // properties that should update whenever possible, but when the predator is not available\r
 246         self.nextthink = time;\r
 247 }\r
 248 \r
 249 void Vore_SwallowModel_Update(entity prey, entity pred)\r
 250 {\r
 251         // if we don't have a swallow model already, spawn one\r
 252         if(!prey.swallow_model)\r
 253         {\r
 254                 prey.swallow_model = spawn();\r
 255                 prey.swallow_model.movetype = MOVETYPE_FOLLOW;\r
 256                 prey.swallow_model.solid = SOLID_NOT;\r
 257                 //prey.swallow_model.effects |= EF_NOGUNBOB; // let it bob\r
 258                 prey.swallow_model.effects |= EF_NODEPTHTEST; // don't hide behind walls\r
 259                 prey.swallow_model.owner = prey;\r
 260                 prey.swallow_model.customizeentityforclient = Vore_SwallowModel_CustomizeEntityForClient;\r
 261                 prey.swallow_model.think = Vore_SwallowModel_Think;\r
 262                 prey.swallow_model.nextthink = time;\r
 263         }\r
 264 \r
 265         // properties that should update whenever possible, but when the predator is available\r
 266         string player_swallowmodel;\r
 267         player_swallowmodel = strcat(substring(pred.playermodel, 0, strlen(pred.playermodel) - 4), "_swallow.md3"); // 4 is the extension length\r
 268         if(prey.swallow_model.model != player_swallowmodel) // player model can be changed while the predator is active\r
 269                 setmodel(prey.swallow_model, player_swallowmodel);\r
 270         if(prey.swallow_model.skin != pred.skin) // player skin can be changed while the predator is active\r
 271                 prey.swallow_model.skin = pred.skin;\r
 272         if(cvar("g_healthsize"))\r
 273                 prey.swallow_model.scale = pred.scale / prey.scale; // player size difference\r
 274         if(prey.swallow_model.enemy != pred)\r
 275                 prey.swallow_model.enemy = pred; // enemy is the predator\r
 276         if(prey.swallow_model.colormap != pred.colormap)\r
 277                 prey.swallow_model.colormap = pred.colormap; // pants and shirt color\r
 278         if(prey.swallow_model.glowmod != pred.glowmod)\r
 279                 prey.swallow_model.glowmod = pred.glowmod; // glow color\r
 280 }\r
 281 \r
 282 .entity pusher;\r
 283 .float pushltime;\r
 284 void Vore_Swallow(entity e)\r
 285 {\r
 286         // this player is being swallowed by another player, apply the proper changes\r
 287 \r
 288         e.vore_oldmovetype = e.movetype;\r
 289         e.vore_oldsolid = e.solid;\r
 290         e.punchvector_z = cvar("g_balance_vore_swallow_prey_punchvector");\r
 291 \r
 292         e.predator = self;\r
 293         setorigin(e, e.predator.origin);\r
 294         e.velocity = '0 0 0';\r
 295         e.movetype = MOVETYPE_FOLLOW;\r
 296         e.solid = SOLID_NOT;\r
 297         e.aiment = e.predator; // follow the predator, automatically unset when regurgitated\r
 298 \r
 299         // drop keys (KH) and flags (CTF) when we get swallowed\r
 300         kh_Key_DropAll(e, FALSE);\r
 301         if(e.flagcarried)\r
 302                 DropFlag(e.flagcarried, world, e.predator);\r
 303 \r
 304         if(stov(cvar_string("g_vore_regurgitatecolor_color_normal")))\r
 305                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_normal"));\r
 306 \r
 307         if(teams_matter && e.team == e.predator.team)\r
 308         {\r
 309                 if(cvar("g_vore_kick"))\r
 310                         centerprint(e, "^3You have been swallowed by a team mate, don't kick!");\r
 311                 if(cvar("g_vore_digestion"))\r
 312                         centerprint(e.predator, "^3You have swallowed a team mate, don't digest!");\r
 313         }\r
 314 \r
 315         PlayerSound(e.predator, playersound_swallow, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 316         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 317         e.predator.punchangle_x -= cvar("g_balance_vore_swallow_predator_punchangle");\r
 318         e.predator.regurgitate_prepare = 0;\r
 319         e.predator.spawnshieldtime = 0; // lose spawn shield when we vore\r
 320         e.predator.hitsound += 1; // play this for team mates too, as we could be swallowing them to heal them\r
 321         Vore_SetPreyPositions(e.predator);\r
 322 \r
 323         // block firing for a small amount of time, or we'll be firing the next frame after we swallow\r
 324         e.predator.weapon_delay = time + button_delay_time;\r
 325         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 326         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 327         e.stomachkick_delay = time + cvar("g_balance_vore_kick_delay"); // don't kick immediately after being swallowed\r
 328 }\r
 329 \r
 330 void Vore_SwallowStep(entity e)\r
 331 {\r
 332         if(!cvar("g_balance_vore_swallow_speed_fill"))\r
 333         {\r
 334                 Vore_Swallow(e);\r
 335                 return;\r
 336         }\r
 337 \r
 338         Vore_SwallowModel_Update(e, self);\r
 339 \r
 340         // increase the progress value until it reaches 1, then swallow the player\r
 341         if(e.swallow_progress_prey < 1)\r
 342         {\r
 343                 float fill;\r
 344                 fill = cvar("g_balance_vore_swallow_speed_fill") * frametime;\r
 345                 if(cvar("g_healthsize") && cvar("g_balance_vore_swallow_speed_fill_scalediff")) // fill rate depends on predator size compared to prey size\r
 346                         fill *= pow(self.scale / e.scale, cvar("g_balance_vore_swallow_speed_fill_scalediff"));\r
 347                 if(cvar("g_balance_vore_swallow_speed_fill_stomachload") && e.stomach_load) // fill rate is influenced by the prey's stomach load\r
 348                         fill *= (1 - ((e.stomach_load / e.stomach_maxload) * bound(0, cvar("g_balance_vore_swallow_speed_fill_stomachload"), 1)));\r
 349 \r
 350                 e.swallow_progress_prey += fill;\r
 351         }\r
 352         else\r
 353         {\r
 354                 Vore_Swallow(e);\r
 355                 e.swallow_progress_prey = 0;\r
 356         }\r
 357 \r
 358         // the predator's progress is how much the prey got swallowed\r
 359         self.swallow_progress_pred = e.swallow_progress_prey;\r
 360 }\r
 361 \r
 362 void Vore_Regurgitate(entity e)\r
 363 {\r
 364         // this player is being regurgitated by their predator, apply the proper changes\r
 365 \r
 366         e.movetype = e.vore_oldmovetype;\r
 367         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 368                 e.solid = e.vore_oldsolid;\r
 369         e.view_ofs_z = PL_VIEW_OFS_z;\r
 370         e.punchvector_z = -cvar("g_balance_vore_regurgitate_prey_punchvector");\r
 371 \r
 372         // if the prey has been fully digested, silently detach them\r
 373         if(e.deadflag != DEAD_NO && e.health <= cvar("g_balance_vore_digestion_limit"))\r
 374         {\r
 375                 e.predator = world;\r
 376                 e.modelindex = 0; // hide the dead body\r
 377                 return;\r
 378         }\r
 379 \r
 380         // apply velocities\r
 381         makevectors(e.predator.v_angle);\r
 382         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 383         e.predator.velocity += -v_forward * cvar("g_balance_vore_regurgitate_predatorforce");\r
 384         e.pusher = e.predator; // allows us to frag players by regurgitating them in deadly pits\r
 385         e.pushltime = time + cvar("g_maxpushtime");\r
 386 \r
 387         // if the dead body of the prey is below gibbing health, gib it\r
 388         e.stat_eaten = 0; // necessary for gibs to show\r
 389         PlayerGib(e, e.predator);\r
 390 \r
 391         // regurgitated prey is given this amount of swallow progress, to simulate being more vulnerable\r
 392         if(cvar("g_balance_vore_swallow_speed_fill") && cvar("g_balance_vore_regurgitate_swallowprogress"))\r
 393         {\r
 394                 e.swallow_progress_prey = cvar("g_balance_vore_regurgitate_swallowprogress");\r
 395                 Vore_SwallowModel_Update(e, e.predator);\r
 396         }\r
 397 \r
 398         // apply regurgitation damage to the predator\r
 399         if(cvar("g_balance_vore_regurgitate_damage"))\r
 400         {\r
 401                 float regurgitate_dmg;\r
 402                 regurgitate_dmg = cvar("g_balance_vore_regurgitate_damage");\r
 403                 if(cvar("g_healthsize"))\r
 404                         regurgitate_dmg *= e.scale / e.predator.scale;\r
 405                 Damage(e.predator, e, e, regurgitate_dmg, DEATH_REGURGITATION, e.predator.origin, '0 0 0');\r
 406         }\r
 407 \r
 408         PlayerSound(e.predator, playersound_regurgitate, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 409         setanim(e.predator, e.predator.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing / regurgitating\r
 410         pointparticles(particleeffectnum("vore_regurgitate"), e.predator.origin, '0 0 0', 1);\r
 411         e.predator.punchangle_x += cvar("g_balance_vore_regurgitate_predator_punchangle");\r
 412         e.predator.regurgitate_prepare = 0;\r
 413         e.predator.action_delay = time + cvar("g_balance_vore_action_delay");\r
 414         Vore_SetPreyPositions(e.predator);\r
 415 \r
 416         // block firing for a small amount of time, or we'll be firing the next frame\r
 417         e.weapon_delay = time + button_delay_time;\r
 418         e.system_delay = e.predator.system_delay = time + system_delay_time;\r
 419         e.predator = world;\r
 420 }\r
 421 \r
 422 void Vore_Disconnect()\r
 423 {\r
 424         // frees prey from their predators when someone disconnects or goes spectating, or in other circumstances\r
 425 \r
 426         // prey disconnects or goes spectating while inside someone's belly\r
 427         if(self.stat_eaten)\r
 428                 Vore_Regurgitate(self);\r
 429 \r
 430         // pred disconnects or goes spectating with players in their belly\r
 431         entity head;\r
 432         FOR_EACH_PLAYER(head)\r
 433         {\r
 434                 if(head.predator == self)\r
 435                         Vore_Regurgitate(head);\r
 436         }\r
 437 \r
 438         self.stomach_load = self.gravity = 0; // prevents a bug\r
 439         Vore_GurgleSound(); // stop the gurgling sound\r
 440 }\r
 441 \r
 442 .float digestion_step;\r
 443 void Vore_Digest()\r
 444 {\r
 445         // apply digestion to prey\r
 446 \r
 447         if(self.predator.deadflag != DEAD_NO) // dead predators don't digest\r
 448         {\r
 449                 self.predator.digesting = FALSE;\r
 450                 return;\r
 451         }\r
 452         if(self.health <= cvar("g_balance_vore_digestion_limit")) // don't digest below this amount of health\r
 453                 return;\r
 454 \r
 455         if(time > self.digestion_step)\r
 456         {\r
 457                 // if distributed digestion is enabled, reduce digestion strength by the amount of prey in our stomach\r
 458                 float damage, damage_offset;\r
 459 \r
 460                 damage_offset = 1;\r
 461                 if(cvar("g_balance_vore_digestion_distribute")) // apply distributed digestion damage\r
 462                         damage_offset /= self.predator.stomach_load / self.predator.stomach_maxload;\r
 463                 if(cvar("g_healthsize") && cvar("g_balance_vore_digestion_scalediff")) // apply player scale to digestion damage\r
 464                         damage_offset *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_digestion_scalediff"));\r
 465 \r
 466                 damage = ceil(cvar("g_balance_vore_digestion_damage") / damage_offset);\r
 467                 if(cvar("g_balance_vore_digestion_damage_death") && self.deadflag != DEAD_NO) // amplify digestion damage for dead prey\r
 468                         damage *= cvar("g_balance_vore_digestion_damage_death");\r
 469 \r
 470                 Damage(self, self.predator, self.predator, damage, DEATH_DIGESTION, self.origin, '0 0 0');\r
 471                 if(cvar("g_balance_vore_digestion_vampire") && self.predator.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 472                 {\r
 473                         self.predator.health += damage * cvar("g_balance_vore_digestion_vampire");\r
 474                         self.predator.pauserothealth_finished = max(self.predator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));\r
 475                 }\r
 476 \r
 477                 self.digestion_step = time + vore_steptime;\r
 478         }\r
 479 \r
 480         if(stov(cvar_string("g_vore_regurgitatecolor_color_digest")))\r
 481                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_color_digest"));\r
 482 }\r
 483 \r
 484 .float teamheal_step;\r
 485 void Vore_Teamheal()\r
 486 {\r
 487         // apply teamheal\r
 488 \r
 489         if(self.deadflag != DEAD_NO)\r
 490                 return;\r
 491 \r
 492         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 493         if(time > self.teamheal_step)\r
 494         {\r
 495                 self.health += cvar("g_balance_vore_teamheal");\r
 496                 self.teamheal_step = time + vore_steptime;\r
 497 \r
 498                 // play beep sound when a team mate was healed to the maximum amount, to both the prey and the predator\r
 499                 if(self.health >= cvar("g_balance_vore_teamheal_stable"))\r
 500                 {\r
 501                         play2(self, "misc/beep.wav");\r
 502                         play2(self.predator, "misc/beep.wav");\r
 503                 }\r
 504         }\r
 505 }\r
 506 \r
 507 .float kick_pressed;\r
 508 void Vore_StomachKick()\r
 509 {\r
 510         // allows prey to kick the predator's stomach and do some damage or attempt to escape\r
 511 \r
 512         if(self.deadflag != DEAD_NO)\r
 513                 return;\r
 514 \r
 515         if(time > self.stomachkick_delay && !self.kick_pressed)\r
 516         {\r
 517                 float damage, vol;\r
 518                 vector force;\r
 519                 damage = cvar("g_balance_vore_kick_damage");\r
 520                 force = v_forward * cvar("g_balance_vore_kick_force");\r
 521                 vol = VOL_BASE;\r
 522 \r
 523                 // apply player scale to the damage / force of the kick\r
 524                 if(cvar("g_healthsize") && cvar("g_balance_vore_kick_scalediff"))\r
 525                 {\r
 526                         damage *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 527                         force *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff"));\r
 528                         vol *= pow(self.scale / self.predator.scale, cvar("g_balance_vore_kick_scalediff")); // kick sound volume based on the same scale\r
 529                 }\r
 530                 vol = bound(0, vol, 1);\r
 531 \r
 532                 Damage(self.predator, self, self, damage, DEATH_STOMACHKICK, self.predator.origin, force);\r
 533                 sound(self.predator, CHAN_PROJECTILE, strcat("weapons/hit", ftos(floor(random() * 8)), ".wav"), vol, ATTN_NORM);\r
 534                 self.predator.punchangle_x -= cvar("g_balance_vore_kick_predator_punchangle");\r
 535                 self.punchangle_x += cvar("g_balance_vore_kick_prey_punchangle");\r
 536 \r
 537                 // abort the predator's scheduled regurgitation\r
 538                 if(random() < cvar("g_balance_vore_kick_cutregurgitate"))\r
 539                         self.predator.regurgitate_prepare = 0;\r
 540 \r
 541                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 542                 if(cvar("g_balance_vore_kick_repress"))\r
 543                 if not(clienttype(self) == CLIENTTYPE_BOT) // not for bots, to prevent an issue\r
 544                         self.kick_pressed = TRUE;\r
 545         }\r
 546 }\r
 547 \r
 548 void Vore_StomachLeave()\r
 549 {\r
 550         // allows players to get out of their predator at will in some circumstances, such as team mates\r
 551 \r
 552         if(self.deadflag != DEAD_NO)\r
 553                 return;\r
 554 \r
 555         if(Vore_CanLeave())\r
 556                 Vore_Regurgitate(self);\r
 557         else if(time > self.complain_vore)\r
 558         {\r
 559                 play2(self, "misc/forbidden.wav");\r
 560                 sprint(self, strcat("You cannot get out of ", self.predator.netname, "\n"));\r
 561                 self.complain_vore = time + complain_delay_time;\r
 562         }\r
 563 }\r
 564 \r
 565 void Vore_AutoTaunt()\r
 566 {\r
 567         // triggers ambient vore taunts, for both pred and prey\r
 568 \r
 569         float taunt_time;\r
 570 \r
 571         // predator taunts\r
 572         if((self.swallow_progress_pred || (self.stomach_load && Stomach_HasLivePrey(self))) && !Stomach_TeamMates_check(self))\r
 573         {\r
 574                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 575                 {\r
 576                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 577                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPRED);\r
 578                 }\r
 579         }\r
 580         else if(self.taunt_soundtype == TAUNTTYPE_VOREPRED)\r
 581         {\r
 582                 // we have a predator taunt scheduled, but are no longer a (suitable) predator, so remove it\r
 583                 SetAutoTaunt(self, 0, 0);\r
 584         }\r
 585 \r
 586         // prey taunts\r
 587         if((self.swallow_progress_prey || (self.stat_eaten && !(teams_matter && self.team == self.predator.team))) && self.deadflag == DEAD_NO)\r
 588         {\r
 589                 if(!self.taunt_soundtime) // taunt_soundtime becomes 0 once the taunt has played\r
 590                 {\r
 591                         taunt_time = random() * (cvar("sv_vore_autotaunt_repeat_max") - cvar("sv_vore_autotaunt_repeat_min")) + cvar("sv_vore_autotaunt_repeat_min");\r
 592                         SetAutoTaunt(self, time + taunt_time, TAUNTTYPE_VOREPREY);\r
 593                 }\r
 594         }\r
 595         else if(self.taunt_soundtype == TAUNTTYPE_VOREPREY)\r
 596         {\r
 597                 // we have a prey taunt scheduled, but are no longer a (suitable) prey, so remove it\r
 598                 SetAutoTaunt(self, 0, 0);\r
 599         }\r
 600 }\r
 601 \r
 602 void Vore_SetSbarRings()\r
 603 {\r
 604         // first clear the ring stats, then configure them if needed\r
 605         self.stat_sbring1_type = self.stat_sbring1_clip = 0;\r
 606         self.stat_sbring2_type = self.stat_sbring2_clip = 0;\r
 607 \r
 608         if(self.stat_eaten)\r
 609         {\r
 610                 if(time <= self.stomachkick_delay)\r
 611                 {\r
 612                         self.stat_sbring1_type = 3; // ring shows stomach kick delay, empties with progress\r
 613                         self.stat_sbring1_clip = bound(0, (time / self.stomachkick_delay - 1) / ((self.stomachkick_delay - cvar("g_balance_vore_kick_delay")) / self.stomachkick_delay - 1), 1);\r
 614                 }\r
 615         }\r
 616         else\r
 617         {\r
 618                 if(self.swallow_progress_pred)\r
 619                 {\r
 620                         self.stat_sbring1_type = 1; // ring shows predator swallow progress, fills with progress\r
 621                         self.stat_sbring1_clip = bound(0, self.swallow_progress_pred, 1);\r
 622                 }\r
 623                 else if(time <= self.action_delay)\r
 624                 {\r
 625                         self.stat_sbring1_type = 2; // ring shows vore action delay, empties with progress\r
 626                         self.stat_sbring1_clip = bound(0, (time / self.action_delay - 1) / ((self.action_delay - cvar("g_balance_vore_action_delay")) / self.action_delay - 1), 1);\r
 627                 }\r
 628 \r
 629                 if(self.swallow_progress_prey)\r
 630                 {\r
 631                         self.stat_sbring2_type = 1; // ring shows prey swallow progress, fills with progress\r
 632                         self.stat_sbring2_clip = bound(0, self.swallow_progress_prey, 1);\r
 633                 }\r
 634                 else if(time <= self.regurgitate_prepare)\r
 635                 {\r
 636                         self.stat_sbring2_type = 2; // ring shows regurgitation preparing, fills with progress\r
 637                         self.stat_sbring2_clip = 1 - bound(0, (time / self.regurgitate_prepare - 1) / ((self.regurgitate_prepare - cvar("g_balance_vore_regurgitate_delay")) / self.regurgitate_prepare - 1), 1);\r
 638                 }\r
 639         }\r
 640 }\r
 641 \r
 642 .float regurgitatecolor_particles_tick;\r
 643 void Vore()\r
 644 {\r
 645         // main vore code, this is where it all happens\r
 646 \r
 647         Vore_AutoTaunt();\r
 648 \r
 649         if(!self.stat_eaten)\r
 650         if(self.modelindex) // not if we're a gibbed dead body or not visible any more\r
 651         if(self.colormod)\r
 652         if(self.colormod != '1 1 1')\r
 653         {\r
 654                 // slowly wash stomach fluids off players once they're out of the stomach\r
 655                 if(cvar("g_vore_regurgitatecolor_fade"))\r
 656                 if(self.deadflag == DEAD_NO) // not for dead bodies\r
 657                 {\r
 658                         float goo_fade;\r
 659                         goo_fade = cvar("g_vore_regurgitatecolor_fade") * frametime;\r
 660                         goo_fade *= 1 + self.waterlevel; // fade faster when underwater\r
 661 \r
 662                         self.colormod_x += goo_fade;\r
 663                         if(self.colormod_x > 1)\r
 664                                 self.colormod_x = 1;\r
 665                         self.colormod_y += goo_fade;\r
 666                         if(self.colormod_y > 1)\r
 667                                 self.colormod_y = 1;\r
 668                         self.colormod_z += goo_fade;\r
 669                         if(self.colormod_z > 1)\r
 670                                 self.colormod_z = 1;\r
 671                 }\r
 672 \r
 673                 // constant particles falling off dirty players\r
 674                 if(cvar("g_vore_regurgitatecolor_particles"))\r
 675                 if(self.regurgitatecolor_particles_tick < time)\r
 676                 {\r
 677                         pointparticles(particleeffectnum("vore_regurgitate_constant"), self.origin, '0 0 0', 1);\r
 678                         self.regurgitatecolor_particles_tick = time + cvar("g_vore_regurgitatecolor_particles") * vlen(self.colormod); // particle time depends on how dirty the player is\r
 679                 }\r
 680         }\r
 681 \r
 682         // set all vore stats\r
 683         Vore_SetSbarRings();\r
 684         if(self.predator.classname == "player")\r
 685         {\r
 686                 self.stat_stomachload = self.predator.stomach_load; // necessary for the stomach board\r
 687                 self.stat_stomachmaxload = self.predator.stomach_maxload; // necessary for the stomach board\r
 688                 self.stat_digesting = self.predator.digesting; // necessary for the stomach board\r
 689                 self.stat_eaten = num_for_edict(self.predator);\r
 690         }\r
 691         else\r
 692         {\r
 693                 self.stat_stomachload = self.stomach_load;\r
 694                 self.stat_stomachmaxload = self.stomach_maxload;\r
 695                 self.stat_digesting = self.digesting;\r
 696                 self.stat_eaten = 0;\r
 697         }\r
 698         self.stat_canleave = Vore_CanLeave();\r
 699 \r
 700         // don't allow a player inside a player inside another player :)\r
 701         // prevent this by checking if such has happened, and taking the proper measures\r
 702         // this code has a high priority and must not be stopped by any delay, so run it here\r
 703         if(self.predator.stat_eaten)\r
 704                 Vore_Regurgitate(self);\r
 705 \r
 706         // the swallow progress of prey and preds idly decrease by this amount\r
 707         if(cvar("g_balance_vore_swallow_speed_decrease"))\r
 708         {\r
 709                 if(self.swallow_progress_pred)\r
 710                 {\r
 711                         self.swallow_progress_pred -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 712                         if(self.swallow_progress_pred < 0)\r
 713                                 self.swallow_progress_pred = 0;\r
 714                 }\r
 715                 if(self.swallow_progress_prey)\r
 716                 {\r
 717                         self.swallow_progress_prey -= cvar("g_balance_vore_swallow_speed_decrease") * frametime;\r
 718                         if(self.swallow_progress_prey < 0)\r
 719                                 self.swallow_progress_prey = 0;\r
 720                 }\r
 721         }\r
 722 \r
 723         // set the predator's stomach load and capacity\r
 724         Vore_StomachLoad_Apply();\r
 725 \r
 726         // apply delays and skip the vore system under some circumstances\r
 727         if(!cvar("g_vore")) // the vore system is disabled\r
 728         {\r
 729                 Vore_Disconnect();\r
 730                 return;\r
 731         }\r
 732         if(time < game_starttime || (time < warmup && !inWarmupStage)) // don't allow vore before a round begins\r
 733         {\r
 734                 Vore_Disconnect();\r
 735                 return;\r
 736         }\r
 737         if(self.spectatee_status)\r
 738                 return;\r
 739         if(time < self.system_delay)\r
 740                 return;\r
 741 \r
 742 // --------------------------------\r
 743 // Code that addresses predators:\r
 744 // --------------------------------\r
 745 \r
 746         entity prey;\r
 747         prey = Swallow_player_check();\r
 748 \r
 749         // attempt to swallow our new prey if we pressed the attack button, and there's any in range\r
 750         self.stat_canswallow = 0;\r
 751         if(Swallow_condition_check(prey))\r
 752         {\r
 753                 // canswallow stat, used by the HUD\r
 754                 if(teams_matter && prey.team == self.team)\r
 755                         self.stat_canswallow = 2;\r
 756                 else\r
 757                         self.stat_canswallow = 1;\r
 758 \r
 759                 if(self.BUTTON_ATCK)\r
 760                         Vore_SwallowStep(prey);\r
 761         }\r
 762         else if(prey != world)\r
 763                 self.stat_canswallow = -1;\r
 764 \r
 765         // toggle digestion, if the player has someone in their stomach\r
 766         if(self.BUTTON_DIGEST && cvar("g_vore_digestion"))\r
 767         {\r
 768                 if(self.stomach_load)\r
 769                 {\r
 770                         if(time > self.digest_button_delay_time)\r
 771                         {\r
 772                                 self.digesting = !self.digesting;\r
 773                                 self.digest_button_delay_time = time + button_delay_time;\r
 774                         }\r
 775                 }\r
 776                 else if(time > self.complain_vore)\r
 777                 {\r
 778                         play2(self, "misc/forbidden.wav");\r
 779                         sprint(self, "There is nothing to digest\n");\r
 780                         self.complain_vore = time + complain_delay_time;\r
 781                 }\r
 782         }\r
 783         if(!self.stomach_load || !cvar("g_vore_digestion"))\r
 784                 self.digesting = FALSE;\r
 785 \r
 786         // predator wishes to regurgitate his prey\r
 787         if(self.BUTTON_REGURGITATE && time > self.action_delay)\r
 788         {\r
 789                 if(self.stomach_load)\r
 790                 {\r
 791                         if(time > self.regurgitate_button_delay_time)\r
 792                         {\r
 793                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 794                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_VOICE, VOICETYPE_PLAYERSOUND);\r
 795                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE); // looks good for preparing regurgitation\r
 796                                 self.regurgitate_button_delay_time = time + button_delay_time;\r
 797                         }\r
 798                 }\r
 799                 else if(time > self.complain_vore)\r
 800                 {\r
 801                         play2(self, "misc/forbidden.wav");\r
 802                         sprint(self, "There is nothing to regurgitate\n");\r
 803                         self.complain_vore = time + complain_delay_time;\r
 804                 }\r
 805         }\r
 806 \r
 807         if(self.stomach_load > self.stomach_maxload) // the predator got beyond his capacity after eating, so some prey must pop out\r
 808         {\r
 809                 self.regurgitate_prepare = -1;\r
 810                 return;\r
 811         }\r
 812         if(cvar("g_balance_vore_load_pred_speedcap") && self.stomach_load)\r
 813         if(vlen(self.velocity) >= cvar("g_balance_vore_load_pred_speedcap") / (self.stomach_load / self.stomach_maxload)) // predator's going too fast, gets sick and throws up\r
 814         {\r
 815                 self.regurgitate_prepare = -1;\r
 816                 return;\r
 817         }\r
 818 \r
 819         if (self.digesting && self.digestsound_finished < time)\r
 820         {\r
 821                 PlayerSound (self, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 822                 self.digestsound_finished = time + 0.5;\r
 823         }\r
 824         if(cvar("g_vore_gurglesound"))\r
 825                 Vore_GurgleSound();\r
 826 \r
 827 // --------------------------------\r
 828 // Code that addresses the prey:\r
 829 // --------------------------------\r
 830 \r
 831         if(!self.stat_eaten)\r
 832                 return;\r
 833 \r
 834         if(self.deadflag != DEAD_NO && self.health < cvar("g_balance_vore_digestion_limit")) // make sure health doesn't go below the limit\r
 835                 self.health = cvar("g_balance_vore_digestion_limit");\r
 836 \r
 837         // automatically regurgitate prey that has reached their digestion limit\r
 838         if(cvar("g_balance_vore_digestion_limit_regurgitate"))\r
 839         if(self.health <= cvar("g_balance_vore_digestion_limit"))\r
 840         {\r
 841                 Vore_Regurgitate(self);\r
 842                 return;\r
 843         }\r
 844 \r
 845         // do we stick around inside dead furries? x_x\r
 846         if(self.predator.deadflag != DEAD_NO)\r
 847         {\r
 848                 if(!cvar("g_balance_vore_deadpredator") || !self.predator.modelindex) // if the predator is gibbed, we are out\r
 849                 {\r
 850                         Vore_Regurgitate(self);\r
 851                         return;\r
 852                 }\r
 853                 if(self.predator.regurgitate_prepare) // abort scheduled regurgitation\r
 854                         self.predator.regurgitate_prepare = 0;\r
 855         }\r
 856 \r
 857         // apply delayed regurgitating if it was scheduled\r
 858         if(self.predator.regurgitate_prepare && time > self.predator.regurgitate_prepare)\r
 859         {\r
 860                 self.predator.regurgitate_prepare = 0;\r
 861                 self.predator.complain_vore = time + complain_delay_time; // prevent complaining the next frame if this empties our stomach\r
 862                 Vore_Regurgitate(self);\r
 863         }\r
 864 \r
 865         // execute digesting and team healing\r
 866         if(self.predator.digesting == TRUE)\r
 867                 Vore_Digest();\r
 868         if(teams_matter && self.team == self.predator.team)\r
 869         if(cvar("g_balance_vore_teamheal") && cvar("g_vore_teamvore"))\r
 870                 Vore_Teamheal();\r
 871 \r
 872         // execute prey commands\r
 873         if(self.BUTTON_ATCK)\r
 874         {\r
 875                 if(cvar("g_vore_kick"))\r
 876                         Vore_StomachKick();\r
 877         }\r
 878         else\r
 879                 self.kick_pressed = FALSE;\r
 880         if(self.BUTTON_JUMP)\r
 881                 Vore_StomachLeave();\r
 882 \r
 883         // Ugly workaround for a Keyhunt issue. Your team's key can still be given to you while in the stomach\r
 884         // (at round start), which is pretty ugly and wrong. So attempt to drop keys each frame for prey\r
 885         kh_Key_DropAll(self, FALSE);\r
 886 \r
 887         // always position camera at the center of the stomach, to reduce probability of the view poking out\r
 888         self.view_ofs_z = PL_PREY_VIEW_OFS_z * self.predator.scale;\r
 889 }