4fc2e38219c144e2a5801129419847e2444c4808
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / t_items.qc
1 #include "t_items.qh"
2
3 #include "items/_mod.qh"
4
5 #if defined(SVQC)
6
7     #include "../server/bot/api.qh"
8
9     #include <server/mutators/_mod.qh>
10
11     #include "../server/weapons/common.qh"
12     #include "../server/weapons/selection.qh"
13     #include "../server/weapons/weaponsystem.qh"
14
15     #include "constants.qh"
16     #include <common/deathtypes/all.qh>
17     #include <common/notifications/all.qh>
18         #include "triggers/subs.qh"
19     #include "util.qh"
20
21     #include <common/monsters/_mod.qh>
22
23     #include <common/weapons/_all.qh>
24
25     #include <common/mutators/mutator/buffs/buffs.qh>
26
27     #include "../lib/warpzone/util_server.qh"
28 #elif defined(CSQC)
29         #include "physics/movetypes/movetypes.qh"
30         #include <common/weapons/_all.qh>
31         #include "../lib/csqcmodel/cl_model.qh"
32         #include "../lib/csqcmodel/common.qh"
33 #endif
34
35 REGISTER_NET_LINKED(ENT_CLIENT_ITEM)
36
37 #ifdef CSQC
38 bool autocvar_cl_ghost_items_vehicle = true;
39 .vector item_glowmod;
40 void Item_SetAlpha(entity this)
41 {
42         bool veh_hud = (hud && autocvar_cl_ghost_items_vehicle);
43
44         if(!veh_hud && (this.ItemStatus & ITS_AVAILABLE))
45         {
46                 this.alpha = 1;
47                 this.colormod = '1 1 1';
48                 this.glowmod = this.item_glowmod;
49         }
50         else
51         {
52                 if (autocvar_cl_ghost_items_color)
53                 {
54                         this.alpha = autocvar_cl_ghost_items;
55                         this.colormod = this.glowmod = autocvar_cl_ghost_items_color;
56                 }
57                 else
58                         this.alpha = -1;
59         }
60
61         if((!veh_hud) && (this.ItemStatus & ITS_STAYWEP))
62         {
63                 this.colormod = this.glowmod = autocvar_cl_weapon_stay_color;
64                 this.alpha = autocvar_cl_weapon_stay_alpha;
65         }
66
67         this.drawmask = ((this.alpha <= 0) ? 0 : MASK_NORMAL);
68 }
69
70 void ItemDraw(entity this)
71 {
72     if(this.gravity)
73     {
74         Movetype_Physics_MatchServer(this, false);
75         if(IS_ONGROUND(this))
76         { // For some reason avelocity gets set to '0 0 0' here ...
77             this.oldorigin = this.origin;
78             this.gravity = 0;
79
80             if(autocvar_cl_animate_items)
81             { // ... so reset it if animations are requested.
82                 if(this.ItemStatus & ITS_ANIMATE1)
83                     this.avelocity = '0 180 0';
84
85                 if(this.ItemStatus & ITS_ANIMATE2)
86                     this.avelocity = '0 -90 0';
87             }
88
89             // delay is for blocking item's position for a while;
90             // it's a workaround for dropped weapons that receive the position
91             // another time right after they spawn overriding animation position
92             this.onground_time = time + 0.5;
93         }
94     }
95     else if (autocvar_cl_animate_items)
96     {
97         if(this.ItemStatus & ITS_ANIMATE1)
98         {
99             this.angles += this.avelocity * frametime;
100             float fade_in = bound(0, time - this.onground_time, 1);
101             setorigin(this, this.oldorigin + fade_in * ('0 0 10' + '0 0 8' * sin((time - this.onground_time) * 2)));
102         }
103
104         if(this.ItemStatus & ITS_ANIMATE2)
105         {
106             this.angles += this.avelocity * frametime;
107             float fade_in = bound(0, time - this.onground_time, 1);
108             setorigin(this, this.oldorigin + fade_in * ('0 0 8' + '0 0 4' * sin((time - this.onground_time) * 3)));
109         }
110     }
111
112     Item_SetAlpha(this);
113 }
114
115 void ItemDrawSimple(entity this)
116 {
117     if(this.gravity)
118     {
119         Movetype_Physics_MatchServer(this, false);
120
121         if(IS_ONGROUND(this))
122             this.gravity = 0;
123     }
124
125     Item_SetAlpha(this);
126 }
127
128 void Item_PreDraw(entity this)
129 {
130         if(warpzone_warpzones_exist)
131         {
132                 setpredraw(this, func_null); // no need to keep running this
133                 return;
134         }
135         float alph;
136         vector org = getpropertyvec(VF_ORIGIN);
137         //if(!checkpvs(org, this)) // this makes sense as long as we don't support recursive warpzones
138                 //alph = 0; // this shouldn't be needed, since items behind walls are culled anyway
139         if(this.fade_start)
140         {
141                 if(vdist(org - this.origin, >, this.fade_end))
142                         alph = 0; // save on some processing
143                 else if(vdist(org - this.origin, <, this.fade_start))
144                         alph = 1; // more processing saved
145                 else
146                         alph = bound(0, (this.fade_end - vlen(org - this.origin - 0.5 * (this.mins + this.maxs))) / (this.fade_end - this.fade_start), 1);
147         }
148         else
149                 alph = 1;
150         //printf("%v <-> %v\n", view_origin, this.origin + 0.5 * (this.mins + this.maxs));
151         if(!hud && (this.ItemStatus & ITS_AVAILABLE))
152                 this.alpha = alph;
153         if(alph <= 0)
154                 this.drawmask = 0;
155         //else
156                 //this.drawmask = MASK_NORMAL; // reset by the setalpha function
157 }
158
159 void ItemRemove(entity this)
160 {
161         if(this.mdl)
162                 strunzone(this.mdl);
163 }
164
165 NET_HANDLE(ENT_CLIENT_ITEM, bool isnew)
166 {
167     int sf = ReadByte();
168
169     if(sf & ISF_LOCATION)
170     {
171         this.origin_x = ReadCoord();
172         this.origin_y = ReadCoord();
173         this.origin_z = ReadCoord();
174         setorigin(this, this.origin);
175         this.oldorigin = this.origin;
176     }
177
178     if(sf & ISF_ANGLES)
179     {
180         this.angles_x = ReadAngle();
181         this.angles_y = ReadAngle();
182         this.angles_z = ReadAngle();
183     }
184
185     if(sf & ISF_SIZE)
186     {
187         float use_bigsize = ReadByte();
188         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
189     }
190
191     if(sf & ISF_STATUS) // need to read/write status first so model can handle simple, fb etc.
192     {
193         this.ItemStatus = ReadByte();
194
195         Item_SetAlpha(this);
196
197         if(autocvar_cl_fullbright_items)
198             if(this.ItemStatus & ITS_ALLOWFB)
199                 this.effects |= EF_FULLBRIGHT;
200
201         if(this.ItemStatus & ITS_GLOW)
202         {
203             if(this.ItemStatus & ITS_AVAILABLE)
204                 this.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
205             else
206                  this.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
207         }
208     }
209
210     if(sf & ISF_MODEL)
211     {
212         this.drawmask  = MASK_NORMAL;
213                 set_movetype(this, MOVETYPE_TOSS);
214                 if (isnew) IL_PUSH(g_drawables, this);
215         this.draw       = ItemDraw;
216         this.solid = SOLID_TRIGGER;
217         //this.flags |= FL_ITEM;
218
219         bool use_bigsize = ReadByte();
220
221         this.fade_end = ReadShort();
222         this.fade_start = ReadShort();
223         if(!warpzone_warpzones_exist && this.fade_start && !autocvar_cl_items_nofade)
224                 setpredraw(this, Item_PreDraw);
225
226         if(this.mdl)
227             strunzone(this.mdl);
228
229         this.mdl = "";
230         string _fn = ReadString();
231
232         if(autocvar_cl_simple_items && (this.ItemStatus & ITS_ALLOWSI))
233         {
234             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
235             this.draw = ItemDrawSimple;
236
237             if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3")))
238                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".md3"));
239             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm")))
240                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".dpm"));
241             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm")))
242                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".iqm"));
243             else if(fexists(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl")))
244                 this.mdl = strzone(strcat(_fn2, autocvar_cl_simpleitems_postfix, ".mdl"));
245             else
246             {
247                 this.draw = ItemDraw;
248                 LOG_TRACE("Simple item requested for ", _fn, " but no model exists for it");
249             }
250         }
251
252         if(this.draw != ItemDrawSimple)
253             this.mdl = strzone(_fn);
254
255
256         if(this.mdl == "")
257             LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, ", tell tZork about this!");
258
259         precache_model(this.mdl);
260         _setmodel(this, this.mdl);
261
262         setsize(this, '-16 -16 0', (use_bigsize) ? '16 16 48' : '16 16 32');
263     }
264
265     if(sf & ISF_COLORMAP)
266     {
267         this.colormap = ReadShort();
268         this.item_glowmod_x = ReadByte() / 255.0;
269         this.item_glowmod_y = ReadByte() / 255.0;
270         this.item_glowmod_z = ReadByte() / 255.0;
271     }
272
273     if(sf & ISF_DROP)
274     {
275         this.gravity = 1;
276         this.pushable = true;
277         //this.angles = '0 0 0';
278         set_movetype(this, MOVETYPE_TOSS);
279         this.velocity_x = ReadCoord();
280         this.velocity_y = ReadCoord();
281         this.velocity_z = ReadCoord();
282         setorigin(this, this.oldorigin);
283
284         if(!this.move_time)
285         {
286             this.move_time = time;
287             this.spawntime = time;
288         }
289         else
290             this.move_time = max(this.move_time, time);
291     }
292
293     if(autocvar_cl_animate_items)
294     {
295         if(this.ItemStatus & ITS_ANIMATE1)
296             this.avelocity = '0 180 0';
297
298         if(this.ItemStatus & ITS_ANIMATE2)
299             this.avelocity = '0 -90 0';
300     }
301
302     this.entremove = ItemRemove;
303
304     return true;
305 }
306
307 #endif
308
309 #ifdef SVQC
310 bool ItemSend(entity this, entity to, int sf)
311 {
312         if(this.gravity)
313                 sf |= ISF_DROP;
314         else
315                 sf &= ~ISF_DROP;
316
317         WriteHeader(MSG_ENTITY, ENT_CLIENT_ITEM);
318         WriteByte(MSG_ENTITY, sf);
319
320         //WriteByte(MSG_ENTITY, this.cnt);
321         if(sf & ISF_LOCATION)
322         {
323                 WriteCoord(MSG_ENTITY, this.origin.x);
324                 WriteCoord(MSG_ENTITY, this.origin.y);
325                 WriteCoord(MSG_ENTITY, this.origin.z);
326         }
327
328         if(sf & ISF_ANGLES)
329         {
330                 WriteAngle(MSG_ENTITY, this.angles_x);
331                 WriteAngle(MSG_ENTITY, this.angles_y);
332                 WriteAngle(MSG_ENTITY, this.angles_z);
333         }
334
335         if(sf & ISF_SIZE)
336         {
337                 Pickup p = this.itemdef;
338                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
339         }
340
341         if(sf & ISF_STATUS)
342                 WriteByte(MSG_ENTITY, this.ItemStatus);
343
344         if(sf & ISF_MODEL)
345         {
346                 Pickup p = this.itemdef;
347                 WriteByte(MSG_ENTITY, p.instanceOfPowerup || p.instanceOfHealth || p.instanceOfArmor);
348                 WriteShort(MSG_ENTITY, this.fade_end);
349                 WriteShort(MSG_ENTITY, this.fade_start);
350
351                 if(this.mdl == "")
352                         LOG_TRACE("^1WARNING!^7 this.mdl is unset for item ", this.classname, "expect a crash just about now");
353
354                 WriteString(MSG_ENTITY, this.mdl);
355         }
356
357
358         if(sf & ISF_COLORMAP)
359         {
360                 WriteShort(MSG_ENTITY, this.colormap);
361                 WriteByte(MSG_ENTITY, this.glowmod.x * 255.0);
362         WriteByte(MSG_ENTITY, this.glowmod.y * 255.0);
363         WriteByte(MSG_ENTITY, this.glowmod.z * 255.0);
364         }
365
366         if(sf & ISF_DROP)
367         {
368                 WriteCoord(MSG_ENTITY, this.velocity.x);
369                 WriteCoord(MSG_ENTITY, this.velocity.y);
370                 WriteCoord(MSG_ENTITY, this.velocity.z);
371         }
372
373         return true;
374 }
375
376 void ItemUpdate(entity this)
377 {
378         this.oldorigin = this.origin;
379         this.SendFlags |= ISF_LOCATION;
380 }
381
382 void UpdateItemAfterTeleport(entity this)
383 {
384         if(getSendEntity(this) == ItemSend)
385                 ItemUpdate(this);
386 }
387
388 bool have_pickup_item(entity this)
389 {
390         if(this.itemdef.instanceOfPowerup)
391         {
392                 if(autocvar_g_powerups > 0)
393                         return true;
394                 if(autocvar_g_powerups == 0)
395                         return false;
396         }
397         else
398         {
399                 if(autocvar_g_pickup_items > 0)
400                         return true;
401                 if(autocvar_g_pickup_items == 0)
402                         return false;
403                 if(g_weaponarena)
404                         if(this.weapons || this.itemdef.instanceOfAmmo) // no item or ammo pickups in weaponarena
405                                 return false;
406         }
407         return true;
408 }
409
410 /*
411 float Item_Customize()
412 {
413         if(this.spawnshieldtime)
414                 return true;
415         if(this.weapons & ~other.weapons)
416         {
417                 this.colormod = '0 0 0';
418                 this.glowmod = this.colormod;
419                 this.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
420                 return true;
421         }
422         else
423         {
424                 if(g_ghost_items)
425                 {
426                         this.colormod = stov(autocvar_g_ghost_items_color);
427                         this.glowmod = this.colormod;
428                         this.alpha = g_ghost_items;
429                         return true;
430                 }
431                 else
432                         return false;
433         }
434 }
435 */
436
437 void Item_Show (entity e, float mode)
438 {
439         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
440         e.ItemStatus &= ~ITS_STAYWEP;
441         entity def = e.itemdef;
442         if (mode > 0)
443         {
444                 // make the item look normal, and be touchable
445                 e.model = e.mdl;
446                 e.solid = SOLID_TRIGGER;
447                 e.spawnshieldtime = 1;
448                 e.ItemStatus |= ITS_AVAILABLE;
449         }
450         else if (mode < 0)
451         {
452                 // hide the item completely
453                 e.model = string_null;
454                 e.solid = SOLID_NOT;
455                 e.spawnshieldtime = 1;
456                 e.ItemStatus &= ~ITS_AVAILABLE;
457         }
458         else
459         {
460                 bool nostay = def.instanceOfWeaponPickup ? !!(def.m_weapon.weapons & WEPSET_SUPERWEAPONS) : false // no weapon-stay on superweapons
461                         || e.team // weapon stay isn't supported for teamed weapons
462                         ;
463                 if(def.instanceOfWeaponPickup && !nostay && g_weapon_stay)
464                 {
465                         // make the item translucent and not touchable
466                         e.model = e.mdl;
467                         e.solid = SOLID_TRIGGER; // can STILL be picked up!
468                         e.effects |= EF_STARDUST;
469                         e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
470                         e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
471                 }
472                 else
473                 {
474                         //setmodel(e, "null");
475                         e.solid = SOLID_NOT;
476                         e.colormod = '0 0 0';
477                         //e.glowmod = e.colormod;
478                         e.spawnshieldtime = 1;
479                         e.ItemStatus &= ~ITS_AVAILABLE;
480                 }
481         }
482
483         if (def.m_glow)
484                 e.ItemStatus |= ITS_GLOW;
485
486         if (autocvar_g_nodepthtestitems)
487                 e.effects |= EF_NODEPTHTEST;
488
489
490         if (autocvar_g_fullbrightitems)
491                 e.ItemStatus |= ITS_ALLOWFB;
492
493         if (autocvar_sv_simple_items)
494                 e.ItemStatus |= ITS_ALLOWSI;
495
496         // relink entity (because solid may have changed)
497         setorigin(e, e.origin);
498         e.SendFlags |= ISF_STATUS;
499 }
500
501 void Item_Think(entity this)
502 {
503         this.nextthink = time;
504         if(this.origin != this.oldorigin)
505                 ItemUpdate(this);
506 }
507
508 bool Item_ItemsTime_SpectatorOnly(GameItem it);
509 bool Item_ItemsTime_Allow(GameItem it);
510 float Item_ItemsTime_UpdateTime(entity e, float t);
511 void Item_ItemsTime_SetTime(entity e, float t);
512 void Item_ItemsTime_SetTimesForAllPlayers();
513
514 void Item_Respawn (entity this)
515 {
516         Item_Show(this, 1);
517         sound(this, CH_TRIGGER, this.itemdef.m_respawnsound, VOL_BASE, ATTEN_NORM);     // play respawn sound
518         setorigin(this, this.origin);
519
520     if (Item_ItemsTime_Allow(this.itemdef) || (this.weapons & WEPSET_SUPERWEAPONS))
521         {
522                 float t = Item_ItemsTime_UpdateTime(this, 0);
523                 Item_ItemsTime_SetTime(this, t);
524                 Item_ItemsTime_SetTimesForAllPlayers();
525         }
526
527         setthink(this, Item_Think);
528         this.nextthink = time;
529
530         //Send_Effect(EFFECT_ITEM_RESPAWN, this.origin + this.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
531         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
532 }
533
534 void Item_RespawnCountdown (entity this)
535 {
536         if(this.count >= ITEM_RESPAWN_TICKS)
537         {
538                 if(this.waypointsprite_attached)
539                         WaypointSprite_Kill(this.waypointsprite_attached);
540                 Item_Respawn(this);
541         }
542         else
543         {
544                 this.nextthink = time + 1;
545                 this.count += 1;
546                 if(this.count == 1)
547                 {
548                         do {
549                                 {
550                                         entity wi = Weapons_from(this.weapon);
551                                         if (wi != WEP_Null) {
552                                                 entity wp = WaypointSprite_Spawn(WP_Weapon, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Weapon);
553                                                 wp.wp_extra = wi.m_id;
554                                                 break;
555                                         }
556                                 }
557                                 {
558                                         entity ii = this.itemdef;
559                                         if (ii != NULL) {
560                                                 entity wp = WaypointSprite_Spawn(WP_Item, 0, 0, this, '0 0 64', NULL, 0, this, waypointsprite_attached, true, RADARICON_Item);
561                                                 wp.wp_extra = ii.m_id;
562                                                 break;
563                                         }
564                                 }
565                         } while (0);
566                         bool mutator_returnvalue = MUTATOR_CALLHOOK(Item_RespawnCountdown, this);
567             if(this.waypointsprite_attached)
568             {
569                 GameItem def = this.itemdef;
570                 if (Item_ItemsTime_SpectatorOnly(def) && !mutator_returnvalue)
571                     WaypointSprite_UpdateRule(this.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
572                 WaypointSprite_UpdateBuildFinished(this.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
573             }
574                 }
575
576                 if(this.waypointsprite_attached)
577                 {
578                         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
579                                 if(this.waypointsprite_attached.waypointsprite_visible_for_player(this.waypointsprite_attached, it, it))
580                                 {
581                                         msg_entity = it;
582                                         soundto(MSG_ONE, this, CH_TRIGGER, SND(ITEMRESPAWNCOUNTDOWN), VOL_BASE, ATTEN_NORM);    // play respawn sound
583                                 }
584                         });
585
586                         WaypointSprite_Ping(this.waypointsprite_attached);
587                         //WaypointSprite_UpdateHealth(this.waypointsprite_attached, this.count);
588                 }
589         }
590 }
591
592 void Item_RespawnThink(entity this)
593 {
594         this.nextthink = time;
595         if(this.origin != this.oldorigin)
596                 ItemUpdate(this);
597
598         if(time >= this.wait)
599                 Item_Respawn(this);
600 }
601
602 void Item_ScheduleRespawnIn(entity e, float t)
603 {
604         // if the respawn time is longer than 10 seconds, show a waypoint, otherwise, just respawn normally
605         if ((Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS) || MUTATOR_CALLHOOK(Item_ScheduleRespawn, e, t)) && (t - ITEM_RESPAWN_TICKS) > 0)
606         {
607                 setthink(e, Item_RespawnCountdown);
608                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
609                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
610                 e.count = 0;
611                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
612                 {
613                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
614                         Item_ItemsTime_SetTime(e, t);
615                         Item_ItemsTime_SetTimesForAllPlayers();
616                 }
617         }
618         else
619         {
620                 setthink(e, Item_RespawnThink);
621                 e.nextthink = time;
622                 e.scheduledrespawntime = time + t;
623                 e.wait = time + t;
624
625                 if(Item_ItemsTime_Allow(e.itemdef) || (e.weapons & WEPSET_SUPERWEAPONS))
626                 {
627                         t = Item_ItemsTime_UpdateTime(e, e.scheduledrespawntime);
628                         Item_ItemsTime_SetTime(e, t);
629                         Item_ItemsTime_SetTimesForAllPlayers();
630                 }
631         }
632 }
633
634 AUTOCVAR(g_pickup_respawntime_scaling_reciprocal, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `reciprocal` (with `offset` and `linear` set to 0) can be used to achieve a constant number of items spawned *per player*");
635 AUTOCVAR(g_pickup_respawntime_scaling_offset, float, 0.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `offset` offsets the curve left or right - the results are not intuitive and I recommend plotting the respawn time and the number of items per player to see what's happening");
636 AUTOCVAR(g_pickup_respawntime_scaling_linear, float, 1.0, "Multiply respawn time by `reciprocal / (p + offset) + linear` where `p` is the current number of players, takes effect with 2 or more players present, `linear` can be used to simply scale the respawn time linearly");
637
638 float adjust_respawntime(float normal_respawntime) {
639         float r = autocvar_g_pickup_respawntime_scaling_reciprocal;
640         float o = autocvar_g_pickup_respawntime_scaling_offset;
641         float l = autocvar_g_pickup_respawntime_scaling_linear;
642
643         if (r == 0 && l == 1) {
644                 return normal_respawntime;
645         }
646
647         CheckAllowedTeams(NULL);
648         GetTeamCounts(NULL);
649         int players = 0;
650         if (c1 != -1) players += c1;
651         if (c2 != -1) players += c2;
652         if (c3 != -1) players += c3;
653         if (c4 != -1) players += c4;
654
655         if (players >= 2) {
656                 return normal_respawntime * (r / (players + o) + l);
657         } else {
658                 return normal_respawntime;
659         }
660 }
661
662 void Item_ScheduleRespawn(entity e)
663 {
664         if(e.respawntime > 0)
665         {
666                 Item_Show(e, 0);
667
668                 float adjusted_respawntime = adjust_respawntime(e.respawntime);
669                 //LOG_INFOF("item %s will respawn in %f", e.classname, adjusted_respawntime);
670
671                 // range: adjusted_respawntime - respawntimejitter .. adjusted_respawntime + respawntimejitter
672                 float actual_time = adjusted_respawntime + crandom() * e.respawntimejitter;
673                 Item_ScheduleRespawnIn(e, actual_time);
674         }
675         else // if respawntime is -1, this item does not respawn
676                 Item_Show(e, -1);
677 }
678
679 void Item_ScheduleInitialRespawn(entity e)
680 {
681         Item_Show(e, 0);
682         Item_ScheduleRespawnIn(e, max(0, game_starttime - time) + ((e.respawntimestart) ? e.respawntimestart : ITEM_RESPAWNTIME_INITIAL(e)));
683 }
684
685 float Item_GiveAmmoTo(entity item, entity player, int resource_type, float ammomax)
686 {
687         float amount = GetResourceAmount(item, resource_type);
688         if (amount == 0)
689         {
690                 return false;
691         }
692         float player_amount = GetResourceAmount(player, resource_type);
693         if (item.spawnshieldtime)
694         {
695                 if ((player_amount >= ammomax) && (item.pickup_anyway <= 0))
696                 {
697                         return false;
698                 }
699                 GiveResourceWithLimit(player, resource_type, amount, ammomax);
700                 return true;
701         }
702         if (g_weapon_stay != 2)
703         {
704                 return false;
705         }
706         GiveResourceWithLimit(player, resource_type, amount, min(amount, ammomax));
707         return true;
708 }
709
710 float Item_GiveTo(entity item, entity player)
711 {
712         float pickedup;
713
714         // if nothing happens to player, just return without taking the item
715         pickedup = false;
716         int _switchweapon = 0;
717         // in case the player has autoswitch enabled do the following:
718         // if the player is using their best weapon before items are given, they
719         // probably want to switch to an even better weapon after items are given
720
721         if(CS(player).autoswitch)
722         {
723                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
724                 {
725                         .entity weaponentity = weaponentities[slot];
726                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
727                         {
728                                 if(player.(weaponentity).m_switchweapon == w_getbestweapon(player, weaponentity))
729                                         _switchweapon |= BIT(slot);
730
731                                 if(!(player.weapons & WepSet_FromWeapon(player.(weaponentity).m_switchweapon)))
732                                         _switchweapon |= BIT(slot);
733                         }
734                 }
735         }
736         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_HEALTH, item.max_health);
737         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ARMOR, item.max_armorvalue);
738         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_SHELLS, g_pickup_shells_max);
739         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_BULLETS, g_pickup_nails_max);
740         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_ROCKETS, g_pickup_rockets_max);
741         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_CELLS, g_pickup_cells_max);
742         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_PLASMA, g_pickup_plasma_max);
743         pickedup |= Item_GiveAmmoTo(item, player, RESOURCE_FUEL, g_pickup_fuel_max);
744         if (item.itemdef.instanceOfWeaponPickup)
745         {
746                 WepSet w;
747                 w = item.weapons;
748                 w &= ~player.weapons;
749
750                 if (w || (item.spawnshieldtime && item.pickup_anyway > 0))
751                 {
752                         pickedup = true;
753                         FOREACH(Weapons, it != WEP_Null, {
754                                 if(w & (it.m_wepset))
755                                 {
756                                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757                                         {
758                                                 .entity weaponentity = weaponentities[slot];
759                                                 if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
760                                                         W_DropEvent(wr_pickup, player, it.m_id, item, weaponentity);
761                                         }
762                                         W_GiveWeapon(player, it.m_id);
763                                 }
764                         });
765                 }
766         }
767
768         if (item.itemdef.instanceOfPowerup)
769         {
770                 if ((item.itemdef == ITEM_JetpackRegen) && !(player.items & IT_FUEL_REGEN))
771                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_FUELREGEN_GOT);
772                 else if ((item.itemdef == ITEM_Jetpack) && !(player.items & IT_JETPACK))
773                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_ITEM_JETPACK_GOT);
774         }
775
776         int its;
777         if((its = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
778         {
779                 pickedup = true;
780                 player.items |= its;
781                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
782         }
783
784         if (item.strength_finished)
785         {
786                 pickedup = true;
787                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
788         }
789         if (item.invincible_finished)
790         {
791                 pickedup = true;
792                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
793         }
794         if (item.superweapons_finished)
795         {
796                 pickedup = true;
797                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
798         }
799
800 LABEL(skip)
801
802         // always eat teamed entities
803         if(item.team)
804                 pickedup = true;
805
806         if (!pickedup)
807                 return 0;
808
809         // crude hack to enforce switching weapons
810         if(g_cts && item.itemdef.instanceOfWeaponPickup)
811         {
812                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
813                 {
814                         .entity weaponentity = weaponentities[slot];
815                         if(player.(weaponentity).m_weapon != WEP_Null || slot == 0)
816                                 W_SwitchWeapon_Force(player, Weapons_from(item.weapon), weaponentity);
817                 }
818                 return 1;
819         }
820
821         if(_switchweapon)
822         {
823                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
824                 {
825                         .entity weaponentity = weaponentities[slot];
826                         if(_switchweapon & BIT(slot))
827                         if(player.(weaponentity).m_switchweapon != w_getbestweapon(player, weaponentity))
828                                 W_SwitchWeapon_Force(player, w_getbestweapon(player, weaponentity), weaponentity);
829                 }
830         }
831
832         return 1;
833 }
834
835 void Item_Touch(entity this, entity toucher)
836 {
837
838         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
839         if (this.classname == "droppedweapon")
840         {
841                 if (ITEM_TOUCH_NEEDKILL())
842                 {
843                         delete(this);
844                         return;
845                 }
846         }
847
848         if(!(toucher.flags & FL_PICKUPITEMS)
849         || STAT(FROZEN, toucher)
850         || IS_DEAD(toucher)
851         || (this.solid != SOLID_TRIGGER)
852         || (this.owner == toucher)
853         || (time < this.item_spawnshieldtime)
854         ) { return; }
855
856         switch (MUTATOR_CALLHOOK(ItemTouch, this, toucher))
857         {
858                 case MUT_ITEMTOUCH_RETURN: { return; }
859                 case MUT_ITEMTOUCH_PICKUP: { toucher = M_ARGV(1, entity); goto pickup; }
860         }
861
862         toucher = M_ARGV(1, entity);
863
864         if (this.classname == "droppedweapon")
865         {
866                 this.strength_finished = max(0, this.strength_finished - time);
867                 this.invincible_finished = max(0, this.invincible_finished - time);
868                 this.superweapons_finished = max(0, this.superweapons_finished - time);
869         }
870         entity it = this.itemdef;
871         bool gave = ITEM_HANDLE(Pickup, it, this, toucher);
872         if (!gave)
873         {
874                 if (this.classname == "droppedweapon")
875                 {
876                         // undo what we did above
877                         this.strength_finished += time;
878                         this.invincible_finished += time;
879                         this.superweapons_finished += time;
880                 }
881                 return;
882         }
883
884 LABEL(pickup)
885
886         toucher.last_pickup = time;
887
888         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
889         _sound (toucher, (this.itemdef.instanceOfPowerup ? CH_TRIGGER_SINGLE : CH_TRIGGER), (this.item_pickupsound ? this.item_pickupsound : Sound_fixpath(this.item_pickupsound_ent)), VOL_BASE, ATTEN_NORM);
890
891         if (this.classname == "droppedweapon")
892                 delete(this);
893         else if (this.spawnshieldtime)
894         {
895                 entity e;
896                 if(this.team)
897                 {
898                         RandomSelection_Init();
899                         IL_EACH(g_items, it.team == this.team,
900                         {
901                                 if(it.itemdef) // is a registered item
902                                 {
903                                         Item_Show(it, -1);
904                                         RandomSelection_AddEnt(it, it.cnt, 0);
905                                 }
906                         });
907                         e = RandomSelection_chosen_ent;
908                         Item_Show(e, 1); // reset its state so it is visible (extra sendflags doesn't matter, this happens anyway)
909                 }
910                 else
911                         e = this;
912                 Item_ScheduleRespawn(e);
913         }
914 }
915
916 void Item_Reset(entity this)
917 {
918         Item_Show(this, !this.state);
919         setorigin(this, this.origin);
920
921         if (this.classname != "droppedweapon")
922         {
923                 setthink(this, Item_Think);
924                 this.nextthink = time;
925
926                 if (this.waypointsprite_attached)
927                         WaypointSprite_Kill(this.waypointsprite_attached);
928
929                 if (this.itemdef.instanceOfPowerup || (this.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
930                         Item_ScheduleInitialRespawn(this);
931         }
932 }
933
934 void Item_FindTeam(entity this)
935 {
936         entity e;
937
938         if(this.effects & EF_NODRAW)
939         {
940                 // marker for item team search
941                 LOG_TRACE("Initializing item team ", ftos(this.team));
942                 RandomSelection_Init();
943                 IL_EACH(g_items, it.team == this.team,
944                 {
945                         if(it.itemdef) // is a registered item
946                                 RandomSelection_AddEnt(it, it.cnt, 0);
947                 });
948
949                 e = RandomSelection_chosen_ent;
950                 e.state = 0;
951                 Item_Show(e, 1);
952
953                 IL_EACH(g_items, it.team == this.team,
954                 {
955                         if(it.itemdef) // is a registered item
956                         {
957                                 if(it != e)
958                                 {
959                                         // make it non-spawned
960                                         Item_Show(it, -1);
961                                         it.state = 1; // state 1 = initially hidden item, apparently
962                                 }
963                                 it.effects &= ~EF_NODRAW;
964                         }
965                 });
966
967                 Item_Reset(this);
968         }
969 }
970
971 // Savage: used for item garbage-collection
972 void RemoveItem(entity this)
973 {
974         if(wasfreed(this) || !this) { return; }
975         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
976         delete(this);
977 }
978
979 // pickup evaluation functions
980 // these functions decide how desirable an item is to the bots
981
982 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
983
984 float weapon_pickupevalfunc(entity player, entity item)
985 {
986         // See if I have it already
987         if(player.weapons & item.weapons)
988         {
989                 // If I can pick it up
990                 if(!item.spawnshieldtime)
991                         return 0;
992                 return ammo_pickupevalfunc(player, item);
993         }
994
995         // reduce weapon value if bot already got a good arsenal
996         float c = 1;
997         int weapons_value = 0;
998         FOREACH(Weapons, it != WEP_Null && (player.weapons & it.m_wepset), {
999                 weapons_value += it.bot_pickupbasevalue;
1000         });
1001         c -= bound(0, weapons_value / 20000, 1) * 0.5;
1002
1003         return item.bot_pickupbasevalue * c;
1004 }
1005
1006 float ammo_pickupevalfunc(entity player, entity item)
1007 {
1008         bool need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1009         entity wpn = NULL;
1010         float c = 0;
1011         float rating = 0;
1012
1013         // Detect needed ammo
1014         if(item.itemdef.instanceOfWeaponPickup)
1015         {
1016                 entity ammo = NULL;
1017                 if(item.ammo_shells)       { need_shells  = true; ammo = ITEM_Shells;      }
1018                 else if(item.ammo_nails)   { need_nails   = true; ammo = ITEM_Bullets;     }
1019                 else if(item.ammo_rockets) { need_rockets = true; ammo = ITEM_Rockets;     }
1020                 else if(item.ammo_cells)   { need_cells   = true; ammo = ITEM_Cells;       }
1021                 else if(item.ammo_plasma)  { need_plasma  = true; ammo = ITEM_Plasma;      }
1022                 else if(item.ammo_fuel)    { need_fuel    = true; ammo = ITEM_JetpackFuel; }
1023
1024                 if(!ammo)
1025                         return 0;
1026                 wpn = item;
1027                 rating = ammo.m_botvalue;
1028         }
1029         else
1030         {
1031                 FOREACH(Weapons, it != WEP_Null, {
1032                         if(!(player.weapons & (it.m_wepset)))
1033                                 continue;
1034
1035                         switch(it.ammo_field)
1036                         {
1037                                 case ammo_shells:  need_shells  = true; break;
1038                                 case ammo_nails:   need_nails   = true; break;
1039                                 case ammo_rockets: need_rockets = true; break;
1040                                 case ammo_cells:   need_cells   = true; break;
1041                                 case ammo_plasma:  need_plasma  = true; break;
1042                                 case ammo_fuel:    need_fuel    = true; break;
1043                         }
1044                 });
1045                 rating = item.bot_pickupbasevalue;
1046         }
1047
1048         float noammorating = 0.5;
1049
1050         if ((need_shells) && (item.ammo_shells) && (player.ammo_shells < g_pickup_shells_max))
1051                 c = item.ammo_shells / max(noammorating, player.ammo_shells);
1052
1053         if ((need_nails) && (item.ammo_nails) && (player.ammo_nails < g_pickup_nails_max))
1054                 c = item.ammo_nails / max(noammorating, player.ammo_nails);
1055
1056         if ((need_rockets) && (item.ammo_rockets) && (player.ammo_rockets < g_pickup_rockets_max))
1057                 c = item.ammo_rockets / max(noammorating, player.ammo_rockets);
1058
1059         if ((need_cells) && (item.ammo_cells) && (player.ammo_cells < g_pickup_cells_max))
1060                 c = item.ammo_cells / max(noammorating, player.ammo_cells);
1061
1062         if ((need_plasma) && (item.ammo_plasma) && (player.ammo_plasma < g_pickup_plasma_max))
1063                 c = item.ammo_plasma / max(noammorating, player.ammo_plasma);
1064
1065         if ((need_fuel) && (item.ammo_fuel) && (player.ammo_fuel < g_pickup_fuel_max))
1066                 c = item.ammo_fuel / max(noammorating, player.ammo_fuel);
1067
1068         rating *= min(c, 2);
1069         if(wpn)
1070                 rating += wpn.bot_pickupbasevalue * 0.1;
1071         return rating;
1072 }
1073
1074 .int item_group;
1075 .int item_group_count;
1076 float healtharmor_pickupevalfunc(entity player, entity item)
1077 {
1078         float c = 0;
1079         float rating = item.bot_pickupbasevalue;
1080
1081         float itemarmor = item.armorvalue;
1082         float itemhealth = item.health;
1083
1084         if(item.item_group)
1085         {
1086                 itemarmor *= min(4, item.item_group_count);
1087                 itemhealth *= min(4, item.item_group_count);
1088         }
1089
1090         if (itemarmor && (player.armorvalue < item.max_armorvalue))
1091                 c = itemarmor / max(1, player.armorvalue * 2/3 + player.health * 1/3);
1092
1093         if (itemhealth && (player.health < item.max_health))
1094                 c = itemhealth / max(1, player.health);
1095
1096         rating *= min(2, c);
1097         return rating;
1098 }
1099
1100 void Item_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1101 {
1102         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1103                 RemoveItem(this);
1104 }
1105
1106 void item_use(entity this, entity actor, entity trigger)
1107 {
1108         // use the touch function to handle collection
1109         gettouch(this)(this, actor);
1110 }
1111
1112 void _StartItem(entity this, entity def, float defaultrespawntime, float defaultrespawntimejitter)
1113 {
1114         string itemname = def.m_name;
1115         Model itemmodel = def.m_model;
1116     Sound pickupsound = def.m_sound;
1117         float(entity player, entity item) pickupevalfunc = def.m_pickupevalfunc;
1118         float pickupbasevalue = def.m_botvalue;
1119         int itemflags = def.m_itemflags;
1120
1121         startitem_failed = false;
1122
1123         this.item_model_ent = itemmodel;
1124     this.item_pickupsound_ent = pickupsound;
1125
1126     if(def.m_iteminit)
1127         def.m_iteminit(this);
1128
1129         if(!this.respawntime) // both need to be set
1130         {
1131                 this.respawntime = defaultrespawntime;
1132                 this.respawntimejitter = defaultrespawntimejitter;
1133         }
1134
1135         if(!this.pickup_anyway && def.m_pickupanyway)
1136                 this.pickup_anyway = def.m_pickupanyway();
1137
1138         int itemid = def.m_itemid;
1139         this.items = itemid;
1140         int weaponid = def.instanceOfWeaponPickup ? def.m_weapon.m_id : 0;
1141         this.weapon = weaponid;
1142
1143         if(!this.fade_end)
1144         {
1145                 this.fade_start = autocvar_g_items_mindist;
1146                 this.fade_end = autocvar_g_items_maxdist;
1147         }
1148
1149         if(weaponid)
1150                 this.weapons = WepSet_FromWeapon(Weapons_from(weaponid));
1151
1152         this.flags = FL_ITEM | itemflags;
1153         IL_PUSH(g_items, this);
1154
1155         if(MUTATOR_CALLHOOK(FilterItem, this)) // error means we do not want the item
1156         {
1157                 startitem_failed = true;
1158                 delete(this);
1159                 return;
1160         }
1161
1162         // is it a dropped weapon?
1163         if (this.classname == "droppedweapon")
1164         {
1165                 this.reset = SUB_Remove;
1166                 // it's a dropped weapon
1167                 set_movetype(this, MOVETYPE_TOSS);
1168
1169                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1170                 setthink(this, RemoveItem);
1171                 this.nextthink = time + 20;
1172
1173                 this.takedamage = DAMAGE_YES;
1174                 this.event_damage = Item_Damage;
1175
1176                 if(this.strength_finished || this.invincible_finished || this.superweapons_finished)
1177                 {
1178                         // if item is worthless after a timer, have it expire then
1179                         this.nextthink = max(this.strength_finished, this.invincible_finished, this.superweapons_finished);
1180                 }
1181
1182                 // don't drop if in a NODROP zone (such as lava)
1183                 traceline(this.origin, this.origin, MOVE_NORMAL, this);
1184                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1185                 {
1186                         startitem_failed = true;
1187                         delete(this);
1188                         return;
1189                 }
1190         }
1191         else
1192         {
1193                 if(!have_pickup_item(this))
1194                 {
1195                         startitem_failed = true;
1196                         delete(this);
1197                         return;
1198                 }
1199
1200                 if(this.angles != '0 0 0')
1201                         this.SendFlags |= ISF_ANGLES;
1202
1203                 this.reset = Item_Reset;
1204                 // it's a level item
1205                 if(this.spawnflags & 1)
1206                         this.noalign = 1;
1207                 if (this.noalign > 0)
1208                         set_movetype(this, MOVETYPE_NONE);
1209                 else
1210                         set_movetype(this, MOVETYPE_TOSS);
1211                 // do item filtering according to game mode and other things
1212                 if (this.noalign <= 0)
1213                 {
1214                         // first nudge it off the floor a little bit to avoid math errors
1215                         setorigin(this, this.origin + '0 0 1');
1216                         // set item size before we spawn a spawnfunc_waypoint
1217                         setsize(this, def.m_mins, def.m_maxs);
1218                         this.SendFlags |= ISF_SIZE;
1219                         // note droptofloor returns false if stuck/or would fall too far
1220                         if (!this.noalign)
1221                                 droptofloor(this);
1222                         waypoint_spawnforitem(this);
1223                 }
1224
1225                 /*
1226                  * can't do it that way, as it would break maps
1227                  * TODO make a target_give like entity another way, that perhaps has
1228                  * the weapon name in a key
1229                 if(this.targetname)
1230                 {
1231                         // target_give not yet supported; maybe later
1232                         print("removed targeted ", this.classname, "\n");
1233                         startitem_failed = true;
1234                         delete(this);
1235                         return;
1236                 }
1237                 */
1238
1239                 if(this.targetname != "" && (this.spawnflags & 16))
1240                         this.use = item_use;
1241
1242                 if(autocvar_spawn_debug >= 2)
1243                 {
1244             // why not flags & fl_item?
1245                     FOREACH_ENTITY_RADIUS(this.origin, 3, it.is_item, {
1246                 LOG_TRACE("XXX Found duplicated item: ", itemname, vtos(this.origin));
1247                 LOG_TRACE(" vs ", it.netname, vtos(it.origin));
1248                 error("Mapper sucks.");
1249             });
1250                         this.is_item = true;
1251                 }
1252
1253                 weaponsInMap |= WepSet_FromWeapon(Weapons_from(weaponid));
1254
1255                 precache_model(this.model);
1256                 precache_sound(this.item_pickupsound);
1257
1258                 if (   def.instanceOfPowerup
1259                         || def.instanceOfWeaponPickup
1260                         || (def.instanceOfHealth && def != ITEM_HealthSmall)
1261                         || (def.instanceOfArmor && def != ITEM_ArmorSmall)
1262                         || (itemid & (IT_KEY1 | IT_KEY2))
1263                 ) this.target = "###item###"; // for finding the nearest item using find()
1264
1265                 Item_ItemsTime_SetTime(this, 0);
1266         }
1267
1268         this.bot_pickup = true;
1269         this.bot_pickupevalfunc = pickupevalfunc;
1270         this.bot_pickupbasevalue = pickupbasevalue;
1271         this.mdl = this.model ? this.model : strzone(this.item_model_ent.model_str());
1272         this.netname = itemname;
1273         settouch(this, Item_Touch);
1274         setmodel(this, MDL_Null); // precision set below
1275         //this.effects |= EF_LOWPRECISION;
1276
1277         setsize (this, this.pos1 =  def.m_mins, this.pos2 = def.m_maxs);
1278
1279         this.SendFlags |= ISF_SIZE;
1280
1281         if (!(this.spawnflags & 1024)) {
1282                 if(def.instanceOfPowerup)
1283                         this.ItemStatus |= ITS_ANIMATE1;
1284
1285                 if(this.armorvalue || this.health)
1286                         this.ItemStatus |= ITS_ANIMATE2;
1287         }
1288
1289         if(def.instanceOfWeaponPickup)
1290         {
1291                 if (this.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1292                         this.colormap = 1024; // color shirt=0 pants=0 grey
1293                 else
1294                         this.gravity = 1;
1295                 if (!(this.spawnflags & 1024))
1296                         this.ItemStatus |= ITS_ANIMATE1;
1297                 this.SendFlags |= ISF_COLORMAP;
1298         }
1299
1300         this.state = 0;
1301         if(this.team) // broken, no idea why.
1302         {
1303                 if(!this.cnt)
1304                         this.cnt = 1; // item probability weight
1305
1306                 this.effects |= EF_NODRAW; // marker for item team search
1307                 InitializeEntity(this, Item_FindTeam, INITPRIO_FINDTARGET);
1308         }
1309         else
1310                 Item_Reset(this);
1311
1312         Net_LinkEntity(this, !(def.instanceOfPowerup || def.instanceOfHealth || def.instanceOfArmor), 0, ItemSend);
1313
1314         // call this hook after everything else has been done
1315         if (MUTATOR_CALLHOOK(Item_Spawn, this))
1316         {
1317                 startitem_failed = true;
1318                 delete(this);
1319                 return;
1320         }
1321
1322         setItemGroup(this);
1323 }
1324
1325 void StartItem(entity this, GameItem def)
1326 {
1327     _StartItem(
1328         this,
1329         this.itemdef = def,
1330         def.m_respawntime(), // defaultrespawntime
1331         def.m_respawntimejitter() // defaultrespawntimejitter
1332         );
1333 }
1334
1335 #define IS_SMALL(def) ((def.instanceOfHealth && def == ITEM_HealthSmall) || (def.instanceOfArmor && def == ITEM_ArmorSmall))
1336 int group_count = 1;
1337
1338 void setItemGroup(entity this)
1339 {
1340         if(!IS_SMALL(this.itemdef))
1341                 return;
1342
1343         FOREACH_ENTITY_RADIUS(this.origin, 120, (it != this) && IS_SMALL(it.itemdef),
1344         {
1345                 if(!this.item_group)
1346                 {
1347                         if(!it.item_group)
1348                         {
1349                                 it.item_group = group_count;
1350                                 group_count++;
1351                         }
1352                         this.item_group = it.item_group;
1353                 }
1354                 else // spawning item is already part of a item_group X
1355                 {
1356                         if(!it.item_group)
1357                                 it.item_group = this.item_group;
1358                         else if(it.item_group != this.item_group) // found an item near the spawning item that is part of a different item_group Y
1359                         {
1360                                 int grY = it.item_group;
1361                                 // move all items of item_group Y to item_group X
1362                                 IL_EACH(g_items, IS_SMALL(it.itemdef),
1363                                 {
1364                                         if(it.item_group == grY)
1365                                                 it.item_group = this.item_group;
1366                                 });
1367                         }
1368                 }
1369         });
1370 }
1371
1372 void setItemGroupCount()
1373 {
1374         for (int k = 1; k <= group_count; k++)
1375         {
1376                 int count = 0;
1377                 IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { count++; });
1378                 if (count)
1379                         IL_EACH(g_items, IS_SMALL(it.itemdef) && it.item_group == k, { it.item_group_count = count; });
1380         }
1381 }
1382
1383 spawnfunc(item_rockets)
1384 {
1385     StartItem(this, ITEM_Rockets);
1386 }
1387
1388 spawnfunc(item_bullets)
1389 {
1390         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1391            (this.classname != "droppedweapon"))
1392         {
1393                 weaponswapping = true;
1394                 spawnfunc_item_shells(this);
1395                 weaponswapping = false;
1396                 return;
1397         }
1398
1399     StartItem(this, ITEM_Bullets);
1400 }
1401
1402 spawnfunc(item_cells)
1403 {
1404         StartItem(this, ITEM_Cells);
1405 }
1406
1407 spawnfunc(item_plasma)
1408 {
1409         StartItem(this, ITEM_Plasma);
1410 }
1411
1412 spawnfunc(item_shells)
1413 {
1414         if(!weaponswapping && autocvar_sv_q3acompat_machineshotgunswap &&
1415            (this.classname != "droppedweapon"))
1416         {
1417                 weaponswapping = true;
1418                 spawnfunc_item_bullets(this);
1419                 weaponswapping = false;
1420                 return;
1421         }
1422
1423         StartItem(this, ITEM_Shells);
1424 }
1425
1426 spawnfunc(item_armor_small)
1427 {
1428         StartItem(this, ITEM_ArmorSmall);
1429 }
1430
1431 spawnfunc(item_armor_medium)
1432 {
1433         StartItem(this, ITEM_ArmorMedium);
1434 }
1435
1436 spawnfunc(item_armor_big)
1437 {
1438         StartItem(this, ITEM_ArmorBig);
1439 }
1440
1441 spawnfunc(item_armor_mega)
1442 {
1443         StartItem(this, ITEM_ArmorMega);
1444 }
1445
1446 spawnfunc(item_health_small)
1447 {
1448         StartItem(this, ITEM_HealthSmall);
1449 }
1450
1451 spawnfunc(item_health_medium)
1452 {
1453     StartItem(this, ITEM_HealthMedium);
1454 }
1455
1456 spawnfunc(item_health_big)
1457 {
1458         StartItem(this, ITEM_HealthBig);
1459 }
1460
1461 spawnfunc(item_health_mega)
1462 {
1463     StartItem(this, ITEM_HealthMega);
1464 }
1465
1466 // support old misnamed entities
1467 spawnfunc(item_armor1) { spawnfunc_item_armor_small(this); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1468 spawnfunc(item_armor25) { spawnfunc_item_armor_mega(this); }
1469 spawnfunc(item_armor_large) { spawnfunc_item_armor_mega(this); }
1470 spawnfunc(item_health1) { spawnfunc_item_health_small(this); }
1471 spawnfunc(item_health25) { spawnfunc_item_health_medium(this); }
1472 spawnfunc(item_health_large) { spawnfunc_item_health_big(this); }
1473 spawnfunc(item_health100) { spawnfunc_item_health_mega(this); }
1474
1475 spawnfunc(item_strength)
1476 {
1477         StartItem(this, ITEM_Strength);
1478 }
1479
1480 spawnfunc(item_invincible)
1481 {
1482         StartItem(this, ITEM_Shield);
1483 }
1484
1485 // compatibility:
1486 spawnfunc(item_quad) { this.classname = "item_strength";spawnfunc_item_strength(this);}
1487
1488 void target_items_use(entity this, entity actor, entity trigger)
1489 {
1490         if(actor.classname == "droppedweapon")
1491         {
1492                 EXACTTRIGGER_TOUCH(this, trigger);
1493                 delete(actor);
1494                 return;
1495         }
1496
1497         if (!IS_PLAYER(actor) || IS_DEAD(actor))
1498                 return;
1499
1500         if(trigger.solid == SOLID_TRIGGER)
1501         {
1502                 EXACTTRIGGER_TOUCH(this, trigger);
1503         }
1504
1505         IL_EACH(g_items, it.enemy == actor && it.classname == "droppedweapon",
1506         {
1507                 delete(it);
1508         });
1509
1510         if(GiveItems(actor, 0, tokenize_console(this.netname)))
1511                 centerprint(actor, this.message);
1512 }
1513
1514 spawnfunc(target_items)
1515 {
1516         int n;
1517         string s;
1518
1519         this.use = target_items_use;
1520         if(!this.strength_finished)
1521                 this.strength_finished = autocvar_g_balance_powerup_strength_time;
1522         if(!this.invincible_finished)
1523                 this.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1524         if(!this.superweapons_finished)
1525                 this.superweapons_finished = autocvar_g_balance_superweapons_time;
1526
1527         n = tokenize_console(this.netname);
1528         if(argv(0) == "give")
1529         {
1530                 this.netname = substring(this.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1531         }
1532         else
1533         {
1534                 for(int j = 0; j < n; ++j)
1535                 {
1536                         if     (argv(j) == "unlimited_ammo")         this.items |= IT_UNLIMITED_AMMO;
1537                         else if(argv(j) == "unlimited_weapon_ammo")  this.items |= IT_UNLIMITED_WEAPON_AMMO;
1538                         else if(argv(j) == "unlimited_superweapons") this.items |= IT_UNLIMITED_SUPERWEAPONS;
1539                         else if(argv(j) == "strength")               this.items |= ITEM_Strength.m_itemid;
1540                         else if(argv(j) == "invincible")             this.items |= ITEM_Shield.m_itemid;
1541                         else if(argv(j) == "superweapons")           this.items |= IT_SUPERWEAPON;
1542                         else if(argv(j) == "jetpack")                this.items |= ITEM_Jetpack.m_itemid;
1543                         else if(argv(j) == "fuel_regen")             this.items |= ITEM_JetpackRegen.m_itemid;
1544                         else
1545                         {
1546                                 FOREACH(Buffs, it != BUFF_Null,
1547                                 {
1548                                         s = Buff_UndeprecateName(argv(j));
1549                                         if(s == it.m_name)
1550                                         {
1551                                                 this.buffs |= (it.m_itemid);
1552                                                 break;
1553                                         }
1554                                 });
1555                                 FOREACH(Weapons, it != WEP_Null, {
1556                                         s = W_UndeprecateName(argv(j));
1557                                         if(s == it.netname)
1558                                         {
1559                                                 this.weapons |= (it.m_wepset);
1560                                                 if(this.spawnflags == 0 || this.spawnflags == 2)
1561                                                         it.wr_init(it);
1562                                                 break;
1563                                         }
1564                                 });
1565                         }
1566                 }
1567
1568                 string itemprefix, valueprefix;
1569                 if(this.spawnflags == 0)
1570                 {
1571                         itemprefix = "";
1572                         valueprefix = "";
1573                 }
1574                 else if(this.spawnflags == 1)
1575                 {
1576                         itemprefix = "max ";
1577                         valueprefix = "max ";
1578                 }
1579                 else if(this.spawnflags == 2)
1580                 {
1581                         itemprefix = "min ";
1582                         valueprefix = "min ";
1583                 }
1584                 else if(this.spawnflags == 4)
1585                 {
1586                         itemprefix = "minus ";
1587                         valueprefix = "max ";
1588                 }
1589                 else
1590                 {
1591                         error("invalid spawnflags");
1592                         itemprefix = valueprefix = string_null;
1593                 }
1594
1595                 this.netname = "";
1596                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1597                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1598                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.strength_finished * boolean(this.items & ITEM_Strength.m_itemid), "strength");
1599                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.invincible_finished * boolean(this.items & ITEM_Shield.m_itemid), "invincible");
1600                 this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, this.superweapons_finished * boolean(this.items & IT_SUPERWEAPON), "superweapons");
1601                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_Jetpack.m_itemid), "jetpack");
1602                 this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, boolean(this.items & ITEM_JetpackRegen.m_itemid), "fuel_regen");
1603                 if(this.ammo_shells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_shells), "shells");
1604                 if(this.ammo_nails != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_nails), "nails");
1605                 if(this.ammo_rockets != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_rockets), "rockets");
1606                 if(this.ammo_cells != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_cells), "cells");
1607                 if(this.ammo_plasma != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_plasma), "plasma");
1608                 if(this.ammo_fuel != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.ammo_fuel), "fuel");
1609                 if(this.health != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.health), "health");
1610                 if(this.armorvalue != 0) this.netname = sprintf("%s %s%d %s", this.netname, valueprefix, max(0, this.armorvalue), "armor");
1611                 FOREACH(Buffs, it != BUFF_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.buffs & (it.m_itemid)), it.m_name));
1612                 FOREACH(Weapons, it != WEP_Null, this.netname = sprintf("%s %s%d %s", this.netname, itemprefix, !!(this.weapons & (it.m_wepset)), it.netname));
1613         }
1614         this.netname = strzone(this.netname);
1615         //print(this.netname, "\n");
1616
1617         n = tokenize_console(this.netname);
1618         for(int j = 0; j < n; ++j)
1619         {
1620                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(argv(j)) == it.netname, {
1621             it.wr_init(it);
1622             break;
1623                 });
1624         }
1625 }
1626
1627 spawnfunc(item_fuel)
1628 {
1629         StartItem(this, ITEM_JetpackFuel);
1630 }
1631
1632 spawnfunc(item_fuel_regen)
1633 {
1634         if(start_items & ITEM_JetpackRegen.m_itemid)
1635         {
1636                 spawnfunc_item_fuel(this);
1637                 return;
1638         }
1639         StartItem(this, ITEM_JetpackRegen);
1640 }
1641
1642 spawnfunc(item_jetpack)
1643 {
1644         if(start_items & ITEM_Jetpack.m_itemid)
1645         {
1646                 spawnfunc_item_fuel(this);
1647                 return;
1648         }
1649         StartItem(this, ITEM_Jetpack);
1650 }
1651
1652 float GiveWeapon(entity e, float wpn, float op, float val)
1653 {
1654         WepSet v0, v1;
1655         WepSet s = WepSet_FromWeapon(Weapons_from(wpn));
1656         v0 = (e.weapons & s);
1657         switch(op)
1658         {
1659                 case OP_SET:
1660                         if(val > 0)
1661                                 e.weapons |= s;
1662                         else
1663                                 e.weapons &= ~s;
1664                         break;
1665                 case OP_MIN:
1666                 case OP_PLUS:
1667                         if(val > 0)
1668                                 e.weapons |= s;
1669                         break;
1670                 case OP_MAX:
1671                         if(val <= 0)
1672                                 e.weapons &= ~s;
1673                         break;
1674                 case OP_MINUS:
1675                         if(val > 0)
1676                                 e.weapons &= ~s;
1677                         break;
1678         }
1679         v1 = (e.weapons & s);
1680         return (v0 != v1);
1681 }
1682
1683 bool GiveBuff(entity e, Buff thebuff, int op, int val)
1684 {
1685         bool had_buff = (e.buffs & thebuff.m_itemid);
1686         switch(op)
1687         {
1688                 case OP_SET:
1689                         if(val > 0)
1690                                 e.buffs |= thebuff.m_itemid;
1691                         else
1692                                 e.buffs &= ~thebuff.m_itemid;
1693                         break;
1694                 case OP_MIN:
1695                 case OP_PLUS:
1696                         if(val > 0)
1697                                 e.buffs |= thebuff.m_itemid;
1698                         break;
1699                 case OP_MAX:
1700                         if(val <= 0)
1701                                 e.buffs &= ~thebuff.m_itemid;
1702                         break;
1703                 case OP_MINUS:
1704                         if(val > 0)
1705                                 e.buffs &= ~thebuff.m_itemid;
1706                         break;
1707         }
1708         bool have_buff = (e.buffs & thebuff.m_itemid);
1709         return (had_buff != have_buff);
1710 }
1711
1712 void GiveSound(entity e, float v0, float v1, float t, Sound snd_incr, Sound snd_decr)
1713 {
1714         if(v1 == v0)
1715                 return;
1716         if(v1 <= v0 - t)
1717         {
1718                 if(snd_decr != NULL)
1719                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1720         }
1721         else if(v0 >= v0 + t)
1722         {
1723                 if(snd_incr != NULL)
1724                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1725         }
1726 }
1727
1728 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1729 {
1730         if(v0 < v1)
1731                 e.(rotfield) = max(e.(rotfield), time + rottime);
1732         else if(v0 > v1)
1733                 e.(regenfield) = max(e.(regenfield), time + regentime);
1734 }
1735 float GiveItems(entity e, float beginarg, float endarg)
1736 {
1737         float got, i, val, op;
1738         string cmd;
1739
1740         val = 999;
1741         op = OP_SET;
1742
1743         got = 0;
1744
1745         int _switchweapon = 0;
1746
1747         if(CS(e).autoswitch)
1748         {
1749                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1750                 {
1751                         .entity weaponentity = weaponentities[slot];
1752                         if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1753                         if(e.(weaponentity).m_switchweapon == w_getbestweapon(e, weaponentity))
1754                                 _switchweapon |= BIT(slot);
1755                 }
1756         }
1757
1758         e.strength_finished = max(0, e.strength_finished - time);
1759         e.invincible_finished = max(0, e.invincible_finished - time);
1760         e.superweapons_finished = max(0, e.superweapons_finished - time);
1761
1762         PREGIVE(e, items);
1763         PREGIVE_WEAPONS(e);
1764         PREGIVE(e, strength_finished);
1765         PREGIVE(e, invincible_finished);
1766         PREGIVE(e, superweapons_finished);
1767         PREGIVE(e, ammo_nails);
1768         PREGIVE(e, ammo_cells);
1769         PREGIVE(e, ammo_plasma);
1770         PREGIVE(e, ammo_shells);
1771         PREGIVE(e, ammo_rockets);
1772         PREGIVE(e, ammo_fuel);
1773         PREGIVE(e, armorvalue);
1774         PREGIVE(e, health);
1775
1776         for(i = beginarg; i < endarg; ++i)
1777         {
1778                 cmd = argv(i);
1779
1780                 if(cmd == "0" || stof(cmd))
1781                 {
1782                         val = stof(cmd);
1783                         continue;
1784                 }
1785                 switch(cmd)
1786                 {
1787                         case "no":
1788                                 op = OP_MAX;
1789                                 val = 0;
1790                                 continue;
1791                         case "max":
1792                                 op = OP_MAX;
1793                                 continue;
1794                         case "min":
1795                                 op = OP_MIN;
1796                                 continue;
1797                         case "plus":
1798                                 op = OP_PLUS;
1799                                 continue;
1800                         case "minus":
1801                                 op = OP_MINUS;
1802                                 continue;
1803                         case "ALL":
1804                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1805                                 got += GiveValue(e, strength_finished, op, val);
1806                                 got += GiveValue(e, invincible_finished, op, val);
1807                                 got += GiveValue(e, superweapons_finished, op, val);
1808                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1809                         case "all":
1810                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1811                                 got += GiveValue(e, health, op, val);
1812                                 got += GiveValue(e, armorvalue, op, val);
1813                         case "allweapons":
1814                                 FOREACH(Weapons, it != WEP_Null && !(it.spawnflags & WEP_FLAG_MUTATORBLOCKED), got += GiveWeapon(e, it.m_id, op, val));
1815                         //case "allbuffs": // all buffs makes a player god, do not want!
1816                                 //FOREACH(Buffs, it != BUFF_Null, got += GiveBuff(e, it.m_itemid, op, val));
1817                         case "allammo":
1818                                 got += GiveValue(e, ammo_cells, op, val);
1819                                 got += GiveValue(e, ammo_plasma, op, val);
1820                                 got += GiveValue(e, ammo_shells, op, val);
1821                                 got += GiveValue(e, ammo_nails, op, val);
1822                                 got += GiveValue(e, ammo_rockets, op, val);
1823                                 got += GiveValue(e, ammo_fuel, op, val);
1824                                 break;
1825                         case "unlimited_ammo":
1826                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1827                                 break;
1828                         case "unlimited_weapon_ammo":
1829                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1830                                 break;
1831                         case "unlimited_superweapons":
1832                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1833                                 break;
1834                         case "jetpack":
1835                                 got += GiveBit(e, items, ITEM_Jetpack.m_itemid, op, val);
1836                                 break;
1837                         case "fuel_regen":
1838                                 got += GiveBit(e, items, ITEM_JetpackRegen.m_itemid, op, val);
1839                                 break;
1840                         case "strength":
1841                                 got += GiveValue(e, strength_finished, op, val);
1842                                 break;
1843                         case "invincible":
1844                                 got += GiveValue(e, invincible_finished, op, val);
1845                                 break;
1846                         case "superweapons":
1847                                 got += GiveValue(e, superweapons_finished, op, val);
1848                                 break;
1849                         case "cells":
1850                                 got += GiveValue(e, ammo_cells, op, val);
1851                                 break;
1852                         case "plasma":
1853                                 got += GiveValue(e, ammo_plasma, op, val);
1854                                 break;
1855                         case "shells":
1856                                 got += GiveValue(e, ammo_shells, op, val);
1857                                 break;
1858                         case "nails":
1859                         case "bullets":
1860                                 got += GiveValue(e, ammo_nails, op, val);
1861                                 break;
1862                         case "rockets":
1863                                 got += GiveValue(e, ammo_rockets, op, val);
1864                                 break;
1865                         case "health":
1866                                 got += GiveValue(e, health, op, val);
1867                                 break;
1868                         case "armor":
1869                                 got += GiveValue(e, armorvalue, op, val);
1870                                 break;
1871                         case "fuel":
1872                                 got += GiveValue(e, ammo_fuel, op, val);
1873                                 break;
1874                         default:
1875                                 FOREACH(Buffs, it != BUFF_Null && Buff_UndeprecateName(cmd) == it.m_name,
1876                                 {
1877                                         got += GiveBuff(e, it, op, val);
1878                                         break;
1879                                 });
1880                                 FOREACH(Weapons, it != WEP_Null && W_UndeprecateName(cmd) == it.netname, {
1881                     got += GiveWeapon(e, it.m_id, op, val);
1882                     break;
1883                                 });
1884                                 break;
1885                 }
1886                 val = 999;
1887                 op = OP_SET;
1888         }
1889
1890         POSTGIVE_BIT(e, items, ITEM_JetpackRegen.m_itemid, SND_ITEMPICKUP, SND_Null);
1891         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, SND_POWERUP, SND_POWEROFF);
1892         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, SND_POWERUP, SND_POWEROFF);
1893         POSTGIVE_BIT(e, items, ITEM_Jetpack.m_itemid, SND_ITEMPICKUP, SND_Null);
1894         FOREACH(Weapons, it != WEP_Null, {
1895                 POSTGIVE_WEAPON(e, it, SND_WEAPONPICKUP, SND_Null);
1896                 if(!(save_weapons & (it.m_wepset)))
1897                         if(e.weapons & (it.m_wepset))
1898                                 it.wr_init(it);
1899         });
1900         POSTGIVE_VALUE(e, strength_finished, 1, SND_POWERUP, SND_POWEROFF);
1901         POSTGIVE_VALUE(e, invincible_finished, 1, SND_Shield, SND_POWEROFF);
1902         //POSTGIVE_VALUE(e, superweapons_finished, 1, SND_Null, SND_Null);
1903         POSTGIVE_VALUE(e, ammo_nails, 0, SND_ITEMPICKUP, SND_Null);
1904         POSTGIVE_VALUE(e, ammo_cells, 0, SND_ITEMPICKUP, SND_Null);
1905         POSTGIVE_VALUE(e, ammo_plasma, 0, SND_ITEMPICKUP, SND_Null);
1906         POSTGIVE_VALUE(e, ammo_shells, 0, SND_ITEMPICKUP, SND_Null);
1907         POSTGIVE_VALUE(e, ammo_rockets, 0, SND_ITEMPICKUP, SND_Null);
1908         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, SND_ITEMPICKUP, SND_Null);
1909         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_ARMOR25, SND_Null);
1910         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, SND_MEGAHEALTH, SND_Null);
1911
1912         if(e.superweapons_finished <= 0)
1913                 if(e.weapons & WEPSET_SUPERWEAPONS)
1914                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1915
1916         if(e.strength_finished <= 0)
1917                 e.strength_finished = 0;
1918         else
1919                 e.strength_finished += time;
1920         if(e.invincible_finished <= 0)
1921                 e.invincible_finished = 0;
1922         else
1923                 e.invincible_finished += time;
1924         if(e.superweapons_finished <= 0)
1925                 e.superweapons_finished = 0;
1926         else
1927                 e.superweapons_finished += time;
1928
1929         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1930         {
1931                 .entity weaponentity = weaponentities[slot];
1932                 if(e.(weaponentity).m_weapon != WEP_Null || slot == 0)
1933                 if(!(e.weapons & WepSet_FromWeapon(e.(weaponentity).m_switchweapon)))
1934                         _switchweapon |= BIT(slot);
1935         }
1936
1937         if(_switchweapon)
1938         {
1939                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1940                 {
1941                         .entity weaponentity = weaponentities[slot];
1942                         if(_switchweapon & BIT(slot))
1943                         {
1944                                 Weapon wep = w_getbestweapon(e, weaponentity);
1945                                 if(wep != e.(weaponentity).m_switchweapon)
1946                                         W_SwitchWeapon_Force(e, wep, weaponentity);
1947                         }
1948                 }
1949         }
1950
1951         return got;
1952 }
1953 #endif