qcsrc/client/hud.qh

   1 #ifndef HUD_H
   2 #define HUD_H
   3
   4 #if defined(CSQC)
   5         #include "../common/util-pre.qh"
   6         #include "sys-pre.qh"
   7         #include "../dpdefs/csprogsdefs.qc"
   8         #include "sys-post.qh"
   9         #include "Defs.qc"
  10         #include "../dpdefs/keycodes.qc"
  11         #include "../common/constants.qh"
  12         #include "../common/stats.qh"
  13         #include "../warpzonelib/anglestransform.qh"
  14         #include "../warpzonelib/mathlib.qh"
  15         #include "../warpzonelib/common.qh"
  16         #include "../warpzonelib/client.qh"
  17         #include "../common/playerstats.qh"
  18         #include "../common/teams.qh"
  19         #include "../common/util.qh"
  20         #include "../common/nades.qh"
  21         #include "../common/buffs.qh"
  22         #include "../common/test.qh"
  23         #include "../common/counting.qh"
  24         #include "../common/weapons/weapons.qh"
  25         #include "../common/mapinfo.qh"
  26         #include "../common/command/markup.qh"
  27         #include "../common/command/rpn.qh"
  28         #include "../common/command/generic.qh"
  29         #include "../common/command/shared_defs.qh"
  30         #include "../common/urllib.qh"
  31         #include "../common/animdecide.qh"
  32         #include "command/cl_cmd.qh"
  33         #include "../common/monsters/monsters.qh"
  34         #include "autocvars.qh"
  35         #include "../common/notifications.qh"
  36         #include "../common/deathtypes.qh"
  37         #include "damage.qh"
  38         #include "../csqcmodellib/interpolate.qh"
  39         #include "teamradar.qh"
  40 #elif defined(MENUQC)
  41 #elif defined(SVQC)
  42 #endif
  43
  44 const int HUD_PANEL_MAX = 24;
  45 entity hud_panel[HUD_PANEL_MAX];
  46 const int HUD_PANEL_FIRST = 0;
  47 int HUD_PANEL_NUM;
  48 int HUD_PANEL_LAST;
  49
  50 int panel_order[HUD_PANEL_MAX];
  51 string hud_panelorder_prev;
  52
  53 float hud_draw_maximized;
  54 float hud_panel_radar_maximized;
  55 float chat_panel_modified;
  56 float radar_panel_modified;
  57
  58 vector mousepos;
  59 vector panel_click_distance; // mouse cursor distance from the top left corner of the panel (saved only upon a click)
  60 vector panel_click_resizeorigin; // coordinates for opposite point when resizing
  61 float resizeCorner; // 1 = topleft, 2 = topright, 3 = bottomleft, 4 = bottomright
  62 entity highlightedPanel;
  63 float highlightedAction; // 0 = nothing, 1 = move, 2 = resize
  64
  65 const float BORDER_MULTIPLIER = 0.25;
  66 float scoreboard_bottom;
  67 int weapon_accuracy[WEP_MAXCOUNT];
  68
  69 int complain_weapon;
  70 string complain_weapon_name;
  71 float complain_weapon_type;
  72 float complain_weapon_time;
  73
  74 int ps_primary, ps_secondary;
  75 int ts_primary, ts_secondary;
  76
  77 float last_switchweapon;
  78 float last_activeweapon;
  79 float weapontime;
  80 float weaponprevtime;
  81
  82 float teamnagger;
  83
  84 float hud_configure_checkcollisions;
  85 float hud_configure_prev;
  86 vector hud_configure_gridSize;
  87 vector hud_configure_realGridSize;
  88
  89 int hudShiftState;
  90 const int S_SHIFT = 1;
  91 const int S_CTRL = 2;
  92 const int S_ALT = 4;
  93
  94 float menu_enabled; // 1 showing the entire HUD, 2 showing only the clicked panel
  95
  96 float hud_fade_alpha;
  97
  98 string hud_skin_path;
  99 string hud_skin_prev;
 100
 101 vector myteamcolors;
 102
 103 entity highlightedPanel_backup;
 104 vector panel_pos_backup;
 105 vector panel_size_backup;
 106
 107 vector panel_size_copied;
 108
 109 entity panel;
 110 .string panel_name;
 111 .int panel_id;
 112 .vector current_panel_pos;
 113 .vector current_panel_size;
 114 .string current_panel_bg;
 115 .float current_panel_bg_alpha;
 116 .float current_panel_bg_border;
 117 .vector current_panel_bg_color;
 118 .float current_panel_bg_color_team;
 119 .float current_panel_bg_padding;
 120 .float current_panel_fg_alpha;
 121 .float update_time;
 122 float panel_enabled;
 123 vector panel_pos;
 124 vector panel_size;
 125 string panel_bg_str; // "_str" vars contain the raw value of the cvar, non-"_str" contains what hud.qc code should use
 126 vector panel_bg_color;
 127 string panel_bg_color_str;
 128 float panel_bg_color_team;
 129 string panel_bg_color_team_str;
 130 float panel_fg_alpha;
 131 float panel_bg_alpha;
 132 string panel_bg_alpha_str;
 133 float panel_bg_border;
 134 string panel_bg_border_str;
 135 float panel_bg_padding;
 136 string panel_bg_padding_str;
 137
 138 .void() panel_draw;
 139
 140 float current_player;
 141
 142
 143 #define HUD_PANELS(HUD_PANEL)                                                                                                                                                                           \
 144         HUD_PANEL(WEAPONS      , HUD_Weapons      , weapons)                                                                                                                    \
 145         HUD_PANEL(AMMO         , HUD_Ammo         , ammo)                                                                                                                               \
 146         HUD_PANEL(POWERUPS     , HUD_Powerups     , powerups)                                                                                                                   \
 147         HUD_PANEL(HEALTHARMOR  , HUD_HealthArmor  , healtharmor)                                                                                                                \
 148         HUD_PANEL(NOTIFY       , HUD_Notify       , notify)                                                                                                                     \
 149         HUD_PANEL(TIMER        , HUD_Timer        , timer)                                                                                                                              \
 150         HUD_PANEL(RADAR        , HUD_Radar        , radar)                                                                                                                              \
 151         HUD_PANEL(SCORE        , HUD_Score        , score)                                                                                                                              \
 152         HUD_PANEL(RACETIMER    , HUD_RaceTimer    , racetimer)                                                                                                                  \
 153         HUD_PANEL(VOTE         , HUD_Vote         , vote)                                                                                                                               \
 154         HUD_PANEL(MODICONS     , HUD_ModIcons     , modicons)                                                                                                                   \
 155         HUD_PANEL(PRESSEDKEYS  , HUD_PressedKeys  , pressedkeys)                                                                                                                \
 156         HUD_PANEL(CHAT         , HUD_Chat         , chat)                                                                                                                               \
 157         HUD_PANEL(ENGINEINFO   , HUD_EngineInfo   , engineinfo)                                                                                                                 \
 158         HUD_PANEL(INFOMESSAGES , HUD_InfoMessages , infomessages)                                                                                                               \
 159         HUD_PANEL(PHYSICS      , HUD_Physics      , physics)                                                                                                                    \
 160         HUD_PANEL(CENTERPRINT  , HUD_CenterPrint  , centerprint)                                                                                                                \
 161         HUD_PANEL(BUFFS        , HUD_Buffs        , buffs)
 162
 163 #define HUD_PANEL(NAME, draw_func, name)                                                                                                                                                        \
 164         int HUD_PANEL_##NAME;                                                                                                                                                                                   \
 165         void draw_func(void);                                                                                                                                                                                   \
 166         void RegisterHUD_Panel_##NAME() {                                                                                                                                                               \
 167                 HUD_PANEL_LAST = HUD_PANEL_##NAME = HUD_PANEL_NUM;                                                                                                                      \
 168                 entity hud_panelent = spawn();                                                                                                                                                          \
 169                 hud_panel[HUD_PANEL_##NAME] = hud_panelent;                                                                                                                             \
 170                 hud_panelent.classname = "hud_panel";                                                                                                                                           \
 171                 hud_panelent.panel_name = #name;                                                                                                                                                        \
 172                 hud_panelent.panel_id = HUD_PANEL_##NAME;                                                                                                                                       \
 173                 hud_panelent.panel_draw = draw_func;                                                                                                                                            \
 174                 HUD_PANEL_NUM++;                                                                                                                                                                                        \
 175         }                                                                                                                                                                                                                               \
 176         ACCUMULATE_FUNCTION(RegisterHUD_Panels, RegisterHUD_Panel_##NAME);
 177
 178 HUD_PANELS(HUD_PANEL)
 179 #undef HUD_PANEL
 180
 181 #define HUD_PANEL(NAME) hud_panel[HUD_PANEL_##NAME]
 182
 183
 184 // Because calling lots of functions in QC apparently cuts fps in half on many machines:
 185 // ----------------------
 186 // MACRO HELL STARTS HERE
 187 // ----------------------
 188 // Little help for the poor people who have to make sense of this: Start from the bottom ;)
 189
 190 // Get value for panel.current_panel_bg: if "" fetch default, else use panel_bg_str
 191 // comment on last line of macro: // we probably want to see a background in config mode at all times...
 192 #define HUD_Panel_GetBg() do {                                                                                      \
 193         string panel_bg;                                                                                                \
 194         if (!autocvar__hud_configure && panel_bg_str == "0") {                                                          \
 195                 panel_bg = "0";                                                                                             \
 196         } else {                                                                                                        \
 197                 if (panel_bg_str == "") {                                                                                   \
 198                         panel_bg_str = autocvar_hud_panel_bg;                                                                   \
 199                 }                                                                                                           \
 200                 if (panel_bg_str == "0" && !autocvar__hud_configure) {                                                      \
 201                         panel_bg = "0";                                                                                         \
 202                 } else {                                                                                                    \
 203                         if (panel_bg_str == "0" && autocvar__hud_configure)                                                     \
 204                                 panel_bg_alpha_str = "0";                                                                           \
 205                         panel_bg = strcat(hud_skin_path, "/", panel_bg_str);                                                    \
 206                         if (precache_pic(panel_bg) == "") {                                                                     \
 207                                 panel_bg = strcat(hud_skin_path, "/", "border_default");                                            \
 208                                 if (precache_pic(panel_bg) == "") {                                                                 \
 209                                         panel_bg = strcat("gfx/hud/default/", "border_default");                                        \
 210                                 }                                                                                                   \
 211                         }                                                                                                       \
 212                 }                                                                                                           \
 213         }                                                                                                               \
 214         if (panel.current_panel_bg)                                                                                     \
 215                 strunzone(panel.current_panel_bg);                                                                          \
 216         panel.current_panel_bg = strzone(panel_bg);                                                                     \
 217 } while(0)
 218
 219 // Get value for panel_bg_color: if "" fetch default, else use panel_bg_color. Convert pants, shirt or teamcolor into a vector.
 220 #define HUD_Panel_GetColor() do {                                                                                   \
 221         if ((teamplay) && panel_bg_color_team) {                                                                        \
 222                 if (autocvar__hud_configure && myteam == NUM_SPECTATOR)                                                     \
 223                         panel_bg_color = '1 0 0' * panel_bg_color_team;                                                         \
 224                 else                                                                                                        \
 225                         panel_bg_color = myteamcolors * panel_bg_color_team;                                                    \
 226         } else if (autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && panel_bg_color_team) {          \
 227                 panel_bg_color = '1 0 0' * panel_bg_color_team;                                                             \
 228         } else {                                                                                                        \
 229                 if (panel_bg_color_str == "") {                                                                             \
 230                         panel_bg_color = autocvar_hud_panel_bg_color;                                                           \
 231                 } else {                                                                                                    \
 232                         if (panel_bg_color_str == "shirt") {                                                                    \
 233                                 panel_bg_color = colormapPaletteColor(floor(stof(getplayerkeyvalue(current_player - 1, "colors")) / 16), 0);\
 234                         } else if (panel_bg_color_str == "pants") {                                                             \
 235                                 panel_bg_color = colormapPaletteColor(stof(getplayerkeyvalue(current_player - 1, "colors")) % 16, 1);\
 236                         } else {                                                                                                \
 237                                 panel_bg_color = stov(panel_bg_color_str);                                                          \
 238                         }                                                                                                       \
 239                 }                                                                                                           \
 240         }                                                                                                               \
 241 } while(0)
 242
 243 // Get value for panel_bg_color_team: if "" fetch default, else use panel_bg_color_team_str
 244 #define HUD_Panel_GetColorTeam() do {                                                                               \
 245         if (panel_bg_color_team_str == "") {                                                                            \
 246                 panel_bg_color_team = autocvar_hud_panel_bg_color_team;                                                     \
 247         } else {                                                                                                        \
 248                 panel_bg_color_team = stof(panel_bg_color_team_str);                                                        \
 249         }                                                                                                               \
 250 } while(0)
 251
 252 // Get value for panel_bg_alpha: if "" fetch default, else use panel_bg_alpha. Also do various menu dialog fadeout/in checks, and minalpha checks
 253 // comment on line 3 of macro: // do not set a minalpha cap when showing the config dialog for this panel
 254 #define HUD_Panel_GetBgAlpha() do {                                                                                 \
 255         if (panel_bg_alpha_str == "") {                                                                                 \
 256                 panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);                                                     \
 257         }                                                                                                               \
 258         panel_bg_alpha = stof(panel_bg_alpha_str);                                                                      \
 259         if (autocvar__hud_configure) {                                                                                  \
 260                 if (!panel_enabled)                                                                                         \
 261                         panel_bg_alpha = 0.25;                                                                                  \
 262                 else if (menu_enabled == 2 && panel == highlightedPanel)                                                    \
 263                         panel_bg_alpha = (1 - autocvar__menu_alpha) * max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha) + autocvar__menu_alpha * panel_bg_alpha;\
 264                 else                                                                                                        \
 265                         panel_bg_alpha = max(cvar("hud_configure_bg_minalpha"), panel_bg_alpha);                                \
 266         }                                                                                                               \
 267 } while(0)
 268
 269 // Get value for panel_fg_alpha. Also do various minalpha checks
 270 // comment on line 2 of macro: // ALWAYS show disabled panels at 0.25 alpha when in config mode
 271 #define HUD_Panel_GetFgAlpha() do {                                                                                 \
 272         panel_fg_alpha = autocvar_hud_panel_fg_alpha;                                                                   \
 273         if (autocvar__hud_configure && !panel_enabled)                                                                  \
 274                 panel_fg_alpha = 0.25;                                                                                      \
 275 } while(0)
 276
 277 // Get border. See comments above, it's similar.
 278 #define HUD_Panel_GetBorder() do {                                                                                  \
 279         if (panel_bg_border_str == "") {                                                                                \
 280                 panel_bg_border = autocvar_hud_panel_bg_border;                                                             \
 281         } else {                                                                                                        \
 282                 panel_bg_border = stof(panel_bg_border_str);                                                                \
 283         }                                                                                                               \
 284 } while(0)
 285
 286 // Get padding. See comments above, it's similar.
 287 // last line is a port of the old function, basically always make sure the panel contents are at least 5 pixels tall/wide, to disallow extreme padding values
 288 #define HUD_Panel_GetPadding() do {                                                                                 \
 289         if (panel_bg_padding_str == "") {                                                                               \
 290                 panel_bg_padding = autocvar_hud_panel_bg_padding;                                                           \
 291         } else {                                                                                                        \
 292                 panel_bg_padding = stof(panel_bg_padding_str);                                                              \
 293         }                                                                                                               \
 294         panel_bg_padding = min(min(panel_size_x, panel_size_y)/2 - 5, panel_bg_padding);                                \
 295 } while(0)
 296
 297 // return smoothly faded pos and size of given panel when a dialog is active
 298 #define HUD_Panel_UpdatePosSize_ForMenu() do {                                                                      \
 299         vector menu_enable_pos;                                                                                         \
 300         vector menu_enable_size = '0 0 0';                                                                              \
 301         float menu_enable_maxsize_x = 0.3 * vid_conwidth;                                                               \
 302         float menu_enable_maxsize_y = 0.18 * vid_conheight;                                                             \
 303         if (panel_size_x > panel_size_y) {                                                                              \
 304                 if (panel_size_y > menu_enable_maxsize_y) {                                                                 \
 305                         menu_enable_size_y = menu_enable_maxsize_y;                                                             \
 306                         menu_enable_size_x = panel_size_x * (menu_enable_maxsize_y/panel_size_y);                               \
 307                         panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;       \
 308                 }                                                                                                           \
 309                 menu_enable_pos = eX * 0.5 * vid_conwidth - eX * 0.5 * panel_size_x + eY * (vid_conheight - menu_enable_maxsize_y);\
 310         } else {                                                                                                        \
 311                 if (panel_size_x > menu_enable_maxsize_x) {                                                                 \
 312                         menu_enable_size_x = menu_enable_maxsize_x;                                                             \
 313                         menu_enable_size_y = panel_size_y * (menu_enable_maxsize_x/panel_size_x);                               \
 314                         panel_size = (1 - autocvar__menu_alpha) * panel_size + (autocvar__menu_alpha) * menu_enable_size;       \
 315                 }                                                                                                           \
 316                 menu_enable_pos = eY * 0.5 * vid_conheight - eY * 0.5 * panel_size_y + eX * (vid_conwidth - menu_enable_maxsize_x);\
 317         }                                                                                                               \
 318         panel_pos = (1 - autocvar__menu_alpha) * panel_pos + (autocvar__menu_alpha) * menu_enable_pos;                  \
 319 } while(0)
 320
 321 // Scale the pos and size vectors to absolute coordinates
 322 #define HUD_Panel_ScalePosSize() do {                                                                               \
 323         panel_pos_x *= vid_conwidth;  panel_pos_y *= vid_conheight;                                                     \
 324         panel_size_x *= vid_conwidth; panel_size_y *= vid_conheight;                                                    \
 325 } while(0)
 326
 327 // NOTE: in hud_configure mode cvars must be reloaded every frame
 328 #define HUD_Panel_UpdateCvars() do {                                                                                \
 329         if (panel.update_time <= time) {                                                                                \
 330                 if (autocvar__hud_configure) panel_enabled = cvar(strcat("hud_panel_", panel.panel_name));                  \
 331                 panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));                              \
 332                 panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));                            \
 333                 HUD_Panel_ScalePosSize();                                                                                   \
 334                 panel_bg_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg"));                                  \
 335                 panel_bg_color_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color"));                      \
 336                 panel_bg_color_team_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_color_team"));            \
 337                 panel_bg_alpha_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_alpha"));                      \
 338                 panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));                    \
 339                 panel_bg_padding_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_padding"));                  \
 340                 HUD_Panel_GetBg();                                                                                          \
 341                 if (panel.current_panel_bg != "0") {                                                                        \
 342                         HUD_Panel_GetColorTeam();                                                                               \
 343                         HUD_Panel_GetColor();                                                                                   \
 344                         HUD_Panel_GetBgAlpha();                                                                                 \
 345                         HUD_Panel_GetBorder();                                                                                  \
 346                 }                                                                                                           \
 347                 HUD_Panel_GetFgAlpha();                                                                                     \
 348                 HUD_Panel_GetPadding();                                                                                     \
 349                 panel.current_panel_bg_alpha = panel_bg_alpha;                                                              \
 350                 panel.current_panel_fg_alpha = panel_fg_alpha;                                                              \
 351                 if (menu_enabled == 2 && panel == highlightedPanel) {                                                       \
 352                         HUD_Panel_UpdatePosSize_ForMenu();                                                                      \
 353                 } else {                                                                                                    \
 354                         panel_bg_alpha *= hud_fade_alpha;                                                                       \
 355                         panel_fg_alpha *= hud_fade_alpha;                                                                       \
 356                 }                                                                                                           \
 357                 panel.current_panel_pos = panel_pos;                                                                        \
 358                 panel.current_panel_size = panel_size;                                                                      \
 359                 panel.current_panel_bg_border = panel_bg_border;                                                            \
 360                 panel.current_panel_bg_color = panel_bg_color;                                                              \
 361                 panel.current_panel_bg_color_team = panel_bg_color_team;                                                    \
 362                 panel.current_panel_bg_padding = panel_bg_padding;                                                          \
 363                 panel.update_time = (autocvar__hud_configure) ? time : time + autocvar_hud_panel_update_interval;           \
 364         } else {                                                                                                        \
 365                 panel_pos = panel.current_panel_pos;                                                                        \
 366                 panel_size = panel.current_panel_size;                                                                      \
 367                 panel_bg_alpha = panel.current_panel_bg_alpha * hud_fade_alpha;                                             \
 368                 panel_bg_border = panel.current_panel_bg_border;                                                            \
 369                 panel_bg_color = panel.current_panel_bg_color;                                                              \
 370                 panel_bg_color_team = panel.current_panel_bg_color_team;                                                    \
 371                 panel_bg_padding = panel.current_panel_bg_padding;                                                          \
 372                 panel_fg_alpha = panel.current_panel_fg_alpha * hud_fade_alpha;                                             \
 373         }                                                                                                               \
 374 } while(0)
 375
 376 #define HUD_Panel_UpdatePosSize() do {                                                                              \
 377         panel_enabled = cvar(strcat("hud_panel_", panel.panel_name));                                                   \
 378         panel_pos = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_pos")));                                  \
 379         panel_size = stov(cvar_string(strcat("hud_panel_", panel.panel_name, "_size")));                                \
 380         HUD_Panel_ScalePosSize();                                                                                       \
 381         if (menu_enabled == 2 && panel == highlightedPanel) {                                                           \
 382                 HUD_Panel_UpdatePosSize_ForMenu();                                                                          \
 383         }                                                                                                               \
 384         panel_bg_border_str = cvar_string(strcat("hud_panel_", panel.panel_name, "_bg_border"));                        \
 385         HUD_Panel_GetBorder();                                                                                          \
 386 } while(0)
 387
 388 const float NOTIFY_MAX_ENTRIES = 10;
 389 const float NOTIFY_ICON_MARGIN = 0.02;
 390
 391 int notify_index;
 392 int notify_count;
 393 float notify_times[NOTIFY_MAX_ENTRIES];
 394 string notify_attackers[NOTIFY_MAX_ENTRIES];
 395 string notify_victims[NOTIFY_MAX_ENTRIES];
 396 string notify_icons[NOTIFY_MAX_ENTRIES];
 397
 398 void HUD_Notify_Push(string icon, string attacker, string victim);
 399
 400 var void HUD_ModIcons_GameType(vector pos, vector size);
 401 void HUD_ModIcons_SetFunc();
 402 #endif