qcsrc/client/main.qc

   1 #include "main.qh"
   2 #include "_all.qh"
   3
   4 #include "controlpoint.qh"
   5 #include "damage.qh"
   6 #include "effects.qh"
   7 #include "generator.qh"
   8 #include "gibs.qh"
   9 #include "hook.qh"
  10 #include "hud.qh"
  11 #include "hud_config.qh"
  12 #include "laser.qh"
  13 #include "mapvoting.qh"
  14 #include "modeleffects.qh"
  15 #include "particles.qh"
  16 #include "scoreboard.qh"
  17 #include "shownames.qh"
  18 #include "tuba.qh"
  19 #include "t_items.qh"
  20 #include "wall.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23
  24 #include "mutators/events.qh"
  25
  26 #include "weapons/projectile.qh"
  27
  28 #include "../common/buffs/all.qh"
  29 #include "../common/deathtypes.qh"
  30 #include "../common/effects/effects.qh"
  31 #include "../common/mapinfo.qh"
  32 #include "../common/monsters/all.qh"
  33 #include "../common/nades/all.qh"
  34 #include "../common/net_notice.qh"
  35 #include "../common/notifications.qh"
  36 #include "../common/stats.qh"
  37 #include "../common/teams.qh"
  38
  39 #include "../common/items/all.qh"
  40
  41 #include "../common/mutators/base.qh"
  42
  43 #include "../common/weapons/all.qh"
  44
  45 #include "../csqcmodellib/cl_model.qh"
  46 #include "../csqcmodellib/interpolate.qh"
  47
  48 #include "../common/triggers/include.qh"
  49
  50 #include "../common/turrets/cl_turrets.qh"
  51
  52 #include "../warpzonelib/client.qh"
  53
  54 // --------------------------------------------------------------------------
  55 // BEGIN REQUIRED CSQC FUNCTIONS
  56 //include "main.qh"
  57
  58 entity clearentity_ent;
  59 void clearentity(entity e)
  60 {
  61         if (!clearentity_ent)
  62         {
  63                 clearentity_ent = spawn();
  64                 clearentity_ent.classname = "clearentity";
  65         }
  66         int n = e.entnum;
  67         copyentity(clearentity_ent, e);
  68         e.entnum = n;
  69 }
  70
  71 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  72 void menu_show_error()
  73 {
  74         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  75 }
  76
  77 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  78 // Useful for precaching things
  79
  80 void menu_sub_null()
  81 {
  82 }
  83
  84 void draw_null(entity this) { }
  85
  86 string forcefog;
  87 void ConsoleCommand_macro_init();
  88 void CSQC_Init(void)
  89 {
  90         prvm_language = strzone(cvar_string("prvm_language"));
  91
  92 #ifdef WATERMARK
  93         LOG_TRACEF("^4CSQC Build information: ^1%s\n", WATERMARK);
  94 #endif
  95
  96         int i;
  97
  98         binddb = db_create();
  99         tempdb = db_create();
 100         ClientProgsDB = db_load("client.db");
 101         compressShortVector_init();
 102
 103         draw_endBoldFont();
 104         menu_visible = false;
 105         menu_show = menu_show_error;
 106         menu_action = func_null;
 107
 108         for(i = 0; i < 255; ++i)
 109                 if(getplayerkeyvalue(i, "viewentity") == "")
 110                         break;
 111         maxclients = i;
 112
 113         //registercommand("hud_configure");
 114         //registercommand("hud_save");
 115         //registercommand("menu_action");
 116
 117         ConsoleCommand_macro_init();
 118
 119         registercvar("hud_usecsqc", "1");
 120         registercvar("scoreboard_columns", "default");
 121
 122         registercvar("cl_nade_type", "3");
 123         registercvar("cl_pokenade_type", "zombie");
 124
 125         registercvar("cl_jumpspeedcap_min", "");
 126         registercvar("cl_jumpspeedcap_max", "");
 127
 128         registercvar("cl_multijump", "0");
 129
 130         registercvar("cl_spawn_near_teammate", "1");
 131
 132         gametype = 0;
 133
 134         // hud_fields uses strunzone on the titles!
 135         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 136                 hud_title[i] = strzone("(null)");
 137
 138         Cmd_HUD_SetFields(0);
 139
 140         postinit = false;
 141
 142         calledhooks = 0;
 143
 144         teams = Sort_Spawn();
 145         players = Sort_Spawn();
 146
 147         GetTeam(NUM_SPECTATOR, true); // add specs first
 148
 149         // needs to be done so early because of the constants they create
 150         static_init();
 151         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 152         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
 153         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
 154
 155         // precaches
 156
 157         Projectile_Precache();
 158         Tuba_Precache();
 159
 160         if(autocvar_cl_reticle)
 161         {
 162                 precache_pic("gfx/reticle_normal");
 163                 // weapon reticles are precached in weapon files
 164         }
 165
 166         get_mi_min_max_texcoords(1); // try the CLEVER way first
 167         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 168         shortmapname = mi_shortname;
 169
 170         if(precache_pic(minimapname) == "")
 171         {
 172                 // but maybe we have a non-clever minimap
 173                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 174                 if(precache_pic(minimapname) == "")
 175                         minimapname = ""; // FAIL
 176                 else
 177                         get_mi_min_max_texcoords(0); // load new texcoords
 178         }
 179
 180         mi_center = (mi_min + mi_max) * 0.5;
 181         mi_scale = mi_max - mi_min;
 182         minimapname = strzone(minimapname);
 183
 184         WarpZone_Init();
 185
 186         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 187         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 188 }
 189
 190 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 191 void Shutdown(void)
 192 {
 193         WarpZone_Shutdown();
 194
 195         remove(teams);
 196         remove(players);
 197         db_close(binddb);
 198         db_close(tempdb);
 199         if(autocvar_cl_db_saveasdump)
 200                 db_dump(ClientProgsDB, "client.db");
 201         else
 202                 db_save(ClientProgsDB, "client.db");
 203         db_close(ClientProgsDB);
 204
 205         if(camera_active)
 206                 cvar_set("chase_active",ftos(chase_active_backup));
 207
 208         // unset the event chasecam's chase_active
 209         if(autocvar_chase_active < 0)
 210                 cvar_set("chase_active", "0");
 211
 212         if (!isdemo())
 213         {
 214                 if (!(calledhooks & HOOK_START))
 215                         localcmd("\n_cl_hook_gamestart nop\n");
 216                 if (!(calledhooks & HOOK_END))
 217                         localcmd("\ncl_hook_gameend\n");
 218         }
 219
 220         deactivate_minigame();
 221         HUD_MinigameMenu_Close();
 222 }
 223
 224 .float has_team;
 225 float SetTeam(entity o, int Team)
 226 {
 227         entity tm;
 228         if(teamplay)
 229         {
 230                 switch(Team)
 231                 {
 232                         case -1:
 233                         case NUM_TEAM_1:
 234                         case NUM_TEAM_2:
 235                         case NUM_TEAM_3:
 236                         case NUM_TEAM_4:
 237                                 break;
 238                         default:
 239                                 if(GetTeam(Team, false) == world)
 240                                 {
 241                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 242                                         Team = NUM_SPECTATOR;
 243                                 }
 244                                 break;
 245                 }
 246         }
 247         else
 248         {
 249                 switch(Team)
 250                 {
 251                         case -1:
 252                         case 0:
 253                                 break;
 254                         default:
 255                                 if(GetTeam(Team, false) == world)
 256                                 {
 257                                         LOG_TRACEF("trying to switch to unsupported team %d\n", Team);
 258                                         Team = NUM_SPECTATOR;
 259                                 }
 260                                 break;
 261                 }
 262         }
 263         if(Team == -1) // leave
 264         {
 265                 if(o.has_team)
 266                 {
 267                         tm = GetTeam(o.team, false);
 268                         tm.team_size -= 1;
 269                         o.has_team = 0;
 270                         return true;
 271                 }
 272         }
 273         else
 274         {
 275                 if (!o.has_team)
 276                 {
 277                         o.team = Team;
 278                         tm = GetTeam(Team, true);
 279                         tm.team_size += 1;
 280                         o.has_team = 1;
 281                         return true;
 282                 }
 283                 else if(Team != o.team)
 284                 {
 285                         tm = GetTeam(o.team, false);
 286                         tm.team_size -= 1;
 287                         o.team = Team;
 288                         tm = GetTeam(Team, true);
 289                         tm.team_size += 1;
 290                         return true;
 291                 }
 292         }
 293         return false;
 294 }
 295
 296 void Playerchecker_Think()
 297 {SELFPARAM();
 298     int i;
 299         entity e;
 300         for(i = 0; i < maxclients; ++i)
 301         {
 302                 e = playerslots[i];
 303                 if(GetPlayerName(i) == "")
 304                 {
 305                         if(e.sort_prev)
 306                         {
 307                                 // player disconnected
 308                                 SetTeam(e, -1);
 309                                 RemovePlayer(e);
 310                                 e.sort_prev = world;
 311                                 //e.gotscores = 0;
 312                         }
 313                 }
 314                 else
 315                 {
 316                         if (!e.sort_prev)
 317                         {
 318                                 // player connected
 319                                 if (!e)
 320                                         playerslots[i] = e = spawn();
 321                                 e.sv_entnum = i;
 322                                 e.ping = 0;
 323                                 e.ping_packetloss = 0;
 324                                 e.ping_movementloss = 0;
 325                                 //e.gotscores = 0; // we might already have the scores...
 326                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 327                                 RegisterPlayer(e);
 328                                 HUD_UpdatePlayerPos(e);
 329                         }
 330                 }
 331         }
 332         self.nextthink = time + 0.2;
 333 }
 334
 335 void Porto_Init();
 336 void TrueAim_Init();
 337 void PostInit(void)
 338 {
 339         entity playerchecker;
 340         playerchecker = spawn();
 341         playerchecker.think = Playerchecker_Think;
 342         playerchecker.nextthink = time + 0.2;
 343
 344         Porto_Init();
 345         TrueAim_Init();
 346
 347         postinit = true;
 348 }
 349
 350 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 351 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 352 // All keys are in ascii.
 353 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 354 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 355 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 356 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 357 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 358 {
 359         float bSkipKey;
 360         bSkipKey = false;
 361
 362         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 363                 return true;
 364
 365         if (QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 366                 return true;
 367
 368         if ( HUD_Radar_InputEvent(bInputType, nPrimary, nSecondary) )
 369                 return true;
 370
 371         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 372                 return true;
 373
 374         if (HUD_Minigame_InputEvent(bInputType, nPrimary, nSecondary))
 375                 return true;
 376
 377         if(menu_visible && menu_action)
 378                 if(menu_action(bInputType, nPrimary, nSecondary))
 379                         return true;
 380
 381         return bSkipKey;
 382 }
 383
 384 // END REQUIRED CSQC FUNCTIONS
 385 // --------------------------------------------------------------------------
 386
 387 // --------------------------------------------------------------------------
 388 // BEGIN OPTIONAL CSQC FUNCTIONS
 389
 390 void Ent_RemoveEntCS()
 391 {SELFPARAM();
 392         entcs_receiver[self.sv_entnum] = NULL;
 393 }
 394 void Ent_ReadEntCS()
 395 {SELFPARAM();
 396         InterpolateOrigin_Undo();
 397         self.classname = "entcs_receiver";
 398         int sf = ReadByte();
 399
 400         if(sf & BIT(0))
 401                 self.sv_entnum = ReadByte();
 402         if (sf & BIT(1))
 403         {
 404                 self.origin_x = ReadShort();
 405                 self.origin_y = ReadShort();
 406                 self.origin_z = ReadShort();
 407                 setorigin(self, self.origin);
 408         }
 409         if (sf & BIT(2))
 410         {
 411                 self.angles_y = ReadByte() * 360.0 / 256;
 412                 self.angles_x = self.angles_z = 0;
 413         }
 414         if (sf & BIT(3))
 415                 self.healthvalue = ReadByte() * 10;
 416         if (sf & BIT(4))
 417                 self.armorvalue = ReadByte() * 10;
 418
 419         entcs_receiver[self.sv_entnum] = self;
 420         self.entremove = Ent_RemoveEntCS;
 421         self.iflags |= IFLAG_ORIGIN;
 422
 423         InterpolateOrigin_Note();
 424 }
 425
 426 void Ent_Remove();
 427
 428 void Ent_RemovePlayerScore()
 429 {SELFPARAM();
 430         if(self.owner) {
 431                 SetTeam(self.owner, -1);
 432                 self.owner.gotscores = 0;
 433                 for(int i = 0; i < MAX_SCORE; ++i) {
 434                         self.owner.(scores[i]) = 0; // clear all scores
 435                 }
 436         }
 437 }
 438
 439 void Ent_ReadPlayerScore()
 440 {SELFPARAM();
 441         int i, n;
 442         bool isNew;
 443         entity o;
 444
 445         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 446         // (no I've never heard of M-x replace-string, sed, or anything like that)
 447         isNew = !self.owner; // workaround for DP bug
 448         n = ReadByte()-1;
 449
 450 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 451         if(!isNew && n != self.sv_entnum)
 452         {
 453                 //print("A CSQC entity changed its owner!\n");
 454                 LOG_INFOF("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 455                 isNew = true;
 456                 Ent_Remove();
 457                 self.enttype = ENT_CLIENT_SCORES;
 458         }
 459 #endif
 460
 461         self.sv_entnum = n;
 462
 463         if (!(playerslots[self.sv_entnum]))
 464                 playerslots[self.sv_entnum] = spawn();
 465         o = self.owner = playerslots[self.sv_entnum];
 466         o.sv_entnum = self.sv_entnum;
 467         o.gotscores = 1;
 468
 469         //if (!o.sort_prev)
 470         //      RegisterPlayer(o);
 471         //playerchecker will do this for us later, if it has not already done so
 472
 473     int sf, lf;
 474 #if MAX_SCORE <= 8
 475         sf = ReadByte();
 476         lf = ReadByte();
 477 #else
 478         sf = ReadShort();
 479         lf = ReadShort();
 480 #endif
 481     int p;
 482         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 483                 if(sf & p)
 484                 {
 485                         if(lf & p)
 486                                 o.(scores[i]) = ReadInt24_t();
 487                         else
 488                                 o.(scores[i]) = ReadChar();
 489                 }
 490
 491         if(o.sort_prev)
 492                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 493
 494         self.entremove = Ent_RemovePlayerScore;
 495 }
 496
 497 void Ent_ReadTeamScore()
 498 {SELFPARAM();
 499         int i;
 500         entity o;
 501
 502         self.team = ReadByte();
 503         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 504
 505     int sf, lf;
 506 #if MAX_TEAMSCORE <= 8
 507         sf = ReadByte();
 508         lf = ReadByte();
 509 #else
 510         sf = ReadShort();
 511         lf = ReadShort();
 512 #endif
 513         int p;
 514         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 515                 if(sf & p)
 516                 {
 517                         if(lf & p)
 518                                 o.(teamscores[i]) = ReadInt24_t();
 519                         else
 520                                 o.(teamscores[i]) = ReadChar();
 521                 }
 522
 523         HUD_UpdateTeamPos(o);
 524 }
 525
 526 void Ent_ClientData()
 527 {
 528         float newspectatee_status;
 529
 530     int f = ReadByte();
 531
 532         scoreboard_showscores_force = (f & 1);
 533
 534         if(f & 2)
 535         {
 536                 newspectatee_status = ReadByte();
 537                 if(newspectatee_status == player_localnum + 1)
 538                         newspectatee_status = -1; // observing
 539         }
 540         else
 541                 newspectatee_status = 0;
 542
 543         spectatorbutton_zoom = (f & 4);
 544
 545         if(f & 8)
 546         {
 547                 angles_held_status = 1;
 548                 angles_held.x = ReadAngle();
 549                 angles_held.y = ReadAngle();
 550                 angles_held.z = 0;
 551         }
 552         else
 553                 angles_held_status = 0;
 554
 555         if(newspectatee_status != spectatee_status)
 556         {
 557                 // clear race stuff
 558                 race_laptime = 0;
 559                 race_checkpointtime = 0;
 560         }
 561         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 562         {
 563                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 564                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 565                 )
 566                         prev_p_health = -1;
 567                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 568                         prev_health = -1;
 569         }
 570         spectatee_status = newspectatee_status;
 571
 572         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 573 }
 574
 575 void Ent_Nagger()
 576 {
 577     int i, j, b, f;
 578
 579     int nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 580
 581         if(!(nags & 4))
 582         {
 583                 if(vote_called_vote)
 584                         strunzone(vote_called_vote);
 585                 vote_called_vote = string_null;
 586                 vote_active = 0;
 587         }
 588         else
 589         {
 590                 vote_active = 1;
 591         }
 592
 593         if(nags & 64)
 594         {
 595                 vote_yescount = ReadByte();
 596                 vote_nocount = ReadByte();
 597                 vote_needed = ReadByte();
 598                 vote_highlighted = ReadChar();
 599         }
 600
 601         if(nags & 128)
 602         {
 603                 if(vote_called_vote)
 604                         strunzone(vote_called_vote);
 605                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 606         }
 607
 608         if(nags & 1)
 609         {
 610                 for(j = 0; j < maxclients; ++j)
 611                         if(playerslots[j])
 612                                 playerslots[j].ready = 1;
 613                 for(i = 1; i <= maxclients; i += 8)
 614                 {
 615                         f = ReadByte();
 616                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 617                                 if (!(f & b))
 618                                         if(playerslots[j])
 619                                                 playerslots[j].ready = 0;
 620                 }
 621         }
 622
 623         ready_waiting = (nags & 1);
 624         ready_waiting_for_me = (nags & 2);
 625         vote_waiting = (nags & 4);
 626         vote_waiting_for_me = (nags & 8);
 627         warmup_stage = (nags & 16);
 628 }
 629
 630 void Ent_EliminatedPlayers()
 631 {
 632     int i, j, b, f;
 633
 634     int sf = ReadByte();
 635         if(sf & 1)
 636         {
 637                 for(j = 0; j < maxclients; ++j)
 638                         if(playerslots[j])
 639                                 playerslots[j].eliminated = 1;
 640                 for(i = 1; i <= maxclients; i += 8)
 641                 {
 642                         f = ReadByte();
 643                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 644                                 if (!(f & b))
 645                                         if(playerslots[j])
 646                                                 playerslots[j].eliminated = 0;
 647                 }
 648         }
 649 }
 650
 651 void Ent_RandomSeed()
 652 {
 653         float s;
 654         prandom_debug();
 655         s = ReadShort();
 656         psrandom(s);
 657 }
 658
 659 void Ent_ReadAccuracy(void)
 660 {
 661     int f, w;
 662     int sf = ReadInt24_t();
 663         if(sf == 0)
 664         {
 665                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 666                         weapon_accuracy[w] = -1;
 667                 return;
 668         }
 669
 670         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 671         {
 672                 if(sf & f)
 673                 {
 674             int b = ReadByte();
 675                         if(b == 0)
 676                                 weapon_accuracy[w] = -1;
 677                         else if(b == 255)
 678                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 679                         else
 680                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 681                 }
 682                 if(f == 0x800000)
 683                         f = 1;
 684                 else
 685                         f *= 2;
 686         }
 687 }
 688
 689 void Spawn_Draw(entity this)
 690 {
 691         pointparticles(this.cnt, this.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 692 }
 693
 694 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 695 {SELFPARAM();
 696         float teamnum = (ReadByte() - 1);
 697         vector spn_origin;
 698         spn_origin.x = ReadShort();
 699         spn_origin.y = ReadShort();
 700         spn_origin.z = ReadShort();
 701
 702         if(is_new)
 703         {
 704                 self.origin = spn_origin;
 705                 setsize(self, PL_MIN_CONST, PL_MAX_CONST);
 706                 droptofloor();
 707
 708                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 709                 {
 710                         self.mdl = "models/spawnpoint.md3";
 711                         self.colormod = Team_ColorRGB(teamnum);
 712                         precache_model(self.mdl);
 713                         setmodel(self, self.mdl);
 714                         self.drawmask = MASK_NORMAL;
 715                         //self.movetype = MOVETYPE_NOCLIP;
 716                         //self.draw = Spawn_Draw;
 717                 }*/
 718                 if(autocvar_cl_spawn_point_particles)
 719                 {
 720                         if((serverflags & SERVERFLAG_TEAMPLAY))
 721                         {
 722                                 switch(teamnum)
 723                                 {
 724                                         case NUM_TEAM_1: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_RED); break;
 725                                         case NUM_TEAM_2: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_BLUE); break;
 726                                         case NUM_TEAM_3: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_YELLOW); break;
 727                                         case NUM_TEAM_4: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_PINK); break;
 728                                         default: self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); break;
 729                                 }
 730                         }
 731                         else { self.cnt = particleeffectnum(EFFECT_SPAWNPOINT_NEUTRAL); }
 732
 733                         self.draw = Spawn_Draw;
 734                 }
 735         }
 736
 737         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 738 }
 739
 740 void Ent_ReadSpawnEvent(float is_new)
 741 {SELFPARAM();
 742         // If entnum is 0, ONLY do the local spawn actions
 743         // this way the server can disable the sending of
 744         // spawn origin or such to clients if wanted.
 745         float entnum = ReadByte();
 746
 747         if(entnum)
 748         {
 749                 self.origin_x = ReadShort();
 750                 self.origin_y = ReadShort();
 751                 self.origin_z = ReadShort();
 752
 753                 if(is_new)
 754                 {
 755                         float teamnum = GetPlayerColor(entnum - 1);
 756
 757                         if(autocvar_cl_spawn_event_particles)
 758                         {
 759                                 switch(teamnum)
 760                                 {
 761                                         case NUM_TEAM_1: pointparticles(particleeffectnum(EFFECT_SPAWN_RED), self.origin, '0 0 0', 1); break;
 762                                         case NUM_TEAM_2: pointparticles(particleeffectnum(EFFECT_SPAWN_BLUE), self.origin, '0 0 0', 1); break;
 763                                         case NUM_TEAM_3: pointparticles(particleeffectnum(EFFECT_SPAWN_YELLOW), self.origin, '0 0 0', 1); break;
 764                                         case NUM_TEAM_4: pointparticles(particleeffectnum(EFFECT_SPAWN_PINK), self.origin, '0 0 0', 1); break;
 765                                         default: pointparticles(particleeffectnum(EFFECT_SPAWN_NEUTRAL), self.origin, '0 0 0', 1); break;
 766                                 }
 767                         }
 768                         if(autocvar_cl_spawn_event_sound)
 769                         {
 770                                 sound(self, CH_TRIGGER, SND_SPAWN, VOL_BASE, ATTEN_NORM);
 771                         }
 772                 }
 773         }
 774
 775         // local spawn actions
 776         if(is_new && (!entnum || (entnum == player_localentnum)))
 777         {
 778                 zoomin_effect = 1;
 779                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 780
 781                 if(autocvar_cl_unpress_zoom_on_spawn)
 782                 {
 783                         localcmd("-zoom\n");
 784                         button_zoom = false;
 785                 }
 786         }
 787         HUD_Radar_Hide_Maximized();
 788         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 789 }
 790
 791 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 792 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 793 void Ent_RadarLink();
 794 void Ent_Init();
 795 void Ent_ScoresInfo();
 796 void CSQC_Ent_Update(float bIsNewEntity)
 797 {SELFPARAM();
 798         int t = ReadByte();
 799
 800         if(autocvar_developer_csqcentities)
 801                 LOG_INFOF("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 802
 803         // set up the "time" global for received entities to be correct for interpolation purposes
 804         float savetime = time;
 805         if(servertime)
 806         {
 807                 time = servertime;
 808         }
 809         else
 810         {
 811                 serverprevtime = time;
 812                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 813                 time = serverprevtime + serverdeltatime;
 814         }
 815
 816 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 817         if(self.enttype)
 818         {
 819                 if(t != self.enttype || bIsNewEntity)
 820                 {
 821                         LOG_INFOF("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 822                         Ent_Remove();
 823                         clearentity(self);
 824                         bIsNewEntity = 1;
 825                 }
 826         }
 827         else
 828         {
 829                 if(!bIsNewEntity)
 830                 {
 831                         LOG_INFOF("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 832                         bIsNewEntity = 1;
 833                 }
 834         }
 835 #endif
 836         self.enttype = t;
 837         bool done = false;
 838         FOREACH(LinkedEntities, it.m_id == t, LAMBDA(
 839                 it.m_read(self, bIsNewEntity);
 840                 done = true;
 841                 break;
 842         ));
 843         if (!done)
 844         switch(t)
 845         {
 846                 case ENT_CLIENT_MUTATOR: {
 847                         int mutID = ReadMutator();
 848                         if (!MUTATOR_CALLHOOK(CSQC_Ent_Update, mutID, bIsNewEntity))
 849                         error(sprintf("Unknown mutator type in CSQC_Ent_Update (mutID: %d, edict: %d, classname: %s)\n", mutID, num_for_edict(self), self.classname));
 850                         break;
 851                 }
 852                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 853                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 854                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 855                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 856                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 857                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 858                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 859                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 860                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 861                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 862                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 863                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 864                 case ENT_CLIENT_INIT: Ent_Init(); break;
 865                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 866                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 867                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 868                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 869                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 870                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 871                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 872                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 873                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 874                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 875                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 876                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 877                 case ENT_CLIENT_INVENTORY: Inventory_Read(self); break;
 878                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 879                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 880                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 881                 case ENT_CLIENT_TURRET: ent_turret(); break;
 882                 case ENT_CLIENT_GENERATOR: ent_generator(); break;
 883                 case ENT_CLIENT_CONTROLPOINT_ICON: ent_cpicon(this); break;
 884                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 885                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 886                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 887                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 888                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 889                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 890                 case ENT_CLIENT_MINIGAME: ent_read_minigame(); break;
 891                 case ENT_CLIENT_VIEWLOC: ent_viewloc(); break;
 892                 case ENT_CLIENT_VIEWLOC_TRIGGER: ent_viewloc_trigger(); break;
 893                 case ENT_CLIENT_LADDER: ent_func_ladder(); break;
 894                 case ENT_CLIENT_TRIGGER_PUSH: ent_trigger_push(); break;
 895                 case ENT_CLIENT_TARGET_PUSH: ent_target_push(); break;
 896                 case ENT_CLIENT_CONVEYOR: ent_conveyor(); break;
 897                 case ENT_CLIENT_DOOR: ent_door(); break;
 898                 case ENT_CLIENT_PLAT: ent_plat(); break;
 899                 case ENT_CLIENT_SWAMP: ent_swamp(); break;
 900                 case ENT_CLIENT_CORNER: ent_corner(); break;
 901                 case ENT_CLIENT_KEYLOCK: ent_keylock(); break;
 902                 case ENT_CLIENT_TRAIN: ent_train(); break;
 903                 case ENT_CLIENT_TRIGGER_IMPULSE: ent_trigger_impulse(); break;
 904                 case ENT_CLIENT_EFFECT: Read_Effect(bIsNewEntity); break;
 905
 906                 default:
 907                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 908                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 909                         break;
 910         }
 911
 912         time = savetime;
 913 }
 914 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 915 // used when an entity changes its type. For an entity that someone interacts
 916 // with others, make sure it can no longer do so.
 917 void Ent_Remove()
 918 {SELFPARAM();
 919         if(self.entremove)
 920                 self.entremove();
 921
 922         if(self.skeletonindex)
 923         {
 924                 skel_delete(self.skeletonindex);
 925                 self.skeletonindex = 0;
 926         }
 927
 928         if(self.snd_looping > 0)
 929         {
 930                 sound(self, self.snd_looping, SND_Null, VOL_BASE, autocvar_g_jetpack_attenuation);
 931                 self.snd_looping = 0;
 932         }
 933
 934         self.enttype = 0;
 935         self.classname = "";
 936         self.draw = draw_null;
 937         self.entremove = menu_sub_null;
 938         // TODO possibly set more stuff to defaults
 939 }
 940 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 941 void CSQC_Ent_Remove()
 942 {SELFPARAM();
 943         if(autocvar_developer_csqcentities)
 944                 LOG_INFOF("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 945
 946         if(wasfreed(self))
 947         {
 948                 LOG_INFO("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 949                 return;
 950         }
 951         if(self.enttype)
 952                 Ent_Remove();
 953         remove(self);
 954 }
 955
 956 void Gamemode_Init()
 957 {
 958         if (!isdemo())
 959         {
 960                 if(!(calledhooks & HOOK_START))
 961                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 962                 calledhooks |= HOOK_START;
 963         }
 964 }
 965 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 966 void CSQC_Parse_StuffCmd(string strMessage)
 967 {
 968         if(autocvar_developer_csqcentities)
 969                 LOG_INFOF("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 970
 971         localcmd(strMessage);
 972 }
 973 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 974 void CSQC_Parse_Print(string strMessage)
 975 {
 976         if(autocvar_developer_csqcentities)
 977                 LOG_INFOF("CSQC_Parse_Print(\"%s\")\n", strMessage);
 978
 979         print(ColorTranslateRGB(strMessage));
 980 }
 981
 982 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 983 void CSQC_Parse_CenterPrint(string strMessage)
 984 {
 985         if(autocvar_developer_csqcentities)
 986                 LOG_INFOF("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 987
 988         centerprint_hud(strMessage);
 989 }
 990
 991 string notranslate_fogcmd1 = "\nfog ";
 992 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 993 void Fog_Force()
 994 {
 995         // TODO somehow thwart prvm_globalset client ...
 996
 997         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 998                 { localcmd("\nr_drawfog 0\n"); }
 999         else if(forcefog != "")
1000                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
1001 }
1002
1003 void Gamemode_Init();
1004 void Ent_ScoresInfo()
1005 {SELFPARAM();
1006     int i;
1007         self.classname = "ent_client_scores_info";
1008         gametype = ReadInt24_t();
1009         HUD_ModIcons_SetFunc();
1010         for(i = 0; i < MAX_SCORE; ++i)
1011         {
1012                 if(scores_label[i])
1013                         strunzone(scores_label[i]);
1014                 scores_label[i] = strzone(ReadString());
1015                 scores_flags[i] = ReadByte();
1016         }
1017         for(i = 0; i < MAX_TEAMSCORE; ++i)
1018         {
1019                 if(teamscores_label[i])
1020                         strunzone(teamscores_label[i]);
1021                 teamscores_label[i] = strzone(ReadString());
1022                 teamscores_flags[i] = ReadByte();
1023         }
1024         HUD_InitScores();
1025         Gamemode_Init();
1026 }
1027
1028 void Ent_Init()
1029 {SELFPARAM();
1030         self.classname = "ent_client_init";
1031
1032         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1033
1034         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1035         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1036         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1037         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1038         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1039         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1040         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1041         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1042
1043         if(forcefog)
1044                 strunzone(forcefog);
1045         forcefog = strzone(ReadString());
1046
1047         armorblockpercent = ReadByte() / 255.0;
1048
1049         g_balance_mortar_bouncefactor = ReadCoord();
1050         g_balance_mortar_bouncestop = ReadCoord();
1051         g_balance_electro_secondary_bouncefactor = ReadCoord();
1052         g_balance_electro_secondary_bouncestop = ReadCoord();
1053
1054         vortex_scope = !ReadByte();
1055         rifle_scope = !ReadByte();
1056
1057         serverflags = ReadByte();
1058
1059         minelayer_maxmines = ReadByte();
1060
1061         hagar_maxrockets = ReadByte();
1062
1063         g_trueaim_minrange = ReadCoord();
1064         g_balance_porto_secondary = ReadByte();
1065
1066         if(!postinit)
1067                 PostInit();
1068 }
1069
1070 void Net_ReadRace()
1071 {
1072         float b;
1073
1074         b = ReadByte();
1075
1076         switch(b)
1077         {
1078                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1079                         race_checkpoint = ReadByte();
1080                         race_time = ReadInt24_t();
1081                         race_previousbesttime = ReadInt24_t();
1082                         if(race_previousbestname)
1083                                 strunzone(race_previousbestname);
1084                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1085
1086                         race_checkpointtime = time;
1087
1088                         if(race_checkpoint == 0 || race_checkpoint == 254)
1089                         {
1090                                 race_penaltyaccumulator = 0;
1091                                 race_laptime = time; // valid
1092                         }
1093
1094                         break;
1095
1096                 case RACE_NET_CHECKPOINT_CLEAR:
1097                         race_laptime = 0;
1098                         race_checkpointtime = 0;
1099                         break;
1100
1101                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1102                         race_laptime = ReadCoord();
1103                         race_checkpointtime = -99999;
1104                         // fall through
1105                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1106                         race_nextcheckpoint = ReadByte();
1107
1108                         race_nextbesttime = ReadInt24_t();
1109                         if(race_nextbestname)
1110                                 strunzone(race_nextbestname);
1111                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1112                         break;
1113
1114                 case RACE_NET_CHECKPOINT_HIT_RACE:
1115                         race_mycheckpoint = ReadByte();
1116                         race_mycheckpointtime = time;
1117                         race_mycheckpointdelta = ReadInt24_t();
1118                         race_mycheckpointlapsdelta = ReadByte();
1119                         if(race_mycheckpointlapsdelta >= 128)
1120                                 race_mycheckpointlapsdelta -= 256;
1121                         if(race_mycheckpointenemy)
1122                                 strunzone(race_mycheckpointenemy);
1123                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1124                         break;
1125
1126                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1127                         race_othercheckpoint = ReadByte();
1128                         race_othercheckpointtime = time;
1129                         race_othercheckpointdelta = ReadInt24_t();
1130                         race_othercheckpointlapsdelta = ReadByte();
1131                         if(race_othercheckpointlapsdelta >= 128)
1132                                 race_othercheckpointlapsdelta -= 256;
1133                         if(race_othercheckpointenemy)
1134                                 strunzone(race_othercheckpointenemy);
1135                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1136                         break;
1137
1138                 case RACE_NET_PENALTY_RACE:
1139                         race_penaltyeventtime = time;
1140                         race_penaltytime = ReadShort();
1141                         //race_penaltyaccumulator += race_penaltytime;
1142                         if(race_penaltyreason)
1143                                 strunzone(race_penaltyreason);
1144                         race_penaltyreason = strzone(ReadString());
1145                         break;
1146
1147                 case RACE_NET_PENALTY_QUALIFYING:
1148                         race_penaltyeventtime = time;
1149                         race_penaltytime = ReadShort();
1150                         race_penaltyaccumulator += race_penaltytime;
1151                         if(race_penaltyreason)
1152                                 strunzone(race_penaltyreason);
1153                         race_penaltyreason = strzone(ReadString());
1154                         break;
1155
1156                 case RACE_NET_SERVER_RECORD:
1157                         race_server_record = ReadInt24_t();
1158                         break;
1159                 case RACE_NET_SPEED_AWARD:
1160                         race_speedaward = ReadInt24_t();
1161                         if(race_speedaward_holder)
1162                                 strunzone(race_speedaward_holder);
1163                         race_speedaward_holder = strzone(ReadString());
1164                         break;
1165                 case RACE_NET_SPEED_AWARD_BEST:
1166                         race_speedaward_alltimebest = ReadInt24_t();
1167                         if(race_speedaward_alltimebest_holder)
1168                                 strunzone(race_speedaward_alltimebest_holder);
1169                         race_speedaward_alltimebest_holder = strzone(ReadString());
1170                         break;
1171                 case RACE_NET_SERVER_RANKINGS:
1172                         float prevpos, del;
1173             int pos = ReadShort();
1174                         prevpos = ReadShort();
1175                         del = ReadShort();
1176
1177                         // move other rankings out of the way
1178             int i;
1179                         if (prevpos) {
1180                                 for (i=prevpos-1;i>pos-1;--i) {
1181                                         grecordtime[i] = grecordtime[i-1];
1182                                         if(grecordholder[i])
1183                                                 strunzone(grecordholder[i]);
1184                                         grecordholder[i] = strzone(grecordholder[i-1]);
1185                                 }
1186                         } else if (del) { // a record has been deleted by the admin
1187                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1188                                         if (i == RANKINGS_CNT-1) { // clear out last record
1189                                                 grecordtime[i] = 0;
1190                                                 if (grecordholder[i])
1191                                                         strunzone(grecordholder[i]);
1192                                                 grecordholder[i] = string_null;
1193                                         }
1194                                         else {
1195                                                 grecordtime[i] = grecordtime[i+1];
1196                                                 if (grecordholder[i])
1197                                                         strunzone(grecordholder[i]);
1198                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1199                                         }
1200                                 }
1201                         } else { // player has no ranked record yet
1202                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1203                                         grecordtime[i] = grecordtime[i-1];
1204                                         if(grecordholder[i])
1205                                                 strunzone(grecordholder[i]);
1206                                         grecordholder[i] = strzone(grecordholder[i-1]);
1207                                 }
1208                         }
1209
1210                         // store new ranking
1211                         if(grecordholder[pos-1] != "")
1212                                 strunzone(grecordholder[pos-1]);
1213                         grecordholder[pos-1] = strzone(ReadString());
1214                         grecordtime[pos-1] = ReadInt24_t();
1215                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1216                                 race_myrank = pos;
1217                         break;
1218                 case RACE_NET_SERVER_STATUS:
1219                         race_status = ReadShort();
1220                         if(race_status_name)
1221                                 strunzone(race_status_name);
1222                         race_status_name = strzone(ReadString());
1223         }
1224 }
1225
1226 void Net_TeamNagger()
1227 {
1228         teamnagger = 1;
1229 }
1230
1231 void Net_ReadPingPLReport()
1232 {
1233         int e, pi, pl, ml;
1234         e = ReadByte();
1235         pi = ReadShort();
1236         pl = ReadByte();
1237         ml = ReadByte();
1238         if (!(playerslots[e]))
1239                 return;
1240         playerslots[e].ping = pi;
1241         playerslots[e].ping_packetloss = pl / 255.0;
1242         playerslots[e].ping_movementloss = ml / 255.0;
1243 }
1244
1245 void Net_WeaponComplain()
1246 {
1247         complain_weapon = ReadByte();
1248
1249         if(complain_weapon_name)
1250                 strunzone(complain_weapon_name);
1251         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1252
1253         complain_weapon_type = ReadByte();
1254
1255         complain_weapon_time = time;
1256         weapontime = time; // ping the weapon panel
1257
1258         switch(complain_weapon_type)
1259         {
1260                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1261                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1262                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1263         }
1264 }
1265
1266 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1267 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1268 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1269 bool CSQC_Parse_TempEntity()
1270 {
1271         // Acquire TE ID
1272         int nTEID = ReadByte();
1273
1274         if (autocvar_developer_csqcentities)
1275                 LOG_INFOF("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1276
1277         FOREACH(TempEntities, it.m_id == nTEID, LAMBDA(
1278                 it.m_read(NULL, true);
1279                 return true;
1280         ));
1281         switch (nTEID)
1282         {
1283                 case TE_CSQC_MUTATOR:
1284                         int mutID = ReadMutator();
1285                         if (MUTATOR_CALLHOOK(CSQC_Parse_TempEntity, mutID))
1286                         return true;
1287                 case TE_CSQC_TARGET_MUSIC:
1288                         Net_TargetMusic();
1289                         return true;
1290                 case TE_CSQC_PICTURE:
1291                         Net_MapVote_Picture();
1292                         return true;
1293                 case TE_CSQC_RACE:
1294                         Net_ReadRace();
1295                         return true;
1296                 case TE_CSQC_VORTEXBEAMPARTICLE:
1297                         Net_ReadVortexBeamParticle();
1298                         return true;
1299                 case TE_CSQC_TEAMNAGGER:
1300                         Net_TeamNagger();
1301                         return true;
1302                 case TE_CSQC_ARC:
1303                         Net_ReadArc();
1304                         return true;
1305                 case TE_CSQC_PINGPLREPORT:
1306                         Net_ReadPingPLReport();
1307                         return true;
1308                 case TE_CSQC_WEAPONCOMPLAIN:
1309                         Net_WeaponComplain();
1310                         return true;
1311                 case TE_CSQC_VEHICLESETUP:
1312                         Net_VehicleSetup();
1313                         return true;
1314                 case TE_CSQC_SVNOTICE:
1315                         cl_notice_read();
1316                         return true;
1317                 case TE_CSQC_SHOCKWAVEPARTICLE:
1318                         Net_ReadShockwaveParticle();
1319                         return true;
1320                 default:
1321                         // No special logic for this temporary entity; return 0 so the engine can handle it
1322                         return false;
1323         }
1324 }
1325
1326 string getcommandkey(string text, string command)
1327 {
1328         string keys;
1329         float n, j, k, l = 0;
1330
1331         if (!autocvar_hud_showbinds)
1332                 return text;
1333
1334         keys = db_get(binddb, command);
1335         if (keys == "")
1336         {
1337                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1338                 for(j = 0; j < n; ++j)
1339                 {
1340                         k = stof(argv(j));
1341                         if(k != -1)
1342                         {
1343                                 if ("" == keys)
1344                                         keys = keynumtostring(k);
1345                                 else
1346                                         keys = strcat(keys, ", ", keynumtostring(k));
1347
1348                                 ++l;
1349                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1350                                         break;
1351                         }
1352
1353                 }
1354                 if (keys == "")
1355                         keys = "NO_KEY";
1356                 db_put(binddb, command, keys);
1357         }
1358
1359         if (keys == "NO_KEY") {
1360                 if (autocvar_hud_showbinds > 1)
1361                         return sprintf(_("%s (not bound)"), text);
1362                 else
1363                         return text;
1364         }
1365         else if (autocvar_hud_showbinds > 1)
1366                 return sprintf("%s (%s)", text, keys);
1367         else
1368                 return keys;
1369 }