qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  94         float velocityzoom, curspeed;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102                 if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir)
 122                 zoomin_effect = 0;
 123
 124         if(zoomin_effect || camera_active)
 125         {
 126                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 127         }
 128         else
 129         {
 130                 if(zoomspeed < 0) // instant zoom
 131                 {
 132                         if(zoomdir)
 133                                 current_viewzoom = 1 / zoomfactor;
 134                         else
 135                                 current_viewzoom = 1;
 136                 }
 137                 else
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 141                         else
 142                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 143                 }
 144         }
 145
 146         if(almost_equals(current_viewzoom, 1))
 147                 current_zoomfraction = 0;
 148         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 149                 current_zoomfraction = 1;
 150         else
 151                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 152
 153         if(zoomsensitivity < 1)
 154                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 155         else
 156                 setsensitivityscale(1);
 157
 158         makevectors(view_angles);
 159
 160         if(autocvar_cl_velocityzoom)
 161         {
 162                 switch(autocvar_cl_velocityzoom_type)
 163                 {
 164                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 165                         case 2: curspeed = (v_forward * pmove_vel); break;
 166                         case 1: default: curspeed = vlen(pmove_vel); break;
 167                 }
 168
 169                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 170                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 171                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 172
 173                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 174         }
 175         else
 176                 velocityzoom = 1;
 177
 178         float frustumx, frustumy, fovx, fovy;
 179         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 180         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 181         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 182         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 183
 184         return '1 0 0' * fovx + '0 1 0' * fovy;
 185 }
 186
 187 // this function must match W_SetupShot!
 188 float zoomscript_caught;
 189
 190 vector wcross_origin;
 191 float wcross_scale_prev, wcross_alpha_prev;
 192 vector wcross_color_prev;
 193 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 194 vector wcross_color_goal_prev;
 195 float wcross_changedonetime;
 196
 197 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 198 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 199 float wcross_name_changestarttime, wcross_name_changedonetime;
 200 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 201 entity trueaim;
 202 entity trueaim_rifle;
 203
 204 #define SHOTTYPE_HITTEAM 1
 205 #define SHOTTYPE_HITOBSTRUCTION 2
 206 #define SHOTTYPE_HITWORLD 3
 207 #define SHOTTYPE_HITENEMY 4
 208
 209 void TrueAim_Init()
 210 {
 211         trueaim = spawn();
 212         trueaim.classname = "trueaim";
 213         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 214         trueaim_rifle = spawn();
 215         trueaim_rifle.classname = "trueaim_rifle";
 216         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 217 }
 218
 219 float EnemyHitCheck()
 220 {
 221         float t;
 222         wcross_origin = project_3d_to_2d(trace_endpos);
 223         wcross_origin_z = 0;
 224         if(trace_networkentity < 1)
 225                 return SHOTTYPE_HITWORLD;
 226         if(trace_networkentity > maxclients)
 227                 return SHOTTYPE_HITWORLD;
 228         t = GetPlayerColor(trace_networkentity - 1);
 229         if(teamplay)
 230                 if(t == myteam)
 231                         return SHOTTYPE_HITTEAM;
 232         if(t == COLOR_SPECTATOR)
 233                 return SHOTTYPE_HITWORLD;
 234         return SHOTTYPE_HITENEMY;
 235 }
 236
 237 float TrueAimCheck()
 238 {
 239         float nudge = 1; // added to traceline target and subtracted from result
 240         vector vecs, trueaimpoint, w_shotorg;
 241         vector mi, ma, dv;
 242         float shottype;
 243         entity ta;
 244         float mv;
 245
 246         mi = ma = '0 0 0';
 247         ta = trueaim;
 248         mv = MOVE_NOMONSTERS;
 249
 250         switch(activeweapon)
 251         {
 252                 case WEP_TUBA: // no aim
 253                 case WEP_PORTO: // shoots from eye
 254                 case WEP_HOOK: // no trueaim
 255                 case WEP_GRENADE_LAUNCHER: // toss curve
 256                         return SHOTTYPE_HITWORLD;
 257                 case WEP_NEX:
 258                 case WEP_MINSTANEX:
 259                         mv = MOVE_NORMAL;
 260                         break;
 261                 case WEP_RIFLE:
 262                         ta = trueaim_rifle;
 263                         mv = MOVE_NORMAL;
 264                         if(zoomscript_caught)
 265                         {
 266                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 267                                 return EnemyHitCheck();
 268                         }
 269                         break;
 270                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 271                         mi = '-3 -3 -3';
 272                         ma = '3 3 3';
 273                         break;
 274                 case WEP_FIREBALL: // projectile has a size!
 275                         mi = '-16 -16 -16';
 276                         ma = '16 16 16';
 277                         break;
 278                 case WEP_SEEKER: // projectile has a size!
 279                         mi = '-2 -2 -2';
 280                         ma = '2 2 2';
 281                         break;
 282                 case WEP_ELECTRO: // projectile has a size!
 283                         mi = '0 0 -3';
 284                         ma = '0 0 -3';
 285                         break;
 286         }
 287
 288         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 289
 290         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 291         trueaimpoint = trace_endpos;
 292
 293         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 294                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 295
 296         if(vecs_x > 0)
 297                 vecs_y = -vecs_y;
 298         else
 299                 vecs = '0 0 0';
 300
 301         dv = view_right * vecs_y + view_up * vecs_z;
 302         w_shotorg = view_origin + dv;
 303
 304         // now move the vecs forward as much as requested if possible
 305         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 306         w_shotorg = trace_endpos - view_forward * nudge;
 307
 308         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 309         shottype = EnemyHitCheck();
 310         if(shottype != SHOTTYPE_HITWORLD)
 311                 return shottype;
 312
 313 #if 0
 314         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 315         // or rather, I know why, but see no fix
 316         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 317                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 318                 return SHOTTYPE_HITOBSTRUCTION;
 319 #endif
 320
 321         return SHOTTYPE_HITWORLD;
 322 }
 323
 324 void CSQC_common_hud(void);
 325
 326 void PostInit(void);
 327 void CSQC_Demo_Camera();
 328 float HUD_WouldDrawScoreboard();
 329 float camera_mode;
 330 float reticle_type;
 331 string NextFrameCommand;
 332 void CSQC_SPIDER_HUD();
 333 void CSQC_RAPTOR_HUD();
 334
 335 vector freeze_org, freeze_ang;
 336 entity nightvision_noise, nightvision_noise2;
 337
 338 #define MAX_TIME_DIFF 5
 339 float pickup_crosshair_time, pickup_crosshair_size;
 340 float hit_time, typehit_time;
 341 float nextsound_hit_time, nextsound_typehit_time;
 342 float hitindication_crosshair_time, hitindication_crosshair_size;
 343 float use_nex_chargepool;
 344
 345 float myhealth, myhealth_prev;
 346 float myhealth_flash;
 347
 348 float old_blurradius, old_bluralpha;
 349 float old_sharpen_intensity;
 350
 351 vector myhealth_gentlergb;
 352
 353 float contentavgalpha, liquidalpha_prev;
 354 vector liquidcolor_prev;
 355
 356 float eventchase_current_distance;
 357
 358 vector damage_blurpostprocess, content_blurpostprocess;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v;
 368         vector vf_size, vf_min;
 369         float a;
 370         hud = getstati(STAT_HUD);
 371
 372         button_attack2 = (input_buttons & BUTTON_3);
 373         button_zoom = (input_buttons & BUTTON_4);
 374
 375         // FIXME do we need this hack?
 376         if(isdemo())
 377         {
 378                 // in demos, input_buttons do not work
 379                 button_zoom = (autocvar__togglezoom == "-");
 380         }
 381
 382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 389         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 390
 391         vf_size = R_SetView3fv(VF_SIZE);
 392         vf_min = R_SetView3fv(VF_MIN);
 393         vid_width = vf_size_x;
 394         vid_height = vf_size_y;
 395
 396         vector reticle_pos, reticle_size;
 397         vector splash_pos, splash_size;
 398
 399         WaypointSprite_Load();
 400
 401         if((e = findfloat(world, entnum, player_localentnum)))
 402         {
 403                 R_SetView3fv(VF_ORIGIN, e.origin + e.view_ofs);
 404                 R_SetView3fv(VF_ANGLES, e.angles);
 405         }
 406
 407         if(spectatee_status)
 408                 myteam = GetPlayerColor(spectatee_status - 1);
 409         else
 410                 myteam = GetPlayerColor(player_localentnum - 1);
 411
 412         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 413
 414         // event chase camera
 415         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 416         {
 417                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 418                 {
 419                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 420                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 421
 422                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 423                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 424                         if(!autocvar_chase_active)
 425                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 426
 427                         // make the camera smooth back
 428                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 429                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 430                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 431                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 432
 433                         vector eventchase_target_origin;
 434                         makevectors(view_angles);
 435                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 436                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 437                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 438                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 439                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 440                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 441                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 442
 443                         R_SetView(VF_ORIGIN, trace_endpos);
 444                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 445                 }
 446                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 447                 {
 448                         cvar_set("chase_active", "0");
 449                         eventchase_current_distance = 0; // start from 0 next time
 450                 }
 451         }
 452
 453         // do lockview after event chase camera so that it still applies whenever necessary.
 454         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 455         {
 456                 R_SetView(VF_ORIGIN, freeze_org);
 457                 R_SetView(VF_ANGLES, freeze_ang);
 458         }
 459         else
 460         {
 461                 freeze_org = R_SetView3fv(VF_ORIGIN);
 462                 freeze_ang = R_SetView3fv(VF_ANGLES);
 463         }
 464
 465         WarpZone_FixView();
 466         //WarpZone_FixPMove();
 467
 468         // Render the Scene
 469         view_origin = R_SetView3fv(VF_ORIGIN);
 470         view_angles = R_SetView3fv(VF_ANGLES);
 471         makevectors(view_angles);
 472         view_forward = v_forward;
 473         view_right = v_right;
 474         view_up = v_up;
 475
 476 #ifdef BLURTEST
 477         if(time > blurtest_time0 && time < blurtest_time1)
 478         {
 479                 float r, t;
 480
 481                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 482                 r = t * blurtest_radius;
 483                 f = 1 / pow(t, blurtest_power) - 1;
 484
 485                 cvar_set("r_glsl_postprocess", "1");
 486                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 487         }
 488         else
 489         {
 490                 cvar_set("r_glsl_postprocess", "0");
 491                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 492         }
 493 #endif
 494
 495         TargetMusic_Advance();
 496         Fog_Force();
 497
 498         if(drawtime == 0)
 499                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 500         else
 501                 drawframetime = bound(0.000001, time - drawtime, 1);
 502         drawtime = time;
 503
 504         // watch for gametype changes here...
 505         // in ParseStuffCMD the cmd isn't executed yet :/
 506         // might even be better to add the gametype to TE_CSQC_INIT...?
 507         if(!postinit)
 508                 PostInit();
 509
 510         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 511         {
 512                 if(calledhooks & HOOK_START)
 513                 {
 514                         localcmd("\ncl_hook_gameend\n");
 515                         calledhooks |= HOOK_END;
 516                 }
 517         }
 518
 519   Announcer();
 520
 521         fov = autocvar_fov;
 522         if(fov <= 59.5)
 523         {
 524                 if(!zoomscript_caught)
 525                 {
 526                         localcmd("+button9\n");
 527                         zoomscript_caught = 1;
 528                 }
 529         }
 530         else
 531         {
 532                 if(zoomscript_caught)
 533                 {
 534                         localcmd("-button9\n");
 535                         zoomscript_caught = 0;
 536                 }
 537         }
 538
 539         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 540
 541         // next WANTED weapon (for HUD)
 542         switchweapon = getstati(STAT_SWITCHWEAPON);
 543
 544         // currently switching-to weapon (for crosshair)
 545         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 546
 547         // actually active weapon (for zoom)
 548         activeweapon = getstati(STAT_ACTIVEWEAPON);
 549
 550         f = (serverflags & SERVERFLAG_TEAMPLAY);
 551         if(f != teamplay)
 552         {
 553                 teamplay = f;
 554                 HUD_InitScores();
 555         }
 556
 557         if(last_switchweapon != switchweapon) {
 558                 weapontime = time;
 559                 last_switchweapon = switchweapon;
 560         }
 561         if(last_activeweapon != activeweapon) {
 562                 last_activeweapon = activeweapon;
 563
 564                 e = get_weaponinfo(activeweapon);
 565                 if(e.netname != "")
 566                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 567                 else
 568                         localcmd("\ncl_hook_activeweapon none\n");
 569         }
 570
 571         // ALWAYS Clear Current Scene First
 572         R_ClearScene();
 573 #ifdef WORKAROUND_XON010
 574         if(checkextension("DP_CSQC_ROTATEMOVES"))
 575         {
 576 #endif
 577         R_SetView(VF_ORIGIN, view_origin);
 578         R_SetView(VF_ANGLES, view_angles);
 579 #ifdef WORKAROUND_XON010
 580         }
 581 #endif
 582
 583         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 584         R_SetView(VF_SIZE, vf_size);
 585         R_SetView(VF_MIN, vf_min);
 586
 587         // Assign Standard Viewflags
 588         // Draw the World (and sky)
 589         R_SetView(VF_DRAWWORLD, 1);
 590
 591         // Set the console size vars
 592         vid_conwidth = autocvar_vid_conwidth;
 593         vid_conheight = autocvar_vid_conheight;
 594         vid_pixelheight = autocvar_vid_pixelheight;
 595
 596         R_SetView(VF_FOV, GetCurrentFov(fov));
 597
 598         // Camera for demo playback
 599         if(camera_active)
 600         {
 601                 if(autocvar_camera_enable)
 602                         CSQC_Demo_Camera();
 603                 else
 604                 {
 605                         cvar_set("chase_active", ftos(chase_active_backup));
 606                         cvar_set("cl_demo_mousegrab", "0");
 607                         camera_active = FALSE;
 608                 }
 609         }
 610 #ifdef CAMERATEST
 611         else if(autocvar_camera_enable)
 612 #else
 613         else if(autocvar_camera_enable && isdemo())
 614 #endif
 615         {
 616                 // Enable required Darkplaces cvars
 617                 chase_active_backup = autocvar_chase_active;
 618                 cvar_set("chase_active", "2");
 619                 cvar_set("cl_demo_mousegrab", "1");
 620                 camera_active = TRUE;
 621                 camera_mode = FALSE;
 622         }
 623
 624         // Draw the Crosshair
 625         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 626
 627         // Draw the Engine Status Bar (the default Quake HUD)
 628         R_SetView(VF_DRAWENGINEHUD, 0);
 629
 630         // Update the mouse position
 631         /*
 632            mousepos_x = vid_conwidth;
 633            mousepos_y = vid_conheight;
 634            mousepos = mousepos*0.5 + getmousepos();
 635          */
 636
 637         e = self;
 638         for(self = world; (self = nextent(self)); )
 639                 if(self.draw)
 640                         self.draw();
 641         self = e;
 642
 643         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 644         R_RenderScene();
 645
 646         // now switch to 2D drawing mode by calling a 2D drawing function
 647         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 648         // next R_RenderScene call
 649         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 650
 651         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 652         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 653         {
 654                 // apply night vision effect
 655                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 656
 657                 if(!nightvision_noise)
 658                 {
 659                         nightvision_noise = spawn();
 660                         nightvision_noise.classname = "nightvision_noise";
 661                 }
 662                 if(!nightvision_noise2)
 663                 {
 664                         nightvision_noise2 = spawn();
 665                         nightvision_noise2.classname = "nightvision_noise2";
 666                 }
 667
 668                 // color tint in yellow
 669                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 670
 671                 // draw BG
 672                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 673                 rgb = '1 1 1';
 674                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 675                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 676                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 677                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 678                 tc_11 = tc_01 + tc_10 - tc_00;
 679                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 680                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 681                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 682                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 683                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 684                 R_EndPolygon();
 685
 686                 // draw FG
 687                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 688                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 689                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 690                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 691                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 692                 tc_11 = tc_01 + tc_10 - tc_00;
 693                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 694                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 695                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 696                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 697                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 698                 R_EndPolygon();
 699         }
 700
 701         // Draw the aiming reticle for weapons that use it
 702         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 703         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 704         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 705         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 706                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 707         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 708                 reticle_type = 2; // nex zoom
 709         else if(button_zoom || zoomscript_caught)
 710                 reticle_type = 1; // normal zoom
 711         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 712                 reticle_type = 2; // nex zoom
 713
 714         if(reticle_type && autocvar_cl_reticle)
 715         {
 716                 if(autocvar_cl_reticle_stretch)
 717                 {
 718                         reticle_size_x = vid_conwidth;
 719                         reticle_size_y = vid_conheight;
 720                         reticle_pos_x = 0;
 721                         reticle_pos_y = 0;
 722                 }
 723                 else
 724                 {
 725                         reticle_size_x = max(vid_conwidth, vid_conheight);
 726                         reticle_size_y = max(vid_conwidth, vid_conheight);
 727                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 728                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 729                 }
 730
 731                 f = current_zoomfraction;
 732                 if(zoomscript_caught)
 733                         f = 1;
 734                 if(autocvar_cl_reticle_item_normal)
 735                 {
 736                         if(reticle_type == 1 && f)
 737                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 738                 }
 739                 if(autocvar_cl_reticle_item_nex)
 740                 {
 741                         if(reticle_type == 2 && f)
 742                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 743                 }
 744         }
 745
 746
 747         // improved polyblend
 748         vector rgb;
 749         if(autocvar_hud_contents)
 750         {
 751                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 752                 vector liquidcolor;
 753
 754                 switch(pointcontents(view_origin))
 755                 {
 756                         case CONTENT_WATER:
 757                                 liquidalpha = autocvar_hud_contents_water_alpha;
 758                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 759                                 incontent = 1;
 760                                 break;
 761
 762                         case CONTENT_LAVA:
 763                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 764                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 765                                 incontent = 1;
 766                                 break;
 767
 768                         case CONTENT_SLIME:
 769                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 770                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 771                                 incontent = 1;
 772                                 break;
 773
 774                         default:
 775                                 liquidalpha = 0;
 776                                 liquidcolor = '0 0 0';
 777                                 incontent = 0;
 778                                 break;
 779                 }
 780
 781                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 782                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 783                         contentfadetime = autocvar_hud_contents_fadeintime;
 784                         liquidalpha_prev = liquidalpha;
 785                         liquidcolor_prev = liquidcolor;
 786                 }
 787                 else
 788                         contentfadetime = autocvar_hud_contents_fadeouttime;
 789
 790                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 791                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 792
 793                 if(contentavgalpha)
 794                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 795
 796                 if(autocvar_hud_postprocessing)
 797                 {
 798                         if(autocvar_hud_contents_blur && contentavgalpha)
 799                         {
 800                                 content_blurpostprocess_x = 1;
 801                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 802                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 803                         }
 804                         else
 805                         {
 806                                 content_blurpostprocess_x = 0;
 807                                 content_blurpostprocess_y = 0;
 808                                 content_blurpostprocess_z = 0;
 809                         }
 810                 }
 811         }
 812
 813         if(autocvar_hud_damage)
 814         {
 815                 splash_size_x = max(vid_conwidth, vid_conheight);
 816                 splash_size_y = max(vid_conwidth, vid_conheight);
 817                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 818                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 819
 820                 float myhealth_flash_temp;
 821                 myhealth = getstati(STAT_HEALTH);
 822
 823                 // fade out
 824                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 825                 // add new damage
 826                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 827
 828                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 829                 pain_threshold = autocvar_hud_damage_pain_threshold;
 830                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 831                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 832
 833                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 834                 {
 835                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 836                 }
 837
 838                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 839
 840                 if(myhealth_prev < 1)
 841                 {
 842                         if(myhealth >= 1)
 843                         {
 844                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 845                                 myhealth_flash_temp = 0;
 846                         }
 847                         else
 848                         {
 849                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 850                         }
 851                 }
 852
 853                 if(spectatee_status == -1 || intermission)
 854                 {
 855                         myhealth_flash = 0; // observing, or match ended
 856                         myhealth_flash_temp = 0;
 857                 }
 858
 859                 myhealth_prev = myhealth;
 860
 861                 // IDEA: change damage color/picture based on player model for robot/alien species?
 862                 // pro: matches model better
 863                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 864                 // maybe different reddish pics?
 865                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 866                 {
 867                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 868                         {
 869                                 if(autocvar_cl_gentle_damage == 2)
 870                                 {
 871                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 872                                         {
 873                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 874                                         }
 875                                 }
 876                                 else
 877                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 878
 879                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 880                         }
 881                         else
 882                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 883                 }
 884
 885                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 886                 {
 887                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 888                         {
 889                                 damage_blurpostprocess_x = 1;
 890                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 891                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 892                         }
 893                         else
 894                         {
 895                                 damage_blurpostprocess_x = 0;
 896                                 damage_blurpostprocess_y = 0;
 897                                 damage_blurpostprocess_z = 0;
 898                         }
 899                 }
 900         }
 901
 902         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 903         {
 904                 // enable or disable rendering types if they are used or not
 905                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 906                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 907
 908                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 909                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 910                 {
 911                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 912                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 913                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 914                         {
 915                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 916                                 old_blurradius = blurradius;
 917                                 old_bluralpha = bluralpha;
 918                         }
 919                 }
 920                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 921                 {
 922                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 923                         old_blurradius = 0;
 924                         old_bluralpha = 0;
 925                 }
 926
 927                 // edge detection postprocess handling done second (used by hud_powerup)
 928                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 929                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 930                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 931
 932                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 933
 934                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 935                 {
 936                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 937                         {
 938                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 939                                 old_sharpen_intensity = sharpen_intensity;
 940                         }
 941                 }
 942                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 943                 {
 944                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 945                         old_sharpen_intensity = 0;
 946                 }
 947         }
 948
 949         if(menu_visible)
 950                 menu_show();
 951
 952         /*if(gametype == GAME_CTF)
 953           {
 954           ctf_view();
 955           } else */
 956
 957         // draw 2D entities
 958         e = self;
 959         for(self = world; (self = nextent(self)); )
 960                 if(self.draw2d)
 961                         self.draw2d();
 962         self = e;
 963         Draw_ShowNames_All();
 964
 965         scoreboard_active = HUD_WouldDrawScoreboard();
 966
 967         hit_time = getstatf(STAT_HIT_TIME);
 968         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 969         {
 970                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 971                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 972
 973                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 974         }
 975         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 976         if(typehit_time > nextsound_typehit_time)
 977         {
 978                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 979                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 980
 981                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 982         }
 983
 984         //else
 985         {
 986                 if(gametype == GAME_FREEZETAG)
 987                 {
 988                         if(getstati(STAT_FROZEN))
 989                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 990                         if(getstatf(STAT_REVIVE_PROGRESS))
 991                         {
 992                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 993                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 994                         }
 995                 }
 996
 997                 if(autocvar_r_letterbox == 0)
 998                         if(autocvar_viewsize < 120)
 999                                 CSQC_common_hud();
1000
1001                 // crosshair goes VERY LAST
1002                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
1003                         string wcross_style;
1004                         float wcross_alpha, wcross_resolution;
1005                         wcross_style = autocvar_crosshair;
1006                         if (wcross_style == "0")
1007                                 return;
1008                         wcross_resolution = autocvar_crosshair_size;
1009                         if (wcross_resolution == 0)
1010                                 return;
1011                         wcross_alpha = autocvar_crosshair_alpha;
1012                         if (wcross_alpha == 0)
1013                                 return;
1014
1015                         // TrueAim check
1016                         float shottype;
1017
1018                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1019                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1020                         wcross_origin_z = 0;
1021                         if(autocvar_crosshair_hittest)
1022                         {
1023                                 vector wcross_oldorigin;
1024                                 wcross_oldorigin = wcross_origin;
1025                                 shottype = TrueAimCheck();
1026                                 if(shottype == SHOTTYPE_HITWORLD)
1027                                 {
1028                                         v = wcross_origin - wcross_oldorigin;
1029                                         v_x /= vid_conwidth;
1030                                         v_y /= vid_conheight;
1031                                         if(vlen(v) > 0.01)
1032                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1033                                 }
1034                                 if(!autocvar_crosshair_hittest_showimpact)
1035                                         wcross_origin = wcross_oldorigin;
1036                         }
1037                         else
1038                                 shottype = SHOTTYPE_HITWORLD;
1039
1040                         vector wcross_color, wcross_size;
1041                         string wcross_wep, wcross_name;
1042                         float wcross_scale, wcross_blur;
1043
1044                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1045                                 e = get_weaponinfo(switchingweapon);
1046                                 if (e && e.netname != "")
1047                                 {
1048                                         wcross_wep = e.netname;
1049                                         if(autocvar_crosshair_per_weapon)
1050                                         {
1051                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1052                                                 if (wcross_resolution == 0)
1053                                                         return;
1054                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1055                                                 if (wcross_alpha == 0)
1056                                                         return;
1057
1058                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1059                                                 if(wcross_style == "" || wcross_style == "0")
1060                                                         wcross_style = wcross_wep;
1061                                         }
1062                                 }
1063                         }
1064                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1065                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1066                         else if(autocvar_crosshair_color_by_health)
1067                         {
1068                                 float x = getstati(STAT_HEALTH);
1069
1070                                 //x = red
1071                                 //y = green
1072                                 //z = blue
1073
1074                                 wcross_color_z = 0;
1075
1076                                 if(x > 200)
1077                                 {
1078                                         wcross_color_x = 0;
1079                                         wcross_color_y = 1;
1080                                 }
1081                                 else if(x > 150)
1082                                 {
1083                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1084                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1085                                 }
1086                                 else if(x > 100)
1087                                 {
1088                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1089                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1090                                         wcross_color_z = 1 - (x-100)*0.02;
1091                                 }
1092                                 else if(x > 50)
1093                                 {
1094                                         wcross_color_x = 1;
1095                                         wcross_color_y = 1;
1096                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1097                                 }
1098                                 else if(x > 20)
1099                                 {
1100                                         wcross_color_x = 1;
1101                                         wcross_color_y = (x-20)*90/27/100;
1102                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1103                                 }
1104                                 else
1105                                 {
1106                                         wcross_color_x = 1;
1107                                         wcross_color_y = 0;
1108                                 }
1109                         }
1110                         else
1111                                 wcross_color = stov(autocvar_crosshair_color);
1112
1113                         wcross_name = strcat("gfx/crosshair", wcross_style);
1114
1115                         if(autocvar_crosshair_effect_scalefade)
1116                         {
1117                                 wcross_scale = wcross_resolution;
1118                                 wcross_resolution = 1;
1119                         }
1120                         else
1121                         {
1122                                 wcross_scale = 1;
1123                         }
1124
1125                         if(autocvar_crosshair_pickup)
1126                         {
1127                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1128
1129                                 if(pickup_crosshair_time < stat_pickup_time)
1130                                 {
1131                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1132                                                 pickup_crosshair_size = 1;
1133
1134                                         pickup_crosshair_time = stat_pickup_time;
1135                                 }
1136
1137                                 if(pickup_crosshair_size > 0)
1138                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1139                                 else
1140                                         pickup_crosshair_size = 0;
1141
1142                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1143                         }
1144
1145                         if(autocvar_crosshair_hitindication)
1146                         {
1147                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1148                                 if(hitindication_crosshair_time < hit_time)
1149                                 {
1150                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1151                                                 hitindication_crosshair_size = 1;
1152
1153                                         hitindication_crosshair_time = hit_time;
1154                                 }
1155
1156                                 if(hitindication_crosshair_size > 0)
1157                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1158                                 else
1159                                         hitindication_crosshair_size = 0;
1160
1161                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1162                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1163                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1164                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1165                         }
1166
1167                         if(shottype == SHOTTYPE_HITENEMY)
1168                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1169                         if(shottype == SHOTTYPE_HITTEAM)
1170                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1171
1172                         f = autocvar_crosshair_effect_speed;
1173                         if(f < 0)
1174                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1175                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1176                         {
1177                                 wcross_changedonetime = time + f;
1178                         }
1179                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1180                         {
1181                                 wcross_name_changestarttime = time;
1182                                 wcross_name_changedonetime = time + f;
1183                                 if(wcross_name_goal_prev_prev)
1184                                         strunzone(wcross_name_goal_prev_prev);
1185                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1186                                 wcross_name_goal_prev = strzone(wcross_name);
1187                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1188                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1189                                 wcross_resolution_goal_prev = wcross_resolution;
1190                         }
1191
1192                         wcross_scale_goal_prev = wcross_scale;
1193                         wcross_alpha_goal_prev = wcross_alpha;
1194                         wcross_color_goal_prev = wcross_color;
1195
1196                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1197                         {
1198                                 wcross_blur = 1;
1199                                 wcross_alpha *= 0.75;
1200                         }
1201                         else
1202                                 wcross_blur = 0;
1203                         // *_prev is at time-frametime
1204                         // * is at wcross_changedonetime+f
1205                         // what do we have at time?
1206                         if(time < wcross_changedonetime)
1207                         {
1208                                 f = frametime / (wcross_changedonetime - time + frametime);
1209                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1210                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1211                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1212                         }
1213
1214                         wcross_scale_prev = wcross_scale;
1215                         wcross_alpha_prev = wcross_alpha;
1216                         wcross_color_prev = wcross_color;
1217
1218                         wcross_scale *= 1 - autocvar__menu_alpha;
1219                         wcross_alpha *= 1 - autocvar__menu_alpha;
1220                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1221
1222                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1223                         {
1224                                 // crosshair rings for weapon stats
1225                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1226                                 {
1227                                         // declarations and stats
1228                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1229                                         string ring_image, ring_inner_image;
1230                                         vector ring_rgb, ring_inner_rgb;
1231
1232                                         ring_scale = autocvar_crosshair_ring_size;
1233
1234                                         float weapon_clipload, weapon_clipsize;
1235                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1236                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1237
1238                                         float nex_charge, nex_chargepool;
1239                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1240                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1241
1242                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1243                                                 nex_charge_movingavg = nex_charge;
1244
1245
1246                                         // handle the values
1247                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1248                                         {
1249                                                 if (nex_chargepool || use_nex_chargepool) {
1250                                                         use_nex_chargepool = 1;
1251                                                         ring_inner_value = nex_chargepool;
1252                                                 } else {
1253                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1254                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1255                                                 }
1256
1257                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1258                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1259                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1260
1261                                                 // draw the outer ring to show the current charge of the weapon
1262                                                 ring_value = nex_charge;
1263                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1264                                                 ring_rgb = wcross_color;
1265                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1266                                         }
1267                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1268                                         {
1269                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1270                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1271                                                 ring_rgb = wcross_color;
1272                                                 ring_image = "gfx/crosshair_ring.tga";
1273                                         }
1274                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1275                                         {
1276                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1277                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1278                                                 ring_rgb = wcross_color;
1279                                                 ring_image = "gfx/crosshair_ring.tga";
1280                                         }
1281
1282                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1283                                         {
1284                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1285                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1286                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1287                                                 ring_rgb = wcross_color;
1288
1289                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1290                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1291                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1292                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1293                                                 else
1294                                                         ring_image = "gfx/crosshair_ring.tga";
1295                                         }
1296
1297                                         // if in weapon switch animation, fade ring out/in
1298                                         if(g_weaponswitchdelay > 0)
1299                                         {
1300                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1301                                                 if(f > 0 && f < 2)
1302                                                         ring_alpha *= fabs(1 - f);
1303                                         }
1304
1305                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1306                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1307
1308                                         if (ring_value)
1309                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1310                                 }
1311
1312 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1313                                 do \
1314                                 { \
1315                                         if(wcross_blur > 0) \
1316                                         { \
1317                                                 for(i = -2; i <= 2; ++i) \
1318                                                 for(j = -2; j <= 2; ++j) \
1319                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1320                                         } \
1321                                         else \
1322                                         { \
1323                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1324                                         } \
1325                                 } \
1326                                 while(0)
1327
1328 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1329                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1330
1331 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1332                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1333
1334                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1335                                 {
1336                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1337                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1338                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1339                                         f = 1 - f;
1340                                 }
1341                                 else
1342                                 {
1343                                         f = 1;
1344                                 }
1345                                 wcross_name_alpha_goal_prev = f;
1346
1347                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1348                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1349
1350                                 if(autocvar_crosshair_dot)
1351                                 {
1352                                         vector wcross_color_old;
1353                                         wcross_color_old = wcross_color;
1354                                         if(autocvar_crosshair_dot_color != "0")
1355                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1356                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1357                                         // FIXME why don't we use wcross_alpha here?
1358                                         wcross_color = wcross_color_old;
1359                                 }
1360                         }
1361                 }
1362                 else
1363                 {
1364                         wcross_scale_prev = 0;
1365                         wcross_alpha_prev = 0;
1366                         wcross_scale_goal_prev = 0;
1367                         wcross_alpha_goal_prev = 0;
1368                         wcross_changedonetime = 0;
1369                         if(wcross_name_goal_prev)
1370                                 strunzone(wcross_name_goal_prev);
1371                         wcross_name_goal_prev = string_null;
1372                         if(wcross_name_goal_prev_prev)
1373                                 strunzone(wcross_name_goal_prev_prev);
1374                         wcross_name_goal_prev_prev = string_null;
1375                         wcross_name_changestarttime = 0;
1376                         wcross_name_changedonetime = 0;
1377                         wcross_name_alpha_goal_prev = 0;
1378                         wcross_name_alpha_goal_prev_prev = 0;
1379                         wcross_resolution_goal_prev = 0;
1380                         wcross_resolution_goal_prev_prev = 0;
1381                 }
1382         }
1383
1384         if(NextFrameCommand)
1385         {
1386                 localcmd("\n", NextFrameCommand, "\n");
1387                 NextFrameCommand = string_null;
1388         }
1389
1390         // we must do this check AFTER a frame was rendered, or it won't work
1391         if(cs_project_is_b0rked == 0)
1392         {
1393                 string w0, h0;
1394                 w0 = ftos(autocvar_vid_conwidth);
1395                 h0 = ftos(autocvar_vid_conheight);
1396                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1397                 //R_SetView(VF_FOV, '90 90 0');
1398                 R_SetView(VF_ORIGIN, '0 0 0');
1399                 R_SetView(VF_ANGLES, '0 0 0');
1400                 R_SetView(VF_PERSPECTIVE, 1);
1401                 makevectors('0 0 0');
1402                 vector v1, v2;
1403                 cvar_set("vid_conwidth", "800");
1404                 cvar_set("vid_conheight", "600");
1405                 v1 = cs_project(v_forward);
1406                 cvar_set("vid_conwidth", "640");
1407                 cvar_set("vid_conheight", "480");
1408                 v2 = cs_project(v_forward);
1409                 if(v1 == v2)
1410                         cs_project_is_b0rked = 1;
1411                 else
1412                         cs_project_is_b0rked = -1;
1413                 cvar_set("vid_conwidth", w0);
1414                 cvar_set("vid_conheight", h0);
1415         }
1416
1417         if(autocvar__hud_configure)
1418                 HUD_Panel_Mouse();
1419
1420     if(hud && !intermission)
1421     {
1422         if(hud == HUD_SPIDERBOT)
1423             CSQC_SPIDER_HUD();
1424         else if(hud == HUD_WAKIZASHI)
1425             CSQC_WAKIZASHI_HUD();
1426         else if(hud == HUD_RAPTOR)
1427             CSQC_RAPTOR_HUD();
1428         else if(hud == HUD_BUMBLEBEE)
1429             CSQC_BUMBLE_HUD();
1430     }
1431         // let's reset the view back to normal for the end
1432         R_SetView(VF_MIN, '0 0 0');
1433         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1434 }
1435
1436
1437 void CSQC_common_hud(void)
1438 {
1439     // do some accuracy var caching
1440     float i;
1441     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1442     {
1443         if(autocvar_accuracy_color_levels != acc_color_levels)
1444         {
1445             if(acc_color_levels)
1446                 strunzone(acc_color_levels);
1447             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1448             acc_levels = tokenize_console(acc_color_levels);
1449             if (acc_levels > MAX_ACCURACY_LEVELS)
1450                 acc_levels = MAX_ACCURACY_LEVELS;
1451
1452             for (i = 0; i < acc_levels; ++i)
1453                 acc_lev[i] = stof(argv(i)) / 100.0;
1454         }
1455         // let know that acc_col[] needs to be loaded
1456         acc_col_x[0] = -1;
1457     }
1458
1459     HUD_Main(); // always run these functions for alpha checks
1460     HUD_DrawScoreboard();
1461
1462     if (scoreboard_active) // scoreboard/accuracy
1463         HUD_Reset();
1464     else if (intermission == 2) // map voting screen
1465     {
1466         HUD_FinaleOverlay();
1467         HUD_Reset();
1468     }
1469         /*
1470         switch(hud)
1471         {
1472                 case HUD_SPIDERBOT:
1473                         CSQC_SPIDER_HUD();
1474                         break;
1475
1476                 case HUD_WAKIZASHI:
1477                         CSQC_WAKIZASHI_HUD();
1478                         break;
1479
1480         case HUD_BUMBLEBEE:
1481             CSQC_BUMBLE_HUD();
1482             break;
1483         }
1484         */
1485 }
1486
1487
1488 // following vectors must be global to allow seamless switching between camera modes
1489 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1490 void CSQC_Demo_Camera()
1491 {
1492         float speed, attenuation, dimensions;
1493         vector tmp, delta;
1494
1495         if( autocvar_camera_reset || !camera_mode )
1496         {
1497                 camera_offset = '0 0 0';
1498                 current_angles = '0 0 0';
1499                 camera_direction = '0 0 0';
1500                 camera_offset_z += 30;
1501                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1502                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1503                 current_origin = view_origin;
1504                 current_camera_offset  = camera_offset;
1505                 cvar_set("camera_reset", "0");
1506                 camera_mode = CAMERA_CHASE;
1507         }
1508
1509         // Camera angles
1510         if( camera_roll )
1511                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1512
1513         if(autocvar_camera_look_player)
1514         {
1515                 vector dir;
1516                 float n;
1517
1518                 dir = normalize(view_origin - current_position);
1519                 n = mouse_angles_z;
1520                 mouse_angles = vectoangles(dir);
1521                 mouse_angles_x = mouse_angles_x * -1;
1522                 mouse_angles_z = n;
1523         }
1524         else
1525         {
1526                 tmp = getmousepos() * 0.1;
1527                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1528                 {
1529                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1530                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1531                 }
1532         }
1533
1534         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1535         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1536         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1537         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1538
1539         // Fix difference when angles don't have the same sign
1540         delta = '0 0 0';
1541         if(mouse_angles_y < -60 && current_angles_y > 60)
1542                 delta = '0 360 0';
1543         if(mouse_angles_y > 60 && current_angles_y < -60)
1544                 delta = '0 -360 0';
1545
1546         if(autocvar_camera_look_player)
1547                 attenuation = autocvar_camera_look_attenuation;
1548         else
1549                 attenuation = autocvar_camera_speed_attenuation;
1550
1551         attenuation = 1 / max(1, attenuation);
1552         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1553
1554         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1555         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1556         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1557         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1558
1559         // Camera position
1560         tmp = '0 0 0';
1561         dimensions = 0;
1562
1563         if( camera_direction_x )
1564         {
1565                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1566                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1567                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1568                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1569                 ++dimensions;
1570         }
1571
1572         if( camera_direction_y )
1573         {
1574                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1575                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1576                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1577                 ++dimensions;
1578         }
1579
1580         if( camera_direction_z )
1581         {
1582                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1583                 ++dimensions;
1584         }
1585
1586         if(autocvar_camera_free)
1587                 speed = autocvar_camera_speed_free;
1588         else
1589                 speed = autocvar_camera_speed_chase;
1590
1591         if(dimensions)
1592         {
1593                 speed = speed * sqrt(1 / dimensions);
1594                 camera_offset += tmp * speed;
1595         }
1596
1597         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1598
1599         // Camera modes
1600         if( autocvar_camera_free )
1601         {
1602                 if ( camera_mode == CAMERA_CHASE )
1603                 {
1604                         current_camera_offset = current_origin + current_camera_offset;
1605                         camera_offset = current_origin + camera_offset;
1606                 }
1607
1608                 camera_mode = CAMERA_FREE;
1609                 current_position = current_camera_offset;
1610         }
1611         else
1612         {
1613                 if ( camera_mode == CAMERA_FREE )
1614                 {
1615                         current_origin = view_origin;
1616                         camera_offset = camera_offset - current_origin;
1617                         current_camera_offset = current_camera_offset - current_origin;
1618                 }
1619
1620                 camera_mode = CAMERA_CHASE;
1621
1622                 if(autocvar_camera_chase_smoothly)
1623                         current_origin += (view_origin - current_origin) * attenuation;
1624                 else
1625                         current_origin = view_origin;
1626
1627                 current_position = current_origin + current_camera_offset;
1628         }
1629
1630         R_SetView(VF_ANGLES, current_angles);
1631         R_SetView(VF_ORIGIN, current_position);
1632 }