qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = func_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(FL_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 158         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 159
 160         WaypointSprite_Load();
 161
 162         // precaches
 163         precache_model("null");
 164         precache_sound("misc/hit.wav");
 165         precache_sound("misc/typehit.wav");
 166         if (autocvar_cl_precacheplayermodels)
 167         {
 168                 precache_all_playermodels("models/player/*.zym");
 169                 precache_all_playermodels("models/player/*.dpm");
 170                 precache_all_playermodels("models/player/*.md3");
 171                 precache_all_playermodels("models/player/*.psk");
 172                 precache_all_playermodels("models/player/*.iqm");
 173         }
 174
 175         Projectile_Precache();
 176         Hook_Precache();
 177         GibSplash_Precache();
 178         Casings_Precache();
 179         DamageInfo_Precache();
 180         Vehicles_Precache();
 181         turrets_precache();
 182     Announcer_Precache();
 183         Tuba_Precache();
 184         CSQCPlayer_Precache();
 185
 186         if(autocvar_cl_reticle)
 187         {
 188                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 189                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 190         }
 191
 192         get_mi_min_max_texcoords(1); // try the CLEVER way first
 193         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 194         shortmapname = mi_shortname;
 195
 196         if(precache_pic(minimapname) == "")
 197         {
 198                 // but maybe we have a non-clever minimap
 199                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 200                 if(precache_pic(minimapname) == "")
 201                         minimapname = ""; // FAIL
 202                 else
 203                         get_mi_min_max_texcoords(0); // load new texcoords
 204         }
 205
 206         mi_center = (mi_min + mi_max) * 0.5;
 207         mi_scale = mi_max - mi_min;
 208         minimapname = strzone(minimapname);
 209
 210         WarpZone_Init();
 211
 212         hud_configure_prev = -1;
 213         tab_panel = -1;
 214
 215         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 216 }
 217
 218 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 219 void Shutdown(void)
 220 {
 221 #ifdef USE_FTE
 222 #pragma TARGET id
 223         if(!__engine_check)
 224                 return 0;
 225 #pragma TARGET fte
 226 #endif
 227
 228         WarpZone_Shutdown();
 229
 230         remove(teams);
 231         remove(players);
 232         db_close(binddb);
 233         db_close(tempdb);
 234         if(autocvar_cl_db_saveasdump)
 235                 db_dump(ClientProgsDB, "client.db");
 236         else
 237                 db_save(ClientProgsDB, "client.db");
 238         db_close(ClientProgsDB);
 239
 240         if(camera_active)
 241                 cvar_set("chase_active",ftos(chase_active_backup));
 242
 243         // unset the event chasecam's chase_active
 244         if(autocvar_chase_active < 0)
 245                 cvar_set("chase_active", "0");
 246
 247         if not(isdemo())
 248         {
 249                 if not(calledhooks & HOOK_START)
 250                         localcmd("\n_cl_hook_gamestart nop\n");
 251                 if not(calledhooks & HOOK_END)
 252                         localcmd("\ncl_hook_gameend\n");
 253         }
 254 }
 255
 256 .float has_team;
 257 float SetTeam(entity o, float Team)
 258 {
 259         entity tm;
 260         if(teamplay)
 261         {
 262                 switch(Team)
 263                 {
 264                         case -1:
 265                         case FL_TEAM_1:
 266                         case FL_TEAM_2:
 267                         case FL_TEAM_3:
 268                         case FL_TEAM_4:
 269                                 break;
 270                         default:
 271                                 if(GetTeam(Team, false) == world)
 272                                 {
 273                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 274                                         Team = FL_SPECTATOR;
 275                                 }
 276                                 break;
 277                 }
 278         }
 279         else
 280         {
 281                 switch(Team)
 282                 {
 283                         case -1:
 284                         case 0:
 285                                 break;
 286                         default:
 287                                 if(GetTeam(Team, false) == world)
 288                                 {
 289                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 290                                         Team = FL_SPECTATOR;
 291                                 }
 292                                 break;
 293                 }
 294         }
 295         if(Team == -1) // leave
 296         {
 297                 if(o.has_team)
 298                 {
 299                         tm = GetTeam(o.team, false);
 300                         tm.team_size -= 1;
 301                         o.has_team = 0;
 302                         return TRUE;
 303                 }
 304         }
 305         else
 306         {
 307                 if not(o.has_team)
 308                 {
 309                         o.team = Team;
 310                         tm = GetTeam(Team, true);
 311                         tm.team_size += 1;
 312                         o.has_team = 1;
 313                         return TRUE;
 314                 }
 315                 else if(Team != o.team)
 316                 {
 317                         tm = GetTeam(o.team, false);
 318                         tm.team_size -= 1;
 319                         o.team = Team;
 320                         tm = GetTeam(Team, true);
 321                         tm.team_size += 1;
 322                         return TRUE;
 323                 }
 324         }
 325         return FALSE;
 326 }
 327
 328 void Playerchecker_Think()
 329 {
 330         float i;
 331         entity e;
 332         for(i = 0; i < maxclients; ++i)
 333         {
 334                 e = playerslots[i];
 335                 if(GetPlayerName(i) == "")
 336                 {
 337                         if(e.sort_prev)
 338                         {
 339                                 // player disconnected
 340                                 SetTeam(e, -1);
 341                                 RemovePlayer(e);
 342                                 e.sort_prev = world;
 343                                 //e.gotscores = 0;
 344                         }
 345                 }
 346                 else
 347                 {
 348                         if not(e.sort_prev)
 349                         {
 350                                 // player connected
 351                                 if not(e)
 352                                         playerslots[i] = e = spawn();
 353                                 e.sv_entnum = i;
 354                                 e.ping = 0;
 355                                 e.ping_packetloss = 0;
 356                                 e.ping_movementloss = 0;
 357                                 //e.gotscores = 0; // we might already have the scores...
 358                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 359                                 RegisterPlayer(e);
 360                                 HUD_UpdatePlayerPos(e);
 361                         }
 362                 }
 363         }
 364         self.nextthink = time + 0.2;
 365 }
 366
 367 void Porto_Init();
 368 void TrueAim_Init();
 369 void PostInit(void)
 370 {
 371         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 372
 373         entity playerchecker;
 374         playerchecker = spawn();
 375         playerchecker.think = Playerchecker_Think;
 376         playerchecker.nextthink = time + 0.2;
 377
 378         Porto_Init();
 379         TrueAim_Init();
 380
 381         postinit = true;
 382 }
 383
 384 float button_zoom;
 385
 386 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 387 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 388 // All keys are in ascii.
 389 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 390 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 391 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 392 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 393 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 394 {
 395         float bSkipKey;
 396         bSkipKey = false;
 397
 398         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 399                 return true;
 400
 401         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 402                 return true;
 403
 404         if(menu_visible && menu_action)
 405                 if(menu_action(bInputType, nPrimary, nSecondary))
 406                         return TRUE;
 407
 408         return bSkipKey;
 409 }
 410
 411 // END REQUIRED CSQC FUNCTIONS
 412 // --------------------------------------------------------------------------
 413
 414 // --------------------------------------------------------------------------
 415 // BEGIN OPTIONAL CSQC FUNCTIONS
 416 void Ent_RemoveEntCS()
 417 {
 418         entcs_receiver[self.sv_entnum] = world;
 419 }
 420 void Ent_ReadEntCS()
 421 {
 422         float sf;
 423         InterpolateOrigin_Undo();
 424
 425         self.classname = "entcs_receiver";
 426         sf = ReadByte();
 427
 428         if(sf & 1)
 429                 self.sv_entnum = ReadByte();
 430         if(sf & 2)
 431         {
 432                 self.origin_x = ReadShort();
 433                 self.origin_y = ReadShort();
 434                 self.origin_z = ReadShort();
 435                 setorigin(self, self.origin);
 436         }
 437         if(sf & 4)
 438         {
 439                 self.angles_y = ReadByte() * 360.0 / 256;
 440                 self.angles_x = self.angles_z = 0;
 441         }
 442         if(sf & 8)
 443                 self.healthvalue = ReadByte() * 10;
 444         if(sf & 16)
 445                 self.armorvalue = ReadByte() * 10;
 446
 447         entcs_receiver[self.sv_entnum] = self;
 448         self.entremove = Ent_RemoveEntCS;
 449
 450         InterpolateOrigin_Note();
 451 }
 452
 453 void Ent_Remove();
 454
 455 void Ent_RemovePlayerScore()
 456 {
 457         float i;
 458
 459         if(self.owner)
 460         {
 461                 SetTeam(self.owner, -1);
 462                 self.owner.gotscores = 0;
 463                 for(i = 0; i < MAX_SCORE; ++i)
 464                         self.owner.(scores[i]) = 0; // clear all scores
 465         }
 466 }
 467
 468 void Ent_ReadPlayerScore()
 469 {
 470         float i, n;
 471         float isNew;
 472         entity o;
 473
 474         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 475         // (no I've never heard of M-x replace-string, sed, or anything like that)
 476         isNew = !self.owner; // workaround for DP bug
 477         n = ReadByte()-1;
 478
 479 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 480         if(!isNew && n != self.sv_entnum)
 481         {
 482                 //print(_("A CSQC entity changed its owner!\n"));
 483                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 484                 isNew = true;
 485                 Ent_Remove();
 486                 self.enttype = ENT_CLIENT_SCORES;
 487         }
 488 #endif
 489
 490         self.sv_entnum = n;
 491
 492         if not(playerslots[self.sv_entnum])
 493                 playerslots[self.sv_entnum] = spawn();
 494         o = self.owner = playerslots[self.sv_entnum];
 495         o.sv_entnum = self.sv_entnum;
 496         o.gotscores = 1;
 497
 498         //if not(o.sort_prev)
 499         //      RegisterPlayer(o);
 500         //playerchecker will do this for us later, if it has not already done so
 501
 502         float sf, lf;
 503 #if MAX_SCORE <= 8
 504         sf = ReadByte();
 505         lf = ReadByte();
 506 #else
 507         sf = ReadShort();
 508         lf = ReadShort();
 509 #endif
 510         float p;
 511         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 512                 if(sf & p)
 513                 {
 514                         if(lf & p)
 515                                 o.(scores[i]) = ReadInt24_t();
 516                         else
 517                                 o.(scores[i]) = ReadChar();
 518                 }
 519
 520         if(o.sort_prev)
 521                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 522
 523         self.entremove = Ent_RemovePlayerScore;
 524 }
 525
 526 void Ent_ReadTeamScore()
 527 {
 528         float i;
 529         entity o;
 530
 531         self.team = ReadByte();
 532         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 533
 534         float sf, lf;
 535 #if MAX_TEAMSCORE <= 8
 536         sf = ReadByte();
 537         lf = ReadByte();
 538 #else
 539         sf = ReadShort();
 540         lf = ReadShort();
 541 #endif
 542         float p;
 543         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 544                 if(sf & p)
 545                 {
 546                         if(lf & p)
 547                                 o.(teamscores[i]) = ReadInt24_t();
 548                         else
 549                                 o.(teamscores[i]) = ReadChar();
 550                 }
 551
 552         HUD_UpdateTeamPos(o);
 553 }
 554
 555 void Ent_ClientData()
 556 {
 557         float f;
 558         float newspectatee_status;
 559
 560         f = ReadByte();
 561
 562         scoreboard_showscores_force = (f & 1);
 563
 564         if(f & 2)
 565         {
 566                 newspectatee_status = ReadByte();
 567                 if(newspectatee_status == player_localnum + 1)
 568                         newspectatee_status = -1; // observing
 569         }
 570         else
 571                 newspectatee_status = 0;
 572
 573         spectatorbutton_zoom = (f & 4);
 574
 575         if(f & 8)
 576         {
 577                 angles_held_status = 1;
 578                 angles_held_x = ReadAngle();
 579                 angles_held_y = ReadAngle();
 580                 angles_held_z = 0;
 581         }
 582         else
 583                 angles_held_status = 0;
 584
 585         if(newspectatee_status != spectatee_status)
 586         {
 587                 // clear race stuff
 588                 race_laptime = 0;
 589                 race_checkpointtime = 0;
 590         }
 591         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 592         {
 593                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 594                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 595                 )
 596                         prev_p_health = -1;
 597                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 598                         prev_health = -1;
 599         }
 600         spectatee_status = newspectatee_status;
 601
 602         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 603 }
 604
 605 void Ent_Nagger()
 606 {
 607         float nags, i, j, b, f;
 608
 609         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 610
 611         if(!(nags & 4))
 612         {
 613                 if(vote_called_vote)
 614                         strunzone(vote_called_vote);
 615                 vote_called_vote = string_null;
 616                 vote_active = 0;
 617         }
 618         else
 619         {
 620                 vote_active = 1;
 621         }
 622
 623         if(nags & 64)
 624         {
 625                 vote_yescount = ReadByte();
 626                 vote_nocount = ReadByte();
 627                 vote_needed = ReadByte();
 628                 vote_highlighted = ReadChar();
 629         }
 630
 631         if(nags & 128)
 632         {
 633                 if(vote_called_vote)
 634                         strunzone(vote_called_vote);
 635                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 636         }
 637
 638         if(nags & 1)
 639         {
 640                 for(j = 0; j < maxclients; ++j)
 641                         if(playerslots[j])
 642                                 playerslots[j].ready = 1;
 643                 for(i = 1; i <= maxclients; i += 8)
 644                 {
 645                         f = ReadByte();
 646                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 647                                 if not(f & b)
 648                                         if(playerslots[j])
 649                                                 playerslots[j].ready = 0;
 650                 }
 651         }
 652
 653         ready_waiting = (nags & 1);
 654         ready_waiting_for_me = (nags & 2);
 655         vote_waiting = (nags & 4);
 656         vote_waiting_for_me = (nags & 8);
 657         warmup_stage = (nags & 16);
 658 }
 659
 660 void Ent_RandomSeed()
 661 {
 662         float s;
 663         prandom_debug();
 664         s = ReadShort();
 665         psrandom(s);
 666 }
 667
 668 void Ent_ReadAccuracy(void)
 669 {
 670         float sf, f, w, b;
 671         sf = ReadInt24_t();
 672         if(sf == 0)
 673         {
 674                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 675                         weapon_accuracy[w] = -1;
 676                 return;
 677         }
 678
 679         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 680         {
 681                 if(sf & f)
 682                 {
 683                         b = ReadByte();
 684                         if(b == 0)
 685                                 weapon_accuracy[w] = -1;
 686                         else if(b == 255)
 687                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 688                         else
 689                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 690                 }
 691                 if(f == 0x800000)
 692                         f = 1;
 693                 else
 694                         f *= 2;
 695         }
 696 }
 697
 698 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 699 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 700 void Ent_RadarLink();
 701 void Ent_Init();
 702 void Ent_ScoresInfo();
 703 void CSQC_Ent_Update(float bIsNewEntity)
 704 {
 705         float t;
 706         float savetime;
 707         t = ReadByte();
 708
 709         if(autocvar_developer_csqcentities)
 710                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 711
 712         // set up the "time" global for received entities to be correct for interpolation purposes
 713         savetime = time;
 714         if(servertime)
 715         {
 716                 time = servertime;
 717         }
 718         else
 719         {
 720                 serverprevtime = time;
 721                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 722                 time = serverprevtime + serverdeltatime;
 723         }
 724
 725 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 726         if(self.enttype)
 727         {
 728                 if(t != self.enttype || bIsNewEntity)
 729                 {
 730                         //print(_("A CSQC entity changed its type!\n"));
 731                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 732                         Ent_Remove();
 733                         clearentity(self);
 734                         bIsNewEntity = 1;
 735                 }
 736         }
 737         else
 738         {
 739                 if(!bIsNewEntity)
 740                 {
 741                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 742                         bIsNewEntity = 1;
 743                 }
 744         }
 745 #endif
 746         self.enttype = t;
 747         switch(t)
 748         {
 749                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 750                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 751                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 752                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 753                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 754                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 755                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 756                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 757                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 758                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 759                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 760                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 761                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 762                 case ENT_CLIENT_INIT: Ent_Init(); break;
 763                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 764                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 765                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 766                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 767                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 768                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 769                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 770                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 771                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 772                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 773                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 774                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 775                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 776                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 777                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 778                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 779                 case ENT_CLIENT_TURRET: ent_turret(); break;
 780                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 781                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 782                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 783                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 784                 default:
 785                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 786                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 787                         break;
 788         }
 789
 790         time = savetime;
 791 }
 792 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 793 // used when an entity changes its type. For an entity that someone interacts
 794 // with others, make sure it can no longer do so.
 795 void Ent_Remove()
 796 {
 797         if(self.entremove)
 798                 self.entremove();
 799
 800         if(self.skeletonindex)
 801         {
 802                 skel_delete(self.skeletonindex);
 803                 self.skeletonindex = 0;
 804         }
 805
 806         if(self.snd_looping > 0)
 807         {
 808                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 809                 self.snd_looping = 0;
 810         }
 811
 812         self.enttype = 0;
 813         self.classname = "";
 814         self.draw = menu_sub_null;
 815         self.entremove = menu_sub_null;
 816         // TODO possibly set more stuff to defaults
 817 }
 818 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 819 void CSQC_Ent_Remove()
 820 {
 821         if(autocvar_developer_csqcentities)
 822                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 823
 824         if(wasfreed(self))
 825         {
 826                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 827                 return;
 828         }
 829         if(self.enttype)
 830                 Ent_Remove();
 831         remove(self);
 832 }
 833
 834 void Gamemode_Init()
 835 {
 836         if not(isdemo())
 837         {
 838                 if(!(calledhooks & HOOK_START))
 839                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 840                 calledhooks |= HOOK_START;
 841         }
 842 }
 843 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 844 void CSQC_Parse_StuffCmd(string strMessage)
 845 {
 846         if(autocvar_developer_csqcentities)
 847                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 848
 849         localcmd(strMessage);
 850 }
 851 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 852 void CSQC_Parse_Print(string strMessage)
 853 {
 854         if(autocvar_developer_csqcentities)
 855                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 856
 857         print(ColorTranslateRGB(strMessage));
 858 }
 859
 860 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 861 void CSQC_Parse_CenterPrint(string strMessage)
 862 {
 863         if(autocvar_developer_csqcentities)
 864                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 865
 866         centerprint_hud(strMessage);
 867 }
 868
 869 string notranslate_fogcmd1 = "\nfog ";
 870 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 871 void Fog_Force()
 872 {
 873         // TODO somehow thwart prvm_globalset client ...
 874
 875         if(forcefog != "")
 876                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 877 }
 878
 879 void Gamemode_Init();
 880 void Ent_ScoresInfo()
 881 {
 882         float i;
 883         self.classname = "ent_client_scores_info";
 884         gametype = ReadInt24_t();
 885         for(i = 0; i < MAX_SCORE; ++i)
 886         {
 887                 scores_label[i] = strzone(ReadString());
 888                 scores_flags[i] = ReadByte();
 889         }
 890         for(i = 0; i < MAX_TEAMSCORE; ++i)
 891         {
 892                 teamscores_label[i] = strzone(ReadString());
 893                 teamscores_flags[i] = ReadByte();
 894         }
 895         HUD_InitScores();
 896         Gamemode_Init();
 897 }
 898
 899 void Ent_Init()
 900 {
 901         self.classname = "ent_client_init";
 902
 903         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 904
 905         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 906         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 907         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 908         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 909         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 910         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 911         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 912         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 913         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 914         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 915         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 916         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 917
 918         if(forcefog)
 919                 strunzone(forcefog);
 920         forcefog = strzone(ReadString());
 921
 922         armorblockpercent = ReadByte() / 255.0;
 923
 924         g_weaponswitchdelay = ReadByte() / 255.0;
 925
 926         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 927         g_balance_grenadelauncher_bouncestop = ReadCoord();
 928         g_balance_electro_secondary_bouncefactor = ReadCoord();
 929         g_balance_electro_secondary_bouncestop = ReadCoord();
 930
 931         nex_scope = !ReadByte();
 932         rifle_scope = !ReadByte();
 933
 934         serverflags = ReadByte();
 935
 936         minelayer_maxmines = ReadByte();
 937
 938         hagar_maxrockets = ReadByte();
 939
 940         g_trueaim_minrange = ReadCoord();
 941         g_balance_porto_secondary = ReadByte();
 942
 943         if(!postinit)
 944                 PostInit();
 945 }
 946
 947 void Net_ReadRace()
 948 {
 949         float b;
 950
 951         b = ReadByte();
 952
 953         switch(b)
 954         {
 955                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 956                         race_checkpoint = ReadByte();
 957                         race_time = ReadInt24_t();
 958                         race_previousbesttime = ReadInt24_t();
 959                         if(race_previousbestname)
 960                                 strunzone(race_previousbestname);
 961                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 962
 963                         race_checkpointtime = time;
 964
 965                         if(race_checkpoint == 0 || race_checkpoint == 254)
 966                         {
 967                                 race_penaltyaccumulator = 0;
 968                                 race_laptime = time; // valid
 969                         }
 970
 971                         break;
 972
 973                 case RACE_NET_CHECKPOINT_CLEAR:
 974                         race_laptime = 0;
 975                         race_checkpointtime = 0;
 976                         break;
 977
 978                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 979                         race_laptime = ReadCoord();
 980                         race_checkpointtime = -99999;
 981                         // fall through
 982                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 983                         race_nextcheckpoint = ReadByte();
 984
 985                         race_nextbesttime = ReadInt24_t();
 986                         if(race_nextbestname)
 987                                 strunzone(race_nextbestname);
 988                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 989                         break;
 990
 991                 case RACE_NET_CHECKPOINT_HIT_RACE:
 992                         race_mycheckpoint = ReadByte();
 993                         race_mycheckpointtime = time;
 994                         race_mycheckpointdelta = ReadInt24_t();
 995                         race_mycheckpointlapsdelta = ReadByte();
 996                         if(race_mycheckpointlapsdelta >= 128)
 997                                 race_mycheckpointlapsdelta -= 256;
 998                         if(race_mycheckpointenemy)
 999                                 strunzone(race_mycheckpointenemy);
1000                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1001                         break;
1002
1003                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1004                         race_othercheckpoint = ReadByte();
1005                         race_othercheckpointtime = time;
1006                         race_othercheckpointdelta = ReadInt24_t();
1007                         race_othercheckpointlapsdelta = ReadByte();
1008                         if(race_othercheckpointlapsdelta >= 128)
1009                                 race_othercheckpointlapsdelta -= 256;
1010                         if(race_othercheckpointenemy)
1011                                 strunzone(race_othercheckpointenemy);
1012                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1013                         break;
1014
1015                 case RACE_NET_PENALTY_RACE:
1016                         race_penaltyeventtime = time;
1017                         race_penaltytime = ReadShort();
1018                         //race_penaltyaccumulator += race_penaltytime;
1019                         if(race_penaltyreason)
1020                                 strunzone(race_penaltyreason);
1021                         race_penaltyreason = strzone(ReadString());
1022                         break;
1023
1024                 case RACE_NET_PENALTY_QUALIFYING:
1025                         race_penaltyeventtime = time;
1026                         race_penaltytime = ReadShort();
1027                         race_penaltyaccumulator += race_penaltytime;
1028                         if(race_penaltyreason)
1029                                 strunzone(race_penaltyreason);
1030                         race_penaltyreason = strzone(ReadString());
1031                         break;
1032
1033                 case RACE_NET_SERVER_RECORD:
1034                         race_server_record = ReadInt24_t();
1035                         break;
1036                 case RACE_NET_SPEED_AWARD:
1037                         race_speedaward = ReadInt24_t();
1038                         if(race_speedaward_holder)
1039                                 strunzone(race_speedaward_holder);
1040                         race_speedaward_holder = strzone(ReadString());
1041                         break;
1042                 case RACE_NET_SPEED_AWARD_BEST:
1043                         race_speedaward_alltimebest = ReadInt24_t();
1044                         if(race_speedaward_alltimebest_holder)
1045                                 strunzone(race_speedaward_alltimebest_holder);
1046                         race_speedaward_alltimebest_holder = strzone(ReadString());
1047                         break;
1048                 case RACE_NET_SERVER_RANKINGS:
1049                         float pos, prevpos, del;
1050                         pos = ReadShort();
1051                         prevpos = ReadShort();
1052                         del = ReadShort();
1053
1054                         // move other rankings out of the way
1055                         float i;
1056                         if (prevpos) {
1057                                 for (i=prevpos-1;i>pos-1;--i) {
1058                                         grecordtime[i] = grecordtime[i-1];
1059                                         if(grecordholder[i])
1060                                                 strunzone(grecordholder[i]);
1061                                         grecordholder[i] = strzone(grecordholder[i-1]);
1062                                 }
1063                         } else if (del) { // a record has been deleted by the admin
1064                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1065                                         if (i == RANKINGS_CNT-1) { // clear out last record
1066                                                 grecordtime[i] = 0;
1067                                                 if (grecordholder[i])
1068                                                         strunzone(grecordholder[i]);
1069                                                 grecordholder[i] = string_null;
1070                                         }
1071                                         else {
1072                                                 grecordtime[i] = grecordtime[i+1];
1073                                                 if (grecordholder[i])
1074                                                         strunzone(grecordholder[i]);
1075                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1076                                         }
1077                                 }
1078                         } else { // player has no ranked record yet
1079                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1080                                         grecordtime[i] = grecordtime[i-1];
1081                                         if(grecordholder[i])
1082                                                 strunzone(grecordholder[i]);
1083                                         grecordholder[i] = strzone(grecordholder[i-1]);
1084                                 }
1085                         }
1086
1087                         // store new ranking
1088                         if(grecordholder[pos-1] != "")
1089                                 strunzone(grecordholder[pos-1]);
1090                         grecordholder[pos-1] = strzone(ReadString());
1091                         grecordtime[pos-1] = ReadInt24_t();
1092                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1093                                 race_myrank = pos;
1094                         break;
1095                 case RACE_NET_SERVER_STATUS:
1096                         race_status = ReadShort();
1097                         if(race_status_name)
1098                                 strunzone(race_status_name);
1099                         race_status_name = strzone(ReadString());
1100         }
1101 }
1102
1103 void Net_ReadSpawn()
1104 {
1105         zoomin_effect = 1;
1106         current_viewzoom = 0.6;
1107 }
1108
1109 void Net_TeamNagger()
1110 {
1111         teamnagger = 1;
1112 }
1113
1114 void Net_ReadPingPLReport()
1115 {
1116         float e, pi, pl, ml;
1117         e = ReadByte();
1118         pi = ReadShort();
1119         pl = ReadByte();
1120         ml = ReadByte();
1121         if not(playerslots[e])
1122                 return;
1123         playerslots[e].ping = pi;
1124         playerslots[e].ping_packetloss = pl / 255.0;
1125         playerslots[e].ping_movementloss = ml / 255.0;
1126 }
1127
1128 void Net_WeaponComplain() {
1129         complain_weapon = ReadByte();
1130
1131         if(complain_weapon_name)
1132                 strunzone(complain_weapon_name);
1133         complain_weapon_name = strzone(ReadString());
1134
1135         complain_weapon_type = ReadByte();
1136
1137         complain_weapon_time = time;
1138         weapontime = time; // ping the weapon panel
1139 }
1140
1141 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1142 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1143 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1144 float CSQC_Parse_TempEntity()
1145 {
1146         float bHandled;
1147                 bHandled  = true;
1148         // Acquire TE ID
1149         float nTEID;
1150                 nTEID = ReadByte();
1151
1152         if(autocvar_developer_csqcentities)
1153                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1154
1155                 // NOTE: Could just do return instead of break...
1156         switch(nTEID)
1157         {
1158                 case TE_CSQC_TARGET_MUSIC:
1159                         Net_TargetMusic();
1160                         bHandled = true;
1161                         break;
1162                 case TE_CSQC_PICTURE:
1163                         Net_MapVote_Picture();
1164                         bHandled = true;
1165                         break;
1166                 case TE_CSQC_RACE:
1167                         Net_ReadRace();
1168                         bHandled = true;
1169                         break;
1170                 case TE_CSQC_SPAWN:
1171                         Net_ReadSpawn();
1172                         bHandled = true;
1173                         break;
1174                 case TE_CSQC_ZCURVEPARTICLES:
1175                         Net_ReadZCurveParticles();
1176                         bHandled = true;
1177                         break;
1178                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1179                         Net_ReadNexgunBeamParticle();
1180                         bHandled = true;
1181                         break;
1182                 case TE_CSQC_TEAMNAGGER:
1183                         Net_TeamNagger();
1184                         bHandled = true;
1185                         break;
1186                 case TE_CSQC_LIGHTNINGARC:
1187                         Net_ReadLightningarc();
1188                         bHandled = true;
1189                         break;
1190                 case TE_CSQC_PINGPLREPORT:
1191                         Net_ReadPingPLReport();
1192                         bHandled = true;
1193                         break;
1194                 case TE_CSQC_ANNOUNCE:
1195                         Announcer_Play(ReadString());
1196                         bHandled = true;
1197                         break;
1198                 case TE_CSQC_KILLNOTIFY:
1199                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1200                         bHandled = true;
1201                         break;
1202                 case TE_CSQC_CENTERPRINT_GENERIC:
1203                         float id;
1204                         string s;
1205                         id = ReadByte();
1206                         s = ReadString();
1207                         if (id != 0 && s != "")
1208                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1209                         else
1210                                 centerprint_generic(id, s, 0, 0);
1211                         bHandled = true;
1212                         break;
1213                 case TE_CSQC_WEAPONCOMPLAIN:
1214                         Net_WeaponComplain();
1215                         bHandled = true;
1216                         break;
1217                 case TE_CSQC_VEHICLESETUP:
1218                         Net_VehicleSetup();
1219                         bHandled = true;
1220                         break;
1221                 case TE_CSQC_SVNOTICE:
1222                         cl_notice_read();
1223                         bHandled = true;
1224                         break;
1225                 default:
1226                         // No special logic for this temporary entity; return 0 so the engine can handle it
1227                         bHandled = false;
1228                         break;
1229         }
1230
1231         return bHandled;
1232 }
1233
1234 string getcommandkey(string text, string command)
1235 {
1236         string keys;
1237         float n, j, k, l = 0;
1238
1239         if (!autocvar_hud_showbinds)
1240                 return text;
1241
1242         keys = db_get(binddb, command);
1243         if (keys == "")
1244         {
1245                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1246                 for(j = 0; j < n; ++j)
1247                 {
1248                         k = stof(argv(j));
1249                         if(k != -1)
1250                         {
1251                                 if ("" == keys)
1252                                         keys = keynumtostring(k);
1253                                 else
1254                                         keys = strcat(keys, ", ", keynumtostring(k));
1255
1256                                 ++l;
1257                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1258                                         break;
1259                         }
1260
1261                 }
1262                 if (keys == "")
1263                         keys = "NO_KEY";
1264                 db_put(binddb, command, keys);
1265         }
1266
1267         if (keys == "NO_KEY") {
1268                 if (autocvar_hud_showbinds > 1)
1269                         return sprintf(_("%s (not bound)"), text);
1270                 else
1271                         return text;
1272         }
1273         else if (autocvar_hud_showbinds > 1)
1274                 return sprintf(_("%s (%s)"), text, keys);
1275         else
1276                 return keys;
1277 }