qcsrc/client/view.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "defs.qh"
   4         #include "../common/constants.qh"
   5         #include "../common/stats.qh"
   6         #include "../warpzonelib/mathlib.qh"
   7         #include "../warpzonelib/common.qh"
   8         #include "../warpzonelib/client.qh"
   9         #include "../common/teams.qh"
  10         #include "../common/util.qh"
  11         #include "../common/nades.qh"
  12         #include "../common/weapons/weapons.qh"
  13         #include "../common/mapinfo.qh"
  14         #include "autocvars.qh"
  15         #include "announcer.qh"
  16         #include "hud.qh"
  17         #include "hud_config.qh"
  18         #include "hook.qh"
  19         #include "mapvoting.qh"
  20         #include "miscfunctions.qh"
  21         #include "scoreboard.qh"
  22         #include "shownames.qh"
  23         #include "target_music.qh"
  24         #include "noise.qh"
  25         #include "main.qh"
  26         #include "waypointsprites.qh"
  27         #include "vehicles/vehicles.qh"
  28         #include "../csqcmodellib/cl_player.qh"
  29 #elif defined(MENUQC)
  30 #elif defined(SVQC)
  31 #endif
  32
  33 entity porto;
  34 vector polyline[16];
  35 void Porto_Draw()
  36 {
  37         vector p, dir, ang, q, nextdir;
  38         float portal_number, portal1_idx;
  39
  40         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  41                 return;
  42         if(g_balance_porto_secondary)
  43                 return;
  44         if(intermission == 1)
  45                 return;
  46         if(intermission == 2)
  47                 return;
  48         if (getstati(STAT_HEALTH) <= 0)
  49                 return;
  50
  51         dir = view_forward;
  52
  53         if(angles_held_status)
  54         {
  55                 makevectors(angles_held);
  56                 dir = v_forward;
  57         }
  58
  59         p = view_origin;
  60
  61         polyline[0] = p;
  62         int idx = 1;
  63         portal_number = 0;
  64         nextdir = dir;
  65
  66         for (;;)
  67         {
  68                 dir = nextdir;
  69                 traceline(p, p + 65536 * dir, true, porto);
  70                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  71                         return;
  72                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  73                 p = trace_endpos;
  74                 polyline[idx] = p;
  75                 ++idx;
  76                 if(idx >= 16)
  77                         return;
  78                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  79                         continue;
  80                 ++portal_number;
  81                 ang = vectoangles2(trace_plane_normal, dir);
  82                 ang.x = -ang.x;
  83                 makevectors(ang);
  84                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  85                         return;
  86                 if(portal_number == 1)
  87                 {
  88                         portal1_idx = idx;
  89                         if(portal_number >= 2)
  90                                 break;
  91                 }
  92         }
  93
  94         while(idx >= 2)
  95         {
  96                 p = polyline[idx-2];
  97                 q = polyline[idx-1];
  98                 if(idx == 2)
  99                         p = p - view_up * 16;
 100                 if(idx-1 >= portal1_idx)
 101                 {
 102                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 103                 }
 104                 else
 105                 {
 106                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 107                 }
 108                 --idx;
 109         }
 110 }
 111
 112 void Porto_Init()
 113 {
 114         porto = spawn();
 115         porto.classname = "porto";
 116         porto.draw = Porto_Draw;
 117         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 118 }
 119
 120 float drawtime;
 121 float avgspeed;
 122 vector GetCurrentFov(float fov)
 123 {
 124         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 125         float velocityzoom, curspeed;
 126         vector v;
 127
 128         zoomsensitivity = autocvar_cl_zoomsensitivity;
 129         zoomfactor = autocvar_cl_zoomfactor;
 130         if(zoomfactor < 1 || zoomfactor > 16)
 131                 zoomfactor = 2.5;
 132         zoomspeed = autocvar_cl_zoomspeed;
 133         if(zoomspeed >= 0)
 134         if(zoomspeed < 0.5 || zoomspeed > 16)
 135                         zoomspeed = 3.5;
 136
 137         zoomdir = button_zoom;
 138         if(hud == HUD_NORMAL)
 139         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 140                 zoomdir += button_attack2;
 141         if(spectatee_status > 0 || isdemo())
 142         {
 143                 if(spectatorbutton_zoom)
 144                 {
 145                         if(zoomdir)
 146                                 zoomdir = 0;
 147                         else
 148                                 zoomdir = 1;
 149                 }
 150                 // fteqcc failed twice here already, don't optimize this
 151         }
 152
 153         if(zoomdir) { zoomin_effect = 0; }
 154
 155         if(camera_active)
 156         {
 157                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 158         }
 159         else if(autocvar_cl_spawnzoom && zoomin_effect)
 160         {
 161                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 162
 163                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 164                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 165                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 166         }
 167         else
 168         {
 169                 if(zoomspeed < 0) // instant zoom
 170                 {
 171                         if(zoomdir)
 172                                 current_viewzoom = 1 / zoomfactor;
 173                         else
 174                                 current_viewzoom = 1;
 175                 }
 176                 else
 177                 {
 178                         if(zoomdir)
 179                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 180                         else
 181                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 182                 }
 183         }
 184
 185         if(almost_equals(current_viewzoom, 1))
 186                 current_zoomfraction = 0;
 187         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 188                 current_zoomfraction = 1;
 189         else
 190                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 191
 192         if(zoomsensitivity < 1)
 193                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 194         else
 195                 setsensitivityscale(1);
 196
 197         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 198         {
 199                 if(intermission) { curspeed = 0; }
 200                 else
 201                 {
 202
 203                         makevectors(view_angles);
 204                         v = pmove_vel;
 205                         if(csqcplayer)
 206                                 v = csqcplayer.velocity;
 207
 208                         switch(autocvar_cl_velocityzoom_type)
 209                         {
 210                                 case 3: curspeed = max(0, v_forward * v); break;
 211                                 case 2: curspeed = (v_forward * v); break;
 212                                 case 1: default: curspeed = vlen(v); break;
 213                         }
 214                 }
 215
 216                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 217                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 218                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 219
 220                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 221         }
 222         else
 223                 velocityzoom = 1;
 224
 225         float frustumx, frustumy, fovx, fovy;
 226         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 227         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 228         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 229         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 230
 231         return '1 0 0' * fovx + '0 1 0' * fovy;
 232 }
 233
 234 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 235 {
 236         float fovx, fovy;
 237         float width = (ov_worldmax.x - ov_worldmin.x);
 238         float height = (ov_worldmax.y - ov_worldmin.y);
 239         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 240         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 241         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 242         return '1 0 0' * fovx + '0 1 0' * fovy;
 243 }
 244
 245 // this function must match W_SetupShot!
 246 float zoomscript_caught;
 247
 248 vector wcross_origin;
 249 float wcross_scale_prev, wcross_alpha_prev;
 250 vector wcross_color_prev;
 251 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 252 vector wcross_color_goal_prev;
 253 float wcross_changedonetime;
 254
 255 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 256 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 257 float wcross_name_changestarttime, wcross_name_changedonetime;
 258 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 259
 260 float wcross_ring_prev;
 261
 262 entity trueaim;
 263 entity trueaim_rifle;
 264
 265 const float SHOTTYPE_HITTEAM = 1;
 266 const float SHOTTYPE_HITOBSTRUCTION = 2;
 267 const float SHOTTYPE_HITWORLD = 3;
 268 const float SHOTTYPE_HITENEMY = 4;
 269
 270 void TrueAim_Init()
 271 {
 272         trueaim = spawn();
 273         trueaim.classname = "trueaim";
 274         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 275         trueaim_rifle = spawn();
 276         trueaim_rifle.classname = "trueaim_rifle";
 277         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 278 }
 279
 280 float EnemyHitCheck()
 281 {
 282         float t, n;
 283         wcross_origin = project_3d_to_2d(trace_endpos);
 284         wcross_origin.z = 0;
 285         if(trace_ent)
 286                 n = trace_ent.entnum;
 287         else
 288                 n = trace_networkentity;
 289         if(n < 1)
 290                 return SHOTTYPE_HITWORLD;
 291         if(n > maxclients)
 292                 return SHOTTYPE_HITWORLD;
 293         t = GetPlayerColor(n - 1);
 294         if(teamplay)
 295                 if(t == myteam)
 296                         return SHOTTYPE_HITTEAM;
 297         if(t == NUM_SPECTATOR)
 298                 return SHOTTYPE_HITWORLD;
 299         return SHOTTYPE_HITENEMY;
 300 }
 301
 302 float TrueAimCheck()
 303 {
 304         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 305         vector vecs, trueaimpoint, w_shotorg;
 306         vector mi, ma, dv;
 307         float shottype;
 308         entity ta;
 309         float mv;
 310
 311         mi = ma = '0 0 0';
 312         ta = trueaim;
 313         mv = MOVE_NOMONSTERS;
 314
 315         switch(activeweapon) // WEAPONTODO
 316         {
 317                 case WEP_TUBA: // no aim
 318                 case WEP_PORTO: // shoots from eye
 319                 case WEP_HOOK: // no trueaim
 320                 case WEP_MORTAR: // toss curve
 321                         return SHOTTYPE_HITWORLD;
 322                 case WEP_VORTEX:
 323                 case WEP_VAPORIZER:
 324                         mv = MOVE_NORMAL;
 325                         break;
 326                 case WEP_RIFLE:
 327                         ta = trueaim_rifle;
 328                         mv = MOVE_NORMAL;
 329                         if(zoomscript_caught)
 330                         {
 331                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 332                                 return EnemyHitCheck();
 333                         }
 334                         break;
 335                 case WEP_DEVASTATOR: // projectile has a size!
 336                         mi = '-3 -3 -3';
 337                         ma = '3 3 3';
 338                         break;
 339                 case WEP_FIREBALL: // projectile has a size!
 340                         mi = '-16 -16 -16';
 341                         ma = '16 16 16';
 342                         break;
 343                 case WEP_SEEKER: // projectile has a size!
 344                         mi = '-2 -2 -2';
 345                         ma = '2 2 2';
 346                         break;
 347                 case WEP_ELECTRO: // projectile has a size!
 348                         mi = '0 0 -3';
 349                         ma = '0 0 -3';
 350                         break;
 351         }
 352
 353         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 354
 355         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 356
 357         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 358         trueaimpoint = trace_endpos;
 359
 360         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 361                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 362
 363         if(vecs.x > 0)
 364                 vecs.y = -vecs.y;
 365         else
 366                 vecs = '0 0 0';
 367
 368         dv = view_right * vecs.y + view_up * vecs.z;
 369         w_shotorg = traceorigin + dv;
 370
 371         // now move the vecs forward as much as requested if possible
 372         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 373         w_shotorg = trace_endpos - view_forward * nudge;
 374
 375         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 376         shottype = EnemyHitCheck();
 377         if(shottype != SHOTTYPE_HITWORLD)
 378                 return shottype;
 379
 380 #if 0
 381         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 382         // or rather, I know why, but see no fix
 383         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 384                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 385                 return SHOTTYPE_HITOBSTRUCTION;
 386 #endif
 387
 388         return SHOTTYPE_HITWORLD;
 389 }
 390
 391 void CSQC_common_hud(void);
 392
 393 void PostInit(void);
 394 void CSQC_Demo_Camera();
 395 float HUD_WouldDrawScoreboard();
 396 float camera_mode;
 397 const float CAMERA_FREE = 1;
 398 const float CAMERA_CHASE = 2;
 399 float reticle_type;
 400 string reticle_image;
 401 string NextFrameCommand;
 402 void CSQC_SPIDER_HUD();
 403 void CSQC_RAPTOR_HUD();
 404
 405 vector freeze_org, freeze_ang;
 406 entity nightvision_noise, nightvision_noise2;
 407
 408 const float MAX_TIME_DIFF = 5;
 409 float pickup_crosshair_time, pickup_crosshair_size;
 410 float hitindication_crosshair_size;
 411 float use_vortex_chargepool;
 412
 413 float myhealth, myhealth_prev;
 414 float myhealth_flash;
 415
 416 float old_blurradius, old_bluralpha;
 417 float old_sharpen_intensity;
 418
 419 vector myhealth_gentlergb;
 420
 421 float contentavgalpha, liquidalpha_prev;
 422 vector liquidcolor_prev;
 423
 424 float eventchase_current_distance;
 425 float eventchase_running;
 426 float WantEventchase()
 427 {
 428         if(autocvar_cl_orthoview)
 429                 return false;
 430         if(intermission)
 431                 return true;
 432         if(spectatee_status >= 0)
 433         {
 434                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 435                         return true;
 436                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 437                 {
 438                         if(autocvar_cl_eventchase_death == 2)
 439                         {
 440                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 441                                 if(self.velocity == '0 0 0' || eventchase_running)
 442                                         return true;
 443                         }
 444                         else return true;
 445                 }
 446         }
 447         return false;
 448 }
 449
 450 vector damage_blurpostprocess, content_blurpostprocess;
 451
 452 float checkfail[16];
 453
 454 float unaccounted_damage = 0;
 455 void UpdateDamage()
 456 {
 457         // accumulate damage with each stat update
 458         static float damage_total_prev = 0;
 459         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 460         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 461         damage_total_prev = damage_total;
 462
 463         static float damage_dealt_time_prev = 0;
 464         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 465         if (damage_dealt_time != damage_dealt_time_prev)
 466         {
 467                 unaccounted_damage += unaccounted_damage_new;
 468                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 469         }
 470         damage_dealt_time_prev = damage_dealt_time;
 471
 472         // prevent hitsound when switching spectatee
 473         static float spectatee_status_prev = 0;
 474         if (spectatee_status != spectatee_status_prev)
 475                 unaccounted_damage = 0;
 476         spectatee_status_prev = spectatee_status;
 477 }
 478
 479 void UpdateHitsound()
 480 {
 481         // varying sound pitch
 482
 483         static float hitsound_time_prev = 0;
 484         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 485         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 486         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 487         {
 488                 if (autocvar_cl_hitsound && unaccounted_damage)
 489                 {
 490                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 491                         float a = autocvar_cl_hitsound_max_pitch;
 492                         float b = autocvar_cl_hitsound_min_pitch;
 493                         float c = autocvar_cl_hitsound_nom_damage;
 494                         float x = unaccounted_damage;
 495                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 496
 497                         // if sound variation is disabled, set pitch_shift to 1
 498                         if (autocvar_cl_hitsound == 1)
 499                                 pitch_shift = 1;
 500
 501                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 502                         if (autocvar_cl_hitsound == 3)
 503                         {
 504                                 float mirror_value = (a-b)/2 + b;
 505                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 506                         }
 507
 508                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 509
 510                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 511                         // todo: normalize sound pressure levels? seems unnecessary
 512
 513                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 514                 }
 515                 unaccounted_damage = 0;
 516                 hitsound_time_prev = time;
 517         }
 518
 519         static float typehit_time_prev = 0;
 520         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 521         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 522         {
 523                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 524                 typehit_time_prev = typehit_time;
 525         }
 526 }
 527
 528 void UpdateCrosshair()
 529 {
 530         static float rainbow_last_flicker;
 531     static vector rainbow_prev_color;
 532         entity e = self;
 533         float f, i, j;
 534         vector v;
 535         if(getstati(STAT_FROZEN))
 536                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 537         else if (getstatf(STAT_HEALING_ORB)>time)
 538                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 539         if(!intermission)
 540         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 541         {
 542                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 543                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 544         }
 545         else if(getstatf(STAT_REVIVE_PROGRESS))
 546         {
 547                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 548                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 549         }
 550
 551         if(autocvar_r_letterbox == 0)
 552                 if(autocvar_viewsize < 120)
 553                         CSQC_common_hud();
 554
 555         // crosshair goes VERY LAST
 556         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 557         {
 558                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 559                         return;
 560
 561                 string wcross_style;
 562                 float wcross_alpha, wcross_resolution;
 563                 wcross_style = autocvar_crosshair;
 564                 if (wcross_style == "0")
 565                         return;
 566                 wcross_resolution = autocvar_crosshair_size;
 567                 if (wcross_resolution == 0)
 568                         return;
 569                 wcross_alpha = autocvar_crosshair_alpha;
 570                 if (wcross_alpha == 0)
 571                         return;
 572
 573                 // TrueAim check
 574                 float shottype;
 575
 576                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 577                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 578                 wcross_origin.z = 0;
 579                 if(autocvar_crosshair_hittest)
 580                 {
 581                         vector wcross_oldorigin;
 582                         wcross_oldorigin = wcross_origin;
 583                         shottype = TrueAimCheck();
 584                         if(shottype == SHOTTYPE_HITWORLD)
 585                         {
 586                                 v = wcross_origin - wcross_oldorigin;
 587                                 v.x /= vid_conwidth;
 588                                 v.y /= vid_conheight;
 589                                 if(vlen(v) > 0.01)
 590                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 591                         }
 592                         if(!autocvar_crosshair_hittest_showimpact)
 593                                 wcross_origin = wcross_oldorigin;
 594                 }
 595                 else
 596                         shottype = SHOTTYPE_HITWORLD;
 597
 598                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 599                 string wcross_name = "";
 600                 float wcross_scale, wcross_blur;
 601
 602                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 603                 {
 604                         e = get_weaponinfo(switchingweapon);
 605                         if(e)
 606                         {
 607                                 if(autocvar_crosshair_per_weapon)
 608                                 {
 609                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 610                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 611                                         //if (wcross_resolution == 0)
 612                                                 //return;
 613
 614                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 615                                         wcross_resolution *= e.w_crosshair_size;
 616                                         wcross_name = e.w_crosshair;
 617                                 }
 618                         }
 619                 }
 620
 621                 if(wcross_name == "")
 622                         wcross_name = strcat("gfx/crosshair", wcross_style);
 623
 624                 // MAIN CROSSHAIR COLOR DECISION
 625                 switch(autocvar_crosshair_color_special)
 626                 {
 627                         case 1: // crosshair_color_per_weapon
 628                         {
 629                                 if(e)
 630                                 {
 631                                         wcross_color = e.wpcolor;
 632                                         break;
 633                                 }
 634                                 else { goto normalcolor; }
 635                         }
 636
 637                         case 2: // crosshair_color_by_health
 638                         {
 639                                 float x = getstati(STAT_HEALTH);
 640
 641                                 //x = red
 642                                 //y = green
 643                                 //z = blue
 644
 645                                 wcross_color.z = 0;
 646
 647                                 if(x > 200)
 648                                 {
 649                                         wcross_color.x = 0;
 650                                         wcross_color.y = 1;
 651                                 }
 652                                 else if(x > 150)
 653                                 {
 654                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 655                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 656                                 }
 657                                 else if(x > 100)
 658                                 {
 659                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 660                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 661                                         wcross_color.z = 1 - (x-100)*0.02;
 662                                 }
 663                                 else if(x > 50)
 664                                 {
 665                                         wcross_color.x = 1;
 666                                         wcross_color.y = 1;
 667                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 668                                 }
 669                                 else if(x > 20)
 670                                 {
 671                                         wcross_color.x = 1;
 672                                         wcross_color.y = (x-20)*90/27/100;
 673                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 674                                 }
 675                                 else
 676                                 {
 677                                         wcross_color.x = 1;
 678                                         wcross_color.y = 0;
 679                                 }
 680                                 break;
 681                         }
 682
 683                         case 3: // crosshair_color_rainbow
 684                         {
 685                                 if(time >= rainbow_last_flicker)
 686                                 {
 687                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 688                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 689                                 }
 690                                 wcross_color = rainbow_prev_color;
 691                                 break;
 692                         }
 693                         :normalcolor
 694                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 695                 }
 696
 697                 if(autocvar_crosshair_effect_scalefade)
 698                 {
 699                         wcross_scale = wcross_resolution;
 700                         wcross_resolution = 1;
 701                 }
 702                 else
 703                 {
 704                         wcross_scale = 1;
 705                 }
 706
 707                 if(autocvar_crosshair_pickup)
 708                 {
 709                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 710
 711                         if(pickup_crosshair_time < stat_pickup_time)
 712                         {
 713                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 714                                         pickup_crosshair_size = 1;
 715
 716                                 pickup_crosshair_time = stat_pickup_time;
 717                         }
 718
 719                         if(pickup_crosshair_size > 0)
 720                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 721                         else
 722                                 pickup_crosshair_size = 0;
 723
 724                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 725                 }
 726
 727                 // todo: make crosshair hit indication dependent on damage dealt
 728                 if(autocvar_crosshair_hitindication)
 729                 {
 730                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 731
 732                         if(unaccounted_damage)
 733                         {
 734                                 hitindication_crosshair_size = 1;
 735                         }
 736
 737                         if(hitindication_crosshair_size > 0)
 738                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 739                         else
 740                                 hitindication_crosshair_size = 0;
 741
 742                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 743                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 744                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 745                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 746                 }
 747
 748                 if(shottype == SHOTTYPE_HITENEMY)
 749                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 750                 if(shottype == SHOTTYPE_HITTEAM)
 751                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 752
 753                 f = fabs(autocvar_crosshair_effect_time);
 754                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 755                 {
 756                         wcross_changedonetime = time + f;
 757                 }
 758                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 759                 {
 760                         wcross_name_changestarttime = time;
 761                         wcross_name_changedonetime = time + f;
 762                         if(wcross_name_goal_prev_prev)
 763                                 strunzone(wcross_name_goal_prev_prev);
 764                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 765                         wcross_name_goal_prev = strzone(wcross_name);
 766                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 767                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 768                         wcross_resolution_goal_prev = wcross_resolution;
 769                 }
 770
 771                 wcross_scale_goal_prev = wcross_scale;
 772                 wcross_alpha_goal_prev = wcross_alpha;
 773                 wcross_color_goal_prev = wcross_color;
 774
 775                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 776                 {
 777                         wcross_blur = 1;
 778                         wcross_alpha *= 0.75;
 779                 }
 780                 else
 781                         wcross_blur = 0;
 782                 // *_prev is at time-frametime
 783                 // * is at wcross_changedonetime+f
 784                 // what do we have at time?
 785                 if(time < wcross_changedonetime)
 786                 {
 787                         f = frametime / (wcross_changedonetime - time + frametime);
 788                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 789                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 790                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 791                 }
 792
 793                 wcross_scale_prev = wcross_scale;
 794                 wcross_alpha_prev = wcross_alpha;
 795                 wcross_color_prev = wcross_color;
 796
 797                 wcross_scale *= 1 - autocvar__menu_alpha;
 798                 wcross_alpha *= 1 - autocvar__menu_alpha;
 799                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 800
 801                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 802                 {
 803                         // crosshair rings for weapon stats
 804                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 805                         {
 806                                 // declarations and stats
 807                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 808                                 string ring_image = string_null, ring_inner_image = string_null;
 809                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 810
 811                                 ring_scale = autocvar_crosshair_ring_size;
 812
 813                                 float weapon_clipload, weapon_clipsize;
 814                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 815                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 816
 817                                 float ok_ammo_charge, ok_ammo_chargepool;
 818                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 819                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 820
 821                                 float vortex_charge, vortex_chargepool;
 822                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 823                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 824
 825                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 826
 827                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 828                                         vortex_charge_movingavg = vortex_charge;
 829
 830
 831                                 // handle the values
 832                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 833                                 {
 834                                         if (vortex_chargepool || use_vortex_chargepool) {
 835                                                 use_vortex_chargepool = 1;
 836                                                 ring_inner_value = vortex_chargepool;
 837                                         } else {
 838                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 839                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 840                                         }
 841
 842                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 843                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 844                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 845
 846                                         // draw the outer ring to show the current charge of the weapon
 847                                         ring_value = vortex_charge;
 848                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 849                                         ring_rgb = wcross_color;
 850                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 851                                 }
 852                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 853                                 {
 854                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 855                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 856                                         ring_rgb = wcross_color;
 857                                         ring_image = "gfx/crosshair_ring.tga";
 858                                 }
 859                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 860                                 {
 861                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 862                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 863                                         ring_rgb = wcross_color;
 864                                         ring_image = "gfx/crosshair_ring.tga";
 865                                 }
 866                                 else if (ok_ammo_charge)
 867                                 {
 868                                         ring_value = ok_ammo_chargepool;
 869                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 870                                         ring_rgb = wcross_color;
 871                                         ring_image = "gfx/crosshair_ring.tga";
 872                                 }
 873                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 874                                 {
 875                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 876                                         ring_scale = autocvar_crosshair_ring_reload_size;
 877                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 878                                         ring_rgb = wcross_color;
 879
 880                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 881                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 882                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 883                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 884                                         else
 885                                                 ring_image = "gfx/crosshair_ring.tga";
 886                                 }
 887                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 888                                 {
 889                                         ring_value = arc_heat;
 890                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 891                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 892                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 893                                         ring_image = "gfx/crosshair_ring.tga";
 894                                 }
 895
 896                                 // if in weapon switch animation, fade ring out/in
 897                                 if(autocvar_crosshair_effect_time > 0)
 898                                 {
 899                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 900                                         if (f >= 1)
 901                                         {
 902                                                 wcross_ring_prev = ((ring_image) ? true : false);
 903                                         }
 904
 905                                         if(wcross_ring_prev)
 906                                         {
 907                                                 if(f < 1)
 908                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 909                                         }
 910                                         else
 911                                         {
 912                                                 if(f < 1)
 913                                                         ring_alpha *= bound(0, f, 1);
 914                                         }
 915                                 }
 916
 917                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 918                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 919
 920                                 if (ring_value)
 921                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 922                         }
 923
 924 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 925                         do \
 926                         { \
 927                                 if(wcross_blur > 0) \
 928                                 { \
 929                                         for(i = -2; i <= 2; ++i) \
 930                                         for(j = -2; j <= 2; ++j) \
 931                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 932                                 } \
 933                                 else \
 934                                 { \
 935                                         M(0,0,sz,wcross_name,wcross_alpha); \
 936                                 } \
 937                         } \
 938                         while(0)
 939
 940 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 941                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 942
 943 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 944                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 945
 946                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 947                         {
 948                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 949                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 950                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 951                                 f = 1 - f;
 952                         }
 953                         else
 954                         {
 955                                 f = 1;
 956                         }
 957                         wcross_name_alpha_goal_prev = f;
 958
 959                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 960                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 961
 962                         if(autocvar_crosshair_dot)
 963                         {
 964                                 vector wcross_color_old;
 965                                 wcross_color_old = wcross_color;
 966
 967                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 968                                         wcross_color = stov(autocvar_crosshair_dot_color);
 969
 970                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 971                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 972                                 wcross_color = wcross_color_old;
 973                         }
 974                 }
 975         }
 976         else
 977         {
 978                 wcross_scale_prev = 0;
 979                 wcross_alpha_prev = 0;
 980                 wcross_scale_goal_prev = 0;
 981                 wcross_alpha_goal_prev = 0;
 982                 wcross_changedonetime = 0;
 983                 if(wcross_name_goal_prev)
 984                         strunzone(wcross_name_goal_prev);
 985                 wcross_name_goal_prev = string_null;
 986                 if(wcross_name_goal_prev_prev)
 987                         strunzone(wcross_name_goal_prev_prev);
 988                 wcross_name_goal_prev_prev = string_null;
 989                 wcross_name_changestarttime = 0;
 990                 wcross_name_changedonetime = 0;
 991                 wcross_name_alpha_goal_prev = 0;
 992                 wcross_name_alpha_goal_prev_prev = 0;
 993                 wcross_resolution_goal_prev = 0;
 994                 wcross_resolution_goal_prev_prev = 0;
 995         }
 996 }
 997
 998 const int BUTTON_3 = 4;
 999 const int BUTTON_4 = 8;
