qcsrc/common/monsters/monster/spider.qc

   1 #ifdef REGISTER_MONSTER
   2 REGISTER_MONSTER(
   3 /* MON_##id   */ SPIDER,
   4 /* function   */ m_spider,
   5 /* spawnflags */ MON_FLAG_MELEE | MON_FLAG_RANGED,
   6 /* mins,maxs  */ '-18 -18 -25', '18 18 30',
   7 /* model      */ "spider.dpm",
   8 /* netname    */ "spider",
   9 /* fullname   */ _("Spider")
  10 );
  11
  12 #define SPIDER_SETTINGS(monster) \
  13         MON_ADD_CVAR(monster, health) \
  14         MON_ADD_CVAR(monster, attack_bite_damage) \
  15         MON_ADD_CVAR(monster, attack_bite_delay) \
  16         MON_ADD_CVAR(monster, attack_web_damagetime) \
  17         MON_ADD_CVAR(monster, attack_web_speed) \
  18         MON_ADD_CVAR(monster, attack_web_speed_up) \
  19         MON_ADD_CVAR(monster, attack_web_delay) \
  20         MON_ADD_CVAR(monster, speed_stop) \
  21         MON_ADD_CVAR(monster, speed_run) \
  22         MON_ADD_CVAR(monster, speed_walk)
  23
  24 #ifdef SVQC
  25 SPIDER_SETTINGS(spider)
  26 #endif // SVQC
  27 #else
  28 #ifdef SVQC
  29 const float spider_anim_idle            = 0;
  30 const float spider_anim_walk            = 1;
  31 const float spider_anim_attack          = 2;
  32 const float spider_anim_attack2         = 3;
  33
  34 .float spider_web_delay;
  35
  36 void spider_web_explode()
  37 {
  38         entity e;
  39         if(self)
  40         {
  41                 pointparticles(particleeffectnum("electro_impact"), self.origin, '0 0 0', 1);
  42                 RadiusDamage(self, self.realowner, 0, 0, 25, world, 25, self.projectiledeathtype, world);
  43
  44                 for(e = findradius(self.origin, 25); e; e = e.chain) if(e != self) if(e.takedamage && e.deadflag == DEAD_NO) if(e.health > 0)
  45                         e.spider_slowness = time + MON_CVAR(spider, attack_web_damagetime);
  46
  47                 remove(self);
  48         }
  49 }
  50
  51 void spider_web_touch()
  52 {
  53         PROJECTILE_TOUCH;
  54
  55         spider_web_explode();
  56 }
  57
  58 void spider_shootweb()
  59 {
  60         monster_makevectors(self.enemy);
  61
  62         sound(self, CH_SHOTS, "weapons/electro_fire2.wav", VOL_BASE, ATTEN_NORM);
  63
  64         entity proj = spawn ();
  65         proj.classname = "plasma";
  66         proj.owner = proj.realowner = self;
  67         proj.use = spider_web_touch;
  68         proj.think = adaptor_think2use_hittype_splash;
  69         proj.bot_dodge = TRUE;
  70         proj.bot_dodgerating = 0;
  71         proj.nextthink = time + 5;
  72         PROJECTILE_MAKETRIGGER(proj);
  73         proj.projectiledeathtype = DEATH_MONSTER_SPIDER;
  74         setorigin(proj, CENTER_OR_VIEWOFS(self));
  75
  76         //proj.glow_size = 50;
  77         //proj.glow_color = 45;
  78         proj.movetype = MOVETYPE_BOUNCE;
  79         W_SetupProjectileVelocityEx(proj, v_forward, v_up, MON_CVAR(spider, attack_web_speed), MON_CVAR(spider, attack_web_speed_up), 0, 0, FALSE);
  80         proj.touch = spider_web_touch;
  81         setsize(proj, '-4 -4 -4', '4 4 4');
  82         proj.takedamage = DAMAGE_NO;
  83         proj.damageforcescale = 0;
  84         proj.health = 500;
  85         proj.event_damage = func_null;
  86         proj.flags = FL_PROJECTILE;
  87         proj.damagedbycontents = TRUE;
  88
  89         proj.bouncefactor = 0.3;
  90         proj.bouncestop = 0.05;
  91         proj.missile_flags = MIF_SPLASH | MIF_ARC;
  92
  93         CSQCProjectile(proj, TRUE, PROJECTILE_ELECTRO, TRUE);
  94 }
  95
  96 float spider_attack(float attack_type)
  97 {
  98         switch(attack_type)
  99         {
 100                 case MONSTER_ATTACK_MELEE:
 101                 {
 102                         return monster_melee(self.enemy, MON_CVAR(spider, attack_bite_damage), ((random() > 0.5) ? spider_anim_attack : spider_anim_attack2), self.attack_range, MON_CVAR(spider, attack_bite_delay), DEATH_MONSTER_SPIDER, TRUE);
 103                 }
 104                 case MONSTER_ATTACK_RANGED:
 105                 {
 106                         if(time >= self.spider_web_delay)
 107                         {
 108                                 self.frame = spider_anim_attack2;
 109                                 self.attack_finished_single = time + MON_CVAR(spider, attack_web_delay);
 110                                 spider_shootweb();
 111                                 self.spider_web_delay = time + 3;
 112                                 return TRUE;
 113                         }
 114
 115                         return FALSE;
 116                 }
 117         }
 118
 119         return FALSE;
 120 }
 121
 122 void spawnfunc_monster_spider()
 123 {
 124         self.classname = "monster_spider";
 125
 126         self.monster_spawnfunc = spawnfunc_monster_spider;
 127
 128         if(Monster_CheckAppearFlags(self))
 129                 return;
 130
 131         if not(monster_initialize(MON_SPIDER, FALSE)) { remove(self); return; }
 132 }
 133
 134 float m_spider(float req)
 135 {
 136         switch(req)
 137         {
 138                 case MR_THINK:
 139                 {
 140                         monster_move(MON_CVAR(spider, speed_run), MON_CVAR(spider, speed_walk), MON_CVAR(spider, speed_stop), spider_anim_walk, spider_anim_walk, spider_anim_idle);
 141                         return TRUE;
 142                 }
 143                 case MR_DEATH:
 144                 {
 145                         self.frame = spider_anim_attack;
 146                         self.angles_x = 180;
 147                         return TRUE;
 148                 }
 149                 case MR_SETUP:
 150                 {
 151                         if not(self.health) self.health = MON_CVAR(spider, health);
 152
 153                         self.monster_loot = spawnfunc_item_health_medium;
 154                         self.monster_attackfunc = spider_attack;
 155                         self.frame = spider_anim_idle;
 156
 157                         return TRUE;
 158                 }
 159                 case MR_PRECACHE:
 160                 {
 161                         precache_model ("models/monsters/spider.dpm");
 162                         precache_sound ("weapons/electro_fire2.wav");
 163                         return TRUE;
 164                 }
 165                 case MR_CONFIG:
 166                 {
 167                         MON_CONFIG_SETTINGS(SPIDER_SETTINGS(spider))
 168                         return TRUE;
 169                 }
 170         }
 171
 172         return TRUE;
 173 }
 174
 175 #endif // SVQC
 176 #ifdef CSQC
 177 float m_spider(float req)
 178 {
 179         switch(req)
 180         {
 181                 case MR_PRECACHE:
 182                 {
 183                         precache_model ("models/monsters/spider.dpm");
 184                         return TRUE;
 185                 }
 186         }
 187
 188         return TRUE;
 189 }
 190
 191 #endif // CSQC
 192 #endif // REGISTER_MONSTER