data/qcsrc/server/vore.qc

   1 .float regurgitate_prepare;\r
   2 .float system_delay, swallow_delay, digest_button_delay, regurgitate_button_delay;\r
   3 .float complain_swallow;\r
   4 const float complain_delay = 1;\r
   5 const float button_delay = 0.5;\r
   6 const float steptime = 0.1;\r
   7 const float system_delay_time = 0.1;\r
   8 \r
   9 .float vore_oldmovetype, vore_oldsolid, vore_oldstomachload;\r
  10 \r
  11 entity Swallow_distance_check()\r
  12 {\r
  13         // check if we can swallow a player instead of firing our weapon\r
  14         vector w_shotorg, w_shotdir;\r
  15         w_shotorg = self.origin + self.view_ofs;\r
  16         w_shotdir = v_forward;\r
  17 \r
  18         WarpZone_traceline_antilag(self, w_shotorg, w_shotorg + w_shotdir * cvar("g_balance_vore_swallow_range"), FALSE, self, ANTILAG_LATENCY(self));\r
  19         if(trace_fraction < 1)\r
  20         if(trace_ent.classname == "player")\r
  21                 return trace_ent;\r
  22         return world;\r
  23 }\r
  24 \r
  25 float Swallow_condition_check(entity prey)\r
  26 {\r
  27         // checks the necessary conditions for swallowing another player\r
  28         if(prey.classname == "player" && prey.eater.classname != "player" && prey.deadflag == DEAD_NO) // we can't swallow someone who's already in someone else's stomach\r
  29         if not(vlen(self.velocity) > cvar("g_balance_vore_regurgitate_velocitylimit"))\r
  30         if(self.eater.classname != "player") // we can't swallow players while inside someone's stomach ourselves\r
  31         {\r
  32                 if(self.stomach_load >= cvar("g_balance_vore_swallow_limit"))\r
  33                 {\r
  34                         if(time > self.complain_swallow)\r
  35                         {\r
  36                                 play2(self, "weapons/unavailable.wav");\r
  37                                 sprint(self, strcat("You cannot swallow more than ^2", cvar_string("g_balance_vore_swallow_limit"), "^7 players at a time\n"));\r
  38                                 self.complain_swallow = time + complain_delay;\r
  39                         }\r
  40                         return FALSE;\r
  41                 }\r
  42 \r
  43                 if(cvar("g_vore_biggergut"))\r
  44                 if(prey.stomach_load > self.stomach_load)\r
  45                 {\r
  46                         if(time > self.complain_swallow)\r
  47                         {\r
  48                                 play2(self, "weapons/unavailable.wav");\r
  49                                 sprint(self, "You cannot swallow someone with a bigger stomach than yours\n");\r
  50                                 self.complain_swallow = time + complain_delay;\r
  51                         }\r
  52                         return FALSE;\r
  53                 }\r
  54                 return TRUE;\r
  55         }\r
  56         return FALSE;\r
  57 }\r
  58 \r
  59 void Vore_Weight_apply(entity e)\r
  60 {\r
  61         // apply stomach weight that makes you heavier the more you eat\r
  62         // slowing the player is applied in cl_physics.qc\r
  63         if(e.stomach_load != e.vore_oldstomachload)\r
  64                 e.gravity += 1 + (e.stomach_load * cvar("g_balance_vore_weight_gravity") - e.vore_oldstomachload);\r
  65         if(e.gravity == 0)\r
  66                 e.gravity = 0.00001; // 0 becomes 1 for .gravity, so do this to allow 0 gravity\r
  67         e.vore_oldstomachload = e.stomach_load;\r
  68 }\r
  69 \r
  70 void Vore_Swallow(entity e)\r
  71 {\r
  72         // this player is beening swallowed by another player, apply the proper changes\r
  73         e.vore_oldmovetype = e.movetype;\r
  74         e.vore_oldsolid = e.solid;\r
  75 \r
  76         setorigin(e, e.eater.origin);\r
  77         e.velocity = '0 0 0';\r
  78         e.movetype = MOVETYPE_FOLLOW;\r
  79         e.solid = SOLID_NOT;\r
  80         e.alpha = -1; // best way of hiding / showing the eaten player\r
  81         e.aiment = e.eater; // follow the predator. Is automatically unset\r
  82         e.view_ofs_z /= 2; // best positioning for the stomach model\r
  83 \r
  84         // drop keys (KH) and flags (CTF) when we get swallowed\r
  85         kh_Key_DropAll(e, FALSE);\r
  86         if(e.flagcarried)\r
  87                 DropFlag(e.flagcarried, world, e.eater);\r
  88 \r
  89         if(stov(cvar_string("g_vore_regurgitatecolor_released")))\r
  90                 e.colormod = stov(cvar_string("g_vore_regurgitatecolor_released"));\r
  91 \r
  92         PlayerSound(e.eater, playersound_swallow, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
  93         setanim(e.eater, e.eater.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing \ regurgitating\r
  94         e.eater.stomach_load += 1;\r
  95         e.eater.regurgitate_prepare = 0;\r
  96         Vore_Weight_apply(e.eater);\r
  97 \r
  98         e.system_delay = e.eater.system_delay = time + system_delay_time;\r
  99 }\r
 100 \r
 101 void Vore_Regurgitate(entity e)\r
 102 {\r
 103         // this player is being released from their predator, apply the proper changes\r
 104         e.movetype = e.vore_oldmovetype;\r
 105         if(e.health > 0) // leave SOLID_NOT for dead bodies\r
 106                 e.solid = e.vore_oldsolid;\r
 107         e.alpha = default_player_alpha; // best way of hiding / showing the eaten player\r
 108         e.view_ofs_z *= 2; // best positioning for the stomach model\r
 109 \r
 110         // velocities\r
 111         local vector oldforward, oldright, oldup;\r
 112         oldforward = v_forward;\r
 113         oldright = v_right;\r
 114         oldup = v_up;\r
 115         makevectors(e.eater.v_angle);\r
 116         e.velocity = v_forward * cvar("g_balance_vore_regurgitate_force");\r
 117         e.eater.velocity += -v_forward * cvar("g_balance_vore_regurgitate_eaterforce");\r
 118         v_forward = oldforward;\r
 119         v_right = oldright;\r
 120         v_up = oldup;\r
 121 \r
 122         PlayerSound(e.eater, playersound_regurgitate, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 123         setanim(e.eater, e.eater.anim_pain1, FALSE, TRUE, TRUE); // looks good for swallowing \ regurgitating\r
 124         pointparticles(particleeffectnum("regurgitate"), e.eater.origin, '0 0 0', 1);\r
 125         e.eater.stomach_load -= 1;\r
 126         e.eater.regurgitate_prepare = 0;\r
 127         e.eater.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 128         Vore_Weight_apply(e.eater);\r
 129 \r
 130         e.system_delay = e.eater.system_delay = time + system_delay_time;\r
 131         e.eater = world;\r
 132 }\r
 133 \r
 134 void Vore_Gurglesound();\r
 135 void Vore_Disconnect()\r
 136 {\r
 137         // frees prey from their predators when someone disconnects or goes spectating\r
 138 \r
 139         // prey disconnects or goes spectating while inside someone's belly:\r
 140         if(self.eater.classname == "player")\r
 141         {\r
 142                 self.view_ofs_z += 25;\r
 143                 self.eater.stomach_load -= 1;\r
 144                 Vore_Weight_apply(self.eater);\r
 145                 self.eater = world;\r
 146         }\r
 147 \r
 148         // pred disconnects or goes spectating with players in their belly:\r
 149         else if(self.stomach_load > 0)\r
 150         {\r
 151                 entity head;\r
 152                 FOR_EACH_PLAYER(head)\r
 153                 {\r
 154                         if(head.eater == self)\r
 155                                 Vore_Regurgitate(head);\r
 156                 }\r
 157                 Vore_Gurglesound(); // stop the gurgling sound\r
 158         }\r
 159 }\r
 160 \r
 161 .float digestion_step;\r
 162 void Vore_Digest()\r
 163 {\r
 164         // apply digestion to prey\r
 165         if(time > self.eater.digestion_step + steptime)\r
 166         {\r
 167                 Damage(self, self.eater, self.eater, cvar("g_balance_vore_digestion_damage"), DEATH_DIGESTION, self.origin, '0 0 0');\r
 168                 if(cvar("g_balance_vore_digestion_vampire") && self.eater.health < cvar("g_balance_vore_digestion_vampire_stable"))\r
 169                         self.eater.health += cvar("g_balance_vore_digestion_vampire");\r
 170 \r
 171                 if (self.eater.digestsound_finished < time)\r
 172                 {\r
 173                         self.eater.digestsound_finished = time + 0.5;\r
 174                         PlayerSound (self.eater, playersound_digest, CHAN_PLAYER, VOICETYPE_PLAYERSOUND);\r
 175                 }\r
 176                 self.eater.digestion_step = time;\r
 177         }\r
 178 \r
 179         if(self.health <= 0)\r
 180         if(stov(cvar_string("g_vore_regurgitatecolor_digested")))\r
 181                 self.colormod = stov(cvar_string("g_vore_regurgitatecolor_digested"));\r
 182 }\r
 183 \r
 184 .float teamheal_step;\r
 185 void Vore_Teamheal()\r
 186 {\r
 187         if(cvar("g_balance_vore_teamheal") && self.health < cvar("g_balance_vore_teamheal_stable"))\r
 188         if(time > self.teamheal_step + steptime)\r
 189         {\r
 190                 self.health += cvar("g_balance_vore_teamheal");\r
 191                 self.teamheal_step = time;\r
 192         }\r
 193 }\r
 194 \r
 195 .float stomachkick_delay;\r
 196 void Vore_StomachKick()\r
 197 {\r
 198         // allows prey to kick the predator's stomach and do some damage / attempt to escape, or bring the predator's digestion upon their self when there's no other option\r
 199         if(self.eater.classname != "player")\r
 200                 return;\r
 201 \r
 202         // kick the predator's stomach and do damage, or escape if we are lucky\r
 203         if(self.BUTTON_ATCK)\r
 204         if(time > self.stomachkick_delay)\r
 205         {\r
 206                 float damage;\r
 207                 damage = ceil(random() * (cvar("g_balance_vore_kick_damage_max") - cvar("g_balance_vore_kick_damage_min")) + cvar("g_balance_vore_kick_damage_min"));\r
 208                 Damage(self.eater, self, self, damage, DEATH_STOMACHKICK, self.eater.origin, '0 0 0');\r
 209                 sound(self.eater, CHAN_PROJECTILE, "weapons/stomachkick.ogg", VOL_BASE, ATTN_NORM);\r
 210 \r
 211                 if(cvar("g_balance_vore_kick_escapeprobability") >= random())\r
 212                         Vore_Regurgitate(self);\r
 213 \r
 214                 self.stomachkick_delay = time + cvar("g_balance_vore_kick_delay");\r
 215         }\r
 216 \r
 217         // start the predator's digestion\r
 218         if(self.BUTTON_ATCK2)\r
 219         {\r
 220                 centerprint(self.eater, strcat(self.netname, " has triggered your digestion"));\r
 221                 self.eater.digesting = TRUE;\r
 222         }\r
 223 }\r
 224 \r
 225 .float gurglesound_finished, gurglesound_oldstomachload;\r
 226 void Vore_Gurglesound()\r
 227 {\r
 228         if(time > self.gurglesound_finished || self.gurglesound_oldstomachload != self.stomach_load)\r
 229         {\r
 230                 GlobalSound(self.playersound_gurgle, CHAN_TRIGGER, VOICETYPE_GURGLE);\r
 231 \r
 232                 self.gurglesound_finished = time + 11; // yes, hard coded sound length. I know it's bad but what can I do?\r
 233                 self.gurglesound_oldstomachload = self.stomach_load;\r
 234         }\r
 235 }\r
 236 \r
 237 void Vore()\r
 238 {\r
 239         // if we are free, show our stomach load on the HUD. Otherwise, show the predator's\r
 240         if(self.eater.classname == "player")\r
 241         {\r
 242                 self.stat_stomachload = self.eater.stomach_load;\r
 243                 self.stat_digesting = self.eater.digesting;\r
 244                 self.stat_eaten = num_for_edict(self.eater);\r
 245         }\r
 246         else\r
 247         {\r
 248                 self.stat_stomachload = self.stomach_load;\r
 249                 self.stat_digesting = self.digesting;\r
 250                 self.stat_eaten = 0;\r
 251         }\r
 252 \r
 253         // skip the vore system under some circumstances\r
 254         if(time < game_starttime)\r
 255         {\r
 256                 Vore_Disconnect();\r
 257                 return;\r
 258         }\r
 259         if(self.spectatee_status)\r
 260                 return;\r
 261         if(time < self.system_delay)\r
 262                 return;\r
 263 \r
 264 // --------------------------------\r
 265 // Code that addresses predators:\r
 266 // --------------------------------\r
 267 \r
 268         entity prey;\r
 269         prey = Swallow_distance_check();\r
 270 \r
 271         // attempt to swallow our new prey if there's any in range\r
 272         if(self.BUTTON_ATCK && !self.BUTTON_REGURGITATE && self.swallow_delay < time)\r
 273         if(Swallow_condition_check(prey))\r
 274         {\r
 275                 prey.eater = self;\r
 276                 Vore_Swallow(prey);\r
 277                 self.swallow_delay = time + cvar("g_balance_vore_swallow_delay");\r
 278 \r
 279                 if(self.team == prey.team && teamplay)\r
 280                         centerprint(self, "You have swallowed a team mate, use caution!");\r
 281 \r
 282                 // block firing for a small amount of time when voring, or we'll be firing the next frame after we swallow\r
 283                 self.weapon_delay = time + 0.25;\r
 284         }\r
 285 \r
 286         // start / stop digestion on command, if the player has someone in their stomach\r
 287         if(self.BUTTON_DIGEST)\r
 288         {\r
 289                 if(self.stomach_load)\r
 290                 {\r
 291                         if(time > self.digest_button_delay)\r
 292                         {\r
 293                                 self.digesting = !self.digesting;\r
 294                                 self.digest_button_delay = time + button_delay;\r
 295                         }\r
 296                 }\r
 297                 else if(time > self.complain_swallow)\r
 298                 {\r
 299                         play2(self, "weapons/unavailable.wav");\r
 300                         sprint(self, "There is nothing to digest\n");\r
 301                         self.complain_swallow = time + complain_delay;\r
 302                 }\r
 303         }\r
 304         if(!self.stomach_load)\r
 305                 self.digesting = FALSE;\r
 306 \r
 307         // release players from this player's stomach on command\r
 308         if(self.BUTTON_REGURGITATE)\r
 309         {\r
 310                 if(self.stomach_load)\r
 311                 {\r
 312                         if(time > self.regurgitate_button_delay)\r
 313                         {\r
 314                                 self.regurgitate_prepare = time + cvar("g_balance_vore_regurgitate_delay");\r
 315                                 PlayerSound(self, playersound_regurgitate_prepare, CHAN_PAIN, VOICETYPE_PLAYERSOUND);\r
 316                                 self.regurgitate_button_delay = time + button_delay;\r
 317                         }\r
 318                 }\r
 319                 else if(time > self.complain_swallow)\r
 320                 {\r
 321                         play2(self, "weapons/unavailable.wav");\r
 322                         sprint(self, "There is nothing to regurgitate\n");\r
 323                         self.complain_swallow = time + complain_delay;\r
 324                 }\r
 325         }\r
 326 \r
 327         if(cvar("g_vore_gurglesound"))\r
 328                 Vore_Gurglesound();\r
 329 \r
 330 // --------------------------------\r
 331 // Code that addresses the prey:\r
 332 // --------------------------------\r
 333 \r
 334         if(self.eater.classname != "player")\r
 335                 return;\r
 336 \r
 337         if(self.eater.deadflag || self.deadflag)\r
 338                 Vore_Regurgitate(self);\r
 339         else if(self.eater.eater.classname == "player") // don't allow a player inside a player inside another player :)\r
 340                 Vore_Regurgitate(self);\r
 341         else if(vlen(self.eater.velocity) > cvar("g_balance_vore_regurgitate_velocitylimit"))\r
 342                 Vore_Regurgitate(self);\r
 343 \r
 344         // apply delayed regurgitating\r
 345         if(self.eater.regurgitate_prepare && time > self.eater.regurgitate_prepare)\r
 346         {\r
 347                 self.eater.regurgitate_prepare = 0;\r
 348                 self.eater.complain_swallow = time + complain_delay;\r
 349                 Vore_Regurgitate(self);\r
 350         }\r
 351 \r
 352         if(self.eater.digesting == TRUE)\r
 353                 Vore_Digest();\r
 354         if(teams_matter && self.team == self.eater.team)\r
 355                 Vore_Teamheal();\r
 356 \r
 357         Vore_StomachKick();\r
 358 }