935f2b66753eed85925f4463884cc3b9136988f0
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / main.qc
1 #include "main.qh"
2
3 #include "defs.qh"
4 #include <common/ent_cs.qh>
5 #include "miscfunctions.qh"
6 #include <common/effects/effect.qh>
7 #include <common/effects/qc/_mod.qh>
8 #include <common/effects/all.qh>
9 #include <common/effects/all.inc>
10 #include "hud/_mod.qh"
11 #include "mapvoting.qh"
12 #include "mutators/events.qh"
13 #include "hud/panel/scoreboard.qh"
14 #include "hud/panel/quickmenu.qh"
15 #include "shownames.qh"
16 #include <common/t_items.qh>
17 #include "wall.qh"
18 #include "weapons/projectile.qh"
19 #include <common/deathtypes/all.qh>
20 #include <common/items/_mod.qh>
21 #include <common/mapinfo.qh>
22 #include <common/minigames/cl_minigames.qh>
23 #include <common/minigames/cl_minigames_hud.qh>
24 #include <common/net_linked.qh>
25 #include <common/net_notice.qh>
26 #include <common/scores.qh>
27 #include <common/triggers/include.qh>
28 #include <common/vehicles/all.qh>
29 #include <lib/csqcmodel/cl_model.qh>
30 #include <lib/csqcmodel/interpolate.qh>
31 #include <lib/warpzone/client.qh>
32
33 // --------------------------------------------------------------------------
34 // BEGIN REQUIRED CSQC FUNCTIONS
35 //include "main.qh"
36
37 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
38
39 void draw_cursor(vector pos, vector ofs, string img, vector col, float a)
40 {
41         ofs = vec2(ofs.x * SIZE_CURSOR.x, ofs.y * SIZE_CURSOR.y);
42         drawpic(pos - ofs, strcat(draw_currentSkin, img), SIZE_CURSOR, col, a, DRAWFLAG_NORMAL);
43 }
44
45 void draw_cursor_normal(vector pos, vector col, float a)
46 {
47         draw_cursor(pos, OFFSET_CURSOR, "/cursor", col, a);
48 }
49
50 void LoadMenuSkinValues()
51 {
52         int fh = -1;
53         if(cvar_string("menu_skin") != "")
54         {
55                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
56                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
57         }
58         if(fh < 0 && cvar_defstring("menu_skin") != "")
59         {
60                 cvar_set("menu_skin", cvar_defstring("menu_skin"));
61                 draw_currentSkin = strcat("gfx/menu/", cvar_string("menu_skin"));
62                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
63         }
64         if(fh < 0)
65         {
66                 draw_currentSkin = "gfx/menu/default";
67                 fh = fopen(strcat(draw_currentSkin, "/skinvalues.txt"), FILE_READ);
68         }
69
70         draw_currentSkin = strzone(draw_currentSkin);
71
72         if(fh >= 0)
73         {
74                 string s;
75                 while((s = fgets(fh)))
76                 {
77                         int n = tokenize_console(s);
78                         if (n < 2)
79                                 continue;
80                         if(substring(argv(0), 0, 2) == "//")
81                                 continue;
82                         if(argv(0) == "SIZE_CURSOR")
83                                 SIZE_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
84                         else if(argv(0) == "OFFSET_CURSOR")
85                                 OFFSET_CURSOR = stov(substring(s, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
86                 }
87                 fclose(fh);
88         }
89 }
90
91 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
92 // Useful for precaching things
93
94 void ConsoleCommand_macro_init();
95 void CSQC_Init()
96 {
97         prvm_language = strzone(cvar_string("prvm_language"));
98
99 #ifdef WATERMARK
100         LOG_INFOF("^4CSQC Build information: ^1%s", WATERMARK);
101 #endif
102
103         {
104                 int i = 0;
105                 for ( ; i < 255; ++i)
106                         if (getplayerkeyvalue(i, "viewentity") == "")
107                                 break;
108                 maxclients = i;
109         }
110
111         // needs to be done so early because of the constants they create
112         static_init();
113         static_init_late();
114         static_init_precache();
115
116         binddb = db_create();
117         tempdb = db_create();
118         ClientProgsDB = db_load("client.db");
119
120         draw_endBoldFont();
121
122         //registercommand("hud_configure");
123         //registercommand("hud_save");
124         //registercommand("menu_action");
125
126         ConsoleCommand_macro_init();
127
128         registercvar("hud_usecsqc", "1");
129         registercvar("scoreboard_columns", "default");
130
131         registercvar("cl_nade_type", "3");
132         registercvar("cl_pokenade_type", "zombie");
133
134         registercvar("cl_jumpspeedcap_min", "");
135         registercvar("cl_jumpspeedcap_max", "");
136
137         registercvar("cl_shootfromfixedorigin", "");
138
139         registercvar("cl_multijump", "1");
140
141         registercvar("cl_spawn_near_teammate", "1");
142
143         if(autocvar_cl_lockview)
144                 cvar_set("cl_lockview", "0");
145
146         gametype = NULL;
147
148         postinit = false;
149
150         calledhooks = 0;
151
152         teams = Sort_Spawn();
153         players = Sort_Spawn();
154
155         GetTeam(NUM_SPECTATOR, true); // add specs first
156
157         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
158                 weapon_accuracy[w] = -1;
159
160         // precaches
161
162         if(autocvar_cl_reticle)
163         {
164                 precache_pic("gfx/reticle_normal");
165                 // weapon reticles are precached in weapon files
166         }
167
168         {
169                 get_mi_min_max_texcoords(1); // try the CLEVER way first
170                 minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
171                 shortmapname = mi_shortname;
172
173                 if (precache_pic(minimapname) == "")
174                 {
175                         // but maybe we have a non-clever minimap
176                         minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
177                         if (precache_pic(minimapname) == "")
178                                 minimapname = ""; // FAIL
179                         else
180                                 get_mi_min_max_texcoords(0); // load new texcoords
181                 }
182
183                 mi_center = (mi_min + mi_max) * 0.5;
184                 mi_scale = mi_max - mi_min;
185                 minimapname = strzone(minimapname);
186         }
187
188         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
189         LoadMenuSkinValues();
190 }
191
192 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
193 void Shutdown()
194 {
195         WarpZone_Shutdown();
196
197         delete(teams);
198         delete(players);
199         db_close(binddb);
200         db_close(tempdb);
201         if(autocvar_cl_db_saveasdump)
202                 db_dump(ClientProgsDB, "client.db");
203         else
204                 db_save(ClientProgsDB, "client.db");
205         db_close(ClientProgsDB);
206
207         if(camera_active)
208                 cvar_set("chase_active",ftos(chase_active_backup));
209
210         // unset the event chasecam's chase_active
211         if(autocvar_chase_active < 0)
212                 cvar_set("chase_active", "0");
213
214         cvar_set("slowmo", cvar_defstring("slowmo")); // reset it back to 'default'
215
216         if (!isdemo())
217         {
218                 if (!(calledhooks & HOOK_START))
219                         localcmd("\n_cl_hook_gamestart nop\n");
220                 if (!(calledhooks & HOOK_END))
221                         localcmd("\ncl_hook_gameend\n");
222         }
223
224         localcmd("\ncl_hook_shutdown\n");
225
226         deactivate_minigame();
227         HUD_MinigameMenu_Close(NULL, NULL, NULL);
228 }
229
230 .float has_team;
231 float SetTeam(entity o, int Team)
232 {
233     TC(int, Team);
234         devassert_once(Team);
235         entity tm;
236         if(teamplay)
237         {
238                 switch(Team)
239                 {
240                         case -1:
241                         case NUM_TEAM_1:
242                         case NUM_TEAM_2:
243                         case NUM_TEAM_3:
244                         case NUM_TEAM_4:
245                                 break;
246                         default:
247                                 if(GetTeam(Team, false) == NULL)
248                                 {
249                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
250                                         Team = NUM_SPECTATOR;
251                                 }
252                                 break;
253                 }
254         }
255         else
256         {
257                 switch(Team)
258                 {
259                         case -1:
260                         case 0:
261                                 break;
262                         default:
263                                 if(GetTeam(Team, false) == NULL)
264                                 {
265                                         LOG_TRACEF("trying to switch to unsupported team %d", Team);
266                                         Team = NUM_SPECTATOR;
267                                 }
268                                 break;
269                 }
270         }
271         if(Team == -1) // leave
272         {
273                 if(o.has_team)
274                 {
275                         tm = GetTeam(o.team, false);
276                         tm.team_size -= 1;
277                         o.has_team = 0;
278                         return true;
279                 }
280         }
281         else
282         {
283                 if (!o.has_team)
284                 {
285                         o.team = Team;
286                         tm = GetTeam(Team, true);
287                         tm.team_size += 1;
288                         o.has_team = 1;
289                         return true;
290                 }
291                 else if(Team != o.team)
292                 {
293                         tm = GetTeam(o.team, false);
294                         tm.team_size -= 1;
295                         o.team = Team;
296                         tm = GetTeam(Team, true);
297                         tm.team_size += 1;
298                         return true;
299                 }
300         }
301         return false;
302 }
303
304 void Playerchecker_Think(entity this)
305 {
306     int i;
307         entity e;
308         for(i = 0; i < maxclients; ++i)
309         {
310                 e = playerslots[i];
311                 if(entcs_GetName(i) == "")
312                 {
313                         if(e.sort_prev)
314                         {
315                                 // player disconnected
316                                 SetTeam(e, -1);
317                                 RemovePlayer(e);
318                                 e.sort_prev = NULL;
319                                 //e.gotscores = 0;
320                         }
321                 }
322                 else
323                 {
324                         if (!e.sort_prev)
325                         {
326                                 // player connected
327                                 if (!e)
328                                 {
329                                         playerslots[i] = e = new_pure(playerslot);
330                                 }
331                                 e.sv_entnum = i;
332                                 e.ping = 0;
333                                 e.ping_packetloss = 0;
334                                 e.ping_movementloss = 0;
335                                 //e.gotscores = 0; // we might already have the scores...
336                                 int t = entcs_GetScoreTeam(i);
337                                 if (t) SetTeam(e, t); // will not hurt; later updates come with Scoreboard_UpdatePlayerTeams
338                                 RegisterPlayer(e);
339                                 Scoreboard_UpdatePlayerPos(e);
340                         }
341                 }
342         }
343         this.nextthink = time + 0.2;
344 }
345
346 void TrueAim_Init();
347 void PostInit()
348 {
349         entity playerchecker = new_pure(playerchecker);
350         setthink(playerchecker, Playerchecker_Think);
351         playerchecker.nextthink = time + 0.2;
352
353         TrueAim_Init();
354
355         postinit = true;
356 }
357
358 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
359 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
360 // All keys are in ascii.
361 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
362 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
363 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
364 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
365 float CSQC_InputEvent(int bInputType, float nPrimary, float nSecondary)
366 {
367     TC(int, bInputType);
368         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
369                 return true;
370
371         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
372                 return true;
373
374         if (HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary))
375                 return true;
376
377         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
378                 return true;
379
380         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
381                 return true;
382
383         return false;
384 }
385
386 // END REQUIRED CSQC FUNCTIONS
387 // --------------------------------------------------------------------------
388
389 // --------------------------------------------------------------------------
390 // BEGIN OPTIONAL CSQC FUNCTIONS
391
392 void Ent_Remove(entity this);
393
394 void Ent_RemovePlayerScore(entity this)
395 {
396         if(this.owner) {
397                 SetTeam(this.owner, -1);
398                 this.owner.gotscores = 0;
399                 FOREACH(Scores, true, {
400                         this.owner.(scores(it)) = 0; // clear all scores
401                 });
402         }
403 }
404
405 NET_HANDLE(ENT_CLIENT_SCORES, bool isnew)
406 {
407         make_pure(this);
408         entity o;
409
410         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
411         // (no I've never heard of M-x replace-string, sed, or anything like that)
412         bool isNew = !this.owner; // workaround for DP bug
413         int n = ReadByte()-1;
414
415 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
416         if(!isNew && n != this.sv_entnum)
417         {
418                 //print("A CSQC entity changed its owner!\n");
419                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)", etof(this), this.classname);
420                 isNew = true;
421                 Ent_Remove(this);
422         }
423 #endif
424
425         this.sv_entnum = n;
426
427         o = playerslots[this.sv_entnum];
428         if (!o)
429         {
430                 o = playerslots[this.sv_entnum] = new_pure(playerslot);
431         }
432         this.owner = o;
433         o.sv_entnum = this.sv_entnum;
434         o.gotscores = 1;
435
436         //if (!o.sort_prev)
437         //      RegisterPlayer(o);
438         //playerchecker will do this for us later, if it has not already done so
439
440         int sf = ReadShort();
441         int lf = ReadShort();
442         FOREACH(Scores, true, {
443                 int p = 1 << (i % 16);
444                 if (sf & p)
445                 {
446                         if (lf & p)
447                                 o.(scores(it)) = ReadInt24_t();
448                         else
449                                 o.(scores(it)) = ReadChar();
450                 }
451         });
452
453         return = true;
454
455         if(o.sort_prev)
456                 Scoreboard_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
457
458         this.entremove = Ent_RemovePlayerScore;
459 }
460
461 NET_HANDLE(ENT_CLIENT_TEAMSCORES, bool isnew)
462 {
463         make_pure(this);
464         int i;
465
466         this.team = ReadByte();
467         entity o = this.owner = GetTeam(this.team, true); // these team numbers can always be trusted
468
469 #if MAX_TEAMSCORE <= 8
470         int sf = ReadByte();
471         int lf = ReadByte();
472 #else
473         int sf = ReadShort();
474         int lf = ReadShort();
475 #endif
476         for(i = 0; i < MAX_TEAMSCORE; ++i)
477                 if(sf & BIT(i))
478                 {
479                         if(lf & BIT(i))
480                                 o.(teamscores(i)) = ReadInt24_t();
481                         else
482                                 o.(teamscores(i)) = ReadChar();
483                 }
484
485         return = true;
486
487         Scoreboard_UpdateTeamPos(o);
488 }
489
490 NET_HANDLE(ENT_CLIENT_CLIENTDATA, bool isnew)
491 {
492         make_pure(this);
493         float newspectatee_status;
494
495         int f = ReadByte();
496
497         scoreboard_showscores_force = (f & BIT(0));
498
499         if(f & BIT(1))
500         {
501                 newspectatee_status = ReadByte();
502                 if(newspectatee_status == player_localnum + 1)
503                         newspectatee_status = -1; // observing
504         }
505         else
506                 newspectatee_status = 0;
507
508         spectatorbutton_zoom = (f & BIT(2));
509
510         if(f & BIT(4))
511         {
512                 num_spectators = ReadByte();
513
514                 float i, slot;
515
516                 for(i = 0; i < MAX_SPECTATORS; ++i)
517                         spectatorlist[i] = 0; // reset list first
518
519                 for(i = 0; i < num_spectators; ++i)
520                 {
521                         slot = ReadByte();
522                         spectatorlist[i] = slot - 1;
523                 }
524         }
525
526         return = true;
527
528         if(newspectatee_status != spectatee_status)
529         {
530                 // clear race stuff
531                 race_laptime = 0;
532                 race_checkpointtime = 0;
533                 hud_dynamic_shake_factor = -1;
534         }
535         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
536         {
537                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
538                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
539                 )
540                         prev_p_health = -1;
541                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
542                         prev_health = -1;
543         }
544         spectatee_status = newspectatee_status;
545
546         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
547 }
548
549 NET_HANDLE(ENT_CLIENT_NAGGER, bool isnew)
550 {
551         make_pure(this);
552         int i, j, b, f;
553
554         int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
555
556         if(!(nags & BIT(2)))
557         {
558                 strfree(vote_called_vote);
559                 vote_active = 0;
560         }
561         else
562         {
563                 vote_active = 1;
564         }
565
566         if(nags & BIT(6))
567         {
568                 vote_yescount = ReadByte();
569                 vote_nocount = ReadByte();
570                 vote_needed = ReadByte();
571                 vote_highlighted = ReadChar();
572         }
573
574         if(nags & BIT(7))
575         {
576                 strcpy(vote_called_vote, ReadString());
577         }
578
579         if(nags & 1)
580         {
581                 for(j = 0; j < maxclients; ++j)
582                         if(playerslots[j])
583                                 playerslots[j].ready = 1;
584                 for(i = 1; i <= maxclients; i += 8)
585                 {
586                         f = ReadByte();
587                         for(j = i-1, b = BIT(0); b < BIT(8); b <<= 1, ++j)
588                                 if (!(f & b))
589                                         if(playerslots[j])
590                                                 playerslots[j].ready = 0;
591                 }
592         }
593
594         return = true;
595
596         ready_waiting = (nags & BIT(0));
597         ready_waiting_for_me = (nags & BIT(1));
598         vote_waiting = (nags & BIT(2));
599         vote_waiting_for_me = (nags & BIT(3));
600         warmup_stage = (nags & BIT(4));
601 }
602
603 NET_HANDLE(ENT_CLIENT_ELIMINATEDPLAYERS, bool isnew)
604 {
605         make_pure(this);
606         int sf = 0;
607         serialize(byte, 0, sf);
608         if (sf & 1) {
609                 for (int j = 0; j < maxclients; ++j) {
610                         if (playerslots[j]) {
611                                 playerslots[j].eliminated = 1;
612                         }
613                 }
614                 for (int i = 1; i <= maxclients; i += 8) {
615                         int f = 0;
616                         serialize(byte, 0, f);
617                         for (int b = 0; b < 8; ++b) {
618                                 if (f & BIT(b)) continue;
619                                 int j = i - 1 + b;
620                                 if (playerslots[j]) {
621                                         playerslots[j].eliminated = 0;
622                                 }
623                         }
624                 }
625         }
626         return true;
627 }
628
629 NET_HANDLE(ENT_CLIENT_RANDOMSEED, bool isnew)
630 {
631         make_pure(this);
632         prandom_debug();
633         float s = ReadShort();
634         psrandom(s);
635         return true;
636 }
637
638 NET_HANDLE(ENT_CLIENT_ACCURACY, bool isnew)
639 {
640         make_pure(this);
641         int sf = ReadInt24_t();
642         if (sf == 0) {
643                 for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
644                         weapon_accuracy[w] = -1;
645                 return true;
646         }
647
648         int f = 1;
649         for (int w = 0; w <= WEP_LAST - WEP_FIRST; ++w) {
650                 if (sf & f) {
651                         int b = ReadByte();
652                         if (b == 0)
653                                 weapon_accuracy[w] = -1;
654                         else if (b == 255)
655                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
656                         else
657                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
658                 }
659                 f = (f == 0x800000) ? 1 : f * 2;
660         }
661         return true;
662 }
663
664 void Spawn_Draw(entity this)
665 {
666         if(this.alpha <= 0)
667                 return;
668
669         __pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
670 }
671
672 void Spawn_PreDraw(entity this)
673 {
674         float alph;
675         vector org = getpropertyvec(VF_ORIGIN);
676         if(this.fade_start)
677         {
678                 if(vdist(org - this.origin, >, this.fade_end))
679                         alph = 0; // save on some processing
680                 else if(vdist(org - this.origin, <, this.fade_start))
681                         alph = 1; // more processing saved
682                 else
683                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
684         }
685         else
686                 alph = 1;
687         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
688         this.alpha = alph;
689         if(alph <= 0)
690                 this.drawmask = 0;
691         else
692                 this.drawmask = MASK_NORMAL;
693 }
694
695 NET_HANDLE(ENT_CLIENT_SPAWNPOINT, bool is_new)
696 {
697         float teamnum = (ReadByte() - 1);
698         vector spn_origin = ReadVector();
699
700         this.team = (teamnum + 1);
701
702         //if(is_new)
703         //{
704                 this.origin = spn_origin;
705                 setsize(this, PL_MIN_CONST, PL_MAX_CONST);
706                 //droptofloor();
707
708                 /*if(autocvar_cl_spawn_point_model) // needs a model first
709                 {
710                         this.mdl = "models/spawnpoint.md3";
711                         this.colormod = Team_ColorRGB(teamnum);
712                         precache_model(this.mdl);
713                         setmodel(this, this.mdl);
714                         this.drawmask = MASK_NORMAL;
715                         //this.move_movetype = MOVETYPE_NOCLIP;
716                         //this.draw = Spawn_Draw;
717                         IL_PUSH(g_drawables, this);
718                 }*/
719                 if(autocvar_cl_spawn_point_particles)
720                 {
721                         if(teamplay)
722                         {
723                                 switch(teamnum)
724                                 {
725                                         case NUM_TEAM_1: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
726                                         case NUM_TEAM_2: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
727                                         case NUM_TEAM_3: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
728                                         case NUM_TEAM_4: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
729                                         default: this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
730                                 }
731                         }
732                         else { this.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
733
734                         this.draw = Spawn_Draw;
735                         if (is_new) IL_PUSH(g_drawables, this);
736                         setpredraw(this, Spawn_PreDraw);
737                         this.fade_start = autocvar_cl_spawn_point_dist_min;
738                         this.fade_end = autocvar_cl_spawn_point_dist_max;
739                 }
740         //}
741
742         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(this.origin), teamnum, this.cnt);
743         return true;
744 }
745
746 NET_HANDLE(ENT_CLIENT_SPAWNEVENT, bool is_new)
747 {
748         // If entnum is 0, ONLY do the local spawn actions
749         // this way the server can disable the sending of
750         // spawn origin or such to clients if wanted.
751         float entnum = ReadByte();
752
753         if(entnum)
754         {
755                 this.origin = ReadVector();
756
757                 if(is_new)
758                 {
759                         float teamnum = entcs_GetTeam(entnum - 1);
760
761                         if(autocvar_cl_spawn_event_particles)
762                         {
763                                 switch(teamnum)
764                                 {
765                                         case NUM_TEAM_1: pointparticles(EFFECT_SPAWN_RED, this.origin, '0 0 0', 1); break;
766                                         case NUM_TEAM_2: pointparticles(EFFECT_SPAWN_BLUE, this.origin, '0 0 0', 1); break;
767                                         case NUM_TEAM_3: pointparticles(EFFECT_SPAWN_YELLOW, this.origin, '0 0 0', 1); break;
768                                         case NUM_TEAM_4: pointparticles(EFFECT_SPAWN_PINK, this.origin, '0 0 0', 1); break;
769                                         default: pointparticles(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1); break;
770                                 }
771                         }
772                         if(autocvar_cl_spawn_event_sound)
773                         {
774                                 sound(this, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
775                         }
776                 }
777         }
778         return = true;
779
780         // local spawn actions
781         if(is_new && (!entnum || (entnum == player_localentnum)))
782         {
783                 zoomin_effect = 1;
784                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
785
786                 if(autocvar_cl_unpress_zoom_on_spawn)
787                 {
788                         localcmd("-zoom\n");
789                         button_zoom = false;
790                 }
791                 HUD_Radar_Hide_Maximized();
792         }
793         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(this.origin), entnum, player_localentnum);
794 }
795
796 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
797 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
798 void CSQC_Ent_Update(entity this, bool isnew)
799 {
800         this.sourceLoc = __FILE__ ":" STR(__LINE__);
801         int t = ReadByte();
802
803         // set up the "time" global for received entities to be correct for interpolation purposes
804         float savetime = time;
805         if(servertime)
806         {
807                 time = servertime;
808         }
809         else
810         {
811                 serverprevtime = time;
812                 serverdeltatime = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
813                 time = serverprevtime + serverdeltatime;
814         }
815
816 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
817         if (this.enttype)
818         {
819                 if (t != this.enttype || isnew)
820                 {
821                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)", etof(this), this.entnum, this.enttype, t);
822                         Ent_Remove(this);
823                         clearentity(this);
824                         isnew = true;
825                 }
826         }
827         else
828         {
829                 if (!isnew)
830                 {
831                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)", etof(this), this.entnum, t);
832                         isnew = true;
833                 }
834         }
835 #endif
836         this.enttype = t;
837         bool done = false;
838         FOREACH(LinkedEntities, it.m_id == t, {
839                 if (isnew) this.classname = it.netname;
840                 if (autocvar_developer_csqcentities)
841             LOG_INFOF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
842                 done = it.m_read(this, NULL, isnew);
843                 MUTATOR_CALLHOOK(Ent_Update, this, isnew);
844                 break;
845         });
846         time = savetime;
847         if (!done)
848         {
849                 LOG_FATALF("CSQC_Ent_Update(%d) at %f with this=%i {.entnum=%d, .enttype=%d} t=%s (%d)", isnew, savetime, this, this.entnum, this.enttype, this.classname, t);
850         }
851 }
852
853 // Destructor, but does NOT deallocate the entity by calling remove(). Also
854 // used when an entity changes its type. For an entity that someone interacts
855 // with others, make sure it can no longer do so.
856 void Ent_Remove(entity this)
857 {
858         if(this.entremove) this.entremove(this);
859
860         if(this.skeletonindex)
861         {
862                 skel_delete(this.skeletonindex);
863                 this.skeletonindex = 0;
864         }
865
866         if(this.snd_looping > 0)
867         {
868                 sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
869                 this.snd_looping = 0;
870         }
871
872         this.enttype = 0;
873         this.classname = "";
874         this.draw = func_null;
875         this.entremove = func_null;
876         // TODO possibly set more stuff to defaults
877 }
878 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(this) as well.
879 void CSQC_Ent_Remove(entity this)
880 {
881         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Ent_Remove() with this=%i {.entnum=%d, .enttype=%d}", this, this.entnum, this.enttype);
882         if (wasfreed(this))
883         {
884                 LOG_WARN("CSQC_Ent_Remove called for already removed entity. Packet loss?");
885                 return;
886         }
887         if (this.enttype) Ent_Remove(this);
888         delete(this);
889 }
890
891 void Gamemode_Init()
892 {
893         if (!isdemo())
894         {
895                 if(!(calledhooks & HOOK_START))
896                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
897                 calledhooks |= HOOK_START;
898         }
899 }
900 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
901 void CSQC_Parse_StuffCmd(string strMessage)
902 {
903         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")", strMessage);
904         localcmd(strMessage);
905 }
906 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
907 void CSQC_Parse_Print(string strMessage)
908 {
909         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_Print(\"%s\")", strMessage);
910         print(ColorTranslateRGB(strMessage));
911 }
912
913 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
914 void CSQC_Parse_CenterPrint(string strMessage)
915 {
916         if (autocvar_developer_csqcentities) LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")", strMessage);
917         centerprint_hud(strMessage);
918 }
919
920 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
921 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
922 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
923 bool CSQC_Parse_TempEntity()
924 {
925         // Acquire TE ID
926         int nTEID = ReadByte();
927
928         FOREACH(TempEntities, it.m_id == nTEID, {
929                 if (autocvar_developer_csqcentities)
930                         LOG_INFOF("CSQC_Parse_TempEntity() nTEID=%s (%d)", it.netname, nTEID);
931                 return it.m_read(NULL, NULL, true);
932         });
933
934         if (autocvar_developer_csqcentities)
935                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d", nTEID);
936
937         // No special logic for this temporary entity; return 0 so the engine can handle it
938         return false;
939 }
940
941 string forcefog;
942 void Fog_Force()
943 {
944         if (autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
945                 localcmd("\nr_drawfog 0\n");
946         else if (forcefog != "")
947                 localcmd(sprintf("\nfog %s\nr_fog_exp2 0\nr_drawfog 1\n", forcefog));
948 }
949
950 void Gamemode_Init();
951 NET_HANDLE(ENT_CLIENT_SCORES_INFO, bool isnew)
952 {
953         make_pure(this);
954         gametype = ReadRegistered(Gametypes);
955         teamplay = _MapInfo_GetTeamPlayBool(gametype);
956         HUD_ModIcons_SetFunc();
957         FOREACH(Scores, true, {
958                 strcpy(scores_label(it), ReadString());
959                 scores_flags(it) = ReadByte();
960         });
961         for (int i = 0; i < MAX_TEAMSCORE; ++i)
962         {
963                 strcpy(teamscores_label(i), ReadString());
964                 teamscores_flags(i) = ReadByte();
965         }
966         return = true;
967         Scoreboard_InitScores();
968         Gamemode_Init();
969 }
970
971 NET_HANDLE(ENT_CLIENT_INIT, bool isnew)
972 {
973         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
974
975         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
976         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
977         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
978         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
979         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
980         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
981         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
982         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
983
984         strcpy(forcefog, ReadString());
985
986         armorblockpercent = ReadByte() / 255.0;
987         damagepush_speedfactor = ReadByte() / 255.0;
988
989         serverflags = ReadByte();
990
991         g_trueaim_minrange = ReadCoord();
992
993         return = true;
994
995         MUTATOR_CALLHOOK(Ent_Init);
996
997         if (!postinit) PostInit();
998 }
999
1000 float GetSpeedUnitFactor(int speed_unit)
1001 {
1002         switch(speed_unit)
1003         {
1004                 default:
1005                 case 1:
1006                         return 1.0;
1007                 case 2:
1008                         return 0.0254;
1009                 case 3:
1010                         return 0.0254 * 3.6;
1011                 case 4:
1012                         return 0.0254 * 3.6 * 0.6213711922;
1013                 case 5:
1014                         return 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
1015         }
1016 }
1017
1018 string GetSpeedUnit(int speed_unit)
1019 {
1020         switch(speed_unit)
1021         {
1022                 default:
1023                 case 1:
1024                         return _(" qu/s");
1025                 case 2:
1026                         return _(" m/s");
1027                 case 3:
1028                         return _(" km/h");
1029                 case 4:
1030                         return _(" mph");
1031                 case 5:
1032                         return _(" knots");
1033         }
1034 }
1035
1036 NET_HANDLE(TE_CSQC_RACE, bool isNew)
1037 {
1038         int b = ReadByte();
1039
1040         switch (b)
1041         {
1042                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1043                         race_checkpoint = ReadByte();
1044                         race_time = ReadInt24_t();
1045                         race_previousbesttime = ReadInt24_t();
1046                         race_mypreviousbesttime = ReadInt24_t();
1047                         string pbestname = ReadString();
1048                         if(autocvar_cl_race_cptimes_onlyself)
1049                         {
1050                                 race_previousbesttime = race_mypreviousbesttime;
1051                                 race_mypreviousbesttime = 0;
1052                                 strcpy(race_previousbestname, "");
1053                         }
1054                         else
1055                                 strcpy(race_previousbestname, pbestname);
1056
1057                         race_checkpointtime = time;
1058
1059                         if(race_checkpoint == 0 || race_checkpoint == 254)
1060                         {
1061                                 race_penaltyaccumulator = 0;
1062                                 race_laptime = time; // valid
1063                         }
1064                         break;
1065
1066                 case RACE_NET_CHECKPOINT_CLEAR:
1067                         race_laptime = 0;
1068                         race_checkpointtime = 0;
1069                         break;
1070
1071                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1072                         race_laptime = ReadCoord();
1073                         race_checkpointtime = -99999;
1074                         // fall through
1075                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1076                         race_nextcheckpoint = ReadByte();
1077
1078                         race_nextbesttime = ReadInt24_t();
1079                         if(b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING) // not while spectating (matches server)
1080                                 race_mybesttime = ReadInt24_t();
1081                         string newname = ReadString();
1082                         if(autocvar_cl_race_cptimes_onlyself && b != RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING)
1083                         {
1084                                 race_nextbesttime = race_mybesttime;
1085                                 race_mybesttime = 0;
1086                                 strcpy(race_nextbestname, "");
1087                         }
1088                         else
1089                                 strcpy(race_nextbestname, newname);
1090                         break;
1091
1092                 case RACE_NET_CHECKPOINT_HIT_RACE:
1093                         race_mycheckpoint = ReadByte();
1094                         race_mycheckpointtime = time;
1095                         race_mycheckpointdelta = ReadInt24_t();
1096                         race_mycheckpointlapsdelta = ReadByte();
1097                         if(race_mycheckpointlapsdelta >= 128)
1098                                 race_mycheckpointlapsdelta -= 256;
1099                         int who = ReadByte();
1100                         if(who)
1101                                 strcpy(race_mycheckpointenemy, entcs_GetName(who - 1));
1102                         else
1103                                 strcpy(race_mycheckpointenemy, ""); // TODO: maybe string_null works fine here?
1104                         break;
1105
1106                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1107                         race_othercheckpoint = ReadByte();
1108                         race_othercheckpointtime = time;
1109                         race_othercheckpointdelta = ReadInt24_t();
1110                         race_othercheckpointlapsdelta = ReadByte();
1111                         if(race_othercheckpointlapsdelta >= 128)
1112                                 race_othercheckpointlapsdelta -= 256;
1113                         int what = ReadByte();
1114                         if(what)
1115                                 strcpy(race_othercheckpointenemy, entcs_GetName(what - 1));
1116                         else
1117                                 strcpy(race_othercheckpointenemy, ""); // TODO: maybe string_null works fine here?
1118                         break;
1119
1120                 case RACE_NET_PENALTY_RACE:
1121                         race_penaltyeventtime = time;
1122                         race_penaltytime = ReadShort();
1123                         //race_penaltyaccumulator += race_penaltytime;
1124                         strcpy(race_penaltyreason, ReadString());
1125                         break;
1126
1127                 case RACE_NET_PENALTY_QUALIFYING:
1128                         race_penaltyeventtime = time;
1129                         race_penaltytime = ReadShort();
1130                         race_penaltyaccumulator += race_penaltytime;
1131                         strcpy(race_penaltyreason, ReadString());
1132                         break;
1133
1134                 case RACE_NET_SERVER_RECORD:
1135                         race_server_record = ReadInt24_t();
1136                         break;
1137                 case RACE_NET_SPEED_AWARD:
1138                         race_speedaward = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1139                         strcpy(race_speedaward_holder, ReadString());
1140                         strcpy(race_speedaward_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1141                         break;
1142                 case RACE_NET_SPEED_AWARD_BEST:
1143                         race_speedaward_alltimebest = ReadInt24_t() * GetSpeedUnitFactor(autocvar_hud_panel_physics_speed_unit);
1144                         strcpy(race_speedaward_alltimebest_holder, ReadString());
1145                         strcpy(race_speedaward_alltimebest_unit, GetSpeedUnit(autocvar_hud_panel_physics_speed_unit));
1146                         break;
1147                 case RACE_NET_SERVER_RANKINGS:
1148                         float prevpos, del;
1149             int pos = ReadShort();
1150                         prevpos = ReadShort();
1151                         del = ReadShort();
1152
1153                         // move other rankings out of the way
1154             int i;
1155                         if (prevpos) {
1156                                 for (i=prevpos-1;i>pos-1;--i) {
1157                                         grecordtime[i] = grecordtime[i-1];
1158                                         strcpy(grecordholder[i], grecordholder[i-1]);
1159                                 }
1160                         } else if (del) { // a record has been deleted by the admin
1161                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1162                                         if (i == RANKINGS_CNT-1) { // clear out last record
1163                                                 grecordtime[i] = 0;
1164                                                 strfree(grecordholder[i]);
1165                                         }
1166                                         else {
1167                                                 grecordtime[i] = grecordtime[i+1];
1168                                                 strcpy(grecordholder[i], grecordholder[i+1]);
1169                                         }
1170                                 }
1171                         } else { // player has no ranked record yet
1172                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1173                                         grecordtime[i] = grecordtime[i-1];
1174                                         strcpy(grecordholder[i], grecordholder[i-1]);
1175                                 }
1176                         }
1177
1178                         // store new ranking
1179                         strcpy(grecordholder[pos-1], ReadString());
1180                         grecordtime[pos-1] = ReadInt24_t();
1181                         if(strdecolorize(grecordholder[pos-1]) == strdecolorize(entcs_GetName(player_localnum)))
1182                                 race_myrank = pos;
1183                         break;
1184                 case RACE_NET_SERVER_STATUS:
1185                         race_status = ReadShort();
1186                         strcpy(race_status_name, ReadString());
1187         }
1188         return true;
1189 }
1190
1191 NET_HANDLE(TE_CSQC_TEAMNAGGER, bool isNew)
1192 {
1193         teamnagger = 1;
1194         return true;
1195 }
1196
1197 NET_HANDLE(TE_CSQC_PINGPLREPORT, bool isNew)
1198 {
1199         int i = ReadByte();
1200         int pi = ReadShort();
1201         int pl = ReadByte();
1202         int ml = ReadByte();
1203         return = true;
1204         entity e = playerslots[i];
1205         if (!e) return;
1206         e.ping = pi;
1207         e.ping_packetloss = pl / 255.0;
1208         e.ping_movementloss = ml / 255.0;
1209 }
1210
1211 NET_HANDLE(TE_CSQC_WEAPONCOMPLAIN, bool isNew)
1212 {
1213         complain_weapon = ReadByte();
1214         complain_weapon_type = ReadByte();
1215         return = true;
1216
1217         complain_weapon_time = time;
1218         weapontime = time; // ping the weapon panel
1219
1220         switch(complain_weapon_type)
1221         {
1222                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1223                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1224                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1225         }
1226 }
1227
1228 string _getcommandkey(string cmd_name, string command, bool forcename)
1229 {
1230         string keys;
1231         float n, j, k, l = 0;
1232
1233         if (!autocvar_hud_showbinds)
1234                 return cmd_name;
1235
1236         keys = db_get(binddb, command);
1237         if (keys == "")
1238         {
1239                 bool joy_active = cvar("joy_active");
1240                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1241                 for(j = 0; j < n; ++j)
1242                 {
1243                         k = stof(argv(j));
1244                         if(k != -1)
1245                         {
1246                                 string key = keynumtostring(k);
1247                                 if(!joy_active && substring(key, 0, 3) == "JOY")
1248                                         continue;
1249
1250                                 key = translate_key(key);
1251
1252                                 if (keys == "")
1253                                         keys = key;
1254                                 else
1255                                         keys = strcat(keys, ", ", key);
1256
1257                                 ++l;
1258                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1259                                         break;
1260                         }
1261
1262                 }
1263                 if (keys == "")
1264                         keys = "NO_KEY";
1265                 db_put(binddb, command, keys);
1266         }
1267
1268         if (keys == "NO_KEY") {
1269                 if (autocvar_hud_showbinds > 1)
1270                         return sprintf(_("%s (not bound)"), cmd_name);
1271                 else
1272                         return cmd_name;
1273         }
1274         else if (autocvar_hud_showbinds > 1 || forcename)
1275                 return sprintf("%s (%s)", cmd_name, keys);
1276         else
1277                 return keys;
1278 }