qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void M_Item_Touch ()
   7 {
   8         if(self && IS_PLAYER(other) && other.deadflag == DEAD_NO)
   9         {
  10                 Item_Touch();
  11                 self.think = SUB_Remove;
  12                 self.nextthink = time + 0.1;
  13         }
  14 }
  15
  16 void monster_item_spawn()
  17 {
  18         if(self.monster_loot)
  19                 self.monster_loot();
  20
  21         self.gravity = 1;
  22         self.velocity = randomvec() * 175 + '0 0 325';
  23         self.touch = M_Item_Touch;
  24
  25         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  26 }
  27
  28 void monster_dropitem()
  29 {
  30         if(!self.candrop || !self.monster_loot)
  31                 return;
  32
  33         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  34         entity e = spawn();
  35
  36         setorigin(e, org);
  37
  38         e.monster_loot = self.monster_loot;
  39
  40         other = e;
  41         MUTATOR_CALLHOOK(MonsterDropItem);
  42         e = other;
  43
  44         e.think = monster_item_spawn;
  45         e.nextthink = time + 0.3;
  46 }
  47
  48 void monsters_setframe(float _frame)
  49 {
  50         if(self.frame == _frame)
  51                 return;
  52
  53         self.anim_start_time = time;
  54         self.frame = _frame;
  55         self.SendFlags |= MSF_ANIM;
  56 }
  57
  58 float monster_isvalidtarget (entity targ, entity ent)
  59 {
  60         if(!targ || !ent)
  61                 return FALSE; // someone doesn't exist
  62
  63         if(targ == ent)
  64                 return FALSE; // don't attack ourselves
  65
  66         if(time < game_starttime)
  67                 return FALSE; // monsters do nothing before the match has started
  68
  69         WarpZone_TraceLine(ent.origin, targ.origin, MOVE_NORMAL, ent);
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(trace_ent != targ)
  75                 return FALSE; // we can't see the enemy
  76
  77         if(targ.takedamage == DAMAGE_NO)
  78                 return FALSE; // enemy can't be damaged
  79
  80         if(targ.items & IT_INVISIBILITY)
  81                 return FALSE; // enemy is invisible
  82
  83         if(substring(targ.classname, 0, 10) == "onslaught_")
  84                 return FALSE; // don't attack onslaught targets
  85
  86         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  87                 return FALSE; // enemy is a spectator
  88
  89         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  90                 return FALSE; // enemy/self is dead
  91
  92         if(ent.monster_owner == targ)
  93                 return FALSE; // don't attack our master
  94
  95         if(targ.monster_owner == ent)
  96                 return FALSE; // don't attack our pet
  97
  98         if(targ.flags & FL_NOTARGET)
  99                 return FALSE; // enemy can't be targeted
 100
 101         if not(autocvar_g_monsters_typefrag)
 102         if(targ.BUTTON_CHAT)
 103                 return FALSE; // no typefragging!
 104
 105         if not(IsDifferentTeam(targ, ent))
 106                 return FALSE; // enemy is on our team
 107
 108         if(autocvar_g_monsters_target_infront)
 109         if(ent.enemy != targ)
 110         {
 111                 float dot;
 112
 113                 makevectors (ent.angles);
 114                 dot = normalize (targ.origin - ent.origin) * v_forward;
 115
 116                 if(dot <= 0.3)
 117                         return FALSE;
 118         }
 119
 120         return TRUE;
 121 }
 122
 123 entity FindTarget (entity ent)
 124 {
 125         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 126
 127         entity head, closest_target = world;
 128         head = findradius(ent.origin, ent.target_range);
 129
 130         while(head) // find the closest acceptable target to pass to
 131         {
 132                 if(monster_isvalidtarget(head, ent))
 133                 {
 134                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 135                         vector head_center = CENTER_OR_VIEWOFS(head);
 136                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 137
 138                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 139                         if(closest_target)
 140                         {
 141                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 142                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 143                                         { closest_target = head; }
 144                         }
 145                         else { closest_target = head; }
 146                 }
 147
 148                 head = head.chain;
 149         }
 150
 151         return closest_target;
 152 }
 153
 154 void MonsterTouch ()
 155 {
 156         if(other == world)
 157                 return;
 158
 159         if(self.enemy != other)
 160         if not(other.flags & FL_MONSTER)
 161         if(monster_isvalidtarget(other, self))
 162                 self.enemy = other;
 163 }
 164
 165 void monster_sound(string msound, float sound_delay, float delaytoo)
 166 {
 167         if(delaytoo && time < self.msound_delay)
 168                 return; // too early
 169
 170         if(msound == "")
 171                 return; // sound doesn't exist
 172
 173         sound(self, CHAN_AUTO, msound, VOL_BASE, ATTEN_NORM);
 174
 175         self.msound_delay = time + sound_delay;
 176 }
 177
 178 void monster_precachesounds(entity e)
 179 {
 180         precache_sound(e.msound_idle);
 181         precache_sound(e.msound_death);
 182         precache_sound(e.msound_attack_melee);
 183         precache_sound(e.msound_attack_ranged);
 184         precache_sound(e.msound_sight);
 185         precache_sound(e.msound_pain);
 186 }
 187
 188 void monster_setupsounds(string mon)
 189 {
 190         if(self.msound_idle == "") self.msound_idle = strzone(strcat("monsters/", mon, "_idle.wav"));
 191         if(self.msound_death == "") self.msound_death = strzone(strcat("monsters/", mon, "_death.wav"));
 192         if(self.msound_pain == "") self.msound_pain = strzone(strcat("monsters/", mon, "_pain.wav"));
 193         if(self.msound_attack_melee == "") self.msound_attack_melee = strzone(strcat("monsters/", mon, "_melee.wav"));
 194         if(self.msound_attack_ranged == "") self.msound_attack_ranged = strzone(strcat("monsters/", mon, "_attack.wav"));
 195         if(self.msound_sight == "") self.msound_sight = strzone(strcat("monsters/", mon, "_sight.wav"));
 196 }
 197
 198 void monster_makevectors(entity e)
 199 {
 200         vector v;
 201
 202         v = CENTER_OR_VIEWOFS(e);
 203         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 204         self.v_angle_x = -self.v_angle_x;
 205
 206         makevectors(self.v_angle);
 207 }
 208
 209 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 210 {
 211         float rdmg = damg * random();
 212
 213         if (self.health <= 0)
 214                 return FALSE; // attacking while dead?!
 215
 216         if(dostop)
 217         {
 218                 self.velocity_x = 0;
 219                 self.velocity_y = 0;
 220                 self.state = MONSTER_STATE_ATTACK_MELEE;
 221                 self.SendFlags |= MSF_MOVE;
 222         }
 223
 224         monsters_setframe(anim);
 225
 226         if(anim_finished != 0)
 227                 self.attack_finished_single = time + anim_finished;
 228
 229         monster_makevectors(targ);
 230
 231         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 232
 233         if(trace_ent.takedamage)
 234                 Damage(trace_ent, self, self, rdmg * monster_skill, deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 235
 236         return TRUE;
 237 }
 238
 239 void Monster_CheckMinibossFlag ()
 240 {
 241         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 242                 return;
 243
 244         float chance = random() * 100;
 245
 246         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 247         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 248         {
 249                 self.health += autocvar_g_monsters_miniboss_healthboost;
 250                 if not(self.weapon)
 251                         self.weapon = WEP_NEX;
 252         }
 253 }
 254
 255 float Monster_CanRespawn(entity ent)
 256 {
 257         other = ent;
 258         if(MUTATOR_CALLHOOK(MonsterRespawn))
 259                 return TRUE; // enabled by a mutator
 260
 261         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 262                 return FALSE;
 263
 264         if not(autocvar_g_monsters_respawn)
 265                 return FALSE;
 266
 267         return TRUE;
 268 }
 269
 270 void Monster_Fade ()
 271 {
 272         if(Monster_CanRespawn(self))
 273         {
 274                 self.monster_respawned = TRUE;
 275                 self.think = self.monster_spawnfunc;
 276                 self.nextthink = time + self.respawntime;
 277                 self.deadflag = DEAD_RESPAWNING;
 278                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 279                 {
 280                         self.pos1 = self.origin;
 281                         self.pos2 = self.angles;
 282                 }
 283                 self.event_damage = func_null;
 284                 self.takedamage = DAMAGE_NO;
 285                 setorigin(self, self.pos1);
 286                 self.angles = self.pos2;
 287                 self.health = self.max_health;
 288
 289                 self.SendFlags |= MSF_MOVE;
 290                 self.SendFlags |= MSF_STATUS;
 291         }
 292         else
 293                 SUB_SetFade(self, time + 3, 1);
 294 }
 295
 296 float Monster_CanJump (vector vel)
 297 {
 298         if(self.state)
 299                 return FALSE; // already attacking
 300         if not(self.flags & FL_ONGROUND)
 301                 return FALSE; // not on the ground
 302         if(self.health <= 0)
 303                 return FALSE; // called when dead?
 304         if(time < self.attack_finished_single)
 305                 return FALSE; // still attacking
 306
 307         vector old = self.velocity;
 308
 309         self.velocity = vel;
 310         tracetoss(self, self);
 311         self.velocity = old;
 312         if (trace_ent != self.enemy)
 313                 return FALSE;
 314
 315         return TRUE;
 316 }
 317
 318 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 319 {
 320         if(!Monster_CanJump(vel))
 321                 return FALSE;
 322
 323         monsters_setframe(anm);
 324         self.state = MONSTER_STATE_ATTACK_LEAP;
 325         self.touch = touchfunc;
 326         self.origin_z += 1;
 327         self.velocity = vel;
 328         self.flags &= ~FL_ONGROUND;
 329
 330         self.attack_finished_single = time + anim_finished;
 331
 332         return TRUE;
 333 }
 334
 335 void monster_checkattack(entity e, entity targ)
 336 {
 337         if(e == world)
 338                 return;
 339         if(targ == world)
 340                 return;
 341
 342         if not(e.monster_attackfunc)
 343                 return;
 344
 345         if(time < e.attack_finished_single)
 346                 return;
 347
 348         if(vlen(targ.origin - e.origin) <= e.attack_range)
 349         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 350         {
 351                 monster_sound(e.msound_attack_melee, 0, FALSE);
 352                 return;
 353         }
 354
 355         if(vlen(targ.origin - e.origin) > e.attack_range)
 356         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 357         {
 358                 monster_sound(e.msound_attack_ranged, 0, FALSE);
 359                 return;
 360         }
 361 }
 362
 363 void monster_use ()
 364 {
 365         if (self.enemy)
 366                 return;
 367         if (self.health <= 0)
 368                 return;
 369
 370         if(!monster_isvalidtarget(activator, self))
 371                 return;
 372
 373         self.enemy = activator;
 374 }
 375
 376 .float last_trace;
 377 .float last_enemycheck; // for checking enemy
 378 vector monster_pickmovetarget(entity targ)
 379 {
 380         // enemy is always preferred target
 381         if(self.enemy)
 382         {
 383                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 384                 self.last_trace = time + 1.2;
 385                 return self.enemy.origin;
 386         }
 387
 388         switch(self.monster_moveflags)
 389         {
 390                 case MONSTER_MOVE_OWNER:
 391                 {
 392                         self.monster_movestate = MONSTER_MOVE_OWNER;
 393                         self.last_trace = time + 0.3;
 394                         if(self.monster_owner && self.monster_owner.classname != "td_spawnpoint")
 395                                 return self.monster_owner.origin;
 396                 }
 397                 case MONSTER_MOVE_SPAWNLOC:
 398                 {
 399                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 400                         self.last_trace = time + 2;
 401                         return self.pos1;
 402                 }
 403                 case MONSTER_MOVE_NOMOVE:
 404                 {
 405                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 406                         self.last_trace = time + 2;
 407                         return self.origin;
 408                 }
 409                 default:
 410                 case MONSTER_MOVE_WANDER:
 411                 {
 412                         vector pos;
 413                         self.monster_movestate = MONSTER_MOVE_WANDER;
 414                         self.last_trace = time + 2;
 415
 416                         self.angles_y = random() * 500;
 417                         makevectors(self.angles);
 418                         pos = self.origin + v_forward * 600;
 419
 420                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 421                         {
 422                                 pos_z = random() * 200;
 423                                 if(random() >= 0.5)
 424                                         pos_z *= -1;
 425                         }
 426
 427                         if(targ)
 428                         {
 429                                 self.last_trace = time + 0.5;
 430                                 pos = targ.origin;
 431                         }
 432
 433                         return pos;
 434                 }
 435         }
 436 }
 437
 438 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 439 {
 440         fixedmakevectors(self.angles);
 441
 442         if(self.target2)
 443                 self.goalentity = find(world, targetname, self.target2);
 444
 445         entity targ;
 446
 447         if(self.frozen)
 448         {
 449                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
 450                 self.health = max(1, self.max_health * self.revive_progress);
 451
 452                 if(self.sprite) WaypointSprite_UpdateHealth(self.sprite, self.health);
 453
 454                 movelib_beak_simple(stopspeed);
 455
 456                 self.velocity = '0 0 0';
 457                 self.enemy = world;
 458                 self.nextthink = time + 0.1;
 459
 460                 if(self.revive_progress >= 1)
 461                         Unfreeze(self); // wait for next think before attacking
 462
 463                 // don't bother updating angles here?
 464                 if(self.origin != self.oldorigin)
 465                 {
 466                         self.oldorigin = self.origin;
 467                         self.SendFlags |= MSF_MOVE;
 468                 }
 469
 470                 return; // no moving while frozen
 471         }
 472
 473         if(self.flags & FL_SWIM)
 474         {
 475                 if(self.waterlevel < WATERLEVEL_WETFEET)
 476                 {
 477                         if(time >= self.last_trace)
 478                         {
 479                                 self.last_trace = time + 0.4;
 480
 481                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 482                                 self.angles = '90 90 0';
 483                                 if(random() < 0.5)
 484                                 {
 485                                         self.velocity_y += random() * 50;
 486                                         self.velocity_x -= random() * 50;
 487                                 }
 488                                 else
 489                                 {
 490                                         self.velocity_y -= random() * 50;
 491                                         self.velocity_x += random() * 50;
 492                                 }
 493                                 self.velocity_z += random() * 150;
 494                         }
 495
 496
 497                         self.movetype = MOVETYPE_BOUNCE;
 498                         //self.velocity_z = -200;
 499
 500                         self.SendFlags |= MSF_MOVE | MSF_ANG;
 501
 502                         return;
 503                 }
 504                 else
 505                 {
 506                         self.angles = '0 0 0';
 507                         self.movetype = MOVETYPE_WALK;
 508                 }
 509         }
 510
 511         targ = self.goalentity;
 512
 513         monster_target = targ;
 514         monster_speed_run = runspeed;
 515         monster_speed_walk = walkspeed;
 516
 517         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 518         {
 519                 runspeed = walkspeed = 0;
 520                 if(time >= self.spawn_time)
 521                         monsters_setframe(manim_idle);
 522                 movelib_beak_simple(stopspeed);
 523                 self.SendFlags |= MSF_MOVE;
 524                 return;
 525         }
 526
 527         targ = monster_target;
 528         runspeed = monster_speed_run;
 529         walkspeed = monster_speed_walk;
 530
 531         if(teamplay)
 532         if(autocvar_g_monsters_teams)
 533         if(IsDifferentTeam(self.monster_owner, self))
 534                 self.monster_owner = world;
 535
 536         if(self.enemy && self.enemy.health < 1)
 537                 self.enemy = world; // enough!
 538
 539         if(time >= self.last_enemycheck)
 540         {
 541                 if not(monster_isvalidtarget(self.enemy, self))
 542                         self.enemy = world;
 543
 544                 if not(self.enemy)
 545                 {
 546                         self.enemy = FindTarget(self);
 547                         if(self.enemy)
 548                                 monster_sound(self.msound_sight, 0, FALSE);
 549                 }
 550
 551                 self.last_enemycheck = time + 2;
 552         }
 553
 554         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 555                 self.state = 0;
 556
 557         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 558         if(time >= self.last_trace || self.enemy) // update enemy instantly
 559                 self.moveto = monster_pickmovetarget(targ);
 560
 561         if not(self.enemy)
 562                 monster_sound(self.msound_idle, 5, TRUE);
 563
 564         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 565                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 566
 567         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 568         {
 569                 self.state = 0;
 570                 self.touch = MonsterTouch;
 571         }
 572
 573         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 574
 575         float turny = 0;
 576         vector real_angle = vectoangles(self.steerto) - self.angles;
 577
 578         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 579                 turny = 20;
 580
 581         if(self.flags & FL_SWIM)
 582                 turny = vlen(self.angles - self.moveto);
 583
 584         if(turny)
 585         {
 586                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 587                 self.angles_y += turny;
 588         }
 589
 590         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 591                 self.moveto = self.origin;
 592         else if(self.enemy)
 593                 self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 594
 595         if not(self.flags & FL_FLY || self.flags & FL_SWIM)
 596                 self.moveto_z = self.origin_z;
 597
 598         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 599                 v_forward = normalize(self.moveto - self.origin);
 600
 601         if(vlen(self.origin - self.moveto) > 64)
 602         {
 603                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 604                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 605                 else
 606                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 607                 if(time > self.pain_finished)
 608                 if(time > self.attack_finished_single)
 609                 if(vlen(self.velocity) > 0)
 610                         monsters_setframe((self.enemy) ? manim_run : manim_walk);
 611                 else
 612                         monsters_setframe(manim_idle);
 613         }
 614         else
 615         {
 616                 entity e = find(world, targetname, self.target2);
 617                 if(e.target2)
 618                         self.target2 = e.target2;
 619                 else if(e.target)
 620                         self.target2 = e.target;
 621
 622                 movelib_beak_simple(stopspeed);
 623                 if(time > self.attack_finished_single)
 624                 if(time > self.pain_finished)
 625                 if (vlen(self.velocity) <= 30)
 626                         monsters_setframe(manim_idle);
 627         }
 628
 629         monster_checkattack(self, self.enemy);
 630
 631         if(self.angles != self.oldangles)
 632         {
 633                 self.oldangles = self.angles;
 634                 self.SendFlags |= MSF_ANG;
 635         }
 636
 637         if(self.origin != self.oldorigin)
 638         {
 639                 self.oldorigin = self.origin;
 640                 self.SendFlags |= MSF_MOVE;
 641         }
 642 }
 643
 644 void monster_dead_think()
 645 {
 646         self.think = monster_dead_think;
 647         self.nextthink = time + 0.3; // don't need to update so often now
 648
 649         self.deadflag = DEAD_DEAD;
 650
 651         if(time >= self.ltime)
 652         {
 653                 Monster_Fade();
 654                 return;
 655         }
 656
 657         self.SendFlags |= MSF_MOVE; // keep up to date on the monster's location
 658 }
 659
 660 void monsters_setstatus()
 661 {
 662         self.stat_monsters_total = monsters_total;
 663         self.stat_monsters_killed = monsters_killed;
 664 }
 665
 666 void Monster_Appear()
 667 {
 668         self.enemy = activator;
 669         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 670         self.monster_spawnfunc();
 671 }
 672
 673 float Monster_CheckAppearFlags(entity ent)
 674 {
 675         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 676                 return FALSE;
 677
 678         ent.think = func_null;
 679         ent.nextthink = 0;
 680         ent.use = Monster_Appear;
 681         ent.flags = FL_MONSTER; // set so this monster can get butchered
 682
 683         return TRUE;
 684 }
 685
 686 void monsters_reset()
 687 {
 688         setorigin(self, self.pos1);
 689         self.angles = self.pos2;
 690
 691         self.health = self.max_health;
 692         self.velocity = '0 0 0';
 693         self.enemy = world;
 694         self.goalentity = world;
 695         self.attack_finished_single = 0;
 696         self.moveto = self.origin;
 697
 698         WaypointSprite_UpdateHealth(self.sprite, self.health);
 699 }
 700
 701 float monster_send(entity to, float sf)
 702 {
 703         WriteByte(MSG_ENTITY, ENT_CLIENT_MONSTER);
 704         WriteByte(MSG_ENTITY, sf);
 705         if(sf & MSF_SETUP)
 706         {
 707             WriteByte(MSG_ENTITY, self.monsterid);
 708
 709             WriteCoord(MSG_ENTITY, self.origin_x);
 710             WriteCoord(MSG_ENTITY, self.origin_y);
 711             WriteCoord(MSG_ENTITY, self.origin_z);
 712
 713             WriteAngle(MSG_ENTITY, self.angles_x);
 714             WriteAngle(MSG_ENTITY, self.angles_y);
 715
 716                 WriteByte(MSG_ENTITY, self.skin);
 717                 WriteByte(MSG_ENTITY, self.team);
 718     }
 719
 720     if(sf & MSF_ANG)
 721     {
 722         WriteShort(MSG_ENTITY, rint(self.angles_x));
 723         WriteShort(MSG_ENTITY, rint(self.angles_y));
 724     }
 725
 726     if(sf & MSF_MOVE)
 727     {
 728         WriteShort(MSG_ENTITY, rint(self.origin_x));
 729         WriteShort(MSG_ENTITY, rint(self.origin_y));
 730         WriteShort(MSG_ENTITY, rint(self.origin_z));
 731
 732         WriteShort(MSG_ENTITY, rint(self.velocity_x));
 733         WriteShort(MSG_ENTITY, rint(self.velocity_y));
 734         WriteShort(MSG_ENTITY, rint(self.velocity_z));
 735
 736         WriteShort(MSG_ENTITY, rint(self.angles_y));
 737     }
 738
 739     if(sf & MSF_ANIM)
 740     {
 741         WriteCoord(MSG_ENTITY, self.anim_start_time);
 742         WriteByte(MSG_ENTITY, self.frame);
 743     }
 744
 745     if(sf & MSF_STATUS)
 746     {
 747                 WriteByte(MSG_ENTITY, self.skin);
 748
 749         WriteByte(MSG_ENTITY, self.team);
 750
 751                 WriteByte(MSG_ENTITY, self.deadflag);
 752
 753         if(self.health <= 0)
 754             WriteByte(MSG_ENTITY, 0);
 755         else
 756             WriteByte(MSG_ENTITY, ceil((self.health / self.max_health) * 255));
 757     }
 758
 759         return TRUE;
 760 }
 761
 762 void monster_link(void() spawnproc)
 763 {
 764     Net_LinkEntity(self, TRUE, 0, monster_send);
 765     self.think      = spawnproc;
 766     self.nextthink  = time;
 767 }
 768
 769 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 770 {
 771         self.health -= damage;
 772
 773         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 774
 775         if(self.health <= -100) // 100 health until gone?
 776         {
 777                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 778
 779                 self.think = SUB_Remove;
 780                 self.nextthink = time + 0.1;
 781         }
 782 }
 783
 784 void monster_die()
 785 {
 786         self.think = monster_dead_think;
 787         self.nextthink = self.ticrate;
 788         self.ltime = time + 5;
 789
 790         monster_dropitem();
 791
 792         WaypointSprite_Kill(self.sprite);
 793
 794         if(self.weaponentity)
 795         {
 796                 remove(self.weaponentity);
 797                 self.weaponentity = world;
 798         }
 799
 800         monster_sound(self.msound_death, 0, FALSE);
 801
 802         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 803                 monsters_killed += 1;
 804
 805         if(self.candrop && self.weapon)
 806                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 807
 808         if(IS_CLIENT(self.realowner))
 809                 self.realowner.monstercount -= 1;
 810
 811         self.event_damage       = monsters_corpse_damage;
 812         self.solid                      = SOLID_CORPSE;
 813         self.takedamage         = DAMAGE_AIM;
 814         self.enemy                      = world;
 815         self.movetype           = MOVETYPE_TOSS;
 816         self.moveto                     = self.origin;
 817         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 818
 819         if not(self.flags & FL_FLY)
 820                 self.velocity = '0 0 0';
 821
 822         self.SendFlags |= MSF_MOVE;
 823
 824         // number of monsters spawned with mobspawn command
 825         totalspawned -= 1;
 826
 827         MON_ACTION(self.monsterid, MR_DEATH);
 828 }
 829
 830 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 831 {
 832         if(self.frozen && deathtype != DEATH_KILL)
 833                 return;
 834
 835         if(time < self.pain_finished && deathtype != DEATH_KILL)
 836                 return;
 837
 838         if(time < self.spawnshieldtime)
 839                 return;
 840
 841         if(deathtype != DEATH_KILL)
 842                 damage *= self.armorvalue;
 843
 844         if(self.weaponentity && self.weaponentity.classname == "shield")
 845                 self.weaponentity.health -= damage;
 846
 847         self.health -= damage;
 848
 849         if(self.sprite)
 850                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 851
 852         self.dmg_time = time;
 853
 854         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 855                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 856
 857         self.velocity += force * self.damageforcescale;
 858
 859         if(deathtype != DEATH_DROWN)
 860         {
 861                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 862                 if (damage > 50)
 863                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 864                 if (damage > 100)
 865                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 866         }
 867
 868         if(self.health <= 0)
 869         {
 870                 // Update one more time to avoid waypoint fading without emptying healthbar
 871                 if(self.sprite)
 872                         WaypointSprite_UpdateHealth(self.sprite, 0);
 873
 874                 if(deathtype == DEATH_KILL)
 875                         self.candrop = FALSE; // killed by mobkill command
 876
 877                 // TODO: fix this?
 878                 activator = attacker;
 879                 other = self.enemy;
 880                 SUB_UseTargets();
 881                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 882
 883                 monster_die();
 884
 885                 frag_attacker = attacker;
 886                 frag_target = self;
 887                 MUTATOR_CALLHOOK(MonsterDies);
 888
 889                 if(self.health <= -100) // check if we're already gibbed
 890                 {
 891                         Violence_GibSplash(self, 1, 0.5, attacker);
 892
 893                         self.think = SUB_Remove;
 894                         self.nextthink = time + 0.1;
 895                 }
 896         }
 897
 898         self.SendFlags |= MSF_STATUS;
 899 }
 900
 901 void monster_think()
 902 {
 903         self.think = monster_think;
 904         self.nextthink = self.ticrate;
 905
 906         MON_ACTION(self.monsterid, MR_THINK);
 907 }
 908
 909 void monster_spawn()
 910 {
 911         MON_ACTION(self.monsterid, MR_SETUP);
 912
 913         if not(self.monster_respawned)
 914                 Monster_CheckMinibossFlag();
 915
 916         self.max_health = self.health;
 917         self.pain_finished = self.nextthink;
 918         self.anim_start_time = time;
 919
 920         if not(self.noalign)
 921         {
 922                 setorigin(self, self.origin + '0 0 20');
 923                 tracebox(self.origin + '0 0 100', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 924                 setorigin(self, trace_endpos);
 925         }
 926
 927         if not(self.monster_respawned)
 928         if not(self.skin)
 929                 self.skin = rint(random() * 4);
 930
 931         if not(self.attack_range)
 932                 self.attack_range = autocvar_g_monsters_attack_range;
 933
 934         self.pos1 = self.origin;
 935
 936         monster_setupsounds(self.netname);
 937
 938         monster_precachesounds(self);
 939
 940         if(teamplay)
 941                 self.monster_attack = TRUE; // we can have monster enemies in team games
 942
 943         if(autocvar_g_monsters_healthbars)
 944         {
 945                 WaypointSprite_Spawn(strzone(strdecolorize(self.monster_name)), 0, 600, self, '0 0 1' * (self.maxs_z + 15), world, 0, self, sprite, FALSE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 946                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 947                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 948         }
 949
 950         monster_sound(self.msound_spawn, 0, FALSE);
 951
 952         MUTATOR_CALLHOOK(MonsterSpawn);
 953
 954         self.think = monster_think;
 955         self.nextthink = time + self.ticrate;
 956
 957         self.SendFlags |= MSF_SETUP;
 958 }
 959
 960 float monster_initialize(float mon_id, float nodrop)
 961 {
 962         if not(autocvar_g_monsters)
 963                 return FALSE;
 964
 965         vector min_s, max_s;
 966         entity mon = get_monsterinfo(mon_id);
 967
 968         // support for quake style removing monsters based on skill
 969         switch(monster_skill)
 970         {
 971                 case 1: if(self.spawnflags & MONSTERSKILL_NOTEASY)              return FALSE; break;
 972                 case 2: if(self.spawnflags & MONSTERSKILL_NOTMEDIUM)    return FALSE; break;
 973                 case 3: if(self.spawnflags & MONSTERSKILL_NOTHARD)              return FALSE; break;
 974                 case 4: if(self.spawnflags & MONSTERSKILL_NOTINSANE)    return FALSE; break;
 975                 case 5: if(self.spawnflags & MONSTERSKILL_NOTNIGHTMARE) return FALSE; break;
 976         }
 977
 978         if(self.monster_name == "")
 979                 self.monster_name = M_NAME(mon_id);
 980
 981         if(self.team && !teamplay)
 982                 self.team = 0;
 983
 984         self.flags = FL_MONSTER;
 985
 986         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
 987         if not(self.monster_respawned)
 988                 monsters_total += 1;
 989
 990         min_s = mon.mins;
 991         max_s = mon.maxs;
 992
 993         self.netname = mon.netname;
 994
 995         setsize(self, min_s, max_s);
 996         self.takedamage                 = DAMAGE_AIM;
 997         self.bot_attack                 = TRUE;
 998         self.iscreature                 = TRUE;
 999         self.teleportable               = TRUE;
1000         self.damagedbycontents  = TRUE;
1001         self.monsterid                  = mon_id;
1002         self.damageforcescale   = 0;
1003         self.event_damage               = monsters_damage;
1004         self.touch                              = MonsterTouch;
1005         self.use                                = monster_use;
1006         self.solid                              = SOLID_BBOX;
1007         self.movetype                   = MOVETYPE_WALK;
1008         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1009         monsters_spawned           += 1;
1010         self.enemy                              = world;
1011         self.velocity                   = '0 0 0';
1012         self.moveto                             = self.origin;
1013         self.pos2                               = self.angles;
1014         self.reset                              = monsters_reset;
1015         self.candrop                    = TRUE;
1016         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1017         self.oldtarget2                 = self.target2;
1018         self.deadflag                   = DEAD_NO;
1019         self.noalign                    = nodrop;
1020         self.spawn_time                 = time;
1021         self.gravity                    = 1;
1022         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1023
1024         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1025                 self.flags |= FL_SWIM;
1026
1027         if(mon.spawnflags & MONSTER_TYPE_FLY)
1028         {
1029                 self.flags |= FL_FLY;
1030                 self.movetype = MOVETYPE_FLY;
1031         }
1032
1033         if not(self.scale)
1034                 self.scale = 1;
1035
1036         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1037                 self.scale = 1.3;
1038
1039         if not(self.ticrate)
1040                 self.ticrate = autocvar_g_monsters_think_delay;
1041
1042         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1043
1044         if not(self.armorvalue)
1045                 self.armorvalue = 1; // multiplier
1046
1047         if not(self.target_range)
1048                 self.target_range = autocvar_g_monsters_target_range;
1049
1050         if not(self.respawntime)
1051                 self.respawntime = autocvar_g_monsters_respawn_delay;
1052
1053         if not(self.monster_moveflags)
1054                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1055
1056         monster_link(monster_spawn);
1057
1058         return TRUE;
1059 }