e528187f42b7f933b967516b6815c07bce8b786c
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / mapvoting.qc
1 #include "mapvoting.qh"
2
3 #include "hud/all.qh"
4 #include "scoreboard.qh"
5
6 #include "../common/mapinfo.qh"
7
8
9 int mv_num_maps;
10
11 string mv_maps[MAPVOTE_COUNT];
12 string mv_pics[MAPVOTE_COUNT];
13 string mv_pk3[MAPVOTE_COUNT]; // map pk3 name or gametype human readable name
14 string mv_desc[MAPVOTE_COUNT];
15 float mv_preview[MAPVOTE_COUNT];
16 float mv_votes[MAPVOTE_COUNT];
17 float mv_flags[MAPVOTE_COUNT];
18 float mv_flags_start[MAPVOTE_COUNT];
19 entity mv_pk3list;
20 float mv_abstain;
21 float mv_ownvote;
22 float mv_detail;
23 float mv_timeout;
24 float mv_top2_time;
25 float mv_top2_alpha;
26
27 vector mv_mousepos;
28 int mv_selection;
29 int mv_columns;
30 int mv_mouse_selection;
31 int mv_selection_keyboard;
32
33 float gametypevote;
34 string mapvote_chosenmap;
35 vector gtv_text_size;
36 vector gtv_text_size_small;
37
38 const int NUM_SSDIRS = 4;
39 string ssdirs[NUM_SSDIRS];
40 int n_ssdirs;
41
42 string MapVote_FormatMapItem(int id, string map, float _count, float maxwidth, vector fontsize)
43 {
44         string pre, post;
45         pre = sprintf("%d. ", id+1);
46         if(mv_detail)
47         {
48                 if(_count == 1)
49                         post = _(" (1 vote)");
50                 else if(_count >= 0 && (mv_flags[id] & GTV_AVAILABLE))
51                         post = sprintf(_(" (%d votes)"), _count);
52                 else
53                         post = "";
54         }
55         else
56                 post = "";
57         maxwidth -= stringwidth(pre, false, fontsize) + stringwidth(post, false, fontsize);
58         map = textShortenToWidth(map, maxwidth, fontsize, stringwidth_nocolors);
59         return strcat(pre, map, post);
60 }
61
62 vector MapVote_RGB(int id)
63 {
64         if(!(mv_flags[id] & GTV_AVAILABLE))
65                 return '1 1 1';
66         if(id == mv_ownvote)
67                 return '0 1 0';
68         else if (id == mv_selection)
69                 return '1 1 0';
70         else
71                 return '1 1 1';
72 }
73
74 void GameTypeVote_DrawGameTypeItem(vector pos, float maxh, float tsize, string gtype, string pic, float _count, int id)
75 {
76         // Find the correct alpha
77         float alpha;
78         if(!(mv_flags_start[id] & GTV_AVAILABLE))
79                 alpha = 0.2; // The gametype isn't supported by the map
80         else if ( !(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
81                 alpha = mv_top2_alpha; // Fade away if not one of the top 2 choice
82         else
83                 alpha = 1; // Normal, full alpha
84
85         // Bounding box details
86         float rect_margin = hud_fontsize.y / 2;
87
88         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
89         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
90         maxh -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
91         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
92
93         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
94         vector rect_size = '1 1 0';
95         rect_size.x = tsize + rect_margin;
96         rect_size.y = maxh + rect_margin;
97
98         // Highlight selected item
99         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
100         {
101                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
102         }
103
104         // Highlight current vote
105         vector rgb = MapVote_RGB(id);
106         if(id == mv_ownvote)
107         {
108                 drawfill(rect_pos, rect_size, rgb, 0.1*alpha, DRAWFLAG_NORMAL);
109                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, alpha, DRAWFLAG_NORMAL);
110         }
111
112         vector offset = pos;
113
114         float title_gap = gtv_text_size.y * 1.4; // distance between the title and the description
115         pos.y += title_gap;
116         maxh -= title_gap;
117
118         // Evaluate the image size
119         vector image_size = '1 1 0' * gtv_text_size.x * 3;
120         if ( maxh < image_size.y )
121                 image_size = '1 1 0' * maxh;
122         image_size *= 0.8;
123         float desc_padding = gtv_text_size.x * 0.6;
124         pos.x += image_size.x + desc_padding;
125         tsize -= image_size.x + desc_padding;
126
127         // Split the description into lines
128         entity title;
129         title = spawn();
130         title.message = MapVote_FormatMapItem(id, mv_pk3[id], _count, tsize, gtv_text_size);
131
132         string thelabel = mv_desc[id], ts;
133         entity last = title;
134         entity next = world;
135         float nlines = 0;
136         if( thelabel != "")
137         {
138                 float i,n = tokenizebyseparator(thelabel, "\n");
139                 for(i = 0; i < n && maxh > (nlines+1)*gtv_text_size_small.y; ++i)
140                 {
141                         getWrappedLine_remaining = argv(i);
142                         while(getWrappedLine_remaining && maxh > (nlines+1)*gtv_text_size_small.y)
143                         {
144                                 ts = getWrappedLine(tsize, gtv_text_size_small, stringwidth_colors);
145                                 if (ts != "")
146                                 {
147                                         next = spawn();
148                                         next.message = ts;
149                                         next.origin = pos-offset;
150                                         last.chain = next;
151                                         last = next;
152                                         pos.y += gtv_text_size_small.y;
153                                         nlines++;
154                                 }
155                         }
156                 }
157         }
158
159         // Center the contents in the bounding box
160         maxh -= max(nlines*gtv_text_size_small.y,image_size.y);
161         if ( maxh > 0 )
162                 offset.y += maxh/2;
163
164         // Draw the title
165         drawstring(offset, title.message, gtv_text_size, rgb, alpha, DRAWFLAG_NORMAL);
166
167         // Draw the icon
168         if(pic != "")
169                 drawpic('0 1 0'*title_gap+'0.5 0 0'*desc_padding+offset, pic, image_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
170
171         // Draw the description
172         for ( last = title.chain; last ; )
173         {
174                 drawstring(last.origin+offset, last.message, gtv_text_size_small, '1 1 1', alpha, DRAWFLAG_NORMAL);
175                 next = last;
176                 last = last.chain;
177                 remove(next);
178         }
179
180         // Cleanup
181         remove(title);
182 }
183
184 void MapVote_DrawMapItem(vector pos, float isize, float tsize, string map, string pic, float _count, int id)
185 {
186         vector img_size = '0 0 0';
187         string label;
188         float text_size;
189
190         float rect_margin = hud_fontsize.y / 2;
191
192         pos.x += rect_margin + autocvar_scoreboard_border_thickness;
193         pos.y += rect_margin + autocvar_scoreboard_border_thickness;
194         isize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
195         tsize -= 2 * (rect_margin + autocvar_scoreboard_border_thickness);
196
197         vector rect_pos = pos - '0.5 0.5 0' * rect_margin;
198         vector rect_size = '1 1 0';
199         rect_size.x = tsize + rect_margin;
200         rect_size.y = isize + rect_margin;
201
202         float img_ar = 4/3;
203         img_size.x = min(tsize, isize * img_ar);
204         img_size.y = img_size.x / img_ar;
205         img_size.y -= hud_fontsize.y;
206         img_size.x = img_size.y * img_ar;
207
208         pos.y += (isize - img_size.y - hud_fontsize.y) / 2;
209
210         label = MapVote_FormatMapItem(id, map, _count, tsize, hud_fontsize);
211
212         text_size = stringwidth(label, false, hud_fontsize);
213
214         float save_rect_sizex = rect_size.x;
215         rect_size.x = max(img_size.x, text_size) + rect_margin;
216         rect_pos.x += (save_rect_sizex - rect_size.x) / 2;
217
218         vector text_pos = '0 0 0';
219         text_pos.x = pos.x + (tsize - text_size) / 2;
220         text_pos.y = pos.y + img_size.y;
221
222         pos.x += (tsize - img_size.x) / 2;
223
224         float theAlpha;
225         if (!(mv_flags[id] & GTV_AVAILABLE) && mv_top2_alpha)
226                 theAlpha = mv_top2_alpha;
227         else
228                 theAlpha = 1;
229
230         // Highlight selected item
231         if(id == mv_selection && (mv_flags[id] & GTV_AVAILABLE))
232                 drawfill(rect_pos, rect_size, '1 1 1', 0.1, DRAWFLAG_NORMAL);
233
234         // Highlight current vote
235         vector rgb = MapVote_RGB(id);
236         if(id == mv_ownvote)
237         {
238                 drawfill(rect_pos, rect_size, rgb, 0.1*theAlpha, DRAWFLAG_NORMAL);
239                 drawborderlines(autocvar_scoreboard_border_thickness, rect_pos, rect_size, rgb, theAlpha, DRAWFLAG_NORMAL);
240         }
241
242         drawstring(text_pos, label, hud_fontsize, rgb, theAlpha, DRAWFLAG_NORMAL);
243
244         if(pic == "")
245         {
246                 drawfill(pos, img_size, '.5 .5 .5', .7 * theAlpha, DRAWFLAG_NORMAL);
247         }
248         else
249         {
250                 if(drawgetimagesize(pic) == '0 0 0')
251                         drawpic(pos, draw_UseSkinFor("nopreview_map"), img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
252                 else
253                         drawpic(pos, pic, img_size, '1 1 1', theAlpha, DRAWFLAG_NORMAL);
254         }
255 }
256
257 void MapVote_DrawAbstain(vector pos, float isize, float tsize, float _count, int id)
258 {
259         vector rgb;
260         float text_size;
261         string label;
262
263         rgb = MapVote_RGB(id);
264
265         label = MapVote_FormatMapItem(id, _("Don't care"), _count, tsize, hud_fontsize);
266
267         text_size = stringwidth(label, false, hud_fontsize);
268
269         pos.x -= text_size*0.5;
270         drawstring(pos, label, hud_fontsize, rgb, 1, DRAWFLAG_NORMAL);
271 }
272
273 vector MapVote_GridVec(vector gridspec, int i, int m)
274 {
275         int r = i % m;
276         return
277                 '1 0 0' * (gridspec.x * r)
278                 +
279                 '0 1 0' * (gridspec.y * (i - r) / m);
280 }
281
282 float MapVote_Selection(vector topleft, vector cellsize, float rows, float columns)
283 {
284
285         float c, r;
286
287         mv_mouse_selection = -1;
288
289         for (r = 0; r < rows; ++r)
290                 for (c = 0; c < columns; ++c)
291                 {
292                         if (mv_mousepos.x >= topleft.x + cellsize.x *  c &&
293                                 mv_mousepos.x <= topleft.x + cellsize.x * (c + 1) &&
294                                 mv_mousepos.y >= topleft.y + cellsize.y *  r &&
295                                 mv_mousepos.y <= topleft.y + cellsize.y * (r + 1))
296                         {
297                                 mv_mouse_selection = r * columns + c;
298                                 break;
299                         }
300                 }
301
302         if (mv_mouse_selection >= mv_num_maps)
303                 mv_mouse_selection = -1;
304
305         if (mv_abstain && mv_mouse_selection < 0)
306                 mv_mouse_selection = mv_num_maps;
307
308         if ( mv_selection_keyboard )
309                 return mv_selection;
310
311         return mv_mouse_selection;
312 }
313
314 vector HUD_GetTableSize_BestItemAR(int item_count, vector psize, float item_aspect);
315 void MapVote_Draw()
316 {
317         string map;
318         int i;
319         float tmp;
320         vector pos;
321         float center;
322         float rows;
323         vector dist = '0 0 0';
324
325         //if(intermission != 2) return;
326         if(!mv_active)
327                 return;
328
329         if (!autocvar_hud_cursormode)
330         {
331                 vector mpos = mv_mousepos + getmousepos();
332                 mpos.x = bound(0, mpos.x, vid_conwidth);
333                 mpos.y = bound(0, mpos.y, vid_conheight);
334
335                 if ( mpos.x != mv_mousepos.x || mpos.y != mv_mousepos.y )
336                         mv_selection_keyboard = 0;
337                 mv_mousepos = mpos;
338
339         }
340
341         center = (vid_conwidth - 1)/2;
342         xmin = vid_conwidth * 0.08;
343         xmax = vid_conwidth - xmin;
344         ymin = 20;
345         ymax = vid_conheight - ymin;
346
347         if(chat_posy + chat_sizey / 2 < vid_conheight / 2)
348                 ymin += chat_sizey;
349         else
350                 ymax -= chat_sizey;
351
352         hud_fontsize = HUD_GetFontsize("hud_fontsize");
353
354         pos.y = ymin;
355         pos.z = 0;
356
357         draw_beginBoldFont();
358
359         map = ((gametypevote) ? _("Decide the gametype") : _("Vote for a map"));
360         pos.x = center - stringwidth(map, false, hud_fontsize * 2) * 0.5;
361         drawstring(pos, map, hud_fontsize * 2, '1 1 1', 1, DRAWFLAG_NORMAL);
362         pos.y += hud_fontsize.y * 2;
363
364         if( mapvote_chosenmap != "" )
365         {
366                 pos.y += hud_fontsize.y * 0.25;
367                 pos.x = center - stringwidth(mapvote_chosenmap, false, hud_fontsize * 1.5) * 0.5;
368                 drawstring(pos, mapvote_chosenmap, hud_fontsize * 1.5, '1 1 1', 1, DRAWFLAG_NORMAL);
369                 pos.y += hud_fontsize.y * 1.5;
370                 pos.y += hud_fontsize.y * 0.5;
371         }
372         else
373                 pos.y += hud_fontsize.y * 0.5;
374
375         draw_endBoldFont();
376
377         i = ceil(max(0, mv_timeout - time));
378         map = sprintf(_("%d seconds left"), i);
379         pos.x = center - stringwidth(map, false, hud_fontsize * 1.5) * 0.5;
380         drawstring(pos, map, hud_fontsize * 1.5, '0 1 0', 1, DRAWFLAG_NORMAL);
381         pos.y += hud_fontsize.y * 1.5;
382         pos.y += hud_fontsize.y * 0.5;
383
384         HUD_Panel_UpdateCvars();
385
386         // base for multi-column stuff...
387         pos.y += hud_fontsize.y;
388         pos.x = xmin;
389         ymin = pos.y;
390         float abstain_spacing = panel_bg_border + hud_fontsize.y;
391         if(mv_abstain)
392         {
393                 mv_num_maps -= 1;
394                 ymax -= abstain_spacing;
395         }
396
397         // higher than the image itself ratio for mapvote items to reserve space for long map names
398         int item_aspect = (gametypevote) ? 3/1 : 5/3;
399         vector table_size = HUD_GetTableSize_BestItemAR(mv_num_maps, eX * (xmax - xmin) + eY * (ymax - ymin), item_aspect);
400         mv_columns = table_size.x;
401         rows = table_size.y;
402
403         dist.x = (xmax - xmin) / mv_columns;
404         dist.y = (ymax - pos.y) / rows;
405
406         // reduce size of too wide items
407         tmp = vid_conwidth / 3; // max width
408         if(dist.x > tmp)
409         {
410                 dist.x = tmp;
411                 dist.y = min(dist.y, dist.x / item_aspect);
412         }
413         tmp = vid_conheight / 3; // max height
414         if(dist.y > tmp)
415         {
416                 dist.y = tmp;
417                 dist.x = min(dist.x, dist.y * item_aspect);
418         }
419
420         // reduce size to fix aspect ratio
421         if(dist.x / dist.y > item_aspect)
422                 dist.x = dist.y * item_aspect;
423         else
424                 dist.y = dist.x / item_aspect;
425
426         // adjust table pos and size according to the new size
427         float offset;
428         offset = ((xmax - pos.x) - dist.x * mv_columns) / 2;
429         xmin = pos.x += offset;
430         xmax -= offset;
431         offset = ((ymax - pos.y) - dist.y * rows) / 2;
432         ymax -= 2 * offset;
433
434         // override panel_pos and panel_size
435         panel_pos.x = pos.x;
436         panel_pos.y = pos.y;
437         panel_size.x = xmax - xmin;
438         panel_size.y = ymax - ymin;
439         HUD_Panel_DrawBg(1);
440
441         if(panel_bg_padding)
442         {
443                 // FIXME item AR gets slightly changed here...
444                 // it's rather hard to avoid it at this point
445                 dist.x -= 2 * panel_bg_padding / mv_columns;
446                 dist.y -= 2 * panel_bg_padding / rows;
447                 xmin = pos.x += panel_bg_padding;
448                 ymin = pos.y += panel_bg_padding;
449                 xmax -= 2 * panel_bg_padding;
450                 ymax -= 2 * panel_bg_padding;
451         }
452
453         mv_selection = MapVote_Selection(pos, dist, rows, mv_columns);
454
455         if (mv_top2_time)
456                 mv_top2_alpha = max(0.2, 1 - (time - mv_top2_time)*(time - mv_top2_time));
457
458         void (vector, float, float, string, string, float, float) DrawItem;
459
460         if(gametypevote)
461                 DrawItem = GameTypeVote_DrawGameTypeItem;
462         else
463                 DrawItem = MapVote_DrawMapItem;
464
465         for(i = 0; i < mv_num_maps; ++i)
466         {
467                 tmp = mv_votes[i]; // FTEQCC bug: too many array accesses in the function call screw it up
468                 map = mv_maps[i];
469                 if(mv_preview[i])
470                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, mv_pics[i], tmp, i);
471                 else
472                         DrawItem(pos + MapVote_GridVec(dist, i, mv_columns), dist.y, dist.x, map, "", tmp, i);
473         }
474
475         if(mv_abstain)
476                 ++mv_num_maps;
477
478         if(mv_abstain && i < mv_num_maps) {
479                 tmp = mv_votes[i];
480                 pos.y = ymax + abstain_spacing;
481                 pos.x = (xmax+xmin)*0.5;
482                 MapVote_DrawAbstain(pos, dist.x, xmax - xmin, tmp, i);
483         }
484
485         drawpic(mv_mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), '32 32 0', '1 1 1', 1 - autocvar__menu_alpha, DRAWFLAG_NORMAL);
486 }
487
488 void Cmd_MapVote_MapDownload(float argc)
489 {
490         entity pak;
491
492         if(argc != 2 || !mv_pk3list)
493         {
494                 LOG_INFO(_("mv_mapdownload: ^3You're not supposed to use this command on your own!\n"));
495                 return;
496         }
497
498         int id = stof(argv(1));
499         for(pak = mv_pk3list; pak; pak = pak.chain)
500                 if(pak.sv_entnum == id)
501                         break;
502
503         if(!pak || pak.sv_entnum != id) {
504                 LOG_INFO(_("^1Error:^7 Couldn't find pak index.\n"));
505                 return;
506         }
507
508         if(PreviewExists(pak.message))
509         {
510                 mv_preview[id] = true;
511                 return;
512         } else {
513                 LOG_INFO(_("Requesting preview...\n"));
514                 localcmd(strcat("\ncmd mv_getpicture ", ftos(id), "\n"));
515         }
516 }
517
518 void MapVote_CheckPK3(string pic, string pk3, int id)
519 {
520         entity pak;
521         pak = spawn();
522         pak.netname = pk3;
523         pak.message = pic;
524         pak.sv_entnum = id;
525
526         pak.chain = mv_pk3list;
527         mv_pk3list = pak;
528
529         if(pk3 != "")
530         {
531                 localcmd(strcat("\ncurl --pak ", pk3, "; wait; cl_cmd mv_download ", ftos(id), "\n"));
532         }
533         else
534         {
535                 Cmd_MapVote_MapDownload(tokenize_console(strcat("mv_download ", ftos(id))));
536         }
537 }
538
539 void MapVote_CheckPic(string pic, string pk3, int id)
540 {
541         // never try to retrieve a pic for the "don't care" 'map'
542         if(mv_abstain && id == mv_num_maps - 1)
543                 return;
544
545         if(PreviewExists(pic))
546         {
547                 mv_preview[id] = true;
548                 return;
549         }
550         MapVote_CheckPK3(pic, pk3, id);
551 }
552
553 void MapVote_ReadMask()
554 {
555         int i;
556         if ( mv_num_maps < 24 )
557         {
558                 int mask, power;
559                 if(mv_num_maps < 8)
560                         mask = ReadByte();
561                 else if(mv_num_maps < 16)
562                         mask = ReadShort();
563                 else
564                         mask = ReadLong();
565
566                 for(i = 0, power = 1; i < mv_num_maps; ++i, power *= 2)
567                 {
568                         if ( mask & power )
569                                 mv_flags[i] |= GTV_AVAILABLE;
570                         else
571                                 mv_flags[i] &= ~GTV_AVAILABLE;
572                 }
573         }
574         else
575         {
576                 for(i = 0; i < mv_num_maps; ++i )
577                         mv_flags[i] = ReadByte();
578         }
579 }
580
581 void MapVote_ReadOption(int i)
582 {
583         string map = strzone(ReadString());
584         string pk3 = strzone(ReadString());
585         int j = bound(0, ReadByte(), n_ssdirs - 1);
586
587         mv_maps[i] = map;
588         mv_pk3[i] = pk3;
589         mv_flags[i] = GTV_AVAILABLE;
590
591         string pic = strzone(strcat(ssdirs[j], "/", map));
592         mv_pics[i] = pic;
593         mv_preview[i] = false;
594         MapVote_CheckPic(pic, pk3, i);
595 }
596
597 void GameTypeVote_ReadOption(int i)
598 {
599         string gt = strzone(ReadString());
600
601         mv_maps[i] = gt;
602         mv_flags[i] = ReadByte();
603
604         string mv_picpath = sprintf("gfx/menu/%s/gametype_%s", autocvar_menu_skin, gt);
605         if(precache_pic(mv_picpath) == "")
606                 mv_picpath = strcat("gfx/menu/default/gametype_", gt);
607         string pic = strzone(mv_picpath);
608         mv_pics[i] = pic;
609         mv_preview[i] = PreviewExists(pic);
610
611         if ( mv_flags[i] & GTV_CUSTOM )
612         {
613                 string name = ReadString();
614                 if ( strlen(name) < 1 )
615                         name = gt;
616                 mv_pk3[i] = strzone(name);
617                 mv_desc[i] = strzone(ReadString());
618         }
619         else
620         {
621                 int type = MapInfo_Type_FromString(gt);
622                 mv_pk3[i] = strzone(MapInfo_Type_ToText(type));
623                 mv_desc[i] = MapInfo_Type_Description(type);
624         }
625 }
626
627 void MapVote_Init()
628 {
629         mv_active = 1;
630         if(autocvar_hud_cursormode) { setcursormode(1); }
631         else { mv_mousepos = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight; }
632         mv_selection = -1;
633         mv_selection_keyboard = 0;
634
635         string s;
636         for(n_ssdirs = 0; ; ++n_ssdirs)
637         {
638                 s = ReadString();
639                 if(s == "")
640                         break;
641                 if(n_ssdirs < NUM_SSDIRS)
642                         ssdirs[n_ssdirs] = s;
643         }
644         n_ssdirs = min(n_ssdirs, NUM_SSDIRS);
645
646         mv_num_maps = min(MAPVOTE_COUNT, ReadByte());
647         mv_abstain = ReadByte();
648         if(mv_abstain)
649                 mv_abstain = 1; // must be 1 for bool-true, makes stuff easier
650         mv_detail = ReadByte();
651
652         mv_ownvote = -1;
653         mv_timeout = ReadCoord();
654
655         gametypevote = ReadByte();
656
657         if(gametypevote)
658         {
659                 mapvote_chosenmap = strzone(ReadString());
660                 if ( gametypevote == 2 )
661                         gametypevote = 0;
662
663                 gtv_text_size = hud_fontsize*1.4;
664                 gtv_text_size_small = hud_fontsize*1.1;
665         }
666
667         MapVote_ReadMask();
668         int i;
669         for(i = 0; i < mv_num_maps; ++i )
670                 mv_flags_start[i] = mv_flags[i];
671
672         // Assume mv_pk3list is world, there should only be 1 mapvote per round
673         mv_pk3list = world; // I'm still paranoid!
674
675         for(i = 0; i < mv_num_maps; ++i)
676         {
677                 mv_votes[i] = 0;
678
679                 if ( gametypevote )
680                         GameTypeVote_ReadOption(i);
681                 else
682                         MapVote_ReadOption(i);
683         }
684
685         for(i = 0; i < n_ssdirs; ++i)
686                 ssdirs[n_ssdirs] = string_null;
687         n_ssdirs = 0;
688 }
689
690 void MapVote_SendChoice(float index)
691 {
692         localcmd(strcat("\nimpulse ", ftos(index+1), "\n"));
693 }
694
695 int MapVote_MoveLeft(int pos)
696 {
697         int imp;
698         if ( pos < 0 )
699                 imp = mv_num_maps - 1;
700         else
701                 imp = pos < 1 ? mv_num_maps - 1 : pos - 1;
702         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
703                 imp = MapVote_MoveLeft(imp);
704         return imp;
705 }
706 int MapVote_MoveRight(int pos)
707 {
708         int imp;
709         if ( pos < 0 )
710                 imp = 0;
711         else
712                 imp = pos >= mv_num_maps - 1 ? 0 : pos + 1;
713         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
714                 imp = MapVote_MoveRight(imp);
715         return imp;
716 }
717 int MapVote_MoveUp(int pos)
718 {
719         int imp;
720         if ( pos < 0 )
721                 imp = mv_num_maps - 1;
722         else
723         {
724                 imp = pos - mv_columns;
725                 if ( imp < 0 )
726                 {
727                         imp = floor(mv_num_maps/mv_columns)*mv_columns + pos % mv_columns;
728                         if ( imp >= mv_num_maps )
729                                 imp -= mv_columns;
730                 }
731         }
732         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
733                 imp = MapVote_MoveUp(imp);
734         return imp;
735 }
736 int MapVote_MoveDown(int pos)
737 {
738         int imp;
739         if ( pos < 0 )
740                 imp = 0;
741         else
742         {
743                 imp = pos + mv_columns;
744                 if ( imp >= mv_num_maps )
745                         imp = imp % mv_columns;
746         }
747         if ( !(mv_flags[imp] & GTV_AVAILABLE) && imp != mv_ownvote )
748                 imp = MapVote_MoveDown(imp);
749         return imp;
750 }
751
752 float MapVote_InputEvent(float bInputType, float nPrimary, float nSecondary)
753 {
754         float imp;
755
756         if (!mv_active)
757                 return false;
758
759         if(bInputType == 3)
760         {
761                 mv_mousepos.x = nPrimary;
762                 mv_mousepos.y = nSecondary;
763                 mv_selection_keyboard = 0;
764                 return true;
765         }
766
767         if (bInputType != 0)
768                 return false;
769
770         if ('0' <= nPrimary && nPrimary <= '9')
771         {
772                 imp = nPrimary - '0';
773                 if (imp == 0) imp = 10;
774                 localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
775                 return true;
776         }
777         switch(nPrimary)
778         {
779                 case K_KP_1: localcmd("\nimpulse 1\n"); return true;
780                 case K_KP_2: localcmd("\nimpulse 2\n"); return true;
781                 case K_KP_3: localcmd("\nimpulse 3\n"); return true;
782                 case K_KP_4: localcmd("\nimpulse 4\n"); return true;
783                 case K_KP_5: localcmd("\nimpulse 5\n"); return true;
784                 case K_KP_6: localcmd("\nimpulse 6\n"); return true;
785                 case K_KP_7: localcmd("\nimpulse 7\n"); return true;
786                 case K_KP_8: localcmd("\nimpulse 8\n"); return true;
787                 case K_KP_9: localcmd("\nimpulse 9\n"); return true;
788                 case K_KP_0: localcmd("\nimpulse 10\n"); return true;
789
790                 case K_RIGHTARROW:
791                         mv_selection_keyboard = 1;
792                         mv_selection = MapVote_MoveRight(mv_selection);
793                         return true;
794                 case K_LEFTARROW:
795                         mv_selection_keyboard = 1;
796                         mv_selection = MapVote_MoveLeft(mv_selection);
797                         return true;
798                 case K_DOWNARROW:
799                         mv_selection_keyboard = 1;
800                         mv_selection = MapVote_MoveDown(mv_selection);
801                         return true;
802                 case K_UPARROW:
803                         mv_selection_keyboard = 1;
804                         mv_selection = MapVote_MoveUp(mv_selection);
805                         return true;
806                 case K_KP_ENTER:
807                 case K_ENTER:
808                 case K_SPACE:
809                         if ( mv_selection_keyboard )
810                                 MapVote_SendChoice(mv_selection);
811                         return true;
812         }
813
814         if (nPrimary == K_MOUSE1)
815         {
816                 mv_selection_keyboard = 0;
817                 mv_selection = mv_mouse_selection;
818                 if (mv_selection >= 0)
819                 {
820                         imp = min(mv_selection + 1, mv_num_maps);
821                         localcmd(strcat("\nimpulse ", ftos(imp), "\n"));
822                         return true;
823                 }
824         }
825
826         return false;
827 }
828
829 void MapVote_UpdateMask()
830 {
831         MapVote_ReadMask();
832         mv_top2_time = time;
833 }
834
835 void MapVote_UpdateVotes()
836 {
837         int i;
838         for(i = 0; i < mv_num_maps; ++i)
839         {
840                 if(mv_flags[i] & GTV_AVAILABLE)
841                 {
842                         if(mv_detail)
843                                 mv_votes[i] = ReadByte();
844                         else
845                                 mv_votes[i] = 0;
846                 }
847                 else
848                         mv_votes[i] = -1;
849         }
850
851         mv_ownvote = ReadByte()-1;
852 }
853
854 void Ent_MapVote()
855 {
856         make_pure(self);
857         int sf = ReadByte();
858
859         if(sf & 1)
860                 MapVote_Init();
861
862         if(sf & 2)
863                 MapVote_UpdateMask();
864
865         if(sf & 4)
866                 MapVote_UpdateVotes();
867 }
868
869 NET_HANDLE(TE_CSQC_PICTURE, bool isNew)
870 {
871         Net_MapVote_Picture();
872         return true;
873 }
874
875 void Net_MapVote_Picture()
876 {
877         int type = ReadByte();
878         mv_preview[type] = true;
879         mv_pics[type] = strzone(ReadPicture());
880 }