qcsrc/common/turrets/turret/walker.qc

   1 #ifndef TUR_WALKER_H
   2 #define TUR_WALKER_H
   3 REGISTER_TURRET(
   4 /* TUR_##id   */ WALKER,
   5 /* function   */ t_walker,
   6 /* spawnflags */ TUR_FLAG_PLAYER | TUR_FLAG_MOVE,
   7 /* mins,maxs  */ '-70 -70 0', '70 70 95',
   8 /* model          */ "walker_body.md3",
   9 /* head_model */ "walker_head_minigun.md3",
  10 /* netname        */ "walker",
  11 /* fullname   */ _("Walker Turret")
  12 );
  13 #endif
  14
  15 #ifdef IMPLEMENTATION
  16 #ifdef SVQC
  17 float autocvar_g_turrets_unit_walker_melee_damage;
  18 float autocvar_g_turrets_unit_walker_melee_force;
  19 float autocvar_g_turrets_unit_walker_melee_range;
  20 float autocvar_g_turrets_unit_walker_rocket_damage;
  21 float autocvar_g_turrets_unit_walker_rocket_radius;
  22 float autocvar_g_turrets_unit_walker_rocket_force;
  23 float autocvar_g_turrets_unit_walker_rocket_speed;
  24 float autocvar_g_turrets_unit_walker_rocket_range;
  25 float autocvar_g_turrets_unit_walker_rocket_range_min;
  26 float autocvar_g_turrets_unit_walker_rocket_refire;
  27 float autocvar_g_turrets_unit_walker_rocket_turnrate;
  28 float autocvar_g_turrets_unit_walker_speed_stop;
  29 float autocvar_g_turrets_unit_walker_speed_walk;
  30 float autocvar_g_turrets_unit_walker_speed_run;
  31 float autocvar_g_turrets_unit_walker_speed_jump;
  32 float autocvar_g_turrets_unit_walker_speed_swim;
  33 float autocvar_g_turrets_unit_walker_speed_roam;
  34 float autocvar_g_turrets_unit_walker_turn;
  35 float autocvar_g_turrets_unit_walker_turn_walk;
  36 float autocvar_g_turrets_unit_walker_turn_strafe;
  37 float autocvar_g_turrets_unit_walker_turn_swim;
  38 float autocvar_g_turrets_unit_walker_turn_run;
  39
  40 #define ANIM_NO         0
  41 #define ANIM_TURN       1
  42 #define ANIM_WALK       2
  43 #define ANIM_RUN        3
  44 #define ANIM_STRAFE_L   4
  45 #define ANIM_STRAFE_R   5
  46 #define ANIM_JUMP       6
  47 #define ANIM_LAND       7
  48 #define ANIM_PAIN       8
  49 #define ANIM_MELEE      9
  50 #define ANIM_SWIM       10
  51 #define ANIM_ROAM       11
  52
  53 .float animflag;
  54 .float idletime;
  55
  56 #define WALKER_PATH(s,e) pathlib_astar(s,e)
  57
  58 float walker_firecheck()
  59 {SELFPARAM();
  60     if (self.animflag == ANIM_MELEE)
  61         return 0;
  62
  63     return turret_firecheck();
  64 }
  65
  66 void walker_melee_do_dmg()
  67 {SELFPARAM();
  68     vector where;
  69     entity e;
  70
  71     makevectors(self.angles);
  72     where = self.origin + v_forward * 128;
  73
  74     e = findradius(where,32);
  75     while (e)
  76     {
  77         if (turret_validate_target(self, e, self.target_validate_flags))
  78             if (e != self && e.owner != self)
  79                 Damage(e, self, self, (autocvar_g_turrets_unit_walker_melee_damage), DEATH_TURRET_WALK_MELEE, '0 0 0', v_forward * (autocvar_g_turrets_unit_walker_melee_force));
  80
  81         e = e.chain;
  82     }
  83 }
  84
  85 void walker_setnoanim()
  86 {SELFPARAM();
  87     turrets_setframe(ANIM_NO, false);
  88     self.animflag = self.frame;
  89 }
  90 void walker_rocket_explode()
  91 {SELFPARAM();
  92     RadiusDamage (self, self.owner, (autocvar_g_turrets_unit_walker_rocket_damage), 0, (autocvar_g_turrets_unit_walker_rocket_radius), self, world, (autocvar_g_turrets_unit_walker_rocket_force), DEATH_TURRET_WALK_ROCKET, world);
  93     remove (self);
  94 }
  95
  96 void walker_rocket_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
  97 {SELFPARAM();
  98     self.health = self.health - damage;
  99     self.velocity = self.velocity + vforce;
 100
 101     if (self.health <= 0)
 102         W_PrepareExplosionByDamage(self.owner, walker_rocket_explode);
 103 }
 104
 105 #define WALKER_ROCKET_MOVE movelib_move_simple(newdir, (autocvar_g_turrets_unit_walker_rocket_speed), (autocvar_g_turrets_unit_walker_rocket_turnrate)); UpdateCSQCProjectile(self)
 106 void walker_rocket_loop();
 107 void walker_rocket_think()
 108 {SELFPARAM();
 109     vector newdir;
 110     float edist;
 111     float itime;
 112     float m_speed;
 113
 114     self.nextthink = time;
 115
 116     edist = vlen(self.enemy.origin - self.origin);
 117
 118     // Simulate crude guidance
 119     if (self.cnt < time)
 120     {
 121         if (edist < 1000)
 122             self.tur_shotorg = randomvec() * min(edist, 64);
 123         else
 124             self.tur_shotorg = randomvec() * min(edist, 256);
 125
 126         self.cnt = time + 0.5;
 127     }
 128
 129     if (edist < 128)
 130         self.tur_shotorg = '0 0 0';
 131
 132     if (self.max_health < time)
 133     {
 134         self.think        = walker_rocket_explode;
 135         self.nextthink  = time;
 136         return;
 137     }
 138
 139     if (self.shot_dmg != 1337 && random() < 0.01)
 140     {
 141         walker_rocket_loop();
 142         return;
 143     }
 144
 145     m_speed = vlen(self.velocity);
 146
 147     // Enemy dead? just keep on the current heading then.
 148     if (self.enemy == world || self.enemy.deadflag != DEAD_NO)
 149         self.enemy = world;
 150
 151     if (self.enemy)
 152     {
 153         itime = max(edist / m_speed, 1);
 154         newdir = steerlib_pull(self.enemy.origin + self.tur_shotorg);
 155     }
 156     else
 157         newdir  = normalize(self.velocity);
 158
 159     WALKER_ROCKET_MOVE;
 160 }
 161
 162 void walker_rocket_loop3()
 163 {SELFPARAM();
 164     vector newdir;
 165     self.nextthink = time;
 166
 167     if (self.max_health < time)
 168     {
 169         self.think = walker_rocket_explode;
 170         return;
 171     }
 172
 173     if (vlen(self.origin - self.tur_shotorg) < 100 )
 174     {
 175         self.think = walker_rocket_think;
 176         return;
 177     }
 178
 179     newdir = steerlib_pull(self.tur_shotorg);
 180     WALKER_ROCKET_MOVE;
 181
 182     self.angles = vectoangles(self.velocity);
 183 }
 184
 185 void walker_rocket_loop2()
 186 {SELFPARAM();
 187     vector newdir;
 188
 189     self.nextthink = time;
 190
 191     if (self.max_health < time)
 192     {
 193         self.think = walker_rocket_explode;
 194         return;
 195     }
 196
 197     if (vlen(self.origin - self.tur_shotorg) < 100 )
 198     {
 199         self.tur_shotorg = self.origin - '0 0 200';
 200         self.think = walker_rocket_loop3;
 201         return;
 202     }
 203
 204     newdir = steerlib_pull(self.tur_shotorg);
 205     WALKER_ROCKET_MOVE;
 206 }
 207
 208 void walker_rocket_loop()
 209 {SELFPARAM();
 210     self.nextthink = time;
 211     self.tur_shotorg = self.origin + '0 0 300';
 212     self.think = walker_rocket_loop2;
 213     self.shot_dmg = 1337;
 214 }
 215
 216 void walker_fire_rocket(vector org)
 217 {SELFPARAM();
 218     entity rocket;
 219
 220     fixedmakevectors(self.angles);
 221
 222     te_explosion (org);
 223
 224     rocket = spawn ();
 225     setorigin(rocket, org);
 226
 227     sound (self, CH_WEAPON_A, SND_HAGAR_FIRE, VOL_BASE, ATTEN_NORM);
 228     setsize (rocket, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 229
 230     rocket.classname              = "walker_rocket";
 231     rocket.owner                          = self;
 232     rocket.bot_dodge              = true;
 233     rocket.bot_dodgerating      = 50;
 234     rocket.takedamage            = DAMAGE_YES;
 235     rocket.damageforcescale   = 2;
 236     rocket.health                        = 25;
 237     rocket.tur_shotorg          = randomvec() * 512;
 238     rocket.cnt                          = time + 1;
 239     rocket.enemy                          = self.enemy;
 240
 241     if (random() < 0.01)
 242         rocket.think              = walker_rocket_loop;
 243     else
 244         rocket.think              = walker_rocket_think;
 245
 246     rocket.event_damage    = walker_rocket_damage;
 247
 248     rocket.nextthink              = time;
 249     rocket.movetype                = MOVETYPE_FLY;
 250     rocket.velocity                = normalize((v_forward + v_up * 0.5) + (randomvec() * 0.2)) * (autocvar_g_turrets_unit_walker_rocket_speed);
 251     rocket.angles                        = vectoangles(rocket.velocity);
 252     rocket.touch                          = walker_rocket_explode;
 253     rocket.flags                          = FL_PROJECTILE;
 254     rocket.solid                          = SOLID_BBOX;
 255     rocket.max_health            = time + 9;
 256     rocket.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_GUIDED_HEAT;
 257
 258     CSQCProjectile(rocket, false, PROJECTILE_ROCKET, false); // no culling, has fly sound
 259 }
 260
 261 .vector enemy_last_loc;
 262 .float enemy_last_time;
 263 void walker_move_to(vector _target, float _dist)
 264 {SELFPARAM();
 265     switch (self.waterlevel)
 266     {
 267         case WATERLEVEL_NONE:
 268             if (_dist > 500)
 269                 self.animflag = ANIM_RUN;
 270             else
 271                 self.animflag = ANIM_WALK;
 272         case WATERLEVEL_WETFEET:
 273         case WATERLEVEL_SWIMMING:
 274             if (self.animflag != ANIM_SWIM)
 275                 self.animflag = ANIM_WALK;
 276             else
 277                 self.animflag = ANIM_SWIM;
 278             break;
 279         case WATERLEVEL_SUBMERGED:
 280             self.animflag = ANIM_SWIM;
 281     }
 282
 283     self.moveto = _target;
 284     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 285
 286     if(self.enemy)
 287     {
 288         self.enemy_last_loc = _target;
 289         self.enemy_last_time = time;
 290     }
 291 }
 292
 293 //#define WALKER_FANCYPATHING
 294
 295 void walker_move_path()
 296 {SELFPARAM();
 297 #ifdef WALKER_FANCYPATHING
 298     // Are we close enougth to a path node to switch to the next?
 299     if (vlen(self.origin  - self.pathcurrent.origin) < 64)
 300         if (self.pathcurrent.path_next == world)
 301         {
 302             // Path endpoint reached
 303             pathlib_deletepath(self.pathcurrent.owner);
 304             self.pathcurrent = world;
 305
 306             if (self.pathgoal)
 307             {
 308                 if (self.pathgoal.use)
 309                     self.pathgoal.use();
 310
 311                 if (self.pathgoal.enemy)
 312                 {
 313                     self.pathcurrent = WALKER_PATH(self.pathgoal.origin,self.pathgoal.enemy.origin);
 314                     self.pathgoal = self.pathgoal.enemy;
 315                 }
 316             }
 317             else
 318                 self.pathgoal = world;
 319         }
 320         else
 321             self.pathcurrent = self.pathcurrent.path_next;
 322
 323     self.moveto = self.pathcurrent.origin;
 324     self.steerto = steerlib_attract2(self.moveto,0.5,500,0.95);
 325     walker_move_to(self.moveto, 0);
 326
 327 #else
 328     if (vlen(self.origin - self.pathcurrent.origin) < 64)
 329         self.pathcurrent = self.pathcurrent.enemy;
 330
 331     if(!self.pathcurrent)
 332         return;
 333
 334     self.moveto = self.pathcurrent.origin;
 335     self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 336     walker_move_to(self.moveto, 0);
 337 #endif
 338 }
 339
 340 void spawnfunc_turret_walker() { SELFPARAM(); if(!turret_initialize(TUR_WALKER.m_id)) remove(self); }
 341
 342 float t_walker(float req)
 343 {SELFPARAM();
 344     switch(req)
 345     {
 346         case TR_ATTACK:
 347         {
 348             sound (self, CH_WEAPON_A, SND_UZI_FIRE, VOL_BASE, ATTEN_NORM);
 349             fireBullet (self.tur_shotorg, self.tur_shotdir_updated, self.shot_spread, 0, self.shot_dmg, self.shot_force, DEATH_TURRET_WALK_GUN, 0);
 350             Send_Effect(EFFECT_BLASTER_MUZZLEFLASH, self.tur_shotorg, self.tur_shotdir_updated * 1000, 1);
 351
 352             return true;
 353         }
 354         case TR_THINK:
 355         {
 356             fixedmakevectors(self.angles);
 357
 358             if (self.spawnflags & TSF_NO_PATHBREAK && self.pathcurrent)
 359                 walker_move_path();
 360             else if (self.enemy == world)
 361             {
 362                 if(self.pathcurrent)
 363                     walker_move_path();
 364                 else
 365                 {
 366                     if(self.enemy_last_time != 0)
 367                     {
 368                         if(vlen(self.origin - self.enemy_last_loc) < 128 || time - self.enemy_last_time > 10)
 369                             self.enemy_last_time = 0;
 370                         else
 371                             walker_move_to(self.enemy_last_loc, 0);
 372                     }
 373                     else
 374                     {
 375                         if(self.animflag != ANIM_NO)
 376                         {
 377                             traceline(self.origin + '0 0 64', self.origin + '0 0 64' + v_forward * 128, MOVE_NORMAL, self);
 378
 379                             if(trace_fraction != 1.0)
 380                                 self.tur_head.idletime = -1337;
 381                             else
 382                             {
 383                                 traceline(trace_endpos, trace_endpos - '0 0 256', MOVE_NORMAL, self);
 384                                 if(trace_fraction == 1.0)
 385                                     self.tur_head.idletime = -1337;
 386                             }
 387
 388                             if(self.tur_head.idletime == -1337)
 389                             {
 390                                 self.moveto = self.origin + randomvec() * 256;
 391                                 self.tur_head.idletime = 0;
 392                             }
 393
 394                             self.moveto = self.moveto * 0.9 + ((self.origin + v_forward * 500) + randomvec() * 400) * 0.1;
 395                             self.moveto_z = self.origin_z + 64;
 396                             walker_move_to(self.moveto, 0);
 397                         }
 398
 399                         if(self.idletime < time)
 400                         {
 401                             if(random() < 0.5 || !(self.spawnflags & TSL_ROAM))
 402                             {
 403                                 self.idletime = time + 1 + random() * 5;
 404                                 self.moveto = self.origin;
 405                                 self.animflag = ANIM_NO;
 406                             }
 407                             else
 408                             {
 409                                 self.animflag = ANIM_WALK;
 410                                 self.idletime = time + 4 + random() * 2;
 411                                 self.moveto = self.origin + randomvec() * 256;
 412                                 self.tur_head.moveto = self.moveto;
 413                                 self.tur_head.idletime = 0;
 414                             }
 415                         }
 416                     }
 417                 }
 418             }
 419             else
 420             {
 421                 if (self.tur_dist_enemy < (autocvar_g_turrets_unit_walker_melee_range) && self.animflag != ANIM_MELEE)
 422                 {
 423                     vector wish_angle;
 424
 425                     wish_angle = angleofs(self, self.enemy);
 426                     if (self.animflag != ANIM_SWIM)
 427                     if (fabs(wish_angle_y) < 15)
 428                     {
 429                         self.moveto   = self.enemy.origin;
 430                         self.steerto  = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 431                         self.animflag = ANIM_MELEE;
 432                     }
 433                 }
 434                 else if (self.tur_head.attack_finished_single < time)
 435                 {
 436                     if(self.tur_head.shot_volly)
 437                     {
 438                         self.animflag = ANIM_NO;
 439
 440                         self.tur_head.shot_volly = self.tur_head.shot_volly -1;
 441                         if(self.tur_head.shot_volly == 0)
 442                             self.tur_head.attack_finished_single = time + (autocvar_g_turrets_unit_walker_rocket_refire);
 443                         else
 444                             self.tur_head.attack_finished_single = time + 0.2;
 445
 446                         if(self.tur_head.shot_volly > 1)
 447                             walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket01")));
 448                         else
 449                             walker_fire_rocket(gettaginfo(self, gettagindex(self, "tag_rocket02")));
 450                     }
 451                     else
 452                     {
 453                         if (self.tur_dist_enemy > (autocvar_g_turrets_unit_walker_rocket_range_min))
 454                         if (self.tur_dist_enemy < (autocvar_g_turrets_unit_walker_rocket_range))
 455                             self.tur_head.shot_volly = 4;
 456                     }
 457                 }
 458                 else
 459                 {
 460                     if (self.animflag != ANIM_MELEE)
 461                         walker_move_to(self.enemy.origin, self.tur_dist_enemy);
 462                 }
 463             }
 464
 465             {
 466                 vector real_angle;
 467                 float turny = 0, turnx = 0;
 468                 float vz;
 469
 470                 real_angle = vectoangles(self.steerto) - self.angles;
 471                 vz = self.velocity_z;
 472
 473                 switch (self.animflag)
 474                 {
 475                     case ANIM_NO:
 476                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 477                         break;
 478
 479                     case ANIM_TURN:
 480                         turny = (autocvar_g_turrets_unit_walker_turn);
 481                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 482                         break;
 483
 484                     case ANIM_WALK:
 485                         turny = (autocvar_g_turrets_unit_walker_turn_walk);
 486                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_walk), 0.6);
 487                         break;
 488
 489                     case ANIM_RUN:
 490                         turny = (autocvar_g_turrets_unit_walker_turn_run);
 491                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_run), 0.6);
 492                         break;
 493
 494                     case ANIM_STRAFE_L:
 495                         turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 496                         movelib_move_simple(v_right * -1, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 497                         break;
 498
 499                     case ANIM_STRAFE_R:
 500                         turny = (autocvar_g_turrets_unit_walker_turn_strafe);
 501                         movelib_move_simple(v_right, (autocvar_g_turrets_unit_walker_speed_walk), 0.8);
 502                         break;
 503
 504                     case ANIM_JUMP:
 505                         self.velocity += '0 0 1' * (autocvar_g_turrets_unit_walker_speed_jump);
 506                         break;
 507
 508                     case ANIM_LAND:
 509                         break;
 510
 511                     case ANIM_PAIN:
 512                         if(self.frame != ANIM_PAIN)
 513                             defer(0.25, walker_setnoanim);
 514
 515                         break;
 516
 517                     case ANIM_MELEE:
 518                         if(self.frame != ANIM_MELEE)
 519                         {
 520                             defer(0.41, walker_setnoanim);
 521                             defer(0.21, walker_melee_do_dmg);
 522                         }
 523
 524                         movelib_beak_simple((autocvar_g_turrets_unit_walker_speed_stop));
 525                         break;
 526
 527                     case ANIM_SWIM:
 528                         turny = (autocvar_g_turrets_unit_walker_turn_swim);
 529                         turnx = (autocvar_g_turrets_unit_walker_turn_swim);
 530
 531                         self.angles_x += bound(-10, shortangle_f(real_angle_x, self.angles_x), 10);
 532                         movelib_move_simple(v_forward, (autocvar_g_turrets_unit_walker_speed_swim), 0.3);
 533                         vz = self.velocity_z + sin(time * 4) * 8;
 534                         break;
 535
 536                     case ANIM_ROAM:
 537                         turny = (autocvar_g_turrets_unit_walker_turn_walk);
 538                         movelib_move_simple(v_forward ,(autocvar_g_turrets_unit_walker_speed_roam), 0.5);
 539                         break;
 540                 }
 541
 542                 if(turny)
 543                 {
 544                     turny = bound( turny * -1, shortangle_f(real_angle_y, self.angles_y), turny );
 545                     self.angles_y += turny;
 546                 }
 547
 548                 if(turnx)
 549                 {
 550                     turnx = bound( turnx * -1, shortangle_f(real_angle_x, self.angles_x), turnx );
 551                     self.angles_x += turnx;
 552                 }
 553
 554                 self.velocity_z = vz;
 555             }
 556
 557
 558             if(self.origin != self.oldorigin)
 559                 self.SendFlags |= TNSF_MOVE;
 560
 561             self.oldorigin = self.origin;
 562             turrets_setframe(self.animflag, false);
 563
 564             return true;
 565         }
 566         case TR_DEATH:
 567         {
 568 #ifdef WALKER_FANCYPATHING
 569             if (self.pathcurrent)
 570                 pathlib_deletepath(self.pathcurrent.owner);
 571 #endif
 572             self.pathcurrent = world;
 573
 574             return true;
 575         }
 576         case TR_SETUP:
 577         {
 578             self.ticrate = 0.05;
 579
 580             entity e;
 581
 582             // Respawn is called & first spawn to, to set team. need to make sure we do not move the initial spawn.
 583             if(self.movetype == MOVETYPE_WALK)
 584             {
 585                 if(self.pos1)
 586                     setorigin(self, self.pos1);
 587                 if(self.pos2)
 588                     self.angles = self.pos2;
 589             }
 590
 591             self.ammo_flags = TFL_AMMO_BULLETS | TFL_AMMO_RECHARGE | TFL_AMMO_RECIEVE;
 592             self.aim_flags = TFL_AIM_LEAD;
 593             self.turret_flags |= TUR_FLAG_HITSCAN;
 594
 595             self.target_select_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 596             self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_RANGELIMITS | TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_LOS;
 597             self.iscreature = true;
 598             self.teleportable = TELEPORT_NORMAL;
 599             self.damagedbycontents = true;
 600             self.solid = SOLID_SLIDEBOX;
 601             self.takedamage = DAMAGE_AIM;
 602             if(self.movetype != MOVETYPE_WALK)
 603             {
 604                 setorigin(self, self.origin);
 605                 tracebox(self.origin + '0 0 128', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_NORMAL, self);
 606                 setorigin(self, trace_endpos + '0 0 4');
 607                 self.pos1 = self.origin;
 608                 self.pos2 = self.angles;
 609             }
 610             self.movetype = MOVETYPE_WALK;
 611             self.idle_aim = '0 0 0';
 612             self.turret_firecheckfunc = walker_firecheck;
 613
 614             if (self.target != "")
 615             {
 616                 e = find(world, targetname, self.target);
 617                 if (!e)
 618                 {
 619                     LOG_TRACE("Initital waypoint for walker does NOT exsist, fix your map!\n");
 620                     self.target = "";
 621                 }
 622
 623                 if (e.classname != "turret_checkpoint")
 624                     LOG_TRACE("Warning: not a turrret path\n");
 625                 else
 626                 {
 627 #ifdef WALKER_FANCYPATHING
 628                     self.pathcurrent = WALKER_PATH(self.origin, e.origin);
 629                     self.pathgoal = e;
 630 #else
 631                     self.pathcurrent = e;
 632 #endif
 633                 }
 634             }
 635
 636             return true;
 637         }
 638         case TR_PRECACHE:
 639         {
 640             return true;
 641         }
 642     }
 643
 644     return true;
 645 }
 646
 647 #endif // SVQC
 648 #ifdef CSQC
 649
 650 #include "../../../client/movelib.qh"
 651
 652 void walker_draw()
 653 {SELFPARAM();
 654     float dt;
 655
 656     dt = time - self.move_time;
 657     self.move_time = time;
 658     if(dt <= 0)
 659         return;
 660
 661     fixedmakevectors(self.angles);
 662     movelib_groundalign4point(300, 100, 0.25, 45);
 663     setorigin(self, self.origin + self.velocity * dt);
 664     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 665     self.angles_y = self.move_angles_y;
 666
 667     if (self.health < 127)
 668     if(random() < 0.15)
 669         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 670 }
 671
 672 float t_walker(float req)
 673 {SELFPARAM();
 674     switch(req)
 675     {
 676         case TR_SETUP:
 677         {
 678             self.gravity                = 1;
 679             self.movetype               = MOVETYPE_BOUNCE;
 680             self.move_movetype  = MOVETYPE_BOUNCE;
 681             self.move_origin    = self.origin;
 682             self.move_time              = time;
 683             self.draw                   = walker_draw;
 684
 685             return true;
 686         }
 687         case TR_PRECACHE:
 688         {
 689             return true;
 690         }
 691     }
 692
 693     return true;
 694 }
 695
 696 #endif // CSQC
 697 #endif // REGISTER_TURRET