qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 135;
  44 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47 bool autocvar_cl_followmodel_velocity_absolute;
  48
  49 float autocvar_cl_leanmodel;
  50 float autocvar_cl_leanmodel_speed = 0.3;
  51 float autocvar_cl_leanmodel_limit = 30;
  52 float autocvar_cl_leanmodel_highpass1 = 0.2;
  53 float autocvar_cl_leanmodel_highpass = 0.2;
  54 float autocvar_cl_leanmodel_lowpass = 0.05;
  55
  56 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  57 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  58 { \
  59         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  60 } MACRO_END
  61
  62 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  65         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  66 } MACRO_END
  67
  68 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  69 { \
  70         float __f = 0; lowpass(value, frac, ref_store, __f); \
  71         ret = (value) - __f; \
  72 } MACRO_END
  73
  74 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  77         ret = (value) - __f; \
  78 } MACRO_END
  79
  80 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  81 { \
  82         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  83         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  84 } MACRO_END
  85
  86 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  87 { \
  88         highpass(value.x, frac, ref_store.x, ref_out.x); \
  89         highpass(value.y, frac, ref_store.y, ref_out.y); \
  90 } MACRO_END
  91
  92 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  95         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 101         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 102         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 103 } MACRO_END
 104
 105 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         highpass(value.x, frac, ref_store.x, ref_out.x); \
 108         highpass(value.y, frac, ref_store.y, ref_out.y); \
 109         highpass(value.z, frac, ref_store.z, ref_out.z); \
 110 } MACRO_END
 111
 112 void viewmodel_animate(entity this)
 113 {
 114         static float prevtime;
 115         float frametime = (time - prevtime);
 116         prevtime = time;
 117
 118         if (autocvar_chase_active) return;
 119         if (STAT(HEALTH) <= 0) return;
 120
 121         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 122
 123         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 124         static bool oldonground;
 125         static float hitgroundtime;
 126         static float lastongroundtime;
 127         if (clonground)
 128         {
 129                 float f = time; // cl.movecmd[0].time
 130                 if (!oldonground)
 131                         hitgroundtime = f;
 132                 lastongroundtime = f;
 133         }
 134         oldonground = clonground;
 135
 136
 137         bool teleported = view.csqcmodel_teleported;
 138
 139         float frac;
 140         if(autocvar_cl_followmodel)
 141         {
 142                 vector gunorg = '0 0 0';
 143                 static vector vel_average;
 144                 static vector gunorg_prev = '0 0 0';
 145                 static vector gunorg_adjustment_highpass;
 146                 static vector gunorg_adjustment_lowpass;
 147
 148                 vector vel;
 149                 if(autocvar_cl_followmodel_velocity_absolute)
 150                         vel = view.velocity;
 151                 else
 152                 {
 153                         vector forward, right = '0 0 0', up = '0 0 0';
 154                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 155                         vel.x = view.velocity * forward;
 156                         vel.y = view.velocity * right * -1;
 157                         vel.z = view.velocity * up;
 158                 }
 159
 160                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 161                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 162                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 163
 164                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 165                 lowpass3(vel, frac, vel_average, gunorg);
 166
 167                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 168
 169                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 170                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 171                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 172                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 173                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 174                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 175
 176                 if(autocvar_cl_followmodel_velocity_absolute)
 177                 {
 178                         vector fixed_gunorg;
 179                         vector forward, right = '0 0 0', up = '0 0 0';
 180                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 181                         fixed_gunorg.x = gunorg * forward;
 182                         fixed_gunorg.y = gunorg * right * -1;
 183                         fixed_gunorg.z = gunorg * up;
 184                         gunorg = fixed_gunorg;
 185                 }
 186
 187                 this.origin += gunorg;
 188         }
 189
 190         if(autocvar_cl_leanmodel)
 191         {
 192                 vector gunangles = '0 0 0';
 193                 static vector gunangles_prev = '0 0 0';
 194                 static vector gunangles_highpass = '0 0 0';
 195                 static vector gunangles_adjustment_highpass;
 196                 static vector gunangles_adjustment_lowpass;
 197
 198                 if (teleported)
 199                         gunangles_prev = view_angles;
 200
 201                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 202                 gunangles_highpass += gunangles_prev;
 203                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 204                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 205                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 206                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 207                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 208                 gunangles_prev = view_angles;
 209                 gunangles_highpass -= gunangles_prev;
 210
 211                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 212                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 213
 214                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 215                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 216                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 217                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 218                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 219
 220                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 221                 this.angles += gunangles;
 222         }
 223
 224         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 225
 226         // vertical view bobbing code
 227         // TODO: cl_bob
 228
 229         // horizontal view bobbing code
 230         // TODO: cl_bob2
 231
 232         // fall bobbing code
 233         // causes the view to swing down and back up when touching the ground
 234         // TODO: cl_bobfall
 235
 236         // gun model bobbing code
 237         if (autocvar_cl_bobmodel)
 238         {
 239                 // calculate for swinging gun model
 240                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 241                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 242                 // for the most part, but for some reason when you go through a message trigger or
 243                 // pick up an item or anything like that it will momentarily jolt the gun.
 244                 float bspeed;
 245                 float t = 1;
 246                 float s = time * autocvar_cl_bobmodel_speed;
 247                 if (clonground)
 248                 {
 249                         if (time - hitgroundtime < 0.2)
 250                         {
 251                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 252                                 t = time - hitgroundtime;
 253                                 t = bound(0, t, 0.2);
 254                                 t *= 5;
 255                         }
 256                 }
 257                 else
 258                 {
 259                         // recently left the ground, slow the bob down over the next 0.2 seconds
 260                         t = time - lastongroundtime;
 261                         t = 0.2 - bound(0, t, 0.2);
 262                         t *= 5;
 263                 }
 264                 bspeed = xyspeed * 0.01;
 265                 vector gunorg = '0 0 0';
 266                 gunorg.y += bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 267                 gunorg.z += bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 268
 269                 this.origin += gunorg;
 270         }
 271 }
 272
 273 .vector viewmodel_origin, viewmodel_angles;
 274 .float weapon_nextthink;
 275 .float weapon_eta_last;
 276 .float weapon_switchdelay;
 277
 278 void viewmodel_draw(entity this)
 279 {
 280         if(!activeweapon)
 281                 return;
 282         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 283         float a = this.alpha;
 284         static bool wasinvehicle;
 285         bool invehicle = player_localentnum > maxclients;
 286         if (invehicle) a = -1;
 287         else if (wasinvehicle) a = 1;
 288         wasinvehicle = invehicle;
 289         Weapon wep = activeweapon;
 290         int c = stof(getplayerkeyvalue(current_player, "colors"));
 291         vector g = weaponentity_glowmod(wep, c);
 292         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 293         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 294                 | EF_NODEPTHTEST)
 295                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 296         for (entity e = this; e; e = e.weaponchild)
 297         {
 298                 e.drawmask = mask;
 299                 e.alpha = a;
 300                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 301                 e.glowmod = g;
 302                 e.csqcmodel_effects = fx;
 303                 CSQCModel_Effects_Apply(e);
 304         }
 305         {
 306                 static string name_last;
 307                 string name = wep.mdl;
 308                 if (name != name_last)
 309                 {
 310                         name_last = name;
 311                         CL_WeaponEntity_SetModel(this, name);
 312                         this.viewmodel_origin = this.origin;
 313                         this.viewmodel_angles = this.angles;
 314                 }
 315                 anim_update(this);
 316                 if (!this.animstate_override)
 317                         anim_set(this, this.anim_idle, true, false, false);
 318         }
 319         float f = 0; // 0..1; 0: fully active
 320         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 321         if (eta <= 0) f = this.weapon_eta_last;
 322         else switch (this.state)
 323         {
 324                 case WS_RAISE:
 325                 {
 326                         f = eta / max(eta, this.weapon_switchdelay);
 327                         break;
 328                 }
 329                 case WS_DROP:
 330                 {
 331                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 332                         break;
 333                 }
 334                 case WS_CLEAR:
 335                 {
 336                         f = 1;
 337                         break;
 338                 }
 339         }
 340         this.weapon_eta_last = f;
 341         this.origin = this.viewmodel_origin;
 342         this.angles = this.viewmodel_angles;
 343         this.angles_x = (-90 * f * f);
 344         viewmodel_animate(this);
 345         setorigin(this, this.origin);
 346 }
 347
 348 entity viewmodel;
 349 STATIC_INIT(viewmodel) {
 350     viewmodel = new(viewmodel);
 351     make_pure(viewmodel);
 352 }
 353
 354 entity porto;
 355 vector polyline[16];
 356 void Porto_Draw(entity this)
 357 {
 358         vector p, dir, ang, q, nextdir;
 359         float portal_number, portal1_idx;
 360
 361         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 362                 return;
 363         if(WEP_CVAR(porto, secondary))
 364                 return;
 365         if(intermission == 1)
 366                 return;
 367         if(intermission == 2)
 368                 return;
 369         if (STAT(HEALTH) <= 0)
 370                 return;
 371
 372         dir = view_forward;
 373
 374         if(angles_held_status)
 375         {
 376                 makevectors(angles_held);
 377                 dir = v_forward;
 378         }
 379
 380         p = view_origin;
 381
 382         polyline[0] = p;
 383         int idx = 1;
 384         portal_number = 0;
 385         nextdir = dir;
 386
 387         for (;;)
 388         {
 389                 dir = nextdir;
 390                 traceline(p, p + 65536 * dir, true, porto);
 391                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 392                         return;
 393                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 394                 p = trace_endpos;
 395                 polyline[idx] = p;
 396                 ++idx;
 397                 if(idx >= 16)
 398                         return;
 399                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 400                         continue;
 401                 ++portal_number;
 402                 ang = vectoangles2(trace_plane_normal, dir);
 403                 ang.x = -ang.x;
 404                 makevectors(ang);
 405                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 406                         return;
 407                 if(portal_number == 1)
 408                 {
 409                         portal1_idx = idx;
 410                         if(portal_number >= 2)
 411                                 break;
 412                 }
 413         }
 414
 415         while(idx >= 2)
 416         {
 417                 p = polyline[idx-2];
 418                 q = polyline[idx-1];
 419                 if(idx == 2)
 420                         p = p - view_up * 16;
 421                 if(idx-1 >= portal1_idx)
 422                 {
 423                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 424                 }
 425                 else
 426                 {
 427                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 428                 }
 429                 --idx;
 430         }
 431 }
 432
 433 void Porto_Init()
 434 {
 435         porto = new(porto);
 436         make_pure(porto);
 437         porto.draw = Porto_Draw;
 438         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 439 }
 440
 441 float drawtime;
 442 float avgspeed;
 443 vector GetCurrentFov(float fov)
 444 {
 445         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 446         float velocityzoom, curspeed;
 447         vector v;
 448
 449         zoomsensitivity = autocvar_cl_zoomsensitivity;
 450         zoomfactor = autocvar_cl_zoomfactor;
 451         if(zoomfactor < 1 || zoomfactor > 30)
 452                 zoomfactor = 2.5;
 453         zoomspeed = autocvar_cl_zoomspeed;
 454         if(zoomspeed >= 0)
 455         if(zoomspeed < 0.5 || zoomspeed > 16)
 456                         zoomspeed = 3.5;
 457
 458         zoomdir = button_zoom;
 459         if(hud == HUD_NORMAL)
 460         if(switchweapon == activeweapon)
 461         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 462                 zoomdir += button_attack2;
 463         if(spectatee_status > 0 || isdemo())
 464         {
 465                 if(spectatorbutton_zoom)
 466                 {
 467                         if(zoomdir)
 468                                 zoomdir = 0;
 469                         else
 470                                 zoomdir = 1;
 471                 }
 472                 // fteqcc failed twice here already, don't optimize this
 473         }
 474
 475         if(zoomdir) { zoomin_effect = 0; }
 476
 477         if(camera_active)
 478         {
 479                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 480         }
 481         else if(autocvar_cl_spawnzoom && zoomin_effect)
 482         {
 483                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 484
 485                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 486                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 487                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 488         }
 489         else
 490         {
 491                 if(zoomspeed < 0) // instant zoom
 492                 {
 493                         if(zoomdir)
 494                                 current_viewzoom = 1 / zoomfactor;
 495                         else
 496                                 current_viewzoom = 1;
 497                 }
 498                 else
 499                 {
 500                         if(zoomdir)
 501                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 502                         else
 503                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 504                 }
 505         }
 506
 507         if(almost_equals(current_viewzoom, 1))
 508                 current_zoomfraction = 0;
 509         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 510                 current_zoomfraction = 1;
 511         else
 512                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 513
 514         if(zoomsensitivity < 1)
 515                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 516         else
 517                 setsensitivityscale(1);
 518
 519         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 520         {
 521                 if(intermission) { curspeed = 0; }
 522                 else
 523                 {
 524
 525                         makevectors(view_angles);
 526                         v = pmove_vel;
 527                         if(csqcplayer)
 528                                 v = csqcplayer.velocity;
 529
 530                         switch(autocvar_cl_velocityzoom_type)
 531                         {
 532                                 case 3: curspeed = max(0, v_forward * v); break;
 533                                 case 2: curspeed = (v_forward * v); break;
 534                                 case 1: default: curspeed = vlen(v); break;
 535                         }
 536                 }
 537
 538                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 539                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 540                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 541
 542                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 543         }
 544         else
 545                 velocityzoom = 1;
 546
 547         float frustumx, frustumy, fovx, fovy;
 548         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 549         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 550         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 551         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 552
 553         return '1 0 0' * fovx + '0 1 0' * fovy;
 554 }
 555
 556 vector GetViewLocationFOV(float fov)
 557 {
 558         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 559         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 560         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 561         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 562         return '1 0 0' * fovx + '0 1 0' * fovy;
 563 }
 564
 565 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 566 {
 567         float fovx, fovy;
 568         float width = (ov_worldmax.x - ov_worldmin.x);
 569         float height = (ov_worldmax.y - ov_worldmin.y);
 570         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 571         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 572         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 // this function must match W_SetupShot!
 577 float zoomscript_caught;
 578
 579 vector wcross_origin;
 580 float wcross_scale_prev, wcross_alpha_prev;
 581 vector wcross_color_prev;
 582 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 583 vector wcross_color_goal_prev;
 584 float wcross_changedonetime;
 585
 586 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 587 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 588 float wcross_name_changestarttime, wcross_name_changedonetime;
 589 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 590
 591 float wcross_ring_prev;
 592
 593 entity trueaim;
 594 entity trueaim_rifle;
 595
 596 const float SHOTTYPE_HITTEAM = 1;
 597 const float SHOTTYPE_HITOBSTRUCTION = 2;
 598 const float SHOTTYPE_HITWORLD = 3;
 599 const float SHOTTYPE_HITENEMY = 4;
 600
 601 void TrueAim_Init()
 602 {
 603         trueaim = new(trueaim);
 604         make_pure(trueaim);
 605         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 606         trueaim_rifle = new(trueaim_rifle);
 607         make_pure(trueaim_rifle);
 608         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 609 }
 610
 611 float EnemyHitCheck()
 612 {
 613         float t, n;
 614         wcross_origin = project_3d_to_2d(trace_endpos);
 615         wcross_origin.z = 0;
 616         if(trace_ent)
 617                 n = trace_ent.entnum;
 618         else
 619                 n = trace_networkentity;
 620         if(n < 1)
 621                 return SHOTTYPE_HITWORLD;
 622         if(n > maxclients)
 623                 return SHOTTYPE_HITWORLD;
 624         t = entcs_GetTeam(n - 1);
 625         if(teamplay)
 626                 if(t == myteam)
 627                         return SHOTTYPE_HITTEAM;
 628         if(t == NUM_SPECTATOR)
 629                 return SHOTTYPE_HITWORLD;
 630         return SHOTTYPE_HITENEMY;
 631 }
 632
 633 float TrueAimCheck()
 634 {
 635         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 636         vector vecs, trueaimpoint, w_shotorg;
 637         vector mi, ma, dv;
 638         float shottype;
 639         entity ta;
 640         float mv;
 641
 642         mi = ma = '0 0 0';
 643         ta = trueaim;
 644         mv = MOVE_NOMONSTERS;
 645
 646         switch(activeweapon) // WEAPONTODO
 647         {
 648                 case WEP_TUBA: // no aim
 649                 case WEP_PORTO: // shoots from eye
 650                 case WEP_NEXBALL: // shoots from eye
 651                 case WEP_HOOK: // no trueaim
 652                 case WEP_MORTAR: // toss curve
 653                         return SHOTTYPE_HITWORLD;
 654                 case WEP_VORTEX:
 655                 case WEP_VAPORIZER:
 656                         mv = MOVE_NORMAL;
 657                         break;
 658                 case WEP_RIFLE:
 659                         ta = trueaim_rifle;
 660                         mv = MOVE_NORMAL;
 661                         if(zoomscript_caught)
 662                         {
 663                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 664                                 return EnemyHitCheck();
 665                         }
 666                         break;
 667                 case WEP_DEVASTATOR: // projectile has a size!
 668                         mi = '-3 -3 -3';
 669                         ma = '3 3 3';
 670                         break;
 671                 case WEP_FIREBALL: // projectile has a size!
 672                         mi = '-16 -16 -16';
 673                         ma = '16 16 16';
 674                         break;
 675                 case WEP_SEEKER: // projectile has a size!
 676                         mi = '-2 -2 -2';
 677                         ma = '2 2 2';
 678                         break;
 679                 case WEP_ELECTRO: // projectile has a size!
 680                         mi = '0 0 -3';
 681                         ma = '0 0 -3';
 682                         break;
 683         }
 684
 685         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 686
 687         vecs = decompressShotOrigin(STAT(SHOTORG));
 688
 689         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 690         trueaimpoint = trace_endpos;
 691
 692         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 693                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 694
 695         if(vecs.x > 0)
 696                 vecs.y = -vecs.y;
 697         else
 698                 vecs = '0 0 0';
 699
 700         dv = view_right * vecs.y + view_up * vecs.z;
 701         w_shotorg = traceorigin + dv;
 702
 703         // now move the vecs forward as much as requested if possible
 704         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 705         w_shotorg = trace_endpos - view_forward * nudge;
 706
 707         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 708         shottype = EnemyHitCheck();
 709         if(shottype != SHOTTYPE_HITWORLD)
 710                 return shottype;
 711
 712 #if 0
 713         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 714         // or rather, I know why, but see no fix
 715         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 716                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 717                 return SHOTTYPE_HITOBSTRUCTION;
 718 #endif
 719
 720         return SHOTTYPE_HITWORLD;
 721 }
 722
 723 void PostInit();
 724 void CSQC_Demo_Camera();
 725 float HUD_WouldDrawScoreboard();
 726 float camera_mode;
 727 const float CAMERA_FREE = 1;
 728 const float CAMERA_CHASE = 2;
 729 float reticle_type;
 730 string reticle_image;
 731 string NextFrameCommand;
 732
 733 vector freeze_org, freeze_ang;
 734 entity nightvision_noise, nightvision_noise2;
 735
 736 const float MAX_TIME_DIFF = 5;
 737 float pickup_crosshair_time, pickup_crosshair_size;
 738 float hitindication_crosshair_size;
 739 float use_vortex_chargepool;
 740
 741 float myhealth, myhealth_prev;
 742 float myhealth_flash;
 743
 744 float old_blurradius, old_bluralpha;
 745 float old_sharpen_intensity;
 746
 747 vector myhealth_gentlergb;
 748
 749 float contentavgalpha, liquidalpha_prev;
 750 vector liquidcolor_prev;
 751
 752 float eventchase_current_distance;
 753 float eventchase_running;
 754 bool WantEventchase(entity this)
 755 {
 756         if(autocvar_cl_orthoview)
 757                 return false;
 758         if(intermission)
 759                 return true;
 760         if(this.viewloc)
 761                 return true;
 762         if(spectatee_status >= 0)
 763         {
 764                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 765                         return true;
 766                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 767                         return true;
 768                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 769                         return true;
 770                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 771                 {
 772                         if(autocvar_cl_eventchase_death == 2)
 773                         {
 774                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 775                                 if(this.velocity == '0 0 0' || eventchase_running)
 776                                         return true;
 777                         }
 778                         else return true;
 779                 }
 780         }
 781         return false;
 782 }
 783
 784 void HUD_Crosshair_Vehicle()
 785 {
 786         if(hud != HUD_BUMBLEBEE_GUN)
 787         {
 788                 Vehicle info = Vehicles_from(hud);
 789                 info.vr_crosshair(info);
 790         }
 791 }
 792
 793 vector damage_blurpostprocess, content_blurpostprocess;
 794
 795 float unaccounted_damage = 0;
 796 void UpdateDamage()
 797 {
 798         // accumulate damage with each stat update
 799         static float damage_total_prev = 0;
 800         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 801         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 802         damage_total_prev = damage_total;
 803
 804         static float damage_dealt_time_prev = 0;
 805         float damage_dealt_time = STAT(HIT_TIME);
 806         if (damage_dealt_time != damage_dealt_time_prev)
 807         {
 808                 unaccounted_damage += unaccounted_damage_new;
 809                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 810         }
 811         damage_dealt_time_prev = damage_dealt_time;
 812
 813         // prevent hitsound when switching spectatee
 814         static float spectatee_status_prev = 0;
 815         if (spectatee_status != spectatee_status_prev)
 816                 unaccounted_damage = 0;
 817         spectatee_status_prev = spectatee_status;
 818 }
 819
 820 void HitSound()
 821 {
 822         // varying sound pitch
 823
 824         static float hitsound_time_prev = 0;
 825         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 826         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 827         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 828         {
 829                 if (autocvar_cl_hitsound && unaccounted_damage)
 830                 {
 831                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 832                         float a = autocvar_cl_hitsound_max_pitch;
 833                         float b = autocvar_cl_hitsound_min_pitch;
 834                         float c = autocvar_cl_hitsound_nom_damage;
 835                         float x = unaccounted_damage;
 836                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 837
 838                         // if sound variation is disabled, set pitch_shift to 1
 839                         if (autocvar_cl_hitsound == 1)
 840                                 pitch_shift = 1;
 841
 842                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 843                         if (autocvar_cl_hitsound == 3)
 844                         {
 845                                 float mirror_value = (a-b)/2 + b;
 846                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 847                         }
 848
 849                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 850
 851                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 852                         // todo: normalize sound pressure levels? seems unnecessary
 853
 854                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 855                 }
 856                 unaccounted_damage = 0;
 857                 hitsound_time_prev = time;
 858         }
 859
 860         static float typehit_time_prev = 0;
 861         float typehit_time = STAT(TYPEHIT_TIME);
 862         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 863         {
 864                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 865                 typehit_time_prev = typehit_time;
 866         }
 867 }
 868
 869 void HUD_Crosshair()
 870 {SELFPARAM();
 871         static float rainbow_last_flicker;
 872         static vector rainbow_prev_color;
 873         entity e = this;
 874         float f, i, j;
 875         vector v;
 876         if(!scoreboard_active && !camera_active && intermission != 2 &&
 877                 spectatee_status != -1 && !csqcplayer.viewloc &&
 878                 !HUD_MinigameMenu_IsOpened() )
 879         {
 880                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 881                         return;
 882
 883                 if (hud != HUD_NORMAL)
 884                 {
 885                         HUD_Crosshair_Vehicle();
 886                         return;
 887                 }
 888
 889                 string wcross_style;
 890                 float wcross_alpha, wcross_resolution;
 891                 wcross_style = autocvar_crosshair;
 892                 if (wcross_style == "0")
 893                         return;
 894                 wcross_resolution = autocvar_crosshair_size;
 895                 if (wcross_resolution == 0)
 896                         return;
 897                 wcross_alpha = autocvar_crosshair_alpha;
 898                 if (wcross_alpha == 0)
 899                         return;
 900
 901                 // TrueAim check
 902                 float shottype;
 903
 904                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 905                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 906                 wcross_origin.z = 0;
 907                 if(autocvar_crosshair_hittest)
 908                 {
 909                         vector wcross_oldorigin;
 910                         wcross_oldorigin = wcross_origin;
 911                         shottype = TrueAimCheck();
 912                         if(shottype == SHOTTYPE_HITWORLD)
 913                         {
 914                                 v = wcross_origin - wcross_oldorigin;
 915                                 v.x /= vid_conwidth;
 916                                 v.y /= vid_conheight;
 917                                 if(vlen(v) > 0.01)
 918                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 919                         }
 920                         if(!autocvar_crosshair_hittest_showimpact)
 921                                 wcross_origin = wcross_oldorigin;
 922                 }
 923                 else
 924                         shottype = SHOTTYPE_HITWORLD;
 925
 926                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 927                 string wcross_name = "";
 928                 float wcross_scale, wcross_blur;
 929
 930                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 931                 {
 932                         e = switchingweapon;
 933                         if(e)
 934                         {
 935                                 if(autocvar_crosshair_per_weapon)
 936                                 {
 937                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 938                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 939                                         //if (wcross_resolution == 0)
 940                                                 //return;
 941
 942                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 943                                         wcross_resolution *= e.w_crosshair_size;
 944                                         wcross_name = e.w_crosshair;
 945                                 }
 946                         }
 947                 }
 948
 949                 if(wcross_name == "")
 950                         wcross_name = strcat("gfx/crosshair", wcross_style);
 951
 952                 // MAIN CROSSHAIR COLOR DECISION
 953                 switch(autocvar_crosshair_color_special)
 954                 {
 955                         case 1: // crosshair_color_per_weapon
 956                         {
 957                                 if(e)
 958                                 {
 959                                         wcross_color = e.wpcolor;
 960                                         break;
 961                                 }
 962                                 else { goto normalcolor; }
 963                         }
 964
 965                         case 2: // crosshair_color_by_health
 966                         {
 967                                 float x = STAT(HEALTH);
 968
 969                                 //x = red
 970                                 //y = green
 971                                 //z = blue
 972
 973                                 wcross_color.z = 0;
 974
 975                                 if(x > 200)
 976                                 {
 977                                         wcross_color.x = 0;
 978                                         wcross_color.y = 1;
 979                                 }
 980                                 else if(x > 150)
 981                                 {
 982                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 983                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 984                                 }
 985                                 else if(x > 100)
 986                                 {
 987                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 988                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 989                                         wcross_color.z = 1 - (x-100)*0.02;
 990                                 }
 991                                 else if(x > 50)
 992                                 {
 993                                         wcross_color.x = 1;
 994                                         wcross_color.y = 1;
 995                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 996                                 }
 997                                 else if(x > 20)
 998                                 {
 999                                         wcross_color.x = 1;
1000                                         wcross_color.y = (x-20)*90/27/100;
1001                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
1002                                 }
1003                                 else
1004                                 {
1005                                         wcross_color.x = 1;
1006                                         wcross_color.y = 0;
1007                                 }
1008                                 break;
1009                         }
1010
1011                         case 3: // crosshair_color_rainbow
1012                         {
1013                                 if(time >= rainbow_last_flicker)
1014                                 {
1015                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1016                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1017                                 }
1018                                 wcross_color = rainbow_prev_color;
1019                                 break;
1020                         }
1021                         :normalcolor
1022                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1023                 }
1024
1025                 if(autocvar_crosshair_effect_scalefade)
1026                 {
1027                         wcross_scale = wcross_resolution;
1028                         wcross_resolution = 1;
1029                 }
1030                 else
1031                 {
1032                         wcross_scale = 1;
1033                 }
1034
1035                 if(autocvar_crosshair_pickup)
1036                 {
1037                         float stat_pickup_time = STAT(LAST_PICKUP);
1038
1039                         if(pickup_crosshair_time < stat_pickup_time)
1040                         {
1041                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1042                                         pickup_crosshair_size = 1;
1043
1044                                 pickup_crosshair_time = stat_pickup_time;
1045                         }
1046
1047                         if(pickup_crosshair_size > 0)
1048                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1049                         else
1050                                 pickup_crosshair_size = 0;
1051
1052                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1053                 }
1054
1055                 // todo: make crosshair hit indication dependent on damage dealt
1056                 if(autocvar_crosshair_hitindication)
1057                 {
1058                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1059
1060                         if(unaccounted_damage)
1061                         {
1062                                 hitindication_crosshair_size = 1;
1063                         }
1064
1065                         if(hitindication_crosshair_size > 0)
1066                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1067                         else
1068                                 hitindication_crosshair_size = 0;
1069
1070                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1071                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1072                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1073                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1074                 }
1075
1076                 if(shottype == SHOTTYPE_HITENEMY)
1077                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1078                 if(shottype == SHOTTYPE_HITTEAM)
1079                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1080
1081                 f = fabs(autocvar_crosshair_effect_time);
1082                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1083                 {
1084                         wcross_changedonetime = time + f;
1085                 }
1086                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1087                 {
1088                         wcross_name_changestarttime = time;
1089                         wcross_name_changedonetime = time + f;
1090                         if(wcross_name_goal_prev_prev)
1091                                 strunzone(wcross_name_goal_prev_prev);
1092                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1093                         wcross_name_goal_prev = strzone(wcross_name);
1094                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1095                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1096                         wcross_resolution_goal_prev = wcross_resolution;
1097                 }
1098
1099                 wcross_scale_goal_prev = wcross_scale;
1100                 wcross_alpha_goal_prev = wcross_alpha;
1101                 wcross_color_goal_prev = wcross_color;
1102
1103                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1104                 {
1105                         wcross_blur = 1;
1106                         wcross_alpha *= 0.75;
1107                 }
1108                 else
1109                         wcross_blur = 0;
1110                 // *_prev is at time-frametime
1111                 // * is at wcross_changedonetime+f
1112                 // what do we have at time?
1113                 if(time < wcross_changedonetime)
1114                 {
1115                         f = frametime / (wcross_changedonetime - time + frametime);
1116                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1117                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1118                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1119                 }
1120
1121                 wcross_scale_prev = wcross_scale;
1122                 wcross_alpha_prev = wcross_alpha;
1123                 wcross_color_prev = wcross_color;
1124
1125                 MUTATOR_CALLHOOK(UpdateCrosshair);
1126
1127                 wcross_scale *= 1 - autocvar__menu_alpha;
1128                 wcross_alpha *= 1 - autocvar__menu_alpha;
1129                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1130
1131                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1132                 {
1133                         // crosshair rings for weapon stats
1134                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1135                         {
1136                                 // declarations and stats
1137                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1138                                 string ring_image = string_null, ring_inner_image = string_null;
1139                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1140
1141                                 ring_scale = autocvar_crosshair_ring_size;
1142
1143                                 float weapon_clipload, weapon_clipsize;
1144                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1145                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1146
1147                                 float ok_ammo_charge, ok_ammo_chargepool;
1148                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1149                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1150
1151                                 float vortex_charge, vortex_chargepool;
1152                                 vortex_charge = STAT(VORTEX_CHARGE);
1153                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1154
1155                                 float arc_heat = STAT(ARC_HEAT);
1156
1157                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1158                                         vortex_charge_movingavg = vortex_charge;
1159
1160
1161                                 // handle the values
1162                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1163                                 {
1164                                         if (vortex_chargepool || use_vortex_chargepool) {
1165                                                 use_vortex_chargepool = 1;
1166                                                 ring_inner_value = vortex_chargepool;
1167                                         } else {
1168                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1169                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1170                                         }
1171
1172                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1173                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1174                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1175
1176                                         // draw the outer ring to show the current charge of the weapon
1177                                         ring_value = vortex_charge;
1178                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1179                                         ring_rgb = wcross_color;
1180                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1181                                 }
1182                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1183                                 {
1184                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1185                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1186                                         ring_rgb = wcross_color;
1187                                         ring_image = "gfx/crosshair_ring.tga";
1188                                 }
1189                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1190                                 {
1191                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1192                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1193                                         ring_rgb = wcross_color;
1194                                         ring_image = "gfx/crosshair_ring.tga";
1195                                 }
1196                                 else if (ok_ammo_charge)
1197                                 {
1198                                         ring_value = ok_ammo_chargepool;
1199                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring.tga";
1202                                 }
1203                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1204                                 {
1205                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1206                                         ring_scale = autocvar_crosshair_ring_reload_size;
1207                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1208                                         ring_rgb = wcross_color;
1209
1210                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1211                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1212                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1213                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1214                                         else
1215                                                 ring_image = "gfx/crosshair_ring.tga";
1216                                 }
1217                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1218                                 {
1219                                         ring_value = arc_heat;
1220                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1221                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1222                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1223                                         ring_image = "gfx/crosshair_ring.tga";
1224                                 }
1225
1226                                 // if in weapon switch animation, fade ring out/in
1227                                 if(autocvar_crosshair_effect_time > 0)
1228                                 {
1229                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1230                                         if (f >= 1)
1231                                         {
1232                                                 wcross_ring_prev = ((ring_image) ? true : false);
1233                                         }
1234
1235                                         if(wcross_ring_prev)
1236                                         {
1237                                                 if(f < 1)
1238                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1239                                         }
1240                                         else
1241                                         {
1242                                                 if(f < 1)
1243                                                         ring_alpha *= bound(0, f, 1);
1244                                         }
1245                                 }
1246
1247                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1248                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1249
1250                                 if (ring_value)
1251                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1252                         }
1253
1254 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1255                         MACRO_BEGIN { \
1256                                 if(wcross_blur > 0) \
1257                                 { \
1258                                         for(i = -2; i <= 2; ++i) \
1259                                         for(j = -2; j <= 2; ++j) \
1260                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1261                                 } \
1262                                 else \
1263                                 { \
1264                                         M(0,0,sz,wcross_name,wcross_alpha); \
1265                                 } \
1266                         } MACRO_END
1267
1268 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1269                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1270
1271 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1272                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1273
1274                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1275                         {
1276                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1277                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1278                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1279                                 f = 1 - f;
1280                         }
1281                         else
1282                         {
1283                                 f = 1;
1284                         }
1285                         wcross_name_alpha_goal_prev = f;
1286
1287                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1288                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1289
1290                         if(autocvar_crosshair_dot)
1291                         {
1292                                 vector wcross_color_old;
1293                                 wcross_color_old = wcross_color;
1294
1295                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1296                                         wcross_color = stov(autocvar_crosshair_dot_color);
1297
1298                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1299                                 // FIXME why don't we use wcross_alpha here?
1300                                 wcross_color = wcross_color_old;
1301                         }
1302                 }
1303         }
1304         else
1305         {
1306                 wcross_scale_prev = 0;
1307                 wcross_alpha_prev = 0;
1308                 wcross_scale_goal_prev = 0;
1309                 wcross_alpha_goal_prev = 0;
1310                 wcross_changedonetime = 0;
1311                 if(wcross_name_goal_prev)
1312                         strunzone(wcross_name_goal_prev);
1313                 wcross_name_goal_prev = string_null;
1314                 if(wcross_name_goal_prev_prev)
1315                         strunzone(wcross_name_goal_prev_prev);
1316                 wcross_name_goal_prev_prev = string_null;
1317                 wcross_name_changestarttime = 0;
1318                 wcross_name_changedonetime = 0;
1319                 wcross_name_alpha_goal_prev = 0;
1320                 wcross_name_alpha_goal_prev_prev = 0;
1321                 wcross_resolution_goal_prev = 0;
1322                 wcross_resolution_goal_prev_prev = 0;
1323         }
1324 }
1325
1326 void HUD_Draw()
1327 {
1328         vector rgb = '0 0 0';
1329         float a = 1;
1330         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1331         {
1332                 rgb = MUTATOR_ARGV(0, vector);
1333                 a = MUTATOR_ARGV(0, float);
1334         }
1335         else if(STAT(FROZEN))
1336         {
1337                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1338         }
1339         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1340         if(!intermission)
1341         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1342         {
1343                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1344                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1345         }
1346         else if(STAT(REVIVE_PROGRESS))
1347         {
1348                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1349                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1350         }
1351
1352         if(autocvar_r_letterbox == 0)
1353                 if(autocvar_viewsize < 120)
1354                 {
1355                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1356                                 Accuracy_LoadLevels();
1357
1358                         HUD_Main();
1359                         HUD_DrawScoreboard();
1360                 }
1361
1362         // crosshair goes VERY LAST
1363         UpdateDamage();
1364         HUD_Crosshair();
1365         HitSound();
1366 }
1367
1368 bool ov_enabled;
1369 float oldr_nearclip;
1370 float oldr_farclip_base;
1371 float oldr_farclip_world;
1372 float oldr_novis;
1373 float oldr_useportalculling;
1374 float oldr_useinfinitefarclip;
1375
1376 void cl_notice_run();
1377 float prev_myteam;
1378 int lasthud;
1379 float vh_notice_time;
1380 void WaypointSprite_Load();
1381 void CSQC_UpdateView(float w, float h)
1382 {SELFPARAM();
1383         entity e;
1384         float fov;
1385         float f;
1386         vector vf_size, vf_min;
1387         float a;
1388
1389         execute_next_frame();
1390
1391         ++framecount;
1392
1393         stats_get();
1394         hud = STAT(HUD);
1395
1396         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1397                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1398
1399         lasthud = hud;
1400
1401         if(autocvar__hud_showbinds_reload) // menu can set this one
1402         {
1403                 db_close(binddb);
1404                 binddb = db_create();
1405                 cvar_set("_hud_showbinds_reload", "0");
1406         }
1407
1408         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1409                 view_quality = getproperty(VF_MINFPS_QUALITY);
1410         else
1411                 view_quality = 1;
1412
1413         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1414         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1415
1416         vf_size = getpropertyvec(VF_SIZE);
1417         vf_min = getpropertyvec(VF_MIN);
1418         vid_width = vf_size.x;
1419         vid_height = vf_size.y;
1420
1421         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1422         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1423
1424         WaypointSprite_Load();
1425
1426         CSQCPlayer_SetCamera();
1427
1428         if(player_localentnum <= maxclients) // is it a client?
1429                 current_player = player_localentnum - 1;
1430         else // then player_localentnum is the vehicle I'm driving
1431                 current_player = player_localnum;
1432         myteam = entcs_GetTeam(current_player);
1433
1434         if(myteam != prev_myteam)
1435         {
1436                 myteamcolors = colormapPaletteColor(myteam, 1);
1437                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1438                 prev_myteam = myteam;
1439         }
1440
1441         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1442
1443         float is_dead = (STAT(HEALTH) <= 0);
1444
1445         // FIXME do we need this hack?
1446         if(isdemo())
1447         {
1448                 // in demos, input_buttons do not work
1449                 button_zoom = (autocvar__togglezoom == "-");
1450         }
1451         else if(button_zoom
1452                 && autocvar_cl_unpress_zoom_on_death
1453                 && (spectatee_status >= 0)
1454                 && (is_dead || intermission))
1455         {
1456                 // no zoom while dead or in intermission please
1457                 localcmd("-zoom\n");
1458                 button_zoom = false;
1459         }
1460
1461         // event chase camera
1462         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1463         {
1464                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1465                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1466                 entity gen = world;
1467
1468                 float vehicle_viewdist = 0;
1469                 vector vehicle_viewofs = '0 0 0';
1470
1471                 if(vehicle_chase)
1472                 {
1473                         if(hud != HUD_BUMBLEBEE_GUN)
1474                         {
1475                                 Vehicle info = Vehicles_from(hud);
1476                                 vehicle_viewdist = info.height;
1477                                 vehicle_viewofs = info.view_ofs;
1478                         }
1479                 }
1480
1481                 if(ons_roundlost)
1482                 {
1483                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1484                                 gen = it;
1485                                 break;
1486                         ));
1487                         if(!gen)
1488                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1489                 }
1490                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1491                 {
1492                         eventchase_running = true;
1493
1494                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1495                         if(!local_player)
1496                                 local_player = self; // fall back!
1497
1498                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1499                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1500                         if(ons_roundlost) { current_view_origin = gen.origin; }
1501
1502                         // detect maximum viewoffset and use it
1503                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1504                         if(vehicle_chase)
1505                         {
1506                                 if(vehicle_viewofs)
1507                                         view_offset = vehicle_viewofs;
1508                                 else
1509                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1510                         }
1511                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1512
1513                         if(view_offset)
1514                         {
1515                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1516                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1517                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1518                         }
1519
1520                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1521                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1522                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1523                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1524
1525                         // make the camera smooth back
1526                         float chase_distance = autocvar_cl_eventchase_distance;
1527                         if(vehicle_chase)
1528                         {
1529                                 if(vehicle_viewofs)
1530                                         chase_distance = vehicle_viewdist;
1531                                 else
1532                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1533                         }
1534                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1535
1536                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1537                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1538                         else if(eventchase_current_distance != chase_distance)
1539                                 eventchase_current_distance = chase_distance;
1540
1541                         makevectors(view_angles);
1542
1543                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1544                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1545
1546                         // If the boxtrace fails, revert back to line tracing.
1547                         if(!local_player.viewloc)
1548                         if(trace_startsolid)
1549                         {
1550                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1551                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1552                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1553                         }
1554                         else { setproperty(VF_ORIGIN, trace_endpos); }
1555
1556                         if(!local_player.viewloc)
1557                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1558                 }
1559                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1560                 {
1561                         eventchase_running = false;
1562                         cvar_set("chase_active", "0");
1563                         eventchase_current_distance = 0; // start from 0 next time
1564                 }
1565         }
1566         // workaround for camera stuck between player's legs when using chase_active 1
1567         // because the engine stops updating the chase_active camera when the game ends
1568         else if(intermission)
1569         {
1570                 cvar_settemp("chase_active", "-1");
1571                 eventchase_current_distance = 0;
1572         }
1573
1574         // do lockview after event chase camera so that it still applies whenever necessary.
1575         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1576         {
1577                 setproperty(VF_ORIGIN, freeze_org);
1578                 setproperty(VF_ANGLES, freeze_ang);
1579         }
1580         else
1581         {
1582                 freeze_org = getpropertyvec(VF_ORIGIN);
1583                 freeze_ang = getpropertyvec(VF_ANGLES);
1584         }
1585
1586         WarpZone_FixView();
1587         //WarpZone_FixPMove();
1588
1589         vector ov_org = '0 0 0';
1590         vector ov_mid = '0 0 0';
1591         vector ov_worldmin = '0 0 0';
1592         vector ov_worldmax = '0 0 0';
1593         if(autocvar_cl_orthoview)
1594         {
1595                 ov_worldmin = mi_picmin;
1596                 ov_worldmax = mi_picmax;
1597
1598                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1599                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1600                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1601
1602                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1603                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1604
1605                 float ov_nearest = vlen(ov_org - vec3(
1606                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1607                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1608                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1609                 ));
1610
1611                 float ov_furthest = 0;
1612                 float dist = 0;
1613
1614                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1615                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1616                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1617                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1618                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1619                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1620                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1621                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1622
1623                 if(!ov_enabled)
1624                 {
1625                         oldr_nearclip = cvar("r_nearclip");
1626                         oldr_farclip_base = cvar("r_farclip_base");
1627                         oldr_farclip_world = cvar("r_farclip_world");
1628                         oldr_novis = cvar("r_novis");
1629                         oldr_useportalculling = cvar("r_useportalculling");
1630                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1631                 }
1632
1633                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1634                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1635                 cvar_settemp("r_farclip_world", "0");
1636                 cvar_settemp("r_novis", "1");
1637                 cvar_settemp("r_useportalculling", "0");
1638                 cvar_settemp("r_useinfinitefarclip", "0");
1639
1640                 setproperty(VF_ORIGIN, ov_org);
1641                 setproperty(VF_ANGLES, '90 0 0');
1642
1643                 ov_enabled = true;
1644
1645                 #if 0
1646                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1647                         vtos(ov_org),
1648                         vtos(getpropertyvec(VF_ANGLES)),
1649                         ov_distance,
1650                         ov_nearest,
1651                         ov_furthest);
1652                 #endif
1653         }
1654         else
1655         {
1656                 if(ov_enabled)
1657                 {
1658                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1659                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1660                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1661                         cvar_set("r_novis", ftos(oldr_novis));
1662                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1663                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1664                 }
1665                 ov_enabled = false;
1666         }
1667
1668         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1669         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1670         viewmodel_draw(viewmodel);
1671
1672         // Render the Scene
1673         view_origin = getpropertyvec(VF_ORIGIN);
1674         view_angles = getpropertyvec(VF_ANGLES);
1675         makevectors(view_angles);
1676         view_forward = v_forward;
1677         view_right = v_right;
1678         view_up = v_up;
1679
1680 #ifdef BLURTEST
1681         if(time > blurtest_time0 && time < blurtest_time1)
1682         {
1683                 float r, t;
1684
1685                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1686                 r = t * blurtest_radius;
1687                 f = 1 / pow(t, blurtest_power) - 1;
1688
1689                 cvar_set("r_glsl_postprocess", "1");
1690                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1691         }
1692         else
1693         {
1694                 cvar_set("r_glsl_postprocess", "0");
1695                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1696         }
1697 #endif
1698
1699         TargetMusic_Advance();
1700         Fog_Force();
1701
1702         if(drawtime == 0)
1703                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1704         else
1705                 drawframetime = bound(0.000001, time - drawtime, 1);
1706         drawtime = time;
1707
1708         // watch for gametype changes here...
1709         // in ParseStuffCMD the cmd isn't executed yet :/
1710         // might even be better to add the gametype to TE_CSQC_INIT...?
1711         if(!postinit)
1712                 PostInit();
1713
1714         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1715         {
1716                 if(calledhooks & HOOK_START)
1717                 {
1718                         localcmd("\ncl_hook_gameend\n");
1719                         calledhooks |= HOOK_END;
1720                 }
1721         }
1722
1723         Announcer();
1724
1725         fov = autocvar_fov;
1726         if(fov <= 59.5)
1727         {
1728                 if(!zoomscript_caught)
1729                 {
1730                         localcmd("+button9\n");
1731                         zoomscript_caught = 1;
1732                 }
1733         }
1734         else
1735         {
1736                 if(zoomscript_caught)
1737                 {
1738                         localcmd("-button9\n");
1739                         zoomscript_caught = 0;
1740                 }
1741         }
1742
1743         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1744
1745         // currently switching-to weapon (for crosshair)
1746         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1747
1748         // actually active weapon (for zoom)
1749         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1750
1751         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1752
1753         f = (serverflags & SERVERFLAG_TEAMPLAY);
1754         if(f != teamplay)
1755         {
1756                 teamplay = f;
1757                 HUD_InitScores();
1758         }
1759
1760         if(last_switchweapon != switchweapon)
1761         {
1762                 weapontime = time;
1763                 last_switchweapon = switchweapon;
1764                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1765                 {
1766                         localcmd("-zoom\n");
1767                         button_zoom = false;
1768                 }
1769                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1770                 {
1771                         localcmd("-fire\n");
1772                         localcmd("-fire2\n");
1773                         button_attack2 = false;
1774                 }
1775         }
1776         if(last_activeweapon != activeweapon)
1777         {
1778                 last_activeweapon = activeweapon;
1779
1780                 e = activeweapon;
1781                 if(e.netname != "")
1782                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1783                 else
1784                         localcmd("\ncl_hook_activeweapon none\n");
1785         }
1786
1787         // ALWAYS Clear Current Scene First
1788         clearscene();
1789
1790         setproperty(VF_ORIGIN, view_origin);
1791         setproperty(VF_ANGLES, view_angles);
1792
1793         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1794         setproperty(VF_SIZE, vf_size);
1795         setproperty(VF_MIN, vf_min);
1796
1797         // Assign Standard Viewflags
1798         // Draw the World (and sky)
1799         setproperty(VF_DRAWWORLD, 1);
1800
1801         // Set the console size vars
1802         vid_conwidth = autocvar_vid_conwidth;
1803         vid_conheight = autocvar_vid_conheight;
1804         vid_pixelheight = autocvar_vid_pixelheight;
1805
1806         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1807         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1808         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1809
1810         // Camera for demo playback
1811         if(camera_active)
1812         {
1813                 if(autocvar_camera_enable)
1814                         CSQC_Demo_Camera();
1815                 else
1816                 {
1817                         cvar_set("chase_active", ftos(chase_active_backup));
1818                         cvar_set("cl_demo_mousegrab", "0");
1819                         camera_active = false;
1820                 }
1821         }
1822         else
1823         {
1824 #ifdef CAMERATEST
1825                 if(autocvar_camera_enable)
1826 #else
1827                 if(autocvar_camera_enable && isdemo())
1828 #endif
1829                 {
1830                         // Enable required Darkplaces cvars
1831                         chase_active_backup = autocvar_chase_active;
1832                         cvar_set("chase_active", "2");
1833                         cvar_set("cl_demo_mousegrab", "1");
1834                         camera_active = true;
1835                         camera_mode = false;
1836                 }
1837         }
1838
1839         // Draw the Crosshair
1840         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1841
1842         // Draw the Engine Status Bar (the default Quake HUD)
1843         setproperty(VF_DRAWENGINESBAR, 0);
1844
1845         // Update the mouse position
1846         /*
1847            mousepos_x = vid_conwidth;
1848            mousepos_y = vid_conheight;
1849            mousepos = mousepos*0.5 + getmousepos();
1850          */
1851
1852         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1853
1854         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1855         renderscene();
1856
1857         // now switch to 2D drawing mode by calling a 2D drawing function
1858         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1859         // next R_RenderScene call
1860         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1861
1862         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1863         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1864         {
1865                 // apply night vision effect
1866                 vector tc_00, tc_01, tc_10, tc_11;
1867                 vector rgb = '0 0 0';
1868
1869                 if(!nightvision_noise)
1870                 {
1871                         nightvision_noise = new(nightvision_noise);
1872                 }
1873                 if(!nightvision_noise2)
1874                 {
1875                         nightvision_noise2 = new(nightvision_noise2);
1876                 }
1877
1878                 // color tint in yellow
1879                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1880
1881                 // draw BG
1882                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1883                 rgb = '1 1 1';
1884                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1885                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1886                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1887                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1888                 tc_11 = tc_01 + tc_10 - tc_00;
1889                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1890                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1891                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1892                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1893                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1894                 R_EndPolygon();
1895
1896                 // draw FG
1897                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1898                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1899                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1900                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1901                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1902                 tc_11 = tc_01 + tc_10 - tc_00;
1903                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1904                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1905                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1906                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1907                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1908                 R_EndPolygon();
1909         }
1910
1911         if(autocvar_cl_reticle)
1912         {
1913                 Weapon wep = activeweapon;
1914                 // Draw the aiming reticle for weapons that use it
1915                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1916                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1917                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1918                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1919                 {
1920                         // no zoom reticle while dead
1921                         reticle_type = 0;
1922                 }
1923                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1924                 {
1925                         if(reticle_image != "") { reticle_type = 2; }
1926                         else { reticle_type = 0; }
1927                 }
1928                 else if(button_zoom || zoomscript_caught)
1929                 {
1930                         // normal zoom
1931                         reticle_type = 1;
1932                 }
1933
1934                 if(reticle_type)
1935                 {
1936                         if(autocvar_cl_reticle_stretch)
1937                         {
1938                                 reticle_size.x = vid_conwidth;
1939                                 reticle_size.y = vid_conheight;
1940                                 reticle_pos.x = 0;
1941                                 reticle_pos.y = 0;
1942                         }
1943                         else
1944                         {
1945                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1946                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1947                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1948                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1949                         }
1950
1951                         if(zoomscript_caught)
1952                                 f = 1;
1953                         else
1954                                 f = current_zoomfraction;
1955
1956                         if(f)
1957                         {
1958                                 switch(reticle_type)
1959                                 {
1960                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1961                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1962                                 }
1963                         }
1964                 }
1965         }
1966         else
1967         {
1968                 if(reticle_type != 0) { reticle_type = 0; }
1969         }
1970
1971
1972         // improved polyblend
1973         if(autocvar_hud_contents)
1974         {
1975                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1976                 vector liquidcolor;
1977
1978                 switch(pointcontents(view_origin))
1979                 {
1980                         case CONTENT_WATER:
1981                                 liquidalpha = autocvar_hud_contents_water_alpha;
1982                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1983                                 incontent = 1;
1984                                 break;
1985
1986                         case CONTENT_LAVA:
1987                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1988                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1989                                 incontent = 1;
1990                                 break;
1991
1992                         case CONTENT_SLIME:
1993                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1994                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1995                                 incontent = 1;
1996                                 break;
1997
1998                         default:
1999                                 liquidalpha = 0;
2000                                 liquidcolor = '0 0 0';
2001                                 incontent = 0;
2002                                 break;
2003                 }
2004
2005                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2006                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2007                         contentfadetime = autocvar_hud_contents_fadeintime;
2008                         liquidalpha_prev = liquidalpha;
2009                         liquidcolor_prev = liquidcolor;
2010                 }
2011                 else
2012                         contentfadetime = autocvar_hud_contents_fadeouttime;
2013
2014                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2015                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2016
2017                 if(contentavgalpha)
2018                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2019
2020                 if(autocvar_hud_postprocessing)
2021                 {
2022                         if(autocvar_hud_contents_blur && contentavgalpha)
2023                         {
2024                                 content_blurpostprocess.x = 1;
2025                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2026                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2027                         }
2028                         else
2029                         {
2030                                 content_blurpostprocess.x = 0;
2031                                 content_blurpostprocess.y = 0;
2032                                 content_blurpostprocess.z = 0;
2033                         }
2034                 }
2035         }
2036
2037         if(autocvar_hud_damage && !STAT(FROZEN))
2038         {
2039                 splash_size.x = max(vid_conwidth, vid_conheight);
2040                 splash_size.y = max(vid_conwidth, vid_conheight);
2041                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2042                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2043
2044                 float myhealth_flash_temp;
2045                 myhealth = STAT(HEALTH);
2046
2047                 // fade out
2048                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2049                 // add new damage
2050                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2051
2052                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2053                 pain_threshold = autocvar_hud_damage_pain_threshold;
2054                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2055                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2056
2057                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2058                 {
2059                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2060                 }
2061
2062                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2063
2064                 if(myhealth_prev < 1)
2065                 {
2066                         if(myhealth >= 1)
2067                         {
2068                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2069                                 myhealth_flash_temp = 0;
2070                         }
2071                         else
2072                         {
2073                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2074                         }
2075                 }
2076
2077                 if(spectatee_status == -1 || intermission)
2078                 {
2079                         myhealth_flash = 0; // observing, or match ended
2080                         myhealth_flash_temp = 0;
2081                 }
2082
2083                 myhealth_prev = myhealth;
2084
2085                 // IDEA: change damage color/picture based on player model for robot/alien species?
2086                 // pro: matches model better
2087                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2088                 // maybe different reddish pics?
2089                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2090                 {
2091                         if(autocvar_cl_gentle_damage == 2)
2092                         {
2093                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2094                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2095                         }
2096                         else
2097                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2098
2099                         if(myhealth_flash_temp > 0)
2100                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2101                 }
2102                 else if(myhealth_flash_temp > 0)
2103                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2104
2105                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2106                 {
2107                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2108                         {
2109                                 damage_blurpostprocess.x = 1;
2110                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2111                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2112                         }
2113                         else
2114                         {
2115                                 damage_blurpostprocess.x = 0;
2116                                 damage_blurpostprocess.y = 0;
2117                                 damage_blurpostprocess.z = 0;
2118                         }
2119                 }
2120         }
2121
2122         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2123         float e2 = (autocvar_hud_powerup != 0);
2124         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2125         {
2126                 // enable or disable rendering types if they are used or not
2127                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2128                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2129
2130                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2131                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2132                 {
2133                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2134                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2135                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2136                         {
2137                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2138                                 old_blurradius = blurradius;
2139                                 old_bluralpha = bluralpha;
2140                         }
2141                 }
2142                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2143                 {
2144                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2145                         old_blurradius = 0;
2146                         old_bluralpha = 0;
2147                 }
2148
2149                 // edge detection postprocess handling done second (used by hud_powerup)
2150                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2151                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2152                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2153
2154                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2155
2156                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2157                 {
2158                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2159                         {
2160                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2161                                 old_sharpen_intensity = sharpen_intensity;
2162                         }
2163                 }
2164                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2165                 {
2166                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2167                         old_sharpen_intensity = 0;
2168                 }
2169
2170                 if(cvar("r_glsl_postprocess") == 0)
2171                         cvar_set("r_glsl_postprocess", "2");
2172         }
2173         else if(cvar("r_glsl_postprocess") == 2)
2174                 cvar_set("r_glsl_postprocess", "0");
2175
2176         /*if(gametype == MAPINFO_TYPE_CTF)
2177           {
2178           ctf_view();
2179           } else */
2180
2181         // draw 2D entities
2182         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2183         Draw_ShowNames_All();
2184         Debug_Draw();
2185
2186         scoreboard_active = HUD_WouldDrawScoreboard();
2187
2188         HUD_Draw();
2189
2190         if(NextFrameCommand)
2191         {
2192                 localcmd("\n", NextFrameCommand, "\n");
2193                 NextFrameCommand = string_null;
2194         }
2195
2196         // we must do this check AFTER a frame was rendered, or it won't work
2197         if(cs_project_is_b0rked == 0)
2198         {
2199                 string w0, h0;
2200                 w0 = ftos(autocvar_vid_conwidth);
2201                 h0 = ftos(autocvar_vid_conheight);
2202                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2203                 //setproperty(VF_FOV, '90 90 0');
2204                 setproperty(VF_ORIGIN, '0 0 0');
2205                 setproperty(VF_ANGLES, '0 0 0');
2206                 setproperty(VF_PERSPECTIVE, 1);
2207                 makevectors('0 0 0');
2208                 vector v1, v2;
2209                 cvar_set("vid_conwidth", "800");
2210                 cvar_set("vid_conheight", "600");
2211                 v1 = cs_project(v_forward);
2212                 cvar_set("vid_conwidth", "640");
2213                 cvar_set("vid_conheight", "480");
2214                 v2 = cs_project(v_forward);
2215                 if(v1 == v2)
2216                         cs_project_is_b0rked = 1;
2217                 else
2218                         cs_project_is_b0rked = -1;
2219                 cvar_set("vid_conwidth", w0);
2220                 cvar_set("vid_conheight", h0);
2221         }
2222
2223         if(autocvar__hud_configure)
2224                 HUD_Panel_Mouse();
2225         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2226                 HUD_Minigame_Mouse();
2227         else if(QuickMenu_IsOpened())
2228                 QuickMenu_Mouse();
2229         else
2230                 HUD_Radar_Mouse();
2231
2232         cl_notice_run();
2233         unpause_update();
2234         Net_Flush();
2235
2236         // let's reset the view back to normal for the end
2237         setproperty(VF_MIN, '0 0 0');
2238         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2239 }
2240
2241
2242 // following vectors must be global to allow seamless switching between camera modes
2243 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2244 void CSQC_Demo_Camera()
2245 {
2246         float speed, attenuation, dimensions;
2247         vector tmp, delta;
2248
2249         if( autocvar_camera_reset || !camera_mode )
2250         {
2251                 camera_offset = '0 0 0';
2252                 current_angles = '0 0 0';
2253                 camera_direction = '0 0 0';
2254                 camera_offset.z += 30;
2255                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2256                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2257                 current_origin = view_origin;
2258                 current_camera_offset  = camera_offset;
2259                 cvar_set("camera_reset", "0");
2260                 camera_mode = CAMERA_CHASE;
2261         }
2262
2263         // Camera angles
2264         if( camera_roll )
2265                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2266
2267         if(autocvar_camera_look_player)
2268         {
2269                 vector dir;
2270                 float n;
2271
2272                 dir = normalize(view_origin - current_position);
2273                 n = mouse_angles.z;
2274                 mouse_angles = vectoangles(dir);
2275                 mouse_angles.x = mouse_angles.x * -1;
2276                 mouse_angles.z = n;
2277         }
2278         else
2279         {
2280                 tmp = getmousepos() * 0.1;
2281                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2282                 {
2283                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2284                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2285                 }
2286         }
2287
2288         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2289         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2290         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2291         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2292
2293         // Fix difference when angles don't have the same sign
2294         delta = '0 0 0';
2295         if(mouse_angles.y < -60 && current_angles.y > 60)
2296                 delta = '0 360 0';
2297         if(mouse_angles.y > 60 && current_angles.y < -60)
2298                 delta = '0 -360 0';
2299
2300         if(autocvar_camera_look_player)
2301                 attenuation = autocvar_camera_look_attenuation;
2302         else
2303                 attenuation = autocvar_camera_speed_attenuation;
2304
2305         attenuation = 1 / max(1, attenuation);
2306         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2307
2308         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2309         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2310         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2311         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2312
2313         // Camera position
2314         tmp = '0 0 0';
2315         dimensions = 0;
2316
2317         if( camera_direction.x )
2318         {
2319                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2320                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2321                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2322                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2323                 ++dimensions;
2324         }
2325
2326         if( camera_direction.y )
2327         {
2328                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2329                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2330                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2331                 ++dimensions;
2332         }
2333
2334         if( camera_direction.z )
2335         {
2336                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2337                 ++dimensions;
2338         }
2339
2340         if(autocvar_camera_free)
2341                 speed = autocvar_camera_speed_free;
2342         else
2343                 speed = autocvar_camera_speed_chase;
2344
2345         if(dimensions)
2346         {
2347                 speed = speed * sqrt(1 / dimensions);
2348                 camera_offset += tmp * speed;
2349         }
2350
2351         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2352
2353         // Camera modes
2354         if( autocvar_camera_free )
2355         {
2356                 if ( camera_mode == CAMERA_CHASE )
2357                 {
2358                         current_camera_offset = current_origin + current_camera_offset;
2359                         camera_offset = current_origin + camera_offset;
2360                 }
2361
2362                 camera_mode = CAMERA_FREE;
2363                 current_position = current_camera_offset;
2364         }
2365         else
2366         {
2367                 if ( camera_mode == CAMERA_FREE )
2368                 {
2369                         current_origin = view_origin;
2370                         camera_offset = camera_offset - current_origin;
2371                         current_camera_offset = current_camera_offset - current_origin;
2372                 }
2373
2374                 camera_mode = CAMERA_CHASE;
2375
2376                 if(autocvar_camera_chase_smoothly)
2377                         current_origin += (view_origin - current_origin) * attenuation;
2378                 else
2379                         current_origin = view_origin;
2380
2381                 current_position = current_origin + current_camera_offset;
2382         }
2383
2384         setproperty(VF_ANGLES, current_angles);
2385         setproperty(VF_ORIGIN, current_position);
2386 }