qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_LAST = 6;
  38
  39 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  40
  41 // find same game piece given its tile name
  42 entity bd_find_piece(entity minig, string tile, bool check_target)
  43 {
  44         entity e = world;
  45         while ( ( e = findentity(e,owner,minig) ) )
  46                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  47                         return e;
  48         return world;
  49 }
  50
  51 // check if the tile name is valid (15x15 grid)
  52 bool bd_valid_tile(string tile)
  53 {
  54         if ( !tile )
  55                 return false;
  56         int number = minigame_tile_number(tile);
  57         int letter = minigame_tile_letter(tile);
  58         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  59 }
  60
  61 entity bd_find_dozer(entity minig)
  62 {
  63         entity e = world;
  64         while ( ( e = findentity(e,owner,minig) ) )
  65                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  66                         return e;
  67         return world;
  68 }
  69
  70 void bd_check_winner(entity minig)
  71 {
  72         int total = 0, valid = 0;
  73         entity e = world;
  74         while ( ( e = findentity(e,owner,minig) ) )
  75                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  76                 {
  77                         ++total;
  78                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  79                                 ++valid;
  80                 }
  81
  82         if(valid >= total)
  83         {
  84                 minig.minigame_flags = BD_TURN_WIN;
  85                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  86         }
  87 }
  88
  89 bool bd_canfill(int ttype)
  90 {
  91         switch(ttype)
  92         {
  93                 case BD_TILE_BRICK1:
  94                 case BD_TILE_BRICK2:
  95                 case BD_TILE_BRICK3: return true;
  96         }
  97
  98         return false;
  99 }
 100
 101 bool bd_move_dozer(entity minigame, entity dozer)
 102 {
 103         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 104                 return false; // nope!
 105
 106         int myx = minigame_tile_letter(dozer.netname);
 107         int myy = minigame_tile_number(dozer.netname);
 108
 109         myx += dozer.bd_dir_x;
 110         myy += dozer.bd_dir_y;
 111
 112         string newpos = minigame_tile_buildname(myx, myy);
 113         entity hit = bd_find_piece(minigame, newpos, false);
 114
 115         if(!bd_valid_tile(newpos))
 116                 return false;
 117
 118         if(hit)
 119         switch(hit.bd_tiletype)
 120         {
 121                 case BD_TILE_DOZER: // wtf, but let's do this incase
 122                 case BD_TILE_BRICK1:
 123                 case BD_TILE_BRICK2:
 124                 case BD_TILE_BRICK3: return false;
 125                 case BD_TILE_BOULDER:
 126                 {
 127                         string testpos;
 128                         int tx = minigame_tile_letter(hit.netname);
 129                         int ty = minigame_tile_number(hit.netname);
 130
 131                         tx += dozer.bd_dir_x;
 132                         ty += dozer.bd_dir_y;
 133
 134                         testpos = minigame_tile_buildname(tx, ty);
 135                         entity testhit = bd_find_piece(minigame, testpos, false);
 136
 137                         if(!bd_valid_tile(testpos) || testhit)
 138                                 return false;
 139
 140                         if(hit.netname) { strunzone(hit.netname); }
 141                         hit.netname = strzone(testpos);
 142                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 143                         break;
 144                 }
 145         }
 146
 147         if(dozer.netname) { strunzone(dozer.netname); }
 148         dozer.netname = strzone(newpos);
 149
 150         return true;
 151 }
 152
 153 // make a move
 154 void bd_move(entity minigame, entity player, string dir)
 155 {
 156         if ( minigame.minigame_flags & BD_TURN_MOVE )
 157         if ( dir )
 158         {
 159                 //if ( bd_valid_tile(pos) )
 160                 //if ( bd_find_piece(minigame, pos, false) )
 161                 {
 162                         entity dozer = bd_find_dozer(minigame);
 163                         if(!dozer)
 164                         {
 165                                 LOG_INFO("Dozer wasn't found!\n");
 166                                 return; // should not happen... TODO: end match?
 167                         }
 168
 169                         int dxs = 0, dys = 0;
 170                         string thedir = strtolower(dir);
 171                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 172                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 173                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 174                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 175
 176                         int dx = bound(-1, dxs, 1);
 177                         int dy = bound(-1, dys, 1);
 178
 179                         dozer.bd_dir_x = dx;
 180                         dozer.bd_dir_y = dy;
 181                         dozer.bd_dir_z = 0;
 182
 183                         if(bd_move_dozer(minigame, dozer))
 184                                 player.bd_moves++;
 185
 186                         bd_check_winner(minigame);
 187
 188                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 189                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 190                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 191                 }
 192         }
 193 }
 194
 195 // editor
 196 void bd_editor_place(entity minigame, entity player, string pos, int thetile)
 197 {
 198         if ( minigame.minigame_flags & BD_TURN_EDIT )
 199         if ( pos && thetile )
 200         {
 201                 if ( bd_valid_tile(pos) )
 202                 {
 203                         bool exists = ( bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true) );
 204
 205                         entity dozer = bd_find_dozer(minigame);
 206                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 207                                 return; // nice try
 208
 209                         if(exists)
 210                         {
 211                                 entity piece = bd_find_piece(minigame, pos, false);
 212                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 213                                 if(!piece)
 214                                         return; // how?!
 215
 216                                 if(piece.netname) { strunzone(piece.netname); }
 217                                 remove(piece);
 218                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 219                                 return;
 220                         }
 221
 222                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 223                         piece.team = 1;
 224                         piece.netname = strzone(pos);
 225                         piece.bd_tiletype = thetile;
 226                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 227
 228                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 229                 }
 230         }
 231 }
 232
 233 void bd_do_move(entity minigame, entity player, string dir, string thetile)
 234 {
 235         if(minigame.minigame_flags & BD_TURN_MOVE)
 236                 bd_move(minigame, player, dir);
 237
 238         if(minigame.minigame_flags & BD_TURN_EDIT)
 239                 bd_editor_place(minigame, player, dir, stof(thetile));
 240 }
 241
 242 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 243 {
 244         string pos = minigame_tile_buildname(letter,number);
 245         if(!bd_valid_tile(pos))
 246                 return;
 247         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 248                 return;
 249
 250         bd_editor_place(minigame, player, pos, thetype);
 251
 252         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 253         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 254         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 255         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 256 }
 257
 258 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 259 {
 260         if(minigame.minigame_flags & BD_TURN_EDIT)
 261         {
 262                 int thetype = stof(thetile);
 263
 264                 if(!bd_canfill(thetype))
 265                         return;
 266
 267                 int letter = minigame_tile_letter(dir);
 268                 int number = minigame_tile_number(dir);
 269
 270                 bd_fill_recurse(minigame, player, thetype, letter, number);
 271         }
 272 }
 273
 274 void bd_reset_moves(entity minigame)
 275 {
 276         entity e;
 277 #ifdef SVQC
 278         for(e = minigame.minigame_players; e; e = e.list_next)
 279 #elif defined(CSQC)
 280         e = world;
 281         while( (e = findentity(e,owner,minigame)) )
 282                 if ( e.classname == "minigame_player" )
 283 #endif
 284                 {
 285                         e.bd_moves = 0;
 286                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 287                 }
 288 }
 289
 290 void bd_load_level(entity minigame);
 291 void bd_setup_pieces(entity minigame)
 292 {
 293         entity e = world;
 294         while( (e = findentity(e, owner, minigame)) )
 295                 if(e.classname == "minigame_board_piece")
 296                 {
 297                         if(e.netname) { strunzone(e.netname); }
 298                         remove(e);
 299                 }
 300
 301         bd_load_level(minigame);
 302 }
 303
 304 void bd_do_next_match(entity minigame, entity player)
 305 {
 306         minigame.minigame_flags = BD_TURN_MOVE;
 307         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 308
 309         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 310         {
 311                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 312                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 313         }
 314
 315         bd_setup_pieces(minigame);
 316
 317         bd_reset_moves(minigame);
 318 }
 319
 320 void bd_set_next_match(entity minigame, string next)
 321 {
 322         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 323         minigame.bd_nextlevel = strzone(next);
 324 }
 325
 326 void bd_next_match(entity minigame, entity player, string next)
 327 {
 328         if(minigame.minigame_flags & BD_TURN_WIN)
 329                 bd_do_next_match(minigame, player);
 330         if(minigame.minigame_flags & BD_TURN_EDIT)
 331                 bd_set_next_match(minigame, next);
 332 }
 333
 334 // request a new match
 335 void bd_restart_match(entity minigame, entity player)
 336 {
 337         minigame.minigame_flags = BD_TURN_MOVE;
 338         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 339
 340         bd_setup_pieces(minigame);
 341
 342         bd_reset_moves(minigame);
 343 }
 344
 345 void bd_activate_editor(entity minigame, entity player)
 346 {
 347 #ifdef SVQC
 348         if(!player.minigame_players.bd_canedit)
 349         {
 350                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 351                 return;
 352         }
 353 #endif
 354
 355         minigame.minigame_flags = BD_TURN_EDIT;
 356         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 357
 358         bd_reset_moves(minigame);
 359
 360         bd_setup_pieces(minigame);
 361 }
 362
 363 string bd_save_piece(entity minigame, entity e)
 364 {
 365         string bd_string = "";
 366
 367         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 368         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 369         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir), " ");
 370         bd_string = strcat(bd_string, "; ");
 371
 372         return bd_string;
 373 }
 374
 375 void bd_set_nextlevel(entity minigame, string s)
 376 {
 377         string blah = substring(s, 11, strlen(s));
 378
 379         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 380         minigame.bd_nextlevel = strzone(blah);
 381 }
 382
 383 entity bd_load_piece(entity minigame, string s)
 384 {
 385         // separate pieces between the ; symbols
 386         tokenizebyseparator(s, "; ");
 387         string bd_string = argv(0);
 388
 389         tokenize_console(bd_string);
 390
 391         entity e = msle_spawn(minigame,"minigame_board_piece");
 392         e.team = 1;
 393
 394         int argv_num = 0;
 395         e.netname = strzone(argv(argv_num)); ++argv_num;
 396         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 397         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 398
 399         minigame_server_sendflags(e,MINIG_SF_ALL);
 400
 401         return e;
 402 }
 403
 404 bool bd_save_level(entity minigame)
 405 {
 406         if(minigame.bd_levelname && minigame.bd_levelname != "")
 407         {
 408                 // saves all objects to the database file
 409                 string file_name;
 410                 float file_get;
 411
 412                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 413                 file_get = fopen(file_name, FILE_WRITE);
 414                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 415
 416                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt")))
 417                         fputs(file_get, strcat("nextlevel=", minigame.bd_nextlevel, "\n"));
 418
 419                 entity e = world;
 420                 while ( ( e = findentity(e,owner,minigame) ) )
 421                 if ( e.classname == "minigame_board_piece" )
 422                 {
 423                         // use a line of text for each object, listing all properties
 424                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 425                 }
 426                 fclose(file_get);
 427
 428                 return true;
 429         }
 430
 431         return false;
 432 }
 433
 434 void bd_load_level(entity minigame)
 435 {
 436         // loads all items from the database file
 437         string file_read, file_name;
 438         float file_get;
 439
 440         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 441         file_get = fopen(file_name, FILE_READ);
 442         if(file_get < 0)
 443         {
 444                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 445         }
 446         else
 447         {
 448                 for(;;)
 449                 {
 450                         file_read = fgets(file_get);
 451                         if(file_read == "")
 452                                 break;
 453                         if(substring(file_read, 0, 2) == "//")
 454                                 continue;
 455                         if(substring(file_read, 0, 1) == "#")
 456                                 continue;
 457                         if(substring(file_read, 0, 10) == "nextlevel=")
 458                         {
 459                                 bd_set_nextlevel(minigame, file_read);
 460                                 continue;
 461                         }
 462
 463                         entity e;
 464                         e = bd_load_piece(minigame, file_read);
 465                 }
 466         }
 467         fclose(file_get);
 468 }
 469
 470 void bd_close_editor(entity minigame)
 471 {
 472         entity dozer = bd_find_dozer(minigame);
 473         if(!dozer)
 474         {
 475                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 476                 return;
 477         }
 478
 479         if(bd_save_level(minigame))
 480         {
 481                 minigame.minigame_flags = BD_TURN_MOVE;
 482                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 483         }
 484         else
 485         {
 486                 LOG_INFO("You need to set the level name!\n");
 487                 return;
 488         }
 489 }
 490
 491 #ifdef SVQC
 492
 493 // required function, handle server side events
 494 int bd_server_event(entity minigame, string event, ...)
 495 {
 496         switch(event)
 497         {
 498                 case "start":
 499                 {
 500                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 501                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 502                         bd_setup_pieces(minigame);
 503                         minigame.minigame_flags = BD_TURN_MOVE;
 504
 505                         return true;
 506                 }
 507                 case "end":
 508                 {
 509                         entity e = world;
 510                         while( (e = findentity(e, owner, minigame)) )
 511                         if(e.classname == "minigame_board_piece")
 512                         {
 513                                 if(e.netname) { strunzone(e.netname); }
 514                                 remove(e);
 515                         }
 516
 517                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 518                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 519                         return false;
 520                 }
 521                 case "join":
 522                 {
 523                         int pl_num = minigame_count_players(minigame);
 524
 525                         if(pl_num >= BD_TEAMS) { return false; }
 526
 527                         return 1;
 528                 }
 529                 case "cmd":
 530                 {
 531                         switch(argv(0))
 532                         {
 533                                 case "move":
 534                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 535                                         return true;
 536                                 case "next":
 537                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 538                                         return true;
 539                                 case "restart":
 540                                         bd_restart_match(minigame,...(0,entity));
 541                                         return true;
 542                                 case "edit":
 543                                         bd_activate_editor(minigame,...(0,entity));
 544                                         return true;
 545                                 case "save":
 546                                         bd_close_editor(minigame);
 547                                         return true;
 548                                 case "fill":
 549                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 550                                         return true;
 551                         }
 552
 553                         return false;
 554                 }
 555                 case "network_send":
 556                 {
 557                         entity sent = ...(0,entity);
 558                         int sf = ...(1,int);
 559                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 560                         {
 561                                 int letter = minigame_tile_letter(sent.netname);
 562                                 int number = minigame_tile_number(sent.netname);
 563
 564                                 WriteByte(MSG_ENTITY,letter);
 565                                 WriteByte(MSG_ENTITY,number);
 566
 567                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 568
 569                                 int dx = sent.bd_dir_x;
 570                                 int dy = sent.bd_dir_y;
 571                                 if(dx == -1) dx = 2;
 572                                 if(dy == -1) dy = 2;
 573                                 WriteByte(MSG_ENTITY,dx);
 574                                 WriteByte(MSG_ENTITY,dy);
 575                         }
 576                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 577                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 578                         return false;
 579                 }
 580         }
 581
 582         return false;
 583 }
 584
 585
 586 #elif defined(CSQC)
 587
 588 int bd_curr_tile;
 589 string bd_curr_pos;
 590
 591 vector bd_boardpos; // HUD board position
 592 vector bd_boardsize;// HUD board size
 593
 594 string bd_get_tile_pic(int tileid)
 595 {
 596         switch(tileid)
 597         {
 598                 case BD_TILE_BOULDER: return "bd/boulder";
 599                 case BD_TILE_BRICK1: return "bd/brick1";
 600                 case BD_TILE_BRICK2: return "bd/brick2";
 601                 case BD_TILE_BRICK3: return "bd/brick3";
 602                 case BD_TILE_TARGET: return "bd/target";
 603                 case BD_TILE_DOZER: return "bd/dozer";
 604         }
 605
 606         return string_null;
 607 }
 608
 609 // Required function, draw the game board
 610 void bd_hud_board(vector pos, vector mySize)
 611 {
 612         minigame_hud_fitsqare(pos, mySize);
 613         bd_boardpos = pos;
 614         bd_boardsize = mySize;
 615
 616         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 617
 618         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 619         vector tile_pos;
 620
 621         entity e;
 622         FOREACH_MINIGAME_ENTITY(e)
 623         {
 624                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 625                 {
 626                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 627                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 628
 629                         string thepiece = "bd/brick1";
 630                         switch(e.bd_tiletype)
 631                         {
 632                                 case BD_TILE_BOULDER: thepiece = "bd/boulder"; break;
 633                                 case BD_TILE_BRICK2: thepiece = "bd/brick2"; break;
 634                                 case BD_TILE_BRICK3: thepiece = "bd/brick3"; break;
 635                         }
 636
 637                         minigame_drawpic_centered( tile_pos,
 638                                         minigame_texture(thepiece),
 639                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 640                 }
 641
 642                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET && e.bd_tiletype != BD_TILE_DOZER )
 643                 {
 644                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 645                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 646
 647                         minigame_drawpic_centered( tile_pos,
 648                                         minigame_texture("bd/target"),
 649                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 650                 }
 651
 652                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype != BD_TILE_TARGET && e.bd_tiletype == BD_TILE_DOZER )
 653                 {
 654                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 655                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 656
 657                         vector thedir = e.bd_dir;
 658                         float theang = 0;
 659
 660                         if(thedir_y == -1) { theang = M_PI; }
 661                         if(thedir_x == 1) { theang = M_PI/2; }
 662                         if(thedir_x == -1) { theang = M_PI*3/2; }
 663
 664                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 665                                                 tile_size, tile_size/2, '1 1 1',
 666                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 667                 }
 668         }
 669
 670         FOREACH_MINIGAME_ENTITY(e)
 671         {
 672                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
 673                 {
 674                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 675                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 676
 677                         minigame_drawpic_centered( tile_pos,
 678                                         minigame_texture("bd/target"),
 679                                         tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 680                 }
 681         }
 682
 683         FOREACH_MINIGAME_ENTITY(e)
 684         {
 685                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 686                 {
 687                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 688                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 689
 690                         vector thedir = e.bd_dir;
 691                         float theang = 0;
 692
 693                         if(thedir_y == -1) { theang = M_PI; }
 694                         if(thedir_x == 1) { theang = M_PI/2; }
 695                         if(thedir_x == -1) { theang = M_PI*3/2; }
 696
 697                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 698                                                 tile_size, tile_size/2, '1 1 1',
 699                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 700                 }
 701         }
 702
 703         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 704         if(bd_valid_tile(bd_curr_pos))
 705         {
 706                 bool exists = (bd_find_piece(active_minigame, bd_curr_pos, false) || bd_find_piece(active_minigame, bd_curr_pos, true));
 707                 string thepiece = ((exists) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 708
 709                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 710                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 711                 minigame_drawpic_centered( tile_pos,
 712                                 minigame_texture(thepiece),
 713                                 tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 714         }
 715
 716         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 717         {
 718                 vector winfs = hud_fontsize*2;
 719                 string victory_text = "Game over!";
 720
 721                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 722                         victory_text = "You win!";
 723
 724                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 725                 vector win_sz;
 726                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 727                         sprintf("%s", victory_text),
 728                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 729
 730                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 731
 732                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 733                         sprintf("%s", victory_text),
 734                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 735         }
 736 }
 737
 738
 739 // Required function, draw the game status panel
 740 void bd_hud_status(vector pos, vector mySize)
 741 {
 742         HUD_Panel_DrawBg(1);
 743         vector ts;
 744         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 745                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 746
 747         pos_y += ts_y;
 748         mySize_y -= ts_y;
 749
 750         vector player_fontsize = hud_fontsize * 1.75;
 751         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 752         ts_x = mySize_x;
 753         vector mypos;
 754         vector tile_size = '48 48 0';
 755
 756         mypos = pos;
 757         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 758         mypos_y += player_fontsize_y;
 759         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 760
 761         entity e;
 762         FOREACH_MINIGAME_ENTITY(e)
 763         {
 764                 if ( e.classname == "minigame_player" )
 765                 {
 766                         mypos = pos;
 767                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 768                                 GetPlayerName(e.minigame_playerslot-1),
 769                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 770
 771                         mypos_y += player_fontsize_y;
 772                         string thepiece = "bd/dozer";
 773                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 774                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 775                         drawpic( mypos,
 776                                         minigame_texture(thepiece),
 777                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 778
 779                         mypos_x += tile_size_x;
 780
 781                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 782                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 783                 }
 784         }
 785 }
 786
 787 // Turn a set of flags into a help message
 788 string bd_turn_to_string(int turnflags)
 789 {
 790         if ( turnflags & BD_TURN_LOSS )
 791                 return _("Better luck next time!");
 792
 793         if ( turnflags & BD_TURN_WIN )
 794                 if(random() > 0.5)
 795                         return _("Tubular! Press ""Next Level"" to continue!");
 796                 else
 797                         return _("Wicked! Press ""Next Level"" to continue!");
 798
 799         if( turnflags & BD_TURN_EDIT )
 800                 return _("Press the space bar to change your currently selected tile");
 801
 802         if ( turnflags & BD_TURN_MOVE )
 803                 return _("Push the boulders onto the targets");
 804
 805         return "";
 806 }
 807
 808 // Make the correct move
 809 void bd_make_move(entity minigame, string dir)
 810 {
 811         if ( minigame.minigame_flags == BD_TURN_MOVE )
 812         {
 813                 minigame_cmd("move ", dir);
 814         }
 815 }
 816
 817 void bd_editor_make_move(entity minigame)
 818 {
 819         if ( minigame.minigame_flags == BD_TURN_EDIT )
 820         {
 821                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile));
 822         }
 823 }
 824
 825 void bd_editor_fill(entity minigame)
 826 {
 827         if ( minigame.minigame_flags == BD_TURN_EDIT )
 828         {
 829                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 830         }
 831 }
 832
 833 void bd_set_curr_pos(string s)
 834 {
 835         if ( bd_curr_pos )
 836                 strunzone(bd_curr_pos);
 837         if ( s )
 838                 s = strzone(s);
 839         bd_curr_pos = s;
 840 }
 841
 842 bool bd_normal_move(entity minigame, int themove)
 843 {
 844         switch ( themove )
 845         {
 846                 case K_RIGHTARROW:
 847                 case K_KP_RIGHTARROW:
 848                         bd_make_move(minigame, "r");
 849                         return true;
 850                 case K_LEFTARROW:
 851                 case K_KP_LEFTARROW:
 852                         bd_make_move(minigame, "l");
 853                         return true;
 854                 case K_UPARROW:
 855                 case K_KP_UPARROW:
 856                         bd_make_move(minigame, "u");
 857                         return true;
 858                 case K_DOWNARROW:
 859                 case K_KP_DOWNARROW:
 860                         bd_make_move(minigame, "d");
 861                         return true;
 862         }
 863
 864         return false;
 865 }
 866
 867 bool bd_editor_move(entity minigame, int themove)
 868 {
 869         switch ( themove )
 870         {
 871                 case K_RIGHTARROW:
 872                 case K_KP_RIGHTARROW:
 873                         if ( ! bd_curr_pos )
 874                                 bd_set_curr_pos("a3");
 875                         else
 876                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
 877                         return true;
 878                 case K_LEFTARROW:
 879                 case K_KP_LEFTARROW:
 880                         if ( ! bd_curr_pos )
 881                                 bd_set_curr_pos("c3");
 882                         else
 883                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
 884                         return true;
 885                 case K_UPARROW:
 886                 case K_KP_UPARROW:
 887                         if ( ! bd_curr_pos )
 888                                 bd_set_curr_pos("a1");
 889                         else
 890                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
 891                         return true;
 892                 case K_DOWNARROW:
 893                 case K_KP_DOWNARROW:
 894                         if ( ! bd_curr_pos )
 895                                 bd_set_curr_pos("a3");
 896                         else
 897                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
 898                         return true;
 899                 case K_ENTER:
 900                 case K_KP_ENTER:
 901                         bd_editor_make_move(minigame);
 902                         return true;
 903                 case K_SPACE:
 904                         bd_curr_tile += 1;
 905                         if(bd_curr_tile > BD_TILE_LAST)
 906                                 bd_curr_tile = 1;
 907                         return true;
 908         }
 909
 910         return false;
 911 }
 912
 913 // Required function, handle client events
 914 int bd_client_event(entity minigame, string event, ...)
 915 {
 916         switch(event)
 917         {
 918                 case "activate":
 919                 {
 920                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
 921                         bd_set_curr_pos("");
 922                         bd_curr_tile = BD_TILE_BRICK1;
 923                         return false;
 924                 }
 925                 case "key_pressed":
 926                 {
 927                         if(minigame.minigame_flags & BD_TURN_MOVE)
 928                         {
 929                                 if(bd_normal_move(minigame, ...(0,int)))
 930                                         return true;
 931                         }
 932
 933                         if(minigame.minigame_flags & BD_TURN_EDIT)
 934                         {
 935                                 if(bd_editor_move(minigame, ...(0,int)))
 936                                         return true;
 937                         }
 938
 939                         return false;
 940                 }
 941                 case "mouse_pressed":
 942                 {
 943                         if(minigame.minigame_flags & BD_TURN_EDIT)
 944                         {
 945                                 if(...(0,int) == K_MOUSE1)
 946                                 {
 947                                         bd_editor_make_move(minigame);
 948                                         return true;
 949                                 }
 950
 951                                 if(...(0,int) == K_MOUSE2)
 952                                 {
 953                                         bd_editor_fill(minigame);
 954                                         return true;
 955                                 }
 956                         }
 957
 958                         return false;
 959                 }
 960                 case "mouse_moved":
 961                 {
 962                         if(minigame.minigame_flags & BD_TURN_EDIT)
 963                         {
 964                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
 965                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
 966                                 if ( ! bd_valid_tile(bd_curr_pos) )
 967                                         bd_set_curr_pos("");
 968                         }
 969                         return true;
 970                 }
 971                 case "network_receive":
 972                 {
 973                         entity sent = ...(0,entity);
 974                         int sf = ...(1,int);
 975                         if ( sent.classname == "minigame" )
 976                         {
 977                                 if ( sf & MINIG_SF_UPDATE )
 978                                 {
 979                                         sent.message = bd_turn_to_string(sent.minigame_flags);
 980                                         //if ( sent.minigame_flags & minigame_self.team )
 981                                                 minigame_prompt();
 982                                 }
 983                         }
 984                         else if(sent.classname == "minigame_board_piece")
 985                         {
 986                                 if(sf & MINIG_SF_UPDATE)
 987                                 {
 988                                         int letter = ReadByte();
 989                                         int number = ReadByte();
 990                                         if(sent.netname) { strunzone(sent.netname); }
 991                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
 992
 993                                         sent.bd_tiletype = ReadByte();
 994
 995                                         int dx = ReadByte();
 996                                         int dy = ReadByte();
 997
 998                                         if(dx == 2) dx = -1;
 999                                         if(dy == 2) dy = -1;
1000
1001                                         sent.bd_dir_x = dx;
1002                                         sent.bd_dir_y = dy;
1003                                         sent.bd_dir_z = 0;
1004                                 }
1005                         }
1006                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1007                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1008
1009                         return false;
1010                 }
1011                 case "menu_show":
1012                 {
1013                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1014                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1015                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1016                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1017                         return false;
1018                 }
1019                 case "menu_click":
1020                 {
1021                         if(...(0,string) == "next")
1022                                 minigame_cmd("next");
1023                         if(...(0,string) == "restart")
1024                                 minigame_cmd("restart");
1025                         if(...(0,string) == "edit")
1026                                 minigame_cmd("edit");
1027                         if(...(0,string) == "save")
1028                                 minigame_cmd("save");
1029                         return false;
1030                 }
1031         }
1032
1033         return false;
1034 }
1035
1036 #endif