qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", cvar_string("cl_announcer"), "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = cvar("cl_zoomsensitivity");
 131         zoomfactor = cvar("cl_zoomfactor");
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = cvar("cl_zoomspeed");
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_CAMPINGRIFLE && campingrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, cvar_or("cl_velocityzoomtime", 0.3)), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -cvar_or("cl_velocityzoom", 0) / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(cvar_or("cl_velocityzoom", 0)), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_CAMPINGRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float view_set;
 343 float camera_mode;
 344 float reticle_type;
 345 string NextFrameCommand;
 346 void CSQC_SPIDER_HUD();
 347 void CSQC_RAPTOR_HUD();
 348
 349 vector freeze_pmove_org, freeze_input_angles;
 350 entity nightvision_noise, nightvision_noise2;
 351
 352 float pickup_crosshair_time, pickup_crosshair_size;
 353 float use_nex_charge_pool;
 354
 355 void CSQC_UpdateView(float w, float h)
 356 {
 357         entity e;
 358         float fov;
 359         float f, i, j;
 360         vector v, vo;
 361         vector vf_size, vf_min;
 362         float a;
 363
 364         vf_size = R_SetView3fv(VF_SIZE);
 365         vf_min = R_SetView3fv(VF_MIN);
 366         vid_width = vf_size_x;
 367         vid_height = vf_size_y;
 368
 369         vector reticle_pos, reticle_size;
 370
 371         WaypointSprite_Load();
 372
 373         if(spectatee_status)
 374                 myteam = GetPlayerColor(spectatee_status - 1);
 375         else
 376                 myteam = GetPlayerColor(player_localentnum - 1);
 377
 378         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 379         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 380
 381         warpzone_fixview_origin = pmove_org + vo;
 382         warpzone_fixview_cl_viewangles = input_angles;
 383         warpzone_fixview_angles = view_angles;
 384         WarpZone_FixView();
 385         pmove_org = warpzone_fixview_origin - vo;
 386         input_angles = warpzone_fixview_cl_viewangles;
 387         view_angles = warpzone_fixview_angles;
 388
 389         if(cvar("cl_lockview") || (autocvar__hud_configure && spectatee_status <= 0))
 390         {
 391                 pmove_org = freeze_pmove_org;
 392                 input_angles = view_angles = freeze_input_angles;
 393                 R_SetView(VF_ORIGIN, pmove_org + vo);
 394                 R_SetView(VF_ANGLES, view_angles);
 395                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 396         }
 397         freeze_pmove_org = pmove_org;
 398         freeze_input_angles = input_angles;
 399
 400         // Render the Scene
 401         if(!intermission || !view_set)
 402         {
 403                 view_origin = pmove_org + vo;
 404                 view_angles = input_angles;
 405                 makevectors(view_angles);
 406                 view_forward = v_forward;
 407                 view_right = v_right;
 408                 view_up = v_up;
 409                 view_set = 1;
 410         }
 411
 412 #ifdef BLURTEST
 413         if(time > blurtest_time0 && time < blurtest_time1)
 414         {
 415                 float r, t;
 416
 417                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 418                 r = t * blurtest_radius;
 419                 f = 1 / pow(t, blurtest_power) - 1;
 420
 421                 cvar_set("r_glsl_postprocess", "1");
 422                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 423         }
 424         else
 425         {
 426                 cvar_set("r_glsl_postprocess", "0");
 427                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 428         }
 429 #endif
 430
 431         TargetMusic_Advance();
 432         Fog_Force();
 433
 434         drawframetime = max(0.000001, time - drawtime);
 435         drawtime = time;
 436
 437         // watch for gametype changes here...
 438         // in ParseStuffCMD the cmd isn't executed yet :/
 439         // might even be better to add the gametype to TE_CSQC_INIT...?
 440         if(!postinit)
 441                 PostInit();
 442
 443         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 444                 if(calledhooks & HOOK_START)
 445                 {
 446                         localcmd("\ncl_hook_gameend\n");
 447                         calledhooks |= HOOK_END;
 448                 }
 449
 450         CheckForGamestartChange();
 451         serverAnnouncer();
 452         maptimeAnnouncer();
 453         carrierAnnouncer();
 454
 455         fov = cvar("fov");
 456         if(button_zoom || fov <= 59.5)
 457         {
 458                 if(!zoomscript_caught)
 459                 {
 460                         localcmd("+button4\n");
 461                         zoomscript_caught = 1;
 462                         ignore_plus_zoom += 1;
 463                 }
 464         }
 465         else
 466         {
 467                 if(zoomscript_caught)
 468                 {
 469                         localcmd("-button4\n");
 470                         zoomscript_caught = 0;
 471                         ignore_minus_zoom += 1;
 472                 }
 473         }
 474
 475         ColorTranslateMode = cvar("cl_stripcolorcodes");
 476         activeweapon = getstati(STAT_SWITCHWEAPON);
 477         f = cvar("teamplay");
 478         if(f != teamplay)
 479         {
 480                 teamplay = f;
 481                 HUD_InitScores();
 482         }
 483
 484         if(last_weapon != activeweapon) {
 485                 weapontime = time;
 486                 last_weapon = activeweapon;
 487
 488                 e = get_weaponinfo(activeweapon);
 489                 if(e.netname != "")
 490                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 491                 else
 492                         localcmd("\ncl_hook_activeweapon none\n");
 493         }
 494
 495         // ALWAYS Clear Current Scene First
 496         R_ClearScene();
 497
 498         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 499         R_SetView(VF_SIZE, vf_size);
 500         R_SetView(VF_MIN, vf_min);
 501
 502         // Assign Standard Viewflags
 503         // Draw the World (and sky)
 504         R_SetView(VF_DRAWWORLD, 1);
 505
 506         // Set the console size vars
 507         vid_conwidth = cvar("vid_conwidth");
 508         vid_conheight = cvar("vid_conheight");
 509         vid_pixelheight = cvar("vid_pixelheight");
 510
 511         R_SetView(VF_FOV, GetCurrentFov(fov));
 512
 513         // Camera for demo playback
 514         if(camera_active)
 515         {
 516                 if(cvar("camera_enable"))
 517                         CSQC_Demo_Camera();
 518                 else
 519                 {
 520                         cvar_set("chase_active", ftos(chase_active_backup));
 521                         cvar_set("cl_demo_mousegrab", "0");
 522                         camera_active = FALSE;
 523                 }
 524         }
 525 #ifdef CAMERATEST
 526         else if(cvar("camera_enable"))
 527 #else
 528         else if(cvar("camera_enable") && isdemo())
 529 #endif
 530         {
 531                 // Enable required Darkplaces cvars
 532                 chase_active_backup = cvar("chase_active");
 533                 cvar_set("chase_active", "2");
 534                 cvar_set("cl_demo_mousegrab", "1");
 535                 camera_active = TRUE;
 536                 camera_mode = FALSE;
 537         }
 538
 539         // Draw the Crosshair
 540         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 541
 542         // Draw the Engine Status Bar (the default Quake HUD)
 543         R_SetView(VF_DRAWENGINEHUD, 0);
 544
 545         // fetch this one only once per frame
 546         hud_showbinds = cvar("hud_showbinds");
 547         hud_showbinds_limit = cvar("hud_showbinds_limit");
 548
 549         // Update the mouse position
 550         /*
 551            mousepos_x = vid_conwidth;
 552            mousepos_y = vid_conheight;
 553            mousepos = mousepos*0.5 + getmousepos();
 554          */
 555
 556         e = self;
 557         for(self = world; (self = nextent(self)); )
 558                 if(self.draw)
 559                         self.draw();
 560         self = e;
 561
 562         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 563         R_RenderScene();
 564
 565         // now switch to 2D drawing mode by calling a 2D drawing function
 566         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 567         // next R_RenderScene call
 568         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 569
 570         if(cvar("r_fakelight") >= 2 || cvar("r_fullbright") >= 1)
 571         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 572         {
 573                 // apply night vision effect
 574                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 575
 576                 if(!nightvision_noise)
 577                 {
 578                         nightvision_noise = spawn();
 579                         nightvision_noise.classname = "nightvision_noise";
 580                 }
 581                 if(!nightvision_noise2)
 582                 {
 583                         nightvision_noise2 = spawn();
 584                         nightvision_noise2.classname = "nightvision_noise2";
 585                 }
 586
 587                 // color tint in yellow
 588                 drawfill('0 0 0', cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 589
 590                 // draw BG
 591                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 592                 rgb = '1 1 1';
 593                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 594                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 595                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 596                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 597                 tc_11 = tc_01 + tc_10 - tc_00;
 598                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 599                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 600                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 601                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 602                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 603                 R_EndPolygon();
 604
 605                 // draw FG
 606                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 607                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 608                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 609                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 610                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 611                 tc_11 = tc_01 + tc_10 - tc_00;
 612                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 613                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 614                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0', tc_10, rgb, a);
 615                 R_PolygonVertex(cvar("vid_conwidth") * '1 0 0' + cvar("vid_conheight") * '0 1 0', tc_11, rgb, a);
 616                 R_PolygonVertex(cvar("vid_conheight") * '0 1 0', tc_01, rgb, a);
 617                 R_EndPolygon();
 618         }
 619
 620         // Draw the aiming reticle for weapons that use it
 621         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 622         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 623         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 624         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 625                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 626         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_CAMPINGRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 627                 reticle_type = 2; // nex zoom
 628         else if(button_zoom || zoomscript_caught)
 629                 reticle_type = 1; // normal zoom
 630         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_CAMPINGRIFLE && button_attack2)
 631                 reticle_type = 2; // nex zoom
 632
 633         if(cvar("cl_reticle_stretch"))
 634         {
 635                 reticle_size_x = vid_conwidth;
 636                 reticle_size_y = vid_conheight;
 637                 reticle_pos_x = 0;
 638                 reticle_pos_y = 0;
 639         }
 640         else
 641         {
 642                 reticle_size_x = max(vid_conwidth, vid_conheight);
 643                 reticle_size_y = max(vid_conwidth, vid_conheight);
 644                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 645                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 646         }
 647
 648         f = current_zoomfraction;
 649         if(zoomscript_caught)
 650                 f = 1;
 651         if(cvar("cl_reticle_item_normal"))
 652         {
 653                 precache_pic("gfx/reticle_normal");
 654                 if(reticle_type == 1 && f)
 655                         drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * cvar("cl_reticle_item_normal"), DRAWFLAG_NORMAL);
 656         }
 657         if(cvar("cl_reticle_item_nex"))
 658         {
 659                 precache_pic("gfx/reticle_nex");
 660                 if(reticle_type == 2 && f)
 661                         drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * cvar("cl_reticle_item_nex"), DRAWFLAG_NORMAL);
 662         }
 663
 664         // Draw the mouse cursor
 665         // NOTE: drawpic must happen after R_RenderScene for some reason
 666         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 667         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 668         //self = edict_num(player_localnum);
 669         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 670         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 671         // as long as the ctf part isn't in, this is useless
 672         if(menu_visible)
 673                 menu_show();
 674
 675         /*if(gametype == GAME_CTF)
 676           {
 677           ctf_view();
 678           } else */
 679
 680         // draw 2D entities
 681         e = self;
 682         for(self = world; (self = nextent(self)); )
 683                 if(self.draw2d)
 684                         self.draw2d();
 685         self = e;
 686
 687         scoreboard_active = HUD_WouldDrawScoreboard();
 688
 689         float hud;
 690         hud = getstati(STAT_HUD);
 691         if(hud == HUD_SPIDERBOT)
 692                 CSQC_SPIDER_HUD();
 693         else if(hud == HUD_WAKIZASHI)
 694         CSQC_WAKIZASHI_HUD();
 695     else if(hud == HUD_RAPTOR)
 696         CSQC_RAPTOR_HUD();
 697         else
 698         {
 699                 if(cvar("r_letterbox") == 0)
 700                         if(cvar("viewsize") < 120)
 701                                 CSQC_common_hud();
 702
 703                 // crosshair goes VERY LAST
 704                 if(!scoreboard_active && !camera_active && intermission != 2) {
 705                         string wcross_style;
 706                         float wcross_alpha, wcross_resolution;
 707                         wcross_style = cvar_string("crosshair");
 708                         if (wcross_style == "0")
 709                                 return;
 710                         wcross_resolution = cvar("crosshair_size");
 711                         if (wcross_resolution == 0)
 712                                 return;
 713                         wcross_alpha = cvar("crosshair_alpha");
 714                         if (wcross_alpha == 0)
 715                                 return;
 716
 717                         // TrueAim check
 718                         float shottype;
 719                         float bullets, ring_scale;
 720                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 721                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 722                         wcross_origin_z = 0;
 723                         if(cvar("crosshair_hittest"))
 724                         {
 725                                 vector wcross_oldorigin;
 726                                 wcross_oldorigin = wcross_origin;
 727                                 shottype = TrueAimCheck();
 728                                 if(shottype == SHOTTYPE_HITWORLD)
 729                                 {
 730                                         v = wcross_origin - wcross_oldorigin;
 731                                         v_x /= vid_conwidth;
 732                                         v_y /= vid_conheight;
 733                                         if(vlen(v) > 0.01)
 734                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 735                                 }
 736                                 if(!cvar("crosshair_hittest_showimpact"))
 737                                         wcross_origin = wcross_oldorigin;
 738                         }
 739                         else
 740                                 shottype = SHOTTYPE_HITWORLD;
 741
 742                         vector wcross_color, wcross_size;
 743                         string wcross_wep, wcross_name;
 744                         float wcross_scale, wcross_blur;
 745
 746                         if (cvar("crosshair_per_weapon") || cvar("crosshair_color_per_weapon")) {
 747                                 e = get_weaponinfo(activeweapon);
 748                                 if (e && e.netname != "")
 749                                 {
 750                                         wcross_wep = e.netname;
 751                                         if(cvar("crosshair_per_weapon"))
 752                                         {
 753                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 754                                                 if (wcross_resolution == 0)
 755                                                         return;
 756                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 757                                                 if (wcross_alpha == 0)
 758                                                         return;
 759
 760                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 761                                                 if(wcross_style == "" || wcross_style == "0")
 762                                                         wcross_style = wcross_wep;
 763                                         }
 764                                 }
 765                         }
 766                         if(wcross_wep != "" && cvar("crosshair_color_per_weapon"))
 767                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 768                         else
 769                                 wcross_color = stov(cvar_string("crosshair_color"));
 770
 771                         wcross_name = strcat("gfx/crosshair", wcross_style);
 772
 773                         if(cvar("crosshair_effect_scalefade"))
 774                         {
 775                                 wcross_scale = wcross_resolution;
 776                                 wcross_resolution = 1;
 777                         }
 778                         else
 779                         {
 780                                 wcross_scale = 1;
 781                         }
 782
 783                         if(cvar("crosshair_pickup"))
 784                         {
 785                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
 786                                 {
 787                                         pickup_crosshair_size = 1;
 788                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
 789                                 }
 790
 791                                 if(pickup_crosshair_size > 0)
 792                                         pickup_crosshair_size -= cvar("crosshair_pickup_speed") * frametime;
 793                                 else
 794                                         pickup_crosshair_size = 0;
 795
 796                                 wcross_scale += sin(pickup_crosshair_size) * cvar("crosshair_pickup");
 797                         }
 798
 799                         if(shottype == SHOTTYPE_HITENEMY)
 800                                 wcross_scale *= cvar("crosshair_hittest"); // is not queried if hittest is 0
 801                         if(shottype == SHOTTYPE_HITTEAM)
 802                                 wcross_scale /= cvar("crosshair_hittest"); // is not queried if hittest is 0
 803
 804                         f = cvar("crosshair_effect_speed");
 805                         if(f < 0)
 806                                 f *= -2 * g_weaponswitchdelay;
 807                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 808                         {
 809                                 wcross_changedonetime = time + f;
 810                         }
 811                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 812                         {
 813                                 wcross_name_changestarttime = time;
 814                                 wcross_name_changedonetime = time + f;
 815                                 if(wcross_name_goal_prev_prev)
 816                                         strunzone(wcross_name_goal_prev_prev);
 817                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
 818                                 wcross_name_goal_prev = strzone(wcross_name);
 819                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 820                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 821                                 wcross_resolution_goal_prev = wcross_resolution;
 822                         }
 823
 824                         wcross_scale_goal_prev = wcross_scale;
 825                         wcross_alpha_goal_prev = wcross_alpha;
 826                         wcross_color_goal_prev = wcross_color;
 827
 828                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && cvar("crosshair_hittest_blur") && !cvar("chase_active")))
 829                         {
 830                                 wcross_blur = 1;
 831                                 wcross_alpha *= 0.75;
 832                         }
 833                         else
 834                                 wcross_blur = 0;
 835                         // *_prev is at time-frametime
 836                         // * is at wcross_changedonetime+f
 837                         // what do we have at time?
 838                         if(time < wcross_changedonetime)
 839                         {
 840                                 f = frametime / (wcross_changedonetime - time + frametime);
 841                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 842                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 843                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 844                         }
 845
 846                         wcross_scale_prev = wcross_scale;
 847                         wcross_alpha_prev = wcross_alpha;
 848                         wcross_color_prev = wcross_color;
 849
 850                         wcross_scale *= 1 - cvar("_menu_alpha");
 851                         wcross_alpha *= 1 - cvar("_menu_alpha");
 852
 853                         ring_scale = cvar("crosshair_ring_size");
 854
 855                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 856
 857                         float nex_charge, nex_charge_pool;
 858                         nex_charge = getstatf(STAT_NEX_CHARGE);
 859                         nex_charge_pool = getstatf(STAT_NEX_CHARGEPOOL);
 860
 861                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 862                                 nex_charge_movingavg = nex_charge;
 863
 864                         // ring around crosshair representing bullets left in camping rifle clip
 865                         if (activeweapon == WEP_CAMPINGRIFLE && cr_maxbullets)
 866                         {
 867                                 bullets = getstati(STAT_BULLETS_LOADED);
 868                                 f = bound(0, bullets / cr_maxbullets, 1);
 869
 870                                 a = cvar("crosshair_campingrifle_bulletcounter_alpha");
 871                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", f, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 872                         }
 873                         else if (activeweapon == WEP_NEX && nex_charge) // ring around crosshair representing velocity-dependent damage for the nex
 874                         {
 875                                 vector rgb;
 876                                 if(nex_charge_pool || use_nex_charge_pool)
 877                                 {
 878                                         use_nex_charge_pool = 1;
 879
 880                                         a = cvar("crosshair_nexvelocity_alpha");
 881                                         rgb = eX * cvar("crosshair_nexvelocity_currentcharge_color_red") + eY * cvar("crosshair_nexvelocity_currentcharge_color_green") + eZ * cvar("crosshair_nexvelocity_currentcharge_color_blue");
 882                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", nex_charge_pool, rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 883                                 }
 884                                 else
 885                                 {
 886                                         // indicate how much we're charging right now with an inner circle
 887                                         a = cvar("crosshair_nexvelocity_currentcharge_alpha");
 888                                         nex_charge_movingavg = (1 - cvar("crosshair_nexvelocity_currentcharge_movingavg_rate")) * nex_charge_movingavg + cvar("crosshair_nexvelocity_currentcharge_movingavg_rate") * nex_charge;
 889
 890                                         rgb = eX * cvar("crosshair_nexvelocity_currentcharge_color_red") + eY * cvar("crosshair_nexvelocity_currentcharge_color_green") + eZ * cvar("crosshair_nexvelocity_currentcharge_color_blue");
 891                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring_inner.tga", bound(0, cvar("crosshair_nexvelocity_currentcharge_scale") * (nex_charge - nex_charge_movingavg), 1), rgb, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 892                                 }
 893
 894                                 // draw the charge
 895                                 a = cvar("crosshair_nexvelocity_alpha");
 896                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, "gfx/crosshair_ring.tga", nex_charge, wcross_color, wcross_alpha * a, DRAWFLAG_ADDITIVE);
 897                         }
 898
 899 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 900                         do \
 901                         { \
 902                                 if(wcross_blur > 0) \
 903                                 { \
 904                                         for(i = -2; i <= 2; ++i) \
 905                                                 for(j = -2; j <= 2; ++j) \
 906                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 907                                 } \
 908                                 else \
 909                                 { \
 910                                         M(0,0,sz,wcross_name,wcross_alpha); \
 911                                 } \
 912                         } \
 913                         while(0)
 914
 915 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 916                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 917
 918 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 919                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 920
 921                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 922                         {
 923                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 924                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 925                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 926                                 f = 1 - f;
 927                         }
 928                         else
 929                         {
 930                                 f = 1;
 931                         }
 932
 933                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
 934                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 935
 936                         if(cvar("crosshair_dot"))
 937                                 CROSSHAIR_DRAW(wcross_resolution * cvar("crosshair_dot_size"), "gfx/crosshairdot.tga", wcross_alpha * f * cvar("crosshair_dot_alpha"));
 938
 939                         wcross_name_alpha_goal_prev = f;
 940                 }
 941                 else
 942                 {
 943                         wcross_scale_prev = 0;
 944                         wcross_alpha_prev = 0;
 945                         wcross_scale_goal_prev = 0;
 946                         wcross_alpha_goal_prev = 0;
 947                         wcross_changedonetime = 0;
 948                         if(wcross_name_goal_prev)
 949                                 strunzone(wcross_name_goal_prev);
 950                         wcross_name_goal_prev = string_null;
 951                         if(wcross_name_goal_prev_prev)
 952                                 strunzone(wcross_name_goal_prev_prev);
 953                         wcross_name_goal_prev_prev = string_null;
 954                         wcross_name_changestarttime = 0;
 955                         wcross_name_changedonetime = 0;
 956                         wcross_name_alpha_goal_prev = 0;
 957                         wcross_name_alpha_goal_prev_prev = 0;
 958                         wcross_resolution_goal_prev = 0;
 959                         wcross_resolution_goal_prev_prev = 0;
 960                 }
 961         }
 962
 963         if(NextFrameCommand)
 964         {
 965                 localcmd("\n", NextFrameCommand, "\n");
 966                 NextFrameCommand = string_null;
 967         }
 968
 969         // we must do this check AFTER a frame was rendered, or it won't work
 970         if(cs_project_is_b0rked == 0)
 971         {
 972                 string w0, h0;
 973                 w0 = cvar_string("vid_conwidth");
 974                 h0 = cvar_string("vid_conheight");
 975                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
 976                 //R_SetView(VF_FOV, '90 90 0');
 977                 R_SetView(VF_ORIGIN, '0 0 0');
 978                 R_SetView(VF_ANGLES, '0 0 0');
 979                 R_SetView(VF_PERSPECTIVE, 1);
 980                 makevectors('0 0 0');
 981                 vector v1, v2;
 982                 cvar_set("vid_conwidth", "800");
 983                 cvar_set("vid_conheight", "600");
 984                 v1 = cs_project(v_forward);
 985                 cvar_set("vid_conwidth", "640");
 986                 cvar_set("vid_conheight", "480");
 987                 v2 = cs_project(v_forward);
 988                 if(v1 == v2)
 989                         cs_project_is_b0rked = 1;
 990                 else
 991                         cs_project_is_b0rked = -1;
 992                 cvar_set("vid_conwidth", w0);
 993                 cvar_set("vid_conheight", h0);
 994         }
 995
 996         if(autocvar__hud_configure)
 997                 HUD_Panel_Mouse();
 998
 999         // let's reset the view back to normal for the end
