CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
   2
   3 project(NetRadiant C CXX)
   4
   5 #-----------------------------------------------------------------------
   6 # Builtins: configuration
   7 #-----------------------------------------------------------------------
   8
   9 set(BUILTINS_INSTALL_DIR "${CMAKE_BINARY_DIR}/builtins")
  10 set(BUILTINS_INCLUDE_DIR "${BUILTINS_INSTALL_DIR}/include")
  11 set(BUILTINS_LIB_DIR "${BUILTINS_INSTALL_DIR}/lib")
  12 set(BUILTINS_PKGCONFIG_DIR "${BUILTINS_INSTALL_DIR}/lib/pkgconfig")
  13
  14 option(BUILTIN_GTKGLEXT "Builtin GtkGLExt" OFF)
  15 option(BUILTIN_GTKTHEME_MOJAVE "Builtin Mojave GTK theme" OFF)
  16
  17 if (APPLE)
  18     set(BUILTIN_GTKGLEXT ON)
  19     set(BUILTIN_GTKTHEME_MOJAVE ON)
  20 endif ()
  21
  22 set(BUILTIN_GTKGLEXT_BUILT OFF CACHE INTERNAL "...")
  23 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}/gtkglext-1.0.pc")
  24     set(BUILTIN_GTKGLEXT_BUILT ON)
  25 endif ()
  26
  27 if (EXISTS "${BUILTINS_INCLUDE_DIR}")
  28     include_directories("${BUILTINS_INCLUDE_DIR}")
  29 endif ()
  30
  31 if (EXISTS "${BUILTINS_LIB_DIR}")
  32     set(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}:${BUILTINS_LIB_DIR}")
  33     link_directories("${BUILTINS_LIB_DIR}")
  34 endif ()
  35
  36 if (EXISTS "${BUILTINS_PKGCONFIG_DIR}")
  37     set(ENV{PKG_CONFIG_PATH} "$ENV{PKG_CONFIG_PATH}:${BUILTINS_PKGCONFIG_DIR}")
  38 endif ()
  39
  40 #-----------------------------------------------------------------------
  41 # CMake modules
  42 #-----------------------------------------------------------------------
  43
  44 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/cmake")
  45
  46 #-----------------------------------------------------------------------
  47 # Submodules
  48 #-----------------------------------------------------------------------
  49
  50 if (EXISTS "${PROJECT_SOURCE_DIR}/libs/crunch/inc/crn_decomp.h")
  51     set(DEFAULT_BUILD_CRUNCH ON CACHE INTERNAL "...")
  52 else ()
  53     set(DEFAULT_BUILD_CRUNCH OFF CACHE INTERNAL "...")
  54 endif ()
  55
  56 if (EXISTS "${PROJECT_SOURCE_DIR}/tools/unvanquished/daemonmap/tools/quake3/q3map2/main.c")
  57     set(DEFAULT_BUILD_DAEMONMAP ON CACHE INTERNAL "...")
  58 else ()
  59     set(DEFAULT_BUILD_DAEMONMAP OFF CACHE INTERNAL "...")
  60 endif ()
  61
  62 #-----------------------------------------------------------------------
  63 # Build options
  64 #-----------------------------------------------------------------------
  65
  66 option(BUILD_RADIANT "Build the GUI" ON)
  67 option(BUILD_TOOLS "Build the tools" ON)
  68 option(BUILD_CRUNCH "Build Crunch image support" ${DEFAULT_BUILD_CRUNCH})
  69 option(BUILD_DAEMONMAP "Build daemonmap navigation mesh generator" ${DEFAULT_BUILD_DAEMONMAP})
  70 option(DOWNLOAD_GAMEPACKS "Download game packs" ON)
  71 option(USE_WERROR "Build with -Werror -pedantic-errors" OFF)
  72 option(FHS_INSTALL "Install according to Filesystem Hierarchy Standard" OFF)
  73
  74 set(BUILD_BINARIES OFF CACHE INTERNAL "...")
  75 if (BUILD_RADIANT OR BUILD_TOOLS)
  76     set(BUILD_BINARIES ON)
  77 endif ()
  78
  79 if (BUILD_BINARIES)
  80     if (WIN32 OR APPLE
  81         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux"
  82         OR "${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD" )
  83         set(BUNDLING_SUPPORTED ON)
  84     endif()
  85
  86     if (BUNDLING_SUPPORTED)
  87         if(WIN32 AND NOT CMAKE_CROSSCOMPILING)
  88             set(BUNDLE_LIBRARIES_DEFAULT ON)
  89         else ()
  90             set(BUNDLE_LIBRARIES_DEFAULT OFF)
  91         endif ()
  92
  93         option(BUNDLE_LIBRARIES "Bundle libraries" ${BUNDLE_LIBRARIES_DEFAULT})
  94     endif ()
  95
  96     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
  97         set(FHS_INSTALL OFF CACHE PATH "Disabled because of BUNDLE_LIBRARIES" FORCE)
  98     endif ()
  99 endif ()
 100
 101 #-----------------------------------------------------------------------
 102 # Paths
 103 #-----------------------------------------------------------------------
 104
 105 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 106     set(CMAKE_INSTALL_PREFIX "${PROJECT_SOURCE_DIR}/install" CACHE PATH "..." FORCE)
 107 endif ()
 108
 109 if (APPLE)
 110     set(APPLE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX}/NetRadiant.app)
 111     set(FINAL_INSTALL_PREFIX ${APPLE_INSTALL_PREFIX}/Contents/Prefix)
 112 else ()
 113     set(FINAL_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX})
 114 endif ()
 115
 116 set(RADIANT_NAME "NetRadiant" CACHE INTERNAL "...")
 117 add_definitions(-DRADIANT_NAME="${RADIANT_NAME}")
 118 set(RADIANT_BASENAME "netradiant" CACHE INTERNAL "...")
 119 add_definitions(-DRADIANT_BASENAME="${RADIANT_BASENAME}")
 120
 121 set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 122 set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib CACHE INTERNAL "...")
 123 set(RADIANT_ADDONS_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 124 set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc CACHE INTERNAL "...")
 125 set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share CACHE INTERNAL "...")
 126 set(RADIANT_DATA_DIR ${FINAL_INSTALL_PREFIX} CACHE INTERNAL "...")
 127
 128 if (FHS_INSTALL AND NOT BUNDLE_LIBRARIES)
 129     set(RADIANT_BIN_DIR ${FINAL_INSTALL_PREFIX}/bin)
 130     set(RADIANT_LIB_DIR ${FINAL_INSTALL_PREFIX}/lib)
 131     set(RADIANT_ADDONS_DIR ${RADIANT_LIB_DIR}/${RADIANT_BASENAME})
 132     set(RADIANT_ETC_DIR ${FINAL_INSTALL_PREFIX}/etc)
 133     set(RADIANT_SHARE_DIR ${FINAL_INSTALL_PREFIX}/share)
 134     set(RADIANT_DATA_DIR ${RADIANT_SHARE_DIR}/${RADIANT_BASENAME})
 135 endif ()
 136
 137 set(GAMEPACKS_DOWNLOAD_DIR ${PROJECT_BINARY_DIR}/download CACHE PATH "Where to store downloaded game packs")
 138
 139 #-----------------------------------------------------------------------
 140 # Version
 141 #-----------------------------------------------------------------------
 142
 143 # CMake 3.0+ would allow this in project()
 144 set(RADIANT_VERSION_MAJOR 1)
 145 set(RADIANT_VERSION_MINOR 5)
 146 set(RADIANT_VERSION_PATCH 0)
 147 set(RADIANT_VERSION "${RADIANT_VERSION_MAJOR}.${RADIANT_VERSION_MINOR}.${RADIANT_VERSION_PATCH}")
 148
 149 set(RADIANT_ABOUTMSG "Custom build" CACHE STRING "About message")
 150
 151 set(RADIANT_VERSION_STRING "${RADIANT_VERSION}n")
 152
 153 if (NOT DEFINED GIT_VERSION)
 154      find_package(Git REQUIRED)
 155
 156      execute_process(
 157           COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 158           WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
 159           OUTPUT_VARIABLE GIT_VERSION
 160           OUTPUT_STRIP_TRAILING_WHITESPACE
 161      )
 162
 163      if (GIT_VERSION)
 164          set(RADIANT_VERSION_STRING "${RADIANT_VERSION_STRING}-git-${GIT_VERSION}")
 165      endif ()
 166 endif ()
 167
 168 message(STATUS "Building ${PROJECT_NAME} ${RADIANT_VERSION_STRING} ${RADIANT_ABOUTMSG}")
 169
 170 #-----------------------------------------------------------------------
 171 # Language standard
 172 #-----------------------------------------------------------------------
 173
 174 if (BUILD_BINARIES)
 175     set(CMAKE_CXX_STANDARD 11)
 176     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 177     set(CMAKE_CXX_EXTENSIONS OFF)
 178
 179     if (CMAKE_VERSION VERSION_LESS "3.1")
 180         if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" OR CMAKE_COMPILER_IS_GNUCXX)
 181             include(CheckCXXCompilerFlag)
 182             check_cxx_compiler_flag(--std=c++${CMAKE_CXX_STANDARD} STD_CXX)
 183             if (STD_CXX)
 184                 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} --std=c++${CMAKE_CXX_STANDARD}")
 185             else ()
 186                 message(SEND_ERROR "Requires C++${CMAKE_CXX_STANDARD} or better")
 187             endif ()
 188         else ()
 189             message(WARNING "Unrecognized compiler: ${CMAKE_CXX_COMPILER_ID}, make sure it supports C++${CMAKE_CXX_STANDARD}")
 190         endif ()
 191     endif ()
 192 endif ()
 193
 194 #-----------------------------------------------------------------------
 195 # Flags
 196 #-----------------------------------------------------------------------
 197
 198 if (BUILD_BINARIES)
 199     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 200
 201     macro (addflags_c args)
 202         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${args}")
 203     endmacro ()
 204
 205     macro (addflags_cxx args)
 206         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${args}")
 207     endmacro ()
 208
 209     macro (addflags args)
 210         addflags_c("${args}")
 211         addflags_cxx("${args}")
 212     endmacro ()
 213
 214     addflags("-fno-strict-aliasing")
 215     if (NOT WIN32)
 216         addflags("-fvisibility=hidden")
 217     endif ()
 218
 219     if (USE_WERROR)
 220         addflags("-Werror")
 221         addflags("-pedantic-errors")
 222     endif ()
 223
 224     addflags("-Wall")
 225     addflags("-Wextra")
 226     addflags("-pedantic")
 227
 228     addflags_c("-Wno-deprecated-declarations") # vfs.c: g_strdown
 229
 230     addflags("-Wno-unused-function")
 231     addflags("-Wno-unused-variable")
 232     addflags("-Wno-unused-parameter")
 233
 234     if (APPLE)
 235         add_definitions(-DGL_SILENCE_DEPRECATION=1)
 236     endif()
 237
 238     set(CMAKE_POSITION_INDEPENDENT_CODE 1)
 239 endif ()
 240
 241 if (BUILD_RADIANT)
 242     set(GTK_TARGET 2 CACHE STRING "GTK target")
 243     add_definitions(-DGTK_TARGET=${GTK_TARGET})
 244
 245     if (WIN32)
 246         add_definitions(-DWORKAROUND_WINDOWS_FLOATING_WINDOW=1)
 247
 248         if (GTK_TARGET EQUAL 2)
 249             add_definitions(-DWORKAROUND_WINDOWS_GTK2_GLWIDGET=1)
 250         endif ()
 251     endif ()
 252
 253     if (APPLE)
 254         if (GTK_TARGET EQUAL 2)
 255             add_definitions(-DWORKAROUND_MACOS_GTK2_DESTROY=1)
 256             add_definitions(-DWORKAROUND_MACOS_GTK2_GLWIDGET=1)
 257             add_definitions(-DWORKAROUND_MACOS_GTK2_LAGGYPOINTER=1)
 258         endif ()
 259     endif ()
 260 endif ()
 261
 262 #-----------------------------------------------------------------------
 263 # Defs
 264 #-----------------------------------------------------------------------
 265
 266 if (BUILD_BINARIES)
 267     add_definitions(-DRADIANT_VERSION="${RADIANT_VERSION}")
 268     add_definitions(-DRADIANT_VERSION_STRING="${RADIANT_VERSION_STRING}")
 269
 270     if (NOT CMAKE_BUILD_TYPE MATCHES Release)
 271         add_definitions(-D_DEBUG=1)
 272     endif ()
 273 endif ()
 274
 275 if (BUILD_RADIANT)
 276     add_definitions(-DRADIANT_ABOUTMSG="${RADIANT_ABOUTMSG}")
 277
 278     macro (disable_deprecated name gtk2only)
 279         add_definitions(-D${name}_DISABLE_SINGLE_INCLUDES)
 280         if ((${gtk2only} EQUAL 0) OR (GTK_TARGET EQUAL 2))
 281             add_definitions(-D${name}_DISABLE_DEPRECATED)
 282         endif ()
 283     endmacro ()
 284
 285     disable_deprecated(ATK 0)
 286     disable_deprecated(G 0)
 287     disable_deprecated(GDK 0)
 288     disable_deprecated(GDK_PIXBUF 0)
 289     disable_deprecated(GTK 1)
 290     disable_deprecated(PANGO 0)
 291 endif ()
 292
 293 if (BUILD_BINARIES)
 294     add_custom_target(binaries ALL)
 295
 296     if(APPLE OR ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD")
 297         link_directories(
 298             /usr/local/lib
 299         )
 300     endif ()
 301
 302     if (WIN32)
 303         add_definitions(
 304             -DWIN32=1
 305             -D_WIN32=1
 306         )
 307     else ()
 308         add_definitions(
 309             -DPOSIX=1
 310         )
 311     endif ()
 312 endif ()
 313
 314 if (BUILD_RADIANT AND NOT APPLE AND NOT WIN32)
 315     set(XWINDOWS ON)
 316     find_package(X11 REQUIRED)
 317     include_directories(${X11_INCLUDE_DIR})
 318     add_definitions(-DXWINDOWS=1)
 319 endif ()
 320
 321 if (BUILD_BINARIES)
 322     include_directories("${PROJECT_SOURCE_DIR}/include")
 323     include_directories("${PROJECT_SOURCE_DIR}/libs")
 324
 325     macro (copy_dlls target)
 326         if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 327             add_custom_command(TARGET ${target} POST_BUILD
 328                 COMMAND "${PROJECT_SOURCE_DIR}/library-bundler"
 329                 "register" "${PROJECT_BINARY_DIR}" "$<TARGET_FILE:${target}>"
 330                 VERBATIM
 331             )
 332             add_dependencies(bundle ${target})
 333         endif ()
 334     endmacro ()
 335 endif ()
 336
 337 #-----------------------------------------------------------------------
 338 # Bundle
 339 #-----------------------------------------------------------------------
 340
 341 if (BUILD_BINARIES)
 342     if (BUNDLE_LIBRARIES AND BUNDLING_SUPPORTED)
 343         add_subdirectory(bundle)
 344     endif ()
 345 endif ()
 346
 347 #-----------------------------------------------------------------------
 348 # Builtins: targets
 349 #-----------------------------------------------------------------------
 350
 351 add_custom_target(builtins)
 352
 353 if (BUILTIN_GTKGLEXT OR BUILTIN_GTKTHEME_MOJAVE)
 354     include(${CMAKE_ROOT}/Modules/ExternalProject.cmake)
 355 endif ()
 356
 357 if (BUILTIN_GTKGLEXT)
 358     set(GTKGLEXT_PKGNAMES "gdk-2.0 gtk+-2.0 glib-2.0")
 359
 360     if (NOT APPLE)
 361         set(GTKGLEXT_PKGNAMES "${GTKGLEXT_PKGNAMES} gl")
 362     endif ()
 363
 364     execute_process(COMMAND pkg-config --libs ${GTKGLEXT_PKGNAMES}
 365         OUTPUT_VARIABLE GTKGLEXT_LDFLAGS
 366         OUTPUT_STRIP_TRAILING_WHITESPACE
 367     )
 368
 369     set(GTKGLEXT_LDFLAGS "$ENV{LDFLAGS} -lm ${GTKGLEXT_LDFLAGS}")
 370
 371     execute_process(COMMAND pkg-config --cflags ${GTKGLEXT_PKGNAMES}
 372         OUTPUT_VARIABLE GTKGLEXT_CFLAGS
 373         OUTPUT_STRIP_TRAILING_WHITESPACE
 374     )
 375
 376     set(GTKGLEXT_CFLAGS "$ENV{CFLAGS} ${GTKGLEXT_CFLAGS}")
 377
 378
 379     set(CONFIGURE_OPTIONS --disable-gtk-doc --disable-gtk-doc-html --disable-gtk-doc-pdf --disable-dependency-tracking --without-x)
 380
 381     if (CMAKE_BUILD_TYPE MATCHES Release)
 382         set(CONFIGURE_OPTIONS ${CONFIGURE_OPTIONS} --disable-debug)
 383     endif ()
 384
 385     if (APPLE)
 386         set(GTKGLEXT_GIT_TAG macos)
 387     else ()
 388         set(GTKGLEXT_GIT_TAG fixes)
 389     endif ()
 390
 391     if (APPLE)
 392         set(GTKGLEXT_CFLAGS "${GTKGLEXT_CFLAGS} -DGL_SILENCE_DEPRECATION=1 -Wno-deprecated-declarations")
 393     endif ()
 394
 395     ExternalProject_Add(gtkglext
 396         GIT_REPOSITORY https://gitlab.gnome.org/illwieckz/gtkglext.git
 397         GIT_TAG ${GTKGLEXT_GIT_TAG}
 398         BUILD_IN_SOURCE ON
 399         CONFIGURE_COMMAND export CCFLAGS=${GTKGLEXT_CFLAGS}
 400         CONFIGURE_COMMAND && export LDFLAGS=${GTKGLEXT_LDFLAGS}
 401         CONFIGURE_COMMAND && export NOCONFIGURE=1
 402         CONFIGURE_COMMAND && ./autogen.sh
 403         CONFIGURE_COMMAND && ./configure --prefix "${BUILTINS_INSTALL_DIR}" ${CONFIGURE_OPTIONS}
 404         BUILD_COMMAND $(MAKE)
 405         BUILD_COMMAND CFLAGS=${GTKGLEXT_CFLAGS}
 406         BUILD_COMMAND LDFLAGS=${GTKGLEXT_LDFLAGS}
 407         INSTALL_COMMAND $(MAKE) install
 408     )
 409
 410     include_directories("${BUILTINS_INCLUDE_DIR}/gtkglext-1.0")
 411     include_directories("${BUILTINS_LIB_DIR}/gtkglext-1.0/include")
 412
 413     add_dependencies(builtins gtkglext)
 414     set_target_properties(gtkglext PROPERTIES EXCLUDE_FROM_ALL ON)
 415 endif ()
 416
 417 if (BUNDLE_LIBRARIES)
 418     # It was required to tell cmake to not patch rpath on macos builtins.
 419     # It was also required to tell cmake to not patch rpath on freebsd binaries.
 420     # Patching rpath is done in library_bundler instead so we can skip this
 421     # step entirely when bundling.
 422     set(CMAKE_SKIP_RPATH ON)
 423 endif()
 424
 425 if (BUILTIN_GTKTHEME_MOJAVE)
 426     ExternalProject_Add(gtktheme-mojave
 427         GIT_REPOSITORY https://github.com/vinceliuice/Mojave-gtk-theme.git
 428         GIT_TAG master
 429         BUILD_IN_SOURCE ON
 430         CONFIGURE_COMMAND echo
 431         BUILD_COMMAND echo
 432         INSTALL_COMMAND ./install.sh -o standard -a standard -s standard -i standard -d "${PROJECT_BINARY_DIR}/themes"
 433     )
 434     add_dependencies(builtins gtktheme-mojave)
 435     set_target_properties(gtktheme-mojave PROPERTIES EXCLUDE_FROM_ALL ON)
 436 endif ()
 437
 438 #-----------------------------------------------------------------------
 439 # Libraries
 440 #-----------------------------------------------------------------------
 441
 442 if (BUILD_BINARIES)
 443     add_subdirectory(libs)
 444 endif ()
 445
 446 if (BUILD_RADIANT)
 447     add_subdirectory(include)
 448 endif ()
 449
 450 #-----------------------------------------------------------------------
 451 # Plugins
 452 #-----------------------------------------------------------------------
 453
 454 if (BUILD_RADIANT)
 455     add_subdirectory(contrib)
 456 endif ()
 457
 458 #-----------------------------------------------------------------------
 459 # Modules
 460 #-----------------------------------------------------------------------
 461
 462 if (BUILD_RADIANT)
 463     add_subdirectory(plugins)
 464 endif ()
 465
 466 #-----------------------------------------------------------------------
 467 # Radiant
 468 #-----------------------------------------------------------------------
 469
 470 if (BUILD_BINARIES)
 471     macro (radiant_tool name)
 472         add_dependencies(binaries ${name})
 473
 474         if (WIN32)
 475             add_executable(${name} ${ARGN} ${PROJECT_SOURCE_DIR}/include/lib.rc)
 476         else ()
 477             add_executable(${name} ${ARGN})
 478         endif()
 479
 480         copy_dlls(${name})
 481
 482         install(
 483             TARGETS ${name}
 484             RUNTIME DESTINATION ${RADIANT_BIN_DIR}
 485         )
 486     endmacro ()
 487
 488     if (BUILD_RADIANT)
 489         add_subdirectory(radiant)
 490     endif ()
 491 endif ()
 492
 493 #-----------------------------------------------------------------------
 494 # Tools
 495 #-----------------------------------------------------------------------
 496
 497 if (BUILD_TOOLS)
 498     add_subdirectory(tools)
 499
 500     file(GLOB DATA_FILES "${PROJECT_SOURCE_DIR}/setup/data/tools/*")
 501
 502     if (NOT (PROJECT_SOURCE_DIR STREQUAL PROJECT_BINARY_DIR))
 503         # Copy data files from sources to the build directory
 504         message(STATUS "Copying data files")
 505         file(COPY ${DATA_FILES} DESTINATION "${PROJECT_BINARY_DIR}")
 506     endif ()
 507 endif ()
 508
 509 #-----------------------------------------------------------------------
 510 # Game packs
 511 #-----------------------------------------------------------------------
 512
 513 set(GAMEPACKS_LICENSE_LIST free CACHE STRING "Download game packs by license")
 514 set(GAMEPACKS_NAME_LIST none CACHE STRING "Download game packs by name")
 515
 516 if (DOWNLOAD_GAMEPACKS)
 517     add_custom_target(gamepacks ALL
 518        COMMAND "${PROJECT_SOURCE_DIR}/gamepack-manager" --license ${GAMEPACKS_LICENSE_LIST} --name ${GAMEPACKS_NAME_LIST} --download-dir "${GAMEPACKS_DOWNLOAD_DIR}" --install-dir "${PROJECT_BINARY_DIR}/gamepacks" --download --install
 519        COMMENT "Downloading game packs"
 520     )
 521 endif ()
 522
 523 #-----------------------------------------------------------------------
 524 # Install
 525 #-----------------------------------------------------------------------
 526
 527 if (BUILD_BINARIES)
 528     install(DIRECTORY
 529         setup/data/tools/base
 530         setup/data/tools/bitmaps
 531         setup/data/tools/gl
 532         setup/data/tools/plugins
 533         docs
 534         DESTINATION ${RADIANT_DATA_DIR}
 535     )
 536
 537     install(FILES
 538         setup/data/tools/global.xlink
 539         DESTINATION ${RADIANT_DATA_DIR}
 540     )
 541 endif ()
 542
 543 if (DOWNLOAD_GAMEPACKS)
 544     install(DIRECTORY
 545         ${PROJECT_BINARY_DIR}/gamepacks
 546         DESTINATION ${RADIANT_DATA_DIR}
 547     )
 548 endif ()
 549
 550 if (BUILD_BINARIES AND FHS_INSTALL AND NOT WIN32 AND NOT APPLE)
 551     install(FILES
 552         icons/netradiant.png
 553         DESTINATION ${RADIANT_SHARE_DIR}/pixmaps
 554     )
 555     install(FILES
 556         icons/netradiant.desktop
 557         DESTINATION ${RADIANT_SHARE_DIR}/applications
 558     )
 559     install(FILES
 560         icons/x-netradiant-map.xml
 561         DESTINATION ${RADIANT_SHARE_DIR}/mime/application
 562     )
 563 endif ()
 564
 565 if (APPLE)
 566     install(DIRECTORY
 567         setup/macos/Contents
 568         DESTINATION ${APPLE_INSTALL_PREFIX}
 569     )
 570     install(DIRECTORY
 571     ${PROJECT_BINARY_DIR}/themes
 572         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/Prefix/share
 573     )
 574     install(PROGRAMS
 575         setup/macos/NetRadiant
 576         DESTINATION ${APPLE_INSTALL_PREFIX}/Contents/MacOS
 577     )
 578 endif ()
 579
 580 include(cmake/scripts/package.cmake)