qcsrc/common/physics/movetypes/movetypes.qc

   1 #include "movetypes.qh"
   2
   3 #ifdef SVQC
   4 void set_movetype(entity this, int mt)
   5 {
   6         this.move_movetype = mt;
   7         if (mt == MOVETYPE_PHYSICS) {
   8                 this.move_qcphysics = false;
   9         } else if (autocvar_sv_qcphysics == 2) {
  10                 this.move_qcphysics = true;
  11         }
  12         if(!IL_CONTAINS(g_moveables, this))
  13                 IL_PUSH(g_moveables, this); // add it to the moveable entities list (even if it doesn't move!) logic: if an object never sets its movetype, we assume it never does anything notable
  14         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCENTITY : mt;
  15 }
  16 #elif defined(CSQC)
  17 void set_movetype(entity this, int mt)
  18 {
  19         this.move_movetype = mt;
  20 }
  21 #endif
  22
  23 bool _Movetype_NudgeOutOfSolid_PivotIsKnownGood(entity this, vector pivot) // SV_NudgeOutOfSolid_PivotIsKnownGood
  24 {
  25         vector stuckorigin = this.origin;
  26         vector goodmins = pivot, goodmaxs = pivot;
  27         for(int bump = 0; bump < 6; bump++)
  28         {
  29                 int coord = 2 - (bump >> 1);
  30                 int dir = (bump & 1);
  31
  32                 for(int subbump = 0; ; ++subbump)
  33                 {
  34                         vector testorigin = stuckorigin;
  35                         if(dir)
  36                         {
  37                                 // pushing maxs
  38                                 switch(coord)
  39                                 {
  40                                         case 0: testorigin.x += this.maxs_x - goodmaxs.x; break;
  41                                         case 1: testorigin.y += this.maxs_y - goodmaxs.y; break;
  42                                         case 2: testorigin.z += this.maxs_z - goodmaxs.z; break;
  43                                 }
  44                         }
  45                         else
  46                         {
  47                                 // pushing mins
  48                                 switch(coord)
  49                                 {
  50                                         case 0: testorigin.x += this.mins_x - goodmins.x; break;
  51                                         case 1: testorigin.y += this.mins_y - goodmins.y; break;
  52                                         case 2: testorigin.z += this.mins_z - goodmins.z; break;
  53                                 }
  54                         }
  55
  56                         tracebox(stuckorigin, goodmins, goodmaxs, testorigin, MOVE_NOMONSTERS, this);
  57                         if(trace_startsolid && trace_ent.solid == SOLID_BSP) // NOTE: this checks for bmodelstartsolid in the engine
  58                         {
  59                                 // BAD BAD, can't fix that
  60                                 return false;
  61                         }
  62
  63                         if(trace_fraction >= 1)
  64                                 break; // it WORKS!
  65
  66                         if(subbump >= 10)
  67                         {
  68                                 // BAD BAD, can't fix that
  69                                 return false;
  70                         }
  71
  72                         // we hit something... let's move out of it
  73                         vector move = trace_endpos - testorigin;
  74                         float nudge = (trace_plane_normal * move) + 0.03125; // FIXME cvar this constant
  75                         stuckorigin = stuckorigin + nudge * trace_plane_normal;
  76                 }
  77
  78                 if(dir)
  79                 {
  80                         // pushing maxs
  81                         switch(coord)
  82                         {
  83                                 case 0: goodmaxs.x = this.maxs_x; break;
  84                                 case 1: goodmaxs.y = this.maxs_y; break;
  85                                 case 2: goodmaxs.z = this.maxs_z; break;
  86                         }
  87                 }
  88                 else
  89                 {
  90                         // pushing mins
  91                         switch(coord)
  92                         {
  93                                 case 0: goodmins.x = this.mins_x; break;
  94                                 case 1: goodmins.y = this.mins_y; break;
  95                                 case 2: goodmins.z = this.mins_z; break;
  96                         }
  97                 }
  98         }
  99
 100         // WE WIN
 101         this.origin = stuckorigin;
 102
 103         return true;
 104 }
 105
 106 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
 107 {
 108         /*float d, i;
 109         vector into, side;
 110         makevectors(this.v_angle);
 111         d = (stepnormal * v_forward) + 0.5;
 112
 113         if(d < 0)
 114         {
 115             i = (stepnormal * this.velocity);
 116             into = i * stepnormal;
 117             side = this.velocity - into;
 118             this.velocity_x = side.x * (1 * d);
 119             this.velocity_y = side.y * (1 * d);
 120         }*/
 121 }
 122
 123 vector planes[MAX_CLIP_PLANES];
 124 int _Movetype_FlyMove(entity this, float dt, bool applygravity, bool applystepnormal, float stepheight) // SV_FlyMove
 125 {
 126         move_stepnormal = '0 0 0';
 127
 128         if(dt <= 0)
 129                 return 0;
 130
 131         int blockedflag = 0;
 132         int i, j, numplanes = 0;
 133         float time_left = dt, grav = 0;
 134         vector push;
 135         vector primal_velocity, original_velocity;
 136         vector restore_velocity = this.velocity;
 137
 138         for(i = 0; i < MAX_CLIP_PLANES; ++i)
 139                 planes[i] = '0 0 0';
 140
 141         if(applygravity)
 142         {
 143                 this.move_didgravity = 1;
 144                 grav = dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
 145
 146                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
 147                 {
 148                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 149                                 this.velocity_z -= grav * 0.5;
 150                         else
 151                                 this.velocity_z -= grav;
 152                 }
 153         }
 154
 155         original_velocity = primal_velocity = this.velocity;
 156
 157         for(int bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
 158         {
 159                 if(this.velocity == '0 0 0')
 160                         break;
 161
 162                 push = this.velocity * time_left;
 163                 if(!_Movetype_PushEntity(this, push, true, false))
 164                 {
 165                         // we got teleported by a touch function
 166                         // let's abort the move
 167                         blockedflag |= 8;
 168                         break;
 169                 }
 170
 171                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
 172                 // abort move if we're stuck in the world (and didn't make it out)
 173                 if(trace_startsolid && trace_allsolid)
 174                 {
 175                         this.velocity = restore_velocity;
 176                         return 3;
 177                 }
 178
 179                 if(trace_fraction == 1)
 180                         break;
 181
 182                 time_left *= 1 - trace_fraction;
 183
 184                 float my_trace_fraction = trace_fraction;
 185                 vector my_trace_plane_normal = trace_plane_normal;
 186
 187                 if(trace_plane_normal.z)
 188                 {
 189                         if(trace_plane_normal.z > 0.7)
 190                         {
 191                                 // floor
 192                                 blockedflag |= 1;
 193
 194                                 if(!trace_ent)
 195                                 {
 196                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
 197                                         trace_ent = NULL;
 198                                 }
 199
 200                                 SET_ONGROUND(this);
 201                                 this.groundentity = trace_ent;
 202                         }
 203                 }
 204                 else if(stepheight)
 205                 {
 206                         // step - handle it immediately
 207                         vector org = this.origin;
 208                         vector steppush = '0 0 1' * stepheight;
 209                         push = this.velocity * time_left;
 210
 211                         if(!_Movetype_PushEntity(this, steppush, true, false))
 212                         {
 213                                 blockedflag |= 8;
 214                                 break;
 215                         }
 216                         if(!_Movetype_PushEntity(this, push, true, false))
 217                         {
 218                                 blockedflag |= 8;
 219                                 break;
 220                         }
 221                         float trace2_fraction = trace_fraction;
 222                         steppush = vec3(0, 0, org.z - this.origin_z);
 223                         if(!_Movetype_PushEntity(this, steppush, true, false))
 224                         {
 225                                 blockedflag |= 8;
 226                                 break;
 227                         }
 228
 229                         // accept the new position if it made some progress...
 230                         // previously this checked if absolute distance >= 0.03125 which made stepping up unreliable
 231                         if(this.origin_x - org.x || this.origin_y - org.y)
 232                         {
 233                                 trace_endpos = this.origin;
 234                                 time_left *= 1 - trace2_fraction;
 235                                 numplanes = 0;
 236                                 continue;
 237                         }
 238                         else
 239                                 this.origin = org;
 240                 }
 241                 else
 242                 {
 243                         // step - return it to caller
 244                         blockedflag |= 2;
 245                         // save the trace for player extrafriction
 246                         if(applystepnormal)
 247                                 move_stepnormal = trace_plane_normal;
 248                 }
 249
 250                 if(my_trace_fraction >= 0.001)
 251                 {
 252                         // actually covered some distance
 253                         original_velocity = this.velocity;
 254                         numplanes = 0;
 255                 }
 256
 257                 // clipped to another plane
 258                 if(numplanes >= MAX_CLIP_PLANES)
 259                 {
 260                         // this shouldn't really happen
 261                         this.velocity = '0 0 0';
 262                         blockedflag = 3;
 263                         break;
 264                 }
 265
 266                 planes[numplanes] = my_trace_plane_normal;
 267                 numplanes++;
 268
 269                 // modify original_velocity so it parallels all of the clip planes
 270                 vector new_velocity = '0 0 0';
 271                 for (i = 0;i < numplanes;i++)
 272                 {
 273                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
 274                         for (j = 0;j < numplanes;j++)
 275                         {
 276                                 if(j != i)
 277                                 {
 278                                         // not ok
 279                                         if((new_velocity * planes[j]) < 0)
 280                                                 break;
 281                                 }
 282                         }
 283                         if(j == numplanes)
 284                                 break;
 285                 }
 286
 287                 if(i != numplanes)
 288                 {
 289                         // go along this plane
 290                         this.velocity = new_velocity;
 291                 }
 292                 else
 293                 {
 294                         // go along the crease
 295                         if(numplanes != 2)
 296                         {
 297                                 this.velocity = '0 0 0';
 298                                 blockedflag = 7;
 299                                 break;
 300                         }
 301                         vector dir = cross(planes[0], planes[1]);
 302                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
 303                         float ilength = sqrt((dir * dir));
 304                         if(ilength)
 305                                 ilength = 1.0 / ilength;
 306                         dir.x *= ilength;
 307                         dir.y *= ilength;
 308                         dir.z *= ilength;
 309                         float d = (dir * this.velocity);
 310                         this.velocity = dir * d;
 311                 }
 312
 313                 // if current velocity is against the original velocity,
 314                 // stop dead to avoid tiny occilations in sloping corners
 315                 if((this.velocity * primal_velocity) <= 0)
 316                 {
 317                         this.velocity = '0 0 0';
 318                         break;
 319                 }
 320         }
 321
 322         // LordHavoc: this came from QW and allows you to get out of water more easily
 323         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.flags & FL_WATERJUMP) && !(blockedflag & 8))
 324                 this.velocity = primal_velocity;
 325
 326         if(PHYS_WALLCLIP(this) && this.pm_time && !(this.flags & FL_WATERJUMP) && !(blockedflag & 8))
 327                 this.velocity = primal_velocity;
 328
 329         if(applygravity)
 330         {
 331                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !IS_ONGROUND(this))
 332                 {
 333                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 334                                 this.velocity_z -= grav * 0.5f;
 335                 }
 336         }
 337
 338         return blockedflag;
 339 }
 340
 341 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
 342 {
 343         // if(vlen(this.velocity) < 0.0001)
 344         // this.velocity = '0 0 0';
 345 }
 346
 347 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
 348 {
 349         vector point = this.origin;
 350         point.z += this.mins.z + 1;
 351
 352         int nativecontents = pointcontents(point);
 353         if(this.watertype && this.watertype != nativecontents)
 354         {
 355                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.watertype, nativecontents);
 356                 if(this.contentstransition)
 357                         this.contentstransition(this.watertype, nativecontents);
 358         }
 359
 360         this.waterlevel = WATERLEVEL_NONE;
 361         this.watertype = CONTENT_EMPTY;
 362
 363         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
 364         if(supercontents & DPCONTENTS_LIQUIDSMASK)
 365         {
 366                 this.watertype = nativecontents;
 367                 this.waterlevel = WATERLEVEL_WETFEET;
 368                 point.z = this.origin.z + (this.mins.z + this.maxs.z) * 0.5;
 369                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 370                 {
 371                         this.waterlevel = WATERLEVEL_SWIMMING;
 372                         point.z = this.origin.z + this.view_ofs.z;
 373                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
 374                                 this.waterlevel = WATERLEVEL_SUBMERGED;
 375                 }
 376         }
 377
 378         return this.waterlevel > 1;
 379 }
 380
 381 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
 382 {
 383         int contents = pointcontents(ent.origin);
 384
 385         if(!ent.watertype)
 386         {
 387                 // just spawned here
 388                 if(!GAMEPLAYFIX_WATERTRANSITION(ent))
 389                 {
 390                         ent.watertype = contents;
 391                         ent.waterlevel = 1;
 392                         return;
 393                 }
 394         }
 395         else if(ent.watertype != contents)
 396         {
 397                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.origin), pointcontents(ent.origin), ent.watertype, contents);
 398                 if(ent.contentstransition)
 399                         ent.contentstransition(ent.watertype, contents);
 400         }
 401
 402         if(contents <= CONTENT_WATER)
 403         {
 404                 ent.watertype = contents;
 405                 ent.waterlevel = 1;
 406         }
 407         else
 408         {
 409                 ent.watertype = CONTENT_EMPTY;
 410                 ent.waterlevel = (GAMEPLAYFIX_WATERTRANSITION(ent) ? 0 : contents);
 411         }
 412 }
 413
 414 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
 415 {
 416         if(!this && !oth)
 417                 return;
 418
 419         // due to a lack of pointers in QC, we must save the trace values and restore them for other functions
 420         bool save_trace_allsolid = trace_allsolid;
 421         bool save_trace_startsolid = trace_startsolid;
 422         float save_trace_fraction = trace_fraction;
 423         bool save_trace_inwater = trace_inwater;
 424         bool save_trace_inopen = trace_inopen;
 425         vector save_trace_endpos = trace_endpos;
 426         vector save_trace_plane_normal = trace_plane_normal;
 427         float save_trace_plane_dist = trace_plane_dist;
 428         entity save_trace_ent = trace_ent;
 429         int save_trace_dpstartcontents = trace_dpstartcontents;
 430         int save_trace_dphitcontents = trace_dphitcontents;
 431         int save_trace_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 432         string save_trace_dphittexturename = trace_dphittexturename;
 433
 434         if(this.solid != SOLID_NOT && gettouch(this))
 435                 gettouch(this)(this, oth);
 436
 437         if(oth.solid != SOLID_NOT && gettouch(oth))
 438                 gettouch(oth)(oth, this);
 439
 440         trace_allsolid = save_trace_allsolid;
 441         trace_startsolid = save_trace_startsolid;
 442         trace_fraction = save_trace_fraction;
 443         trace_inwater = save_trace_inwater;
 444         trace_inopen = save_trace_inopen;
 445         trace_endpos = save_trace_endpos;
 446         trace_plane_normal = save_trace_plane_normal;
 447         trace_plane_dist = save_trace_plane_dist;
 448         trace_ent = save_trace_ent;
 449         trace_dpstartcontents = save_trace_dpstartcontents;
 450         trace_dphitcontents = save_trace_dphitcontents;
 451         trace_dphitq3surfaceflags = save_trace_dphitq3surfaceflags;
 452         trace_dphittexturename = save_trace_dphittexturename;
 453 }
 454
 455 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
 456 {
 457         if(this.solid == SOLID_NOT)
 458                 return;
 459
 460         // due to a lack of pointers in QC, we must save the trace values and restore them for other functions
 461         bool save_trace_allsolid = trace_allsolid;
 462         bool save_trace_startsolid = trace_startsolid;
 463         float save_trace_fraction = trace_fraction;
 464         bool save_trace_inwater = trace_inwater;
 465         bool save_trace_inopen = trace_inopen;
 466         vector save_trace_endpos = trace_endpos;
 467         vector save_trace_plane_normal = trace_plane_normal;
 468         float save_trace_plane_dist = trace_plane_dist;
 469         entity save_trace_ent = trace_ent;
 470         int save_trace_dpstartcontents = trace_dpstartcontents;
 471         int save_trace_dphitcontents = trace_dphitcontents;
 472         int save_trace_dphitq3surfaceflags = trace_dphitq3surfaceflags;
 473         string save_trace_dphittexturename = trace_dphittexturename;
 474
 475     FOREACH_ENTITY_RADIUS_ORDERED(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
 476                 if (it.solid == SOLID_TRIGGER && it != this)
 477                 if (it.move_nomonsters != MOVE_NOMONSTERS && it.move_nomonsters != MOVE_WORLDONLY)
 478                 if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax))
 479                 {
 480                         trace_allsolid = false;
 481                         trace_startsolid = false;
 482                         trace_fraction = 1;
 483                         trace_inwater = false;
 484                         trace_inopen = true;
 485                         trace_endpos = it.origin;
 486                         trace_plane_normal = '0 0 1';
 487                         trace_plane_dist = 0;
 488                         trace_ent = this;
 489                         trace_dpstartcontents = 0;
 490                         trace_dphitcontents = 0;
 491                         trace_dphitq3surfaceflags = 0;
 492                         trace_dphittexturename = string_null;
 493
 494                         gettouch(it)(it, this);
 495                 }
 496     });
 497
 498         trace_allsolid = save_trace_allsolid;
 499         trace_startsolid = save_trace_startsolid;
 500         trace_fraction = save_trace_fraction;
 501         trace_inwater = save_trace_inwater;
 502         trace_inopen = save_trace_inopen;
 503         trace_endpos = save_trace_endpos;
 504         trace_plane_normal = save_trace_plane_normal;
 505         trace_plane_dist = save_trace_plane_dist;
 506         trace_ent = save_trace_ent;
 507         trace_dpstartcontents = save_trace_dpstartcontents;
 508         trace_dphitcontents = save_trace_dphitcontents;
 509         trace_dphitq3surfaceflags = save_trace_dphitq3surfaceflags;
 510         trace_dphittexturename = save_trace_dphittexturename;
 511 }
 512
 513 bool autocvar__movetype_debug = false;
 514 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
 515 {
 516         if(autocvar__movetype_debug)
 517         {
 518                 vector mi, ma;
 519                 if(this.solid == SOLID_BSP)
 520                 {
 521                         // TODO set the absolute bbox
 522                         mi = this.mins;
 523                         ma = this.maxs;
 524                 }
 525                 else
 526                 {
 527                         mi = this.mins;
 528                         ma = this.maxs;
 529                 }
 530                 mi += this.origin;
 531                 ma += this.origin;
 532
 533                 if(this.flags & FL_ITEM)
 534                 {
 535                         mi -= '15 15 1';
 536                         ma += '15 15 1';
 537                 }
 538                 else
 539                 {
 540                         mi -= '1 1 1';
 541                         ma += '1 1 1';
 542                 }
 543
 544                 this.absmin = mi;
 545                 this.absmax = ma;
 546         }
 547         else
 548         {
 549                 setorigin(this, this.origin); // calls SV_LinkEdict
 550         #ifdef CSQC
 551                 // NOTE: CSQC's version of setorigin doesn't expand
 552                 this.absmin -= '1 1 1';
 553                 this.absmax += '1 1 1';
 554         #endif
 555         }
 556
 557         if(touch_triggers)
 558                 _Movetype_LinkEdict_TouchAreaGrid(this);
 559 }
 560
 561 int _Movetype_ContentsMask(entity this)  // SV_GenericHitSuperContentsMask
 562 {
 563         if(this)
 564         {
 565                 if(this.dphitcontentsmask)
 566                         return this.dphitcontentsmask;
 567                 else if(this.solid == SOLID_SLIDEBOX)
 568                 {
 569                         if(this.flags & FL_MONSTER)
 570                                 return DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_MONSTERCLIP;
 571                         else
 572                                 return DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 573                 }
 574                 else if(this.solid == SOLID_CORPSE)
 575                         return DPCONTENTS_SOLID | DPCONTENTS_BODY;
 576                 else if(this.solid == SOLID_TRIGGER)
 577                         return DPCONTENTS_SOLID | DPCONTENTS_BODY;
 578                 else
 579                         return DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 580         }
 581         else
 582                 return DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 583 }
 584
 585 entity _Movetype_TestEntityPosition_ent;
 586 bool _Movetype_TestEntityPosition(vector ofs)  // SV_TestEntityPosition
 587 {
 588     entity this = _Movetype_TestEntityPosition_ent;
 589         vector org = this.origin + ofs;
 590
 591         //int cont = this.dphitcontentsmask;
 592         //this.dphitcontentsmask = DPCONTENTS_SOLID;
 593         tracebox(org, this.mins, this.maxs, this.origin, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
 594         //this.dphitcontentsmask = cont;
 595         if(trace_dpstartcontents & _Movetype_ContentsMask(this))
 596                 return true;
 597
 598         if(vlen2(trace_endpos - this.origin) >= 0.0001)
 599         {
 600                 tracebox(trace_endpos, this.mins, this.maxs, trace_endpos, MOVE_NOMONSTERS, this);
 601                 if(!trace_startsolid)
 602                         this.origin = trace_endpos;
 603         }
 604         return false;
 605 }
 606
 607 bool _Movetype_TestEntityPosition_Offset(int offset)
 608 {
 609         // NOTE: expects _Movetype_TestEntityPosition_ent to be set to the correct entity
 610         // returns true if stuck
 611
 612     // start at 2, since the first position has already been checked
 613     for(int j = 2; j <= offset; ++j)
 614     {
 615         if(!_Movetype_TestEntityPosition('0 0 -1' * j))
 616                 return false;
 617         if(!_Movetype_TestEntityPosition('0 0 1' * j))
 618                 return false;
 619     }
 620
 621         return true;
 622 }
 623
 624 int _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
 625 {
 626     _Movetype_TestEntityPosition_ent = this;
 627         if (!_Movetype_TestEntityPosition(' 0  0  0')) {
 628             return UNSTICK_FINE;
 629         }
 630         #define X(v) if (_Movetype_TestEntityPosition(v))
 631         X('0  0  -1') X(' 0  0  1')
 632         X('-1  0  0') X(' 1  0  0')
 633         X(' 0 -1  0') X(' 0  1  0')
 634         X('-1 -1  0') X(' 1 -1  0')
 635         X('-1  1  0') X(' 1  1  0')
 636         #undef X
 637         {
 638         if(_Movetype_TestEntityPosition_Offset(rint((this.maxs.z - this.mins.z) * 0.36)))
 639         {
 640             LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)",
 641                 etof(this), this.classname, vtos(this.origin));
 642             return UNSTICK_STUCK;
 643         }
 644         }
 645         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)",
 646                 etof(this), this.classname, vtos(this.origin));
 647         _Movetype_LinkEdict(this, false);
 648         return UNSTICK_FIXED;
 649 }
 650
 651 void _Movetype_CheckStuck(entity this)  // SV_CheckStuck
 652 {
 653         int unstick = _Movetype_UnstickEntity(this); // sets test position entity
 654         switch(unstick)
 655         {
 656                 case UNSTICK_FINE:
 657                         this.oldorigin = this.origin;
 658                         break;
 659                 case UNSTICK_FIXED:
 660                         break; // already sorted
 661                 case UNSTICK_STUCK:
 662                         vector offset = this.oldorigin - this.origin;
 663                         if(!_Movetype_TestEntityPosition(offset))
 664                                 _Movetype_LinkEdict(this, false);
 665                         // couldn't unstick, should we warn about this?
 666                         break;
 667         }
 668 }
 669
 670 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // ClipVelocity
 671 {
 672         vel -= ((vel * norm) * norm) * f;
 673
 674         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
 675         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
 676         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
 677
 678         return vel;
 679 }
 680
 681 void _Movetype_PushEntityTrace(entity this, vector push)
 682 {
 683         vector end = this.origin + push;
 684         int type;
 685         if(this.move_nomonsters)
 686                 type = max(0, this.move_nomonsters);
 687         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
 688                 type = MOVE_MISSILE;
 689         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
 690                 type = MOVE_WORLDONLY;
 691         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
 692                 type = MOVE_NOMONSTERS;
 693         else
 694                 type = MOVE_NORMAL;
 695
 696         tracebox(this.origin, this.mins, this.maxs, end, type, this);
 697 }
 698
 699 bool _Movetype_PushEntity(entity this, vector push, bool failonstartsolid, bool dolink)  // SV_PushEntity
 700 {
 701         _Movetype_PushEntityTrace(this, push);
 702
 703         // NOTE: this is a workaround for the QC's lack of a worldstartsolid trace parameter
 704         if(trace_startsolid && failonstartsolid)
 705         {
 706                 int oldtype = this.move_nomonsters;
 707                 this.move_nomonsters = MOVE_WORLDONLY;
 708                 _Movetype_PushEntityTrace(this, push);
 709                 this.move_nomonsters = oldtype;
 710                 if(trace_startsolid)
 711                         return true;
 712         }
 713
 714         this.origin = trace_endpos;
 715
 716         vector last_origin = this.origin;
 717
 718         _Movetype_LinkEdict(this, dolink);
 719
 720         if((this.solid >= SOLID_TRIGGER && trace_fraction < 1 && (!IS_ONGROUND(this) || this.groundentity != trace_ent)))
 721                 _Movetype_Impact(this, trace_ent);
 722
 723         return (this.origin == last_origin); // false if teleported by touch
 724 }
 725
 726 void _Movetype_Physics_Frame(entity this, float movedt)
 727 {
 728         this.move_didgravity = -1;
 729         switch (this.move_movetype)
 730         {
 731                 case MOVETYPE_PUSH:
 732                 case MOVETYPE_FAKEPUSH:
 733                         _Movetype_Physics_Push(this, movedt);
 734                         break;
 735                 case MOVETYPE_NONE:
 736                         break;
 737                 case MOVETYPE_FOLLOW:
 738                         _Movetype_Physics_Follow(this);
 739                         break;
 740                 case MOVETYPE_NOCLIP:
 741                         _Movetype_CheckWater(this);
 742                         this.origin = this.origin + movedt * this.velocity;
 743                         this.angles = this.angles + movedt * this.avelocity;
 744                         _Movetype_LinkEdict(this, false);
 745                         break;
 746                 case MOVETYPE_STEP:
 747                         _Movetype_Physics_Step(this, movedt);
 748                         break;
 749                 case MOVETYPE_WALK:
 750                         _Movetype_Physics_Walk(this, movedt);
 751                         break;
 752                 case MOVETYPE_TOSS:
 753                 case MOVETYPE_BOUNCE:
 754                 case MOVETYPE_BOUNCEMISSILE:
 755                 case MOVETYPE_FLYMISSILE:
 756                 case MOVETYPE_FLY:
 757                 case MOVETYPE_FLY_WORLDONLY:
 758                         _Movetype_Physics_Toss(this, movedt);
 759                         break;
 760                 case MOVETYPE_PHYSICS:
 761                         break;
 762         }
 763 }
 764
 765 void _Movetype_Physics_ClientFrame(entity this, float movedt)
 766 {
 767         this.move_didgravity = -1;
 768         switch (this.move_movetype)
 769         {
 770                 case MOVETYPE_PUSH:
 771                 case MOVETYPE_FAKEPUSH:
 772                         LOG_DEBUG("Physics: Lacking QuakeC support for Push movetype, FIX ME by using engine physics!");
 773                         break;
 774                 case MOVETYPE_NONE:
 775                         break;
 776                 case MOVETYPE_FOLLOW:
 777                         _Movetype_Physics_Follow(this);
 778                         break;
 779                 case MOVETYPE_NOCLIP:
 780                         _Movetype_CheckWater(this);
 781                         this.origin = this.origin + movedt * this.velocity;
 782                         this.angles = this.angles + movedt * this.avelocity;
 783                         break;
 784                 case MOVETYPE_STEP:
 785                         _Movetype_Physics_Step(this, movedt);
 786                         break;
 787                 case MOVETYPE_WALK:
 788                 case MOVETYPE_FLY:
 789                 case MOVETYPE_FLY_WORLDONLY:
 790                         _Movetype_Physics_Walk(this, movedt);
 791                         break;
 792                 case MOVETYPE_TOSS:
 793                 case MOVETYPE_BOUNCE:
 794                 case MOVETYPE_BOUNCEMISSILE:
 795                 case MOVETYPE_FLYMISSILE:
 796                         if (GAMEPLAYFIX_UNSTICKPLAYERS(this) == 2)
 797                                 _Movetype_CheckStuck(this);
 798                         _Movetype_Physics_Toss(this, movedt);
 799                         break;
 800                 case MOVETYPE_PHYSICS:
 801                         break;
 802         }
 803
 804         //_Movetype_CheckVelocity(this);
 805
 806         _Movetype_LinkEdict(this, true);
 807
 808         //_Movetype_CheckVelocity(this);
 809 }
 810
 811 void Movetype_Physics_NoMatchTicrate(entity this, float movedt, bool isclient)  // to be run every move frame
 812 {
 813         bool didmove = (this.move_time != 0);
 814         this.move_time = time;
 815
 816         if(isclient)
 817                 _Movetype_Physics_ClientFrame(this, movedt);
 818         else
 819         {
 820                 // this doesn't apply to clients, and only applies to unmatched entities
 821                 // don't run think/move on newly spawned projectiles as it messes up
 822                 // movement interpolation and rocket trails, and is inconsistent with
 823                 // respect to entities spawned in the same frame
 824                 // (if an ent spawns a higher numbered ent, it moves in the same frame,
 825                 //  but if it spawns a lower numbered ent, it doesn't - this never moves
 826                 //  ents in the first frame regardless)
 827                 if(!didmove && GAMEPLAYFIX_DELAYPROJECTILES(this) > 0)
 828                         return;
 829                 _Movetype_Physics_Frame(this, movedt);
 830         }
 831         if(wasfreed(this))
 832                 return;
 833
 834         setorigin(this, this.origin);
 835 }
 836
 837 void Movetype_Physics_NoMatchServer(entity this)  // optimized
 838 {
 839         float movedt = time - this.move_time;
 840         this.move_time = time;
 841
 842         _Movetype_Physics_Frame(this, movedt);
 843         if(wasfreed(this))
 844                 return;
 845
 846         setorigin(this, this.origin);
 847 }
 848
 849 void Movetype_Physics_MatchServer(entity this, bool sloppy)
 850 {
 851         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
 852 }
 853
 854 // saved .move_*
 855 .vector tic_origin;
 856 .vector tic_velocity;
 857 .int tic_flags;
 858 .vector tic_avelocity;
 859 .vector tic_angles;
 860
 861 // saved .*
 862 .vector tic_saved_origin;
 863 .vector tic_saved_velocity;
 864 .int tic_saved_flags;
 865 .vector tic_saved_avelocity;
 866 .vector tic_saved_angles;
 867 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
 868 {
 869         // this hack exists to contain the physics feature
 870         // (so entities can place themselves in the world and not need to update .tic_* themselves)
 871 #define X(s) \
 872         if(this.(s) != this.tic_saved_##s) \
 873                 this.tic_##s = this.(s)
 874
 875         X(origin);
 876         X(velocity);
 877         X(flags);
 878         X(avelocity);
 879         X(angles);
 880 #undef X
 881
 882         this.flags = this.tic_flags;
 883         this.velocity = this.tic_velocity;
 884         setorigin(this, this.tic_origin);
 885         this.avelocity = this.tic_avelocity;
 886         this.angles = this.tic_angles;
 887
 888         if(tr <= 0)
 889         {
 890                 Movetype_Physics_NoMatchServer(this);
 891
 892                 this.tic_saved_flags = this.tic_flags = this.flags;
 893                 this.tic_saved_velocity = this.tic_velocity = this.velocity;
 894                 this.tic_saved_origin = this.tic_origin = this.origin;
 895                 this.tic_saved_avelocity = this.tic_avelocity = this.avelocity;
 896                 this.tic_saved_angles = this.tic_angles = this.angles;
 897                 return;
 898         }
 899
 900         float dt = time - this.move_time;
 901
 902         int n = bound(0, floor(dt / tr), 32); // limit the number of frames to 32 (CL_MAX_USERCMDS, using DP_SMALLMEMORY value for consideration of QC's limitations)
 903         dt -= n * tr;
 904         this.move_time += n * tr;
 905
 906         if(!this.move_didgravity)
 907                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.tic_flags & FL_ONGROUND));
 908
 909         for (int j = 0; j < n; ++j)
 910         {
 911                 _Movetype_Physics_Frame(this, tr);
 912                 if(wasfreed(this))
 913                         return;
 914         }
 915
 916         // update the physics fields
 917         this.tic_origin = this.origin;
 918         this.tic_velocity = this.velocity;
 919         this.tic_avelocity = this.avelocity;
 920         this.tic_angles = this.angles;
 921         this.tic_flags = this.flags;
 922
 923         // restore their actual values
 924         this.flags = this.tic_saved_flags;
 925         this.velocity = this.tic_saved_velocity;
 926         setorigin(this, this.tic_saved_origin);
 927         //this.avelocity = this.tic_saved_avelocity;
 928         this.angles = this.tic_saved_angles;
 929
 930         this.avelocity = this.tic_avelocity;
 931
 932         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.tic_flags & FL_ONGROUND))
 933         {
 934                 // now continue the move from move_time to time
 935                 this.velocity = this.tic_velocity;
 936
 937                 if(this.move_didgravity > 0)
 938                 {
 939                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
 940                             * dt
 941                             * ((this.gravity) ? this.gravity : 1)
 942                             * PHYS_GRAVITY(this);
 943                 }
 944
 945                 this.angles = this.tic_angles + dt * this.avelocity;
 946
 947                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
 948                 {
 949                         setorigin(this, this.tic_origin + dt * this.velocity);
 950                 }
 951                 else
 952                 {
 953                         setorigin(this, this.tic_origin);
 954                         _Movetype_PushEntityTrace(this, dt * this.velocity);
 955                         if(!trace_startsolid)
 956                                 setorigin(this, trace_endpos);
 957                         else
 958                                 setorigin(this, this.tic_saved_origin);
 959                 }
 960
 961                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
 962                         this.velocity_z -= 0.5 * dt * ((this.gravity) ? this.gravity : 1) * PHYS_GRAVITY(this);
 963         }
 964         else
 965         {
 966                 this.velocity = this.tic_velocity;
 967                 this.angles = this.tic_angles;
 968                 setorigin(this, this.tic_origin);
 969         }
 970
 971         this.flags = this.tic_flags;
 972
 973         this.tic_saved_flags = this.flags;
 974         this.tic_saved_velocity = this.velocity;
 975         this.tic_saved_origin = this.origin;
 976         this.tic_saved_avelocity = this.avelocity;
 977         this.tic_saved_angles = this.angles;
 978 }