qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 #define PHYS_DODGING                                            g_dodging
   4 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   5 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   6 #define PHYS_DODGING_FROZEN_DOUBLETAP           autocvar_sv_dodging_frozen_doubletap
   7 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold // TODO not used - kill? (also below)
   8 #define PHYS_DODGING_HORIZ_SPEED                        autocvar_sv_dodging_horiz_speed
   9 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         autocvar_sv_dodging_horiz_speed_frozen
  10 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  11 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  12 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  13 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  14 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed
  15
  16 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  17 #if 0
  18 #define PHYS_DODGING                                            STAT(DODGING, this)
  19 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  20 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  21 #define PHYS_DODGING_FROZEN_DOUBLETAP           STAT(DODGING_FROZEN_DOUBLETAP, this)
  22 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  23 #define PHYS_DODGING_HORIZ_SPEED                        STAT(DODGING_HORIZ_SPEED, this)
  24 #define PHYS_DODGING_HORIZ_SPEED_FROZEN         STAT(DODGING_HORIZ_SPEED_FROZEN, this)
  25 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  26 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  27 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  28 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  29 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  30 #endif
  31
  32 #ifdef CSQC
  33         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  34         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  35         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  36 #elif defined(SVQC)
  37         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  38         #define PHYS_DODGING_TIMEOUT(s)                         CS(s).cvar_cl_dodging_timeout
  39         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  40 #endif
  41
  42 #ifdef SVQC
  43
  44 bool autocvar_sv_dodging_sound;
  45
  46 #include <common/animdecide.qh>
  47 #include <common/physics/player.qh>
  48
  49 .float cvar_cl_dodging_timeout;
  50
  51 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  52 {
  53         // this just turns on the cvar.
  54         MUTATOR_ONADD
  55         {
  56                 g_dodging = cvar("g_dodging");
  57         }
  58
  59         // this just turns off the cvar.
  60         MUTATOR_ONROLLBACK_OR_REMOVE
  61         {
  62                 g_dodging = 0;
  63         }
  64
  65         return false;
  66 }
  67
  68 #elif defined(CSQC)
  69 REGISTER_MUTATOR(dodging, true);
  70 #endif
  71
  72 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  73 .float dodging_action;
  74
  75 // the jump part of the dodge cannot be ramped
  76 .float dodging_single_action;
  77
  78
  79 // these are used to store the last key press time for each of the keys..
  80 .float last_FORWARD_KEY_time;
  81 .float last_BACKWARD_KEY_time;
  82 .float last_LEFT_KEY_time;
  83 .float last_RIGHT_KEY_time;
  84
  85 // these store the movement direction at the time of the dodge action happening.
  86 .vector dodging_direction;
  87
  88 // this indicates the last time a dodge was executed. used to check if another one is allowed
  89 // and to ramp up the dodge acceleration in the physics hook.
  90 .float last_dodging_time;
  91
  92 // This is the velocity gain to be added over the ramp time.
  93 // It will decrease from frame to frame during dodging_action = 1
  94 // until it's 0.
  95 .float dodging_velocity_gain;
  96
  97 #ifdef CSQC
  98 .int pressedkeys;
  99 #endif
 100
 101 // returns true if the player is close to a wall
 102 bool check_close_to_wall(entity this, float threshold)
 103 {
 104         if (PHYS_DODGING_WALL == 0) { return false; }
 105
 106 #define X(dir) \
 107         tracebox(this.origin, this.mins, this.maxs, this.origin + threshold * dir, true, this); \
 108         if (trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)) \
 109                 return true;
 110
 111         X(v_right);
 112         X(-v_right);
 113         X(v_forward);
 114         X(-v_forward);
 115 #undef X
 116
 117         return false;
 118 }
 119
 120 bool check_close_to_ground(entity this, float threshold)
 121 {
 122         return IS_ONGROUND(this) ? true : false;
 123 }
 124
 125 bool PM_dodging_checkpressedkeys(entity this)
 126 {
 127         // first check if the last dodge is far enough back in time so we can dodge again
 128         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 129                 return false;
 130
 131         makevectors(this.angles);
 132
 133         bool wall_dodge = false;
 134
 135         if(!PHYS_DODGING_AIR)
 136         if(!check_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD))
 137         {
 138                 wall_dodge = check_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD);
 139                 if(!wall_dodge) // we're not on the ground, and wall dodging isn't allowed, end it!
 140                         return true;
 141         }
 142
 143         if(!wall_dodge && PHYS_DODGING_MAXSPEED && vdist(this.velocity, >, PHYS_DODGING_MAXSPEED))
 144                 return false;
 145
 146         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 147         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_DOUBLETAP);
 148
 149         float tap_direction_x = 0;
 150         float tap_direction_y = 0;
 151         bool dodge_detected = false;
 152         vector mymovement = PHYS_CS(this).movement;
 153
 154         #define X(COND,BTN,RESULT)                                                                                                                      \
 155         if (mymovement_##COND)                                                                                          \
 156                 /* is this a state change? */                                                                                                   \
 157                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {             \
 158                                 tap_direction_##RESULT;                                                                                                 \
 159                                 if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap)    \
 160                                         dodge_detected = true;                                                                                          \
 161                                 if(PHYS_INPUT_BUTTON_DODGE(this))                                                                               \
 162                                         dodge_detected = true;                                                                                          \
 163                                 this.last_##BTN##_KEY_time = time;                                                                              \
 164                 }
 165         X(x < 0, BACKWARD,      x--);
 166         X(x > 0, FORWARD,       x++);
 167         X(y < 0, LEFT,          y--);
 168         X(y > 0, RIGHT,         y++);
 169         #undef X
 170
 171         if (dodge_detected)
 172         {
 173                 this.last_dodging_time = time;
 174
 175                 this.dodging_action = 1;
 176                 this.dodging_single_action = 1;
 177
 178                 this.dodging_velocity_gain = PHYS_DODGING_HORIZ_SPEED;
 179
 180                 this.dodging_direction_x = tap_direction_x;
 181                 this.dodging_direction_y = tap_direction_y;
 182
 183                 // normalize the dodging_direction vector.. (unlike UT99) XD
 184                 float length = this.dodging_direction_x * this.dodging_direction_x
 185                                         + this.dodging_direction_y * this.dodging_direction_y;
 186                 length = sqrt(length);
 187
 188                 this.dodging_direction_x = this.dodging_direction_x * 1.0 / length;
 189                 this.dodging_direction_y = this.dodging_direction_y * 1.0 / length;
 190                 return true;
 191         }
 192         return false;
 193 }
 194
 195 // TODO use real cvars
 196 /*float autocvar_velocity_min = 200;
 197 float autocvar_velocity_max = 700;
 198 float autocvar_force_min = 50;
 199 float autocvar_force_max = 350;*/
 200 float determine_speed(entity player) {
 201         float x = PHYS_FROZEN(player) ? PHYS_DODGING_HORIZ_SPEED_FROZEN : PHYS_DODGING_HORIZ_SPEED;
 202         x = x; // unused
 203         return x;
 204
 205         /*float horiz_vel = vlen(vec2(player.velocity));
 206         // force min and max are inverted - the faster you are the wekaer dodging becomes
 207         // TODO document cvars in cfg
 208         return map_bound_ranges(horiz_vel, autocvar_velocity_min, autocvar_velocity_max, autocvar_force_max, autocvar_force_min);*/
 209 }
 210
 211 void PM_dodging(entity this)
 212 {
 213         // when swimming or dead, no dodging allowed..
 214         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 215         {
 216                 this.dodging_action = 0;
 217                 this.dodging_direction_x = 0;
 218                 this.dodging_direction_y = 0;
 219                 return;
 220         }
 221
 222         // make sure v_up, v_right and v_forward are sane
 223         if(PHYS_DODGING_AIR)
 224                 makevectors(this.v_angle);
 225         else
 226                 makevectors(this.angles);
 227
 228         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 229         // will be called ramp_time/frametime times = 2 times. so, we need to
 230         // add 0.5 * the total speed each frame until the dodge action is done..
 231         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 232
 233         // if ramp time is smaller than frametime we get problems ;D
 234         common_factor = min(common_factor, 1);
 235
 236         float horiz_speed = determine_speed(this); // TODO kill this
 237         //OG_INFOF("velocity %f -> force %f\n", vlen(vec2(this.velocity)), horiz_speed);
 238         float new_velocity_gain = this.dodging_velocity_gain - (common_factor * horiz_speed);
 239         new_velocity_gain = max(0, new_velocity_gain);
 240
 241         float velocity_difference = this.dodging_velocity_gain - new_velocity_gain;
 242
 243         // ramp up dodging speed by adding some velocity each frame..
 244         if (this.dodging_action == 1)
 245         {
 246                 //disable jump key during dodge accel phase
 247                 if(PHYS_CS(this).movement.z > 0) { PHYS_CS(this).movement_z = 0; }
 248
 249                 this.velocity += ((this.dodging_direction_y * velocity_difference) * v_right)
 250                                         + ((this.dodging_direction_x * velocity_difference) * v_forward);
 251
 252                 this.dodging_velocity_gain = this.dodging_velocity_gain - velocity_difference;
 253         }
 254
 255         // the up part of the dodge is a single shot action
 256         if (this.dodging_single_action == 1)
 257         {
 258                 UNSET_ONGROUND(this);
 259
 260                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 261
 262 #ifdef SVQC
 263                 if (autocvar_sv_dodging_sound)
 264                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 265
 266                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 267 #endif
 268
 269                 this.dodging_single_action = 0;
 270         }
 271
 272         // are we done with the dodging ramp yet?
 273         if((this.dodging_action == 1) && ((time - this.last_dodging_time) > PHYS_DODGING_RAMP_TIME))
 274         {
 275                 // reset state so next dodge can be done correctly
 276                 this.dodging_action = 0;
 277                 this.dodging_direction_x = 0;
 278                 this.dodging_direction_y = 0;
 279         }
 280 }
 281
 282 void PM_dodging_GetPressedKeys(entity this)
 283 {
 284 #ifdef CSQC
 285         PM_dodging_checkpressedkeys(this);
 286
 287         int keys = this.pressedkeys;
 288         keys = BITSET(keys, KEY_FORWARD,        PHYS_CS(this).movement.x > 0);
 289         keys = BITSET(keys, KEY_BACKWARD,       PHYS_CS(this).movement.x < 0);
 290         keys = BITSET(keys, KEY_RIGHT,          PHYS_CS(this).movement.y > 0);
 291         keys = BITSET(keys, KEY_LEFT,           PHYS_CS(this).movement.y < 0);
 292
 293         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 294         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 295         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 296         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 297         this.pressedkeys = keys;
 298 #endif
 299 }
 300
 301 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 302 {
 303         entity player = M_ARGV(0, entity);
 304
 305         // print("dodging_PlayerPhysics\n");
 306         PM_dodging_GetPressedKeys(player);
 307         PM_dodging(player);
 308 }
 309
 310 #ifdef SVQC
 311
 312 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 313
 314 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 315 {
 316         entity player = M_ARGV(0, entity);
 317
 318         PM_dodging_checkpressedkeys(player);
 319 }
 320
 321 #endif