qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         Weapon wep = this.activeweapon;
 297         int c = entcs_GetClientColors(current_player);
 298         vector g = weaponentity_glowmod(wep, NULL, c, this);
 299         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 300         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 301                 | EF_NODEPTHTEST)
 302                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 303         for (entity e = this; e; e = e.weaponchild)
 304         {
 305                 e.drawmask = mask;
 306                 e.alpha = a;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 float showfps_prevfps;
 367 float showfps_prevfps_time;
 368 int showfps_framecounter;
 369
 370 void fpscounter_update()
 371 {
 372         if(!STAT(SHOWFPS))
 373                 return;
 374
 375         float currentTime = gettime(GETTIME_REALTIME);
 376         showfps_framecounter += 1;
 377         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 378         {
 379                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 380                 showfps_framecounter = 0;
 381                 showfps_prevfps_time = currentTime;
 382
 383                 int channel = MSG_C2S;
 384                 WriteHeader(channel, fpsreport);
 385                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 386         }
 387 }
 388
 389 STATIC_INIT(fpscounter_init)
 390 {
 391         float currentTime = gettime(GETTIME_REALTIME);
 392         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 393 }
 394
 395 float drawtime;
 396 float avgspeed;
 397 vector GetCurrentFov(float fov)
 398 {
 399         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 400         float velocityzoom, curspeed;
 401         vector v;
 402
 403         zoomsensitivity = autocvar_cl_zoomsensitivity;
 404         zoomfactor = autocvar_cl_zoomfactor;
 405         if(zoomfactor < 1 || zoomfactor > 30)
 406                 zoomfactor = 2.5;
 407         zoomspeed = autocvar_cl_zoomspeed;
 408         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 409                 zoomspeed = 3.5;
 410
 411         zoomdir = button_zoom;
 412
 413         if(hud == HUD_NORMAL && !spectatee_status)
 414         {
 415                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416                 {
 417                         entity wepent = viewmodels[slot];
 418                         if(wepent.switchweapon != wepent.activeweapon)
 419                                 continue;
 420                         Weapon wep = wepent.activeweapon;
 421                         if(wep != WEP_Null && wep.wr_zoomdir)
 422                         {
 423                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 424                                 zoomdir += do_zoom;
 425                         }
 426                 }
 427         }
 428         if(spectatee_status > 0 || isdemo())
 429         {
 430                 if(spectatorbutton_zoom)
 431                 {
 432                         if(zoomdir)
 433                                 zoomdir = 0;
 434                         else
 435                                 zoomdir = 1;
 436                 }
 437                 // fteqcc failed twice here already, don't optimize this
 438         }
 439
 440         if(zoomdir) { zoomin_effect = 0; }
 441
 442         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 443         {
 444                 current_viewzoom = 1;
 445         }
 446         else if (camera_active)
 447         {
 448                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 449         }
 450         else if(autocvar_cl_spawnzoom && zoomin_effect)
 451         {
 452                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 453
 454                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 455                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 456                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 457         }
 458         else
 459         {
 460                 if(zoomspeed < 0) // instant zoom
 461                 {
 462                         if(zoomdir)
 463                                 current_viewzoom = 1 / zoomfactor;
 464                         else
 465                                 current_viewzoom = 1;
 466                 }
 467                 else
 468                 {
 469                         if(zoomdir)
 470                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 471                         else
 472                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 473                 }
 474         }
 475
 476         if(almost_equals(current_viewzoom, 1))
 477                 current_zoomfraction = 0;
 478         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 479                 current_zoomfraction = 1;
 480         else
 481                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 482
 483         if(zoomsensitivity < 1)
 484                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 485         else
 486                 setsensitivityscale(1);
 487
 488         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 489         {
 490                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 491                         curspeed = 0;
 492                 else
 493                 {
 494                         vector forward, right, up;
 495                         MAKE_VECTORS(view_angles, forward, right, up);
 496                         v = pmove_vel;
 497                         if(csqcplayer)
 498                                 v = csqcplayer.velocity;
 499
 500                         switch(autocvar_cl_velocityzoom_type)
 501                         {
 502                                 case 3: curspeed = max(0, forward * v); break;
 503                                 case 2: curspeed = (forward * v); break;
 504                                 case 1: default: curspeed = vlen(v); break;
 505                         }
 506                 }
 507
 508                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 509                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 510                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 511
 512                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 513         }
 514         else
 515                 velocityzoom = 1;
 516
 517         float frustumx, frustumy, fovx, fovy;
 518         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 519         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 520         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 521         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 522
 523         return '1 0 0' * fovx + '0 1 0' * fovy;
 524 }
 525
 526 vector GetViewLocationFOV(float fov)
 527 {
 528         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 529         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 530         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 531         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 532         return '1 0 0' * fovx + '0 1 0' * fovy;
 533 }
 534
 535 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 536 {
 537         float fovx, fovy;
 538         float width = (ov_worldmax.x - ov_worldmin.x);
 539         float height = (ov_worldmax.y - ov_worldmin.y);
 540         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 541         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 542         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         return '1 0 0' * fovx + '0 1 0' * fovy;
 544 }
 545
 546 // this function must match W_SetupShot!
 547 float zoomscript_caught;
 548
 549 bool minigame_wasactive;
 550
 551 vector wcross_origin;
 552 float wcross_scale_prev, wcross_alpha_prev;
 553 vector wcross_color_prev;
 554 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 555 vector wcross_color_goal_prev;
 556 float wcross_changedonetime;
 557
 558 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 559 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 560 float wcross_name_changestarttime, wcross_name_changedonetime;
 561 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 562
 563 float wcross_ring_prev;
 564
 565 entity trueaim;
 566 entity trueaim_rifle;
 567
 568 const float SHOTTYPE_HITTEAM = 1;
 569 const float SHOTTYPE_HITOBSTRUCTION = 2;
 570 const float SHOTTYPE_HITWORLD = 3;
 571 const float SHOTTYPE_HITENEMY = 4;
 572
 573 void TrueAim_Init()
 574 {
 575         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 576         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577 }
 578
 579 float EnemyHitCheck()
 580 {
 581         float t, n;
 582         wcross_origin = project_3d_to_2d(trace_endpos);
 583         wcross_origin.z = 0;
 584         if(trace_ent)
 585                 n = trace_ent.entnum;
 586         else
 587                 n = trace_networkentity;
 588         if(n < 1)
 589                 return SHOTTYPE_HITWORLD;
 590         if(n > maxclients)
 591                 return SHOTTYPE_HITWORLD;
 592         t = entcs_GetTeam(n - 1);
 593         if(teamplay)
 594                 if(t == myteam)
 595                         return SHOTTYPE_HITTEAM;
 596         if(t == NUM_SPECTATOR)
 597                 return SHOTTYPE_HITWORLD;
 598         return SHOTTYPE_HITENEMY;
 599 }
 600
 601 float TrueAimCheck(entity wepent)
 602 {
 603         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 604                 return SHOTTYPE_HITWORLD;
 605
 606         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 607         vector vecs, trueaimpoint, w_shotorg;
 608         vector mi, ma, dv;
 609         float shottype;
 610         entity ta;
 611         float mv;
 612
 613         mi = ma = '0 0 0';
 614         ta = trueaim;
 615         mv = MOVE_NOMONSTERS;
 616
 617         switch(wepent.activeweapon) // WEAPONTODO
 618         {
 619                 case WEP_VORTEX:
 620                 case WEP_OVERKILL_NEX:
 621                 case WEP_VAPORIZER:
 622                         mv = MOVE_NORMAL;
 623                         break;
 624                 case WEP_RIFLE:
 625                         ta = trueaim_rifle;
 626                         mv = MOVE_NORMAL;
 627                         if(zoomscript_caught)
 628                         {
 629                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 630                                 return EnemyHitCheck();
 631                         }
 632                         break;
 633                 case WEP_DEVASTATOR: // projectile has a size!
 634                         mi = '-3 -3 -3';
 635                         ma = '3 3 3';
 636                         break;
 637                 case WEP_FIREBALL: // projectile has a size!
 638                         mi = '-16 -16 -16';
 639                         ma = '16 16 16';
 640                         break;
 641                 case WEP_SEEKER: // projectile has a size!
 642                         mi = '-2 -2 -2';
 643                         ma = '2 2 2';
 644                         break;
 645                 case WEP_ELECTRO: // projectile has a size!
 646                         mi = '0 0 -3';
 647                         ma = '0 0 -3';
 648                         break;
 649         }
 650
 651         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 652
 653         vecs = decompressShotOrigin(STAT(SHOTORG));
 654
 655         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 656         trueaimpoint = trace_endpos;
 657
 658         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 659                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 660
 661         if(vecs.x > 0)
 662                 vecs.y = -vecs.y;
 663         else
 664                 vecs = '0 0 0';
 665
 666         dv = view_right * vecs.y + view_up * vecs.z;
 667         w_shotorg = traceorigin + dv;
 668
 669         // now move the vecs forward as much as requested if possible
 670         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 671         w_shotorg = trace_endpos - view_forward * nudge;
 672
 673         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 674         shottype = EnemyHitCheck();
 675         if(shottype != SHOTTYPE_HITWORLD)
 676                 return shottype;
 677
 678 #if 0
 679         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 680         // or rather, I know why, but see no fix
 681         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 682                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 683                 return SHOTTYPE_HITOBSTRUCTION;
 684 #endif
 685
 686         return SHOTTYPE_HITWORLD;
 687 }
 688
 689 float camera_mode;
 690 const float CAMERA_FREE = 1;
 691 const float CAMERA_CHASE = 2;
 692 float reticle_type;
 693 string NextFrameCommand;
 694
 695 vector freeze_org, freeze_ang;
 696 entity nightvision_noise, nightvision_noise2;
 697
 698 const float MAX_TIME_DIFF = 5;
 699 float pickup_crosshair_time, pickup_crosshair_size;
 700 float hitindication_crosshair_size;
 701 float use_vortex_chargepool;
 702
 703 float myhealth, myhealth_prev;
 704 float myhealth_flash;
 705
 706 float old_blurradius, old_bluralpha;
 707 float old_sharpen_intensity;
 708
 709 vector myhealth_gentlergb;
 710
 711 float contentavgalpha, liquidalpha_prev;
 712 vector liquidcolor_prev;
 713
 714 float eventchase_current_distance;
 715 float eventchase_running;
 716 int WantEventchase(entity this)
 717 {
 718         if(autocvar_cl_orthoview)
 719                 return 0;
 720         if(STAT(GAME_STOPPED) || intermission)
 721                 return 1;
 722         if(this.viewloc)
 723                 return 1;
 724         if(spectatee_status >= 0)
 725         {
 726                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 727                         return 1;
 728                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 729                         return 1;
 730                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 731                         return 1;
 732                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 733                 {
 734                         if(autocvar_cl_eventchase_death == 2)
 735                         {
 736                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 737                                 if(this.velocity == '0 0 0' || eventchase_running)
 738                                         return 1;
 739                         }
 740                         else return 1;
 741                 }
 742                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 743                 {
 744                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 745                                 return 1;
 746                         else if (eventchase_running)
 747                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 748                 }
 749         }
 750         return 0;
 751 }
 752
 753 void HUD_Crosshair_Vehicle(entity this)
 754 {
 755         if(hud != HUD_BUMBLEBEE_GUN)
 756         {
 757                 Vehicle info = Vehicles_from(hud);
 758                 info.vr_crosshair(info, this);
 759         }
 760 }
 761
 762 vector damage_blurpostprocess, content_blurpostprocess;
 763
 764 float unaccounted_damage = 0;
 765 void UpdateDamage()
 766 {
 767         // accumulate damage with each stat update
 768         static float damage_total_prev = 0;
 769         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 770         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 771         damage_total_prev = damage_total;
 772
 773         static float damage_dealt_time_prev = 0;
 774         float damage_dealt_time = STAT(HIT_TIME);
 775         if (damage_dealt_time != damage_dealt_time_prev)
 776         {
 777                 unaccounted_damage += unaccounted_damage_new;
 778                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 779         }
 780         damage_dealt_time_prev = damage_dealt_time;
 781
 782         // prevent hitsound when switching spectatee
 783         static float spectatee_status_prev = 0;
 784         if (spectatee_status != spectatee_status_prev)
 785                 unaccounted_damage = 0;
 786         spectatee_status_prev = spectatee_status;
 787 }
 788
 789 void HitSound()
 790 {
 791         // varying sound pitch
 792
 793         bool have_arc = false;
 794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795         {
 796                 entity wepent = viewmodels[slot];
 797
 798                 if(wepent.activeweapon == WEP_ARC)
 799                         have_arc = true;
 800         }
 801
 802         static float hitsound_time_prev = 0;
 803         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 804         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 805         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 806         {
 807                 if (autocvar_cl_hitsound && unaccounted_damage)
 808                 {
 809                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 810                         float a = autocvar_cl_hitsound_max_pitch;
 811                         float b = autocvar_cl_hitsound_min_pitch;
 812                         float c = autocvar_cl_hitsound_nom_damage;
 813                         float d = unaccounted_damage;
 814                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 815
 816                         // if sound variation is disabled, set pitch_shift to 1
 817                         if (autocvar_cl_hitsound == 1)
 818                                 pitch_shift = 1;
 819
 820                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 821                         if (autocvar_cl_hitsound == 3)
 822                         {
 823                                 float mirror_value = (a-b)/2 + b;
 824                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 825                         }
 826
 827                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 828
 829                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 830                         // todo: normalize sound pressure levels? seems unnecessary
 831
 832                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 833                 }
 834                 unaccounted_damage = 0;
 835                 hitsound_time_prev = time;
 836         }
 837
 838         static float typehit_time_prev = 0;
 839         float typehit_time = STAT(TYPEHIT_TIME);
 840         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 841         {
 842                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 843                 typehit_time_prev = typehit_time;
 844         }
 845
 846         static float kill_time_prev = 0;
 847         float kill_time = STAT(KILL_TIME);
 848         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 849         {
 850                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 851                 kill_time_prev = kill_time;
 852         }
 853 }
 854
 855 vector crosshair_getcolor(entity this, float health_stat)
 856 {
 857         static float rainbow_last_flicker;
 858         static vector rainbow_prev_color;
 859         vector wcross_color = '0 0 0';
 860         switch(autocvar_crosshair_color_special)
 861         {
 862                 case 1: // crosshair_color_per_weapon
 863                 {
 864                         if(this != WEP_Null && hud == HUD_NORMAL)
 865                         {
 866                                 wcross_color = this.wpcolor;
 867                                 break;
 868                         }
 869                         else { goto normalcolor; }
 870                 }
 871
 872                 case 2: // crosshair_color_by_health
 873                 {
 874                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 875                         float hp = floor(v.x + 1);
 876
 877                         //x = red
 878                         //y = green
 879                         //z = blue
 880
 881                         wcross_color.z = 0;
 882
 883                         if(hp > 200)
 884                         {
 885                                 wcross_color.x = 0;
 886                                 wcross_color.y = 1;
 887                         }
 888                         else if(hp > 150)
 889                         {
 890                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 891                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 892                         }
 893                         else if(hp > 100)
 894                         {
 895                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 896                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 897                                 wcross_color.z = 1 - (hp-100)*0.02;
 898                         }
 899                         else if(hp > 50)
 900                         {
 901                                 wcross_color.x = 1;
 902                                 wcross_color.y = 1;
 903                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 904                         }
 905                         else if(hp > 20)
 906                         {
 907                                 wcross_color.x = 1;
 908                                 wcross_color.y = (hp-20)*90/27/100;
 909                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 910                         }
 911                         else
 912                         {
 913                                 wcross_color.x = 1;
 914                                 wcross_color.y = 0;
 915                         }
 916                         break;
 917                 }
 918
 919                 case 3: // crosshair_color_rainbow
 920                 {
 921                         if(time >= rainbow_last_flicker)
 922                         {
 923                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 924                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 925                         }
 926                         wcross_color = rainbow_prev_color;
 927                         break;
 928                 }
 929 LABEL(normalcolor)
 930                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 931         }
 932
 933         return wcross_color;
 934 }
 935
 936 void HUD_Crosshair(entity this)
 937 {
 938         float f, i, j;
 939         vector v;
 940         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 941                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 942                 !HUD_MinigameMenu_IsOpened() )
 943         {
 944                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 945                         return;
 946
 947                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 948                         return;
 949
 950                 if (hud != HUD_NORMAL)
 951                 {
 952                         HUD_Crosshair_Vehicle(this);
 953                         return;
 954                 }
 955
 956                 string wcross_style;
 957                 float wcross_alpha, wcross_resolution;
 958                 wcross_style = autocvar_crosshair;
 959                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 960                         wcross_style = autocvar_crosshair_2d;
 961                 if (wcross_style == "0")
 962                         return;
 963                 wcross_resolution = autocvar_crosshair_size;
 964                 if (wcross_resolution == 0)
 965                         return;
 966                 wcross_alpha = autocvar_crosshair_alpha;
 967                 if (wcross_alpha == 0)
 968                         return;
 969
 970                 // TrueAim check
 971                 float shottype;
 972
 973                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 974                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 975                         wcross_origin = viewloc_mousepos;
 976                 else
 977                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 978                 wcross_origin.z = 0;
 979                 if(autocvar_crosshair_hittest)
 980                 {
 981                         vector wcross_oldorigin;
 982                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 983                         wcross_oldorigin = wcross_origin;
 984                         shottype = TrueAimCheck(thiswep);
 985                         if(shottype == SHOTTYPE_HITWORLD)
 986                         {
 987                                 v = wcross_origin - wcross_oldorigin;
 988                                 v.x /= vid_conwidth;
 989                                 v.y /= vid_conheight;
 990                                 if(vdist(v, >, 0.01))
 991                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 992                         }
 993                         if(!autocvar_crosshair_hittest_showimpact)
 994                                 wcross_origin = wcross_oldorigin;
 995                 }
 996                 else
 997                         shottype = SHOTTYPE_HITWORLD;
 998
 999                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1000                 string wcross_name = "";
1001                 float wcross_scale, wcross_blur;
1002
1003         entity e = WEP_Null;
1004                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1005                 {
1006                         entity wepent = viewmodels[0]; // TODO: unhardcode
1007                         e = wepent.switchingweapon;
1008                         if(e)
1009                         {
1010                                 if(autocvar_crosshair_per_weapon)
1011                                 {
1012                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1013                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1014                                         //if (wcross_resolution == 0)
1015                                                 //return;
1016
1017                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1018                                         wcross_resolution *= e.w_crosshair_size;
1019                                         wcross_name = e.w_crosshair;
1020                                 }
1021                         }
1022                 }
1023
1024                 if(wcross_name == "")
1025                         wcross_name = strcat("gfx/crosshair", wcross_style);
1026
1027                 // MAIN CROSSHAIR COLOR DECISION
1028                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1029
1030                 if(autocvar_crosshair_effect_scalefade)
1031                 {
1032                         wcross_scale = wcross_resolution;
1033                         wcross_resolution = 1;
1034                 }
1035                 else
1036                 {
1037                         wcross_scale = 1;
1038                 }
1039
1040                 if(autocvar_crosshair_pickup)
1041                 {
1042                         float stat_pickup_time = STAT(LAST_PICKUP);
1043
1044                         if(pickup_crosshair_time < stat_pickup_time)
1045                         {
1046                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1047                                         pickup_crosshair_size = 1;
1048
1049                                 pickup_crosshair_time = stat_pickup_time;
1050                         }
1051
1052                         if(pickup_crosshair_size > 0)
1053                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1054                         else
1055                                 pickup_crosshair_size = 0;
1056
1057                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1058                 }
1059
1060                 // todo: make crosshair hit indication dependent on damage dealt
1061                 if(autocvar_crosshair_hitindication)
1062                 {
1063                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1064
1065                         if(unaccounted_damage)
1066                         {
1067                                 hitindication_crosshair_size = 1;
1068                         }
1069
1070                         if(hitindication_crosshair_size > 0)
1071                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1072                         else
1073                                 hitindication_crosshair_size = 0;
1074
1075                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1076                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1077                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1078                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1079                 }
1080
1081                 if(shottype == SHOTTYPE_HITENEMY)
1082                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1083                 if(shottype == SHOTTYPE_HITTEAM)
1084                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1085
1086                 f = fabs(autocvar_crosshair_effect_time);
1087                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1088                 {
1089                         wcross_changedonetime = time + f;
1090                 }
1091                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1092                 {
1093                         wcross_name_changestarttime = time;
1094                         wcross_name_changedonetime = time + f;
1095                         if(wcross_name_goal_prev_prev)
1096                                 strunzone(wcross_name_goal_prev_prev);
1097                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1098                         wcross_name_goal_prev = strzone(wcross_name);
1099                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1100                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1101                         wcross_resolution_goal_prev = wcross_resolution;
1102                 }
1103
1104                 wcross_scale_goal_prev = wcross_scale;
1105                 wcross_alpha_goal_prev = wcross_alpha;
1106                 wcross_color_goal_prev = wcross_color;
1107
1108                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1109                 {
1110                         wcross_blur = 1;
1111                         wcross_alpha *= 0.75;
1112                 }
1113                 else
1114                         wcross_blur = 0;
1115                 // *_prev is at time-frametime
1116                 // * is at wcross_changedonetime+f
1117                 // what do we have at time?
1118                 if(time < wcross_changedonetime)
1119                 {
1120                         f = frametime / (wcross_changedonetime - time + frametime);
1121                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1122                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1123                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1124                 }
1125
1126                 wcross_scale_prev = wcross_scale;
1127                 wcross_alpha_prev = wcross_alpha;
1128                 wcross_color_prev = wcross_color;
1129
1130                 MUTATOR_CALLHOOK(UpdateCrosshair);
1131
1132                 wcross_scale *= 1 - autocvar__menu_alpha;
1133                 wcross_alpha *= 1 - autocvar__menu_alpha;
1134                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1135
1136                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1137                 {
1138                         // crosshair rings for weapon stats
1139                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1140                         {
1141                                 // declarations and stats
1142                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1143                                 string ring_image = string_null, ring_inner_image = string_null;
1144                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1145
1146                                 ring_scale = autocvar_crosshair_ring_size;
1147
1148                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1149
1150                                 int weapon_clipload = wepent.clip_load;
1151                                 int weapon_clipsize = wepent.clip_size;
1152
1153                                 float arc_heat = wepent.arc_heat_percent;
1154                                 float vcharge = wepent.vortex_charge;
1155                                 float vchargepool = wepent.vortex_chargepool_ammo;
1156                                 float oknex_charge_ = wepent.oknex_charge;
1157                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1158
1159                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1160                                         vortex_charge_movingavg = vcharge;
1161
1162                                 // handle the values
1163                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1164                                 {
1165                                         if (vchargepool || use_vortex_chargepool) {
1166                                                 use_vortex_chargepool = 1;
1167                                                 ring_inner_value = vchargepool;
1168                                         } else {
1169                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1170                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1171                                         }
1172
1173                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1174                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1175                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1176
1177                                         // draw the outer ring to show the current charge of the weapon
1178                                         ring_value = vcharge;
1179                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1180                                         ring_rgb = wcross_color;
1181                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1182                                 }
1183                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1184                                 {
1185                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1186                                                 use_vortex_chargepool = 1;
1187                                                 ring_inner_value = oknex_chargepool_;
1188                                         } else {
1189                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1190                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1191                                         }
1192
1193                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1194                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1195                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1196
1197                                         // draw the outer ring to show the current charge of the weapon
1198                                         ring_value = oknex_charge_;
1199                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1202                                 }
1203                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1204                                 {
1205                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1206                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1207                                         ring_rgb = wcross_color;
1208                                         ring_image = "gfx/crosshair_ring.tga";
1209                                 }
1210                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1211                                 {
1212                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1213                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1214                                         ring_rgb = wcross_color;
1215                                         ring_image = "gfx/crosshair_ring.tga";
1216                                 }
1217                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1218                                 {
1219                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1220                                         ring_scale = autocvar_crosshair_ring_reload_size;
1221                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1222                                         ring_rgb = wcross_color;
1223
1224                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1225                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1226                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1227                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1228                                         else
1229                                                 ring_image = "gfx/crosshair_ring.tga";
1230                                 }
1231                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1232                                 {
1233                                         ring_value = arc_heat;
1234                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1235                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1236                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1237                                         ring_image = "gfx/crosshair_ring.tga";
1238                                 }
1239
1240                                 // if in weapon switch animation, fade ring out/in
1241                                 if(autocvar_crosshair_effect_time > 0)
1242                                 {
1243                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1244                                         if (f >= 1)
1245                                         {
1246                                                 wcross_ring_prev = ((ring_image) ? true : false);
1247                                         }
1248
1249                                         if(wcross_ring_prev)
1250                                         {
1251                                                 if(f < 1)
1252                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1253                                         }
1254                                         else
1255                                         {
1256                                                 if(f < 1)
1257                                                         ring_alpha *= bound(0, f, 1);
1258                                         }
1259                                 }
1260
1261                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1262                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1263
1264                                 if (ring_value)
1265                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1266                         }
1267
1268 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1269                         MACRO_BEGIN \
1270                                 vector scaled_sz = sz * wcross_size; \
1271                                 if(wcross_blur > 0) \
1272                                 { \
1273                                         for(i = -2; i <= 2; ++i) \
1274                                         for(j = -2; j <= 2; ++j) \
1275                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1276                                 } \
1277                                 else \
1278                                 { \
1279                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1280                                 } \
1281                         MACRO_END
1282
1283 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1284                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1285
1286 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1287                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1288
1289                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1290                         {
1291                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1292                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1293                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1294                                 f = 1 - f;
1295                         }
1296                         else
1297                         {
1298                                 f = 1;
1299                         }
1300                         wcross_name_alpha_goal_prev = f;
1301
1302                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1303                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1304
1305                         if(autocvar_crosshair_dot)
1306                         {
1307                                 vector wcross_color_old;
1308                                 wcross_color_old = wcross_color;
1309
1310                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1311                                         wcross_color = stov(autocvar_crosshair_dot_color);
1312
1313                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1314                                 // FIXME why don't we use wcross_alpha here?
1315                                 wcross_color = wcross_color_old;
1316                         }
1317                 }
1318         }
1319         else
1320         {
1321                 wcross_scale_prev = 0;
1322                 wcross_alpha_prev = 0;
1323                 wcross_scale_goal_prev = 0;
1324                 wcross_alpha_goal_prev = 0;
1325                 wcross_changedonetime = 0;
1326                 strfree(wcross_name_goal_prev);
1327                 strfree(wcross_name_goal_prev_prev);
1328                 wcross_name_changestarttime = 0;
1329                 wcross_name_changedonetime = 0;
1330                 wcross_name_alpha_goal_prev = 0;
1331                 wcross_name_alpha_goal_prev_prev = 0;
1332                 wcross_resolution_goal_prev = 0;
1333                 wcross_resolution_goal_prev_prev = 0;
1334         }
1335 }
1336
1337 const int MAX_SPECIALCOMMAND = 15;
1338 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1339 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1340 const float SPECIALCOMMAND_SPEED = 150;
1341 const float SPECIALCOMMAND_TURNSPEED = 2;
1342 const float SPECIALCOMMAND_SIZE = 0.025;
1343 const float SPECIALCOMMAND_CHANCE = 0.35;
1344 float sc_spawntime, sc_changetime;
1345 vector sc_color = '1 1 1';
1346 void SpecialCommand()
1347 {
1348         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1349                 return;
1350
1351         if(time >= sc_changetime)
1352         {
1353                 sc_changetime = time + 1;
1354                 sc_color = randomvec() * 1.5;
1355                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1356                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1357                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1358         }
1359         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1360
1361         if(!precache_pic("gfx/smile"))
1362                 return; // damn party poopers
1363
1364         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1365         {
1366                 vector slot = specialcommand_slots[j];
1367                 if(slot.y)
1368                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1369                 //if(slot.z)
1370                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1371                 if(slot.y >= vid_conheight)
1372                         slot = '0 0 0';
1373
1374                 if(slot == '0 0 0')
1375                 {
1376                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1377                         {
1378                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1379                                 slot.y = 1; // start it off 0 so we can use it
1380                                 slot.z = floor(random() * Weapons_MAX);
1381                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1382                                 vector newcolor = randomvec() * 2;
1383                                 newcolor.x = bound(0.4, newcolor.x, 1);
1384                                 newcolor.y = bound(0.4, newcolor.y, 1);
1385                                 newcolor.z = bound(0.4, newcolor.z, 1);
1386                                 specialcommand_colors[j] = newcolor;
1387                         }
1388                 }
1389                 else
1390                 {
1391                         vector splash_size = '0 0 0';
1392                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1393                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1394                         entity wep = Weapons_from(slot.z);
1395                         if(wep == WEP_Null)
1396                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1397                         else
1398                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1399                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1400                 }
1401
1402                 specialcommand_slots[j] = slot;
1403         }
1404 }
1405
1406 void HUD_Draw(entity this)
1407 {
1408         // if we don't know gametype and scores yet avoid drawing the scoreboard
1409         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1410         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1411         // cl_deathscoreboard would show the scoreboard and so on
1412         if(!gametype)
1413                 return;
1414
1415         Hud_Dynamic_Frame();
1416
1417         if(!intermission)
1418         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1419         {
1420                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1421         }
1422         else if(STAT(FROZEN))
1423         {
1424                 vector col = '0.25 0.90 1';
1425                 if(STAT(REVIVE_PROGRESS))
1426                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1427                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1428         }
1429
1430         HUD_Scale_Enable();
1431         if(!intermission)
1432         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1433         {
1434                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1435                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1436                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1437         }
1438         else if(STAT(CAPTURE_PROGRESS))
1439         {
1440                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1441                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1442         }
1443         else if(STAT(REVIVE_PROGRESS))
1444         {
1445                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1446                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1447         }
1448         HUD_Scale_Disable();
1449
1450         if(autocvar_r_letterbox == 0)
1451                 if(autocvar_viewsize < 120)
1452                 {
1453                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1454                                 Accuracy_LoadLevels();
1455
1456                         HUD_Main();
1457                         HUD_Scale_Disable();
1458                 }
1459
1460         // crosshair goes VERY LAST
1461         SpecialCommand();
1462         UpdateDamage();
1463         HUD_Crosshair(this);
1464         HitSound();
1465 }
1466
1467 void ViewLocation_Mouse()
1468 {
1469         if(spectatee_status)
1470                 return; // don't draw it as spectator!
1471
1472         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1473         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1474         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1475
1476         //float cursor_alpha = 1 - autocvar__menu_alpha;
1477         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1478 }
1479
1480 void HUD_Cursor_Show()
1481 {
1482         float cursor_alpha = 1 - autocvar__menu_alpha;
1483         if(cursor_type == CURSOR_NORMAL)
1484                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1485         else if(cursor_type == CURSOR_MOVE)
1486                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1487         else if(cursor_type == CURSOR_RESIZE)
1488                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1489         else if(cursor_type == CURSOR_RESIZE2)
1490                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1491 }
1492
1493 void HUD_Mouse(entity player)
1494 {
1495         if(autocvar__menu_alpha == 1)
1496                 return;
1497
1498         if(!cursor_active)
1499         {
1500                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1501                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1502                 return;
1503         }
1504
1505         if (cursor_active == -1) // starting to display the cursor
1506         {
1507                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1508                 // in the first frame mousepos is the mouse position of the last time
1509                 // the cursor was displayed, thus we ignore it to avoid a glictch
1510                 cursor_active = 1;
1511                 return;
1512         }
1513
1514         if(!autocvar_hud_cursormode)
1515                 update_mousepos();
1516
1517         if(autocvar__hud_configure)
1518                 HUD_Panel_Mouse();
1519         else
1520         {
1521                 if (HUD_MinigameMenu_IsOpened())
1522                         HUD_Minigame_Mouse();
1523                 if (QuickMenu_IsOpened())
1524                         QuickMenu_Mouse();
1525                 if (HUD_Radar_Clickable())
1526                         HUD_Radar_Mouse();
1527         }
1528
1529         prevMouseClicked = mouseClicked;
1530
1531         HUD_Cursor_Show();
1532 }
1533
1534 bool ov_enabled;
1535 float oldr_nearclip;
1536 float oldr_farclip_base;
1537 float oldr_farclip_world;
1538 float oldr_novis;
1539 float oldr_useportalculling;
1540 float oldr_useinfinitefarclip;
1541
1542 float prev_myteam;
1543 int lasthud;
1544 float vh_notice_time;
1545 void CSQC_UpdateView(entity this, float w, float h)
1546 {
1547         TC(int, w); TC(int, h);
1548         entity e;
1549         float fov;
1550         float f;
1551         vector vf_size, vf_min;
1552         float a;
1553
1554         execute_next_frame();
1555
1556         ++framecount;
1557
1558         stats_get();
1559         hud = STAT(HUD);
1560
1561         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1562                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1563
1564         lasthud = hud;
1565
1566         HUD_Scale_Disable();
1567
1568         if(autocvar__hud_showbinds_reload) // menu can set this one
1569         {
1570                 db_close(binddb);
1571                 binddb = db_create();
1572                 cvar_set("_hud_showbinds_reload", "0");
1573         }
1574
1575         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1576                 view_quality = getproperty(VF_MINFPS_QUALITY);
1577         else
1578                 view_quality = 1;
1579
1580         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1581         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1582
1583         vf_size = getpropertyvec(VF_SIZE);
1584         vf_min = getpropertyvec(VF_MIN);
1585         vid_width = vf_size.x;
1586         vid_height = vf_size.y;
1587
1588         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1589         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1590
1591         WaypointSprite_Load();
1592
1593         CSQCPlayer_SetCamera();
1594
1595         if(player_localentnum <= maxclients) // is it a client?
1596                 current_player = player_localentnum - 1;
1597         else // then player_localentnum is the vehicle I'm driving
1598                 current_player = player_localnum;
1599         myteam = entcs_GetTeam(current_player);
1600
1601         if(myteam != prev_myteam)
1602         {
1603                 myteamcolors = colormapPaletteColor(myteam, 1);
1604                 FOREACH(hud_panels, true, it.update_time = time);
1605                 prev_myteam = myteam;
1606         }
1607
1608         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1609
1610         float is_dead = (STAT(HEALTH) <= 0);
1611
1612         // FIXME do we need this hack?
1613         if(isdemo())
1614         {
1615                 // in demos, input_buttons do not work
1616                 button_zoom = (autocvar__togglezoom == "-");
1617         }
1618         else if(button_zoom
1619                 && autocvar_cl_unpress_zoom_on_death
1620                 && (spectatee_status >= 0)
1621                 && (is_dead || intermission))
1622         {
1623                 // no zoom while dead or in intermission please
1624                 localcmd("-zoom\n");
1625                 button_zoom = false;
1626         }
1627
1628         // abused multiple places below
1629         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1630         if(!local_player)
1631                 local_player = this; // fall back!
1632
1633         // event chase camera
1634         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1635         {
1636                 if(STAT(CAMERA_SPECTATOR))
1637                 {
1638                         if(spectatee_status > 0)
1639                         {
1640                                 if(!autocvar_chase_active)
1641                                 {
1642                                         cvar_set("chase_active", "-2");
1643                                         goto skip_eventchase_death;
1644                                 }
1645                         }
1646                         else if(autocvar_chase_active == -2)
1647                                 cvar_set("chase_active", "0");
1648
1649                         if(autocvar_chase_active == -2)
1650                                 goto skip_eventchase_death;
1651                 }
1652                 else if(autocvar_chase_active == -2)
1653                         cvar_set("chase_active", "0");
1654
1655                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1656
1657                 float vehicle_viewdist = 0;
1658                 vector vehicle_viewofs = '0 0 0';
1659
1660                 if(vehicle_chase)
1661                 {
1662                         if(hud != HUD_BUMBLEBEE_GUN)
1663                         {
1664                                 Vehicle info = Vehicles_from(hud);
1665                                 vehicle_viewdist = info.height;
1666                                 vehicle_viewofs = info.view_ofs;
1667                         }
1668                 }
1669
1670                 int eventchase = WantEventchase(this);
1671                 if (eventchase)
1672                 {
1673                         vector current_view_origin_override = '0 0 0';
1674                         vector view_offset_override = '0 0 0';
1675                         float chase_distance_override = 0;
1676                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1677                         if(custom_eventchase)
1678                         {
1679                                 current_view_origin_override = M_ARGV(0, vector);
1680                                 view_offset_override = M_ARGV(1, vector);
1681                                 chase_distance_override = M_ARGV(0, float);
1682                         }
1683                         eventchase_running = true;
1684
1685                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1686                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1687                         if (custom_eventchase)
1688                                 current_view_origin = current_view_origin_override;
1689
1690                         // detect maximum viewoffset and use it
1691                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1692                         if(vehicle_chase)
1693                         {
1694                                 if(vehicle_viewofs)
1695                                         view_offset = vehicle_viewofs;
1696                                 else
1697                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1698                         }
1699                         if (custom_eventchase)
1700                                 view_offset = view_offset_override;
1701
1702                         if(view_offset)
1703                         {
1704                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1705                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1706                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1707                         }
1708
1709                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1710                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1711                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1712                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1713
1714                         // make the camera smooth back
1715                         float chase_distance = autocvar_cl_eventchase_distance;
1716                         if(vehicle_chase)
1717                         {
1718                                 if(vehicle_viewofs)
1719                                         chase_distance = vehicle_viewdist;
1720                                 else
1721                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1722                         }
1723                         if (custom_eventchase)
1724                                 chase_distance = chase_distance_override;
1725
1726                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1727                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1728                         else if(eventchase_current_distance != chase_distance)
1729                                 eventchase_current_distance = chase_distance;
1730
1731                         vector forward, right, up;
1732                         MAKE_VECTORS(view_angles, forward, right, up);
1733
1734                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1735                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1736
1737                         // If the boxtrace fails, revert back to line tracing.
1738                         if(!local_player.viewloc)
1739                         if(trace_startsolid)
1740                         {
1741                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
1742                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1743                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
1744                         }
1745                         else { setproperty(VF_ORIGIN, trace_endpos); }
1746
1747                         if(!local_player.viewloc)
1748                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1749                 }
1750
1751                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1752                 {
1753                         eventchase_running = false;
1754                         cvar_set("chase_active", "0");
1755                         eventchase_current_distance = 0; // start from 0 next time
1756                 }
1757         }
1758         // workaround for camera stuck between player's legs when using chase_active 1
1759         // because the engine stops updating the chase_active camera when the game ends
1760         else if(intermission)
1761         {
1762                 cvar_settemp("chase_active", "-1");
1763                 eventchase_current_distance = 0;
1764         }
1765
1766         LABEL(skip_eventchase_death);
1767
1768         // do lockview after event chase camera so that it still applies whenever necessary.
1769         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1770         {
1771                 setproperty(VF_ORIGIN, freeze_org);
1772                 setproperty(VF_ANGLES, freeze_ang);
1773         }
1774         else
1775         {
1776                 freeze_org = getpropertyvec(VF_ORIGIN);
1777                 freeze_ang = getpropertyvec(VF_ANGLES);
1778         }
1779
1780         WarpZone_FixView();
1781         //WarpZone_FixPMove();
1782
1783         vector ov_org = '0 0 0';
1784         vector ov_mid = '0 0 0';
1785         vector ov_worldmin = '0 0 0';
1786         vector ov_worldmax = '0 0 0';
1787         if(autocvar_cl_orthoview)
1788         {
1789                 ov_worldmin = mi_picmin;
1790                 ov_worldmax = mi_picmax;
1791
1792                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1793                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1794                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1795
1796                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1797                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1798
1799                 float ov_nearest = vlen(ov_org - vec3(
1800                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1801                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1802                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1803                 ));
1804
1805                 float ov_furthest = 0;
1806                 float dist = 0;
1807
1808                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1809                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1810                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1811                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1812                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1813                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1814                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1815                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1816
1817                 if(!ov_enabled)
1818                 {
1819                         oldr_nearclip = cvar("r_nearclip");
1820                         oldr_farclip_base = cvar("r_farclip_base");
1821                         oldr_farclip_world = cvar("r_farclip_world");
1822                         oldr_novis = cvar("r_novis");
1823                         oldr_useportalculling = cvar("r_useportalculling");
1824                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1825                 }
1826
1827                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1828                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1829                 cvar_settemp("r_farclip_world", "0");
1830                 cvar_settemp("r_novis", "1");
1831                 cvar_settemp("r_useportalculling", "0");
1832                 cvar_settemp("r_useinfinitefarclip", "0");
1833
1834                 setproperty(VF_ORIGIN, ov_org);
1835                 setproperty(VF_ANGLES, '90 0 0');
1836
1837                 ov_enabled = true;
1838
1839                 #if 0
1840                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1841                         vtos(ov_org),
1842                         vtos(getpropertyvec(VF_ANGLES)),
1843                         ov_distance,
1844                         ov_nearest,
1845                         ov_furthest);
1846                 #endif
1847         }
1848         else
1849         {
1850                 if(ov_enabled)
1851                 {
1852                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1853                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1854                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1855                         cvar_set("r_novis", ftos(oldr_novis));
1856                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1857                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1858                 }
1859                 ov_enabled = false;
1860         }
1861
1862         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1863         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1864         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1865                 viewmodel_draw(viewmodels[slot]);
1866
1867         // Render the Scene
1868         view_origin = getpropertyvec(VF_ORIGIN);
1869         view_angles = getpropertyvec(VF_ANGLES);
1870         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1871
1872 #ifdef BLURTEST
1873         if(time > blurtest_time0 && time < blurtest_time1)
1874         {
1875                 float r, t;
1876
1877                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1878                 r = t * blurtest_radius;
1879                 f = 1 / (t ** blurtest_power) - 1;
1880
1881                 cvar_set("r_glsl_postprocess", "1");
1882                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1883         }
1884         else
1885         {
1886                 cvar_set("r_glsl_postprocess", "0");
1887                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1888         }
1889 #endif
1890
1891         TargetMusic_Advance();
1892         Fog_Force();
1893         fpscounter_update();
1894
1895         if(drawtime == 0)
1896                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1897         else
1898                 drawframetime = bound(0.000001, time - drawtime, 1);
1899         drawtime = time;
1900
1901         // watch for gametype changes here...
1902         // in ParseStuffCMD the cmd isn't executed yet :/
1903         // might even be better to add the gametype to TE_CSQC_INIT...?
1904         if(!postinit)
1905                 PostInit();
1906
1907         if(intermission && !intermission_time)
1908                 intermission_time = time;
1909
1910         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1911         {
1912                 if(calledhooks & HOOK_START)
1913                 {
1914                         localcmd("\ncl_hook_gameend\n");
1915                         calledhooks |= HOOK_END;
1916                 }
1917         }
1918
1919         Announcer();
1920
1921         fov = autocvar_fov;
1922         if(fov <= 59.5)
1923         {
1924                 if(!zoomscript_caught)
1925                 {
1926                         localcmd("+button9\n");
1927                         zoomscript_caught = 1;
1928                 }
1929         }
1930         else
1931         {
1932                 if(zoomscript_caught)
1933                 {
1934                         localcmd("-button9\n");
1935                         zoomscript_caught = 0;
1936                 }
1937         }
1938
1939         if(active_minigame && HUD_MinigameMenu_IsOpened())
1940         {
1941                 if(!minigame_wasactive)
1942                 {
1943                         localcmd("+button12\n");
1944                         minigame_wasactive = true;
1945                 }
1946         }
1947         else if(minigame_wasactive)
1948         {
1949                 localcmd("-button12\n");
1950                 minigame_wasactive = false;
1951         }
1952
1953         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1954
1955         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1956         {
1957                 entity wepent = viewmodels[slot];
1958
1959                 if(wepent.last_switchweapon != wepent.switchweapon)
1960                 {
1961                         weapontime = time;
1962                         wepent.last_switchweapon = wepent.switchweapon;
1963                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1964                         {
1965                                 localcmd("-zoom\n");
1966                                 button_zoom = false;
1967                         }
1968                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1969                         {
1970                                 localcmd("-fire\n");
1971                                 localcmd("-fire2\n");
1972                                 button_attack2 = false;
1973                         }
1974                 }
1975                 if(wepent.last_activeweapon != wepent.activeweapon)
1976                 {
1977                         wepent.last_activeweapon = wepent.activeweapon;
1978
1979                         e = wepent.activeweapon;
1980                         if(e.netname != "")
1981                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1982                         else if(slot == 0)
1983                                 localcmd("\ncl_hook_activeweapon none\n");
1984                 }
1985         }
1986
1987         // ALWAYS Clear Current Scene First
1988         clearscene();
1989
1990         setproperty(VF_ORIGIN, view_origin);
1991         setproperty(VF_ANGLES, view_angles);
1992
1993         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1994         setproperty(VF_SIZE, vf_size);
1995         setproperty(VF_MIN, vf_min);
1996
1997         // Assign Standard Viewflags
1998         // Draw the World (and sky)
1999         setproperty(VF_DRAWWORLD, 1);
2000
2001         // Set the console size vars
2002         vid_conwidth = autocvar_vid_conwidth;
2003         vid_conheight = autocvar_vid_conheight;
2004         vid_pixelheight = autocvar_vid_pixelheight;
2005
2006         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2007         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2008         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2009
2010         if(camera_active) // Camera for demo playback
2011         {
2012                 if(autocvar_camera_enable)
2013                         CSQC_Demo_Camera();
2014                 else
2015                 {
2016                         cvar_set("chase_active", ftos(chase_active_backup));
2017                         cvar_set("cl_demo_mousegrab", "0");
2018                         camera_active = false;
2019                 }
2020         }
2021         else
2022         {
2023 #ifdef CAMERATEST
2024                 if(autocvar_camera_enable)
2025 #else
2026                 if(autocvar_camera_enable && isdemo())
2027 #endif
2028                 {
2029                         // Enable required Darkplaces cvars
2030                         chase_active_backup = autocvar_chase_active;
2031                         cvar_set("chase_active", "2");
2032                         cvar_set("cl_demo_mousegrab", "1");
2033                         camera_active = true;
2034                         camera_mode = false;
2035                 }
2036         }
2037
2038         // Draw the Crosshair
2039         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2040
2041         // Draw the Engine Status Bar (the default Quake HUD)
2042         setproperty(VF_DRAWENGINESBAR, 0);
2043
2044         // Update the mouse position
2045         /*
2046            mousepos_x = vid_conwidth;
2047            mousepos_y = vid_conheight;
2048            mousepos = mousepos*0.5 + getmousepos();
2049          */
2050
2051         IL_EACH(g_drawables, it.draw, it.draw(it));
2052
2053         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2054         renderscene();
2055
2056         // now switch to 2D drawing mode by calling a 2D drawing function
2057         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2058         // next R_RenderScene call
2059         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2060
2061         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2062         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2063         {
2064                 // apply night vision effect
2065                 vector tc_00, tc_01, tc_10, tc_11;
2066                 vector rgb = '0 0 0';
2067
2068                 if(!nightvision_noise)
2069                 {
2070                         nightvision_noise = new(nightvision_noise);
2071                 }
2072                 if(!nightvision_noise2)
2073                 {
2074                         nightvision_noise2 = new(nightvision_noise2);
2075                 }
2076
2077                 // color tint in yellow
2078                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2079
2080                 // draw BG
2081                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2082                 rgb = '1 1 1';
2083                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2084                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2085                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2086                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2087                 tc_11 = tc_01 + tc_10 - tc_00;
2088                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2089                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2090                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2091                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2092                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2093                 R_EndPolygon();
2094
2095                 // draw FG
2096                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2097                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2098                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2099                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2100                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2101                 tc_11 = tc_01 + tc_10 - tc_00;
2102                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2103                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2104                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2105                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2106                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2107                 R_EndPolygon();
2108         }
2109
2110         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2111         {
2112                 string reticle_image = string_null;
2113                 bool wep_zoomed = false;
2114                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2115                 {
2116                         entity wepe = viewmodels[slot];
2117                         Weapon wep = wepe.activeweapon;
2118                         if(wep != WEP_Null && wep.wr_zoom)
2119                         {
2120                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2121                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2122                                         reticle_image = wep.w_reticle;
2123                                 wep_zoomed += do_zoom;
2124                         }
2125                 }
2126                 // Draw the aiming reticle for weapons that use it
2127                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2128                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2129                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2130                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2131                 {
2132                         // no zoom reticle while dead
2133                         reticle_type = 0;
2134                 }
2135                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2136                 {
2137                         if(reticle_image) { reticle_type = 2; }
2138                         else { reticle_type = 0; }
2139                 }
2140                 else if(button_zoom || zoomscript_caught)
2141                 {
2142                         // normal zoom
2143                         reticle_type = 1;
2144                 }
2145
2146                 if(reticle_type)
2147                 {
2148                         if(autocvar_cl_reticle_stretch)
2149                         {
2150                                 reticle_size.x = vid_conwidth;
2151                                 reticle_size.y = vid_conheight;
2152                                 reticle_pos.x = 0;
2153                                 reticle_pos.y = 0;
2154                         }
2155                         else
2156                         {
2157                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2158                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2159                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2160                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2161                         }
2162
2163                         if(zoomscript_caught)
2164                                 f = 1;
2165                         else
2166                                 f = current_zoomfraction;
2167
2168                         if(f)
2169                         {
2170                                 switch(reticle_type)
2171                                 {
2172                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2173                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2174                                 }
2175                         }
2176                 }
2177         }
2178         else
2179         {
2180                 if(reticle_type != 0) { reticle_type = 0; }
2181         }
2182
2183
2184         // improved polyblend
2185         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2186         {
2187                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2188                 vector liquidcolor;
2189
2190                 switch(pointcontents(view_origin))
2191                 {
2192                         case CONTENT_WATER:
2193                                 liquidalpha = autocvar_hud_contents_water_alpha;
2194                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2195                                 incontent = 1;
2196                                 break;
2197
2198                         case CONTENT_LAVA:
2199                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2200                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2201                                 incontent = 1;
2202                                 break;
2203
2204                         case CONTENT_SLIME:
2205                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2206                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2207                                 incontent = 1;
2208                                 break;
2209
2210                         default:
2211                                 liquidalpha = 0;
2212                                 liquidcolor = '0 0 0';
2213                                 incontent = 0;
2214                                 break;
2215                 }
2216
2217                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2218                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2219                         contentfadetime = autocvar_hud_contents_fadeintime;
2220                         liquidalpha_prev = liquidalpha;
2221                         liquidcolor_prev = liquidcolor;
2222                 }
2223                 else
2224                         contentfadetime = autocvar_hud_contents_fadeouttime;
2225
2226                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2227                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2228
2229                 if(contentavgalpha)
2230                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2231
2232                 if(autocvar_hud_postprocessing)
2233                 {
2234                         if(autocvar_hud_contents_blur && contentavgalpha)
2235                         {
2236                                 content_blurpostprocess.x = 1;
2237                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2238                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2239                         }
2240                         else
2241                         {
2242                                 content_blurpostprocess.x = 0;
2243                                 content_blurpostprocess.y = 0;
2244                                 content_blurpostprocess.z = 0;
2245                         }
2246                 }
2247         }
2248
2249         if(autocvar_hud_damage && !STAT(FROZEN))
2250         {
2251                 splash_size.x = max(vid_conwidth, vid_conheight);
2252                 splash_size.y = max(vid_conwidth, vid_conheight);
2253                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2254                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2255
2256                 float myhealth_flash_temp;
2257                 myhealth = STAT(HEALTH);
2258
2259                 // fade out
2260                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2261                 // add new damage
2262                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2263
2264                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2265                 pain_threshold = autocvar_hud_damage_pain_threshold;
2266                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2267                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2268
2269                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2270                 {
2271                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2272                 }
2273
2274                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2275
2276                 if(myhealth_prev < 1)
2277                 {
2278                         if(myhealth >= 1)
2279                         {
2280                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2281                                 myhealth_flash_temp = 0;
2282                         }
2283                         else
2284                         {
2285                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2286                         }
2287                 }
2288
2289                 if(spectatee_status == -1 || intermission)
2290                 {
2291                         myhealth_flash = 0; // observing, or match ended
2292                         myhealth_flash_temp = 0;
2293                 }
2294
2295                 myhealth_prev = myhealth;
2296
2297                 // IDEA: change damage color/picture based on player model for robot/alien species?
2298                 // pro: matches model better
2299                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2300                 // maybe different reddish pics?
2301                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2302                 {
2303                         if(autocvar_cl_gentle_damage == 2)
2304                         {
2305                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2306                                         myhealth_gentlergb = randomvec();
2307                         }
2308                         else
2309                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2310
2311                         if(myhealth_flash_temp > 0)
2312                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2313                 }
2314                 else if(myhealth_flash_temp > 0)
2315                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2316
2317                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2318                 {
2319                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2320                         {
2321                                 damage_blurpostprocess.x = 1;
2322                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2323                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2324                         }
2325                         else
2326                         {
2327                                 damage_blurpostprocess.x = 0;
2328                                 damage_blurpostprocess.y = 0;
2329                                 damage_blurpostprocess.z = 0;
2330                         }
2331                 }
2332         }
2333
2334         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2335         float e2 = (autocvar_hud_powerup != 0);
2336         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2337         {
2338                 // enable or disable rendering types if they are used or not
2339                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2340                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2341
2342                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2343                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2344                 {
2345                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2346                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2347                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2348                         {
2349                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2350                                 old_blurradius = blurradius;
2351                                 old_bluralpha = bluralpha;
2352                         }
2353                 }
2354                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2355                 {
2356                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2357                         old_blurradius = 0;
2358                         old_bluralpha = 0;
2359                 }
2360
2361                 // edge detection postprocess handling done second (used by hud_powerup)
2362                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2363                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2364                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2365
2366                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2367
2368                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2369                 {
2370                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2371                         {
2372                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2373                                 old_sharpen_intensity = sharpen_intensity;
2374                         }
2375                 }
2376                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2377                 {
2378                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2379                         old_sharpen_intensity = 0;
2380                 }
2381
2382                 if(cvar("r_glsl_postprocess") == 0)
2383                         cvar_set("r_glsl_postprocess", "2");
2384         }
2385         else if(cvar("r_glsl_postprocess") == 2)
2386                 cvar_set("r_glsl_postprocess", "0");
2387
2388         /*if(ISGAMETYPE(CTF))
2389           {
2390           ctf_view();
2391           } else */
2392
2393         // draw 2D entities
2394         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2395         Draw_ShowNames_All();
2396 #if ENABLE_DEBUGDRAW
2397         Debug_Draw();
2398 #endif
2399
2400         scoreboard_active = Scoreboard_WouldDraw();
2401
2402         HUD_Draw(this); // this parameter for deep vehicle function
2403
2404         if(NextFrameCommand)
2405         {
2406                 localcmd("\n", NextFrameCommand, "\n");
2407                 NextFrameCommand = string_null;
2408         }
2409
2410         // we must do this check AFTER a frame was rendered, or it won't work
2411         if(cs_project_is_b0rked == 0)
2412         {
2413                 string w0, h0;
2414                 w0 = ftos(autocvar_vid_conwidth);
2415                 h0 = ftos(autocvar_vid_conheight);
2416                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2417                 //setproperty(VF_FOV, '90 90 0');
2418                 setproperty(VF_ORIGIN, '0 0 0');
2419                 setproperty(VF_ANGLES, '0 0 0');
2420                 setproperty(VF_PERSPECTIVE, 1);
2421                 vector forward, right, up;
2422                 MAKE_VECTORS('0 0 0', forward, right, up);
2423                 vector v1, v2;
2424                 cvar_set("vid_conwidth", "800");
2425                 cvar_set("vid_conheight", "600");
2426                 v1 = cs_project(forward);
2427                 cvar_set("vid_conwidth", "640");
2428                 cvar_set("vid_conheight", "480");
2429                 v2 = cs_project(forward);
2430                 if(v1 == v2)
2431                         cs_project_is_b0rked = 1;
2432                 else
2433                         cs_project_is_b0rked = -1;
2434                 cvar_set("vid_conwidth", w0);
2435                 cvar_set("vid_conheight", h0);
2436         }
2437
2438         HUD_Mouse(local_player);
2439
2440         cl_notice_run();
2441         unpause_update();
2442         Net_Flush();
2443
2444         // let's reset the view back to normal for the end
2445         setproperty(VF_MIN, '0 0 0');
2446         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2447
2448         IL_ENDFRAME();
2449 }
2450
2451
2452 // following vectors must be global to allow seamless switching between camera modes
2453 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2454 void CSQC_Demo_Camera()
2455 {
2456         float speed, attenuation, dimensions;
2457         vector tmp, delta;
2458
2459         if( autocvar_camera_reset || !camera_mode )
2460         {
2461                 camera_offset = '0 0 0';
2462                 current_angles = '0 0 0';
2463                 camera_direction = '0 0 0';
2464                 camera_offset.z += 30;
2465                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2466                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2467                 current_origin = view_origin;
2468                 current_camera_offset  = camera_offset;
2469                 cvar_set("camera_reset", "0");
2470                 camera_mode = CAMERA_CHASE;
2471         }
2472
2473         // Camera angles
2474         if( camera_roll )
2475                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2476
2477         if(autocvar_camera_look_player)
2478         {
2479                 vector dir;
2480                 float n;
2481
2482                 dir = normalize(view_origin - current_position);
2483                 n = mouse_angles.z;
2484                 mouse_angles = vectoangles(dir);
2485                 mouse_angles.x = mouse_angles.x * -1;
2486                 mouse_angles.z = n;
2487         }
2488         else
2489         {
2490                 tmp = getmousepos() * 0.1;
2491                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2492                 {
2493                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2494                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2495                 }
2496         }
2497
2498         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2499         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2500         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2501         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2502
2503         // Fix difference when angles don't have the same sign
2504         delta = '0 0 0';
2505         if(mouse_angles.y < -60 && current_angles.y > 60)
2506                 delta = '0 360 0';
2507         if(mouse_angles.y > 60 && current_angles.y < -60)
2508                 delta = '0 -360 0';
2509
2510         if(autocvar_camera_look_player)
2511                 attenuation = autocvar_camera_look_attenuation;
2512         else
2513                 attenuation = autocvar_camera_speed_attenuation;
2514
2515         attenuation = 1 / max(1, attenuation);
2516         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2517
2518         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2519         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2520         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2521         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2522
2523         // Camera position
2524         tmp = '0 0 0';
2525         dimensions = 0;
2526
2527         if( camera_direction.x )
2528         {
2529                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2530                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2531                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2532                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2533                 ++dimensions;
2534         }
2535
2536         if( camera_direction.y )
2537         {
2538                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2539                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2540                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2541                 ++dimensions;
2542         }
2543
2544         if( camera_direction.z )
2545         {
2546                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2547                 ++dimensions;
2548         }
2549
2550         if(autocvar_camera_free)
2551                 speed = autocvar_camera_speed_free;
2552         else
2553                 speed = autocvar_camera_speed_chase;
2554
2555         if(dimensions)
2556         {
2557                 speed = speed * sqrt(1 / dimensions);
2558                 camera_offset += tmp * speed;
2559         }
2560
2561         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2562
2563         // Camera modes
2564         if( autocvar_camera_free )
2565         {
2566                 if ( camera_mode == CAMERA_CHASE )
2567                 {
2568                         current_camera_offset = current_origin + current_camera_offset;
2569                         camera_offset = current_origin + camera_offset;
2570                 }
2571
2572                 camera_mode = CAMERA_FREE;
2573                 current_position = current_camera_offset;
2574         }
2575         else
2576         {
2577                 if ( camera_mode == CAMERA_FREE )
2578                 {
2579                         current_origin = view_origin;
2580                         camera_offset = camera_offset - current_origin;
2581                         current_camera_offset = current_camera_offset - current_origin;
2582                 }
2583
2584                 camera_mode = CAMERA_CHASE;
2585
2586                 if(autocvar_camera_chase_smoothly)
2587                         current_origin += (view_origin - current_origin) * attenuation;
2588                 else
2589                         current_origin = view_origin;
2590
2591                 current_position = current_origin + current_camera_offset;
2592         }
2593
2594         setproperty(VF_ANGLES, current_angles);
2595         setproperty(VF_ORIGIN, current_position);
2596 }