17f48136a6c0a4126f1ae96bf172c89fc63b9d4d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / effects / qc / damageeffects.qc
1 #include "damageeffects.qh"
2
3 REGISTER_NET_LINKED(ENT_CLIENT_DAMAGEINFO)
4
5 #ifdef SVQC
6
7 bool Damage_DamageInfo_SendEntity(entity this, entity to, int sf)
8 {
9         vector org = vec3(floor(this.origin.x), floor(this.origin.y), floor(this.origin.z));
10         WriteHeader(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
11         WriteShort(MSG_ENTITY, this.projectiledeathtype);
12         WriteVector(MSG_ENTITY, org);
13         WriteByte(MSG_ENTITY, bound(1, this.dmg, 255));
14         WriteByte(MSG_ENTITY, bound(0, this.dmg_radius, 255));
15         WriteByte(MSG_ENTITY, bound(1, this.dmg_edge, 255));
16         WriteShort(MSG_ENTITY, this.oldorigin.x);
17         WriteByte(MSG_ENTITY, this.species);
18         return true;
19 }
20
21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, int deathtype, float bloodtype, entity dmgowner)
22 {
23         // TODO maybe call this from non-edgedamage too?
24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
25
26         entity e;
27
28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
29                 deathtype |= 0x8000;
30
31         e = new(damageinfo);
32         setorigin(e, org);
33         e.projectiledeathtype = deathtype;
34         e.dmg = coredamage;
35         e.dmg_edge = edgedamage;
36         e.dmg_radius = rad;
37         e.dmg_force = vlen(force);
38         e.velocity = force;
39         e.oldorigin_x = compressShortVector(e.velocity);
40         e.species = bloodtype;
41
42         Net_LinkEntity(e, false, 0.2, Damage_DamageInfo_SendEntity);
43 }
44
45 #endif
46
47 #ifdef CSQC
48
49 /** number of effects which currently are attached to a player */
50 .int total_damages;
51
52 .entity tag_entity;
53
54 .float cnt;
55 .int state;
56
57 void DamageEffect_Think(entity this)
58 {
59         // if particle distribution is enabled, slow ticrate by total number of damages
60         if(autocvar_cl_damageeffect_distribute)
61                 this.nextthink = time + autocvar_cl_damageeffect_ticrate * this.owner.total_damages;
62         else
63                 this.nextthink = time + autocvar_cl_damageeffect_ticrate;
64
65         if(time >= this.cnt || !this.owner || !this.owner.modelindex || !this.owner.drawmask)
66         {
67                 // time is up or the player got gibbed / disconnected
68                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
69                 delete(this);
70                 return;
71         }
72         if(this.state && !this.owner.csqcmodel_isdead)
73         {
74                 // if the player was dead but is now alive, it means he respawned
75                 // if so, clear his damage effects, or damages from his dead body will be copied back
76                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
77                 delete(this);
78                 return;
79         }
80         this.state = this.owner.csqcmodel_isdead;
81         if((this.owner.isplayermodel & ISPLAYER_LOCAL) && !autocvar_chase_active)
82                 return; // if we aren't using a third person camera, hide our own effects
83
84         // now generate the particles
85         vector org = gettaginfo(this, 0); // origin at attached location
86         __pointparticles(this.team, org, '0 0 0', 1);
87 }
88
89 string species_prefix(int specnum)
90 {
91         switch(specnum)
92         {
93                 case SPECIES_HUMAN:       return "";
94                 case SPECIES_ALIEN:       return "alien_";
95                 case SPECIES_ROBOT_SHINY: return "robot_";
96                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
97                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
98                 case SPECIES_ANIMAL:      return "animal_";
99                 case SPECIES_RESERVED:    return "reserved_";
100                 default:         return "";
101         }
102 }
103
104 void DamageEffect(entity this, vector hitorg, float thedamage, int type, int specnum)
105 {
106         // particle effects for players and objects damaged by weapons (eg: flames coming out of victims shot with rockets)
107
108         int nearestbone = 0;
109         float life;
110         string effectname;
111         entity e, wep;
112
113         if(!autocvar_cl_damageeffect || autocvar_cl_gentle || autocvar_cl_gentle_damage)
114                 return;
115         if(!this || !this.modelindex || !this.drawmask)
116                 return;
117
118         // if this is a rigged mesh, the effect will show on the bone where damage was dealt
119         // we do this by choosing the skeletal bone closest to the impact, and attaching our entity to it
120         // if there's no skeleton, object origin will automatically be selected
121         FOR_EACH_TAG(this)
122         {
123                 if(!tagnum)
124                         continue; // skip empty bones
125                 // blacklist bones positioned outside the mesh, or the effect will be floating
126                 // TODO: Do we have to do it this way? Why do these bones exist at all?
127                 if(gettaginfo_name == "master" || gettaginfo_name == "knee_L" || gettaginfo_name == "knee_R" || gettaginfo_name == "leg_L" || gettaginfo_name == "leg_R")
128                         continue; // player model bone blacklist
129
130                 // now choose the bone closest to impact origin
131                 if(nearestbone == 0 || vlen2(hitorg - gettaginfo(this, tagnum)) <= vlen2(hitorg - gettaginfo(this, nearestbone)))
132                         nearestbone = tagnum;
133         }
134         gettaginfo(this, nearestbone); // set gettaginfo_name
135
136         // return if we reached our damage effect limit or damages are disabled
137         // TODO: When the limit is reached, it would be better if the oldest damage was removed instead of not adding a new one
138         if(nearestbone)
139         {
140                 if(this.total_damages >= autocvar_cl_damageeffect_bones)
141                         return; // allow multiple damages on skeletal models
142         }
143         else
144         {
145                 if(autocvar_cl_damageeffect < 2 || this.total_damages)
146                         return; // allow a single damage on non-skeletal models
147         }
148
149         life = bound(autocvar_cl_damageeffect_lifetime_min, thedamage * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
150
151         wep = DEATH_WEAPONOF(type);
152         effectname = strcat("damage_", wep.netname);
153         if((wep.spawnflags & WEP_FLAG_BLEED))
154         {
155                 // if this weapon induces bleeding, use the effect name with the proper species prefix (blood type)
156                 if((this.isplayermodel & ISPLAYER_MODEL))
157                 {
158                         string specstr = species_prefix(specnum);
159                         effectname = strcat(specstr, effectname);
160                 }
161                 else { return; } // objects don't bleed
162         }
163
164         e = new(damage);
165         setmodel(e, MDL_Null); // necessary to attach and read origin
166         setattachment(e, this, gettaginfo_name); // attach to the given bone
167         e.owner = this;
168         e.cnt = time + life;
169         e.team = _particleeffectnum(effectname);
170         setthink(e, DamageEffect_Think);
171         e.nextthink = time;
172         this.total_damages += 1;
173 }
174
175 NET_HANDLE(ENT_CLIENT_DAMAGEINFO, bool isNew)
176 {
177         float thedamage, rad, edge, thisdmg;
178         bool hitplayer = false;
179         int species, forcemul;
180         vector force, thisforce;
181
182         w_deathtype = ReadShort();
183         w_issilent = (w_deathtype & 0x8000);
184         w_deathtype = (w_deathtype & 0x7FFF);
185
186         w_org = ReadVector();
187
188         thedamage = ReadByte();
189         rad = ReadByte();
190         edge = ReadByte();
191         force = decompressShortVector(ReadShort());
192         species = ReadByte();
193
194         return = true;
195
196         if (!isNew)
197                 return;
198
199         if(rad < 0)
200         {
201                 rad = -rad;
202                 forcemul = -1;
203         }
204         else
205                 forcemul = 1;
206
207     FOREACH_ENTITY_RADIUS(w_org, rad + MAX_DAMAGEEXTRARADIUS, !it.tag_entity, {
208                 vector nearest = NearestPointOnBox(it, w_org);
209                 if (rad)
210                 {
211                         thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
212                         if(thisdmg >= 1)
213                                 continue;
214                         if(thisdmg < 0)
215                                 thisdmg = 0;
216                         if(thedamage)
217                         {
218                                 thisdmg = thedamage + (edge - thedamage) * thisdmg;
219                                 thisforce = forcemul * vlen(force) * (thisdmg / thedamage) * normalize(it.origin - w_org);
220                         }
221                         else
222                         {
223                                 thisdmg = 0;
224                                 thisforce = forcemul * vlen(force) * normalize(it.origin - w_org);
225                         }
226                 }
227                 else
228                 {
229                         if(vdist((nearest - w_org), >, bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)))
230                                 continue;
231
232                         thisdmg = thedamage;
233                         thisforce = forcemul * force;
234                 }
235
236                 if(it.damageforcescale)
237                         if(vdist(thisforce, !=, 0))
238                         {
239                                 it.velocity = it.velocity + damage_explosion_calcpush(it.damageforcescale * thisforce, it.velocity, damagepush_speedfactor);
240                                 UNSET_ONGROUND(it);
241                         }
242
243                 if(w_issilent)
244                         it.silent = 1;
245
246                 if(it.event_damage)
247                         it.event_damage(it, thisdmg, w_deathtype, w_org, thisforce);
248
249                 DamageEffect(it, w_org, thisdmg, w_deathtype, species);
250
251                 if((it.isplayermodel & ISPLAYER_MODEL))
252                         hitplayer = true; // this impact damaged a player
253         });
254
255         if(DEATH_ISVEHICLE(w_deathtype))
256         {
257                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
258                 if(trace_plane_normal != '0 0 0')
259                         w_backoff = trace_plane_normal;
260                 else
261                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
262
263                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
264
265                 switch(DEATH_ENT(w_deathtype))
266                 {
267                         case DEATH_VH_CRUSH:
268                                 break;
269
270                         // spiderbot
271                         case DEATH_VH_SPID_MINIGUN:
272                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
273                                 pointparticles(EFFECT_SPIDERBOT_MINIGUN_IMPACT, this.origin, w_backoff * 1000, 1);
274                                 break;
275                         case DEATH_VH_SPID_ROCKET:
276                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
277                                 pointparticles(EFFECT_SPIDERBOT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
278                                 break;
279                         case DEATH_VH_SPID_DEATH:
280                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
281                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
282                                 break;
283
284                         case DEATH_VH_WAKI_GUN:
285                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
286                                 pointparticles(EFFECT_RACER_IMPACT, this.origin, w_backoff * 1000, 1);
287                                 break;
288                         case DEATH_VH_WAKI_ROCKET:
289                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
290                                 pointparticles(EFFECT_RACER_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
291                                 break;
292                         case DEATH_VH_WAKI_DEATH:
293                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
294                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
295                                 break;
296
297                         case DEATH_VH_RAPT_CANNON:
298                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
299                                 pointparticles(EFFECT_RAPTOR_CANNON_IMPACT, this.origin, w_backoff * 1000, 1);
300                                 break;
301                         case DEATH_VH_RAPT_FRAGMENT:
302                                 float i;
303                                 vector ang, vel;
304                                 for(i = 1; i < 4; ++i)
305                                 {
306                                         vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
307                                         ang = vectoangles(vel);
308                                         RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
309                                 }
310                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
311                                 pointparticles(EFFECT_RAPTOR_BOMB_SPREAD, this.origin, w_backoff * 1000, 1);
312                                 break;
313                         case DEATH_VH_RAPT_BOMB:
314                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
315                                 pointparticles(EFFECT_RAPTOR_BOMB_IMPACT, this.origin, w_backoff * 1000, 1);
316                                 break;
317                         case DEATH_VH_RAPT_DEATH:
318                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
319                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
320                                 break;
321                         case DEATH_VH_BUMB_GUN:
322                                 sound(this, CH_SHOTS, SND_FIREBALL_IMPACT2, VOL_BASE, ATTEN_NORM);
323                                 pointparticles(EFFECT_BIGPLASMA_IMPACT, this.origin, w_backoff * 1000, 1);
324                                 break;
325                 }
326         }
327
328
329         if(DEATH_ISTURRET(w_deathtype))
330         {
331                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
332                 if(trace_plane_normal != '0 0 0')
333                         w_backoff = trace_plane_normal;
334                 else
335                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
336
337                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
338
339                 switch(DEATH_ENT(w_deathtype))
340                 {
341                          case DEATH_TURRET_EWHEEL:
342                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
343                                 pointparticles(EFFECT_BLASTER_IMPACT, this.origin, w_backoff * 1000, 1);
344                                 break;
345
346                          case DEATH_TURRET_FLAC:
347                                 pointparticles(EFFECT_HAGAR_EXPLODE, w_org, '0 0 0', 1);
348                                 sound(this, CH_SHOTS, SND_HAGEXP_RANDOM(), VOL_BASE, ATTEN_NORM);
349                                 break;
350
351                          case DEATH_TURRET_MLRS:
352                          case DEATH_TURRET_HK:
353                          case DEATH_TURRET_WALK_ROCKET:
354                          case DEATH_TURRET_HELLION:
355                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
356                                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
357                                 break;
358
359                          case DEATH_TURRET_MACHINEGUN:
360                          case DEATH_TURRET_WALK_GUN:
361                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
362                                 pointparticles(EFFECT_MACHINEGUN_IMPACT, this.origin, w_backoff * 1000, 1);
363                                 break;
364
365                          case DEATH_TURRET_PLASMA:
366                                 sound(this, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_LOW);
367                                 pointparticles(EFFECT_ELECTRO_IMPACT, this.origin, w_backoff * 1000, 1);
368                                 break;
369
370                          case DEATH_TURRET_WALK_MELEE:
371                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_LOW);
372                                 pointparticles(EFFECT_TE_SPARK, this.origin, w_backoff * 1000, 1);
373                                 break;
374
375                          case DEATH_TURRET_PHASER:
376                                 break;
377
378                          case DEATH_TURRET_TESLA:
379                                 te_smallflash(this.origin);
380                                 break;
381
382                 }
383         }
384
385         MUTATOR_CALLHOOK(DamageInfo, this, w_deathtype, w_org);
386
387         // TODO spawn particle effects and sounds based on w_deathtype
388         if(!DEATH_ISSPECIAL(w_deathtype))
389         if(!hitplayer || rad) // don't show ground impacts for hitscan weapons if a player was hit
390         {
391                 Weapon hitwep = DEATH_WEAPONOF(w_deathtype);
392                 w_random = prandom();
393
394                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
395                 if(trace_fraction < 1 && !(hitwep.spawnflags & WEP_TYPE_HITSCAN))
396                         w_backoff = trace_plane_normal;
397                 else
398                         w_backoff = -1 * normalize(force);
399                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
400
401                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
402                 {
403                         if(!MUTATOR_CALLHOOK(Weapon_ImpactEffect, hitwep, this))
404                                 hitwep.wr_impacteffect(hitwep, this);
405                 }
406         }
407 }
408
409 #endif