qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if not(clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 #ifdef USE_FTE
  32 float __engine_check;
  33 #endif
  34
  35 void precache_playermodel(string m)
  36 {
  37         string f;
  38
  39         if(substring(m, -9,5) == "_lod1")
  40                 return;
  41         if(substring(m, -9,5) == "_lod2")
  42                 return;
  43         precache_model(m);
  44         f = strcat(substring(m, 0, -5), "_lod1", substring(m, -4, -1));
  45         if(fexists(f))
  46                 precache_model(f);
  47         f = strcat(substring(m, 0, -5), "_lod2", substring(m, -4, -1));
  48         if(fexists(f))
  49                 precache_model(f);
  50
  51         /*
  52         float globhandle, i, n;
  53         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
  54         if (globhandle < 0)
  55                 return;
  56         n = search_getsize(globhandle);
  57         for (i = 0; i < n; ++i)
  58         {
  59                 //print(search_getfilename(globhandle, i), "\n");
  60                 f = search_getfilename(globhandle, i);
  61                 PrecachePlayerSounds(f);
  62         }
  63         search_end(globhandle);
  64         */
  65 }
  66 void precache_all_playermodels(string pattern)
  67 {
  68         float globhandle, i, n;
  69         string f;
  70
  71         globhandle = search_begin(pattern, TRUE, FALSE);
  72         if (globhandle < 0)
  73                 return;
  74         n = search_getsize(globhandle);
  75         for (i = 0; i < n; ++i)
  76         {
  77                 //print(search_getfilename(globhandle, i), "\n");
  78                 f = search_getfilename(globhandle, i);
  79                 precache_playermodel(f);
  80         }
  81         search_end(globhandle);
  82 }
  83
  84 string forcefog;
  85 void WaypointSprite_Load();
  86 void ConsoleCommand_macro_init();
  87 void CSQC_Init(void)
  88 {
  89         prvm_language = cvar_string("prvm_language");
  90 #ifdef USE_FTE
  91 #pragma target ID
  92         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  93         if(!__engine_check)
  94         {
  95                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  96                 localcmd("\ndisconnect\n");
  97                 return;
  98         }
  99 #pragma target FTE
 100 #endif
 101
 102         check_unacceptable_compiler_bugs();
 103
 104 #ifdef WATERMARK
 105         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
 106 #endif
 107
 108         float i;
 109
 110 #ifdef COMPAT_XON050_ENGINE
 111         // old engine lacks implementation of player_localnum
 112         player_localnum = player_localentnum - 1;
 113 #endif
 114
 115         binddb = db_create();
 116         tempdb = db_create();
 117         ClientProgsDB = db_load("client.db");
 118         compressShortVector_init();
 119
 120         draw_endBoldFont();
 121         menu_visible = FALSE;
 122         menu_show = menu_show_error;
 123         menu_action = menu_sub_null;
 124
 125         for(i = 0; i < 255; ++i)
 126                 if(getplayerkeyvalue(i, "viewentity") == "")
 127                         break;
 128         maxclients = i;
 129
 130         //registercommand("hud_configure");
 131         //registercommand("hud_save");
 132         //registercommand("menu_action");
 133
 134         ConsoleCommand_macro_init();
 135
 136         registercvar("hud_usecsqc", "1");
 137         registercvar("scoreboard_columns", "default");
 138
 139         gametype = 0;
 140
 141         // hud_fields uses strunzone on the titles!
 142         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 143                 hud_title[i] = strzone("(null)");
 144
 145         postinit = false;
 146
 147         calledhooks = 0;
 148
 149         teams = Sort_Spawn();
 150         players = Sort_Spawn();
 151
 152         GetTeam(COLOR_SPECTATOR, true); // add specs first
 153
 154         // needs to be done so early because of the constants they create
 155         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
 156         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
 157
 158         WaypointSprite_Load();
 159
 160         // precaches
 161         precache_model("null");
 162         precache_sound("misc/hit.wav");
 163         precache_sound("misc/typehit.wav");
 164         if (autocvar_cl_precacheplayermodels)
 165         {
 166                 precache_all_playermodels("models/player/*.zym");
 167                 precache_all_playermodels("models/player/*.dpm");
 168                 precache_all_playermodels("models/player/*.md3");
 169                 precache_all_playermodels("models/player/*.psk");
 170                 precache_all_playermodels("models/player/*.iqm");
 171         }
 172
 173         Projectile_Precache();
 174         Hook_Precache();
 175         GibSplash_Precache();
 176         Casings_Precache();
 177         DamageInfo_Precache();
 178         Vehicles_Precache();
 179         turrets_precache();
 180     Announcer_Precache();
 181         Tuba_Precache();
 182
 183         if(autocvar_cl_reticle)
 184         {
 185                 if(autocvar_cl_reticle_item_normal) { precache_pic("gfx/reticle_normal"); }
 186                 if(autocvar_cl_reticle_item_nex) { precache_pic("gfx/reticle_nex"); }
 187         }
 188
 189         get_mi_min_max_texcoords(1); // try the CLEVER way first
 190         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 191         shortmapname = mi_shortname;
 192
 193         if(precache_pic(minimapname) == "")
 194         {
 195                 // but maybe we have a non-clever minimap
 196                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 197                 if(precache_pic(minimapname) == "")
 198                         minimapname = ""; // FAIL
 199                 else
 200                         get_mi_min_max_texcoords(0); // load new texcoords
 201         }
 202
 203         mi_center = (mi_min + mi_max) * 0.5;
 204         mi_scale = mi_max - mi_min;
 205         minimapname = strzone(minimapname);
 206
 207         WarpZone_Init();
 208
 209         hud_configure_prev = -1;
 210         tab_panel = -1;
 211
 212         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 213 }
 214
 215 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 216 void Shutdown(void)
 217 {
 218 #ifdef USE_FTE
 219 #pragma TARGET id
 220         if(!__engine_check)
 221                 return 0;
 222 #pragma TARGET fte
 223 #endif
 224
 225         WarpZone_Shutdown();
 226
 227         remove(teams);
 228         remove(players);
 229         db_close(binddb);
 230         db_close(tempdb);
 231         if(autocvar_cl_db_saveasdump)
 232                 db_dump(ClientProgsDB, "client.db");
 233         else
 234                 db_save(ClientProgsDB, "client.db");
 235         db_close(ClientProgsDB);
 236
 237         if(camera_active)
 238                 cvar_set("chase_active",ftos(chase_active_backup));
 239
 240         // unset the event chasecam's chase_active
 241         if(autocvar_chase_active < 0)
 242                 cvar_set("chase_active", "0");
 243
 244         if not(isdemo())
 245         {
 246                 if not(calledhooks & HOOK_START)
 247                         localcmd("\n_cl_hook_gamestart nop\n");
 248                 if not(calledhooks & HOOK_END)
 249                         localcmd("\ncl_hook_gameend\n");
 250         }
 251 }
 252
 253 .float has_team;
 254 float SetTeam(entity o, float Team)
 255 {
 256         entity tm;
 257         if(teamplay)
 258         {
 259                 switch(Team)
 260                 {
 261                         case -1:
 262                         case COLOR_TEAM1:
 263                         case COLOR_TEAM2:
 264                         case COLOR_TEAM3:
 265                         case COLOR_TEAM4:
 266                                 break;
 267                         default:
 268                                 if(GetTeam(Team, false) == world)
 269                                 {
 270                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 271                                         Team = COLOR_SPECTATOR;
 272                                 }
 273                                 break;
 274                 }
 275         }
 276         else
 277         {
 278                 switch(Team)
 279                 {
 280                         case -1:
 281                         case 0:
 282                                 break;
 283                         default:
 284                                 if(GetTeam(Team, false) == world)
 285                                 {
 286                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 287                                         Team = COLOR_SPECTATOR;
 288                                 }
 289                                 break;
 290                 }
 291         }
 292         if(Team == -1) // leave
 293         {
 294                 if(o.has_team)
 295                 {
 296                         tm = GetTeam(o.team, false);
 297                         tm.team_size -= 1;
 298                         o.has_team = 0;
 299                         return TRUE;
 300                 }
 301         }
 302         else
 303         {
 304                 if not(o.has_team)
 305                 {
 306                         o.team = Team;
 307                         tm = GetTeam(Team, true);
 308                         tm.team_size += 1;
 309                         o.has_team = 1;
 310                         return TRUE;
 311                 }
 312                 else if(Team != o.team)
 313                 {
 314                         tm = GetTeam(o.team, false);
 315                         tm.team_size -= 1;
 316                         o.team = Team;
 317                         tm = GetTeam(Team, true);
 318                         tm.team_size += 1;
 319                         return TRUE;
 320                 }
 321         }
 322         return FALSE;
 323 }
 324
 325 void Playerchecker_Think()
 326 {
 327         float i;
 328         entity e;
 329         for(i = 0; i < maxclients; ++i)
 330         {
 331                 e = playerslots[i];
 332                 if(GetPlayerName(i) == "")
 333                 {
 334                         if(e.sort_prev)
 335                         {
 336                                 // player disconnected
 337                                 SetTeam(e, -1);
 338                                 RemovePlayer(e);
 339                                 e.sort_prev = world;
 340                                 //e.gotscores = 0;
 341                         }
 342                 }
 343                 else
 344                 {
 345                         if not(e.sort_prev)
 346                         {
 347                                 // player connected
 348                                 if not(e)
 349                                         playerslots[i] = e = spawn();
 350                                 e.sv_entnum = i;
 351                                 e.ping = 0;
 352                                 e.ping_packetloss = 0;
 353                                 e.ping_movementloss = 0;
 354                                 //e.gotscores = 0; // we might already have the scores...
 355                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 356                                 RegisterPlayer(e);
 357                                 HUD_UpdatePlayerPos(e);
 358                         }
 359                 }
 360         }
 361         self.nextthink = time + 0.2;
 362 }
 363
 364 void Porto_Init();
 365 void TrueAim_Init();
 366 void PostInit(void)
 367 {
 368         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 369
 370         entity playerchecker;
 371         playerchecker = spawn();
 372         playerchecker.think = Playerchecker_Think;
 373         playerchecker.nextthink = time + 0.2;
 374
 375         Porto_Init();
 376         TrueAim_Init();
 377
 378         postinit = true;
 379 }
 380
 381 float button_zoom;
 382
 383 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 384 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 385 // All keys are in ascii.
 386 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 387 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 388 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 389 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 390 {
 391         float bSkipKey;
 392         bSkipKey = false;
 393
 394         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 395                 return true;
 396
 397         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 398                 return true;
 399
 400         if(menu_visible)
 401                 if(menu_action(bInputType, nPrimary, nSecondary))
 402                         return TRUE;
 403
 404         return bSkipKey;
 405 }
 406
 407 // END REQUIRED CSQC FUNCTIONS
 408 // --------------------------------------------------------------------------
 409
 410 // --------------------------------------------------------------------------
 411 // BEGIN OPTIONAL CSQC FUNCTIONS
 412 void Ent_RemoveEntCS()
 413 {
 414         entcs_receiver[self.sv_entnum] = world;
 415 }
 416 void Ent_ReadEntCS()
 417 {
 418         float sf;
 419         InterpolateOrigin_Undo();
 420
 421         self.classname = "entcs_receiver";
 422         sf = ReadByte();
 423
 424         if(sf & 1)
 425                 self.sv_entnum = ReadByte();
 426         if(sf & 2)
 427         {
 428                 self.origin_x = ReadShort();
 429                 self.origin_y = ReadShort();
 430                 self.origin_z = ReadShort();
 431         }
 432         if(sf & 4)
 433         {
 434                 self.angles_y = ReadByte() * 360.0 / 256;
 435                 self.angles_x = self.angles_z = 0;
 436         }
 437         if(sf & 8)
 438                 self.healthvalue = ReadByte() * 10;
 439         if(sf & 16)
 440                 self.armorvalue = ReadByte() * 10;
 441
 442         entcs_receiver[self.sv_entnum] = self;
 443         self.entremove = Ent_RemoveEntCS;
 444
 445         InterpolateOrigin_Note();
 446 }
 447
 448 void Ent_Remove();
 449
 450 void Ent_RemovePlayerScore()
 451 {
 452         float i;
 453
 454         if(self.owner)
 455         {
 456                 SetTeam(self.owner, -1);
 457                 self.owner.gotscores = 0;
 458                 for(i = 0; i < MAX_SCORE; ++i)
 459                         self.owner.(scores[i]) = 0; // clear all scores
 460         }
 461 }
 462
 463 void Ent_ReadPlayerScore()
 464 {
 465         float i, n;
 466         float isNew;
 467         entity o;
 468
 469         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 470         // (no I've never heard of M-x replace-string, sed, or anything like that)
 471         isNew = !self.owner; // workaround for DP bug
 472         n = ReadByte()-1;
 473
 474 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 475         if(!isNew && n != self.sv_entnum)
 476         {
 477                 //print(_("A CSQC entity changed its owner!\n"));
 478                 print(sprintf(_("A CSQC entity changed its owner! (edict: %d, classname: %s)\n"), num_for_edict(self), self.classname));
 479                 isNew = true;
 480                 Ent_Remove();
 481                 self.enttype = ENT_CLIENT_SCORES;
 482         }
 483 #endif
 484
 485         self.sv_entnum = n;
 486
 487         if not(playerslots[self.sv_entnum])
 488                 playerslots[self.sv_entnum] = spawn();
 489         o = self.owner = playerslots[self.sv_entnum];
 490         o.sv_entnum = self.sv_entnum;
 491         o.gotscores = 1;
 492
 493         //if not(o.sort_prev)
 494         //      RegisterPlayer(o);
 495         //playerchecker will do this for us later, if it has not already done so
 496
 497         float sf, lf;
 498 #if MAX_SCORE <= 8
 499         sf = ReadByte();
 500         lf = ReadByte();
 501 #else
 502         sf = ReadShort();
 503         lf = ReadShort();
 504 #endif
 505         float p;
 506         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 507                 if(sf & p)
 508                 {
 509                         if(lf & p)
 510                                 o.(scores[i]) = ReadInt24_t();
 511                         else
 512                                 o.(scores[i]) = ReadChar();
 513                 }
 514
 515         if(o.sort_prev)
 516                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 517
 518         self.entremove = Ent_RemovePlayerScore;
 519 }
 520
 521 void Ent_ReadTeamScore()
 522 {
 523         float i;
 524         entity o;
 525
 526         self.team = ReadByte();
 527         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 528
 529         float sf, lf;
 530 #if MAX_TEAMSCORE <= 8
 531         sf = ReadByte();
 532         lf = ReadByte();
 533 #else
 534         sf = ReadShort();
 535         lf = ReadShort();
 536 #endif
 537         float p;
 538         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 539                 if(sf & p)
 540                 {
 541                         if(lf & p)
 542                                 o.(teamscores[i]) = ReadInt24_t();
 543                         else
 544                                 o.(teamscores[i]) = ReadChar();
 545                 }
 546
 547         HUD_UpdateTeamPos(o);
 548 }
 549
 550 void Ent_ClientData()
 551 {
 552         float f;
 553         float newspectatee_status;
 554
 555         f = ReadByte();
 556
 557         scoreboard_showscores_force = (f & 1);
 558
 559         if(f & 2)
 560         {
 561                 newspectatee_status = ReadByte();
 562                 if(newspectatee_status == player_localnum + 1)
 563                         newspectatee_status = -1; // observing
 564         }
 565         else
 566                 newspectatee_status = 0;
 567
 568         spectatorbutton_zoom = (f & 4);
 569
 570         if(f & 8)
 571         {
 572                 angles_held_status = 1;
 573                 angles_held_x = ReadAngle();
 574                 angles_held_y = ReadAngle();
 575                 angles_held_z = 0;
 576         }
 577         else
 578                 angles_held_status = 0;
 579
 580         if(newspectatee_status != spectatee_status)
 581         {
 582                 // clear race stuff
 583                 race_laptime = 0;
 584                 race_checkpointtime = 0;
 585         }
 586         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 587         {
 588                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 589                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 590                 )
 591                         prev_p_health = -1;
 592                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 593                         prev_health = -1;
 594         }
 595         spectatee_status = newspectatee_status;
 596
 597         // non-COMPAT_XON050_ENGINE: we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 598 }
 599
 600 void Ent_Nagger()
 601 {
 602         float nags, i, j, b, f;
 603
 604         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 605
 606         if(!(nags & 4))
 607         {
 608                 if(vote_called_vote)
 609                         strunzone(vote_called_vote);
 610                 vote_called_vote = string_null;
 611                 vote_active = 0;
 612         }
 613         else
 614         {
 615                 vote_active = 1;
 616         }
 617
 618         if(nags & 64)
 619         {
 620                 vote_yescount = ReadByte();
 621                 vote_nocount = ReadByte();
 622                 vote_needed = ReadByte();
 623                 vote_highlighted = ReadChar();
 624         }
 625
 626         if(nags & 128)
 627         {
 628                 if(vote_called_vote)
 629                         strunzone(vote_called_vote);
 630                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 631         }
 632
 633         if(nags & 1)
 634         {
 635                 for(j = 0; j < maxclients; ++j)
 636                         if(playerslots[j])
 637                                 playerslots[j].ready = 1;
 638                 for(i = 1; i <= maxclients; i += 8)
 639                 {
 640                         f = ReadByte();
 641                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 642                                 if not(f & b)
 643                                         if(playerslots[j])
 644                                                 playerslots[j].ready = 0;
 645                 }
 646         }
 647
 648         ready_waiting = (nags & 1);
 649         ready_waiting_for_me = (nags & 2);
 650         vote_waiting = (nags & 4);
 651         vote_waiting_for_me = (nags & 8);
 652         warmup_stage = (nags & 16);
 653 }
 654
 655 void Ent_RandomSeed()
 656 {
 657         float s;
 658         prandom_debug();
 659         s = ReadShort();
 660         psrandom(s);
 661 }
 662
 663 void Ent_ReadAccuracy(void)
 664 {
 665         float sf, f, w, b;
 666         sf = ReadInt24_t();
 667         if(sf == 0)
 668         {
 669                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 670                         weapon_accuracy[w] = -1;
 671                 return;
 672         }
 673
 674         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 675         {
 676                 if(sf & f)
 677                 {
 678                         b = ReadByte();
 679                         if(b == 0)
 680                                 weapon_accuracy[w] = -1;
 681                         else if(b == 255)
 682                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 683                         else
 684                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 685                 }
 686                 if(f == 0x800000)
 687                         f = 1;
 688                 else
 689                         f *= 2;
 690         }
 691 }
 692
 693 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 694 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 695 void Ent_RadarLink();
 696 void Ent_Init();
 697 void Ent_ScoresInfo();
 698 void CSQC_Ent_Update(float bIsNewEntity)
 699 {
 700         float t;
 701         float savetime;
 702         t = ReadByte();
 703
 704         if(autocvar_developer_csqcentities)
 705                 print(sprintf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t));
 706
 707         // set up the "time" global for received entities to be correct for interpolation purposes
 708         savetime = time;
 709         if(servertime)
 710         {
 711                 time = servertime;
 712         }
 713         else
 714         {
 715                 serverprevtime = time;
 716                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 717                 time = serverprevtime + serverdeltatime;
 718         }
 719
 720 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 721         if(self.enttype)
 722         {
 723                 if(t != self.enttype || bIsNewEntity)
 724                 {
 725                         //print(_("A CSQC entity changed its type!\n"));
 726                         print(sprintf(_("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n"), num_for_edict(self), self.entnum, self.enttype, t));
 727                         Ent_Remove();
 728                         clearentity(self);
 729                         bIsNewEntity = 1;
 730                 }
 731         }
 732         else
 733         {
 734                 if(!bIsNewEntity)
 735                 {
 736                         print(sprintf(_("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n"), num_for_edict(self), self.entnum, t));
 737                         bIsNewEntity = 1;
 738                 }
 739         }
 740 #endif
 741         self.enttype = t;
 742         switch(t)
 743         {
 744                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 745                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 746                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 747                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 748                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 749                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 750                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 751                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 752                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 753                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 754                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 755                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 756                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 757                 case ENT_CLIENT_INIT: Ent_Init(); break;
 758                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 759                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 760                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 761                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 762                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 763                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 764                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 765                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 766                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 767                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 768                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 769                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 770                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 771                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 772                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 773                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 774                 case ENT_CLIENT_TURRET: ent_turret(); break;
 775                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 776                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 777                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 778                 default:
 779                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 780                         error(sprintf(_("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n"), self.enttype, num_for_edict(self), self.classname));
 781                         break;
 782         }
 783
 784         time = savetime;
 785 }
 786 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 787 // used when an entity changes its type. For an entity that someone interacts
 788 // with others, make sure it can no longer do so.
 789 void Ent_Remove()
 790 {
 791         if(self.entremove)
 792                 self.entremove();
 793
 794         self.enttype = 0;
 795         self.classname = "";
 796         self.draw = menu_sub_null;
 797         self.entremove = menu_sub_null;
 798         // TODO possibly set more stuff to defaults
 799 }
 800 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 801 void CSQC_Ent_Remove()
 802 {
 803         if(autocvar_developer_csqcentities)
 804                 print(sprintf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype));
 805
 806         if(wasfreed(self))
 807         {
 808                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 809                 return;
 810         }
 811         if(self.enttype)
 812                 Ent_Remove();
 813         remove(self);
 814 }
 815
 816 void Gamemode_Init()
 817 {
 818         if not(isdemo())
 819         {
 820                 if(!(calledhooks & HOOK_START))
 821                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 822                 calledhooks |= HOOK_START;
 823         }
 824 }
 825 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 826 void CSQC_Parse_StuffCmd(string strMessage)
 827 {
 828         if(autocvar_developer_csqcentities)
 829                 print(sprintf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage));
 830
 831         localcmd(strMessage);
 832 }
 833 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 834 void CSQC_Parse_Print(string strMessage)
 835 {
 836         if(autocvar_developer_csqcentities)
 837                 print(sprintf("CSQC_Parse_Print(\"%s\")\n", strMessage));
 838
 839         print(ColorTranslateRGB(strMessage));
 840 }
 841
 842 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 843 void CSQC_Parse_CenterPrint(string strMessage)
 844 {
 845         if(autocvar_developer_csqcentities)
 846                 print(sprintf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage));
 847
 848         centerprint_hud(strMessage);
 849 }
 850
 851 string notranslate_fogcmd1 = "\nfog ";
 852 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 853 void Fog_Force()
 854 {
 855         // TODO somehow thwart prvm_globalset client ...
 856
 857         if(forcefog != "")
 858                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
 859 }
 860
 861 void Gamemode_Init();
 862 void Ent_ScoresInfo()
 863 {
 864         float i;
 865         self.classname = "ent_client_scores_info";
 866         gametype = ReadInt24_t();
 867         for(i = 0; i < MAX_SCORE; ++i)
 868         {
 869                 scores_label[i] = strzone(ReadString());
 870                 scores_flags[i] = ReadByte();
 871         }
 872         for(i = 0; i < MAX_TEAMSCORE; ++i)
 873         {
 874                 teamscores_label[i] = strzone(ReadString());
 875                 teamscores_flags[i] = ReadByte();
 876         }
 877         HUD_InitScores();
 878         Gamemode_Init();
 879 }
 880
 881 void Ent_Init()
 882 {
 883         self.classname = "ent_client_init";
 884
 885         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 886
 887         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 888         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 889         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 890         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 891         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 892         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 893         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 894         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 895         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 896         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 897         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 898         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 899
 900         if(forcefog)
 901                 strunzone(forcefog);
 902         forcefog = strzone(ReadString());
 903
 904         armorblockpercent = ReadByte() / 255.0;
 905
 906         g_weaponswitchdelay = ReadByte() / 255.0;
 907
 908         g_balance_grenadelauncher_bouncefactor = ReadCoord();
 909         g_balance_grenadelauncher_bouncestop = ReadCoord();
 910         g_balance_electro_secondary_bouncefactor = ReadCoord();
 911         g_balance_electro_secondary_bouncestop = ReadCoord();
 912
 913         nex_scope = !ReadByte();
 914         rifle_scope = !ReadByte();
 915
 916         serverflags = ReadByte();
 917
 918         minelayer_maxmines = ReadByte();
 919
 920         hagar_maxrockets = ReadByte();
 921
 922         g_trueaim_minrange = ReadCoord();
 923         g_balance_porto_secondary = ReadByte();
 924
 925         if(!postinit)
 926                 PostInit();
 927 }
 928
 929 void Net_ReadRace()
 930 {
 931         float b;
 932
 933         b = ReadByte();
 934
 935         switch(b)
 936         {
 937                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
 938                         race_checkpoint = ReadByte();
 939                         race_time = ReadInt24_t();
 940                         race_previousbesttime = ReadInt24_t();
 941                         if(race_previousbestname)
 942                                 strunzone(race_previousbestname);
 943                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
 944
 945                         race_checkpointtime = time;
 946
 947                         if(race_checkpoint == 0 || race_checkpoint == 254)
 948                         {
 949                                 race_penaltyaccumulator = 0;
 950                                 race_laptime = time; // valid
 951                         }
 952
 953                         break;
 954
 955                 case RACE_NET_CHECKPOINT_CLEAR:
 956                         race_laptime = 0;
 957                         race_checkpointtime = 0;
 958                         break;
 959
 960                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
 961                         race_laptime = ReadCoord();
 962                         race_checkpointtime = -99999;
 963                         // fall through
 964                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
 965                         race_nextcheckpoint = ReadByte();
 966
 967                         race_nextbesttime = ReadInt24_t();
 968                         if(race_nextbestname)
 969                                 strunzone(race_nextbestname);
 970                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
 971                         break;
 972
 973                 case RACE_NET_CHECKPOINT_HIT_RACE:
 974                         race_mycheckpoint = ReadByte();
 975                         race_mycheckpointtime = time;
 976                         race_mycheckpointdelta = ReadInt24_t();
 977                         race_mycheckpointlapsdelta = ReadByte();
 978                         if(race_mycheckpointlapsdelta >= 128)
 979                                 race_mycheckpointlapsdelta -= 256;
 980                         if(race_mycheckpointenemy)
 981                                 strunzone(race_mycheckpointenemy);
 982                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 983                         break;
 984
 985                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
 986                         race_othercheckpoint = ReadByte();
 987                         race_othercheckpointtime = time;
 988                         race_othercheckpointdelta = ReadInt24_t();
 989                         race_othercheckpointlapsdelta = ReadByte();
 990                         if(race_othercheckpointlapsdelta >= 128)
 991                                 race_othercheckpointlapsdelta -= 256;
 992                         if(race_othercheckpointenemy)
 993                                 strunzone(race_othercheckpointenemy);
 994                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
 995                         break;
 996
 997                 case RACE_NET_PENALTY_RACE:
 998                         race_penaltyeventtime = time;
 999                         race_penaltytime = ReadShort();
1000                         //race_penaltyaccumulator += race_penaltytime;
1001                         if(race_penaltyreason)
1002                                 strunzone(race_penaltyreason);
1003                         race_penaltyreason = strzone(ReadString());
1004                         break;
1005
1006                 case RACE_NET_PENALTY_QUALIFYING:
1007                         race_penaltyeventtime = time;
1008                         race_penaltytime = ReadShort();
1009                         race_penaltyaccumulator += race_penaltytime;
1010                         if(race_penaltyreason)
1011                                 strunzone(race_penaltyreason);
1012                         race_penaltyreason = strzone(ReadString());
1013                         break;
1014
1015                 case RACE_NET_SERVER_RECORD:
1016                         race_server_record = ReadInt24_t();
1017                         break;
1018                 case RACE_NET_SPEED_AWARD:
1019                         race_speedaward = ReadInt24_t();
1020                         if(race_speedaward_holder)
1021                                 strunzone(race_speedaward_holder);
1022                         race_speedaward_holder = strzone(ReadString());
1023                         break;
1024                 case RACE_NET_SPEED_AWARD_BEST:
1025                         race_speedaward_alltimebest = ReadInt24_t();
1026                         if(race_speedaward_alltimebest_holder)
1027                                 strunzone(race_speedaward_alltimebest_holder);
1028                         race_speedaward_alltimebest_holder = strzone(ReadString());
1029                         break;
1030                 case RACE_NET_SERVER_RANKINGS:
1031                         float pos, prevpos, del;
1032                         pos = ReadShort();
1033                         prevpos = ReadShort();
1034                         del = ReadShort();
1035
1036                         // move other rankings out of the way
1037                         float i;
1038                         if (prevpos) {
1039                                 for (i=prevpos-1;i>pos-1;--i) {
1040                                         grecordtime[i] = grecordtime[i-1];
1041                                         if(grecordholder[i])
1042                                                 strunzone(grecordholder[i]);
1043                                         grecordholder[i] = strzone(grecordholder[i-1]);
1044                                 }
1045                         } else if (del) { // a record has been deleted by the admin
1046                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1047                                         if (i == RANKINGS_CNT-1) { // clear out last record
1048                                                 grecordtime[i] = 0;
1049                                                 if (grecordholder[i])
1050                                                         strunzone(grecordholder[i]);
1051                                                 grecordholder[i] = string_null;
1052                                         }
1053                                         else {
1054                                                 grecordtime[i] = grecordtime[i+1];
1055                                                 if (grecordholder[i])
1056                                                         strunzone(grecordholder[i]);
1057                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1058                                         }
1059                                 }
1060                         } else { // player has no ranked record yet
1061                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1062                                         grecordtime[i] = grecordtime[i-1];
1063                                         if(grecordholder[i])
1064                                                 strunzone(grecordholder[i]);
1065                                         grecordholder[i] = strzone(grecordholder[i-1]);
1066                                 }
1067                         }
1068
1069                         // store new ranking
1070                         if(grecordholder[pos-1] != "")
1071                                 strunzone(grecordholder[pos-1]);
1072                         grecordholder[pos-1] = strzone(ReadString());
1073                         grecordtime[pos-1] = ReadInt24_t();
1074                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1075                                 race_myrank = pos;
1076                         break;
1077                 case RACE_NET_SERVER_STATUS:
1078                         race_status = ReadShort();
1079                         if(race_status_name)
1080                                 strunzone(race_status_name);
1081                         race_status_name = strzone(ReadString());
1082         }
1083 }
1084
1085 void Net_ReadSpawn()
1086 {
1087         zoomin_effect = 1;
1088         current_viewzoom = 0.6;
1089 }
1090
1091 void Net_TeamNagger()
1092 {
1093         teamnagger = 1;
1094 }
1095
1096 void Net_ReadPingPLReport()
1097 {
1098         float e, pi, pl, ml;
1099         e = ReadByte();
1100         pi = ReadShort();
1101         pl = ReadByte();
1102         ml = ReadByte();
1103         if not(playerslots[e])
1104                 return;
1105         playerslots[e].ping = pi;
1106         playerslots[e].ping_packetloss = pl / 255.0;
1107         playerslots[e].ping_movementloss = ml / 255.0;
1108 }
1109
1110 void Net_WeaponComplain() {
1111         complain_weapon = ReadByte();
1112
1113         if(complain_weapon_name)
1114                 strunzone(complain_weapon_name);
1115         complain_weapon_name = strzone(ReadString());
1116
1117         complain_weapon_type = ReadByte();
1118
1119         complain_weapon_time = time;
1120         weapontime = time; // ping the weapon panel
1121 }
1122
1123 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1124 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1125 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1126 float CSQC_Parse_TempEntity()
1127 {
1128         float bHandled;
1129                 bHandled  = true;
1130         // Acquire TE ID
1131         float nTEID;
1132                 nTEID = ReadByte();
1133
1134         if(autocvar_developer_csqcentities)
1135                 print(sprintf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID));
1136
1137                 // NOTE: Could just do return instead of break...
1138         switch(nTEID)
1139         {
1140                 case TE_CSQC_TARGET_MUSIC:
1141                         Net_TargetMusic();
1142                         bHandled = true;
1143                         break;
1144                 case TE_CSQC_PICTURE:
1145                         Net_MapVote_Picture();
1146                         bHandled = true;
1147                         break;
1148                 case TE_CSQC_RACE:
1149                         Net_ReadRace();
1150                         bHandled = true;
1151                         break;
1152                 case TE_CSQC_SPAWN:
1153                         Net_ReadSpawn();
1154                         bHandled = true;
1155                         break;
1156                 case TE_CSQC_ZCURVEPARTICLES:
1157                         Net_ReadZCurveParticles();
1158                         bHandled = true;
1159                         break;
1160                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1161                         Net_ReadNexgunBeamParticle();
1162                         bHandled = true;
1163                         break;
1164                 case TE_CSQC_TEAMNAGGER:
1165                         Net_TeamNagger();
1166                         bHandled = true;
1167                         break;
1168                 case TE_CSQC_LIGHTNINGARC:
1169                         Net_ReadLightningarc();
1170                         bHandled = true;
1171                         break;
1172                 case TE_CSQC_PINGPLREPORT:
1173                         Net_ReadPingPLReport();
1174                         bHandled = true;
1175                         break;
1176                 case TE_CSQC_ANNOUNCE:
1177                         Announcer_Play(ReadString());
1178                         bHandled = true;
1179                         break;
1180                 case TE_CSQC_KILLNOTIFY:
1181                         HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1182                         bHandled = true;
1183                         break;
1184                 case TE_CSQC_KILLCENTERPRINT:
1185                         HUD_KillCenterprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1186                         bHandled = true;
1187                         break;
1188                 case TE_CSQC_CENTERPRINT_GENERIC:
1189                         float id;
1190                         string s;
1191                         id = ReadByte();
1192                         s = ReadString();
1193                         if (id != 0 && s != "")
1194                                 centerprint_generic(id, s, ReadByte(), ReadByte());
1195                         else
1196                                 centerprint_generic(id, s, 0, 0);
1197                         bHandled = true;
1198                         break;
1199                 case TE_CSQC_WEAPONCOMPLAIN:
1200                         Net_WeaponComplain();
1201                         bHandled = true;
1202                         break;
1203                 case TE_CSQC_VEHICLESETUP:
1204                         Net_VehicleSetup();
1205                         bHandled = true;
1206                         break;
1207                 case TE_CSQC_SVNOTICE:
1208                         cl_notice_read();
1209                         bHandled = true;
1210                         break;
1211                 default:
1212                         // No special logic for this temporary entity; return 0 so the engine can handle it
1213                         bHandled = false;
1214                         break;
1215         }
1216
1217         return bHandled;
1218 }
1219
1220 string getcommandkey(string text, string command)
1221 {
1222         string keys;
1223         float n, j, k, l;
1224
1225         if (!autocvar_hud_showbinds)
1226                 return text;
1227
1228         keys = db_get(binddb, command);
1229         if (!keys)
1230         {
1231                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1232                 for(j = 0; j < n; ++j)
1233                 {
1234                         k = stof(argv(j));
1235                         if(k != -1)
1236                         {
1237                                 if ("" == keys)
1238                                         keys = keynumtostring(k);
1239                                 else
1240                                         keys = strcat(keys, ", ", keynumtostring(k));
1241
1242                                 ++l;
1243                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit >= l) break;
1244                         }
1245
1246                 }
1247                 db_put(binddb, command, keys);
1248         }
1249
1250         if ("" == keys) {
1251                 if (autocvar_hud_showbinds > 1)
1252                         return sprintf(_("%s (not bound)"), text);
1253                 else
1254                         return text;
1255         }
1256         else if (autocvar_hud_showbinds > 1)
1257                 return sprintf(_("%s (%s)"), text, keys);
1258         else
1259                 return keys;
1260 }