49b0d26d2765343eb7e917722a37906f70078a8f
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "autocvars.qh"
4 #include "miscfunctions.qh"
5 #include "announcer.qh"
6 #include "hud/_mod.qh"
7 #include "mapvoting.qh"
8 #include "shownames.qh"
9 #include "hud/panel/scoreboard.qh"
10 #include "hud/panel/quickmenu.qh"
11
12 #include <client/mutators/_mod.qh>
13
14 #include <common/animdecide.qh>
15 #include <common/deathtypes/all.qh>
16 #include <common/ent_cs.qh>
17 #include <common/anim.qh>
18 #include <common/constants.qh>
19 #include <common/net_linked.qh>
20 #include <common/net_notice.qh>
21 #include <common/debug.qh>
22 #include <common/mapinfo.qh>
23 #include <common/gamemodes/_mod.qh>
24 #include <common/physics/player.qh>
25 #include <common/stats.qh>
26 #include <common/mapobjects/target/music.qh>
27 #include <common/teams.qh>
28 #include <common/wepent.qh>
29
30 #include <common/weapons/weapon/tuba.qh>
31
32 #include <common/vehicles/all.qh>
33 #include <common/weapons/_all.qh>
34 #include <common/mutators/mutator/overkill/oknex.qh>
35 #include <common/mutators/mutator/waypoints/all.qh>
36 #include <common/viewloc.qh>
37 #include <common/mapobjects/trigger/viewloc.qh>
38 #include <common/minigames/cl_minigames.qh>
39 #include <common/minigames/cl_minigames_hud.qh>
40
41 #include <lib/csqcmodel/cl_player.qh>
42 #include <lib/csqcmodel/cl_model.qh>
43 #include "csqcmodel_hooks.qh"
44
45 #include <lib/warpzone/client.qh>
46 #include <lib/warpzone/common.qh>
47
48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
49
50 float autocvar_cl_viewmodel_scale;
51 float autocvar_cl_viewmodel_alpha;
52
53 bool autocvar_cl_bobmodel;
54 float autocvar_cl_bobmodel_speed;
55 float autocvar_cl_bobmodel_side;
56 float autocvar_cl_bobmodel_up;
57
58 float autocvar_cl_followmodel;
59 float autocvar_cl_followmodel_speed = 0.3;
60 float autocvar_cl_followmodel_limit = 135;
61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
62 float autocvar_cl_followmodel_highpass = 0.05;
63 float autocvar_cl_followmodel_lowpass = 0.03;
64 bool autocvar_cl_followmodel_velocity_absolute;
65
66 float autocvar_cl_leanmodel;
67 float autocvar_cl_leanmodel_speed = 0.3;
68 float autocvar_cl_leanmodel_limit = 30;
69 float autocvar_cl_leanmodel_highpass1 = 0.2;
70 float autocvar_cl_leanmodel_highpass = 0.2;
71 float autocvar_cl_leanmodel_lowpass = 0.05;
72
73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
74
75 #define lowpass(value, frac, ref_store, ret) \
76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
77
78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
81 MACRO_END
82
83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
84         float __f = 0; lowpass(value, frac, ref_store, __f); \
85         ret = (value) - __f; \
86 MACRO_END
87
88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
90         ret = (value) - __f; \
91 MACRO_END
92
93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
96 MACRO_END
97
98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
99         highpass(value.x, frac, ref_store.x, ref_out.x); \
100         highpass(value.y, frac, ref_store.y, ref_out.y); \
101 MACRO_END
102
103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
106 MACRO_END
107
108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
112 MACRO_END
113
114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
115         highpass(value.x, frac, ref_store.x, ref_out.x); \
116         highpass(value.y, frac, ref_store.y, ref_out.y); \
117         highpass(value.z, frac, ref_store.z, ref_out.z); \
118 MACRO_END
119
120 void calc_followmodel_ofs(entity view)
121 {
122         if(cl_followmodel_time == time)
123                 return; // cl_followmodel_ofs already calculated for this frame
124
125         float frac;
126         vector gunorg = '0 0 0';
127         static vector vel_average;
128         static vector gunorg_adjustment_highpass;
129         static vector gunorg_adjustment_lowpass;
130
131         vector vel;
132         if (autocvar_cl_followmodel_velocity_absolute)
133                 vel = view.velocity;
134         else
135         {
136                 vector forward, right, up;
137                 MAKE_VECTORS(view_angles, forward, right, up);
138                 vel.x = view.velocity * forward;
139                 vel.y = view.velocity * right * -1;
140                 vel.z = view.velocity * up;
141         }
142
143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
146
147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
148         lowpass3(vel, frac, vel_average, gunorg);
149
150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
151
152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
154         frac = avg_factor(autocvar_cl_followmodel_highpass);
155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
158
159         if (autocvar_cl_followmodel_velocity_absolute)
160         {
161                 vector fixed_gunorg;
162                 vector forward, right, up;
163                 MAKE_VECTORS(view_angles, forward, right, up);
164                 fixed_gunorg.x = gunorg * forward;
165                 fixed_gunorg.y = gunorg * right * -1;
166                 fixed_gunorg.z = gunorg * up;
167                 gunorg = fixed_gunorg;
168         }
169
170         cl_followmodel_ofs = gunorg;
171         cl_followmodel_time = time;
172 }
173
174 vector leanmodel_ofs(entity view)
175 {
176         float frac;
177         vector gunangles = '0 0 0';
178         static vector gunangles_prev = '0 0 0';
179         static vector gunangles_highpass = '0 0 0';
180         static vector gunangles_adjustment_highpass;
181         static vector gunangles_adjustment_lowpass;
182
183         if (view.csqcmodel_teleported)
184                 gunangles_prev = view_angles;
185
186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
187         gunangles_highpass += gunangles_prev;
188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
193         gunangles_prev = view_angles;
194         gunangles_highpass -= gunangles_prev;
195
196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
198
199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
204
205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
206
207         return gunangles;
208 }
209
210 vector bobmodel_ofs(entity view)
211 {
212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
213         static bool oldonground;
214         static float hitgroundtime;
215         if (clonground)
216         {
217                 float f = time; // cl.movecmd[0].time
218                 if (!oldonground)
219                         hitgroundtime = f;
220         }
221         oldonground = clonground;
222
223         // calculate for swinging gun model
224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
225         vector gunorg = '0 0 0';
226         static float bobmodel_scale = 0;
227         static float time_ofs = 0; // makes the effect always restart in the same way
228         if (clonground)
229         {
230                 if (time - hitgroundtime > 0.05)
231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
232         }
233         else
234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
235
236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
237         if (bobmodel_scale && xyspeed)
238         {
239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
243         }
244         else
245                 time_ofs = time;
246
247         return gunorg;
248 }
249
250 void viewmodel_animate(entity this)
251 {
252         if (autocvar_chase_active) return;
253         if (STAT(HEALTH) <= 0) return;
254
255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
256
257         if (autocvar_cl_followmodel)
258         {
259                 calc_followmodel_ofs(view);
260                 this.origin += cl_followmodel_ofs;
261         }
262
263         if (autocvar_cl_leanmodel)
264                 this.angles += leanmodel_ofs(view);
265
266         // vertical view bobbing code
267         // TODO: cl_bob
268
269         // horizontal view bobbing code
270         // TODO: cl_bob2
271
272         // fall bobbing code
273         // causes the view to swing down and back up when touching the ground
274         // TODO: cl_bobfall
275
276         // gun model bobbing code
277         if (autocvar_cl_bobmodel)
278                 this.origin += bobmodel_ofs(view);
279 }
280
281 .vector viewmodel_origin, viewmodel_angles;
282 .float weapon_nextthink;
283 .float weapon_eta_last;
284 .float weapon_switchdelay;
285
286 .string name_last;
287
288 void viewmodel_draw(entity this)
289 {
290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
291                 return;
292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
294         int wepskin = this.m_skin;
295         bool invehicle = player_localentnum > maxclients;
296         if (invehicle) a = -1;
297         Weapon wep = this.activeweapon;
298         int c = entcs_GetClientColors(current_player);
299         vector g = weaponentity_glowmod(wep, NULL, c, this);
300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
302                 | EF_NODEPTHTEST)
303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
304         for (entity e = this; e; e = e.weaponchild)
305         {
306                 e.drawmask = mask;
307                 e.alpha = a;
308                 e.skin = wepskin;
309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
310                 e.glowmod = g;
311                 e.csqcmodel_effects = fx;
312                 CSQCModel_Effects_Apply(e);
313         }
314         if(a >= 0)
315         {
316                 string name = wep.mdl;
317                 string newname = wep.wr_viewmodel(wep, this);
318                 if(newname)
319                         name = newname;
320                 bool swap = name != this.name_last;
321                 // if (swap)
322                 {
323                         this.name_last = name;
324                         CL_WeaponEntity_SetModel(this, name, swap);
325                         this.viewmodel_origin = this.origin;
326                         this.viewmodel_angles = this.angles;
327                 }
328                 anim_update(this);
329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
330                         anim_set(this, this.anim_idle, true, false, false);
331         }
332         float f = 0; // 0..1; 0: fully active
333         float rate = STAT(WEAPONRATEFACTOR);
334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
335         if (eta <= 0) f = this.weapon_eta_last;
336         else switch (this.state)
337         {
338                 case WS_RAISE:
339                 {
340                         f = eta / max(eta, this.weapon_switchdelay);
341                         break;
342                 }
343                 case WS_DROP:
344                 {
345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
346                         break;
347                 }
348                 case WS_CLEAR:
349                 {
350                         f = 1;
351                         break;
352                 }
353         }
354         this.weapon_eta_last = f;
355         this.origin = this.viewmodel_origin;
356         this.angles = this.viewmodel_angles;
357         this.angles_x = (-90 * f * f);
358         viewmodel_animate(this);
359         MUTATOR_CALLHOOK(DrawViewModel, this);
360         setorigin(this, this.origin);
361 }
362
363 STATIC_INIT(viewmodel) {
364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
365         viewmodels[slot] = new(viewmodel);
366 }
367
368 float showfps_prevfps;
369 float showfps_prevfps_time;
370 int showfps_framecounter;
371
372 void fpscounter_update()
373 {
374         if(!STAT(SHOWFPS))
375                 return;
376
377         float currentTime = gettime(GETTIME_REALTIME);
378         showfps_framecounter += 1;
379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
380         {
381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
382                 showfps_framecounter = 0;
383                 showfps_prevfps_time = currentTime;
384
385                 int channel = MSG_C2S;
386                 WriteHeader(channel, fpsreport);
387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
388         }
389 }
390
391 STATIC_INIT(fpscounter_init)
392 {
393         float currentTime = gettime(GETTIME_REALTIME);
394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
395 }
396
397 float drawtime;
398 float avgspeed;
399 vector GetCurrentFov(float fov)
400 {
401         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
402         float velocityzoom, curspeed;
403         vector v;
404
405         zoomsensitivity = autocvar_cl_zoomsensitivity;
406         zoomfactor = autocvar_cl_zoomfactor;
407         if(zoomfactor < 1 || zoomfactor > 30)
408                 zoomfactor = 2.5;
409         zoomspeed = autocvar_cl_zoomspeed;
410         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
411                 zoomspeed = 3.5;
412
413         zoomdir = button_zoom;
414
415         if(hud == HUD_NORMAL && !spectatee_status)
416         {
417                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
418                 {
419                         entity wepent = viewmodels[slot];
420                         if(wepent.switchweapon != wepent.activeweapon)
421                                 continue;
422                         Weapon wep = wepent.activeweapon;
423                         if(wep != WEP_Null && wep.wr_zoomdir)
424                         {
425                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
426                                 zoomdir += do_zoom;
427                         }
428                 }
429         }
430         if(spectatee_status > 0 || isdemo())
431         {
432                 if(spectatorbutton_zoom)
433                 {
434                         if(zoomdir)
435                                 zoomdir = 0;
436                         else
437                                 zoomdir = 1;
438                 }
439                 // fteqcc failed twice here already, don't optimize this
440         }
441
442         if(zoomdir) { zoomin_effect = 0; }
443
444         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
445         {
446                 current_viewzoom = 1;
447         }
448         else if (camera_active)
449         {
450                 current_viewzoom = min(1, current_viewzoom + drawframetime);
451         }
452         else if(autocvar_cl_spawnzoom && zoomin_effect)
453         {
454                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
455
456                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
457                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
458                 if(current_viewzoom == 1) { zoomin_effect = 0; }
459         }
460         else
461         {
462                 if(zoomspeed < 0) // instant zoom
463                 {
464                         if(zoomdir)
465                                 current_viewzoom = 1 / zoomfactor;
466                         else
467                                 current_viewzoom = 1;
468                 }
469                 else
470                 {
471                         if(zoomdir)
472                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
473                         else
474                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
475                 }
476         }
477
478         if(almost_equals(current_viewzoom, 1))
479                 current_zoomfraction = 0;
480         else if(almost_equals(current_viewzoom, 1/zoomfactor))
481                 current_zoomfraction = 1;
482         else
483                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
484
485         if(zoomsensitivity < 1)
486                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
487         else
488                 setsensitivityscale(1);
489
490         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
491         {
492                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
493                         curspeed = 0;
494                 else
495                 {
496                         vector forward, right, up;
497                         MAKE_VECTORS(view_angles, forward, right, up);
498                         v = pmove_vel;
499                         if(csqcplayer)
500                                 v = csqcplayer.velocity;
501
502                         switch(autocvar_cl_velocityzoom_type)
503                         {
504                                 case 3: curspeed = max(0, forward * v); break;
505                                 case 2: curspeed = (forward * v); break;
506                                 case 1: default: curspeed = vlen(v); break;
507                         }
508                 }
509
510                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
511                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
512                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
513
514                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
515         }
516         else
517                 velocityzoom = 1;
518
519         float frustumx, frustumy, fovx, fovy;
520         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
521         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
522         fovx = atan2(frustumx, 1) / M_PI * 360.0;
523         fovy = atan2(frustumy, 1) / M_PI * 360.0;
524
525         return '1 0 0' * fovx + '0 1 0' * fovy;
526 }
527
528 vector GetViewLocationFOV(float fov)
529 {
530         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
531         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
532         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
533         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
534         return '1 0 0' * fovx + '0 1 0' * fovy;
535 }
536
537 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
538 {
539         float fovx, fovy;
540         float width = (ov_worldmax.x - ov_worldmin.x);
541         float height = (ov_worldmax.y - ov_worldmin.y);
542         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
543         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
544         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
545         return '1 0 0' * fovx + '0 1 0' * fovy;
546 }
547
548 // this function must match W_SetupShot!
549 float zoomscript_caught;
550
551 bool minigame_wasactive;
552
553 vector wcross_origin;
554 float wcross_scale_prev, wcross_alpha_prev;
555 vector wcross_color_prev;
556 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
557 vector wcross_color_goal_prev;
558 float wcross_changedonetime;
559
560 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
561 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
562 float wcross_name_changestarttime, wcross_name_changedonetime;
563 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
564
565 float wcross_ring_prev;
566
567 entity trueaim;
568 entity trueaim_rifle;
569
570 const float SHOTTYPE_HITTEAM = 1;
571 const float SHOTTYPE_HITOBSTRUCTION = 2;
572 const float SHOTTYPE_HITWORLD = 3;
573 const float SHOTTYPE_HITENEMY = 4;
574
575 void TrueAim_Init()
576 {
577         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
578         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
579 }
580
581 float EnemyHitCheck()
582 {
583         float t, n;
584         wcross_origin = project_3d_to_2d(trace_endpos);
585         wcross_origin.z = 0;
586         if(trace_ent)
587                 n = trace_ent.entnum;
588         else
589                 n = trace_networkentity;
590         if(n < 1)
591                 return SHOTTYPE_HITWORLD;
592         if(n > maxclients)
593                 return SHOTTYPE_HITWORLD;
594         t = entcs_GetTeam(n - 1);
595         if(teamplay)
596                 if(t == myteam)
597                         return SHOTTYPE_HITTEAM;
598         if(t == NUM_SPECTATOR)
599                 return SHOTTYPE_HITWORLD;
600         return SHOTTYPE_HITENEMY;
601 }
602
603 float TrueAimCheck(entity wepent)
604 {
605         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
606                 return SHOTTYPE_HITWORLD;
607
608         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
609         vector vecs, trueaimpoint, w_shotorg;
610         vector mi, ma, dv;
611         float shottype;
612         entity ta;
613         float mv;
614
615         mi = ma = '0 0 0';
616         ta = trueaim;
617         mv = MOVE_NOMONSTERS;
618
619         switch(wepent.activeweapon) // WEAPONTODO
620         {
621                 case WEP_VORTEX:
622                 case WEP_OVERKILL_NEX:
623                 case WEP_VAPORIZER:
624                         mv = MOVE_NORMAL;
625                         break;
626                 case WEP_RIFLE:
627                         ta = trueaim_rifle;
628                         mv = MOVE_NORMAL;
629                         if(zoomscript_caught)
630                         {
631                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
632                                 return EnemyHitCheck();
633                         }
634                         break;
635                 case WEP_DEVASTATOR: // projectile has a size!
636                         mi = '-3 -3 -3';
637                         ma = '3 3 3';
638                         break;
639                 case WEP_FIREBALL: // projectile has a size!
640                         mi = '-16 -16 -16';
641                         ma = '16 16 16';
642                         break;
643                 case WEP_SEEKER: // projectile has a size!
644                         mi = '-2 -2 -2';
645                         ma = '2 2 2';
646                         break;
647                 case WEP_ELECTRO: // projectile has a size!
648                         mi = '0 0 -3';
649                         ma = '0 0 -3';
650                         break;
651         }
652
653         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
654
655         vecs = decompressShotOrigin(STAT(SHOTORG));
656
657         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
658         trueaimpoint = trace_endpos;
659
660         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
661                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
662
663         if(vecs.x > 0)
664                 vecs.y = -vecs.y;
665         else
666                 vecs = '0 0 0';
667
668         dv = view_right * vecs.y + view_up * vecs.z;
669         w_shotorg = traceorigin + dv;
670
671         // now move the vecs forward as much as requested if possible
672         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
673         w_shotorg = trace_endpos - view_forward * nudge;
674
675         if (mi == '0 0 0')
676                 traceline(w_shotorg, trueaimpoint, MOVE_NORMAL, ta);
677         else
678                 tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
679         shottype = EnemyHitCheck();
680         if(shottype != SHOTTYPE_HITWORLD)
681                 return shottype;
682
683 #if 0
684         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
685         // or rather, I know why, but see no fix
686         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
687                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
688                 return SHOTTYPE_HITOBSTRUCTION;
689 #endif
690
691         return SHOTTYPE_HITWORLD;
692 }
693
694 float camera_mode;
695 const float CAMERA_FREE = 1;
696 const float CAMERA_CHASE = 2;
697 float reticle_type;
698 string NextFrameCommand;
699
700 vector freeze_org, freeze_ang;
701 entity nightvision_noise, nightvision_noise2;
702
703 const float MAX_TIME_DIFF = 5;
704 float pickup_crosshair_time, pickup_crosshair_size;
705 float hitindication_crosshair_size;
706 float use_vortex_chargepool;
707
708 float myhealth, myhealth_prev;
709 float myhealth_flash;
710
711 float old_blurradius, old_bluralpha;
712 float old_sharpen_intensity;
713
714 vector myhealth_gentlergb;
715
716 float contentavgalpha, liquidalpha_prev;
717 vector liquidcolor_prev;
718
719 float eventchase_current_distance;
720 float eventchase_running;
721 int WantEventchase(entity this, bool want_vehiclechase)
722 {
723         if(autocvar_cl_orthoview)
724                 return 0;
725         if(STAT(GAME_STOPPED) || intermission)
726                 return 1;
727         if(this.viewloc)
728                 return 1;
729         if(spectatee_status >= 0)
730         {
731                 if(want_vehiclechase)
732                         return 1;
733                 if(MUTATOR_CALLHOOK(WantEventchase, this))
734                         return 1;
735                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
736                         return 1;
737                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
738                 {
739                         if(autocvar_cl_eventchase_death == 2)
740                         {
741                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
742                                 if(this.velocity == '0 0 0' || eventchase_running)
743                                         return 1;
744                         }
745                         else return 1;
746                 }
747                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
748                 {
749                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
750                                 return 1;
751                         else if (eventchase_running)
752                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
753                 }
754         }
755         return 0;
756 }
757
758 void HUD_Crosshair_Vehicle(entity this)
759 {
760         if(hud != HUD_BUMBLEBEE_GUN)
761         {
762                 Vehicle info = Vehicles_from(hud);
763                 info.vr_crosshair(info, this);
764         }
765 }
766
767 vector damage_blurpostprocess, content_blurpostprocess;
768
769 float unaccounted_damage = 0;
770 void UpdateDamage()
771 {
772         // accumulate damage with each stat update
773         static float damage_total_prev = 0;
774         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
775         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
776         damage_total_prev = damage_total;
777
778         static float damage_dealt_time_prev = 0;
779         float damage_dealt_time = STAT(HIT_TIME);
780         if (damage_dealt_time != damage_dealt_time_prev)
781         {
782                 unaccounted_damage += unaccounted_damage_new;
783                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
784         }
785         damage_dealt_time_prev = damage_dealt_time;
786
787         // prevent hitsound when switching spectatee
788         static float spectatee_status_prev = 0;
789         if (spectatee_status != spectatee_status_prev)
790                 unaccounted_damage = 0;
791         spectatee_status_prev = spectatee_status;
792 }
793
794 void HitSound()
795 {
796         // varying sound pitch
797
798         bool have_arc = false;
799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
800         {
801                 entity wepent = viewmodels[slot];
802
803                 if(wepent.activeweapon == WEP_ARC)
804                         have_arc = true;
805         }
806
807         static float hitsound_time_prev = 0;
808         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
809         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
810         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
811         {
812                 if (autocvar_cl_hitsound && unaccounted_damage)
813                 {
814                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
815                         float a = autocvar_cl_hitsound_max_pitch;
816                         float b = autocvar_cl_hitsound_min_pitch;
817                         float c = autocvar_cl_hitsound_nom_damage;
818                         float d = unaccounted_damage;
819                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
820
821                         // if sound variation is disabled, set pitch_shift to 1
822                         if (autocvar_cl_hitsound == 1)
823                                 pitch_shift = 1;
824
825                         // if pitch shift is reversed, mirror in (max-min)/2 + min
826                         if (autocvar_cl_hitsound == 3)
827                         {
828                                 float mirror_value = (a-b)/2 + b;
829                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
830                         }
831
832                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
833
834                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
835                         // todo: normalize sound pressure levels? seems unnecessary
836
837                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
838                 }
839                 unaccounted_damage = 0;
840                 hitsound_time_prev = time;
841         }
842
843         static float typehit_time_prev = 0;
844         float typehit_time = STAT(TYPEHIT_TIME);
845         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
846         {
847                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
848                 typehit_time_prev = typehit_time;
849         }
850
851         static float kill_time_prev = 0;
852         float kill_time = STAT(KILL_TIME);
853         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
854         {
855                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
856                 kill_time_prev = kill_time;
857         }
858 }
859
860 vector crosshair_getcolor(entity this, float health_stat)
861 {
862         static float rainbow_last_flicker;
863         static vector rainbow_prev_color;
864         vector wcross_color = '0 0 0';
865         switch(autocvar_crosshair_color_special)
866         {
867                 case 1: // crosshair_color_per_weapon
868                 {
869                         if(this != WEP_Null && hud == HUD_NORMAL)
870                         {
871                                 wcross_color = this.wpcolor;
872                                 break;
873                         }
874                         else { goto normalcolor; }
875                 }
876
877                 case 2: // crosshair_color_by_health
878                 {
879                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
880                         float hp = floor(v.x + 1);
881
882                         //x = red
883                         //y = green
884                         //z = blue
885
886                         wcross_color.z = 0;
887
888                         if(hp > 200)
889                         {
890                                 wcross_color.x = 0;
891                                 wcross_color.y = 1;
892                         }
893                         else if(hp > 150)
894                         {
895                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
896                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
897                         }
898                         else if(hp > 100)
899                         {
900                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
901                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
902                                 wcross_color.z = 1 - (hp-100)*0.02;
903                         }
904                         else if(hp > 50)
905                         {
906                                 wcross_color.x = 1;
907                                 wcross_color.y = 1;
908                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
909                         }
910                         else if(hp > 20)
911                         {
912                                 wcross_color.x = 1;
913                                 wcross_color.y = (hp-20)*90/27/100;
914                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
915                         }
916                         else
917                         {
918                                 wcross_color.x = 1;
919                                 wcross_color.y = 0;
920                         }
921                         break;
922                 }
923
924                 case 3: // crosshair_color_rainbow
925                 {
926                         if(time >= rainbow_last_flicker)
927                         {
928                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
929                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
930                         }
931                         wcross_color = rainbow_prev_color;
932                         break;
933                 }
934 LABEL(normalcolor)
935                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
936         }
937
938         return wcross_color;
939 }
940
941 void HUD_Crosshair(entity this)
942 {
943         float f, i, j;
944         vector v;
945         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
946                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
947                 !HUD_MinigameMenu_IsOpened() )
948         {
949                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
950                         return;
951
952                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
953                         return;
954
955                 if (hud != HUD_NORMAL)
956                 {
957                         HUD_Crosshair_Vehicle(this);
958                         return;
959                 }
960
961                 string wcross_style;
962                 float wcross_alpha, wcross_resolution;
963                 wcross_style = autocvar_crosshair;
964                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
965                         wcross_style = autocvar_crosshair_2d;
966                 if (wcross_style == "0")
967                         return;
968                 wcross_resolution = autocvar_crosshair_size;
969                 if (wcross_resolution == 0)
970                         return;
971                 wcross_alpha = autocvar_crosshair_alpha;
972                 if (wcross_alpha == 0)
973                         return;
974
975                 // TrueAim check
976                 float shottype;
977
978                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
979                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
980                         wcross_origin = viewloc_mousepos;
981                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
982                 {
983                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
984                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
985                         {
986                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
987                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
988                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
989                                         csqcplayer.alpha = min(crosshair_chase_playeralpha, myalpha);
990                                 else
991                                         csqcplayer.alpha = csqcplayer.m_alpha;
992                         }
993                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
994                         wcross_origin = project_3d_to_2d(trace_endpos);
995                 }
996                 else
997                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
998                 wcross_origin.z = 0;
999                 if(autocvar_crosshair_hittest)
1000                 {
1001                         vector wcross_oldorigin;
1002                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1003                         wcross_oldorigin = wcross_origin;
1004                         shottype = TrueAimCheck(thiswep);
1005                         if(shottype == SHOTTYPE_HITWORLD)
1006                         {
1007                                 v = wcross_origin - wcross_oldorigin;
1008                                 v.x /= vid_conwidth;
1009                                 v.y /= vid_conheight;
1010                                 if(vdist(v, >, 0.01))
1011                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1012                         }
1013                         if(!autocvar_crosshair_hittest_showimpact)
1014                                 wcross_origin = wcross_oldorigin;
1015                 }
1016                 else
1017                         shottype = SHOTTYPE_HITWORLD;
1018
1019                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1020                 string wcross_name = "";
1021                 float wcross_scale, wcross_blur;
1022
1023         entity e = WEP_Null;
1024                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1025                 {
1026                         entity wepent = viewmodels[0]; // TODO: unhardcode
1027                         e = wepent.switchingweapon;
1028                         if(e)
1029                         {
1030                                 if(autocvar_crosshair_per_weapon)
1031                                 {
1032                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1033                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1034                                         //if (wcross_resolution == 0)
1035                                                 //return;
1036
1037                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1038                                         wcross_resolution *= e.w_crosshair_size;
1039                                         wcross_name = e.w_crosshair;
1040                                 }
1041                         }
1042                 }
1043
1044                 if(wcross_name == "")
1045                         wcross_name = strcat("gfx/crosshair", wcross_style);
1046
1047                 // MAIN CROSSHAIR COLOR DECISION
1048                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1049
1050                 if(autocvar_crosshair_effect_scalefade)
1051                 {
1052                         wcross_scale = wcross_resolution;
1053                         wcross_resolution = 1;
1054                 }
1055                 else
1056                 {
1057                         wcross_scale = 1;
1058                 }
1059
1060                 if(autocvar_crosshair_pickup)
1061                 {
1062                         float stat_pickup_time = STAT(LAST_PICKUP);
1063
1064                         if(pickup_crosshair_time < stat_pickup_time)
1065                         {
1066                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1067                                         pickup_crosshair_size = 1;
1068
1069                                 pickup_crosshair_time = stat_pickup_time;
1070                         }
1071
1072                         if(pickup_crosshair_size > 0)
1073                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1074                         else
1075                                 pickup_crosshair_size = 0;
1076
1077                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1078                 }
1079
1080                 // todo: make crosshair hit indication dependent on damage dealt
1081                 if(autocvar_crosshair_hitindication)
1082                 {
1083                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1084
1085                         if(unaccounted_damage)
1086                         {
1087                                 hitindication_crosshair_size = 1;
1088                         }
1089
1090                         if(hitindication_crosshair_size > 0)
1091                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1092                         else
1093                                 hitindication_crosshair_size = 0;
1094
1095                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1096                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1097                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1098                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1099                 }
1100
1101                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1102                 // just show for teammates to give a sign that they're an invalid target
1103                 //if(shottype == SHOTTYPE_HITENEMY)
1104                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1105                 if(shottype == SHOTTYPE_HITTEAM)
1106                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1107
1108                 f = fabs(autocvar_crosshair_effect_time);
1109                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1110                 {
1111                         wcross_changedonetime = time + f;
1112                 }
1113                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1114                 {
1115                         wcross_name_changestarttime = time;
1116                         wcross_name_changedonetime = time + f;
1117                         if(wcross_name_goal_prev_prev)
1118                                 strunzone(wcross_name_goal_prev_prev);
1119                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1120                         wcross_name_goal_prev = strzone(wcross_name);
1121                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1122                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1123                         wcross_resolution_goal_prev = wcross_resolution;
1124                 }
1125
1126                 wcross_scale_goal_prev = wcross_scale;
1127                 wcross_alpha_goal_prev = wcross_alpha;
1128                 wcross_color_goal_prev = wcross_color;
1129
1130                 if(spectatee_status == 0 && (shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active)))
1131                 {
1132                         wcross_blur = 1;
1133                         wcross_alpha *= 0.75;
1134                 }
1135                 else
1136                         wcross_blur = 0;
1137                 // *_prev is at time-frametime
1138                 // * is at wcross_changedonetime+f
1139                 // what do we have at time?
1140                 if(time < wcross_changedonetime)
1141                 {
1142                         f = frametime / (wcross_changedonetime - time + frametime);
1143                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1144                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1145                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1146                 }
1147
1148                 wcross_scale_prev = wcross_scale;
1149                 wcross_alpha_prev = wcross_alpha;
1150                 wcross_color_prev = wcross_color;
1151
1152                 MUTATOR_CALLHOOK(UpdateCrosshair);
1153
1154                 wcross_scale *= 1 - autocvar__menu_alpha;
1155                 wcross_alpha *= 1 - autocvar__menu_alpha;
1156                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1157
1158                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1159                 {
1160                         // crosshair rings for weapon stats
1161                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1162                         {
1163                                 // declarations and stats
1164                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1165                                 string ring_image = string_null, ring_inner_image = string_null;
1166                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1167
1168                                 ring_scale = autocvar_crosshair_ring_size;
1169
1170                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1171
1172                                 int weapon_clipload = wepent.clip_load;
1173                                 int weapon_clipsize = wepent.clip_size;
1174
1175                                 float arc_heat = wepent.arc_heat_percent;
1176                                 float vcharge = wepent.vortex_charge;
1177                                 float vchargepool = wepent.vortex_chargepool_ammo;
1178                                 float oknex_charge_ = wepent.oknex_charge;
1179                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1180
1181                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1182                                         vortex_charge_movingavg = vcharge;
1183
1184                                 // handle the values
1185                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1186                                 {
1187                                         if (vchargepool || use_vortex_chargepool) {
1188                                                 use_vortex_chargepool = 1;
1189                                                 ring_inner_value = vchargepool;
1190                                         } else {
1191                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1192                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1193                                         }
1194
1195                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1196                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1197                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1198
1199                                         // draw the outer ring to show the current charge of the weapon
1200                                         ring_value = vcharge;
1201                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1204                                 }
1205                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1206                                 {
1207                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1208                                                 use_vortex_chargepool = 1;
1209                                                 ring_inner_value = oknex_chargepool_;
1210                                         } else {
1211                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1212                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1213                                         }
1214
1215                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1216                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1217                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1218
1219                                         // draw the outer ring to show the current charge of the weapon
1220                                         ring_value = oknex_charge_;
1221                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1222                                         ring_rgb = wcross_color;
1223                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1224                                 }
1225                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1226                                 {
1227                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1228                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1229                                         ring_rgb = wcross_color;
1230                                         ring_image = "gfx/crosshair_ring.tga";
1231                                 }
1232                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1233                                 {
1234                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1235                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1236                                         ring_rgb = wcross_color;
1237                                         ring_image = "gfx/crosshair_ring.tga";
1238                                 }
1239                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1240                                 {
1241                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1242                                         ring_scale = autocvar_crosshair_ring_reload_size;
1243                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1244                                         ring_rgb = wcross_color;
1245
1246                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1247                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1248                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1249                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1250                                         else
1251                                                 ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1254                                 {
1255                                         ring_value = arc_heat;
1256                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1257                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1258                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1259                                         ring_image = "gfx/crosshair_ring.tga";
1260                                 }
1261
1262                                 // if in weapon switch animation, fade ring out/in
1263                                 if(autocvar_crosshair_effect_time > 0)
1264                                 {
1265                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1266                                         if (f >= 1)
1267                                         {
1268                                                 wcross_ring_prev = ((ring_image) ? true : false);
1269                                         }
1270
1271                                         if(wcross_ring_prev)
1272                                         {
1273                                                 if(f < 1)
1274                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1275                                         }
1276                                         else
1277                                         {
1278                                                 if(f < 1)
1279                                                         ring_alpha *= bound(0, f, 1);
1280                                         }
1281                                 }
1282
1283                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1284                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1285
1286                                 if (ring_value)
1287                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1288                         }
1289
1290 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1291                         MACRO_BEGIN \
1292                                 vector scaled_sz = sz * wcross_size; \
1293                                 if(wcross_blur > 0) \
1294                                 { \
1295                                         for(i = -2; i <= 2; ++i) \
1296                                         for(j = -2; j <= 2; ++j) \
1297                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1298                                 } \
1299                                 else \
1300                                 { \
1301                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1302                                 } \
1303                         MACRO_END
1304
1305 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1306                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1307
1308 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1309                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1310
1311                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1312                         {
1313                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1314                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1315                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1316                                 f = 1 - f;
1317                         }
1318                         else
1319                         {
1320                                 f = 1;
1321                         }
1322                         wcross_name_alpha_goal_prev = f;
1323
1324                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1325                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1326
1327                         if(autocvar_crosshair_dot)
1328                         {
1329                                 vector wcross_color_old;
1330                                 wcross_color_old = wcross_color;
1331
1332                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1333                                         wcross_color = stov(autocvar_crosshair_dot_color);
1334
1335                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1336                                 // FIXME why don't we use wcross_alpha here?
1337                                 wcross_color = wcross_color_old;
1338                         }
1339                 }
1340         }
1341         else
1342         {
1343                 wcross_scale_prev = 0;
1344                 wcross_alpha_prev = 0;
1345                 wcross_scale_goal_prev = 0;
1346                 wcross_alpha_goal_prev = 0;
1347                 wcross_changedonetime = 0;
1348                 strfree(wcross_name_goal_prev);
1349                 strfree(wcross_name_goal_prev_prev);
1350                 wcross_name_changestarttime = 0;
1351                 wcross_name_changedonetime = 0;
1352                 wcross_name_alpha_goal_prev = 0;
1353                 wcross_name_alpha_goal_prev_prev = 0;
1354                 wcross_resolution_goal_prev = 0;
1355                 wcross_resolution_goal_prev_prev = 0;
1356         }
1357 }
1358
1359 const int MAX_SPECIALCOMMAND = 15;
1360 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1361 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1362 const float SPECIALCOMMAND_SPEED = 150;
1363 const float SPECIALCOMMAND_TURNSPEED = 2;
1364 const float SPECIALCOMMAND_SIZE = 0.025;
1365 const float SPECIALCOMMAND_CHANCE = 0.35;
1366 float sc_spawntime, sc_changetime;
1367 vector sc_color = '1 1 1';
1368 void SpecialCommand()
1369 {
1370         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1371                 return;
1372
1373         if(time >= sc_changetime)
1374         {
1375                 sc_changetime = time + 1;
1376                 sc_color = randomvec() * 1.5;
1377                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1378                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1379                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1380         }
1381         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1382
1383         if(!precache_pic("gfx/smile"))
1384                 return; // damn party poopers
1385
1386         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1387         {
1388                 vector slot = specialcommand_slots[j];
1389                 if(slot.y)
1390                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1391                 //if(slot.z)
1392                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1393                 if(slot.y >= vid_conheight)
1394                         slot = '0 0 0';
1395
1396                 if(slot == '0 0 0')
1397                 {
1398                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1399                         {
1400                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1401                                 slot.y = 1; // start it off 0 so we can use it
1402                                 slot.z = floor(random() * Weapons_MAX);
1403                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1404                                 vector newcolor = randomvec() * 2;
1405                                 newcolor.x = bound(0.4, newcolor.x, 1);
1406                                 newcolor.y = bound(0.4, newcolor.y, 1);
1407                                 newcolor.z = bound(0.4, newcolor.z, 1);
1408                                 specialcommand_colors[j] = newcolor;
1409                         }
1410                 }
1411                 else
1412                 {
1413                         vector splash_size = '0 0 0';
1414                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1415                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1416                         entity wep = Weapons_from(slot.z);
1417                         if(wep == WEP_Null)
1418                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1419                         else
1420                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1421                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1422                 }
1423
1424                 specialcommand_slots[j] = slot;
1425         }
1426 }
1427
1428 void HUD_Draw(entity this)
1429 {
1430         // if we don't know gametype and scores yet avoid drawing the scoreboard
1431         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1432         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1433         // cl_deathscoreboard would show the scoreboard and so on
1434         if(!gametype)
1435                 return;
1436
1437         Hud_Dynamic_Frame();
1438
1439         if(!intermission)
1440         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1441         {
1442                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1443         }
1444         else if(STAT(FROZEN))
1445         {
1446                 vector col = '0.25 0.90 1';
1447                 if(STAT(REVIVE_PROGRESS))
1448                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1449                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1450         }
1451
1452         HUD_Scale_Enable();
1453         if(!intermission)
1454         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1455         {
1456                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1457                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1458                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1459         }
1460         else if(STAT(CAPTURE_PROGRESS))
1461         {
1462                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1463                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1464         }
1465         else if(STAT(REVIVE_PROGRESS))
1466         {
1467                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1468                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1469         }
1470         HUD_Scale_Disable();
1471
1472         if(autocvar_r_letterbox == 0)
1473                 if(autocvar_viewsize < 120)
1474                 {
1475                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1476                                 Accuracy_LoadLevels();
1477
1478                         HUD_Main();
1479                         HUD_Scale_Disable();
1480                 }
1481
1482         // crosshair goes VERY LAST
1483         SpecialCommand();
1484         UpdateDamage();
1485         HUD_Crosshair(this);
1486         HitSound();
1487 }
1488
1489 void ViewLocation_Mouse()
1490 {
1491         if(spectatee_status)
1492                 return; // don't draw it as spectator!
1493
1494         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1495         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1496         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1497
1498         //float cursor_alpha = 1 - autocvar__menu_alpha;
1499         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1500 }
1501
1502 void HUD_Cursor_Show()
1503 {
1504         float cursor_alpha = 1 - autocvar__menu_alpha;
1505         if(cursor_type == CURSOR_NORMAL)
1506                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1507         else if(cursor_type == CURSOR_MOVE)
1508                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1509         else if(cursor_type == CURSOR_RESIZE)
1510                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1511         else if(cursor_type == CURSOR_RESIZE2)
1512                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1513 }
1514
1515 void HUD_Mouse(entity player)
1516 {
1517         if(autocvar__menu_alpha == 1)
1518                 return;
1519
1520         if(!cursor_active)
1521         {
1522                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1523                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1524                 return;
1525         }
1526
1527         if (cursor_active == -1) // starting to display the cursor
1528         {
1529                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1530                 // in the first frame mousepos is the mouse position of the last time
1531                 // the cursor was displayed, thus we ignore it to avoid a glictch
1532                 cursor_active = 1;
1533                 return;
1534         }
1535
1536         if(!autocvar_hud_cursormode)
1537                 update_mousepos();
1538
1539         if(autocvar__hud_configure)
1540                 HUD_Panel_Mouse();
1541         else
1542         {
1543                 if (HUD_MinigameMenu_IsOpened())
1544                         HUD_Minigame_Mouse();
1545                 if (QuickMenu_IsOpened())
1546                         QuickMenu_Mouse();
1547                 if (HUD_Radar_Clickable())
1548                         HUD_Radar_Mouse();
1549         }
1550
1551         prevMouseClicked = mouseClicked;
1552
1553         HUD_Cursor_Show();
1554 }
1555
1556 bool ov_enabled;
1557 float oldr_nearclip;
1558 float oldr_farclip_base;
1559 float oldr_farclip_world;
1560 float oldr_novis;
1561 float oldr_useportalculling;
1562 float oldr_useinfinitefarclip;
1563
1564 float prev_myteam;
1565 int lasthud;
1566 float vh_notice_time;
1567 void CSQC_UpdateView(entity this, float w, float h)
1568 {
1569         TC(int, w); TC(int, h);
1570         entity e;
1571         float fov;
1572         float f;
1573         vector vf_size, vf_min;
1574         float a;
1575
1576         execute_next_frame();
1577
1578         ++framecount;
1579
1580         stats_get();
1581         hud = STAT(HUD);
1582
1583         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1584                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1585
1586         lasthud = hud;
1587
1588         ReplicateVars(false);
1589         if (ReplicateVars_NOT_SENDING())
1590                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1591
1592         HUD_Scale_Disable();
1593
1594         if(autocvar__hud_showbinds_reload) // menu can set this one
1595         {
1596                 db_close(binddb);
1597                 binddb = db_create();
1598                 cvar_set("_hud_showbinds_reload", "0");
1599         }
1600
1601         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1602                 view_quality = getproperty(VF_MINFPS_QUALITY);
1603         else
1604                 view_quality = 1;
1605
1606         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1607         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1608
1609         vf_size = getpropertyvec(VF_SIZE);
1610         vf_min = getpropertyvec(VF_MIN);
1611         vid_width = vf_size.x;
1612         vid_height = vf_size.y;
1613
1614         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1615         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1616
1617         WaypointSprite_Load();
1618
1619         CSQCPlayer_SetCamera();
1620
1621         if(player_localentnum <= maxclients) // is it a client?
1622                 current_player = player_localentnum - 1;
1623         else // then player_localentnum is the vehicle I'm driving
1624                 current_player = player_localnum;
1625         myteam = entcs_GetTeam(current_player);
1626
1627         if(myteam != prev_myteam)
1628         {
1629                 myteamcolors = colormapPaletteColor(myteam, 1);
1630                 FOREACH(hud_panels, true, it.update_time = time);
1631                 prev_myteam = myteam;
1632         }
1633
1634         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1635
1636         float is_dead = (STAT(HEALTH) <= 0);
1637
1638         // FIXME do we need this hack?
1639         if(isdemo())
1640         {
1641                 // in demos, input_buttons do not work
1642                 button_zoom = (autocvar__togglezoom == "-");
1643         }
1644         else if(button_zoom
1645                 && autocvar_cl_unpress_zoom_on_death
1646                 && (spectatee_status >= 0)
1647                 && (is_dead || intermission))
1648         {
1649                 // no zoom while dead or in intermission please
1650                 localcmd("-zoom\n");
1651                 button_zoom = false;
1652         }
1653
1654         // abused multiple places below
1655         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1656         if(!local_player)
1657                 local_player = this; // fall back!
1658
1659         // event chase camera
1660         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1661         {
1662                 if(STAT(CAMERA_SPECTATOR))
1663                 {
1664                         if(spectatee_status > 0)
1665                         {
1666                                 if(!autocvar_chase_active)
1667                                 {
1668                                         cvar_set("chase_active", "-2");
1669                                         goto skip_eventchase_death;
1670                                 }
1671                         }
1672                         else if(autocvar_chase_active == -2)
1673                                 cvar_set("chase_active", "0");
1674
1675                         if(autocvar_chase_active == -2)
1676                                 goto skip_eventchase_death;
1677                 }
1678                 else if(autocvar_chase_active == -2)
1679                         cvar_set("chase_active", "0");
1680
1681                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1682
1683                 float vehicle_viewdist = 0;
1684                 vector vehicle_viewofs = '0 0 0';
1685
1686                 if(vehicle_chase)
1687                 {
1688                         if(hud != HUD_BUMBLEBEE_GUN)
1689                         {
1690                                 Vehicle info = Vehicles_from(hud);
1691                                 vehicle_viewdist = info.height;
1692                                 vehicle_viewofs = info.view_ofs;
1693                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
1694                                         vehicle_chase = false;
1695                         }
1696                         else
1697                                 vehicle_chase = false;
1698                 }
1699
1700                 int eventchase = WantEventchase(this, vehicle_chase);
1701                 if (eventchase)
1702                 {
1703                         vector current_view_origin_override = '0 0 0';
1704                         vector view_offset_override = '0 0 0';
1705                         float chase_distance_override = 0;
1706                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1707                         if(custom_eventchase)
1708                         {
1709                                 current_view_origin_override = M_ARGV(0, vector);
1710                                 view_offset_override = M_ARGV(1, vector);
1711                                 chase_distance_override = M_ARGV(0, float);
1712                         }
1713                         eventchase_running = true;
1714
1715                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1716                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1717                         if (custom_eventchase)
1718                                 current_view_origin = current_view_origin_override;
1719
1720                         // detect maximum viewoffset and use it
1721                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1722                         if(vehicle_chase)
1723                         {
1724                                 if(vehicle_viewofs)
1725                                         view_offset = vehicle_viewofs;
1726                                 else
1727                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1728                         }
1729                         if (custom_eventchase)
1730                                 view_offset = view_offset_override;
1731
1732                         if(view_offset)
1733                         {
1734                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1735                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1736                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1737                         }
1738
1739                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1740                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1741                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1742                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1743
1744                         // make the camera smooth back
1745                         float chase_distance = autocvar_cl_eventchase_distance;
1746                         if(vehicle_chase)
1747                         {
1748                                 if(vehicle_viewofs)
1749                                         chase_distance = vehicle_viewdist;
1750                                 else
1751                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1752                         }
1753                         if (custom_eventchase)
1754                                 chase_distance = chase_distance_override;
1755
1756                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1757                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1758                         else if(eventchase_current_distance != chase_distance)
1759                                 eventchase_current_distance = chase_distance;
1760
1761                         vector forward, right, up;
1762                         MAKE_VECTORS(view_angles, forward, right, up);
1763
1764                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1765                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1766
1767                         // If the boxtrace fails, revert back to line tracing.
1768                         if(!local_player.viewloc)
1769                         if(trace_startsolid)
1770                         {
1771                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1772                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1773                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1774                         }
1775                         else { setproperty(VF_ORIGIN, trace_endpos); }
1776
1777                         if(!local_player.viewloc)
1778                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1779                 }
1780
1781                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1782                 {
1783                         eventchase_running = false;
1784                         cvar_set("chase_active", "0");
1785                         eventchase_current_distance = 0; // start from 0 next time
1786                 }
1787         }
1788         // workaround for camera stuck between player's legs when using chase_active 1
1789         // because the engine stops updating the chase_active camera when the game ends
1790         else if(intermission)
1791         {
1792                 cvar_settemp("chase_active", "-1");
1793                 eventchase_current_distance = 0;
1794         }
1795
1796         LABEL(skip_eventchase_death);
1797
1798         // do lockview after event chase camera so that it still applies whenever necessary.
1799         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1800         {
1801                 setproperty(VF_ORIGIN, freeze_org);
1802                 setproperty(VF_ANGLES, freeze_ang);
1803         }
1804         else
1805         {
1806                 freeze_org = getpropertyvec(VF_ORIGIN);
1807                 freeze_ang = getpropertyvec(VF_ANGLES);
1808         }
1809
1810         WarpZone_FixView();
1811         //WarpZone_FixPMove();
1812
1813         vector ov_org = '0 0 0';
1814         vector ov_mid = '0 0 0';
1815         vector ov_worldmin = '0 0 0';
1816         vector ov_worldmax = '0 0 0';
1817         if(autocvar_cl_orthoview)
1818         {
1819                 ov_worldmin = mi_picmin;
1820                 ov_worldmax = mi_picmax;
1821
1822                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1823                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1824                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1825
1826                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1827                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1828
1829                 float ov_nearest = vlen(ov_org - vec3(
1830                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1831                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1832                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1833                 ));
1834
1835                 float ov_furthest = 0;
1836                 float dist = 0;
1837
1838                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1840                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1841                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1842                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1843                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1844                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1845                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1846
1847                 if(!ov_enabled)
1848                 {
1849                         oldr_nearclip = cvar("r_nearclip");
1850                         oldr_farclip_base = cvar("r_farclip_base");
1851                         oldr_farclip_world = cvar("r_farclip_world");
1852                         oldr_novis = cvar("r_novis");
1853                         oldr_useportalculling = cvar("r_useportalculling");
1854                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1855                 }
1856
1857                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1858                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1859                 cvar_settemp("r_farclip_world", "0");
1860                 cvar_settemp("r_novis", "1");
1861                 cvar_settemp("r_useportalculling", "0");
1862                 cvar_settemp("r_useinfinitefarclip", "0");
1863
1864                 setproperty(VF_ORIGIN, ov_org);
1865                 setproperty(VF_ANGLES, '90 0 0');
1866
1867                 ov_enabled = true;
1868
1869                 #if 0
1870                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1871                         vtos(ov_org),
1872                         vtos(getpropertyvec(VF_ANGLES)),
1873                         ov_distance,
1874                         ov_nearest,
1875                         ov_furthest);
1876                 #endif
1877         }
1878         else
1879         {
1880                 if(ov_enabled)
1881                 {
1882                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1883                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1884                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1885                         cvar_set("r_novis", ftos(oldr_novis));
1886                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1887                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1888                 }
1889                 ov_enabled = false;
1890         }
1891
1892         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1893         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1894         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1895                 viewmodel_draw(viewmodels[slot]);
1896
1897         // Render the Scene
1898         view_origin = getpropertyvec(VF_ORIGIN);
1899         view_angles = getpropertyvec(VF_ANGLES);
1900         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1901
1902 #ifdef BLURTEST
1903         if(time > blurtest_time0 && time < blurtest_time1)
1904         {
1905                 float r, t;
1906
1907                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1908                 r = t * blurtest_radius;
1909                 f = 1 / (t ** blurtest_power) - 1;
1910
1911                 cvar_set("r_glsl_postprocess", "1");
1912                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1913         }
1914         else
1915         {
1916                 cvar_set("r_glsl_postprocess", "0");
1917                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1918         }
1919 #endif
1920
1921         TargetMusic_Advance();
1922         Fog_Force();
1923         fpscounter_update();
1924
1925         if(drawtime == 0)
1926                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1927         else
1928                 drawframetime = bound(0.000001, time - drawtime, 1);
1929         drawtime = time;
1930
1931         // watch for gametype changes here...
1932         // in ParseStuffCMD the cmd isn't executed yet :/
1933         // might even be better to add the gametype to TE_CSQC_INIT...?
1934         if(!postinit)
1935                 PostInit();
1936
1937         if(intermission && !intermission_time)
1938                 intermission_time = time;
1939
1940         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1941         {
1942                 if(calledhooks & HOOK_START)
1943                 {
1944                         localcmd("\ncl_hook_gameend\n");
1945                         calledhooks |= HOOK_END;
1946                 }
1947         }
1948
1949         Announcer();
1950
1951         fov = autocvar_fov;
1952         if(fov <= 59.5)
1953         {
1954                 if(!zoomscript_caught)
1955                 {
1956                         localcmd("+button9\n");
1957                         zoomscript_caught = 1;
1958                 }
1959         }
1960         else
1961         {
1962                 if(zoomscript_caught)
1963                 {
1964                         localcmd("-button9\n");
1965                         zoomscript_caught = 0;
1966                 }
1967         }
1968
1969         if(active_minigame && HUD_MinigameMenu_IsOpened())
1970         {
1971                 if(!minigame_wasactive)
1972                 {
1973                         localcmd("+button12\n");
1974                         minigame_wasactive = true;
1975                 }
1976         }
1977         else if(minigame_wasactive)
1978         {
1979                 localcmd("-button12\n");
1980                 minigame_wasactive = false;
1981         }
1982
1983         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1984
1985         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1986         {
1987                 entity wepent = viewmodels[slot];
1988
1989                 if(wepent.last_switchweapon != wepent.switchweapon)
1990                 {
1991                         weapontime = time;
1992                         wepent.last_switchweapon = wepent.switchweapon;
1993                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1994                         {
1995                                 localcmd("-zoom\n");
1996                                 button_zoom = false;
1997                         }
1998                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1999                         {
2000                                 localcmd("-fire\n");
2001                                 localcmd("-fire2\n");
2002                                 button_attack2 = false;
2003                         }
2004                 }
2005                 if(wepent.last_activeweapon != wepent.activeweapon)
2006                 {
2007                         wepent.last_activeweapon = wepent.activeweapon;
2008
2009                         e = wepent.activeweapon;
2010                         if(e.netname != "")
2011                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2012                         else if(slot == 0)
2013                                 localcmd("\ncl_hook_activeweapon none\n");
2014                 }
2015         }
2016
2017         // ALWAYS Clear Current Scene First
2018         clearscene();
2019
2020         setproperty(VF_ORIGIN, view_origin);
2021         setproperty(VF_ANGLES, view_angles);
2022
2023         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2024         setproperty(VF_SIZE, vf_size);
2025         setproperty(VF_MIN, vf_min);
2026
2027         // Assign Standard Viewflags
2028         // Draw the World (and sky)
2029         setproperty(VF_DRAWWORLD, 1);
2030
2031         // Set the console size vars
2032         vid_conwidth = autocvar_vid_conwidth;
2033         vid_conheight = autocvar_vid_conheight;
2034         vid_pixelheight = autocvar_vid_pixelheight;
2035
2036         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2037         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2038         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2039
2040         if(camera_active) // Camera for demo playback
2041         {
2042                 if(autocvar_camera_enable)
2043                         CSQC_Demo_Camera();
2044                 else
2045                 {
2046                         cvar_set("chase_active", ftos(chase_active_backup));
2047                         cvar_set("cl_demo_mousegrab", "0");
2048                         camera_active = false;
2049                 }
2050         }
2051         else
2052         {
2053 #ifdef CAMERATEST
2054                 if(autocvar_camera_enable)
2055 #else
2056                 if(autocvar_camera_enable && isdemo())
2057 #endif
2058                 {
2059                         // Enable required Darkplaces cvars
2060                         chase_active_backup = autocvar_chase_active;
2061                         cvar_set("chase_active", "2");
2062                         cvar_set("cl_demo_mousegrab", "1");
2063                         camera_active = true;
2064                         camera_mode = false;
2065                 }
2066         }
2067
2068         // Draw the Crosshair
2069         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2070
2071         // Draw the Engine Status Bar (the default Quake HUD)
2072         setproperty(VF_DRAWENGINESBAR, 0);
2073
2074         // Update the mouse position
2075         /*
2076            mousepos_x = vid_conwidth;
2077            mousepos_y = vid_conheight;
2078            mousepos = mousepos*0.5 + getmousepos();
2079          */
2080
2081         IL_EACH(g_drawables, it.draw, it.draw(it));
2082
2083         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2084         renderscene();
2085
2086         // now switch to 2D drawing mode by calling a 2D drawing function
2087         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2088         // next R_RenderScene call
2089         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2090
2091         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2092         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2093         {
2094                 // apply night vision effect
2095                 vector tc_00, tc_01, tc_10, tc_11;
2096                 vector rgb = '0 0 0';
2097
2098                 if(!nightvision_noise)
2099                 {
2100                         nightvision_noise = new(nightvision_noise);
2101                 }
2102                 if(!nightvision_noise2)
2103                 {
2104                         nightvision_noise2 = new(nightvision_noise2);
2105                 }
2106
2107                 // color tint in yellow
2108                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2109
2110                 // draw BG
2111                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2112                 rgb = '1 1 1';
2113                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2114                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2115                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2116                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2117                 tc_11 = tc_01 + tc_10 - tc_00;
2118                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2119                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2120                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2121                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2122                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2123                 R_EndPolygon();
2124
2125                 // draw FG
2126                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2127                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2128                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2129                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2130                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2131                 tc_11 = tc_01 + tc_10 - tc_00;
2132                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2133                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2134                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2135                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2136                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2137                 R_EndPolygon();
2138         }
2139
2140         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2141         {
2142                 string reticle_image = string_null;
2143                 bool wep_zoomed = false;
2144                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2145                 {
2146                         entity wepe = viewmodels[slot];
2147                         Weapon wep = wepe.activeweapon;
2148                         if(wep != WEP_Null && wep.wr_zoom)
2149                         {
2150                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2151                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2152                                         reticle_image = wep.w_reticle;
2153                                 wep_zoomed += do_zoom;
2154                         }
2155                 }
2156                 // Draw the aiming reticle for weapons that use it
2157                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2158                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2159                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2160                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2161                 {
2162                         // no zoom reticle while dead
2163                         reticle_type = 0;
2164                 }
2165                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2166                 {
2167                         if(reticle_image) { reticle_type = 2; }
2168                         else { reticle_type = 0; }
2169                 }
2170                 else if(button_zoom || zoomscript_caught)
2171                 {
2172                         // normal zoom
2173                         reticle_type = 1;
2174                 }
2175
2176                 if(reticle_type)
2177                 {
2178                         if(autocvar_cl_reticle_stretch)
2179                         {
2180                                 reticle_size.x = vid_conwidth;
2181                                 reticle_size.y = vid_conheight;
2182                                 reticle_pos.x = 0;
2183                                 reticle_pos.y = 0;
2184                         }
2185                         else
2186                         {
2187                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2188                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2189                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2190                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2191                         }
2192
2193                         if(zoomscript_caught)
2194                                 f = 1;
2195                         else
2196                                 f = current_zoomfraction;
2197
2198                         if(f)
2199                         {
2200                                 switch(reticle_type)
2201                                 {
2202                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2203                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2204                                 }
2205                         }
2206                 }
2207         }
2208         else
2209         {
2210                 if(reticle_type != 0) { reticle_type = 0; }
2211         }
2212
2213
2214         // improved polyblend
2215         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2216         {
2217                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2218                 vector liquidcolor;
2219
2220                 switch(pointcontents(view_origin))
2221                 {
2222                         case CONTENT_WATER:
2223                                 liquidalpha = autocvar_hud_contents_water_alpha;
2224                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2225                                 incontent = 1;
2226                                 break;
2227
2228                         case CONTENT_LAVA:
2229                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2230                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2231                                 incontent = 1;
2232                                 break;
2233
2234                         case CONTENT_SLIME:
2235                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2236                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2237                                 incontent = 1;
2238                                 break;
2239
2240                         default:
2241                                 liquidalpha = 0;
2242                                 liquidcolor = '0 0 0';
2243                                 incontent = 0;
2244                                 break;
2245                 }
2246
2247                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2248                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2249                         contentfadetime = autocvar_hud_contents_fadeintime;
2250                         liquidalpha_prev = liquidalpha;
2251                         liquidcolor_prev = liquidcolor;
2252                 }
2253                 else
2254                         contentfadetime = autocvar_hud_contents_fadeouttime;
2255
2256                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2257                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2258
2259                 if(contentavgalpha)
2260                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2261
2262                 if(autocvar_hud_postprocessing)
2263                 {
2264                         if(autocvar_hud_contents_blur && contentavgalpha)
2265                         {
2266                                 content_blurpostprocess.x = 1;
2267                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2268                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2269                         }
2270                         else
2271                         {
2272                                 content_blurpostprocess.x = 0;
2273                                 content_blurpostprocess.y = 0;
2274                                 content_blurpostprocess.z = 0;
2275                         }
2276                 }
2277         }
2278
2279         if(autocvar_hud_damage && !STAT(FROZEN))
2280         {
2281                 splash_size.x = max(vid_conwidth, vid_conheight);
2282                 splash_size.y = max(vid_conwidth, vid_conheight);
2283                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2284                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2285
2286                 float myhealth_flash_temp;
2287                 myhealth = STAT(HEALTH);
2288
2289                 // fade out
2290                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2291                 // add new damage
2292                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2293
2294                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2295                 pain_threshold = autocvar_hud_damage_pain_threshold;
2296                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2297                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2298
2299                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2300                 {
2301                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2302                 }
2303
2304                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2305
2306                 if(myhealth_prev < 1)
2307                 {
2308                         if(myhealth >= 1)
2309                         {
2310                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2311                                 myhealth_flash_temp = 0;
2312                         }
2313                         else
2314                         {
2315                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2316                         }
2317                 }
2318
2319                 if(spectatee_status == -1 || intermission)
2320                 {
2321                         myhealth_flash = 0; // observing, or match ended
2322                         myhealth_flash_temp = 0;
2323                 }
2324
2325                 myhealth_prev = myhealth;
2326
2327                 // IDEA: change damage color/picture based on player model for robot/alien species?
2328                 // pro: matches model better
2329                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2330                 // maybe different reddish pics?
2331                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2332                 {
2333                         if(autocvar_cl_gentle_damage == 2)
2334                         {
2335                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2336                                         myhealth_gentlergb = randomvec();
2337                         }
2338                         else
2339                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2340
2341                         if(myhealth_flash_temp > 0)
2342                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2343                 }
2344                 else if(myhealth_flash_temp > 0)
2345                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2346
2347                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2348                 {
2349                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2350                         {
2351                                 damage_blurpostprocess.x = 1;
2352                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2353                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2354                         }
2355                         else
2356                         {
2357                                 damage_blurpostprocess.x = 0;
2358                                 damage_blurpostprocess.y = 0;
2359                                 damage_blurpostprocess.z = 0;
2360                         }
2361                 }
2362         }
2363
2364         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2365         float e2 = (autocvar_hud_powerup != 0);
2366         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2367         {
2368                 // enable or disable rendering types if they are used or not
2369                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2370                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2371
2372                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2373                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2374                 {
2375                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2376                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2377                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2378                         {
2379                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2380                                 old_blurradius = blurradius;
2381                                 old_bluralpha = bluralpha;
2382                         }
2383                 }
2384                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2385                 {
2386                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2387                         old_blurradius = 0;
2388                         old_bluralpha = 0;
2389                 }
2390
2391                 // edge detection postprocess handling done second (used by hud_powerup)
2392                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2393                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2394                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2395
2396                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2397
2398                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2399                 {
2400                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2401                         {
2402                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2403                                 old_sharpen_intensity = sharpen_intensity;
2404                         }
2405                 }
2406                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2407                 {
2408                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2409                         old_sharpen_intensity = 0;
2410                 }
2411
2412                 if(cvar("r_glsl_postprocess") == 0)
2413                         cvar_set("r_glsl_postprocess", "2");
2414         }
2415         else if(cvar("r_glsl_postprocess") == 2)
2416                 cvar_set("r_glsl_postprocess", "0");
2417
2418         /*if(ISGAMETYPE(CTF))
2419           {
2420           ctf_view();
2421           } else */
2422
2423         // draw 2D entities
2424         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2425         Draw_ShowNames_All();
2426 #if ENABLE_DEBUGDRAW
2427         Debug_Draw();
2428 #endif
2429
2430         scoreboard_active = Scoreboard_WouldDraw();
2431
2432         HUD_Draw(this); // this parameter for deep vehicle function
2433
2434         if(NextFrameCommand)
2435         {
2436                 localcmd("\n", NextFrameCommand, "\n");
2437                 NextFrameCommand = string_null;
2438         }
2439
2440         // we must do this check AFTER a frame was rendered, or it won't work
2441         if(cs_project_is_b0rked == 0)
2442         {
2443                 string w0, h0;
2444                 w0 = ftos(autocvar_vid_conwidth);
2445                 h0 = ftos(autocvar_vid_conheight);
2446                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2447                 //setproperty(VF_FOV, '90 90 0');
2448                 setproperty(VF_ORIGIN, '0 0 0');
2449                 setproperty(VF_ANGLES, '0 0 0');
2450                 setproperty(VF_PERSPECTIVE, 1);
2451                 vector forward, right, up;
2452                 MAKE_VECTORS('0 0 0', forward, right, up);
2453                 vector v1, v2;
2454                 cvar_set("vid_conwidth", "800");
2455                 cvar_set("vid_conheight", "600");
2456                 v1 = cs_project(forward);
2457                 cvar_set("vid_conwidth", "640");
2458                 cvar_set("vid_conheight", "480");
2459                 v2 = cs_project(forward);
2460                 if(v1 == v2)
2461                         cs_project_is_b0rked = 1;
2462                 else
2463                         cs_project_is_b0rked = -1;
2464                 cvar_set("vid_conwidth", w0);
2465                 cvar_set("vid_conheight", h0);
2466         }
2467
2468         HUD_Mouse(local_player);
2469
2470         cl_notice_run();
2471         unpause_update();
2472         Net_Flush();
2473
2474         // let's reset the view back to normal for the end
2475         setproperty(VF_MIN, '0 0 0');
2476         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2477
2478         IL_ENDFRAME();
2479 }
2480
2481
2482 // following vectors must be global to allow seamless switching between camera modes
2483 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2484 void CSQC_Demo_Camera()
2485 {
2486         float speed, attenuation, dimensions;
2487         vector tmp, delta;
2488
2489         if( autocvar_camera_reset || !camera_mode )
2490         {
2491                 camera_offset = '0 0 0';
2492                 current_angles = '0 0 0';
2493                 camera_direction = '0 0 0';
2494                 camera_offset.z += 30;
2495                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2496                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2497                 current_origin = view_origin;
2498                 current_camera_offset  = camera_offset;
2499                 cvar_set("camera_reset", "0");
2500                 camera_mode = CAMERA_CHASE;
2501         }
2502
2503         // Camera angles
2504         if( camera_roll )
2505                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2506
2507         if(autocvar_camera_look_player)
2508         {
2509                 vector dir;
2510                 float n;
2511
2512                 dir = normalize(view_origin - current_position);
2513                 n = mouse_angles.z;
2514                 mouse_angles = vectoangles(dir);
2515                 mouse_angles.x = mouse_angles.x * -1;
2516                 mouse_angles.z = n;
2517         }
2518         else
2519         {
2520                 tmp = getmousepos() * 0.1;
2521                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2522                 {
2523                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2524                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2525                 }
2526         }
2527
2528         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2529         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2530         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2531         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2532
2533         // Fix difference when angles don't have the same sign
2534         delta = '0 0 0';
2535         if(mouse_angles.y < -60 && current_angles.y > 60)
2536                 delta = '0 360 0';
2537         if(mouse_angles.y > 60 && current_angles.y < -60)
2538                 delta = '0 -360 0';
2539
2540         if(autocvar_camera_look_player)
2541                 attenuation = autocvar_camera_look_attenuation;
2542         else
2543                 attenuation = autocvar_camera_speed_attenuation;
2544
2545         attenuation = 1 / max(1, attenuation);
2546         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2547
2548         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2549         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2550         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2551         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2552
2553         // Camera position
2554         tmp = '0 0 0';
2555         dimensions = 0;
2556
2557         if( camera_direction.x )
2558         {
2559                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2560                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2561                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2562                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2563                 ++dimensions;
2564         }
2565
2566         if( camera_direction.y )
2567         {
2568                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2569                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2570                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2571                 ++dimensions;
2572         }
2573
2574         if( camera_direction.z )
2575         {
2576                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2577                 ++dimensions;
2578         }
2579
2580         if(autocvar_camera_free)
2581                 speed = autocvar_camera_speed_free;
2582         else
2583                 speed = autocvar_camera_speed_chase;
2584
2585         if(dimensions)
2586         {
2587                 speed = speed * sqrt(1 / dimensions);
2588                 camera_offset += tmp * speed;
2589         }
2590
2591         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2592
2593         // Camera modes
2594         if( autocvar_camera_free )
2595         {
2596                 if ( camera_mode == CAMERA_CHASE )
2597                 {
2598                         current_camera_offset = current_origin + current_camera_offset;
2599                         camera_offset = current_origin + camera_offset;
2600                 }
2601
2602                 camera_mode = CAMERA_FREE;
2603                 current_position = current_camera_offset;
2604         }
2605         else
2606         {
2607                 if ( camera_mode == CAMERA_FREE )
2608                 {
2609                         current_origin = view_origin;
2610                         camera_offset = camera_offset - current_origin;
2611                         current_camera_offset = current_camera_offset - current_origin;
2612                 }
2613
2614                 camera_mode = CAMERA_CHASE;
2615
2616                 if(autocvar_camera_chase_smoothly)
2617                         current_origin += (view_origin - current_origin) * attenuation;
2618                 else
2619                         current_origin = view_origin;
2620
2621                 current_position = current_origin + current_camera_offset;
2622         }
2623
2624         setproperty(VF_ANGLES, current_angles);
2625         setproperty(VF_ORIGIN, current_position);
2626 }