a68e3e3a08121a9493c041cb07d06f0702e0ed89
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / physics / movetypes / movetypes.qc
1 #include "../player.qh"
2
3 #if defined(CSQC)
4         #include <client/defs.qh>
5         #include <common/stats.qh>
6         #include <common/util.qh>
7         #include "movetypes.qh"
8         #include <lib/csqcmodel/common.qh>
9         #include <common/t_items.qh>
10 #elif defined(MENUQC)
11 #elif defined(SVQC)
12         #include <server/autocvars.qh>
13 #endif
14
15 void _Movetype_WallFriction(entity this, vector stepnormal)  // SV_WallFriction
16 {
17         /*float d, i;
18         vector into, side;
19         makevectors(this.v_angle);
20         d = (stepnormal * v_forward) + 0.5;
21
22         if(d < 0)
23         {
24             i = (stepnormal * this.move_velocity);
25             into = i * stepnormal;
26             side = this.move_velocity - into;
27             this.move_velocity_x = side.x * (1 * d);
28             this.move_velocity_y = side.y * (1 * d);
29         }*/
30 }
31
32 vector planes[MAX_CLIP_PLANES];
33 int _Movetype_FlyMove(entity this, float dt, bool applygravity, vector stepnormal, float stepheight) // SV_FlyMove
34 {
35         int blocked = 0, bumpcount;
36         int i, j, numplanes = 0;
37         float time_left = dt, grav = 0;
38         vector push;
39         vector primal_velocity, original_velocity, restore_velocity;
40
41         for(i = 0; i < MAX_CLIP_PLANES; ++i)
42                 planes[i] = '0 0 0';
43
44         if(applygravity)
45         {
46                 this.move_didgravity = 1;
47                 grav = dt * (PHYS_ENTGRAVITY(this) ? PHYS_ENTGRAVITY(this) : 1) * PHYS_GRAVITY(this);
48
49                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
50                 {
51                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
52                                 this.move_velocity_z -= grav * 0.5;
53                         else
54                                 this.move_velocity_z -= grav;
55                 }
56         }
57
58         original_velocity = primal_velocity = restore_velocity = this.move_velocity;
59
60         for(bumpcount = 0;bumpcount < MAX_CLIP_PLANES;bumpcount++)
61         {
62                 if(this.move_velocity == '0 0 0')
63                         break;
64
65                 push = this.move_velocity * time_left;
66                 _Movetype_PushEntity(this, push, true);
67                 if(trace_startsolid)
68                 {
69                         // we got teleported by a touch function
70                         // let's abort the move
71                         blocked |= 8;
72                         break;
73                 }
74
75                 // this code is used by MOVETYPE_WALK and MOVETYPE_STEP and SV_UnstickEntity
76                 // abort move if we're stuck in the world (and didn't make it out)
77                 if(trace_startsolid && trace_allsolid)
78                 {
79                         this.move_velocity = restore_velocity;
80                         return 3;
81                 }
82
83                 if(trace_fraction == 1)
84                         break;
85
86                 float my_trace_fraction = trace_fraction;
87                 vector my_trace_plane_normal = trace_plane_normal;
88
89                 if(trace_plane_normal.z)
90                 {
91                         if(trace_plane_normal.z > 0.7)
92                         {
93                                 // floor
94                                 blocked |= 1;
95
96                                 if(!trace_ent)
97                                 {
98                                         //dprint("_Movetype_FlyMove: !trace_ent\n");
99                                         trace_ent = NULL;
100                                 }
101
102                                 this.move_flags |= FL_ONGROUND;
103                                 this.move_groundentity = trace_ent;
104                         }
105                 }
106                 else if(stepheight)
107                 {
108                         // step - handle it immediately
109                         vector org = this.move_origin;
110                         vector steppush = '0 0 1' * stepheight;
111
112                         _Movetype_PushEntity(this, steppush, true);
113                         if(trace_startsolid)
114                         {
115                                 blocked |= 8;
116                                 break;
117                         }
118                         _Movetype_PushEntity(this, push, true);
119                         if(trace_startsolid)
120                         {
121                                 blocked |= 8;
122                                 break;
123                         }
124                         float trace2_fraction = trace_fraction;
125                         steppush = '0 0 1' * (org_z - this.move_origin_z);
126                         _Movetype_PushEntity(this, steppush, true);
127                         if(trace_startsolid)
128                         {
129                                 blocked |= 8;
130                                 break;
131                         }
132
133                         // accept the new position if it made some progress...
134                         if(fabs(this.move_origin_x - org_x) >= 0.03125 || fabs(this.move_origin_y - org_y) >= 0.03125)
135                         {
136                                 trace_endpos = this.move_origin;
137                                 time_left *= 1 - trace2_fraction;
138                                 numplanes = 0;
139                                 continue;
140                         }
141                         else
142                                 this.move_origin = org;
143                 }
144                 else
145                 {
146                         // step - return it to caller
147                         blocked |= 2;
148                         // save the trace for player extrafriction
149                         if(stepnormal)
150                                 stepnormal = trace_plane_normal;
151                 }
152
153                 if(my_trace_fraction >= 0.001)
154                 {
155                         // actually covered some distance
156                         original_velocity = this.move_velocity;
157                         numplanes = 0;
158                 }
159
160                 time_left *= 1 - my_trace_fraction;
161
162                 // clipped to another plane
163                 if(numplanes >= MAX_CLIP_PLANES)
164                 {
165                         // this shouldn't really happen
166                         this.move_velocity = '0 0 0';
167                         blocked = 3;
168                         break;
169                 }
170
171                 planes[numplanes] = my_trace_plane_normal;
172                 numplanes++;
173
174                 // modify original_velocity so it parallels all of the clip planes
175                 vector new_velocity = '0 0 0';
176                 for (i = 0;i < numplanes;i++)
177                 {
178                         new_velocity = _Movetype_ClipVelocity(original_velocity, planes[i], 1);
179                         for (j = 0;j < numplanes;j++)
180                         {
181                                 if(j != i)
182                                 {
183                                         // not ok
184                                         if((new_velocity * planes[j]) < 0)
185                                                 break;
186                                 }
187                         }
188                         if(j == numplanes)
189                                 break;
190                 }
191
192                 if(i != numplanes)
193                 {
194                         // go along this plane
195                         this.move_velocity = new_velocity;
196                 }
197                 else
198                 {
199                         // go along the crease
200                         if(numplanes != 2)
201                         {
202                                 this.move_velocity = '0 0 0';
203                                 blocked = 7;
204                                 break;
205                         }
206                         vector dir = cross(planes[0], planes[1]);
207                         // LordHavoc: thanks to taniwha of QuakeForge for pointing out this fix for slowed falling in corners
208                         float ilength = sqrt((dir * dir));
209                         if(ilength)
210                                 ilength = 1.0 / ilength;
211                         dir.x *= ilength;
212                         dir.y *= ilength;
213                         dir.z *= ilength;
214                         float d = (dir * this.move_velocity);
215                         this.move_velocity = dir * d;
216                 }
217
218                 // if current velocity is against the original velocity,
219                 // stop dead to avoid tiny occilations in sloping corners
220                 if((this.move_velocity * primal_velocity) <= 0)
221                 {
222                         this.move_velocity = '0 0 0';
223                         break;
224                 }
225         }
226
227         // LordHavoc: this came from QW and allows you to get out of water more easily
228         if(GAMEPLAYFIX_EASIERWATERJUMP(this) && (this.move_flags & FL_WATERJUMP) && !(blocked & 8))
229                 this.move_velocity = primal_velocity;
230
231         if(applygravity)
232         {
233                 if(!GAMEPLAYFIX_NOGRAVITYONGROUND || !(this.move_flags & FL_ONGROUND))
234                 {
235                         if(GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
236                                 this.move_velocity_z -= grav * 0.5f;
237                 }
238         }
239
240         return blocked;
241 }
242
243 void _Movetype_CheckVelocity(entity this)  // SV_CheckVelocity
244 {
245         // if(vlen(this.move_velocity) < 0.0001)
246         // this.move_velocity = '0 0 0';
247 }
248
249 bool _Movetype_CheckWater(entity this)  // SV_CheckWater
250 {
251         vector point = this.move_origin;
252         point.z += this.mins.z + 1;
253
254         int nativecontents = pointcontents(point);
255         if(this.move_watertype && this.move_watertype != nativecontents)
256         {
257                 // dprintf("_Movetype_CheckWater(): Original: '%d', New: '%d'\n", this.move_watertype, nativecontents);
258                 if(this.contentstransition)
259                         this.contentstransition(this.move_watertype, nativecontents);
260         }
261
262         this.move_waterlevel = WATERLEVEL_NONE;
263         this.move_watertype = CONTENT_EMPTY;
264
265         int supercontents = Mod_Q1BSP_SuperContentsFromNativeContents(nativecontents);
266         if(supercontents & DPCONTENTS_LIQUIDSMASK)
267         {
268                 this.move_watertype = nativecontents;
269                 this.move_waterlevel = WATERLEVEL_WETFEET;
270                 point.z = this.move_origin.z + (this.mins.z + this.maxs.z) * 0.5;
271                 if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
272                 {
273                         this.move_waterlevel = WATERLEVEL_SWIMMING;
274                         point.z = this.move_origin.z + this.view_ofs.z;
275                         if(Mod_Q1BSP_SuperContentsFromNativeContents(pointcontents(point)) & DPCONTENTS_LIQUIDSMASK)
276                                 this.move_waterlevel = WATERLEVEL_SUBMERGED;
277                 }
278         }
279
280         return this.move_waterlevel > 1;
281 }
282
283 void _Movetype_CheckWaterTransition(entity ent)  // SV_CheckWaterTransition
284 {
285         int contents = pointcontents(ent.move_origin);
286
287         if(!ent.move_watertype)
288         {
289                 // just spawned here
290                 if(!autocvar_cl_gameplayfix_fixedcheckwatertransition)
291                 {
292                         ent.move_watertype = contents;
293                         ent.move_waterlevel = 1;
294                         return;
295                 }
296         }
297         else if(ent.move_watertype != contents)
298         {
299                 // dprintf("_Movetype_CheckWaterTransition(): Origin: %s, Direct: '%d', Original: '%d', New: '%d'\n", vtos(ent.move_origin), pointcontents(ent.move_origin), ent.move_watertype, contents);
300                 if(ent.contentstransition)
301                         ent.contentstransition(ent.move_watertype, contents);
302         }
303
304         if(contents <= CONTENT_WATER)
305         {
306                 ent.move_watertype = contents;
307                 ent.move_waterlevel = 1;
308         }
309         else
310         {
311                 ent.move_watertype = CONTENT_EMPTY;
312                 ent.move_waterlevel = (autocvar_cl_gameplayfix_fixedcheckwatertransition ? 0 : contents);
313         }
314 }
315
316 void _Movetype_Impact(entity this, entity oth)  // SV_Impact
317 {
318         entity oldother = other;
319
320         if(gettouch(this))
321         {
322                 other = oth;
323
324                 gettouch(this)(this);
325
326                 other = oldother;
327         }
328
329         if(gettouch(oth))
330         {
331                 other = this;
332
333                 gettouch(oth)(oth);
334
335                 other = oldother;
336         }
337 }
338
339 void _Movetype_LinkEdict_TouchAreaGrid(entity this)  // SV_LinkEdict_TouchAreaGrid
340 {
341         if(this.solid == SOLID_NOT)
342                 return;
343
344         entity oldother = other;
345
346     FOREACH_ENTITY_RADIUS(0.5 * (this.absmin + this.absmax), 0.5 * vlen(this.absmax - this.absmin), true, {
347                 if (it.solid == SOLID_TRIGGER && it != this)
348                 if (it.move_nomonsters != MOVE_NOMONSTERS && it.move_nomonsters != MOVE_WORLDONLY)
349                 if (gettouch(it) && boxesoverlap(it.absmin, it.absmax, this.absmin, this.absmax))
350                 {
351                         other = this;
352
353                         trace_allsolid = false;
354                         trace_startsolid = false;
355                         trace_fraction = 1;
356                         trace_inwater = false;
357                         trace_inopen = true;
358                         trace_endpos = it.move_origin;
359                         trace_plane_normal = '0 0 1';
360                         trace_plane_dist = 0;
361                         trace_ent = this;
362
363                         gettouch(it)(it);
364                 }
365     });
366
367         other = oldother;
368 }
369
370 void _Movetype_LinkEdict(entity this, bool touch_triggers)  // SV_LinkEdict
371 {
372         vector mi, ma;
373         if(this.solid == SOLID_BSP)
374         {
375                 // TODO set the absolute bbox
376                 mi = this.mins;
377                 ma = this.maxs;
378         }
379         else
380         {
381                 mi = this.mins;
382                 ma = this.maxs;
383         }
384         mi += this.move_origin;
385         ma += this.move_origin;
386
387         if(this.move_flags & FL_ITEM)
388         {
389                 mi.x -= 15;
390                 mi.y -= 15;
391                 mi.z -= 1;
392                 ma.x += 15;
393                 ma.y += 15;
394                 ma.z += 1;
395         }
396         else
397         {
398                 mi.x -= 1;
399                 mi.y -= 1;
400                 mi.z -= 1;
401                 ma.x += 1;
402                 ma.y += 1;
403                 ma.z += 1;
404         }
405
406         this.absmin = mi;
407         this.absmax = ma;
408
409         if(touch_triggers)
410                 _Movetype_LinkEdict_TouchAreaGrid(this);
411 }
412
413 entity _Movetype_TestEntityPosition_ent;
414 bool _Movetype_TestEntityPosition(vector ofs)  // SV_TestEntityPosition
415 {
416     entity this = _Movetype_TestEntityPosition_ent;
417 //      vector org = this.move_origin + ofs;
418
419         int cont = this.dphitcontentsmask;
420         this.dphitcontentsmask = DPCONTENTS_SOLID;
421         tracebox(this.move_origin, this.mins, this.maxs, this.move_origin, ((this.move_movetype == MOVETYPE_FLY_WORLDONLY) ? MOVE_WORLDONLY : MOVE_NOMONSTERS), this);
422         this.dphitcontentsmask = cont;
423
424         if(trace_startsolid)
425                 return true;
426
427         if(vdist(trace_endpos - this.move_origin, >, 0.0001))
428                 this.move_origin = trace_endpos;
429         return false;
430 }
431
432 bool _Movetype_UnstickEntity(entity this)  // SV_UnstickEntity
433 {
434     _Movetype_TestEntityPosition_ent = this;
435         if (!_Movetype_TestEntityPosition(' 0  0  0')) {
436             return true;
437         }
438         #define X(v) if (_Movetype_TestEntityPosition(v))
439         X('-1  0  0') X(' 1  0  0')
440         X(' 0 -1  0') X(' 0  1  0')
441         X('-1 -1  0') X(' 1 -1  0')
442         X('-1  1  0') X(' 1  1  0')
443         #undef X
444         {
445         #define X(i) \
446             if (_Movetype_TestEntityPosition('0 0 -1' * i)) \
447             if (_Movetype_TestEntityPosition('0 0 1' * i))
448         X(01) X(02) X(03) X(04) X(05) X(06) X(07) X(08)
449         X(09) X(10) X(11) X(12) X(13) X(14) X(15) X(16)
450         X(17)
451         #undef X
452         {
453             LOG_DEBUGF("Can't unstick an entity (edict: %d, classname: %s, origin: %s)\n",
454                 etof(this), this.classname, vtos(this.move_origin));
455             return false;
456         }
457         }
458         LOG_DEBUGF("Sucessfully unstuck an entity (edict: %d, classname: %s, origin: %s)\n",
459                 etof(this), this.classname, vtos(this.move_origin));
460         _Movetype_LinkEdict(this, true);
461         return true;
462 }
463
464 vector _Movetype_ClipVelocity(vector vel, vector norm, float f)  // SV_ClipVelocity
465 {
466         vel -= ((vel * norm) * norm) * f;
467
468         if(vel.x > -0.1 && vel.x < 0.1) vel.x = 0;
469         if(vel.y > -0.1 && vel.y < 0.1) vel.y = 0;
470         if(vel.z > -0.1 && vel.z < 0.1) vel.z = 0;
471
472         return vel;
473 }
474
475 void _Movetype_PushEntityTrace(entity this, vector push)
476 {
477         vector end = this.move_origin + push;
478         int type;
479         if(this.move_nomonsters)
480                 type = max(0, this.move_nomonsters);
481         else if(this.move_movetype == MOVETYPE_FLYMISSILE)
482                 type = MOVE_MISSILE;
483         else if(this.move_movetype == MOVETYPE_FLY_WORLDONLY)
484                 type = MOVE_WORLDONLY;
485         else if(this.solid == SOLID_TRIGGER || this.solid == SOLID_NOT)
486                 type = MOVE_NOMONSTERS;
487         else
488                 type = MOVE_NORMAL;
489
490         tracebox(this.move_origin, this.mins, this.maxs, end, type, this);
491 }
492
493 float _Movetype_PushEntity(entity this, vector push, bool failonstartsolid)  // SV_PushEntity
494 {
495         _Movetype_PushEntityTrace(this, push);
496
497         if(trace_startsolid && failonstartsolid)
498                 return trace_fraction;
499
500         this.move_origin = trace_endpos;
501
502         if(trace_fraction < 1)
503                 if(this.solid >= SOLID_TRIGGER && (!(this.move_flags & FL_ONGROUND) || (this.move_groundentity != trace_ent)))
504                         _Movetype_Impact(this, trace_ent);
505
506         return trace_fraction;
507 }
508
509
510 .float ltime;
511 .void() blocked;
512 // matrix version of makevectors, sets v_forward, v_right and v_up
513 void makevectors_matrix(vector myangles)  // AngleVectorsFLU
514 {
515         v_forward = v_right = v_up = '0 0 0';
516
517         float y = myangles.y * (M_PI * 2 / 360);
518         float sy = sin(y);
519         float cy = cos(y);
520         float p = myangles.x * (M_PI * 2 / 360);
521         float sp = sin(p);
522         float cp = cos(p);
523         if(v_forward)
524         {
525                 v_forward.x = cp * cy;
526                 v_forward.y = cp * sy;
527                 v_forward.z = -sp;
528         }
529         if(v_right || v_up)
530         {
531                 if(myangles.z)
532                 {
533                         float r = myangles.z * (M_PI * 2 / 360);
534                         float sr = sin(r);
535                         float cr = cos(r);
536                         if(v_right)
537                         {
538                                 v_right.x = sr * sp * cy + cr * -sy;
539                                 v_right.y = sr * sp * sy + cr * cy;
540                                 v_right.z = sr * cp;
541                         }
542                         if(v_up)
543                         {
544                                 v_up.x = cr * sp * cy + -sr * -sy;
545                                 v_up.y = cr * sp * sy + -sr * cy;
546                                 v_up.z = cr * cp;
547                         }
548                 }
549                 else
550                 {
551                         if(v_right)
552                         {
553                                 v_right.x = -sy;
554                                 v_right.y = cy;
555                                 v_right.z = 0;
556                         }
557                         if(v_up)
558                         {
559                                 v_up.x = sp * cy;
560                                 v_up.y = sp * sy;
561                                 v_up.z = cp;
562                         }
563                 }
564         }
565 }
566
567 void _Movetype_Physics_Frame(entity this, float movedt)
568 {
569         this.move_didgravity = -1;
570         switch (this.move_movetype)
571         {
572                 case MOVETYPE_PUSH:
573                 case MOVETYPE_FAKEPUSH:
574                         _Movetype_Physics_Pusher(this, movedt);
575                         break;
576                 case MOVETYPE_NONE:
577                         break;
578                 case MOVETYPE_FOLLOW:
579                         _Movetype_Physics_Follow(this);
580                         break;
581                 case MOVETYPE_NOCLIP:
582                         _Movetype_CheckWater(this);
583                         this.move_origin = this.move_origin + TICRATE * this.move_velocity;
584                         this.move_angles = this.move_angles + TICRATE * this.move_avelocity;
585                         _Movetype_LinkEdict(this, false);
586                         break;
587                 case MOVETYPE_STEP:
588                         _Movetype_Physics_Step(this, movedt);
589                         break;
590                 case MOVETYPE_WALK:
591                         _Movetype_Physics_Walk(this, movedt);
592                         break;
593                 case MOVETYPE_TOSS:
594                 case MOVETYPE_BOUNCE:
595                 case MOVETYPE_BOUNCEMISSILE:
596                 case MOVETYPE_FLYMISSILE:
597                 case MOVETYPE_FLY:
598                 case MOVETYPE_FLY_WORLDONLY:
599                         _Movetype_Physics_Toss(this, movedt);
600                         _Movetype_LinkEdict(this, true);
601                         break;
602                 case MOVETYPE_PHYSICS:
603                         break;
604         }
605 }
606
607 void _Movetype_Physics_ClientFrame(entity this, float movedt)
608 {
609         this.move_didgravity = -1;
610         switch (this.move_movetype)
611         {
612                 case MOVETYPE_PUSH:
613                 case MOVETYPE_FAKEPUSH:
614                         _Movetype_Physics_Pusher(this, movedt);
615                         break;
616                 case MOVETYPE_NONE:
617                         break;
618                 case MOVETYPE_FOLLOW:
619                         _Movetype_Physics_Follow(this);
620                         break;
621                 case MOVETYPE_NOCLIP:
622                         _Movetype_CheckWater(this);
623                         this.move_origin = this.move_origin + movedt * this.move_velocity;
624                         this.move_angles = this.move_angles + movedt * this.move_avelocity;
625                         _Movetype_LinkEdict(this, false);
626                         break;
627                 case MOVETYPE_STEP:
628                         _Movetype_Physics_Step(this, movedt);
629                         break;
630                 case MOVETYPE_WALK:
631                 case MOVETYPE_FLY:
632                 case MOVETYPE_FLY_WORLDONLY:
633                         _Movetype_Physics_Walk(this, movedt);
634                         break;
635                 case MOVETYPE_TOSS:
636                 case MOVETYPE_BOUNCE:
637                 case MOVETYPE_BOUNCEMISSILE:
638                 case MOVETYPE_FLYMISSILE:
639                         _Movetype_Physics_Toss(this, movedt);
640                         break;
641                 case MOVETYPE_PHYSICS:
642                         break;
643         }
644 }
645
646 void Movetype_Physics_NoMatchServer(entity this)  // optimized
647 {
648         float movedt = time - this.move_time;
649         this.move_time = time;
650
651         _Movetype_Physics_Frame(this, movedt);
652         if(wasfreed(this))
653                 return;
654
655         this.avelocity = this.move_avelocity;
656         this.velocity = this.move_velocity;
657         this.angles = this.move_angles;
658         setorigin(this, this.move_origin);
659 }
660
661 void Movetype_Physics_MatchServer(entity this, bool sloppy)
662 {
663         Movetype_Physics_MatchTicrate(this, TICRATE, sloppy);
664 }
665
666 void Movetype_Physics_MatchTicrate(entity this, float tr, bool sloppy)  // SV_Physics_Entity
667 {
668         if(tr <= 0)
669         {
670                 Movetype_Physics_NoMatchServer(this);
671                 return;
672         }
673
674         float dt = time - this.move_time;
675
676         int n = max(0, floor(dt / tr));
677         dt -= n * tr;
678         this.move_time += n * tr;
679
680         if(!this.move_didgravity)
681                 this.move_didgravity = ((this.move_movetype == MOVETYPE_BOUNCE || this.move_movetype == MOVETYPE_TOSS) && !(this.move_flags & FL_ONGROUND));
682
683         for (int i = 0; i < n; ++i)
684         {
685                 _Movetype_Physics_Frame(this, tr);
686                 if(wasfreed(this))
687                         return;
688         }
689
690         this.avelocity = this.move_avelocity;
691
692         if(dt > 0 && this.move_movetype != MOVETYPE_NONE && !(this.move_flags & FL_ONGROUND))
693         {
694                 // now continue the move from move_time to time
695                 this.velocity = this.move_velocity;
696
697                 if(this.move_didgravity > 0)
698                 {
699                         this.velocity_z -= (GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE ? 0.5 : 1)
700                             * dt
701                             * (this.gravity ? this.gravity : 1)
702                             * PHYS_GRAVITY(this);
703                 }
704
705                 this.angles = this.move_angles + dt * this.avelocity;
706
707                 if(sloppy || this.move_movetype == MOVETYPE_NOCLIP)
708                 {
709                         setorigin(this, this.move_origin + dt * this.velocity);
710                 }
711                 else
712                 {
713                         _Movetype_PushEntityTrace(this, dt * this.velocity);
714                         if(!trace_startsolid)
715                                 setorigin(this, trace_endpos);
716                 }
717
718                 if(this.move_didgravity > 0 && GAMEPLAYFIX_GRAVITYUNAFFECTEDBYTICRATE)
719                         this.velocity_z -= 0.5 * dt * (this.gravity ? this.gravity : 1) * PHYS_GRAVITY(this);
720         }
721         else
722         {
723                 this.velocity = this.move_velocity;
724                 this.angles = this.move_angles;
725                 setorigin(this, this.move_origin);
726         }
727 }