qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 bool swap = name != this.name_last;
 316                 // if (swap)
 317                 {
 318                         this.name_last = name;
 319                         CL_WeaponEntity_SetModel(this, name, swap);
 320                         this.viewmodel_origin = this.origin;
 321                         this.viewmodel_angles = this.angles;
 322                 }
 323                 anim_update(this);
 324                 if (!this.animstate_override && !this.animstate_looping)
 325                         anim_set(this, this.anim_idle, true, false, false);
 326         }
 327         float f = 0; // 0..1; 0: fully active
 328         float rate = STAT(WEAPONRATEFACTOR);
 329         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 330         if (eta <= 0) f = this.weapon_eta_last;
 331         else switch (this.state)
 332         {
 333                 case WS_RAISE:
 334                 {
 335                         f = eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_DROP:
 339                 {
 340                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_CLEAR:
 344                 {
 345                         f = 1;
 346                         break;
 347                 }
 348         }
 349         this.weapon_eta_last = f;
 350         this.origin = this.viewmodel_origin;
 351         this.angles = this.viewmodel_angles;
 352         this.angles_x = (-90 * f * f);
 353         viewmodel_animate(this);
 354         setorigin(this, this.origin);
 355 }
 356
 357 entity viewmodels[MAX_WEAPONSLOTS];
 358 STATIC_INIT(viewmodel) {
 359     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 360         viewmodels[slot] = new(viewmodel);
 361 }
 362
 363 void Porto_Draw(entity this);
 364 STATIC_INIT(Porto)
 365 {
 366         entity e = new_pure(porto);
 367         e.draw = Porto_Draw;
 368         IL_PUSH(g_drawables, e);
 369         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 370 }
 371
 372 const int polyline_length = 16;
 373 vector polyline[polyline_length];
 374 void Porto_Draw(entity this)
 375 {
 376         entity wepent = viewmodels[0]; // TODO: unhardcode
 377         if (wepent.activeweapon != WEP_PORTO) return;
 378         if (spectatee_status) return;
 379         if (WEP_CVAR(porto, secondary)) return;
 380         if (intermission == 1) return;
 381         if (intermission == 2) return;
 382         if (STAT(HEALTH) <= 0) return;
 383
 384         vector pos = view_origin;
 385         vector dir = view_forward;
 386         if (angles_held_status)
 387         {
 388                 makevectors(angles_held);
 389                 dir = v_forward;
 390         }
 391
 392         polyline[0] = pos;
 393
 394         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 395         int n = 1 + 2;  // 2 lines == 3 points
 396         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 397         {
 398                 traceline(pos, pos + 65536 * dir, true, this);
 399                 dir = reflect(dir, trace_plane_normal);
 400                 pos = trace_endpos;
 401                 polyline[++idx] = pos;
 402                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 403                 {
 404                         n += 1;
 405                         continue;
 406                 }
 407                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 408                 {
 409                         n = max(2, idx);
 410                         break;
 411                 }
 412                 // check size
 413                 {
 414                         vector ang = vectoangles2(trace_plane_normal, dir);
 415                         ang.x = -ang.x;
 416                         makevectors(ang);
 417                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 418                         {
 419                                 n = max(2, idx);
 420                                 break;
 421                         }
 422                 }
 423                 portal_number += 1;
 424                 if (portal_number >= portal_max) break;
 425                 if (portal_number == 1) portal1_idx = idx;
 426         }
 427         for (int idx = 0; idx < n - 1; ++idx)
 428         {
 429                 vector p = polyline[idx], q = polyline[idx + 1];
 430                 if (idx == 0) p -= view_up * 16;  // line from player
 431                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 432                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 433         }
 434 }
 435
 436 float drawtime;
 437 float avgspeed;
 438 vector GetCurrentFov(float fov)
 439 {
 440         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 441         float velocityzoom, curspeed;
 442         vector v;
 443
 444         zoomsensitivity = autocvar_cl_zoomsensitivity;
 445         zoomfactor = autocvar_cl_zoomfactor;
 446         if(zoomfactor < 1 || zoomfactor > 30)
 447                 zoomfactor = 2.5;
 448         zoomspeed = autocvar_cl_zoomspeed;
 449         if(zoomspeed >= 0)
 450         if(zoomspeed < 0.5 || zoomspeed > 16)
 451                         zoomspeed = 3.5;
 452
 453         zoomdir = button_zoom;
 454
 455         if(hud == HUD_NORMAL && !spectatee_status)
 456         {
 457                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 458                 {
 459                         entity wepent = viewmodels[slot];
 460                         if(wepent.switchweapon == wepent.activeweapon)
 461                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 462                                 zoomdir += button_attack2;
 463                 }
 464         }
 465         if(spectatee_status > 0 || isdemo())
 466         {
 467                 if(spectatorbutton_zoom)
 468                 {
 469                         if(zoomdir)
 470                                 zoomdir = 0;
 471                         else
 472                                 zoomdir = 1;
 473                 }
 474                 // fteqcc failed twice here already, don't optimize this
 475         }
 476
 477         if(zoomdir) { zoomin_effect = 0; }
 478
 479         if(camera_active)
 480         {
 481                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 482         }
 483         else if(autocvar_cl_spawnzoom && zoomin_effect)
 484         {
 485                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 486
 487                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 488                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 489                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 490         }
 491         else
 492         {
 493                 if(zoomspeed < 0) // instant zoom
 494                 {
 495                         if(zoomdir)
 496                                 current_viewzoom = 1 / zoomfactor;
 497                         else
 498                                 current_viewzoom = 1;
 499                 }
 500                 else
 501                 {
 502                         if(zoomdir)
 503                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 504                         else
 505                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 506                 }
 507         }
 508
 509         if(almost_equals(current_viewzoom, 1))
 510                 current_zoomfraction = 0;
 511         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 512                 current_zoomfraction = 1;
 513         else
 514                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 515
 516         if(zoomsensitivity < 1)
 517                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 518         else
 519                 setsensitivityscale(1);
 520
 521         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 522         {
 523                 if(intermission) { curspeed = 0; }
 524                 else
 525                 {
 526
 527                         makevectors(view_angles);
 528                         v = pmove_vel;
 529                         if(csqcplayer)
 530                                 v = csqcplayer.velocity;
 531
 532                         switch(autocvar_cl_velocityzoom_type)
 533                         {
 534                                 case 3: curspeed = max(0, v_forward * v); break;
 535                                 case 2: curspeed = (v_forward * v); break;
 536                                 case 1: default: curspeed = vlen(v); break;
 537                         }
 538                 }
 539
 540                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 541                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 542                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 543
 544                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 545         }
 546         else
 547                 velocityzoom = 1;
 548
 549         float frustumx, frustumy, fovx, fovy;
 550         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 551         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 552         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 553         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 554
 555         return '1 0 0' * fovx + '0 1 0' * fovy;
 556 }
 557
 558 vector GetViewLocationFOV(float fov)
 559 {
 560         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 561         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 562         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 563         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 568 {
 569         float fovx, fovy;
 570         float width = (ov_worldmax.x - ov_worldmin.x);
 571         float height = (ov_worldmax.y - ov_worldmin.y);
 572         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 573         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 574         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 575         return '1 0 0' * fovx + '0 1 0' * fovy;
 576 }
 577
 578 // this function must match W_SetupShot!
 579 float zoomscript_caught;
 580
 581 vector wcross_origin;
 582 float wcross_scale_prev, wcross_alpha_prev;
 583 vector wcross_color_prev;
 584 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 585 vector wcross_color_goal_prev;
 586 float wcross_changedonetime;
 587
 588 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 589 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 590 float wcross_name_changestarttime, wcross_name_changedonetime;
 591 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 592
 593 float wcross_ring_prev;
 594
 595 entity trueaim;
 596 entity trueaim_rifle;
 597
 598 const float SHOTTYPE_HITTEAM = 1;
 599 const float SHOTTYPE_HITOBSTRUCTION = 2;
 600 const float SHOTTYPE_HITWORLD = 3;
 601 const float SHOTTYPE_HITENEMY = 4;
 602
 603 void TrueAim_Init()
 604 {
 605         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 606         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 607 }
 608
 609 float EnemyHitCheck()
 610 {
 611         float t, n;
 612         wcross_origin = project_3d_to_2d(trace_endpos);
 613         wcross_origin.z = 0;
 614         if(trace_ent)
 615                 n = trace_ent.entnum;
 616         else
 617                 n = trace_networkentity;
 618         if(n < 1)
 619                 return SHOTTYPE_HITWORLD;
 620         if(n > maxclients)
 621                 return SHOTTYPE_HITWORLD;
 622         t = entcs_GetTeam(n - 1);
 623         if(teamplay)
 624                 if(t == myteam)
 625                         return SHOTTYPE_HITTEAM;
 626         if(t == NUM_SPECTATOR)
 627                 return SHOTTYPE_HITWORLD;
 628         return SHOTTYPE_HITENEMY;
 629 }
 630
 631 float TrueAimCheck()
 632 {
 633         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 634         vector vecs, trueaimpoint, w_shotorg;
 635         vector mi, ma, dv;
 636         float shottype;
 637         entity ta;
 638         float mv;
 639
 640         mi = ma = '0 0 0';
 641         ta = trueaim;
 642         mv = MOVE_NOMONSTERS;
 643
 644         entity wepent = viewmodels[0]; // TODO: unhardcode
 645
 646         switch(wepent.activeweapon) // WEAPONTODO
 647         {
 648                 case WEP_TUBA: // no aim
 649                 case WEP_PORTO: // shoots from eye
 650                 case WEP_NEXBALL: // shoots from eye
 651                 case WEP_HOOK: // no trueaim
 652                 case WEP_MORTAR: // toss curve
 653                         return SHOTTYPE_HITWORLD;
 654                 case WEP_VORTEX:
 655                 case WEP_VAPORIZER:
 656                         mv = MOVE_NORMAL;
 657                         break;
 658                 case WEP_RIFLE:
 659                         ta = trueaim_rifle;
 660                         mv = MOVE_NORMAL;
 661                         if(zoomscript_caught)
 662                         {
 663                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 664                                 return EnemyHitCheck();
 665                         }
 666                         break;
 667                 case WEP_DEVASTATOR: // projectile has a size!
 668                         mi = '-3 -3 -3';
 669                         ma = '3 3 3';
 670                         break;
 671                 case WEP_FIREBALL: // projectile has a size!
 672                         mi = '-16 -16 -16';
 673                         ma = '16 16 16';
 674                         break;
 675                 case WEP_SEEKER: // projectile has a size!
 676                         mi = '-2 -2 -2';
 677                         ma = '2 2 2';
 678                         break;
 679                 case WEP_ELECTRO: // projectile has a size!
 680                         mi = '0 0 -3';
 681                         ma = '0 0 -3';
 682                         break;
 683         }
 684
 685         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 686
 687         vecs = decompressShotOrigin(STAT(SHOTORG));
 688
 689         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 690         trueaimpoint = trace_endpos;
 691
 692         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 693                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 694
 695         if(vecs.x > 0)
 696                 vecs.y = -vecs.y;
 697         else
 698                 vecs = '0 0 0';
 699
 700         dv = view_right * vecs.y + view_up * vecs.z;
 701         w_shotorg = traceorigin + dv;
 702
 703         // now move the vecs forward as much as requested if possible
 704         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 705         w_shotorg = trace_endpos - view_forward * nudge;
 706
 707         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 708         shottype = EnemyHitCheck();
 709         if(shottype != SHOTTYPE_HITWORLD)
 710                 return shottype;
 711
 712 #if 0
 713         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 714         // or rather, I know why, but see no fix
 715         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 716                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 717                 return SHOTTYPE_HITOBSTRUCTION;
 718 #endif
 719
 720         return SHOTTYPE_HITWORLD;
 721 }
 722
 723 void PostInit();
 724 void CSQC_Demo_Camera();
 725 float camera_mode;
 726 const float CAMERA_FREE = 1;
 727 const float CAMERA_CHASE = 2;
 728 float reticle_type;
 729 string NextFrameCommand;
 730
 731 vector freeze_org, freeze_ang;
 732 entity nightvision_noise, nightvision_noise2;
 733
 734 const float MAX_TIME_DIFF = 5;
 735 float pickup_crosshair_time, pickup_crosshair_size;
 736 float hitindication_crosshair_size;
 737 float use_vortex_chargepool;
 738
 739 float myhealth, myhealth_prev;
 740 float myhealth_flash;
 741
 742 float old_blurradius, old_bluralpha;
 743 float old_sharpen_intensity;
 744
 745 vector myhealth_gentlergb;
 746
 747 float contentavgalpha, liquidalpha_prev;
 748 vector liquidcolor_prev;
 749
 750 float eventchase_current_distance;
 751 float eventchase_running;
 752 bool WantEventchase(entity this)
 753 {
 754         if(autocvar_cl_orthoview)
 755                 return false;
 756         if(intermission)
 757                 return true;
 758         if(this.viewloc)
 759                 return true;
 760         if(spectatee_status >= 0)
 761         {
 762                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 763                         return true;
 764                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 765                         return true;
 766                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 767                 {
 768                         if(autocvar_cl_eventchase_death == 2)
 769                         {
 770                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 771                                 if(this.velocity == '0 0 0' || eventchase_running)
 772                                         return true;
 773                         }
 774                         else return true;
 775                 }
 776         }
 777         return false;
 778 }
 779
 780 void HUD_Crosshair_Vehicle(entity this)
 781 {
 782         if(hud != HUD_BUMBLEBEE_GUN)
 783         {
 784                 Vehicle info = Vehicles_from(hud);
 785                 info.vr_crosshair(info, this);
 786         }
 787 }
 788
 789 vector damage_blurpostprocess, content_blurpostprocess;
 790
 791 float unaccounted_damage = 0;
 792 void UpdateDamage()
 793 {
 794         // accumulate damage with each stat update
 795         static float damage_total_prev = 0;
 796         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 797         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 798         damage_total_prev = damage_total;
 799
 800         static float damage_dealt_time_prev = 0;
 801         float damage_dealt_time = STAT(HIT_TIME);
 802         if (damage_dealt_time != damage_dealt_time_prev)
 803         {
 804                 unaccounted_damage += unaccounted_damage_new;
 805                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 806         }
 807         damage_dealt_time_prev = damage_dealt_time;
 808
 809         // prevent hitsound when switching spectatee
 810         static float spectatee_status_prev = 0;
 811         if (spectatee_status != spectatee_status_prev)
 812                 unaccounted_damage = 0;
 813         spectatee_status_prev = spectatee_status;
 814 }
 815
 816 void HitSound()
 817 {
 818         // varying sound pitch
 819
 820         bool have_arc = false;
 821         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 822         {
 823                 entity wepent = viewmodels[slot];
 824
 825                 if(wepent.activeweapon == WEP_ARC)
 826                         have_arc = true;
 827         }
 828
 829         static float hitsound_time_prev = 0;
 830         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 831         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 832         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 833         {
 834                 if (autocvar_cl_hitsound && unaccounted_damage)
 835                 {
 836                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 837                         float a = autocvar_cl_hitsound_max_pitch;
 838                         float b = autocvar_cl_hitsound_min_pitch;
 839                         float c = autocvar_cl_hitsound_nom_damage;
 840                         float x = unaccounted_damage;
 841                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 842
 843                         // if sound variation is disabled, set pitch_shift to 1
 844                         if (autocvar_cl_hitsound == 1)
 845                                 pitch_shift = 1;
 846
 847                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 848                         if (autocvar_cl_hitsound == 3)
 849                         {
 850                                 float mirror_value = (a-b)/2 + b;
 851                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 852                         }
 853
 854                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 855
 856                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 857                         // todo: normalize sound pressure levels? seems unnecessary
 858
 859                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 860                 }
 861                 unaccounted_damage = 0;
 862                 hitsound_time_prev = time;
 863         }
 864
 865         static float typehit_time_prev = 0;
 866         float typehit_time = STAT(TYPEHIT_TIME);
 867         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 868         {
 869                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 870                 typehit_time_prev = typehit_time;
 871         }
 872 }
 873
 874 vector crosshair_getcolor(entity this, float health_stat)
 875 {
 876         static float rainbow_last_flicker;
 877         static vector rainbow_prev_color;
 878         vector wcross_color = '0 0 0';
 879         switch(autocvar_crosshair_color_special)
 880         {
 881                 case 1: // crosshair_color_per_weapon
 882                 {
 883                         if(this != WEP_Null && hud == HUD_NORMAL)
 884                         {
 885                                 wcross_color = this.wpcolor;
 886                                 break;
 887                         }
 888                         else { goto normalcolor; }
 889                 }
 890
 891                 case 2: // crosshair_color_by_health
 892                 {
 893                         float x = health_stat;
 894
 895                         //x = red
 896                         //y = green
 897                         //z = blue
 898
 899                         wcross_color.z = 0;
 900
 901                         if(x > 200)
 902                         {
 903                                 wcross_color.x = 0;
 904                                 wcross_color.y = 1;
 905                         }
 906                         else if(x > 150)
 907                         {
 908                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 909                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 910                         }
 911                         else if(x > 100)
 912                         {
 913                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 914                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 915                                 wcross_color.z = 1 - (x-100)*0.02;
 916                         }
 917                         else if(x > 50)
 918                         {
 919                                 wcross_color.x = 1;
 920                                 wcross_color.y = 1;
 921                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 922                         }
 923                         else if(x > 20)
 924                         {
 925                                 wcross_color.x = 1;
 926                                 wcross_color.y = (x-20)*90/27/100;
 927                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 928                         }
 929                         else
 930                         {
 931                                 wcross_color.x = 1;
 932                                 wcross_color.y = 0;
 933                         }
 934                         break;
 935                 }
 936
 937                 case 3: // crosshair_color_rainbow
 938                 {
 939                         if(time >= rainbow_last_flicker)
 940                         {
 941                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 942                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 943                         }
 944                         wcross_color = rainbow_prev_color;
 945                         break;
 946                 }
 947 LABEL(normalcolor)
 948                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 949         }
 950
 951         return wcross_color;
 952 }
 953
 954 void HUD_Crosshair(entity this)
 955 {
 956         float f, i, j;
 957         vector v;
 958         if(!scoreboard_active && !camera_active && intermission != 2 &&
 959                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 960                 !HUD_MinigameMenu_IsOpened() )
 961         {
 962                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 963                         return;
 964
 965                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 966                         return;
 967
 968                 if (hud != HUD_NORMAL)
 969                 {
 970                         HUD_Crosshair_Vehicle(this);
 971                         return;
 972                 }
 973
 974                 string wcross_style;
 975                 float wcross_alpha, wcross_resolution;
 976                 wcross_style = autocvar_crosshair;
 977                 if (wcross_style == "0")
 978                         return;
 979                 wcross_resolution = autocvar_crosshair_size;
 980                 if (wcross_resolution == 0)
 981                         return;
 982                 wcross_alpha = autocvar_crosshair_alpha;
 983                 if (wcross_alpha == 0)
 984                         return;
 985
 986                 // TrueAim check
 987                 float shottype;
 988
 989                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 990                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 991                 wcross_origin.z = 0;
 992                 if(autocvar_crosshair_hittest)
 993                 {
 994                         vector wcross_oldorigin;
 995                         wcross_oldorigin = wcross_origin;
 996                         shottype = TrueAimCheck();
 997                         if(shottype == SHOTTYPE_HITWORLD)
 998                         {
 999                                 v = wcross_origin - wcross_oldorigin;
1000                                 v.x /= vid_conwidth;
1001                                 v.y /= vid_conheight;
1002                                 if(vdist(v, >, 0.01))
1003                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1004                         }
1005                         if(!autocvar_crosshair_hittest_showimpact)
1006                                 wcross_origin = wcross_oldorigin;
1007                 }
1008                 else
1009                         shottype = SHOTTYPE_HITWORLD;
1010
1011                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1012                 string wcross_name = "";
1013                 float wcross_scale, wcross_blur;
1014
1015         entity e = WEP_Null;
1016                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1017                 {
1018                         entity wepent = viewmodels[0]; // TODO: unhardcode
1019                         e = wepent.switchingweapon;
1020                         if(e)
1021                         {
1022                                 if(autocvar_crosshair_per_weapon)
1023                                 {
1024                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1025                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1026                                         //if (wcross_resolution == 0)
1027                                                 //return;
1028
1029                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1030                                         wcross_resolution *= e.w_crosshair_size;
1031                                         wcross_name = e.w_crosshair;
1032                                 }
1033                         }
1034                 }
1035
1036                 if(wcross_name == "")
1037                         wcross_name = strcat("gfx/crosshair", wcross_style);
1038
1039                 // MAIN CROSSHAIR COLOR DECISION
1040                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1041
1042                 if(autocvar_crosshair_effect_scalefade)
1043                 {
1044                         wcross_scale = wcross_resolution;
1045                         wcross_resolution = 1;
1046                 }
1047                 else
1048                 {
1049                         wcross_scale = 1;
1050                 }
1051
1052                 if(autocvar_crosshair_pickup)
1053                 {
1054                         float stat_pickup_time = STAT(LAST_PICKUP);
1055
1056                         if(pickup_crosshair_time < stat_pickup_time)
1057                         {
1058                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1059                                         pickup_crosshair_size = 1;
1060
1061                                 pickup_crosshair_time = stat_pickup_time;
1062                         }
1063
1064                         if(pickup_crosshair_size > 0)
1065                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1066                         else
1067                                 pickup_crosshair_size = 0;
1068
1069                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1070                 }
1071
1072                 // todo: make crosshair hit indication dependent on damage dealt
1073                 if(autocvar_crosshair_hitindication)
1074                 {
1075                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1076
1077                         if(unaccounted_damage)
1078                         {
1079                                 hitindication_crosshair_size = 1;
1080                         }
1081
1082                         if(hitindication_crosshair_size > 0)
1083                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1084                         else
1085                                 hitindication_crosshair_size = 0;
1086
1087                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1088                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1089                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1090                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1091                 }
1092
1093                 if(shottype == SHOTTYPE_HITENEMY)
1094                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1095                 if(shottype == SHOTTYPE_HITTEAM)
1096                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1097
1098                 f = fabs(autocvar_crosshair_effect_time);
1099                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1100                 {
1101                         wcross_changedonetime = time + f;
1102                 }
1103                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1104                 {
1105                         wcross_name_changestarttime = time;
1106                         wcross_name_changedonetime = time + f;
1107                         if(wcross_name_goal_prev_prev)
1108                                 strunzone(wcross_name_goal_prev_prev);
1109                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1110                         wcross_name_goal_prev = strzone(wcross_name);
1111                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1112                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1113                         wcross_resolution_goal_prev = wcross_resolution;
1114                 }
1115
1116                 wcross_scale_goal_prev = wcross_scale;
1117                 wcross_alpha_goal_prev = wcross_alpha;
1118                 wcross_color_goal_prev = wcross_color;
1119
1120                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1121                 {
1122                         wcross_blur = 1;
1123                         wcross_alpha *= 0.75;
1124                 }
1125                 else
1126                         wcross_blur = 0;
1127                 // *_prev is at time-frametime
1128                 // * is at wcross_changedonetime+f
1129                 // what do we have at time?
1130                 if(time < wcross_changedonetime)
1131                 {
1132                         f = frametime / (wcross_changedonetime - time + frametime);
1133                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1134                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1135                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1136                 }
1137
1138                 wcross_scale_prev = wcross_scale;
1139                 wcross_alpha_prev = wcross_alpha;
1140                 wcross_color_prev = wcross_color;
1141
1142                 MUTATOR_CALLHOOK(UpdateCrosshair);
1143
1144                 wcross_scale *= 1 - autocvar__menu_alpha;
1145                 wcross_alpha *= 1 - autocvar__menu_alpha;
1146                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1147
1148                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1149                 {
1150                         // crosshair rings for weapon stats
1151                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1152                         {
1153                                 // declarations and stats
1154                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1155                                 string ring_image = string_null, ring_inner_image = string_null;
1156                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1157
1158                                 ring_scale = autocvar_crosshair_ring_size;
1159
1160                                 float weapon_clipload, weapon_clipsize;
1161                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1162                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1163
1164                                 float vortex_charge, vortex_chargepool;
1165                                 vortex_charge = STAT(VORTEX_CHARGE);
1166                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1167
1168                                 float arc_heat = STAT(ARC_HEAT);
1169
1170                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1171                                         vortex_charge_movingavg = vortex_charge;
1172
1173                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1174
1175                                 // handle the values
1176                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1177                                 {
1178                                         if (vortex_chargepool || use_vortex_chargepool) {
1179                                                 use_vortex_chargepool = 1;
1180                                                 ring_inner_value = vortex_chargepool;
1181                                         } else {
1182                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1183                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1184                                         }
1185
1186                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1187                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1188                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1189
1190                                         // draw the outer ring to show the current charge of the weapon
1191                                         ring_value = vortex_charge;
1192                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1193                                         ring_rgb = wcross_color;
1194                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1195                                 }
1196                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1197                                 {
1198                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1199                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring.tga";
1202                                 }
1203                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1204                                 {
1205                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1206                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1207                                         ring_rgb = wcross_color;
1208                                         ring_image = "gfx/crosshair_ring.tga";
1209                                 }
1210                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1211                                 {
1212                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1213                                         ring_scale = autocvar_crosshair_ring_reload_size;
1214                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1215                                         ring_rgb = wcross_color;
1216
1217                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1218                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1219                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1220                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1221                                         else
1222                                                 ring_image = "gfx/crosshair_ring.tga";
1223                                 }
1224                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1225                                 {
1226                                         ring_value = arc_heat;
1227                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1228                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1229                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1230                                         ring_image = "gfx/crosshair_ring.tga";
1231                                 }
1232
1233                                 // if in weapon switch animation, fade ring out/in
1234                                 if(autocvar_crosshair_effect_time > 0)
1235                                 {
1236                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1237                                         if (f >= 1)
1238                                         {
1239                                                 wcross_ring_prev = ((ring_image) ? true : false);
1240                                         }
1241
1242                                         if(wcross_ring_prev)
1243                                         {
1244                                                 if(f < 1)
1245                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1246                                         }
1247                                         else
1248                                         {
1249                                                 if(f < 1)
1250                                                         ring_alpha *= bound(0, f, 1);
1251                                         }
1252                                 }
1253
1254                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1255                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1256
1257                                 if (ring_value)
1258                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1259                         }
1260
1261 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1262                         MACRO_BEGIN { \
1263                                 if(wcross_blur > 0) \
1264                                 { \
1265                                         for(i = -2; i <= 2; ++i) \
1266                                         for(j = -2; j <= 2; ++j) \
1267                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1268                                 } \
1269                                 else \
1270                                 { \
1271                                         M(0,0,sz,wcross_name,wcross_alpha); \
1272                                 } \
1273                         } MACRO_END
1274
1275 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1276                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1277
1278 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1279                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1280
1281                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1282                         {
1283                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1284                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1285                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1286                                 f = 1 - f;
1287                         }
1288                         else
1289                         {
1290                                 f = 1;
1291                         }
1292                         wcross_name_alpha_goal_prev = f;
1293
1294                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1295                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1296
1297                         if(autocvar_crosshair_dot)
1298                         {
1299                                 vector wcross_color_old;
1300                                 wcross_color_old = wcross_color;
1301
1302                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1303                                         wcross_color = stov(autocvar_crosshair_dot_color);
1304
1305                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1306                                 // FIXME why don't we use wcross_alpha here?
1307                                 wcross_color = wcross_color_old;
1308                         }
1309                 }
1310         }
1311         else
1312         {
1313                 wcross_scale_prev = 0;
1314                 wcross_alpha_prev = 0;
1315                 wcross_scale_goal_prev = 0;
1316                 wcross_alpha_goal_prev = 0;
1317                 wcross_changedonetime = 0;
1318                 if(wcross_name_goal_prev)
1319                         strunzone(wcross_name_goal_prev);
1320                 wcross_name_goal_prev = string_null;
1321                 if(wcross_name_goal_prev_prev)
1322                         strunzone(wcross_name_goal_prev_prev);
1323                 wcross_name_goal_prev_prev = string_null;
1324                 wcross_name_changestarttime = 0;
1325                 wcross_name_changedonetime = 0;
1326                 wcross_name_alpha_goal_prev = 0;
1327                 wcross_name_alpha_goal_prev_prev = 0;
1328                 wcross_resolution_goal_prev = 0;
1329                 wcross_resolution_goal_prev_prev = 0;
1330         }
1331 }
1332
1333 void HUD_Draw(entity this)
1334 {
1335         // if we don't know gametype and scores yet avoid drawing the scoreboard
1336         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1337         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1338         // cl_deathscoreboard would show the scoreboard and so on
1339         if(!gametype)
1340                 return;
1341
1342         if(!intermission)
1343         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1344         {
1345                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1346         }
1347         else if(STAT(FROZEN))
1348         {
1349                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1350         }
1351         if(!intermission)
1352         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1353         {
1354                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1355                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1356         }
1357         else if(STAT(CAPTURE_PROGRESS))
1358         {
1359                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1360                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1361         }
1362         else if(STAT(REVIVE_PROGRESS))
1363         {
1364                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1365                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1366         }
1367
1368         if(autocvar_r_letterbox == 0)
1369                 if(autocvar_viewsize < 120)
1370                 {
1371                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1372                                 Accuracy_LoadLevels();
1373
1374                         HUD_Main();
1375                         HUD_Scale_Disable();
1376                 }
1377
1378         // crosshair goes VERY LAST
1379         UpdateDamage();
1380         HUD_Crosshair(this);
1381         HitSound();
1382 }
1383
1384 bool ov_enabled;
1385 float oldr_nearclip;
1386 float oldr_farclip_base;
1387 float oldr_farclip_world;
1388 float oldr_novis;
1389 float oldr_useportalculling;
1390 float oldr_useinfinitefarclip;
1391
1392 void cl_notice_run();
1393
1394 float prev_myteam;
1395 int lasthud;
1396 float vh_notice_time;
1397 void WaypointSprite_Load();
1398 void CSQC_UpdateView(entity this, float w, float h)
1399 {
1400     TC(int, w); TC(int, h);
1401         entity e;
1402         float fov;
1403         float f;
1404         vector vf_size, vf_min;
1405         float a;
1406
1407         execute_next_frame();
1408
1409         ++framecount;
1410
1411         stats_get();
1412         hud = STAT(HUD);
1413
1414         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1415                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1416
1417         lasthud = hud;
1418
1419         HUD_Scale_Disable();
1420
1421         if(autocvar__hud_showbinds_reload) // menu can set this one
1422         {
1423                 db_close(binddb);
1424                 binddb = db_create();
1425                 cvar_set("_hud_showbinds_reload", "0");
1426         }
1427
1428         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1429                 view_quality = getproperty(VF_MINFPS_QUALITY);
1430         else
1431                 view_quality = 1;
1432
1433         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1434         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1435
1436         vf_size = getpropertyvec(VF_SIZE);
1437         vf_min = getpropertyvec(VF_MIN);
1438         vid_width = vf_size.x;
1439         vid_height = vf_size.y;
1440
1441         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1442         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1443
1444         WaypointSprite_Load();
1445
1446         CSQCPlayer_SetCamera();
1447
1448         if(player_localentnum <= maxclients) // is it a client?
1449                 current_player = player_localentnum - 1;
1450         else // then player_localentnum is the vehicle I'm driving
1451                 current_player = player_localnum;
1452         myteam = entcs_GetTeam(current_player);
1453
1454         if(myteam != prev_myteam)
1455         {
1456                 myteamcolors = colormapPaletteColor(myteam, 1);
1457                 FOREACH(hud_panels, true, it.update_time = time);
1458                 prev_myteam = myteam;
1459         }
1460
1461         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1462
1463         float is_dead = (STAT(HEALTH) <= 0);
1464
1465         // FIXME do we need this hack?
1466         if(isdemo())
1467         {
1468                 // in demos, input_buttons do not work
1469                 button_zoom = (autocvar__togglezoom == "-");
1470         }
1471         else if(button_zoom
1472                 && autocvar_cl_unpress_zoom_on_death
1473                 && (spectatee_status >= 0)
1474                 && (is_dead || intermission))
1475         {
1476                 // no zoom while dead or in intermission please
1477                 localcmd("-zoom\n");
1478                 button_zoom = false;
1479         }
1480
1481         // event chase camera
1482         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1483         {
1484                 if(STAT(CAMERA_SPECTATOR))
1485                 {
1486                         if(spectatee_status > 0)
1487                         {
1488                                 if(!autocvar_chase_active)
1489                                 {
1490                                         cvar_set("chase_active", "-2");
1491                                         goto skip_eventchase_death;
1492                                 }
1493                         }
1494                         else if(autocvar_chase_active == -2)
1495                                 cvar_set("chase_active", "0");
1496
1497                         if(autocvar_chase_active == -2)
1498                                 goto skip_eventchase_death;
1499                 }
1500                 else if(autocvar_chase_active == -2)
1501                         cvar_set("chase_active", "0");
1502
1503                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1504
1505                 float vehicle_viewdist = 0;
1506                 vector vehicle_viewofs = '0 0 0';
1507
1508                 if(vehicle_chase)
1509                 {
1510                         if(hud != HUD_BUMBLEBEE_GUN)
1511                         {
1512                                 Vehicle info = Vehicles_from(hud);
1513                                 vehicle_viewdist = info.height;
1514                                 vehicle_viewofs = info.view_ofs;
1515                         }
1516                 }
1517
1518                 if(WantEventchase(this))
1519                 {
1520                         vector current_view_origin_override = '0 0 0';
1521                         vector view_offset_override = '0 0 0';
1522                         float chase_distance_override = 0;
1523                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1524                         if(custom_eventchase)
1525                         {
1526                                 current_view_origin_override = M_ARGV(0, vector);
1527                                 view_offset_override = M_ARGV(1, vector);
1528                                 chase_distance_override = M_ARGV(0, float);
1529                         }
1530                         eventchase_running = true;
1531
1532                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1533                         if(!local_player)
1534                                 local_player = this; // fall back!
1535
1536                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1537                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1538                         if (custom_eventchase)
1539                                 current_view_origin = current_view_origin_override;
1540
1541                         // detect maximum viewoffset and use it
1542                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1543                         if(vehicle_chase)
1544                         {
1545                                 if(vehicle_viewofs)
1546                                         view_offset = vehicle_viewofs;
1547                                 else
1548                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1549                         }
1550                         if (custom_eventchase)
1551                                 view_offset = view_offset_override;
1552
1553                         if(view_offset)
1554                         {
1555                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1556                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1557                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1558                         }
1559
1560                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1561                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1562                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1563                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1564
1565                         // make the camera smooth back
1566                         float chase_distance = autocvar_cl_eventchase_distance;
1567                         if(vehicle_chase)
1568                         {
1569                                 if(vehicle_viewofs)
1570                                         chase_distance = vehicle_viewdist;
1571                                 else
1572                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1573                         }
1574                         if (custom_eventchase)
1575                                 chase_distance = chase_distance_override;
1576
1577                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1578                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1579                         else if(eventchase_current_distance != chase_distance)
1580                                 eventchase_current_distance = chase_distance;
1581
1582                         makevectors(view_angles);
1583
1584                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1585                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1586
1587                         // If the boxtrace fails, revert back to line tracing.
1588                         if(!local_player.viewloc)
1589                         if(trace_startsolid)
1590                         {
1591                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1592                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1593                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1594                         }
1595                         else { setproperty(VF_ORIGIN, trace_endpos); }
1596
1597                         if(!local_player.viewloc)
1598                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1599                 }
1600                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1601                 {
1602                         eventchase_running = false;
1603                         cvar_set("chase_active", "0");
1604                         eventchase_current_distance = 0; // start from 0 next time
1605                 }
1606         }
1607         // workaround for camera stuck between player's legs when using chase_active 1
1608         // because the engine stops updating the chase_active camera when the game ends
1609         else if(intermission)
1610         {
1611                 cvar_settemp("chase_active", "-1");
1612                 eventchase_current_distance = 0;
1613         }
1614
1615         LABEL(skip_eventchase_death);
1616
1617         // do lockview after event chase camera so that it still applies whenever necessary.
1618         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1619         {
1620                 setproperty(VF_ORIGIN, freeze_org);
1621                 setproperty(VF_ANGLES, freeze_ang);
1622         }
1623         else
1624         {
1625                 freeze_org = getpropertyvec(VF_ORIGIN);
1626                 freeze_ang = getpropertyvec(VF_ANGLES);
1627         }
1628
1629         WarpZone_FixView();
1630         //WarpZone_FixPMove();
1631
1632         vector ov_org = '0 0 0';
1633         vector ov_mid = '0 0 0';
1634         vector ov_worldmin = '0 0 0';
1635         vector ov_worldmax = '0 0 0';
1636         if(autocvar_cl_orthoview)
1637         {
1638                 ov_worldmin = mi_picmin;
1639                 ov_worldmax = mi_picmax;
1640
1641                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1642                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1643                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1644
1645                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1646                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1647
1648                 float ov_nearest = vlen(ov_org - vec3(
1649                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1650                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1651                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1652                 ));
1653
1654                 float ov_furthest = 0;
1655                 float dist = 0;
1656
1657                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1658                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1659                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665
1666                 if(!ov_enabled)
1667                 {
1668                         oldr_nearclip = cvar("r_nearclip");
1669                         oldr_farclip_base = cvar("r_farclip_base");
1670                         oldr_farclip_world = cvar("r_farclip_world");
1671                         oldr_novis = cvar("r_novis");
1672                         oldr_useportalculling = cvar("r_useportalculling");
1673                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1674                 }
1675
1676                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1677                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1678                 cvar_settemp("r_farclip_world", "0");
1679                 cvar_settemp("r_novis", "1");
1680                 cvar_settemp("r_useportalculling", "0");
1681                 cvar_settemp("r_useinfinitefarclip", "0");
1682
1683                 setproperty(VF_ORIGIN, ov_org);
1684                 setproperty(VF_ANGLES, '90 0 0');
1685
1686                 ov_enabled = true;
1687
1688                 #if 0
1689                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1690                         vtos(ov_org),
1691                         vtos(getpropertyvec(VF_ANGLES)),
1692                         ov_distance,
1693                         ov_nearest,
1694                         ov_furthest);
1695                 #endif
1696         }
1697         else
1698         {
1699                 if(ov_enabled)
1700                 {
1701                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1702                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1703                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1704                         cvar_set("r_novis", ftos(oldr_novis));
1705                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1706                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1707                 }
1708                 ov_enabled = false;
1709         }
1710
1711         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1712         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1713         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1714                 viewmodel_draw(viewmodels[slot]);
1715
1716         // Render the Scene
1717         view_origin = getpropertyvec(VF_ORIGIN);
1718         view_angles = getpropertyvec(VF_ANGLES);
1719         makevectors(view_angles);
1720         view_forward = v_forward;
1721         view_right = v_right;
1722         view_up = v_up;
1723
1724 #ifdef BLURTEST
1725         if(time > blurtest_time0 && time < blurtest_time1)
1726         {
1727                 float r, t;
1728
1729                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1730                 r = t * blurtest_radius;
1731                 f = 1 / pow(t, blurtest_power) - 1;
1732
1733                 cvar_set("r_glsl_postprocess", "1");
1734                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1735         }
1736         else
1737         {
1738                 cvar_set("r_glsl_postprocess", "0");
1739                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1740         }
1741 #endif
1742
1743         TargetMusic_Advance();
1744         Fog_Force();
1745
1746         if(drawtime == 0)
1747                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1748         else
1749                 drawframetime = bound(0.000001, time - drawtime, 1);
1750         drawtime = time;
1751
1752         // watch for gametype changes here...
1753         // in ParseStuffCMD the cmd isn't executed yet :/
1754         // might even be better to add the gametype to TE_CSQC_INIT...?
1755         if(!postinit)
1756                 PostInit();
1757
1758         if(intermission && !gameover_time)
1759                 gameover_time = time;
1760
1761         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1762         {
1763                 if(calledhooks & HOOK_START)
1764                 {
1765                         localcmd("\ncl_hook_gameend\n");
1766                         calledhooks |= HOOK_END;
1767                 }
1768         }
1769
1770         Announcer();
1771
1772         fov = autocvar_fov;
1773         if(fov <= 59.5)
1774         {
1775                 if(!zoomscript_caught)
1776                 {
1777                         localcmd("+button9\n");
1778                         zoomscript_caught = 1;
1779                 }
1780         }
1781         else
1782         {
1783                 if(zoomscript_caught)
1784                 {
1785                         localcmd("-button9\n");
1786                         zoomscript_caught = 0;
1787                 }
1788         }
1789
1790         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1791
1792         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1793         {
1794                 entity wepent = viewmodels[slot];
1795
1796                 if(wepent.last_switchweapon != wepent.switchweapon)
1797                 {
1798                         weapontime = time;
1799                         wepent.last_switchweapon = wepent.switchweapon;
1800                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1801                         {
1802                                 localcmd("-zoom\n");
1803                                 button_zoom = false;
1804                         }
1805                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1806                         {
1807                                 localcmd("-fire\n");
1808                                 localcmd("-fire2\n");
1809                                 button_attack2 = false;
1810                         }
1811                 }
1812                 if(wepent.last_activeweapon != wepent.activeweapon)
1813                 {
1814                         wepent.last_activeweapon = wepent.activeweapon;
1815
1816                         e = wepent.activeweapon;
1817                         if(e.netname != "")
1818                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1819                         else if(slot == 0)
1820                                 localcmd("\ncl_hook_activeweapon none\n");
1821                 }
1822         }
1823
1824         // ALWAYS Clear Current Scene First
1825         clearscene();
1826
1827         setproperty(VF_ORIGIN, view_origin);
1828         setproperty(VF_ANGLES, view_angles);
1829
1830         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1831         setproperty(VF_SIZE, vf_size);
1832         setproperty(VF_MIN, vf_min);
1833
1834         // Assign Standard Viewflags
1835         // Draw the World (and sky)
1836         setproperty(VF_DRAWWORLD, 1);
1837
1838         // Set the console size vars
1839         vid_conwidth = autocvar_vid_conwidth;
1840         vid_conheight = autocvar_vid_conheight;
1841         vid_pixelheight = autocvar_vid_pixelheight;
1842
1843         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1844         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1845         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1846
1847         if(camera_active) // Camera for demo playback
1848         {
1849                 if(autocvar_camera_enable)
1850                         CSQC_Demo_Camera();
1851                 else
1852                 {
1853                         cvar_set("chase_active", ftos(chase_active_backup));
1854                         cvar_set("cl_demo_mousegrab", "0");
1855                         camera_active = false;
1856                 }
1857         }
1858         else
1859         {
1860 #ifdef CAMERATEST
1861                 if(autocvar_camera_enable)
1862 #else
1863                 if(autocvar_camera_enable && isdemo())
1864 #endif
1865                 {
1866                         // Enable required Darkplaces cvars
1867                         chase_active_backup = autocvar_chase_active;
1868                         cvar_set("chase_active", "2");
1869                         cvar_set("cl_demo_mousegrab", "1");
1870                         camera_active = true;
1871                         camera_mode = false;
1872                 }
1873         }
1874
1875         // Draw the Crosshair
1876         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1877
1878         // Draw the Engine Status Bar (the default Quake HUD)
1879         setproperty(VF_DRAWENGINESBAR, 0);
1880
1881         // Update the mouse position
1882         /*
1883            mousepos_x = vid_conwidth;
1884            mousepos_y = vid_conheight;
1885            mousepos = mousepos*0.5 + getmousepos();
1886          */
1887
1888         IL_EACH(g_drawables, it.draw, it.draw(it));
1889
1890         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1891         renderscene();
1892
1893         // now switch to 2D drawing mode by calling a 2D drawing function
1894         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1895         // next R_RenderScene call
1896         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1897
1898         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1899         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1900         {
1901                 // apply night vision effect
1902                 vector tc_00, tc_01, tc_10, tc_11;
1903                 vector rgb = '0 0 0';
1904
1905                 if(!nightvision_noise)
1906                 {
1907                         nightvision_noise = new(nightvision_noise);
1908                 }
1909                 if(!nightvision_noise2)
1910                 {
1911                         nightvision_noise2 = new(nightvision_noise2);
1912                 }
1913
1914                 // color tint in yellow
1915                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1916
1917                 // draw BG
1918                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1919                 rgb = '1 1 1';
1920                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1921                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1922                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1923                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1924                 tc_11 = tc_01 + tc_10 - tc_00;
1925                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1926                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1927                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1928                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1929                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1930                 R_EndPolygon();
1931
1932                 // draw FG
1933                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1934                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1935                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1936                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1937                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1938                 tc_11 = tc_01 + tc_10 - tc_00;
1939                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1940                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1941                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1942                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1943                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1944                 R_EndPolygon();
1945         }
1946
1947         if(autocvar_cl_reticle)
1948         {
1949                 string reticle_image = "";
1950                 bool wep_zoomed = false;
1951                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1952                 {
1953                         entity wepe = viewmodels[slot];
1954                         Weapon wep = wepe.activeweapon;
1955                         if(wep != WEP_Null && wep.wr_zoom)
1956                         {
1957                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1958                                 if(wep.w_reticle && wep.w_reticle != "")
1959                                         reticle_image = wep.w_reticle;
1960                                 wep_zoomed += do_zoom;
1961                         }
1962                 }
1963                 // Draw the aiming reticle for weapons that use it
1964                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1965                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1966                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1967                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1968                 {
1969                         // no zoom reticle while dead
1970                         reticle_type = 0;
1971                 }
1972                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1973                 {
1974                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1975                         else { reticle_type = 0; }
1976                 }
1977                 else if(button_zoom || zoomscript_caught)
1978                 {
1979                         // normal zoom
1980                         reticle_type = 1;
1981                 }
1982
1983                 if(reticle_type)
1984                 {
1985                         if(autocvar_cl_reticle_stretch)
1986                         {
1987                                 reticle_size.x = vid_conwidth;
1988                                 reticle_size.y = vid_conheight;
1989                                 reticle_pos.x = 0;
1990                                 reticle_pos.y = 0;
1991                         }
1992                         else
1993                         {
1994                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1995                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1996                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1997                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1998                         }
1999
2000                         if(zoomscript_caught)
2001                                 f = 1;
2002                         else
2003                                 f = current_zoomfraction;
2004
2005                         if(f)
2006                         {
2007                                 switch(reticle_type)
2008                                 {
2009                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2010                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2011                                 }
2012                         }
2013                 }
2014         }
2015         else
2016         {
2017                 if(reticle_type != 0) { reticle_type = 0; }
2018         }
2019
2020
2021         // improved polyblend
2022         if(autocvar_hud_contents)
2023         {
2024                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2025                 vector liquidcolor;
2026
2027                 switch(pointcontents(view_origin))
2028                 {
2029                         case CONTENT_WATER:
2030                                 liquidalpha = autocvar_hud_contents_water_alpha;
2031                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2032                                 incontent = 1;
2033                                 break;
2034
2035                         case CONTENT_LAVA:
2036                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2037                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2038                                 incontent = 1;
2039                                 break;
2040
2041                         case CONTENT_SLIME:
2042                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2043                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2044                                 incontent = 1;
2045                                 break;
2046
2047                         default:
2048                                 liquidalpha = 0;
2049                                 liquidcolor = '0 0 0';
2050                                 incontent = 0;
2051                                 break;
2052                 }
2053
2054                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2055                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2056                         contentfadetime = autocvar_hud_contents_fadeintime;
2057                         liquidalpha_prev = liquidalpha;
2058                         liquidcolor_prev = liquidcolor;
2059                 }
2060                 else
2061                         contentfadetime = autocvar_hud_contents_fadeouttime;
2062
2063                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2064                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2065
2066                 if(contentavgalpha)
2067                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2068
2069                 if(autocvar_hud_postprocessing)
2070                 {
2071                         if(autocvar_hud_contents_blur && contentavgalpha)
2072                         {
2073                                 content_blurpostprocess.x = 1;
2074                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2075                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2076                         }
2077                         else
2078                         {
2079                                 content_blurpostprocess.x = 0;
2080                                 content_blurpostprocess.y = 0;
2081                                 content_blurpostprocess.z = 0;
2082                         }
2083                 }
2084         }
2085
2086         if(autocvar_hud_damage && !STAT(FROZEN))
2087         {
2088                 splash_size.x = max(vid_conwidth, vid_conheight);
2089                 splash_size.y = max(vid_conwidth, vid_conheight);
2090                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2091                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2092
2093                 float myhealth_flash_temp;
2094                 myhealth = STAT(HEALTH);
2095
2096                 // fade out
2097                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2098                 // add new damage
2099                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2100
2101                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2102                 pain_threshold = autocvar_hud_damage_pain_threshold;
2103                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2104                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2105
2106                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2107                 {
2108                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2109                 }
2110
2111                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2112
2113                 if(myhealth_prev < 1)
2114                 {
2115                         if(myhealth >= 1)
2116                         {
2117                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2118                                 myhealth_flash_temp = 0;
2119                         }
2120                         else
2121                         {
2122                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2123                         }
2124                 }
2125
2126                 if(spectatee_status == -1 || intermission)
2127                 {
2128                         myhealth_flash = 0; // observing, or match ended
2129                         myhealth_flash_temp = 0;
2130                 }
2131
2132                 myhealth_prev = myhealth;
2133
2134                 // IDEA: change damage color/picture based on player model for robot/alien species?
2135                 // pro: matches model better
2136                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2137                 // maybe different reddish pics?
2138                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2139                 {
2140                         if(autocvar_cl_gentle_damage == 2)
2141                         {
2142                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2143                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2144                         }
2145                         else
2146                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2147
2148                         if(myhealth_flash_temp > 0)
2149                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2150                 }
2151                 else if(myhealth_flash_temp > 0)
2152                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2153
2154                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2155                 {
2156                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2157                         {
2158                                 damage_blurpostprocess.x = 1;
2159                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2160                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2161                         }
2162                         else
2163                         {
2164                                 damage_blurpostprocess.x = 0;
2165                                 damage_blurpostprocess.y = 0;
2166                                 damage_blurpostprocess.z = 0;
2167                         }
2168                 }
2169         }
2170
2171         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2172         float e2 = (autocvar_hud_powerup != 0);
2173         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2174         {
2175                 // enable or disable rendering types if they are used or not
2176                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2177                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2178
2179                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2180                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2181                 {
2182                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2183                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2184                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2185                         {
2186                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2187                                 old_blurradius = blurradius;
2188                                 old_bluralpha = bluralpha;
2189                         }
2190                 }
2191                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2192                 {
2193                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2194                         old_blurradius = 0;
2195                         old_bluralpha = 0;
2196                 }
2197
2198                 // edge detection postprocess handling done second (used by hud_powerup)
2199                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2200                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2201                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2202
2203                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2204
2205                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2206                 {
2207                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2208                         {
2209                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2210                                 old_sharpen_intensity = sharpen_intensity;
2211                         }
2212                 }
2213                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2214                 {
2215                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2216                         old_sharpen_intensity = 0;
2217                 }
2218
2219                 if(cvar("r_glsl_postprocess") == 0)
2220                         cvar_set("r_glsl_postprocess", "2");
2221         }
2222         else if(cvar("r_glsl_postprocess") == 2)
2223                 cvar_set("r_glsl_postprocess", "0");
2224
2225         /*if(gametype == MAPINFO_TYPE_CTF)
2226           {
2227           ctf_view();
2228           } else */
2229
2230         // draw 2D entities
2231         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2232         Draw_ShowNames_All();
2233         Debug_Draw();
2234
2235         scoreboard_active = Scoreboard_WouldDraw();
2236
2237         HUD_Draw(this); // this parameter for deep vehicle function
2238
2239         if(NextFrameCommand)
2240         {
2241                 localcmd("\n", NextFrameCommand, "\n");
2242                 NextFrameCommand = string_null;
2243         }
2244
2245         // we must do this check AFTER a frame was rendered, or it won't work
2246         if(cs_project_is_b0rked == 0)
2247         {
2248                 string w0, h0;
2249                 w0 = ftos(autocvar_vid_conwidth);
2250                 h0 = ftos(autocvar_vid_conheight);
2251                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2252                 //setproperty(VF_FOV, '90 90 0');
2253                 setproperty(VF_ORIGIN, '0 0 0');
2254                 setproperty(VF_ANGLES, '0 0 0');
2255                 setproperty(VF_PERSPECTIVE, 1);
2256                 makevectors('0 0 0');
2257                 vector v1, v2;
2258                 cvar_set("vid_conwidth", "800");
2259                 cvar_set("vid_conheight", "600");
2260                 v1 = cs_project(v_forward);
2261                 cvar_set("vid_conwidth", "640");
2262                 cvar_set("vid_conheight", "480");
2263                 v2 = cs_project(v_forward);
2264                 if(v1 == v2)
2265                         cs_project_is_b0rked = 1;
2266                 else
2267                         cs_project_is_b0rked = -1;
2268                 cvar_set("vid_conwidth", w0);
2269                 cvar_set("vid_conheight", h0);
2270         }
2271
2272         if(autocvar__hud_configure)
2273                 HUD_Panel_Mouse();
2274         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2275                 HUD_Minigame_Mouse();
2276         else if(QuickMenu_IsOpened())
2277                 QuickMenu_Mouse();
2278         else
2279                 HUD_Radar_Mouse();
2280
2281         cl_notice_run();
2282         unpause_update();
2283         Net_Flush();
2284
2285         // let's reset the view back to normal for the end
2286         setproperty(VF_MIN, '0 0 0');
2287         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2288
2289         IL_ENDFRAME();
2290 }
2291
2292
2293 // following vectors must be global to allow seamless switching between camera modes
2294 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2295 void CSQC_Demo_Camera()
2296 {
2297         float speed, attenuation, dimensions;
2298         vector tmp, delta;
2299
2300         if( autocvar_camera_reset || !camera_mode )
2301         {
2302                 camera_offset = '0 0 0';
2303                 current_angles = '0 0 0';
2304                 camera_direction = '0 0 0';
2305                 camera_offset.z += 30;
2306                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2307                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2308                 current_origin = view_origin;
2309                 current_camera_offset  = camera_offset;
2310                 cvar_set("camera_reset", "0");
2311                 camera_mode = CAMERA_CHASE;
2312         }
2313
2314         // Camera angles
2315         if( camera_roll )
2316                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2317
2318         if(autocvar_camera_look_player)
2319         {
2320                 vector dir;
2321                 float n;
2322
2323                 dir = normalize(view_origin - current_position);
2324                 n = mouse_angles.z;
2325                 mouse_angles = vectoangles(dir);
2326                 mouse_angles.x = mouse_angles.x * -1;
2327                 mouse_angles.z = n;
2328         }
2329         else
2330         {
2331                 tmp = getmousepos() * 0.1;
2332                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2333                 {
2334                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2335                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2336                 }
2337         }
2338
2339         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2340         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2341         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2342         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2343
2344         // Fix difference when angles don't have the same sign
2345         delta = '0 0 0';
2346         if(mouse_angles.y < -60 && current_angles.y > 60)
2347                 delta = '0 360 0';
2348         if(mouse_angles.y > 60 && current_angles.y < -60)
2349                 delta = '0 -360 0';
2350
2351         if(autocvar_camera_look_player)
2352                 attenuation = autocvar_camera_look_attenuation;
2353         else
2354                 attenuation = autocvar_camera_speed_attenuation;
2355
2356         attenuation = 1 / max(1, attenuation);
2357         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2358
2359         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2360         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2361         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2362         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2363
2364         // Camera position
2365         tmp = '0 0 0';
2366         dimensions = 0;
2367
2368         if( camera_direction.x )
2369         {
2370                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2371                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2372                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2373                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2374                 ++dimensions;
2375         }
2376
2377         if( camera_direction.y )
2378         {
2379                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2380                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2381                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2382                 ++dimensions;
2383         }
2384
2385         if( camera_direction.z )
2386         {
2387                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2388                 ++dimensions;
2389         }
2390
2391         if(autocvar_camera_free)
2392                 speed = autocvar_camera_speed_free;
2393         else
2394                 speed = autocvar_camera_speed_chase;
2395
2396         if(dimensions)
2397         {
2398                 speed = speed * sqrt(1 / dimensions);
2399                 camera_offset += tmp * speed;
2400         }
2401
2402         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2403
2404         // Camera modes
2405         if( autocvar_camera_free )
2406         {
2407                 if ( camera_mode == CAMERA_CHASE )
2408                 {
2409                         current_camera_offset = current_origin + current_camera_offset;
2410                         camera_offset = current_origin + camera_offset;
2411                 }
2412
2413                 camera_mode = CAMERA_FREE;
2414                 current_position = current_camera_offset;
2415         }
2416         else
2417         {
2418                 if ( camera_mode == CAMERA_FREE )
2419                 {
2420                         current_origin = view_origin;
2421                         camera_offset = camera_offset - current_origin;
2422                         current_camera_offset = current_camera_offset - current_origin;
2423                 }
2424
2425                 camera_mode = CAMERA_CHASE;
2426
2427                 if(autocvar_camera_chase_smoothly)
2428                         current_origin += (view_origin - current_origin) * attenuation;
2429                 else
2430                         current_origin = view_origin;
2431
2432                 current_position = current_origin + current_camera_offset;
2433         }
2434
2435         setproperty(VF_ANGLES, current_angles);
2436         setproperty(VF_ORIGIN, current_position);
2437 }