qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/mutators/mutator/overkill/okvortex.qh>
  30 #include <common/viewloc.qh>
  31 #include <common/minigames/cl_minigames.qh>
  32 #include <common/minigames/cl_minigames_hud.qh>
  33
  34 #include <lib/csqcmodel/cl_player.qh>
  35 #include <lib/csqcmodel/cl_model.qh>
  36 #include "csqcmodel_hooks.qh"
  37
  38 #include <lib/warpzone/client.qh>
  39 #include <lib/warpzone/common.qh>
  40
  41 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  42
  43 float autocvar_cl_viewmodel_scale;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  67 { \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  69 } MACRO_END
  70
  71 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  72 { \
  73         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  74         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  75 } MACRO_END
  76
  77 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __f = 0; lowpass(value, frac, ref_store, __f); \
  80         ret = (value) - __f; \
  81 } MACRO_END
  82
  83 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  90 { \
  91         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  92         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  93 } MACRO_END
  94
  95 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         highpass(value.x, frac, ref_store.x, ref_out.x); \
  98         highpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 104         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 } MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         highpass(value.x, frac, ref_store.x, ref_out.x); \
 117         highpass(value.y, frac, ref_store.y, ref_out.y); \
 118         highpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 void calc_followmodel_ofs(entity view)
 122 {
 123         if(cl_followmodel_time == time)
 124                 return; // cl_followmodel_ofs already calculated for this frame
 125
 126         float frac;
 127         vector gunorg = '0 0 0';
 128         static vector vel_average;
 129         static vector gunorg_adjustment_highpass;
 130         static vector gunorg_adjustment_lowpass;
 131
 132         vector vel;
 133         if (autocvar_cl_followmodel_velocity_absolute)
 134                 vel = view.velocity;
 135         else
 136         {
 137                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 138                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 139                 vel.x = view.velocity * forward;
 140                 vel.y = view.velocity * right * -1;
 141                 vel.z = view.velocity * up;
 142         }
 143
 144         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 145         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 146         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 147
 148         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 149         lowpass3(vel, frac, vel_average, gunorg);
 150
 151         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 152
 153         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 154         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 155         frac = avg_factor(autocvar_cl_followmodel_highpass);
 156         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 157         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 158         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 159
 160         if (autocvar_cl_followmodel_velocity_absolute)
 161         {
 162                 vector fixed_gunorg;
 163                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 164                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 165                 fixed_gunorg.x = gunorg * forward;
 166                 fixed_gunorg.y = gunorg * right * -1;
 167                 fixed_gunorg.z = gunorg * up;
 168                 gunorg = fixed_gunorg;
 169         }
 170
 171         cl_followmodel_ofs = gunorg;
 172         cl_followmodel_time = time;
 173 }
 174
 175 vector leanmodel_ofs(entity view)
 176 {
 177         float frac;
 178         vector gunangles = '0 0 0';
 179         static vector gunangles_prev = '0 0 0';
 180         static vector gunangles_highpass = '0 0 0';
 181         static vector gunangles_adjustment_highpass;
 182         static vector gunangles_adjustment_lowpass;
 183
 184         if (view.csqcmodel_teleported)
 185                 gunangles_prev = view_angles;
 186
 187         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 188         gunangles_highpass += gunangles_prev;
 189         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 190         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 191         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 193         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 194         gunangles_prev = view_angles;
 195         gunangles_highpass -= gunangles_prev;
 196
 197         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 198         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 199
 200         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 201         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 202         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 203         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 204         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 205
 206         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 207
 208         return gunangles;
 209 }
 210
 211 vector bobmodel_ofs(entity view)
 212 {
 213         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 214         static bool oldonground;
 215         static float hitgroundtime;
 216         if (clonground)
 217         {
 218                 float f = time; // cl.movecmd[0].time
 219                 if (!oldonground)
 220                         hitgroundtime = f;
 221         }
 222         oldonground = clonground;
 223
 224         // calculate for swinging gun model
 225         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 226         vector gunorg = '0 0 0';
 227         static float bobmodel_scale = 0;
 228         static float time_ofs = 0; // makes the effect always restart in the same way
 229         if (clonground)
 230         {
 231                 if (time - hitgroundtime > 0.05)
 232                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 233         }
 234         else
 235                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 236
 237         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 238         if (bobmodel_scale && xyspeed)
 239         {
 240                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 241                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 242                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 243                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 244         }
 245         else
 246                 time_ofs = time;
 247
 248         return gunorg;
 249 }
 250
 251 void viewmodel_animate(entity this)
 252 {
 253         if (autocvar_chase_active) return;
 254         if (STAT(HEALTH) <= 0) return;
 255
 256         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 257
 258         if (autocvar_cl_followmodel)
 259         {
 260                 calc_followmodel_ofs(view);
 261                 this.origin += cl_followmodel_ofs;
 262         }
 263
 264         if (autocvar_cl_leanmodel)
 265                 this.angles += leanmodel_ofs(view);
 266
 267         // vertical view bobbing code
 268         // TODO: cl_bob
 269
 270         // horizontal view bobbing code
 271         // TODO: cl_bob2
 272
 273         // fall bobbing code
 274         // causes the view to swing down and back up when touching the ground
 275         // TODO: cl_bobfall
 276
 277         // gun model bobbing code
 278         if (autocvar_cl_bobmodel)
 279                 this.origin += bobmodel_ofs(view);
 280 }
 281
 282 .vector viewmodel_origin, viewmodel_angles;
 283 .float weapon_nextthink;
 284 .float weapon_eta_last;
 285 .float weapon_switchdelay;
 286
 287 .string name_last;
 288
 289 void viewmodel_draw(entity this)
 290 {
 291         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 292                 return;
 293         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 294         float a = this.alpha;
 295         static bool wasinvehicle;
 296         bool invehicle = player_localentnum > maxclients;
 297         if (invehicle) a = -1;
 298         else if (wasinvehicle) a = 1;
 299         wasinvehicle = invehicle;
 300         Weapon wep = this.activeweapon;
 301         int c = entcs_GetClientColors(current_player);
 302         vector g = weaponentity_glowmod(wep, NULL, c, this);
 303         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 304         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 305                 | EF_NODEPTHTEST)
 306                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 307         for (entity e = this; e; e = e.weaponchild)
 308         {
 309                 e.drawmask = mask;
 310                 e.alpha = a;
 311                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 312                 e.glowmod = g;
 313                 e.csqcmodel_effects = fx;
 314                 CSQCModel_Effects_Apply(e);
 315         }
 316         {
 317                 string name = wep.mdl;
 318                 string newname = wep.wr_viewmodel(wep, this);
 319                 if(newname)
 320                         name = newname;
 321                 bool swap = name != this.name_last;
 322                 // if (swap)
 323                 {
 324                         this.name_last = name;
 325                         CL_WeaponEntity_SetModel(this, name, swap);
 326                         this.viewmodel_origin = this.origin;
 327                         this.viewmodel_angles = this.angles;
 328                 }
 329                 anim_update(this);
 330                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 331                         anim_set(this, this.anim_idle, true, false, false);
 332         }
 333         float f = 0; // 0..1; 0: fully active
 334         float rate = STAT(WEAPONRATEFACTOR);
 335         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 336         if (eta <= 0) f = this.weapon_eta_last;
 337         else switch (this.state)
 338         {
 339                 case WS_RAISE:
 340                 {
 341                         f = eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_DROP:
 345                 {
 346                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_CLEAR:
 350                 {
 351                         f = 1;
 352                         break;
 353                 }
 354         }
 355         this.weapon_eta_last = f;
 356         this.origin = this.viewmodel_origin;
 357         this.angles = this.viewmodel_angles;
 358         this.angles_x = (-90 * f * f);
 359         viewmodel_animate(this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 void Porto_Draw(entity this);
 369 STATIC_INIT(Porto)
 370 {
 371         entity e = new_pure(porto);
 372         e.draw = Porto_Draw;
 373         IL_PUSH(g_drawables, e);
 374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 375 }
 376
 377 const int polyline_length = 16;
 378 .vector polyline[polyline_length];
 379 void Porto_Draw(entity this)
 380 {
 381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 382         {
 383                 entity wepent = viewmodels[slot];
 384
 385                 if (wepent.activeweapon != WEP_PORTO) continue;
 386                 if (spectatee_status) continue;
 387                 if (WEP_CVAR(porto, secondary)) continue;
 388                 if (intermission == 1) continue;
 389                 if (intermission == 2) continue;
 390                 if (STAT(HEALTH) <= 0) continue;
 391
 392                 vector pos = view_origin;
 393                 vector dir = view_forward;
 394                 if (wepent.angles_held_status)
 395                 {
 396                         makevectors(wepent.angles_held);
 397                         dir = v_forward;
 398                 }
 399
 400                 wepent.polyline[0] = pos;
 401
 402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 403                 int n = 1 + 2;  // 2 lines == 3 points
 404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 405                 {
 406                         traceline(pos, pos + 65536 * dir, true, this);
 407                         dir = reflect(dir, trace_plane_normal);
 408                         pos = trace_endpos;
 409                         wepent.polyline[++idx] = pos;
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 411                         {
 412                                 n += 1;
 413                                 continue;
 414                         }
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 416                         {
 417                                 n = max(2, idx);
 418                                 break;
 419                         }
 420                         // check size
 421                         {
 422                                 vector ang = vectoangles2(trace_plane_normal, dir);
 423                                 ang.x = -ang.x;
 424                                 makevectors(ang);
 425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 426                                 {
 427                                         n = max(2, idx);
 428                                         break;
 429                                 }
 430                         }
 431                         portal_number += 1;
 432                         if (portal_number >= portal_max) break;
 433                         if (portal_number == 1) portal1_idx = idx;
 434                 }
 435                 for (int idx = 0; idx < n - 1; ++idx)
 436                 {
 437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 438                         if (idx == 0) p -= view_up * 16;  // line from player
 439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 441                 }
 442         }
 443 }
 444
 445 float drawtime;
 446 float avgspeed;
 447 vector GetCurrentFov(float fov)
 448 {
 449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 450         float velocityzoom, curspeed;
 451         vector v;
 452
 453         zoomsensitivity = autocvar_cl_zoomsensitivity;
 454         zoomfactor = autocvar_cl_zoomfactor;
 455         if(zoomfactor < 1 || zoomfactor > 30)
 456                 zoomfactor = 2.5;
 457         zoomspeed = autocvar_cl_zoomspeed;
 458         if(zoomspeed >= 0)
 459         if(zoomspeed < 0.5 || zoomspeed > 16)
 460                         zoomspeed = 3.5;
 461
 462         zoomdir = button_zoom;
 463
 464         if(hud == HUD_NORMAL && !spectatee_status)
 465         {
 466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 467                 {
 468                         entity wepent = viewmodels[slot];
 469                         if(wepent.switchweapon == wepent.activeweapon)
 470                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary)) || (wepent.activeweapon == WEP_OVERKILL_VORTEX && !WEP_CVAR(okvortex, secondary))) // do NOT use switchweapon here
 471                                 zoomdir += button_attack2;
 472                 }
 473         }
 474         if(spectatee_status > 0 || isdemo())
 475         {
 476                 if(spectatorbutton_zoom)
 477                 {
 478                         if(zoomdir)
 479                                 zoomdir = 0;
 480                         else
 481                                 zoomdir = 1;
 482                 }
 483                 // fteqcc failed twice here already, don't optimize this
 484         }
 485
 486         if(zoomdir) { zoomin_effect = 0; }
 487
 488         if(camera_active)
 489         {
 490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 491         }
 492         else if(autocvar_cl_spawnzoom && zoomin_effect)
 493         {
 494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 495
 496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 499         }
 500         else
 501         {
 502                 if(zoomspeed < 0) // instant zoom
 503                 {
 504                         if(zoomdir)
 505                                 current_viewzoom = 1 / zoomfactor;
 506                         else
 507                                 current_viewzoom = 1;
 508                 }
 509                 else
 510                 {
 511                         if(zoomdir)
 512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 513                         else
 514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 515                 }
 516         }
 517
 518         if(almost_equals(current_viewzoom, 1))
 519                 current_zoomfraction = 0;
 520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 521                 current_zoomfraction = 1;
 522         else
 523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 524
 525         if(zoomsensitivity < 1)
 526                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 527         else
 528                 setsensitivityscale(1);
 529
 530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 531         {
 532                 if(intermission) { curspeed = 0; }
 533                 else
 534                 {
 535
 536                         makevectors(view_angles);
 537                         v = pmove_vel;
 538                         if(csqcplayer)
 539                                 v = csqcplayer.velocity;
 540
 541                         switch(autocvar_cl_velocityzoom_type)
 542                         {
 543                                 case 3: curspeed = max(0, v_forward * v); break;
 544                                 case 2: curspeed = (v_forward * v); break;
 545                                 case 1: default: curspeed = vlen(v); break;
 546                         }
 547                 }
 548
 549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 552
 553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 554         }
 555         else
 556                 velocityzoom = 1;
 557
 558         float frustumx, frustumy, fovx, fovy;
 559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 563
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetViewLocationFOV(float fov)
 568 {
 569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 577 {
 578         float fovx, fovy;
 579         float width = (ov_worldmax.x - ov_worldmin.x);
 580         float height = (ov_worldmax.y - ov_worldmin.y);
 581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 // this function must match W_SetupShot!
 588 float zoomscript_caught;
 589
 590 vector wcross_origin;
 591 float wcross_scale_prev, wcross_alpha_prev;
 592 vector wcross_color_prev;
 593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 594 vector wcross_color_goal_prev;
 595 float wcross_changedonetime;
 596
 597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 599 float wcross_name_changestarttime, wcross_name_changedonetime;
 600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 601
 602 float wcross_ring_prev;
 603
 604 entity trueaim;
 605 entity trueaim_rifle;
 606
 607 const float SHOTTYPE_HITTEAM = 1;
 608 const float SHOTTYPE_HITOBSTRUCTION = 2;
 609 const float SHOTTYPE_HITWORLD = 3;
 610 const float SHOTTYPE_HITENEMY = 4;
 611
 612 void TrueAim_Init()
 613 {
 614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616 }
 617
 618 float EnemyHitCheck()
 619 {
 620         float t, n;
 621         wcross_origin = project_3d_to_2d(trace_endpos);
 622         wcross_origin.z = 0;
 623         if(trace_ent)
 624                 n = trace_ent.entnum;
 625         else
 626                 n = trace_networkentity;
 627         if(n < 1)
 628                 return SHOTTYPE_HITWORLD;
 629         if(n > maxclients)
 630                 return SHOTTYPE_HITWORLD;
 631         t = entcs_GetTeam(n - 1);
 632         if(teamplay)
 633                 if(t == myteam)
 634                         return SHOTTYPE_HITTEAM;
 635         if(t == NUM_SPECTATOR)
 636                 return SHOTTYPE_HITWORLD;
 637         return SHOTTYPE_HITENEMY;
 638 }
 639
 640 float TrueAimCheck(entity wepent)
 641 {
 642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 643         vector vecs, trueaimpoint, w_shotorg;
 644         vector mi, ma, dv;
 645         float shottype;
 646         entity ta;
 647         float mv;
 648
 649         mi = ma = '0 0 0';
 650         ta = trueaim;
 651         mv = MOVE_NOMONSTERS;
 652
 653         switch(wepent.activeweapon) // WEAPONTODO
 654         {
 655                 case WEP_TUBA: // no aim
 656                 case WEP_PORTO: // shoots from eye
 657                 case WEP_NEXBALL: // shoots from eye
 658                 case WEP_HOOK: // no trueaim
 659                 case WEP_MORTAR: // toss curve
 660                         return SHOTTYPE_HITWORLD;
 661                 case WEP_VORTEX:
 662                 case WEP_OVERKILL_VORTEX:
 663                 case WEP_VAPORIZER:
 664                         mv = MOVE_NORMAL;
 665                         break;
 666                 case WEP_RIFLE:
 667                         ta = trueaim_rifle;
 668                         mv = MOVE_NORMAL;
 669                         if(zoomscript_caught)
 670                         {
 671                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 672                                 return EnemyHitCheck();
 673                         }
 674                         break;
 675                 case WEP_DEVASTATOR: // projectile has a size!
 676                         mi = '-3 -3 -3';
 677                         ma = '3 3 3';
 678                         break;
 679                 case WEP_FIREBALL: // projectile has a size!
 680                         mi = '-16 -16 -16';
 681                         ma = '16 16 16';
 682                         break;
 683                 case WEP_SEEKER: // projectile has a size!
 684                         mi = '-2 -2 -2';
 685                         ma = '2 2 2';
 686                         break;
 687                 case WEP_ELECTRO: // projectile has a size!
 688                         mi = '0 0 -3';
 689                         ma = '0 0 -3';
 690                         break;
 691         }
 692
 693         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 694
 695         vecs = decompressShotOrigin(STAT(SHOTORG));
 696
 697         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 698         trueaimpoint = trace_endpos;
 699
 700         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 701                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 702
 703         if(vecs.x > 0)
 704                 vecs.y = -vecs.y;
 705         else
 706                 vecs = '0 0 0';
 707
 708         dv = view_right * vecs.y + view_up * vecs.z;
 709         w_shotorg = traceorigin + dv;
 710
 711         // now move the vecs forward as much as requested if possible
 712         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 713         w_shotorg = trace_endpos - view_forward * nudge;
 714
 715         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 716         shottype = EnemyHitCheck();
 717         if(shottype != SHOTTYPE_HITWORLD)
 718                 return shottype;
 719
 720 #if 0
 721         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 722         // or rather, I know why, but see no fix
 723         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 724                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 725                 return SHOTTYPE_HITOBSTRUCTION;
 726 #endif
 727
 728         return SHOTTYPE_HITWORLD;
 729 }
 730
 731 void PostInit();
 732 void CSQC_Demo_Camera();
 733 float camera_mode;
 734 const float CAMERA_FREE = 1;
 735 const float CAMERA_CHASE = 2;
 736 float reticle_type;
 737 string NextFrameCommand;
 738
 739 vector freeze_org, freeze_ang;
 740 entity nightvision_noise, nightvision_noise2;
 741
 742 const float MAX_TIME_DIFF = 5;
 743 float pickup_crosshair_time, pickup_crosshair_size;
 744 float hitindication_crosshair_size;
 745 float use_vortex_chargepool;
 746
 747 float myhealth, myhealth_prev;
 748 float myhealth_flash;
 749
 750 float old_blurradius, old_bluralpha;
 751 float old_sharpen_intensity;
 752
 753 vector myhealth_gentlergb;
 754
 755 float contentavgalpha, liquidalpha_prev;
 756 vector liquidcolor_prev;
 757
 758 float eventchase_current_distance;
 759 float eventchase_running;
 760 bool WantEventchase(entity this)
 761 {
 762         if(autocvar_cl_orthoview)
 763                 return false;
 764         if(STAT(GAME_STOPPED) || intermission)
 765                 return true;
 766         if(this.viewloc)
 767                 return true;
 768         if(spectatee_status >= 0)
 769         {
 770                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 771                         return true;
 772                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 773                         return true;
 774                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 775                 {
 776                         if(autocvar_cl_eventchase_death == 2)
 777                         {
 778                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 779                                 if(this.velocity == '0 0 0' || eventchase_running)
 780                                         return true;
 781                         }
 782                         else return true;
 783                 }
 784         }
 785         return false;
 786 }
 787
 788 void HUD_Crosshair_Vehicle(entity this)
 789 {
 790         if(hud != HUD_BUMBLEBEE_GUN)
 791         {
 792                 Vehicle info = Vehicles_from(hud);
 793                 info.vr_crosshair(info, this);
 794         }
 795 }
 796
 797 vector damage_blurpostprocess, content_blurpostprocess;
 798
 799 float unaccounted_damage = 0;
 800 void UpdateDamage()
 801 {
 802         // accumulate damage with each stat update
 803         static float damage_total_prev = 0;
 804         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 805         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 806         damage_total_prev = damage_total;
 807
 808         static float damage_dealt_time_prev = 0;
 809         float damage_dealt_time = STAT(HIT_TIME);
 810         if (damage_dealt_time != damage_dealt_time_prev)
 811         {
 812                 unaccounted_damage += unaccounted_damage_new;
 813                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 814         }
 815         damage_dealt_time_prev = damage_dealt_time;
 816
 817         // prevent hitsound when switching spectatee
 818         static float spectatee_status_prev = 0;
 819         if (spectatee_status != spectatee_status_prev)
 820                 unaccounted_damage = 0;
 821         spectatee_status_prev = spectatee_status;
 822 }
 823
 824 void HitSound()
 825 {
 826         // varying sound pitch
 827
 828         bool have_arc = false;
 829         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830         {
 831                 entity wepent = viewmodels[slot];
 832
 833                 if(wepent.activeweapon == WEP_ARC)
 834                         have_arc = true;
 835         }
 836
 837         static float hitsound_time_prev = 0;
 838         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 839         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 840         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 841         {
 842                 if (autocvar_cl_hitsound && unaccounted_damage)
 843                 {
 844                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 845                         float a = autocvar_cl_hitsound_max_pitch;
 846                         float b = autocvar_cl_hitsound_min_pitch;
 847                         float c = autocvar_cl_hitsound_nom_damage;
 848                         float d = unaccounted_damage;
 849                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 850
 851                         // if sound variation is disabled, set pitch_shift to 1
 852                         if (autocvar_cl_hitsound == 1)
 853                                 pitch_shift = 1;
 854
 855                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 856                         if (autocvar_cl_hitsound == 3)
 857                         {
 858                                 float mirror_value = (a-b)/2 + b;
 859                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 860                         }
 861
 862                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 863
 864                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 865                         // todo: normalize sound pressure levels? seems unnecessary
 866
 867                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 868                 }
 869                 unaccounted_damage = 0;
 870                 hitsound_time_prev = time;
 871         }
 872
 873         static float typehit_time_prev = 0;
 874         float typehit_time = STAT(TYPEHIT_TIME);
 875         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 876         {
 877                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 878                 typehit_time_prev = typehit_time;
 879         }
 880
 881         static float kill_time_prev = 0;
 882         float kill_time = STAT(KILL_TIME);
 883         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 884         {
 885                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 886                 kill_time_prev = kill_time;
 887         }
 888 }
 889
 890 vector crosshair_getcolor(entity this, float health_stat)
 891 {
 892         static float rainbow_last_flicker;
 893         static vector rainbow_prev_color;
 894         vector wcross_color = '0 0 0';
 895         switch(autocvar_crosshair_color_special)
 896         {
 897                 case 1: // crosshair_color_per_weapon
 898                 {
 899                         if(this != WEP_Null && hud == HUD_NORMAL)
 900                         {
 901                                 wcross_color = this.wpcolor;
 902                                 break;
 903                         }
 904                         else { goto normalcolor; }
 905                 }
 906
 907                 case 2: // crosshair_color_by_health
 908                 {
 909                         float hp = health_stat;
 910
 911                         //x = red
 912                         //y = green
 913                         //z = blue
 914
 915                         wcross_color.z = 0;
 916
 917                         if(hp > 200)
 918                         {
 919                                 wcross_color.x = 0;
 920                                 wcross_color.y = 1;
 921                         }
 922                         else if(hp > 150)
 923                         {
 924                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 925                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 926                         }
 927                         else if(hp > 100)
 928                         {
 929                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 930                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 931                                 wcross_color.z = 1 - (hp-100)*0.02;
 932                         }
 933                         else if(hp > 50)
 934                         {
 935                                 wcross_color.x = 1;
 936                                 wcross_color.y = 1;
 937                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 938                         }
 939                         else if(hp > 20)
 940                         {
 941                                 wcross_color.x = 1;
 942                                 wcross_color.y = (hp-20)*90/27/100;
 943                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 944                         }
 945                         else
 946                         {
 947                                 wcross_color.x = 1;
 948                                 wcross_color.y = 0;
 949                         }
 950                         break;
 951                 }
 952
 953                 case 3: // crosshair_color_rainbow
 954                 {
 955                         if(time >= rainbow_last_flicker)
 956                         {
 957                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 958                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 959                         }
 960                         wcross_color = rainbow_prev_color;
 961                         break;
 962                 }
 963 LABEL(normalcolor)
 964                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 965         }
 966
 967         return wcross_color;
 968 }
 969
 970 void HUD_Crosshair(entity this)
 971 {
 972         float f, i, j;
 973         vector v;
 974         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 975                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 976                 !HUD_MinigameMenu_IsOpened() )
 977         {
 978                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 979                         return;
 980
 981                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 982                         return;
 983
 984                 if (hud != HUD_NORMAL)
 985                 {
 986                         HUD_Crosshair_Vehicle(this);
 987                         return;
 988                 }
 989
 990                 string wcross_style;
 991                 float wcross_alpha, wcross_resolution;
 992                 wcross_style = autocvar_crosshair;
 993                 if (wcross_style == "0")
 994                         return;
 995                 wcross_resolution = autocvar_crosshair_size;
 996                 if (wcross_resolution == 0)
 997                         return;
 998                 wcross_alpha = autocvar_crosshair_alpha;
 999                 if (wcross_alpha == 0)
1000                         return;
1001
1002                 // TrueAim check
1003                 float shottype;
1004
1005                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1006                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1007                 wcross_origin.z = 0;
1008                 if(autocvar_crosshair_hittest)
1009                 {
1010                         vector wcross_oldorigin;
1011                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1012                         wcross_oldorigin = wcross_origin;
1013                         shottype = TrueAimCheck(thiswep);
1014                         if(shottype == SHOTTYPE_HITWORLD)
1015                         {
1016                                 v = wcross_origin - wcross_oldorigin;
1017                                 v.x /= vid_conwidth;
1018                                 v.y /= vid_conheight;
1019                                 if(vdist(v, >, 0.01))
1020                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1021                         }
1022                         if(!autocvar_crosshair_hittest_showimpact)
1023                                 wcross_origin = wcross_oldorigin;
1024                 }
1025                 else
1026                         shottype = SHOTTYPE_HITWORLD;
1027
1028                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1029                 string wcross_name = "";
1030                 float wcross_scale, wcross_blur;
1031
1032         entity e = WEP_Null;
1033                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1034                 {
1035                         entity wepent = viewmodels[0]; // TODO: unhardcode
1036                         e = wepent.switchingweapon;
1037                         if(e)
1038                         {
1039                                 if(autocvar_crosshair_per_weapon)
1040                                 {
1041                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1042                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1043                                         //if (wcross_resolution == 0)
1044                                                 //return;
1045
1046                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1047                                         wcross_resolution *= e.w_crosshair_size;
1048                                         wcross_name = e.w_crosshair;
1049                                 }
1050                         }
1051                 }
1052
1053                 if(wcross_name == "")
1054                         wcross_name = strcat("gfx/crosshair", wcross_style);
1055
1056                 // MAIN CROSSHAIR COLOR DECISION
1057                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1058
1059                 if(autocvar_crosshair_effect_scalefade)
1060                 {
1061                         wcross_scale = wcross_resolution;
1062                         wcross_resolution = 1;
1063                 }
1064                 else
1065                 {
1066                         wcross_scale = 1;
1067                 }
1068
1069                 if(autocvar_crosshair_pickup)
1070                 {
1071                         float stat_pickup_time = STAT(LAST_PICKUP);
1072
1073                         if(pickup_crosshair_time < stat_pickup_time)
1074                         {
1075                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1076                                         pickup_crosshair_size = 1;
1077
1078                                 pickup_crosshair_time = stat_pickup_time;
1079                         }
1080
1081                         if(pickup_crosshair_size > 0)
1082                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1083                         else
1084                                 pickup_crosshair_size = 0;
1085
1086                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1087                 }
1088
1089                 // todo: make crosshair hit indication dependent on damage dealt
1090                 if(autocvar_crosshair_hitindication)
1091                 {
1092                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1093
1094                         if(unaccounted_damage)
1095                         {
1096                                 hitindication_crosshair_size = 1;
1097                         }
1098
1099                         if(hitindication_crosshair_size > 0)
1100                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1101                         else
1102                                 hitindication_crosshair_size = 0;
1103
1104                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1105                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1106                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1107                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1108                 }
1109
1110                 if(shottype == SHOTTYPE_HITENEMY)
1111                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1112                 if(shottype == SHOTTYPE_HITTEAM)
1113                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1114
1115                 f = fabs(autocvar_crosshair_effect_time);
1116                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1117                 {
1118                         wcross_changedonetime = time + f;
1119                 }
1120                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1121                 {
1122                         wcross_name_changestarttime = time;
1123                         wcross_name_changedonetime = time + f;
1124                         if(wcross_name_goal_prev_prev)
1125                                 strunzone(wcross_name_goal_prev_prev);
1126                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1127                         wcross_name_goal_prev = strzone(wcross_name);
1128                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1129                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1130                         wcross_resolution_goal_prev = wcross_resolution;
1131                 }
1132
1133                 wcross_scale_goal_prev = wcross_scale;
1134                 wcross_alpha_goal_prev = wcross_alpha;
1135                 wcross_color_goal_prev = wcross_color;
1136
1137                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1138                 {
1139                         wcross_blur = 1;
1140                         wcross_alpha *= 0.75;
1141                 }
1142                 else
1143                         wcross_blur = 0;
1144                 // *_prev is at time-frametime
1145                 // * is at wcross_changedonetime+f
1146                 // what do we have at time?
1147                 if(time < wcross_changedonetime)
1148                 {
1149                         f = frametime / (wcross_changedonetime - time + frametime);
1150                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1151                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1152                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1153                 }
1154
1155                 wcross_scale_prev = wcross_scale;
1156                 wcross_alpha_prev = wcross_alpha;
1157                 wcross_color_prev = wcross_color;
1158
1159                 MUTATOR_CALLHOOK(UpdateCrosshair);
1160
1161                 wcross_scale *= 1 - autocvar__menu_alpha;
1162                 wcross_alpha *= 1 - autocvar__menu_alpha;
1163                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1164
1165                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1166                 {
1167                         // crosshair rings for weapon stats
1168                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1169                         {
1170                                 // declarations and stats
1171                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1172                                 string ring_image = string_null, ring_inner_image = string_null;
1173                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1174
1175                                 ring_scale = autocvar_crosshair_ring_size;
1176
1177                                 float weapon_clipload, weapon_clipsize;
1178                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1179                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1180
1181                                 float vortex_charge, vortex_chargepool;
1182                                 vortex_charge = STAT(VORTEX_CHARGE);
1183                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1184
1185                                 float okvortex_charge, okvortex_chargepool;
1186                                 okvortex_charge = STAT(OVERKILL_VORTEX_CHARGE);
1187                                 okvortex_chargepool = STAT(OVERKILL_VORTEX_CHARGEPOOL);
1188
1189                                 float arc_heat = STAT(ARC_HEAT);
1190
1191                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1192                                         vortex_charge_movingavg = vortex_charge;
1193
1194                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1195
1196                                 // handle the values
1197                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1198                                 {
1199                                         if (vortex_chargepool || use_vortex_chargepool) {
1200                                                 use_vortex_chargepool = 1;
1201                                                 ring_inner_value = vortex_chargepool;
1202                                         } else {
1203                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1204                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1205                                         }
1206
1207                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1208                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1209                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1210
1211                                         // draw the outer ring to show the current charge of the weapon
1212                                         ring_value = vortex_charge;
1213                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1214                                         ring_rgb = wcross_color;
1215                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1216                                 }
1217                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_VORTEX) && okvortex_charge && autocvar_crosshair_ring_vortex)
1218                                 {
1219                                         if (okvortex_chargepool || use_vortex_chargepool) {
1220                                                 use_vortex_chargepool = 1;
1221                                                 ring_inner_value = okvortex_chargepool;
1222                                         } else {
1223                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * okvortex_charge;
1224                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (okvortex_charge - vortex_charge_movingavg), 1);
1225                                         }
1226
1227                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1228                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1229                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1230
1231                                         // draw the outer ring to show the current charge of the weapon
1232                                         ring_value = okvortex_charge;
1233                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1234                                         ring_rgb = wcross_color;
1235                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1236                                 }
1237                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1238                                 {
1239                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1240                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1241                                         ring_rgb = wcross_color;
1242                                         ring_image = "gfx/crosshair_ring.tga";
1243                                 }
1244                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1245                                 {
1246                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1247                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1248                                         ring_rgb = wcross_color;
1249                                         ring_image = "gfx/crosshair_ring.tga";
1250                                 }
1251                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1252                                 {
1253                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1254                                         ring_scale = autocvar_crosshair_ring_reload_size;
1255                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1256                                         ring_rgb = wcross_color;
1257
1258                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1259                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1260                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1261                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1262                                         else
1263                                                 ring_image = "gfx/crosshair_ring.tga";
1264                                 }
1265                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1266                                 {
1267                                         ring_value = arc_heat;
1268                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1269                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1270                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1271                                         ring_image = "gfx/crosshair_ring.tga";
1272                                 }
1273
1274                                 // if in weapon switch animation, fade ring out/in
1275                                 if(autocvar_crosshair_effect_time > 0)
1276                                 {
1277                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1278                                         if (f >= 1)
1279                                         {
1280                                                 wcross_ring_prev = ((ring_image) ? true : false);
1281                                         }
1282
1283                                         if(wcross_ring_prev)
1284                                         {
1285                                                 if(f < 1)
1286                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1287                                         }
1288                                         else
1289                                         {
1290                                                 if(f < 1)
1291                                                         ring_alpha *= bound(0, f, 1);
1292                                         }
1293                                 }
1294
1295                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1296                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1297
1298                                 if (ring_value)
1299                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1300                         }
1301
1302 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1303                         MACRO_BEGIN { \
1304                                 if(wcross_blur > 0) \
1305                                 { \
1306                                         for(i = -2; i <= 2; ++i) \
1307                                         for(j = -2; j <= 2; ++j) \
1308                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1309                                 } \
1310                                 else \
1311                                 { \
1312                                         M(0,0,sz,wcross_name,wcross_alpha); \
1313                                 } \
1314                         } MACRO_END
1315
1316 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1317                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1318
1319 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1320                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1321
1322                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1323                         {
1324                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1325                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1326                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1327                                 f = 1 - f;
1328                         }
1329                         else
1330                         {
1331                                 f = 1;
1332                         }
1333                         wcross_name_alpha_goal_prev = f;
1334
1335                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1336                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1337
1338                         if(autocvar_crosshair_dot)
1339                         {
1340                                 vector wcross_color_old;
1341                                 wcross_color_old = wcross_color;
1342
1343                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1344                                         wcross_color = stov(autocvar_crosshair_dot_color);
1345
1346                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1347                                 // FIXME why don't we use wcross_alpha here?
1348                                 wcross_color = wcross_color_old;
1349                         }
1350                 }
1351         }
1352         else
1353         {
1354                 wcross_scale_prev = 0;
1355                 wcross_alpha_prev = 0;
1356                 wcross_scale_goal_prev = 0;
1357                 wcross_alpha_goal_prev = 0;
1358                 wcross_changedonetime = 0;
1359                 if(wcross_name_goal_prev)
1360                         strunzone(wcross_name_goal_prev);
1361                 wcross_name_goal_prev = string_null;
1362                 if(wcross_name_goal_prev_prev)
1363                         strunzone(wcross_name_goal_prev_prev);
1364                 wcross_name_goal_prev_prev = string_null;
1365                 wcross_name_changestarttime = 0;
1366                 wcross_name_changedonetime = 0;
1367                 wcross_name_alpha_goal_prev = 0;
1368                 wcross_name_alpha_goal_prev_prev = 0;
1369                 wcross_resolution_goal_prev = 0;
1370                 wcross_resolution_goal_prev_prev = 0;
1371         }
1372 }
1373
1374 void HUD_Draw(entity this)
1375 {
1376         // if we don't know gametype and scores yet avoid drawing the scoreboard
1377         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1378         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1379         // cl_deathscoreboard would show the scoreboard and so on
1380         if(!gametype)
1381                 return;
1382
1383         if(!intermission)
1384         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1385         {
1386                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1387         }
1388         else if(STAT(FROZEN))
1389         {
1390                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1391         }
1392         if(!intermission)
1393         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1394         {
1395                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1396                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1397         }
1398         else if(STAT(CAPTURE_PROGRESS))
1399         {
1400                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1401                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1402         }
1403         else if(STAT(REVIVE_PROGRESS))
1404         {
1405                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1406                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1407         }
1408
1409         if(autocvar_r_letterbox == 0)
1410                 if(autocvar_viewsize < 120)
1411                 {
1412                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1413                                 Accuracy_LoadLevels();
1414
1415                         HUD_Main();
1416                         HUD_Scale_Disable();
1417                 }
1418
1419         // crosshair goes VERY LAST
1420         UpdateDamage();
1421         HUD_Crosshair(this);
1422         HitSound();
1423 }
1424
1425 bool ov_enabled;
1426 float oldr_nearclip;
1427 float oldr_farclip_base;
1428 float oldr_farclip_world;
1429 float oldr_novis;
1430 float oldr_useportalculling;
1431 float oldr_useinfinitefarclip;
1432
1433 void cl_notice_run();
1434
1435 float prev_myteam;
1436 int lasthud;
1437 float vh_notice_time;
1438 void WaypointSprite_Load();
1439 void CSQC_UpdateView(entity this, float w, float h)
1440 {
1441     TC(int, w); TC(int, h);
1442         entity e;
1443         float fov;
1444         float f;
1445         vector vf_size, vf_min;
1446         float a;
1447
1448         execute_next_frame();
1449
1450         ++framecount;
1451
1452         stats_get();
1453         hud = STAT(HUD);
1454
1455         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1456                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1457
1458         lasthud = hud;
1459
1460         HUD_Scale_Disable();
1461
1462         if(autocvar__hud_showbinds_reload) // menu can set this one
1463         {
1464                 db_close(binddb);
1465                 binddb = db_create();
1466                 cvar_set("_hud_showbinds_reload", "0");
1467         }
1468
1469         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1470                 view_quality = getproperty(VF_MINFPS_QUALITY);
1471         else
1472                 view_quality = 1;
1473
1474         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1475         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1476
1477         vf_size = getpropertyvec(VF_SIZE);
1478         vf_min = getpropertyvec(VF_MIN);
1479         vid_width = vf_size.x;
1480         vid_height = vf_size.y;
1481
1482         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1483         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1484
1485         WaypointSprite_Load();
1486
1487         CSQCPlayer_SetCamera();
1488
1489         if(player_localentnum <= maxclients) // is it a client?
1490                 current_player = player_localentnum - 1;
1491         else // then player_localentnum is the vehicle I'm driving
1492                 current_player = player_localnum;
1493         myteam = entcs_GetTeam(current_player);
1494
1495         if(myteam != prev_myteam)
1496         {
1497                 myteamcolors = colormapPaletteColor(myteam, 1);
1498                 FOREACH(hud_panels, true, it.update_time = time);
1499                 prev_myteam = myteam;
1500         }
1501
1502         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1503
1504         float is_dead = (STAT(HEALTH) <= 0);
1505
1506         // FIXME do we need this hack?
1507         if(isdemo())
1508         {
1509                 // in demos, input_buttons do not work
1510                 button_zoom = (autocvar__togglezoom == "-");
1511         }
1512         else if(button_zoom
1513                 && autocvar_cl_unpress_zoom_on_death
1514                 && (spectatee_status >= 0)
1515                 && (is_dead || intermission))
1516         {
1517                 // no zoom while dead or in intermission please
1518                 localcmd("-zoom\n");
1519                 button_zoom = false;
1520         }
1521
1522         // event chase camera
1523         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1524         {
1525                 if(STAT(CAMERA_SPECTATOR))
1526                 {
1527                         if(spectatee_status > 0)
1528                         {
1529                                 if(!autocvar_chase_active)
1530                                 {
1531                                         cvar_set("chase_active", "-2");
1532                                         goto skip_eventchase_death;
1533                                 }
1534                         }
1535                         else if(autocvar_chase_active == -2)
1536                                 cvar_set("chase_active", "0");
1537
1538                         if(autocvar_chase_active == -2)
1539                                 goto skip_eventchase_death;
1540                 }
1541                 else if(autocvar_chase_active == -2)
1542                         cvar_set("chase_active", "0");
1543
1544                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1545
1546                 float vehicle_viewdist = 0;
1547                 vector vehicle_viewofs = '0 0 0';
1548
1549                 if(vehicle_chase)
1550                 {
1551                         if(hud != HUD_BUMBLEBEE_GUN)
1552                         {
1553                                 Vehicle info = Vehicles_from(hud);
1554                                 vehicle_viewdist = info.height;
1555                                 vehicle_viewofs = info.view_ofs;
1556                         }
1557                 }
1558
1559                 if(WantEventchase(this))
1560                 {
1561                         vector current_view_origin_override = '0 0 0';
1562                         vector view_offset_override = '0 0 0';
1563                         float chase_distance_override = 0;
1564                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1565                         if(custom_eventchase)
1566                         {
1567                                 current_view_origin_override = M_ARGV(0, vector);
1568                                 view_offset_override = M_ARGV(1, vector);
1569                                 chase_distance_override = M_ARGV(0, float);
1570                         }
1571                         eventchase_running = true;
1572
1573                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1574                         if(!local_player)
1575                                 local_player = this; // fall back!
1576
1577                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1578                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1579                         if (custom_eventchase)
1580                                 current_view_origin = current_view_origin_override;
1581
1582                         // detect maximum viewoffset and use it
1583                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1584                         if(vehicle_chase)
1585                         {
1586                                 if(vehicle_viewofs)
1587                                         view_offset = vehicle_viewofs;
1588                                 else
1589                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1590                         }
1591                         if (custom_eventchase)
1592                                 view_offset = view_offset_override;
1593
1594                         if(view_offset)
1595                         {
1596                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1597                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1598                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1599                         }
1600
1601                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1602                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1603                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1604                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1605
1606                         // make the camera smooth back
1607                         float chase_distance = autocvar_cl_eventchase_distance;
1608                         if(vehicle_chase)
1609                         {
1610                                 if(vehicle_viewofs)
1611                                         chase_distance = vehicle_viewdist;
1612                                 else
1613                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1614                         }
1615                         if (custom_eventchase)
1616                                 chase_distance = chase_distance_override;
1617
1618                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1619                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1620                         else if(eventchase_current_distance != chase_distance)
1621                                 eventchase_current_distance = chase_distance;
1622
1623                         makevectors(view_angles);
1624
1625                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1626                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1627
1628                         // If the boxtrace fails, revert back to line tracing.
1629                         if(!local_player.viewloc)
1630                         if(trace_startsolid)
1631                         {
1632                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1633                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1634                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1635                         }
1636                         else { setproperty(VF_ORIGIN, trace_endpos); }
1637
1638                         if(!local_player.viewloc)
1639                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1640                 }
1641                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1642                 {
1643                         eventchase_running = false;
1644                         cvar_set("chase_active", "0");
1645                         eventchase_current_distance = 0; // start from 0 next time
1646                 }
1647         }
1648         // workaround for camera stuck between player's legs when using chase_active 1
1649         // because the engine stops updating the chase_active camera when the game ends
1650         else if(intermission)
1651         {
1652                 cvar_settemp("chase_active", "-1");
1653                 eventchase_current_distance = 0;
1654         }
1655
1656         LABEL(skip_eventchase_death);
1657
1658         // do lockview after event chase camera so that it still applies whenever necessary.
1659         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1660         {
1661                 setproperty(VF_ORIGIN, freeze_org);
1662                 setproperty(VF_ANGLES, freeze_ang);
1663         }
1664         else
1665         {
1666                 freeze_org = getpropertyvec(VF_ORIGIN);
1667                 freeze_ang = getpropertyvec(VF_ANGLES);
1668         }
1669
1670         WarpZone_FixView();
1671         //WarpZone_FixPMove();
1672
1673         vector ov_org = '0 0 0';
1674         vector ov_mid = '0 0 0';
1675         vector ov_worldmin = '0 0 0';
1676         vector ov_worldmax = '0 0 0';
1677         if(autocvar_cl_orthoview)
1678         {
1679                 ov_worldmin = mi_picmin;
1680                 ov_worldmax = mi_picmax;
1681
1682                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1683                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1684                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1685
1686                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1687                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1688
1689                 float ov_nearest = vlen(ov_org - vec3(
1690                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1691                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1692                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1693                 ));
1694
1695                 float ov_furthest = 0;
1696                 float dist = 0;
1697
1698                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1699                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1700                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1701                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1702                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1703                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1704                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1705                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1706
1707                 if(!ov_enabled)
1708                 {
1709                         oldr_nearclip = cvar("r_nearclip");
1710                         oldr_farclip_base = cvar("r_farclip_base");
1711                         oldr_farclip_world = cvar("r_farclip_world");
1712                         oldr_novis = cvar("r_novis");
1713                         oldr_useportalculling = cvar("r_useportalculling");
1714                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1715                 }
1716
1717                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1718                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1719                 cvar_settemp("r_farclip_world", "0");
1720                 cvar_settemp("r_novis", "1");
1721                 cvar_settemp("r_useportalculling", "0");
1722                 cvar_settemp("r_useinfinitefarclip", "0");
1723
1724                 setproperty(VF_ORIGIN, ov_org);
1725                 setproperty(VF_ANGLES, '90 0 0');
1726
1727                 ov_enabled = true;
1728
1729                 #if 0
1730                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1731                         vtos(ov_org),
1732                         vtos(getpropertyvec(VF_ANGLES)),
1733                         ov_distance,
1734                         ov_nearest,
1735                         ov_furthest);
1736                 #endif
1737         }
1738         else
1739         {
1740                 if(ov_enabled)
1741                 {
1742                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1743                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1744                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1745                         cvar_set("r_novis", ftos(oldr_novis));
1746                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1747                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1748                 }
1749                 ov_enabled = false;
1750         }
1751
1752         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1753         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1754         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1755                 viewmodel_draw(viewmodels[slot]);
1756
1757         // Render the Scene
1758         view_origin = getpropertyvec(VF_ORIGIN);
1759         view_angles = getpropertyvec(VF_ANGLES);
1760         makevectors(view_angles);
1761         view_forward = v_forward;
1762         view_right = v_right;
1763         view_up = v_up;
1764
1765 #ifdef BLURTEST
1766         if(time > blurtest_time0 && time < blurtest_time1)
1767         {
1768                 float r, t;
1769
1770                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1771                 r = t * blurtest_radius;
1772                 f = 1 / (t ** blurtest_power) - 1;
1773
1774                 cvar_set("r_glsl_postprocess", "1");
1775                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1776         }
1777         else
1778         {
1779                 cvar_set("r_glsl_postprocess", "0");
1780                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1781         }
1782 #endif
1783
1784         TargetMusic_Advance();
1785         Fog_Force();
1786
1787         if(drawtime == 0)
1788                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1789         else
1790                 drawframetime = bound(0.000001, time - drawtime, 1);
1791         drawtime = time;
1792
1793         // watch for gametype changes here...
1794         // in ParseStuffCMD the cmd isn't executed yet :/
1795         // might even be better to add the gametype to TE_CSQC_INIT...?
1796         if(!postinit)
1797                 PostInit();
1798
1799         if(intermission && !intermission_time)
1800                 intermission_time = time;
1801
1802         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1803         {
1804                 if(calledhooks & HOOK_START)
1805                 {
1806                         localcmd("\ncl_hook_gameend\n");
1807                         calledhooks |= HOOK_END;
1808                 }
1809         }
1810
1811         Announcer();
1812
1813         fov = autocvar_fov;
1814         if(fov <= 59.5)
1815         {
1816                 if(!zoomscript_caught)
1817                 {
1818                         localcmd("+button9\n");
1819                         zoomscript_caught = 1;
1820                 }
1821         }
1822         else
1823         {
1824                 if(zoomscript_caught)
1825                 {
1826                         localcmd("-button9\n");
1827                         zoomscript_caught = 0;
1828                 }
1829         }
1830
1831         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1832
1833         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1834         {
1835                 entity wepent = viewmodels[slot];
1836
1837                 if(wepent.last_switchweapon != wepent.switchweapon)
1838                 {
1839                         weapontime = time;
1840                         wepent.last_switchweapon = wepent.switchweapon;
1841                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1842                         {
1843                                 localcmd("-zoom\n");
1844                                 button_zoom = false;
1845                         }
1846                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1847                         {
1848                                 localcmd("-fire\n");
1849                                 localcmd("-fire2\n");
1850                                 button_attack2 = false;
1851                         }
1852                 }
1853                 if(wepent.last_activeweapon != wepent.activeweapon)
1854                 {
1855                         wepent.last_activeweapon = wepent.activeweapon;
1856
1857                         e = wepent.activeweapon;
1858                         if(e.netname != "")
1859                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1860                         else if(slot == 0)
1861                                 localcmd("\ncl_hook_activeweapon none\n");
1862                 }
1863         }
1864
1865         // ALWAYS Clear Current Scene First
1866         clearscene();
1867
1868         setproperty(VF_ORIGIN, view_origin);
1869         setproperty(VF_ANGLES, view_angles);
1870
1871         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1872         setproperty(VF_SIZE, vf_size);
1873         setproperty(VF_MIN, vf_min);
1874
1875         // Assign Standard Viewflags
1876         // Draw the World (and sky)
1877         setproperty(VF_DRAWWORLD, 1);
1878
1879         // Set the console size vars
1880         vid_conwidth = autocvar_vid_conwidth;
1881         vid_conheight = autocvar_vid_conheight;
1882         vid_pixelheight = autocvar_vid_pixelheight;
1883
1884         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1885         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1886         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1887
1888         if(camera_active) // Camera for demo playback
1889         {
1890                 if(autocvar_camera_enable)
1891                         CSQC_Demo_Camera();
1892                 else
1893                 {
1894                         cvar_set("chase_active", ftos(chase_active_backup));
1895                         cvar_set("cl_demo_mousegrab", "0");
1896                         camera_active = false;
1897                 }
1898         }
1899         else
1900         {
1901 #ifdef CAMERATEST
1902                 if(autocvar_camera_enable)
1903 #else
1904                 if(autocvar_camera_enable && isdemo())
1905 #endif
1906                 {
1907                         // Enable required Darkplaces cvars
1908                         chase_active_backup = autocvar_chase_active;
1909                         cvar_set("chase_active", "2");
1910                         cvar_set("cl_demo_mousegrab", "1");
1911                         camera_active = true;
1912                         camera_mode = false;
1913                 }
1914         }
1915
1916         // Draw the Crosshair
1917         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1918
1919         // Draw the Engine Status Bar (the default Quake HUD)
1920         setproperty(VF_DRAWENGINESBAR, 0);
1921
1922         // Update the mouse position
1923         /*
1924            mousepos_x = vid_conwidth;
1925            mousepos_y = vid_conheight;
1926            mousepos = mousepos*0.5 + getmousepos();
1927          */
1928
1929         IL_EACH(g_drawables, it.draw, it.draw(it));
1930
1931         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1932         renderscene();
1933
1934         // now switch to 2D drawing mode by calling a 2D drawing function
1935         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1936         // next R_RenderScene call
1937         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1938
1939         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1940         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1941         {
1942                 // apply night vision effect
1943                 vector tc_00, tc_01, tc_10, tc_11;
1944                 vector rgb = '0 0 0';
1945
1946                 if(!nightvision_noise)
1947                 {
1948                         nightvision_noise = new(nightvision_noise);
1949                 }
1950                 if(!nightvision_noise2)
1951                 {
1952                         nightvision_noise2 = new(nightvision_noise2);
1953                 }
1954
1955                 // color tint in yellow
1956                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1957
1958                 // draw BG
1959                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1960                 rgb = '1 1 1';
1961                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1962                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1963                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1964                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1965                 tc_11 = tc_01 + tc_10 - tc_00;
1966                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1967                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1968                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1969                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1970                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1971                 R_EndPolygon();
1972
1973                 // draw FG
1974                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1975                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1976                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1977                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1978                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1979                 tc_11 = tc_01 + tc_10 - tc_00;
1980                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1981                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1982                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1983                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1984                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1985                 R_EndPolygon();
1986         }
1987
1988         if(autocvar_cl_reticle)
1989         {
1990                 string reticle_image = string_null;
1991                 bool wep_zoomed = false;
1992                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1993                 {
1994                         entity wepe = viewmodels[slot];
1995                         Weapon wep = wepe.activeweapon;
1996                         if(wep != WEP_Null && wep.wr_zoom)
1997                         {
1998                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1999                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2000                                         reticle_image = wep.w_reticle;
2001                                 wep_zoomed += do_zoom;
2002                         }
2003                 }
2004                 // Draw the aiming reticle for weapons that use it
2005                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2006                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2007                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2008                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2009                 {
2010                         // no zoom reticle while dead
2011                         reticle_type = 0;
2012                 }
2013                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2014                 {
2015                         if(reticle_image) { reticle_type = 2; }
2016                         else { reticle_type = 0; }
2017                 }
2018                 else if(button_zoom || zoomscript_caught)
2019                 {
2020                         // normal zoom
2021                         reticle_type = 1;
2022                 }
2023
2024                 if(reticle_type)
2025                 {
2026                         if(autocvar_cl_reticle_stretch)
2027                         {
2028                                 reticle_size.x = vid_conwidth;
2029                                 reticle_size.y = vid_conheight;
2030                                 reticle_pos.x = 0;
2031                                 reticle_pos.y = 0;
2032                         }
2033                         else
2034                         {
2035                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2036                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2037                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2038                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2039                         }
2040
2041                         if(zoomscript_caught)
2042                                 f = 1;
2043                         else
2044                                 f = current_zoomfraction;
2045
2046                         if(f)
2047                         {
2048                                 switch(reticle_type)
2049                                 {
2050                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2051                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2052                                 }
2053                         }
2054                 }
2055         }
2056         else
2057         {
2058                 if(reticle_type != 0) { reticle_type = 0; }
2059         }
2060
2061
2062         // improved polyblend
2063         if(autocvar_hud_contents)
2064         {
2065                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2066                 vector liquidcolor;
2067
2068                 switch(pointcontents(view_origin))
2069                 {
2070                         case CONTENT_WATER:
2071                                 liquidalpha = autocvar_hud_contents_water_alpha;
2072                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2073                                 incontent = 1;
2074                                 break;
2075
2076                         case CONTENT_LAVA:
2077                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2078                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2079                                 incontent = 1;
2080                                 break;
2081
2082                         case CONTENT_SLIME:
2083                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2084                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2085                                 incontent = 1;
2086                                 break;
2087
2088                         default:
2089                                 liquidalpha = 0;
2090                                 liquidcolor = '0 0 0';
2091                                 incontent = 0;
2092                                 break;
2093                 }
2094
2095                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2096                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2097                         contentfadetime = autocvar_hud_contents_fadeintime;
2098                         liquidalpha_prev = liquidalpha;
2099                         liquidcolor_prev = liquidcolor;
2100                 }
2101                 else
2102                         contentfadetime = autocvar_hud_contents_fadeouttime;
2103
2104                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2105                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2106
2107                 if(contentavgalpha)
2108                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2109
2110                 if(autocvar_hud_postprocessing)
2111                 {
2112                         if(autocvar_hud_contents_blur && contentavgalpha)
2113                         {
2114                                 content_blurpostprocess.x = 1;
2115                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2116                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2117                         }
2118                         else
2119                         {
2120                                 content_blurpostprocess.x = 0;
2121                                 content_blurpostprocess.y = 0;
2122                                 content_blurpostprocess.z = 0;
2123                         }
2124                 }
2125         }
2126
2127         if(autocvar_hud_damage && !STAT(FROZEN))
2128         {
2129                 splash_size.x = max(vid_conwidth, vid_conheight);
2130                 splash_size.y = max(vid_conwidth, vid_conheight);
2131                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2132                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2133
2134                 float myhealth_flash_temp;
2135                 myhealth = STAT(HEALTH);
2136
2137                 // fade out
2138                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2139                 // add new damage
2140                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2141
2142                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2143                 pain_threshold = autocvar_hud_damage_pain_threshold;
2144                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2145                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2146
2147                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2148                 {
2149                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2150                 }
2151
2152                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2153
2154                 if(myhealth_prev < 1)
2155                 {
2156                         if(myhealth >= 1)
2157                         {
2158                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2159                                 myhealth_flash_temp = 0;
2160                         }
2161                         else
2162                         {
2163                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2164                         }
2165                 }
2166
2167                 if(spectatee_status == -1 || intermission)
2168                 {
2169                         myhealth_flash = 0; // observing, or match ended
2170                         myhealth_flash_temp = 0;
2171                 }
2172
2173                 myhealth_prev = myhealth;
2174
2175                 // IDEA: change damage color/picture based on player model for robot/alien species?
2176                 // pro: matches model better
2177                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2178                 // maybe different reddish pics?
2179                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2180                 {
2181                         if(autocvar_cl_gentle_damage == 2)
2182                         {
2183                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2184                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2185                         }
2186                         else
2187                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2188
2189                         if(myhealth_flash_temp > 0)
2190                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2191                 }
2192                 else if(myhealth_flash_temp > 0)
2193                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2194
2195                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2196                 {
2197                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2198                         {
2199                                 damage_blurpostprocess.x = 1;
2200                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2201                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2202                         }
2203                         else
2204                         {
2205                                 damage_blurpostprocess.x = 0;
2206                                 damage_blurpostprocess.y = 0;
2207                                 damage_blurpostprocess.z = 0;
2208                         }
2209                 }
2210         }
2211
2212         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2213         float e2 = (autocvar_hud_powerup != 0);
2214         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2215         {
2216                 // enable or disable rendering types if they are used or not
2217                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2218                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2219
2220                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2221                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2222                 {
2223                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2224                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2225                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2226                         {
2227                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2228                                 old_blurradius = blurradius;
2229                                 old_bluralpha = bluralpha;
2230                         }
2231                 }
2232                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2233                 {
2234                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2235                         old_blurradius = 0;
2236                         old_bluralpha = 0;
2237                 }
2238
2239                 // edge detection postprocess handling done second (used by hud_powerup)
2240                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2241                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2242                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2243
2244                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2245
2246                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2247                 {
2248                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2249                         {
2250                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2251                                 old_sharpen_intensity = sharpen_intensity;
2252                         }
2253                 }
2254                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2255                 {
2256                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2257                         old_sharpen_intensity = 0;
2258                 }
2259
2260                 if(cvar("r_glsl_postprocess") == 0)
2261                         cvar_set("r_glsl_postprocess", "2");
2262         }
2263         else if(cvar("r_glsl_postprocess") == 2)
2264                 cvar_set("r_glsl_postprocess", "0");
2265
2266         /*if(gametype == MAPINFO_TYPE_CTF)
2267           {
2268           ctf_view();
2269           } else */
2270
2271         // draw 2D entities
2272         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2273         Draw_ShowNames_All();
2274         Debug_Draw();
2275
2276         scoreboard_active = Scoreboard_WouldDraw();
2277
2278         HUD_Draw(this); // this parameter for deep vehicle function
2279
2280         if(NextFrameCommand)
2281         {
2282                 localcmd("\n", NextFrameCommand, "\n");
2283                 NextFrameCommand = string_null;
2284         }
2285
2286         // we must do this check AFTER a frame was rendered, or it won't work
2287         if(cs_project_is_b0rked == 0)
2288         {
2289                 string w0, h0;
2290                 w0 = ftos(autocvar_vid_conwidth);
2291                 h0 = ftos(autocvar_vid_conheight);
2292                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2293                 //setproperty(VF_FOV, '90 90 0');
2294                 setproperty(VF_ORIGIN, '0 0 0');
2295                 setproperty(VF_ANGLES, '0 0 0');
2296                 setproperty(VF_PERSPECTIVE, 1);
2297                 makevectors('0 0 0');
2298                 vector v1, v2;
2299                 cvar_set("vid_conwidth", "800");
2300                 cvar_set("vid_conheight", "600");
2301                 v1 = cs_project(v_forward);
2302                 cvar_set("vid_conwidth", "640");
2303                 cvar_set("vid_conheight", "480");
2304                 v2 = cs_project(v_forward);
2305                 if(v1 == v2)
2306                         cs_project_is_b0rked = 1;
2307                 else
2308                         cs_project_is_b0rked = -1;
2309                 cvar_set("vid_conwidth", w0);
2310                 cvar_set("vid_conheight", h0);
2311         }
2312
2313         if(autocvar__hud_configure)
2314                 HUD_Panel_Mouse();
2315         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2316                 HUD_Minigame_Mouse();
2317         else if(QuickMenu_IsOpened())
2318                 QuickMenu_Mouse();
2319         else
2320                 HUD_Radar_Mouse();
2321
2322         cl_notice_run();
2323         unpause_update();
2324         Net_Flush();
2325
2326         // let's reset the view back to normal for the end
2327         setproperty(VF_MIN, '0 0 0');
2328         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2329
2330         IL_ENDFRAME();
2331 }
2332
2333
2334 // following vectors must be global to allow seamless switching between camera modes
2335 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2336 void CSQC_Demo_Camera()
2337 {
2338         float speed, attenuation, dimensions;
2339         vector tmp, delta;
2340
2341         if( autocvar_camera_reset || !camera_mode )
2342         {
2343                 camera_offset = '0 0 0';
2344                 current_angles = '0 0 0';
2345                 camera_direction = '0 0 0';
2346                 camera_offset.z += 30;
2347                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2348                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2349                 current_origin = view_origin;
2350                 current_camera_offset  = camera_offset;
2351                 cvar_set("camera_reset", "0");
2352                 camera_mode = CAMERA_CHASE;
2353         }
2354
2355         // Camera angles
2356         if( camera_roll )
2357                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2358
2359         if(autocvar_camera_look_player)
2360         {
2361                 vector dir;
2362                 float n;
2363
2364                 dir = normalize(view_origin - current_position);
2365                 n = mouse_angles.z;
2366                 mouse_angles = vectoangles(dir);
2367                 mouse_angles.x = mouse_angles.x * -1;
2368                 mouse_angles.z = n;
2369         }
2370         else
2371         {
2372                 tmp = getmousepos() * 0.1;
2373                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2374                 {
2375                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2376                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2377                 }
2378         }
2379
2380         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2381         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2382         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2383         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2384
2385         // Fix difference when angles don't have the same sign
2386         delta = '0 0 0';
2387         if(mouse_angles.y < -60 && current_angles.y > 60)
2388                 delta = '0 360 0';
2389         if(mouse_angles.y > 60 && current_angles.y < -60)
2390                 delta = '0 -360 0';
2391
2392         if(autocvar_camera_look_player)
2393                 attenuation = autocvar_camera_look_attenuation;
2394         else
2395                 attenuation = autocvar_camera_speed_attenuation;
2396
2397         attenuation = 1 / max(1, attenuation);
2398         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2399
2400         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2401         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2402         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2403         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2404
2405         // Camera position
2406         tmp = '0 0 0';
2407         dimensions = 0;
2408
2409         if( camera_direction.x )
2410         {
2411                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2412                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2413                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2414                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2415                 ++dimensions;
2416         }
2417
2418         if( camera_direction.y )
2419         {
2420                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2421                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2422                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2423                 ++dimensions;
2424         }
2425
2426         if( camera_direction.z )
2427         {
2428                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2429                 ++dimensions;
2430         }
2431
2432         if(autocvar_camera_free)
2433                 speed = autocvar_camera_speed_free;
2434         else
2435                 speed = autocvar_camera_speed_chase;
2436
2437         if(dimensions)
2438         {
2439                 speed = speed * sqrt(1 / dimensions);
2440                 camera_offset += tmp * speed;
2441         }
2442
2443         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2444
2445         // Camera modes
2446         if( autocvar_camera_free )
2447         {
2448                 if ( camera_mode == CAMERA_CHASE )
2449                 {
2450                         current_camera_offset = current_origin + current_camera_offset;
2451                         camera_offset = current_origin + camera_offset;
2452                 }
2453
2454                 camera_mode = CAMERA_FREE;
2455                 current_position = current_camera_offset;
2456         }
2457         else
2458         {
2459                 if ( camera_mode == CAMERA_FREE )
2460                 {
2461                         current_origin = view_origin;
2462                         camera_offset = camera_offset - current_origin;
2463                         current_camera_offset = current_camera_offset - current_origin;
2464                 }
2465
2466                 camera_mode = CAMERA_CHASE;
2467
2468                 if(autocvar_camera_chase_smoothly)
2469                         current_origin += (view_origin - current_origin) * attenuation;
2470                 else
2471                         current_origin = view_origin;
2472
2473                 current_position = current_origin + current_camera_offset;
2474         }
2475
2476         setproperty(VF_ANGLES, current_angles);
2477         setproperty(VF_ORIGIN, current_position);
2478 }