CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
   2 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
   3 project(NetRadiant C CXX)
   4
   5 option(BUILD_RADIANT "Build the GUI" ON)
   6 option(BUILD_TOOLS "Build the tools" ON)
   7 option(BUILD_CRUNCH "Build Crunch image support" OFF)
   8 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
   9 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  10 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  11
  12 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  13 if (BUILD_RADIANT OR BUILD_TOOLS)
  14     set(BUILD_BINARIES ON)
  15 endif ()
  16
  17 #-----------------------------------------------------------------------
  18 # Paths
  19 #-----------------------------------------------------------------------
  20
  21 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  22     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
  23 endif ()
  24
  25 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
  26 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
  27 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
  28 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
  29
  30 set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  31 set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  32 set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX} CACHE INTERNAL "...")
  33
  34 if (FHS_INSTALL)
  35     set(RADIANT_LIB_DIR ${CMAKE_INSTALL_PREFIX}/lib/${RADIANT_BASENAME})
  36     set(RADIANT_BIN_DIR ${CMAKE_INSTALL_PREFIX}/bin)
  37     set(RADIANT_DATA_DIR ${CMAKE_INSTALL_PREFIX}/share/${RADIANT_BASENAME})
  38 endif ()
  39
  40 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
  41
  42 #-----------------------------------------------------------------------
  43 # Version
  44 #-----------------------------------------------------------------------
  45
  46 # CMake 3.0+ would allow this in project()
  47 set(RADIANT_VERSION_MAJOR 1)
  48 set(RADIANT_VERSION_MINOR 5)
  49 set(RADIANT_VERSION_PATCH 0)
  50 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
  51
  52 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
  53
  54 find_package(Git REQUIRED)
  55
  56 execute_process(
  57      COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
  58      WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
  59      OUTPUT_VARIABLE GIT_VERSION
  60      OUTPUT_STRIP_TRAILING_WHITESPACE
  61 )
  62
  63 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
  64
  65 if (GIT_VERSION)
  66     set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
  67 endif ()
  68
  69 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
  70
  71 #-----------------------------------------------------------------------
  72 # Language standard
  73 #-----------------------------------------------------------------------
  74
  75 if (BUILD_BINARIES)
  76     set(CMAKE_CXX_STANDARD 11)
  77     set(CMAKE_CXX_STANDARD_REQUIRED ON)
  78     set(CMAKE_CXX_EXTENSIONS OFF)
  79
  80     if (CMAKE_VERSION VERSION_LESS "3.1")
  81         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
  82             include(CheckCXXCompilerFlag)
  83             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
  84             if (STD_CXX)
  85                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
  86             else ()
  87                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
  88             endif ()
  89         else ()
  90             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
  91         endif ()
  92     endif ()
  93 endif ()
  94
  95 #-----------------------------------------------------------------------
  96 # Flags
  97 #-----------------------------------------------------------------------
  98
  99 if (BUILD_BINARIES)
 100     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 101
 102     macro (addflags_c args)
 103         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 104     endmacro ()
 105
 106     macro (addflags_cxx args)
 107         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 108     endmacro ()
 109
 110     macro (addflags args)
 111         addflags_c("${args}")
 112         addflags_cxx("${args}")
 113     endmacro ()
 114
 115     addflags("-fno-strict-aliasing")
 116     if (NOT WIN32)
 117         addflags("-fvisibility=hidden")
 118     endif ()
 119
 120     if (USE_WERROR)
 121         addflags("-Werror")
 122         addflags("-pedantic-errors")
 123     endif ()
 124
 125     addflags("-Wall")
 126     addflags("-Wextra")
 127     addflags("-pedantic")
 128
 129     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 130
 131     addflags("-Wno-unused-function")
 132     addflags("-Wno-unused-variable")
 133     addflags("-Wno-unused-parameter")
 134
 135     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 136 endif ()
 137
 138 if (BUILD_RADIANT)
 139     set(GTK_TARGET 2 CACHE STRING "GTK target")
 140     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 141
 142     if (GTK_TARGET EQUAL 2 AND WIN32)
 143         add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 144     endif ()
 145 endif ()
 146
 147 #-----------------------------------------------------------------------
 148 # Defs
 149 #-----------------------------------------------------------------------
 150
 151 if (BUILD_BINARIES)
 152     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 153     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 154
 155     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 156         add_definitions(-D_DEBUG=1)
 157     endif ()
 158 endif ()
 159
 160 if (BUILD_RADIANT)
 161     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 162
 163     macro (disable_deprecated name gtk2only)
 164         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 165         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 166             add_definitions(-D${name}_DISABLE_DEPRECATED)
 167         endif ()
 168     endmacro ()
 169
 170     disable_deprecated(ATK 0)
 171     disable_deprecated(G 0)
 172     disable_deprecated(GDK 0)
 173     disable_deprecated(GDK_PIXBUF 0)
 174     disable_deprecated(GTK 1)
 175     disable_deprecated(PANGO 0)
 176 endif ()
 177
 178 if (BUILD_BINARIES)
 179     add_custom_target(binaries ALL)
 180
 181     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 182         link_directories(
 183             /usr/local/lib
 184         )
 185     endif ()
 186
 187     if (WIN32)
 188         add_definitions(
 189             -DWIN32=1
 190             -D_WIN32=1
 191         )
 192     else ()
 193         add_definitions(
 194             -DPOSIX=1
 195         )
 196     endif ()
 197 endif ()
 198
 199 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 200     set(XWINDOWS ON)
 201     find_package(X11 REQUIRED)
 202     include_directories(${X11_INCLUDE_DIR})
 203     add_definitions(-DXWINDOWS=1)
 204 endif ()
 205
 206 if (BUILD_BINARIES)
 207     include_directories("${PROJECT_SOURCE_DIR}/include")
 208     include_directories("${PROJECT_SOURCE_DIR}/libs")
 209
 210     if (WIN32 AND NOT CMAKE_CROSSCOMPILING)
 211         set(BUNDLE_LIBRARIES_DEFAULT ON)
 212     else ()
 213         set(BUNDLE_LIBRARIES_DEFAULT OFF)
 214     endif ()
 215
 216     option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
 217
 218     if (BUNDLE_LIBRARIES)
 219         add_subdirectory(bundle)
 220     endif ()
 221
 222     macro (copy_dlls target)
 223         if (BUNDLE_LIBRARIES)
 224             add_custom_command(TARGET ${target} POST_BUILD
 225                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 226                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 227                 VERBATIM
 228             )
 229             add_dependencies(bundle ${target})
 230         endif ()
 231     endmacro ()
 232 endif ()
 233
 234 #-----------------------------------------------------------------------
 235 # Libraries
 236 #-----------------------------------------------------------------------
 237
 238 if (BUILD_BINARIES)
 239     add_subdirectory(libs)
 240 endif ()
 241
 242 if (BUILD_RADIANT)
 243     add_subdirectory(include)
 244 endif ()
 245
 246 #-----------------------------------------------------------------------
 247 # Plugins
 248 #-----------------------------------------------------------------------
 249
 250 if (BUILD_RADIANT)
 251     add_subdirectory(contrib)
 252 endif ()
 253
 254 #-----------------------------------------------------------------------
 255 # Modules
 256 #-----------------------------------------------------------------------
 257
 258 if (BUILD_RADIANT)
 259     add_subdirectory(plugins)
 260 endif ()
 261
 262 #-----------------------------------------------------------------------
 263 # Radiant
 264 #-----------------------------------------------------------------------
 265
 266 if (BUILD_BINARIES)
 267     if (CMAKE_EXECUTABLE_SUFFIX)
 268         string(REGEX REPLACE "^[.]" "" RADIANT_EXECUTABLE ${CMAKE_EXECUTABLE_SUFFIX})
 269     endif ()
 270
 271     macro (radiant_tool name)
 272         add_dependencies(binaries ${name})
 273
 274         if (BUNDLE_LIBRARIES AND WIN32)
 275             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 276         else ()
 277             add_executable(${name} ${ARGN})
 278         endif ()
 279
 280         copy_dlls(${name})
 281
 282         install(
 283             TARGETS ${name}
 284             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 285         )
 286     endmacro ()
 287
 288     if (BUILD_RADIANT)
 289         add_subdirectory(radiant)
 290         set_target_properties(${RADIANT_BASENAME} PROPERTIES
 291         COMPILE_DEFINITIONS RADIANT_EXECUTABLE="${RADIANT_EXECUTABLE}"
 292     )
 293     endif ()
 294 endif ()
 295
 296 #-----------------------------------------------------------------------
 297 # Tools
 298 #-----------------------------------------------------------------------
 299
 300 if (BUILD_TOOLS)
 301     add_subdirectory(tools)
 302
 303     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 304
 305     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 306         # Copy data files from sources to the build directory
 307         message(STATUS "Copying data files")
 308         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 309     endif ()
 310 endif ()
 311
 312 #-----------------------------------------------------------------------
 313 # Game packs
 314 #-----------------------------------------------------------------------
 315
 316 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 317 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 318
 319 if (DOWNLOAD_GAMEPACKS)
 320     add_custom_target(gamepacks ALL
 321        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 322        COMMENT "Downloading game packs"
 323     )
 324 endif ()
 325
 326 #-----------------------------------------------------------------------
 327 # Install
 328 #-----------------------------------------------------------------------
 329
 330 if (BUILD_BINARIES)
 331     install(DIRECTORY
 332         setup/data/tools/base
 333         setup/data/tools/bitmaps
 334         setup/data/tools/gl
 335         setup/data/tools/plugins
 336         docs
 337         DESTINATION ${RADIANT_DATA_DIR}
 338     )
 339 endif ()
 340
 341 if (DOWNLOAD_GAMEPACKS)
 342     if (FHS_INSTALL)
 343        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/share/netradiant")
 344     else ()
 345        set(GAME_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
 346     endif ()
 347
 348     install(DIRECTORY
 349         ${PROJECT_BINARY_DIR}/gamepacks
 350         DESTINATION ${RADIANT_DATA_DIR}
 351     )
 352 endif ()
 353
 354 if(BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 355     install(FILES
 356         ${PROJECT_SOURCE_DIR}/icons/netradiant.png
 357         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/pixmaps
 358     )
 359     install(FILES
 360         ${PROJECT_SOURCE_DIR}/icons/netradiant.desktop
 361         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/applications
 362     )
 363     install(FILES
 364         ${PROJECT_SOURCE_DIR}/icons/mime/map.xml
 365         DESTINATION ${CMAKE_INSTALL_PREFIX}/share/mime/model
 366     )
 367 endif ()
 368
 369 include(cmake/scripts/package.cmake)