qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 136
 137 enum {
 138     MUTATOR_REMOVING,
 139     MUTATOR_ADDING,
 140     MUTATOR_ROLLING_BACK
 141 };
 142
 143 typedef bool(int) mutatorfunc_t;
 144
 145 CLASS(Mutator, Object)
 146     ATTRIB(Mutator, m_id, int, 0)
 147     ATTRIB(Mutator, m_name, string, string_null)
 148     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 149     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 150     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 151         CONSTRUCT(Mutator);
 152         this.m_name = _name;
 153         this.mutatorfunc = func;
 154     }
 155 ENDCLASS(Mutator)
 156
 157 REGISTRY(Mutators, BITS(6))
 158 Mutator loaded_mutators[Mutators_MAX];
 159
 160 bool Mutator_Add(Mutator mut)
 161 {
 162     int j = -1;
 163     for (int i = 0; i < Mutators_MAX; ++i) {
 164         if (loaded_mutators[i] == mut)
 165             return true; // already added
 166         if (!(loaded_mutators[i]))
 167             j = i;
 168     }
 169     if (j < 0) {
 170         backtrace("WARNING: too many mutators, cannot add any more\n");
 171         return false;
 172     }
 173     loaded_mutators[j] = mut;
 174     mutatorfunc_t func = mut.mutatorfunc;
 175     if (!func(MUTATOR_ADDING)) {
 176         // good
 177         return true;
 178     }
 179     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 180     if (func(MUTATOR_ROLLING_BACK)) {
 181         // baaaaad
 182         error("WARNING: when adding mutator: rolling back failed");
 183     }
 184     return false;
 185 }
 186
 187 void Mutator_Remove(Mutator mut)
 188 {
 189     int i;
 190     for (i = 0; i < Mutators_MAX; ++i)
 191         if (loaded_mutators[i] == mut)
 192             break;
 193     if (i >= Mutators_MAX) {
 194         backtrace("WARNING: removing not-added mutator\n");
 195         return;
 196     }
 197     loaded_mutators[i] = NULL;
 198     mutatorfunc_t func = mut.mutatorfunc;
 199     if (func(MUTATOR_REMOVING)) {
 200         // baaaaad
 201         error("Mutator_Remove: removing mutator failed");
 202     }
 203 }
 204
 205 #define REGISTER_MUTATOR(id, dependence) \
 206     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 207     bool MUTATORFUNCTION_##id(int mode) { \
 208         return = false; \
 209         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 210     } \
 211     bool MUTATOR_##id##_check() { return dependence; } \
 212     REGISTER(RegisterMutators, MUTATOR, Mutators, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 213     { this.mutatorcheck = MUTATOR_##id##_check; } \
 214     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 215
 216 STATIC_INIT(Mutators) {
 217     RegisterHooks();
 218     RegisterCallbacks();
 219     RegisterMutators();
 220 }
 221
 222 STATIC_INIT_LATE(Mutators) {
 223     FOREACH(Mutators, it.mutatorcheck(), LAMBDA(Mutator_Add(it)));
 224 }
 225
 226 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 227 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 228 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 229 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 230 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 231 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 232
 233 #define _MUTATOR_CALLBACK(name, func) \
 234     Callback CALLBACK_##name; \
 235     bool func(); \
 236     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 237
 238 #define MUTATOR_HOOKFUNCTION(...) \
 239     EVAL(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 240
 241 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 242     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 243
 244 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 245     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 246     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 247     bool mut##_##cb() { return = false; } \
 248     [[accumulate]] bool mut##_##cb()
 249
 250 #define MUTATOR_HOOK(cb, func, order) do {                              \
 251     MUTATOR_ONADD {                                                     \
 252         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 253             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 254             return true;                                                \
 255         }                                                               \
 256     }                                                                   \
 257     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 258         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 259     }                                                                   \
 260 } while (0)
 261
 262 #include "events.qh"
 263
 264 #endif