1000         R_SetView(VF_MIN, '0 0 0');
1001         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1002 }
1003
1004 #define spider_h "gfx/vehicles/hud_bg.tga"
1005 #define spider_b "gfx/vehicles/sbot.tga"
1006 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1007 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1008 #define spider_s "gfx/vehicles/shiled.tga"
1009 #define spider_a1 "gfx/hud/sb_rocket.tga"
1010 #define spider_a2 "gfx/sb_bullets.tga"
1011
1012 void CSQC_SPIDER_HUD()
1013 {
1014         float rockets, reload, heat, hp, shield;
1015         vector picsize, hudloc;
1016
1017     // Fetch health & ammo stats
1018     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1019         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1020         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1021         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1022         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1023
1024     // Draw the crosshairs
1025     picsize = drawgetimagesize(SPIDER_CROSS);
1026     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1027     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1028     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1029
1030     hudloc_y =  4;
1031     hudloc_x = 4;
1032
1033     picsize = drawgetimagesize(spider_h) * 0.5;
1034     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1035
1036     picsize = drawgetimagesize(spider_a2) * 0.5;
1037     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1038
1039     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1040     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1041     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1042
1043     picsize = drawgetimagesize(spider_a1) * 0.85;
1044     if(rockets == 9)
1045     {
1046         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1047         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1048     }
1049     else
1050     {
1051         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1052         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1053     }
1054
1055     picsize = drawgetimagesize(spider_b) * 0.5;
1056     hudloc_y = 10.5;
1057     hudloc_x = 10.5;
1058
1059     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1060     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1061     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1062     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1063
1064
1065         /*
1066         // Draw health bar
1067         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1068         p = p + '0 1 0' * vid_conheight - '0 32 0';
1069         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1070         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1071         p_y += 8;
1072         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1073         p_x += 256 * hp;
1074         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1075
1076         // Draw minigun heat indicator
1077         p = '0.5 0 0' * (vid_conwidth - 256);
1078         p = p + '0 1 0' * vid_conheight - '0 34  0';
1079         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1080         p_x += 256 * (1-heat);
1081         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1082
1083
1084         // Draw rocket icons for loaded/empty tubes.
1085         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1086         pp += '0 1 0' * vid_conheight - '0 64 0';
1087         for(i = 0; i < 8; ++i)
1088         {
1089                 p = pp + '1 0 0' * (rkt_size * i);
1090                 if(rockets == 8)
1091                 {
1092                         if(floor(reload * 8) == i)
1093                         {
1094                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1095                         }
1096                         else if(i < reload * 8)
1097                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1098                         else
1099                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1100                 }
1101                 else
1102                 {
1103                         if(i < rockets)
1104                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1105                         else
1106                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1107                 }
1108         }
1109         */
1110
1111         if (scoreboard_showscores)
1112         {
1113                 HUD_DrawScoreboard();
1114                 HUD_DrawCenterPrint();
1115         }
1116
1117 }
1118
1119 #define raptor_h "gfx/vehicles/hud_bg.tga"
1120 #define raptor_b "gfx/vehicles/raptor.tga"
1121 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1122 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1123 #define raptor_s "gfx/vehicles/shiled.tga"
1124
1125 void CSQC_RAPTOR_HUD()
1126 {
1127         float reload, hp, shield, energy;
1128         vector picsize, hudloc;
1129
1130     // Fetch health & ammo stats
1131     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1132         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1133         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1134         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1135
1136     // Draw the crosshairs
1137     picsize = drawgetimagesize(SPIDER_CROSS);
1138     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1139     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1140     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1141
1142     hudloc_y =  4;
1143     hudloc_x = 4;
1144
1145     picsize = drawgetimagesize(raptor_h) * 0.5;
1146     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1147
1148     picsize = drawgetimagesize(spider_a2) * 0.5;
1149     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1150
1151     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1152     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1153     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1154
1155
1156     picsize = drawgetimagesize(spider_a1) * 0.85;
1157     if(reload == 1)
1158     {
1159         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1160         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1161     }
1162     else
1163     {
1164         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1165         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1166     }
1167
1168     picsize = drawgetimagesize(raptor_b) * 0.5;
1169     hudloc_y = 10.5;
1170     hudloc_x = 10.5;
1171
1172     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1173     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1174     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1175     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1176
1177
1178         if (scoreboard_showscores)
1179         {
1180                 HUD_DrawScoreboard();
1181                 HUD_DrawCenterPrint();
1182         }
1183
1184 }
1185
1186 #define waki_h "gfx/vehicles/hud_bg.tga"
1187 #define waki_b "gfx/vehicles/waki.tga"
1188 #define waki_e "gfx/vehicles/waki_e.tga"
1189 #define waki_g "gfx/vehicles/waki_guns.tga"
1190 #define waki_r "gfx/vehicles/waki_rockets.tga"
1191 #define waki_s "gfx/vehicles/shiled.tga"
1192
1193 #define waki_a1 "gfx/hud/sb_rocket.tga"
1194 #define waki_a2 "gfx/sb_cells.tga"
1195
1196 void CSQC_WAKIZASHI_HUD()
1197 {
1198         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1199         float health, shield, energy, rockets;
1200         vector picsize, hudloc;
1201
1202     picsize = drawgetimagesize(SPIDER_CROSS);
1203     picsize_x *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1204     picsize_y *= cvar_or("cl_vehicle_spiderbot_cross_size", 1);
1205     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', cvar_or("cl_vehicle_spiderbot_cross_alpha",0.6), DRAWFLAG_NORMAL);
1206
1207 /*
1208 const float STAT_VEHICLESTAT_HEALTH  = 60;
1209 const float STAT_VEHICLESTAT_SHIELD  = 61;
1210 const float STAT_VEHICLESTAT_ENERGY  = 62;
1211 const float STAT_VEHICLESTAT_AMMO1   = 63;
1212 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1213 const float STAT_VEHICLESTAT_AMMO2   = 65;
1214 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1215 */
1216     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1217         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1218         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1219         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1220
1221     hudloc_y =  4;
1222     hudloc_x = 4;
1223
1224     picsize = drawgetimagesize(waki_h) * 0.5;
1225     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1226
1227     picsize = drawgetimagesize(waki_a2) * 0.7;
1228     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1229
1230
1231     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1232     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1233
1234     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1235
1236     picsize = drawgetimagesize(waki_a1) * 0.75;
1237     if(rockets == 1)
1238     {
1239         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1240         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1241     }
1242     else
1243     {
1244         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1245         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1246         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1247     }
1248
1249     picsize = drawgetimagesize(waki_b) * 0.5;
1250     hudloc_y = 10.5;
1251     hudloc_x = 10.5;
1252
1253     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1254     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1255     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1256     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1257
1258
1259
1260         /*
1261         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1262         p = p + '0 1 0' * vid_conheight - '0 32 0';
1263
1264         // Draw health bar
1265         p_y += 8;
1266         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1267         p_x += 256 * health;
1268         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1269
1270         // Draw shiled bar
1271         p_x -= 256 * health;
1272         p_y += 4;
1273         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1274
1275         // Draw energy
1276         //p_x -= 256 * health;
1277         p_y -= 8;
1278         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1279
1280         // Draw rockets bar
1281         p_y += 12;
1282         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1283         */
1284
1285
1286
1287
1288         if (scoreboard_showscores)
1289         {
1290                 HUD_DrawScoreboard();
1291                 HUD_DrawCenterPrint();
1292         }
1293
1294 }
1295
1296
1297 void CSQC_common_hud(void)
1298 {
1299         // HUD_SortFrags(); done in HUD_Draw
1300         float hud;
1301         hud = getstati(STAT_HUD);
1302
1303         //hud = 10;
1304         switch(hud)
1305         {
1306                 case HUD_NORMAL:
1307                         // do some accuracy var caching
1308                         float i;
1309                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1310                         {
1311                                 if(cvar_string("accuracy_color_levels") != acc_color_levels)
1312                                 {
1313                                         if(acc_color_levels)
1314                                                 strunzone(acc_color_levels);
1315                                         acc_color_levels = strzone(cvar_string("accuracy_color_levels"));
1316                                         acc_levels = tokenize(acc_color_levels);
1317                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1318                                                 acc_levels = MAX_ACCURACY_LEVELS;
1319
1320                                         for (i = 0; i < acc_levels; ++i)
1321                                                 acc_lev[i] = stof(argv(i));
1322                                 }
1323                                 // let know that acc_col[] needs to be loaded
1324                                 acc_col_x[0] = -1;
1325                         }
1326
1327                         HUD_Main(); // always run these functions for alpha checks
1328                         HUD_DrawScoreboard();
1329
1330                         if (scoreboard_active) // scoreboard/accuracy
1331                         {
1332                                 HUD_Reset();
1333                                 // HUD_DrawScoreboard takes care of centerprint_start
1334                         }
1335                         else if (intermission == 2) // map voting screen
1336                         {
1337                                 HUD_FinaleOverlay();
1338                                 HUD_Reset();
1339
1340                                 centerprint_start_x = 0;
1341                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1342                         }
1343                         else // hud
1344                         {
1345                                 centerprint_start_x = 0;
1346                                 centerprint_start_y = cvar("scr_centerpos") * vid_conheight;
1347                         }
1348
1349                         HUD_DrawCenterPrint();
1350                         break;
1351
1352                 case HUD_SPIDERBOT:
1353                         CSQC_SPIDER_HUD();
1354                         break;
1355
1356                 case HUD_WAKIZASHI:
1357                         CSQC_WAKIZASHI_HUD();
1358                         break;
1359         }
1360 }
1361
1362
1363 // following vectors must be global to allow seamless switching between camera modes
1364 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1365 void CSQC_Demo_Camera()
1366 {
1367         float speed, attenuation, dimensions;
1368         vector tmp, delta;
1369
1370         if( cvar("camera_reset") || !camera_mode )
1371         {
1372                 camera_offset = '0 0 0';
1373                 current_angles = '0 0 0';
1374                 camera_direction = '0 0 0';
1375                 camera_offset_z += 30;
1376                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1377                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1378                 current_origin = view_origin;
1379                 current_camera_offset  = camera_offset;
1380                 cvar_set("camera_reset", "0");
1381                 camera_mode = CAMERA_CHASE;
1382         }
1383
1384         // Camera angles
1385         if( camera_roll )
1386                 mouse_angles_z += camera_roll * cvar("camera_speed_roll");
1387
1388         if(cvar("camera_look_player"))
1389         {
1390                 local vector dir;
1391                 local float n;
1392
1393                 dir = normalize(view_origin - current_position);
1394                 n = mouse_angles_z;
1395                 mouse_angles = vectoangles(dir);
1396                 mouse_angles_x = mouse_angles_x * -1;
1397                 mouse_angles_z = n;
1398         }
1399         else
1400         {
1401                 tmp = getmousepos() * 0.1;
1402                 if(vlen(tmp)>cvar("camera_mouse_treshold"))
1403                 {
1404                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1405                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1406                 }
1407         }
1408
1409         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1410         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1411         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1412         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1413
1414         // Fix difference when angles don't have the same sign
1415         delta = '0 0 0';
1416         if(mouse_angles_y < -60 && current_angles_y > 60)
1417                 delta = '0 360 0';
1418         if(mouse_angles_y > 60 && current_angles_y < -60)
1419                 delta = '0 -360 0';
1420
1421         if(cvar("camera_look_player"))
1422                 attenuation = cvar("camera_look_attenuation");
1423         else
1424                 attenuation = cvar("camera_speed_attenuation");
1425
1426         attenuation = 1 / max(1, attenuation);
1427         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1428
1429         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1430         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1431         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1432         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1433
1434         // Camera position
1435         tmp = '0 0 0';
1436         dimensions = 0;
1437
1438         if( camera_direction_x )
1439         {
1440                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1441                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1442                 if( cvar("camera_forward_follows") && !cvar("camera_look_player") )
1443                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1444                 ++dimensions;
1445         }
1446
1447         if( camera_direction_y )
1448         {
1449                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1450                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1451                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1452                 ++dimensions;
1453         }
1454
1455         if( camera_direction_z )
1456         {
1457                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1458                 ++dimensions;
1459         }
1460
1461         if(cvar("camera_free"))
1462                 speed = cvar("camera_speed_free");
1463         else
1464                 speed = cvar("camera_speed_chase");
1465
1466         if(dimensions)
1467         {
1468                 speed = speed * sqrt(1 / dimensions);
1469                 camera_offset += tmp * speed;
1470         }
1471
1472         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1473
1474         // Camera modes
1475         if( cvar("camera_free") )
1476         {
1477                 if ( camera_mode == CAMERA_CHASE )
1478                 {
1479                         current_camera_offset = current_origin + current_camera_offset;
1480                         camera_offset = current_origin + camera_offset;
1481                 }
1482
1483                 camera_mode = CAMERA_FREE;
1484                 current_position = current_camera_offset;
1485         }
1486         else
1487         {
1488                 if ( camera_mode == CAMERA_FREE )
1489                 {
1490                         current_origin = view_origin;
1491                         camera_offset = camera_offset - current_origin;
1492                         current_camera_offset = current_camera_offset - current_origin;
1493                 }
1494
1495                 camera_mode = CAMERA_CHASE;
1496
1497                 if(cvar("camera_chase_smoothly"))
1498                         current_origin += (view_origin - current_origin) * attenuation;
1499                 else
1500                         current_origin = view_origin;
1501
1502                 current_position = current_origin + current_camera_offset;
1503         }
1504
1505         R_SetView(VF_ANGLES, current_angles);
1506         R_SetView(VF_ORIGIN, current_position);
1507 }