1000 float cl_notice_run();
1001 float prev_myteam;
1002 void CSQC_UpdateView(float w, float h)
1003 {
1004         entity e;
1005         float fov;
1006         float f;
1007         int i;
1008         vector vf_size, vf_min;
1009         float a;
1010
1011         execute_next_frame();
1012
1013         ++framecount;
1014
1015         hud = getstati(STAT_HUD);
1016
1017         if(autocvar__hud_showbinds_reload) // menu can set this one
1018         {
1019                 db_close(binddb);
1020                 binddb = db_create();
1021                 cvar_set("_hud_showbinds_reload", "0");
1022         }
1023
1024         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1025                 view_quality = getproperty(VF_MINFPS_QUALITY);
1026         else
1027                 view_quality = 1;
1028
1029         button_attack2 = (input_buttons & BUTTON_3);
1030         button_zoom = (input_buttons & BUTTON_4);
1031
1032 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1033         float checkfailv = (func)(parm);                                                                                \
1034         if (checkfailv != (val)) {                                                                                      \
1035                 if (!checkfail[(flag)])                                                                                     \
1036                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1037                 checkfail[(flag)] = 1;                                                                                      \
1038         }                                                                                                               \
1039 } while(0)
1040         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1041         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1042         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1043         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1044         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1045         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1046         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1047
1048         vf_size = getpropertyvec(VF_SIZE);
1049         vf_min = getpropertyvec(VF_MIN);
1050         vid_width = vf_size.x;
1051         vid_height = vf_size.y;
1052
1053         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1054         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1055
1056         WaypointSprite_Load();
1057
1058         CSQCPlayer_SetCamera();
1059
1060         myteam = GetPlayerColor(player_localentnum - 1);
1061
1062         if(myteam != prev_myteam)
1063         {
1064                 myteamcolors = colormapPaletteColor(myteam, 1);
1065                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1066                         hud_panel[i].update_time = time;
1067                 prev_myteam = myteam;
1068         }
1069
1070         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1071
1072         float is_dead = (getstati(STAT_HEALTH) <= 0);
1073
1074         // FIXME do we need this hack?
1075         if(isdemo())
1076         {
1077                 // in demos, input_buttons do not work
1078                 button_zoom = (autocvar__togglezoom == "-");
1079         }
1080         else if(button_zoom
1081                 && autocvar_cl_unpress_zoom_on_death
1082                 && (spectatee_status >= 0)
1083                 && (is_dead || intermission))
1084         {
1085                 // no zoom while dead or in intermission please
1086                 localcmd("-zoom\n");
1087                 button_zoom = false;
1088         }
1089
1090         // event chase camera
1091         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1092         {
1093                 if(WantEventchase())
1094                 {
1095                         eventchase_running = true;
1096
1097                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1098                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1099
1100                         // detect maximum viewoffset and use it
1101                         if(autocvar_cl_eventchase_viewoffset)
1102                         {
1103                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1104                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1105                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1106                         }
1107
1108                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1109                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1110                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1111                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1112
1113                         // make the camera smooth back
1114                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1115                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1116                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1117                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1118
1119                         makevectors(view_angles);
1120
1121                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1122                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1123
1124                         // If the boxtrace fails, revert back to line tracing.
1125                         if(trace_startsolid)
1126                         {
1127                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1128                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1129                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1130                         }
1131                         else { setproperty(VF_ORIGIN, trace_endpos); }
1132
1133                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1134                 }
1135                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1136                 {
1137                         eventchase_running = false;
1138                         cvar_set("chase_active", "0");
1139                         eventchase_current_distance = 0; // start from 0 next time
1140                 }
1141         }
1142         // workaround for camera stuck between player's legs when using chase_active 1
1143         // because the engine stops updating the chase_active camera when the game ends
1144         else if(intermission)
1145         {
1146                 cvar_settemp("chase_active", "-1");
1147                 eventchase_current_distance = 0;
1148         }
1149
1150         // do lockview after event chase camera so that it still applies whenever necessary.
1151         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1152         {
1153                 setproperty(VF_ORIGIN, freeze_org);
1154                 setproperty(VF_ANGLES, freeze_ang);
1155         }
1156         else
1157         {
1158                 freeze_org = getpropertyvec(VF_ORIGIN);
1159                 freeze_ang = getpropertyvec(VF_ANGLES);
1160         }
1161
1162         WarpZone_FixView();
1163         //WarpZone_FixPMove();
1164
1165         vector ov_org = '0 0 0';
1166         vector ov_mid = '0 0 0';
1167         vector ov_worldmin = '0 0 0';
1168         vector ov_worldmax = '0 0 0';
1169         if(autocvar_cl_orthoview)
1170         {
1171                 ov_worldmin = mi_picmin;
1172                 ov_worldmax = mi_picmax;
1173
1174                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1175                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1176                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1177
1178                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1179                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1180
1181                 float ov_nearest = vlen(ov_org - vec3(
1182                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1183                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1184                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1185                 ));
1186
1187                 float ov_furthest = 0;
1188                 float dist = 0;
1189
1190                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1191                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1192                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1193                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1194                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1195                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1196                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1197                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1198
1199                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1200                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1201                 cvar_settemp("r_farclip_world", "0");
1202                 cvar_settemp("r_novis", "1");
1203                 cvar_settemp("r_useportalculling", "0");
1204                 cvar_settemp("r_useinfinitefarclip", "0");
1205
1206                 setproperty(VF_ORIGIN, ov_org);
1207                 setproperty(VF_ANGLES, '90 0 0');
1208
1209                 #if 0
1210                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1211                         vtos(ov_org),
1212                         vtos(getpropertyvec(VF_ANGLES)),
1213                         ov_distance,
1214                         ov_nearest,
1215                         ov_furthest);
1216                 #endif
1217         }
1218
1219         // Render the Scene
1220         view_origin = getpropertyvec(VF_ORIGIN);
1221         view_angles = getpropertyvec(VF_ANGLES);
1222         makevectors(view_angles);
1223         view_forward = v_forward;
1224         view_right = v_right;
1225         view_up = v_up;
1226
1227 #ifdef BLURTEST
1228         if(time > blurtest_time0 && time < blurtest_time1)
1229         {
1230                 float r, t;
1231
1232                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1233                 r = t * blurtest_radius;
1234                 f = 1 / pow(t, blurtest_power) - 1;
1235
1236                 cvar_set("r_glsl_postprocess", "1");
1237                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1238         }
1239         else
1240         {
1241                 cvar_set("r_glsl_postprocess", "0");
1242                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1243         }
1244 #endif
1245
1246         TargetMusic_Advance();
1247         Fog_Force();
1248
1249         if(drawtime == 0)
1250                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1251         else
1252                 drawframetime = bound(0.000001, time - drawtime, 1);
1253         drawtime = time;
1254
1255         // watch for gametype changes here...
1256         // in ParseStuffCMD the cmd isn't executed yet :/
1257         // might even be better to add the gametype to TE_CSQC_INIT...?
1258         if(!postinit)
1259                 PostInit();
1260
1261         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1262         {
1263                 if(calledhooks & HOOK_START)
1264                 {
1265                         localcmd("\ncl_hook_gameend\n");
1266                         calledhooks |= HOOK_END;
1267                 }
1268         }
1269
1270         Announcer();
1271
1272         fov = autocvar_fov;
1273         if(fov <= 59.5)
1274         {
1275                 if(!zoomscript_caught)
1276                 {
1277                         localcmd("+button9\n");
1278                         zoomscript_caught = 1;
1279                 }
1280         }
1281         else
1282         {
1283                 if(zoomscript_caught)
1284                 {
1285                         localcmd("-button9\n");
1286                         zoomscript_caught = 0;
1287                 }
1288         }
1289
1290         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1291
1292         // next WANTED weapon (for HUD)
1293         switchweapon = getstati(STAT_SWITCHWEAPON);
1294
1295         // currently switching-to weapon (for crosshair)
1296         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1297
1298         // actually active weapon (for zoom)
1299         activeweapon = getstati(STAT_ACTIVEWEAPON);
1300
1301         f = (serverflags & SERVERFLAG_TEAMPLAY);
1302         if(f != teamplay)
1303         {
1304                 teamplay = f;
1305                 HUD_InitScores();
1306         }
1307
1308         if(last_switchweapon != switchweapon)
1309         {
1310                 weapontime = time;
1311                 last_switchweapon = switchweapon;
1312                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1313                 {
1314                         localcmd("-zoom\n");
1315                         button_zoom = false;
1316                 }
1317                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1318                 {
1319                         localcmd("-fire\n");
1320                         localcmd("-fire2\n");
1321                         button_attack2 = false;
1322                 }
1323         }
1324         if(last_activeweapon != activeweapon)
1325         {
1326                 last_activeweapon = activeweapon;
1327
1328                 e = get_weaponinfo(activeweapon);
1329                 if(e.netname != "")
1330                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1331                 else
1332                         localcmd("\ncl_hook_activeweapon none\n");
1333         }
1334
1335         // ALWAYS Clear Current Scene First
1336         clearscene();
1337
1338         setproperty(VF_ORIGIN, view_origin);
1339         setproperty(VF_ANGLES, view_angles);
1340
1341         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1342         setproperty(VF_SIZE, vf_size);
1343         setproperty(VF_MIN, vf_min);
1344
1345         // Assign Standard Viewflags
1346         // Draw the World (and sky)
1347         setproperty(VF_DRAWWORLD, 1);
1348
1349         // Set the console size vars
1350         vid_conwidth = autocvar_vid_conwidth;
1351         vid_conheight = autocvar_vid_conheight;
1352         vid_pixelheight = autocvar_vid_pixelheight;
1353
1354         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1355         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1356
1357         // Camera for demo playback
1358         if(camera_active)
1359         {
1360                 if(autocvar_camera_enable)
1361                         CSQC_Demo_Camera();
1362                 else
1363                 {
1364                         cvar_set("chase_active", ftos(chase_active_backup));
1365                         cvar_set("cl_demo_mousegrab", "0");
1366                         camera_active = false;
1367                 }
1368         }
1369         else
1370         {
1371 #ifdef CAMERATEST
1372                 if(autocvar_camera_enable)
1373 #else
1374                 if(autocvar_camera_enable && isdemo())
1375 #endif
1376                 {
1377                         // Enable required Darkplaces cvars
1378                         chase_active_backup = autocvar_chase_active;
1379                         cvar_set("chase_active", "2");
1380                         cvar_set("cl_demo_mousegrab", "1");
1381                         camera_active = true;
1382                         camera_mode = false;
1383                 }
1384         }
1385
1386         // Draw the Crosshair
1387         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1388
1389         // Draw the Engine Status Bar (the default Quake HUD)
1390         setproperty(VF_DRAWENGINESBAR, 0);
1391
1392         // Update the mouse position
1393         /*
1394            mousepos_x = vid_conwidth;
1395            mousepos_y = vid_conheight;
1396            mousepos = mousepos*0.5 + getmousepos();
1397          */
1398
1399         e = self;
1400         for(self = world; (self = nextent(self)); )
1401                 if(self.draw)
1402                         self.draw();
1403         self = e;
1404
1405         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1406         renderscene();
1407
1408         // now switch to 2D drawing mode by calling a 2D drawing function
1409         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1410         // next R_RenderScene call
1411         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1412
1413         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1414         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1415         {
1416                 // apply night vision effect
1417                 vector tc_00, tc_01, tc_10, tc_11;
1418                 vector rgb = '0 0 0';
1419
1420                 if(!nightvision_noise)
1421                 {
1422                         nightvision_noise = spawn();
1423                         nightvision_noise.classname = "nightvision_noise";
1424                 }
1425                 if(!nightvision_noise2)
1426                 {
1427                         nightvision_noise2 = spawn();
1428                         nightvision_noise2.classname = "nightvision_noise2";
1429                 }
1430
1431                 // color tint in yellow
1432                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1433
1434                 // draw BG
1435                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1436                 rgb = '1 1 1';
1437                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1438                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1439                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1440                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1441                 tc_11 = tc_01 + tc_10 - tc_00;
1442                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1443                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1444                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1445                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1446                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1447                 R_EndPolygon();
1448
1449                 // draw FG
1450                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1451                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1452                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1453                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1454                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1455                 tc_11 = tc_01 + tc_10 - tc_00;
1456                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1457                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1458                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1459                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1460                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1461                 R_EndPolygon();
1462         }
1463
1464         if(autocvar_cl_reticle)
1465         {
1466                 // Draw the aiming reticle for weapons that use it
1467                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1468                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1469                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1470                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1471                 {
1472                         // no zoom reticle while dead
1473                         reticle_type = 0;
1474                 }
1475                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1476                 {
1477                         if(reticle_image != "") { reticle_type = 2; }
1478                         else { reticle_type = 0; }
1479                 }
1480                 else if(button_zoom || zoomscript_caught)
1481                 {
1482                         // normal zoom
1483                         reticle_type = 1;
1484                 }
1485
1486                 if(reticle_type)
1487                 {
1488                         if(autocvar_cl_reticle_stretch)
1489                         {
1490                                 reticle_size.x = vid_conwidth;
1491                                 reticle_size.y = vid_conheight;
1492                                 reticle_pos.x = 0;
1493                                 reticle_pos.y = 0;
1494                         }
1495                         else
1496                         {
1497                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1498                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1499                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1500                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1501                         }
1502
1503                         if(zoomscript_caught)
1504                                 f = 1;
1505                         else
1506                                 f = current_zoomfraction;
1507
1508                         if(f)
1509                         {
1510                                 switch(reticle_type)
1511                                 {
1512                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1513                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1514                                 }
1515                         }
1516                 }
1517         }
1518         else
1519         {
1520                 if(reticle_type != 0) { reticle_type = 0; }
1521         }
1522
1523
1524         // improved polyblend
1525         if(autocvar_hud_contents)
1526         {
1527                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1528                 vector liquidcolor;
1529
1530                 switch(pointcontents(view_origin))
1531                 {
1532                         case CONTENT_WATER:
1533                                 liquidalpha = autocvar_hud_contents_water_alpha;
1534                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1535                                 incontent = 1;
1536                                 break;
1537
1538                         case CONTENT_LAVA:
1539                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1540                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1541                                 incontent = 1;
1542                                 break;
1543
1544                         case CONTENT_SLIME:
1545                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1546                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1547                                 incontent = 1;
1548                                 break;
1549
1550                         default:
1551                                 liquidalpha = 0;
1552                                 liquidcolor = '0 0 0';
1553                                 incontent = 0;
1554                                 break;
1555                 }
1556
1557                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1558                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1559                         contentfadetime = autocvar_hud_contents_fadeintime;
1560                         liquidalpha_prev = liquidalpha;
1561                         liquidcolor_prev = liquidcolor;
1562                 }
1563                 else
1564                         contentfadetime = autocvar_hud_contents_fadeouttime;
1565
1566                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1567                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1568
1569                 if(contentavgalpha)
1570                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1571
1572                 if(autocvar_hud_postprocessing)
1573                 {
1574                         if(autocvar_hud_contents_blur && contentavgalpha)
1575                         {
1576                                 content_blurpostprocess.x = 1;
1577                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1578                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1579                         }
1580                         else
1581                         {
1582                                 content_blurpostprocess.x = 0;
1583                                 content_blurpostprocess.y = 0;
1584                                 content_blurpostprocess.z = 0;
1585                         }
1586                 }
1587         }
1588
1589         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1590         {
1591                 splash_size.x = max(vid_conwidth, vid_conheight);
1592                 splash_size.y = max(vid_conwidth, vid_conheight);
1593                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1594                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1595
1596                 float myhealth_flash_temp;
1597                 myhealth = getstati(STAT_HEALTH);
1598
1599                 // fade out
1600                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1601                 // add new damage
1602                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1603
1604                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1605                 pain_threshold = autocvar_hud_damage_pain_threshold;
1606                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1607                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1608
1609                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1610                 {
1611                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1612                 }
1613
1614                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1615
1616                 if(myhealth_prev < 1)
1617                 {
1618                         if(myhealth >= 1)
1619                         {
1620                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1621                                 myhealth_flash_temp = 0;
1622                         }
1623                         else
1624                         {
1625                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1626                         }
1627                 }
1628
1629                 if(spectatee_status == -1 || intermission)
1630                 {
1631                         myhealth_flash = 0; // observing, or match ended
1632                         myhealth_flash_temp = 0;
1633                 }
1634
1635                 myhealth_prev = myhealth;
1636
1637                 // IDEA: change damage color/picture based on player model for robot/alien species?
1638                 // pro: matches model better
1639                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1640                 // maybe different reddish pics?
1641                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1642                 {
1643                         if(autocvar_cl_gentle_damage == 2)
1644                         {
1645                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1646                                 {
1647                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1648                                 }
1649                         }
1650                         else
1651                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1652
1653                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1654                 }
1655                 else
1656                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1657
1658                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1659                 {
1660                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1661                         {
1662                                 damage_blurpostprocess.x = 1;
1663                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1664                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1665                         }
1666                         else
1667                         {
1668                                 damage_blurpostprocess.x = 0;
1669                                 damage_blurpostprocess.y = 0;
1670                                 damage_blurpostprocess.z = 0;
1671                         }
1672                 }
1673         }
1674
1675         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1676         float e2 = (autocvar_hud_powerup != 0);
1677         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1678         {
1679                 // enable or disable rendering types if they are used or not
1680                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1681                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1682
1683                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1684                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1685                 {
1686                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1687                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1688                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1689                         {
1690                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1691                                 old_blurradius = blurradius;
1692                                 old_bluralpha = bluralpha;
1693                         }
1694                 }
1695                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1696                 {
1697                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1698                         old_blurradius = 0;
1699                         old_bluralpha = 0;
1700                 }
1701
1702                 // edge detection postprocess handling done second (used by hud_powerup)
1703                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1704                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1705                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1706
1707                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1708
1709                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1710                 {
1711                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1712                         {
1713                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1714                                 old_sharpen_intensity = sharpen_intensity;
1715                         }
1716                 }
1717                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1718                 {
1719                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1720                         old_sharpen_intensity = 0;
1721                 }
1722
1723                 if(cvar("r_glsl_postprocess") == 0)
1724                         cvar_set("r_glsl_postprocess", "2");
1725         }
1726         else if(cvar("r_glsl_postprocess") == 2)
1727                 cvar_set("r_glsl_postprocess", "0");
1728
1729         if(menu_visible)
1730                 menu_show();
1731
1732         /*if(gametype == MAPINFO_TYPE_CTF)
1733           {
1734           ctf_view();
1735           } else */
1736
1737         // draw 2D entities
1738         e = self;
1739         for(self = world; (self = nextent(self)); )
1740                 if(self.draw2d)
1741                         self.draw2d();
1742         self = e;
1743         Draw_ShowNames_All();
1744
1745         scoreboard_active = HUD_WouldDrawScoreboard();
1746
1747         UpdateDamage();
1748         UpdateCrosshair();
1749         UpdateHitsound();
1750
1751         if(NextFrameCommand)
1752         {
1753                 localcmd("\n", NextFrameCommand, "\n");
1754                 NextFrameCommand = string_null;
1755         }
1756
1757         // we must do this check AFTER a frame was rendered, or it won't work
1758         if(cs_project_is_b0rked == 0)
1759         {
1760                 string w0, h0;
1761                 w0 = ftos(autocvar_vid_conwidth);
1762                 h0 = ftos(autocvar_vid_conheight);
1763                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1764                 //setproperty(VF_FOV, '90 90 0');
1765                 setproperty(VF_ORIGIN, '0 0 0');
1766                 setproperty(VF_ANGLES, '0 0 0');
1767                 setproperty(VF_PERSPECTIVE, 1);
1768                 makevectors('0 0 0');
1769                 vector v1, v2;
1770                 cvar_set("vid_conwidth", "800");
1771                 cvar_set("vid_conheight", "600");
1772                 v1 = cs_project(v_forward);
1773                 cvar_set("vid_conwidth", "640");
1774                 cvar_set("vid_conheight", "480");
1775                 v2 = cs_project(v_forward);
1776                 if(v1 == v2)
1777                         cs_project_is_b0rked = 1;
1778                 else
1779                         cs_project_is_b0rked = -1;
1780                 cvar_set("vid_conwidth", w0);
1781                 cvar_set("vid_conheight", h0);
1782         }
1783
1784         if(autocvar__hud_configure)
1785                 HUD_Panel_Mouse();
1786
1787     if(hud && !intermission)
1788     {
1789         if(hud == HUD_SPIDERBOT)
1790             CSQC_SPIDER_HUD();
1791         else if(hud == HUD_WAKIZASHI)
1792             CSQC_WAKIZASHI_HUD();
1793         else if(hud == HUD_RAPTOR)
1794             CSQC_RAPTOR_HUD();
1795         else if(hud == HUD_BUMBLEBEE)
1796             CSQC_BUMBLE_HUD();
1797         else if(hud == HUD_BUMBLEBEE_GUN)
1798             CSQC_BUMBLE_GUN_HUD();
1799     }
1800
1801         cl_notice_run();
1802
1803         // let's reset the view back to normal for the end
1804         setproperty(VF_MIN, '0 0 0');
1805         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1806 }
1807
1808
1809 void CSQC_common_hud(void)
1810 {
1811         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1812                 Accuracy_LoadLevels();
1813
1814         HUD_Main(); // always run these functions for alpha checks
1815         HUD_DrawScoreboard();
1816
1817         if (scoreboard_active) // scoreboard/accuracy
1818                 HUD_Reset();
1819         else if (intermission == 2) // map voting screen
1820         {
1821                 MapVote_Draw();
1822                 HUD_Reset();
1823         }
1824 }
1825
1826
1827 // following vectors must be global to allow seamless switching between camera modes
1828 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1829 void CSQC_Demo_Camera()
1830 {
1831         float speed, attenuation, dimensions;
1832         vector tmp, delta;
1833
1834         if( autocvar_camera_reset || !camera_mode )
1835         {
1836                 camera_offset = '0 0 0';
1837                 current_angles = '0 0 0';
1838                 camera_direction = '0 0 0';
1839                 camera_offset.z += 30;
1840                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1841                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1842                 current_origin = view_origin;
1843                 current_camera_offset  = camera_offset;
1844                 cvar_set("camera_reset", "0");
1845                 camera_mode = CAMERA_CHASE;
1846         }
1847
1848         // Camera angles
1849         if( camera_roll )
1850                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1851
1852         if(autocvar_camera_look_player)
1853         {
1854                 vector dir;
1855                 float n;
1856
1857                 dir = normalize(view_origin - current_position);
1858                 n = mouse_angles.z;
1859                 mouse_angles = vectoangles(dir);
1860                 mouse_angles.x = mouse_angles.x * -1;
1861                 mouse_angles.z = n;
1862         }
1863         else
1864         {
1865                 tmp = getmousepos() * 0.1;
1866                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1867                 {
1868                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1869                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1870                 }
1871         }
1872
1873         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1874         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1875         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1876         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1877
1878         // Fix difference when angles don't have the same sign
1879         delta = '0 0 0';
1880         if(mouse_angles.y < -60 && current_angles.y > 60)
1881                 delta = '0 360 0';
1882         if(mouse_angles.y > 60 && current_angles.y < -60)
1883                 delta = '0 -360 0';
1884
1885         if(autocvar_camera_look_player)
1886                 attenuation = autocvar_camera_look_attenuation;
1887         else
1888                 attenuation = autocvar_camera_speed_attenuation;
1889
1890         attenuation = 1 / max(1, attenuation);
1891         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1892
1893         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1894         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1895         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1896         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1897
1898         // Camera position
1899         tmp = '0 0 0';
1900         dimensions = 0;
1901
1902         if( camera_direction.x )
1903         {
1904                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1905                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1906                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1907                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1908                 ++dimensions;
1909         }
1910
1911         if( camera_direction.y )
1912         {
1913                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1914                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1915                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1916                 ++dimensions;
1917         }
1918
1919         if( camera_direction.z )
1920         {
1921                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1922                 ++dimensions;
1923         }
1924
1925         if(autocvar_camera_free)
1926                 speed = autocvar_camera_speed_free;
1927         else
1928                 speed = autocvar_camera_speed_chase;
1929
1930         if(dimensions)
1931         {
1932                 speed = speed * sqrt(1 / dimensions);
1933                 camera_offset += tmp * speed;
1934         }
1935
1936         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1937
1938         // Camera modes
1939         if( autocvar_camera_free )
1940         {
1941                 if ( camera_mode == CAMERA_CHASE )
1942                 {
1943                         current_camera_offset = current_origin + current_camera_offset;
1944                         camera_offset = current_origin + camera_offset;
1945                 }
1946
1947                 camera_mode = CAMERA_FREE;
1948                 current_position = current_camera_offset;
1949         }
1950         else
1951         {
1952                 if ( camera_mode == CAMERA_FREE )
1953                 {
1954                         current_origin = view_origin;
1955                         camera_offset = camera_offset - current_origin;
1956                         current_camera_offset = current_camera_offset - current_origin;
1957                 }
1958
1959                 camera_mode = CAMERA_CHASE;
1960
1961                 if(autocvar_camera_chase_smoothly)
1962                         current_origin += (view_origin - current_origin) * attenuation;
1963                 else
1964                         current_origin = view_origin;
1965
1966                 current_position = current_origin + current_camera_offset;
1967         }
1968
1969         setproperty(VF_ANGLES, current_angles);
1970         setproperty(VF_ORIGIN, current_position);
1971 }