qcsrc/common/util.qc

   1 string wordwrap_buffer;
   2
   3 void wordwrap_buffer_put(string s)
   4 {
   5         wordwrap_buffer = strcat(wordwrap_buffer, s);
   6 }
   7
   8 string wordwrap(string s, float l)
   9 {
  10         string r;
  11         wordwrap_buffer = "";
  12         wordwrap_cb(s, l, wordwrap_buffer_put);
  13         r = wordwrap_buffer;
  14         wordwrap_buffer = "";
  15         return r;
  16 }
  17
  18 #ifndef MENUQC
  19 #ifndef CSQC
  20 void wordwrap_buffer_sprint(string s)
  21 {
  22         wordwrap_buffer = strcat(wordwrap_buffer, s);
  23         if(s == "\n")
  24         {
  25                 sprint(self, wordwrap_buffer);
  26                 wordwrap_buffer = "";
  27         }
  28 }
  29
  30 void wordwrap_sprint(string s, float l)
  31 {
  32         wordwrap_buffer = "";
  33         wordwrap_cb(s, l, wordwrap_buffer_sprint);
  34         if(wordwrap_buffer != "")
  35                 sprint(self, strcat(wordwrap_buffer, "\n"));
  36         wordwrap_buffer = "";
  37         return;
  38 }
  39 #endif
  40 #endif
  41
  42 #ifndef SVQC
  43 string draw_UseSkinFor(string pic)
  44 {
  45         if(substring(pic, 0, 1) == "/")
  46                 return substring(pic, 1, strlen(pic)-1);
  47         else
  48                 return strcat(draw_currentSkin, "/", pic);
  49 }
  50 #endif
  51
  52 string unescape(string in)
  53 {
  54         float i, len;
  55         string str, s;
  56
  57         // but it doesn't seem to be necessary in my tests at least
  58         in = strzone(in);
  59
  60         len = strlen(in);
  61         str = "";
  62         for(i = 0; i < len; ++i)
  63         {
  64                 s = substring(in, i, 1);
  65                 if(s == "\\")
  66                 {
  67                         s = substring(in, i+1, 1);
  68                         if(s == "n")
  69                                 str = strcat(str, "\n");
  70                         else if(s == "\\")
  71                                 str = strcat(str, "\\");
  72                         else
  73                                 str = strcat(str, substring(in, i, 2));
  74                         ++i;
  75                 } else
  76                         str = strcat(str, s);
  77         }
  78
  79         strunzone(in);
  80         return str;
  81 }
  82
  83 void wordwrap_cb(string s, float l, void(string) callback)
  84 {
  85         string c;
  86         float lleft, i, j, wlen;
  87
  88         s = strzone(s);
  89         lleft = l;
  90         for (i = 0;i < strlen(s);++i)
  91         {
  92                 if (substring(s, i, 2) == "\\n")
  93                 {
  94                         callback("\n");
  95                         lleft = l;
  96                         ++i;
  97                 }
  98                 else if (substring(s, i, 1) == "\n")
  99                 {
 100                         callback("\n");
 101                         lleft = l;
 102                 }
 103                 else if (substring(s, i, 1) == " ")
 104                 {
 105                         if (lleft > 0)
 106                         {
 107                                 callback(" ");
 108                                 lleft = lleft - 1;
 109                         }
 110                 }
 111                 else
 112                 {
 113                         for (j = i+1;j < strlen(s);++j)
 114                                 //    ^^ this skips over the first character of a word, which
 115                                 //       is ALWAYS part of the word
 116                                 //       this is safe since if i+1 == strlen(s), i will become
 117                                 //       strlen(s)-1 at the end of this block and the function
 118                                 //       will terminate. A space can't be the first character we
 119                                 //       read here, and neither can a \n be the start, since these
 120                                 //       two cases have been handled above.
 121                         {
 122                                 c = substring(s, j, 1);
 123                                 if (c == " ")
 124                                         break;
 125                                 if (c == "\\")
 126                                         break;
 127                                 if (c == "\n")
 128                                         break;
 129                                 // we need to keep this tempstring alive even if substring is
 130                                 // called repeatedly, so call strcat even though we're not
 131                                 // doing anything
 132                                 callback("");
 133                         }
 134                         wlen = j - i;
 135                         if (lleft < wlen)
 136                         {
 137                                 callback("\n");
 138                                 lleft = l;
 139                         }
 140                         callback(substring(s, i, wlen));
 141                         lleft = lleft - wlen;
 142                         i = j - 1;
 143                 }
 144         }
 145         strunzone(s);
 146 }
 147
 148 float dist_point_line(vector p, vector l0, vector ldir)
 149 {
 150         ldir = normalize(ldir);
 151
 152         // remove the component in line direction
 153         p = p - (p * ldir) * ldir;
 154
 155         // vlen of the remaining vector
 156         return vlen(p);
 157 }
 158
 159 void depthfirst(entity start, .entity up, .entity downleft, .entity right, void(entity, entity) funcPre, void(entity, entity) funcPost, entity pass)
 160 {
 161         entity e;
 162         e = start;
 163         funcPre(pass, e);
 164         while(e.downleft)
 165         {
 166                 e = e.downleft;
 167                 funcPre(pass, e);
 168         }
 169         funcPost(pass, e);
 170         while(e != start)
 171         {
 172                 if(e.right)
 173                 {
 174                         e = e.right;
 175                         funcPre(pass, e);
 176                         while(e.downleft)
 177                         {
 178                                 e = e.downleft;
 179                                 funcPre(pass, e);
 180                         }
 181                 }
 182                 else
 183                         e = e.up;
 184                 funcPost(pass, e);
 185         }
 186 }
 187
 188 float median(float a, float b, float c)
 189 {
 190         if(a < c)
 191                 return bound(a, b, c);
 192         return bound(c, b, a);
 193 }
 194
 195 // converts a number to a string with the indicated number of decimals
 196 // works for up to 10 decimals!
 197 string ftos_decimals(float number, float decimals)
 198 {
 199         // inhibit stupid negative zero
 200         if(number == 0)
 201                 number = 0;
 202         // we have sprintf...
 203         return sprintf("%.*f", decimals, number);
 204 }
 205
 206 float time;
 207 vector colormapPaletteColor(float c, float isPants)
 208 {
 209         switch(c)
 210         {
 211                 case  0: return '1.000000 1.000000 1.000000';
 212                 case  1: return '1.000000 0.333333 0.000000';
 213                 case  2: return '0.000000 1.000000 0.501961';
 214                 case  3: return '0.000000 1.000000 0.000000';
 215                 case  4: return '1.000000 0.000000 0.000000';
 216                 case  5: return '0.000000 0.666667 1.000000';
 217                 case  6: return '0.000000 1.000000 1.000000';
 218                 case  7: return '0.501961 1.000000 0.000000';
 219                 case  8: return '0.501961 0.000000 1.000000';
 220                 case  9: return '1.000000 0.000000 1.000000';
 221                 case 10: return '1.000000 0.000000 0.501961';
 222                 case 11: return '0.000000 0.000000 1.000000';
 223                 case 12: return '1.000000 1.000000 0.000000';
 224                 case 13: return '0.000000 0.333333 1.000000';
 225                 case 14: return '1.000000 0.666667 0.000000';
 226                 case 15:
 227                         if(isPants)
 228                                 return
 229                                           '1 0 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 0.0000000000))
 230                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 2.7182818285 + 2.0943951024))
 231                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 2.7182818285 + 4.1887902048));
 232                         else
 233                                 return
 234                                           '1 0 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 5.2359877560))
 235                                         + '0 1 0' * (0.502 + 0.498 * sin(time / 3.1415926536 + 3.1415926536))
 236                                         + '0 0 1' * (0.502 + 0.498 * sin(time / 3.1415926536 + 1.0471975512));
 237                 default: return '0.000 0.000 0.000';
 238         }
 239 }
 240
 241 // unzone the string, and return it as tempstring. Safe to be called on string_null
 242 string fstrunzone(string s)
 243 {
 244         string sc;
 245         if not(s)
 246                 return s;
 247         sc = strcat(s, "");
 248         strunzone(s);
 249         return sc;
 250 }
 251
 252 float fexists(string f)
 253 {
 254     float fh;
 255     fh = fopen(f, FILE_READ);
 256     if (fh < 0)
 257         return FALSE;
 258     fclose(fh);
 259     return TRUE;
 260 }
 261
 262 // Databases (hash tables)
 263 #define DB_BUCKETS 8192
 264 void db_save(float db, string pFilename)
 265 {
 266         float fh, i, n;
 267         fh = fopen(pFilename, FILE_WRITE);
 268         if(fh < 0)
 269         {
 270                 print(strcat("^1Can't write DB to ", pFilename));
 271                 return;
 272         }
 273         n = buf_getsize(db);
 274         fputs(fh, strcat(ftos(DB_BUCKETS), "\n"));
 275         for(i = 0; i < n; ++i)
 276                 fputs(fh, strcat(bufstr_get(db, i), "\n"));
 277         fclose(fh);
 278 }
 279
 280 float db_create()
 281 {
 282         return buf_create();
 283 }
 284
 285 float db_load(string pFilename)
 286 {
 287         float db, fh, i, j, n;
 288         string l;
 289         db = buf_create();
 290         if(db < 0)
 291                 return -1;
 292         fh = fopen(pFilename, FILE_READ);
 293         if(fh < 0)
 294                 return db;
 295         l = fgets(fh);
 296         if(stof(l) == DB_BUCKETS)
 297         {
 298                 i = 0;
 299                 while((l = fgets(fh)))
 300                 {
 301                         if(l != "")
 302                                 bufstr_set(db, i, l);
 303                         ++i;
 304                 }
 305         }
 306         else
 307         {
 308                 // different count of buckets, or a dump?
 309                 // need to reorganize the database then (SLOW)
 310                 //
 311                 // note: we also parse the first line (l) in case the DB file is
 312                 // missing the bucket count
 313                 do
 314                 {
 315                         n = tokenizebyseparator(l, "\\");
 316                         for(j = 2; j < n; j += 2)
 317                                 db_put(db, argv(j-1), uri_unescape(argv(j)));
 318                 }
 319                 while((l = fgets(fh)));
 320         }
 321         fclose(fh);
 322         return db;
 323 }
 324
 325 void db_dump(float db, string pFilename)
 326 {
 327         float fh, i, j, n, m;
 328         fh = fopen(pFilename, FILE_WRITE);
 329         if(fh < 0)
 330                 error(strcat("Can't dump DB to ", pFilename));
 331         n = buf_getsize(db);
 332         fputs(fh, "0\n");
 333         for(i = 0; i < n; ++i)
 334         {
 335                 m = tokenizebyseparator(bufstr_get(db, i), "\\");
 336                 for(j = 2; j < m; j += 2)
 337                         fputs(fh, strcat("\\", argv(j-1), "\\", argv(j), "\n"));
 338         }
 339         fclose(fh);
 340 }
 341
 342 void db_close(float db)
 343 {
 344         buf_del(db);
 345 }
 346
 347 string db_get(float db, string pKey)
 348 {
 349         float h;
 350         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 351         return uri_unescape(infoget(bufstr_get(db, h), pKey));
 352 }
 353
 354 void db_put(float db, string pKey, string pValue)
 355 {
 356         float h;
 357         h = mod(crc16(FALSE, pKey), DB_BUCKETS);
 358         bufstr_set(db, h, infoadd(bufstr_get(db, h), pKey, uri_escape(pValue)));
 359 }
 360
 361 void db_test()
 362 {
 363         float db, i;
 364         print("LOAD...\n");
 365         db = db_load("foo.db");
 366         print("LOADED. FILL...\n");
 367         for(i = 0; i < DB_BUCKETS; ++i)
 368                 db_put(db, ftos(random()), "X");
 369         print("FILLED. SAVE...\n");
 370         db_save(db, "foo.db");
 371         print("SAVED. CLOSE...\n");
 372         db_close(db);
 373         print("CLOSED.\n");
 374 }
 375
 376 // Multiline text file buffers
 377 float buf_load(string pFilename)
 378 {
 379         float buf, fh, i;
 380         string l;
 381         buf = buf_create();
 382         if(buf < 0)
 383                 return -1;
 384         fh = fopen(pFilename, FILE_READ);
 385         if(fh < 0)
 386         {
 387                 buf_del(buf);
 388                 return -1;
 389         }
 390         i = 0;
 391         while((l = fgets(fh)))
 392         {
 393                 bufstr_set(buf, i, l);
 394                 ++i;
 395         }
 396         fclose(fh);
 397         return buf;
 398 }
 399
 400 void buf_save(float buf, string pFilename)
 401 {
 402         float fh, i, n;
 403         fh = fopen(pFilename, FILE_WRITE);
 404         if(fh < 0)
 405                 error(strcat("Can't write buf to ", pFilename));
 406         n = buf_getsize(buf);
 407         for(i = 0; i < n; ++i)
 408                 fputs(fh, strcat(bufstr_get(buf, i), "\n"));
 409         fclose(fh);
 410 }
 411
 412 string mmsss(float tenths)
 413 {
 414         float minutes;
 415         string s;
 416         tenths = floor(tenths + 0.5);
 417         minutes = floor(tenths / 600);
 418         tenths -= minutes * 600;
 419         s = ftos(1000 + tenths);
 420         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 1));
 421 }
 422
 423 string mmssss(float hundredths)
 424 {
 425         float minutes;
 426         string s;
 427         hundredths = floor(hundredths + 0.5);
 428         minutes = floor(hundredths / 6000);
 429         hundredths -= minutes * 6000;
 430         s = ftos(10000 + hundredths);
 431         return strcat(ftos(minutes), ":", substring(s, 1, 2), ".", substring(s, 3, 2));
 432 }
 433
 434 string ScoreString(float pFlags, float pValue)
 435 {
 436         string valstr;
 437         float l;
 438
 439         pValue = floor(pValue + 0.5); // round
 440
 441         if((pValue == 0) && (pFlags & (SFL_HIDE_ZERO | SFL_RANK | SFL_TIME)))
 442                 valstr = "";
 443         else if(pFlags & SFL_RANK)
 444         {
 445                 valstr = ftos(pValue);
 446                 l = strlen(valstr);
 447                 if((l >= 2) && (substring(valstr, l - 2, 1) == "1"))
 448                         valstr = strcat(valstr, "th");
 449                 else if(substring(valstr, l - 1, 1) == "1")
 450                         valstr = strcat(valstr, "st");
 451                 else if(substring(valstr, l - 1, 1) == "2")
 452                         valstr = strcat(valstr, "nd");
 453                 else if(substring(valstr, l - 1, 1) == "3")
 454                         valstr = strcat(valstr, "rd");
 455                 else
 456                         valstr = strcat(valstr, "th");
 457         }
 458         else if(pFlags & SFL_TIME)
 459                 valstr = TIME_ENCODED_TOSTRING(pValue);
 460         else
 461                 valstr = ftos(pValue);
 462
 463         return valstr;
 464 }
 465
 466 vector cross(vector a, vector b)
 467 {
 468         return
 469                 '1 0 0' * (a_y * b_z - a_z * b_y)
 470         +       '0 1 0' * (a_z * b_x - a_x * b_z)
 471         +       '0 0 1' * (a_x * b_y - a_y * b_x);
 472 }
 473
 474 // compressed vector format:
 475 // like MD3, just even shorter
 476 //   4 bit pitch (16 angles), 0 is -90, 8 is 0, 16 would be 90
 477 //   5 bit yaw (32 angles), 0=0, 8=90, 16=180, 24=270
 478 //   7 bit length (logarithmic encoding), 1/8 .. about 7844
 479 //     length = 2^(length_encoded/8) / 8
 480 // if pitch is 90, yaw does nothing and therefore indicates the sign (yaw is then either 11111 or 11110); 11111 is pointing DOWN
 481 // thus, valid values are from 0000.11110.0000000 to 1111.11111.1111111
 482 // the special value 0 indicates the zero vector
 483
 484 float lengthLogTable[128];
 485
 486 float invertLengthLog(float x)
 487 {
 488         float l, r, m, lerr, rerr;
 489
 490         if(x >= lengthLogTable[127])
 491                 return 127;
 492         if(x <= lengthLogTable[0])
 493                 return 0;
 494
 495         l = 0;
 496         r = 127;
 497
 498         while(r - l > 1)
 499         {
 500                 m = floor((l + r) / 2);
 501                 if(lengthLogTable[m] < x)
 502                         l = m;
 503                 else
 504                         r = m;
 505         }
 506
 507         // now: r is >=, l is <
 508         lerr = (x - lengthLogTable[l]);
 509         rerr = (lengthLogTable[r] - x);
 510         if(lerr < rerr)
 511                 return l;
 512         return r;
 513 }
 514
 515 vector decompressShortVector(float data)
 516 {
 517         vector out;
 518         float p, y, len;
 519         if(data == 0)
 520                 return '0 0 0';
 521         p   = (data & 0xF000) / 0x1000;
 522         y   = (data & 0x0F80) / 0x80;
 523         len = (data & 0x007F);
 524
 525         //print("\ndecompress: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 526
 527         if(p == 0)
 528         {
 529                 out_x = 0;
 530                 out_y = 0;
 531                 if(y == 31)
 532                         out_z = -1;
 533                 else
 534                         out_z = +1;
 535         }
 536         else
 537         {
 538                 y   = .19634954084936207740 * y;
 539                 p = .19634954084936207740 * p - 1.57079632679489661922;
 540                 out_x = cos(y) *  cos(p);
 541                 out_y = sin(y) *  cos(p);
 542                 out_z =          -sin(p);
 543         }
 544
 545         //print("decompressed: ", vtos(out), "\n");
 546
 547         return out * lengthLogTable[len];
 548 }
 549
 550 float compressShortVector(vector vec)
 551 {
 552         vector ang;
 553         float p, y, len;
 554         if(vlen(vec) == 0)
 555                 return 0;
 556         //print("compress: ", vtos(vec), "\n");
 557         ang = vectoangles(vec);
 558         ang_x = -ang_x;
 559         if(ang_x < -90)
 560                 ang_x += 360;
 561         if(ang_x < -90 && ang_x > +90)
 562                 error("BOGUS vectoangles");
 563         //print("angles: ", vtos(ang), "\n");
 564
 565         p = floor(0.5 + (ang_x + 90) * 16 / 180) & 15; // -90..90 to 0..14
 566         if(p == 0)
 567         {
 568                 if(vec_z < 0)
 569                         y = 31;
 570                 else
 571                         y = 30;
 572         }
 573         else
 574                 y = floor(0.5 + ang_y * 32 / 360)          & 31; // 0..360 to 0..32
 575         len = invertLengthLog(vlen(vec));
 576
 577         //print("compressed: p ", ftos(p)); print("y ", ftos(y)); print("len ", ftos(len), "\n");
 578
 579         return (p * 0x1000) + (y * 0x80) + len;
 580 }
 581
 582 void compressShortVector_init()
 583 {
 584         float l, f, i;
 585         l = 1;
 586         f = pow(2, 1/8);
 587         for(i = 0; i < 128; ++i)
 588         {
 589                 lengthLogTable[i] = l;
 590                 l *= f;
 591         }
 592
 593         if(cvar("developer"))
 594         {
 595                 print("Verifying vector compression table...\n");
 596                 for(i = 0x0F00; i < 0xFFFF; ++i)
 597                         if(i != compressShortVector(decompressShortVector(i)))
 598                         {
 599                                 print("BROKEN vector compression: ", ftos(i));
 600                                 print(" -> ", vtos(decompressShortVector(i)));
 601                                 print(" -> ", ftos(compressShortVector(decompressShortVector(i))));
 602                                 print("\n");
 603                                 error("b0rk");
 604                         }
 605                 print("Done.\n");
 606         }
 607 }
 608
 609 #ifndef MENUQC
 610 float CheckWireframeBox(entity forent, vector v0, vector dvx, vector dvy, vector dvz)
 611 {
 612         traceline(v0, v0 + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 613         traceline(v0, v0 + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 614         traceline(v0, v0 + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 615         traceline(v0 + dvx, v0 + dvx + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 616         traceline(v0 + dvx, v0 + dvx + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 617         traceline(v0 + dvy, v0 + dvy + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 618         traceline(v0 + dvy, v0 + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 619         traceline(v0 + dvz, v0 + dvz + dvx, TRUE, forent); if(trace_fraction < 1) return 0;
 620         traceline(v0 + dvz, v0 + dvz + dvy, TRUE, forent); if(trace_fraction < 1) return 0;
 621         traceline(v0 + dvx + dvy, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 622         traceline(v0 + dvx + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 623         traceline(v0 + dvy + dvz, v0 + dvx + dvy + dvz, TRUE, forent); if(trace_fraction < 1) return 0;
 624         return 1;
 625 }
 626 #endif
 627
 628 string fixPriorityList(string order, float from, float to, float subtract, float complete)
 629 {
 630         string neworder;
 631         float i, n, w;
 632
 633         n = tokenize_console(order);
 634         neworder = "";
 635         for(i = 0; i < n; ++i)
 636         {
 637                 w = stof(argv(i));
 638                 if(w == floor(w))
 639                 {
 640                         if(w >= from && w <= to)
 641                                 neworder = strcat(neworder, ftos(w), " ");
 642                         else
 643                         {
 644                                 w -= subtract;
 645                                 if(w >= from && w <= to)
 646                                         neworder = strcat(neworder, ftos(w), " ");
 647                         }
 648                 }
 649         }
 650
 651         if(complete)
 652         {
 653                 n = tokenize_console(neworder);
 654                 for(w = to; w >= from; --w)
 655                 {
 656                         for(i = 0; i < n; ++i)
 657                                 if(stof(argv(i)) == w)
 658                                         break;
 659                         if(i == n) // not found
 660                                 neworder = strcat(neworder, ftos(w), " ");
 661                 }
 662         }
 663
 664         return substring(neworder, 0, strlen(neworder) - 1);
 665 }
 666
 667 string mapPriorityList(string order, string(string) mapfunc)
 668 {
 669         string neworder;
 670         float i, n;
 671
 672         n = tokenize_console(order);
 673         neworder = "";
 674         for(i = 0; i < n; ++i)
 675                 neworder = strcat(neworder, mapfunc(argv(i)), " ");
 676
 677         return substring(neworder, 0, strlen(neworder) - 1);
 678 }
 679
 680 string swapInPriorityList(string order, float i, float j)
 681 {
 682         string s;
 683         float w, n;
 684
 685         n = tokenize_console(order);
 686
 687         if(i >= 0 && i < n && j >= 0 && j < n && i != j)
 688         {
 689                 s = "";
 690                 for(w = 0; w < n; ++w)
 691                 {
 692                         if(w == i)
 693                                 s = strcat(s, argv(j), " ");
 694                         else if(w == j)
 695                                 s = strcat(s, argv(i), " ");
 696                         else
 697                                 s = strcat(s, argv(w), " ");
 698                 }
 699                 return substring(s, 0, strlen(s) - 1);
 700         }
 701
 702         return order;
 703 }
 704
 705 float cvar_value_issafe(string s)
 706 {
 707         if(strstrofs(s, "\"", 0) >= 0)
 708                 return 0;
 709         if(strstrofs(s, "\\", 0) >= 0)
 710                 return 0;
 711         if(strstrofs(s, ";", 0) >= 0)
 712                 return 0;
 713         if(strstrofs(s, "$", 0) >= 0)
 714                 return 0;
 715         if(strstrofs(s, "\r", 0) >= 0)
 716                 return 0;
 717         if(strstrofs(s, "\n", 0) >= 0)
 718                 return 0;
 719         return 1;
 720 }
 721
 722 #ifndef MENUQC
 723 void get_mi_min_max(float mode)
 724 {
 725         vector mi, ma;
 726
 727         if(mi_shortname)
 728                 strunzone(mi_shortname);
 729         mi_shortname = mapname;
 730         if(!strcasecmp(substring(mi_shortname, 0, 5), "maps/"))
 731                 mi_shortname = substring(mi_shortname, 5, strlen(mi_shortname) - 5);
 732         if(!strcasecmp(substring(mi_shortname, strlen(mi_shortname) - 4, 4), ".bsp"))
 733                 mi_shortname = substring(mi_shortname, 0, strlen(mi_shortname) - 4);
 734         mi_shortname = strzone(mi_shortname);
 735
 736 #ifdef CSQC
 737         mi = world.mins;
 738         ma = world.maxs;
 739 #else
 740         mi = world.absmin;
 741         ma = world.absmax;
 742 #endif
 743
 744         mi_min = mi;
 745         mi_max = ma;
 746         MapInfo_Get_ByName(mi_shortname, 0, 0);
 747         if(MapInfo_Map_mins_x < MapInfo_Map_maxs_x)
 748         {
 749                 mi_min = MapInfo_Map_mins;
 750                 mi_max = MapInfo_Map_maxs;
 751         }
 752         else
 753         {
 754                 // not specified
 755                 if(mode)
 756                 {
 757                         // be clever
 758                         tracebox('1 0 0' * mi_x,
 759                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 760                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 761                                          '1 0 0' * ma_x,
 762                                          MOVE_WORLDONLY,
 763                                          world);
 764                         if(!trace_startsolid)
 765                                 mi_min_x = trace_endpos_x;
 766
 767                         tracebox('0 1 0' * mi_y,
 768                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 769                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 770                                          '0 1 0' * ma_y,
 771                                          MOVE_WORLDONLY,
 772                                          world);
 773                         if(!trace_startsolid)
 774                                 mi_min_y = trace_endpos_y;
 775
 776                         tracebox('0 0 1' * mi_z,
 777                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 778                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 779                                          '0 0 1' * ma_z,
 780                                          MOVE_WORLDONLY,
 781                                          world);
 782                         if(!trace_startsolid)
 783                                 mi_min_z = trace_endpos_z;
 784
 785                         tracebox('1 0 0' * ma_x,
 786                                          '0 1 0' * mi_y + '0 0 1' * mi_z,
 787                                          '0 1 0' * ma_y + '0 0 1' * ma_z,
 788                                          '1 0 0' * mi_x,
 789                                          MOVE_WORLDONLY,
 790                                          world);
 791                         if(!trace_startsolid)
 792                                 mi_max_x = trace_endpos_x;
 793
 794                         tracebox('0 1 0' * ma_y,
 795                                          '1 0 0' * mi_x + '0 0 1' * mi_z,
 796                                          '1 0 0' * ma_x + '0 0 1' * ma_z,
 797                                          '0 1 0' * mi_y,
 798                                          MOVE_WORLDONLY,
 799                                          world);
 800                         if(!trace_startsolid)
 801                                 mi_max_y = trace_endpos_y;
 802
 803                         tracebox('0 0 1' * ma_z,
 804                                          '1 0 0' * mi_x + '0 1 0' * mi_y,
 805                                          '1 0 0' * ma_x + '0 1 0' * ma_y,
 806                                          '0 0 1' * mi_z,
 807                                          MOVE_WORLDONLY,
 808                                          world);
 809                         if(!trace_startsolid)
 810                                 mi_max_z = trace_endpos_z;
 811                 }
 812         }
 813 }
 814
 815 void get_mi_min_max_texcoords(float mode)
 816 {
 817         vector extend;
 818
 819         get_mi_min_max(mode);
 820
 821         mi_picmin = mi_min;
 822         mi_picmax = mi_max;
 823
 824         // extend mi_picmax to get a square aspect ratio
 825         // center the map in that area
 826         extend = mi_picmax - mi_picmin;
 827         if(extend_y > extend_x)
 828         {
 829                 mi_picmin_x -= (extend_y - extend_x) * 0.5;
 830                 mi_picmax_x += (extend_y - extend_x) * 0.5;
 831         }
 832         else
 833         {
 834                 mi_picmin_y -= (extend_x - extend_y) * 0.5;
 835                 mi_picmax_y += (extend_x - extend_y) * 0.5;
 836         }
 837
 838         // add another some percent
 839         extend = (mi_picmax - mi_picmin) * (1 / 64.0);
 840         mi_picmin -= extend;
 841         mi_picmax += extend;
 842
 843         // calculate the texcoords
 844         mi_pictexcoord0 = mi_pictexcoord1 = mi_pictexcoord2 = mi_pictexcoord3 = '0 0 0';
 845         // first the two corners of the origin
 846         mi_pictexcoord0_x = (mi_min_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 847         mi_pictexcoord0_y = (mi_min_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 848         mi_pictexcoord2_x = (mi_max_x - mi_picmin_x) / (mi_picmax_x - mi_picmin_x);
 849         mi_pictexcoord2_y = (mi_max_y - mi_picmin_y) / (mi_picmax_y - mi_picmin_y);
 850         // then the other corners
 851         mi_pictexcoord1_x = mi_pictexcoord0_x;
 852         mi_pictexcoord1_y = mi_pictexcoord2_y;
 853         mi_pictexcoord3_x = mi_pictexcoord2_x;
 854         mi_pictexcoord3_y = mi_pictexcoord0_y;
 855 }
 856 #endif
 857
 858 float cvar_settemp(string tmp_cvar, string tmp_value)
 859 {
 860         float created_saved_value;
 861         entity e;
 862
 863         created_saved_value = FALSE;
 864
 865         if not(tmp_cvar || tmp_value)
 866         {
 867                 dprint("Error: Invalid usage of cvar_settemp(string, string); !\n");
 868                 return FALSE;
 869         }
 870
 871         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
 872                 if(e.netname == tmp_cvar)
 873                         goto saved; // skip creation
 874
 875         // creating a new entity to keep track of this cvar
 876         e = spawn();
 877         e.classname = "saved_cvar_value";
 878         e.netname = strzone(tmp_cvar);
 879         e.message = strzone(cvar_string(tmp_cvar));
 880         created_saved_value = TRUE;
 881
 882         // an entity for this cvar already exists
 883         :saved
 884
 885         // update the cvar to the value given
 886         cvar_set(tmp_cvar, tmp_value);
 887
 888         return created_saved_value;
 889 }
 890
 891 float cvar_settemp_restore()
 892 {
 893         float i;
 894         entity e;
 895         while((e = find(world, classname, "saved_cvar_value")))
 896         {
 897                 cvar_set(e.netname, e.message);
 898                 remove(e);
 899         }
 900
 901         return i;
 902 }
 903
 904 float almost_equals(float a, float b)
 905 {
 906         float eps;
 907         eps = (max(a, -a) + max(b, -b)) * 0.001;
 908         if(a - b < eps && b - a < eps)
 909                 return TRUE;
 910         return FALSE;
 911 }
 912
 913 float almost_in_bounds(float a, float b, float c)
 914 {
 915         float eps;
 916         eps = (max(a, -a) + max(c, -c)) * 0.001;
 917         if(a > c)
 918                 eps = -eps;
 919         return b == median(a - eps, b, c + eps);
 920 }
 921
 922 float power2of(float e)
 923 {
 924         return pow(2, e);
 925 }
 926 float log2of(float x)
 927 {
 928         // NOTE: generated code
 929         if(x > 2048)
 930                 if(x > 131072)
 931                         if(x > 1048576)
 932                                 if(x > 4194304)
 933                                         return 23;
 934                                 else
 935                                         if(x > 2097152)
 936                                                 return 22;
 937                                         else
 938                                                 return 21;
 939                         else
 940                                 if(x > 524288)
 941                                         return 20;
 942                                 else
 943                                         if(x > 262144)
 944                                                 return 19;
 945                                         else
 946                                                 return 18;
 947                 else
 948                         if(x > 16384)
 949                                 if(x > 65536)
 950                                         return 17;
 951                                 else
 952                                         if(x > 32768)
 953                                                 return 16;
 954                                         else
 955                                                 return 15;
 956                         else
 957                                 if(x > 8192)
 958                                         return 14;
 959                                 else
 960                                         if(x > 4096)
 961                                                 return 13;
 962                                         else
 963                                                 return 12;
 964         else
 965                 if(x > 32)
 966                         if(x > 256)
 967                                 if(x > 1024)
 968                                         return 11;
 969                                 else
 970                                         if(x > 512)
 971                                                 return 10;
 972                                         else
 973                                                 return 9;
 974                         else
 975                                 if(x > 128)
 976                                         return 8;
 977                                 else
 978                                         if(x > 64)
 979                                                 return 7;
 980                                         else
 981                                                 return 6;
 982                 else
 983                         if(x > 4)
 984                                 if(x > 16)
 985                                         return 5;
 986                                 else
 987                                         if(x > 8)
 988                                                 return 4;
 989                                         else
 990                                                 return 3;
 991                         else
 992                                 if(x > 2)
 993                                         return 2;
 994                                 else
 995                                         if(x > 1)
 996                                                 return 1;
 997                                         else
 998                                                 return 0;
 999 }
1000
1001 float rgb_mi_ma_to_hue(vector rgb, float mi, float ma)
1002 {
1003         if(mi == ma)
1004                 return 0;
1005         else if(ma == rgb_x)
1006         {
1007                 if(rgb_y >= rgb_z)
1008                         return (rgb_y - rgb_z) / (ma - mi);
1009                 else
1010                         return (rgb_y - rgb_z) / (ma - mi) + 6;
1011         }
1012         else if(ma == rgb_y)
1013                 return (rgb_z - rgb_x) / (ma - mi) + 2;
1014         else // if(ma == rgb_z)
1015                 return (rgb_x - rgb_y) / (ma - mi) + 4;
1016 }
1017
1018 vector hue_mi_ma_to_rgb(float hue, float mi, float ma)
1019 {
1020         vector rgb;
1021
1022         hue -= 6 * floor(hue / 6);
1023
1024         //else if(ma == rgb_x)
1025         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1026         if(hue <= 1)
1027         {
1028                 rgb_x = ma;
1029                 rgb_y = hue * (ma - mi) + mi;
1030                 rgb_z = mi;
1031         }
1032         //else if(ma == rgb_y)
1033         //      hue = 60 * (rgb_z - rgb_x) / (ma - mi) + 120;
1034         else if(hue <= 2)
1035         {
1036                 rgb_x = (2 - hue) * (ma - mi) + mi;
1037                 rgb_y = ma;
1038                 rgb_z = mi;
1039         }
1040         else if(hue <= 3)
1041         {
1042                 rgb_x = mi;
1043                 rgb_y = ma;
1044                 rgb_z = (hue - 2) * (ma - mi) + mi;
1045         }
1046         //else // if(ma == rgb_z)
1047         //      hue = 60 * (rgb_x - rgb_y) / (ma - mi) + 240;
1048         else if(hue <= 4)
1049         {
1050                 rgb_x = mi;
1051                 rgb_y = (4 - hue) * (ma - mi) + mi;
1052                 rgb_z = ma;
1053         }
1054         else if(hue <= 5)
1055         {
1056                 rgb_x = (hue - 4) * (ma - mi) + mi;
1057                 rgb_y = mi;
1058                 rgb_z = ma;
1059         }
1060         //else if(ma == rgb_x)
1061         //      hue = 60 * (rgb_y - rgb_z) / (ma - mi);
1062         else // if(hue <= 6)
1063         {
1064                 rgb_x = ma;
1065                 rgb_y = mi;
1066                 rgb_z = (6 - hue) * (ma - mi) + mi;
1067         }
1068
1069         return rgb;
1070 }
1071
1072 vector rgb_to_hsv(vector rgb)
1073 {
1074         float mi, ma;
1075         vector hsv;
1076
1077         mi = min(rgb_x, rgb_y, rgb_z);
1078         ma = max(rgb_x, rgb_y, rgb_z);
1079
1080         hsv_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1081         hsv_z = ma;
1082
1083         if(ma == 0)
1084                 hsv_y = 0;
1085         else
1086                 hsv_y = 1 - mi/ma;
1087
1088         return hsv;
1089 }
1090
1091 vector hsv_to_rgb(vector hsv)
1092 {
1093         return hue_mi_ma_to_rgb(hsv_x, hsv_z * (1 - hsv_y), hsv_z);
1094 }
1095
1096 vector rgb_to_hsl(vector rgb)
1097 {
1098         float mi, ma;
1099         vector hsl;
1100
1101         mi = min(rgb_x, rgb_y, rgb_z);
1102         ma = max(rgb_x, rgb_y, rgb_z);
1103
1104         hsl_x = rgb_mi_ma_to_hue(rgb, mi, ma);
1105
1106         hsl_z = 0.5 * (mi + ma);
1107         if(mi == ma)
1108                 hsl_y = 0;
1109         else if(hsl_z <= 0.5)
1110                 hsl_y = (ma - mi) / (2*hsl_z);
1111         else // if(hsl_z > 0.5)
1112                 hsl_y = (ma - mi) / (2 - 2*hsl_z);
1113
1114         return hsl;
1115 }
1116
1117 vector hsl_to_rgb(vector hsl)
1118 {
1119         float mi, ma, maminusmi;
1120
1121         if(hsl_z <= 0.5)
1122                 maminusmi = hsl_y * 2 * hsl_z;
1123         else
1124                 maminusmi = hsl_y * (2 - 2 * hsl_z);
1125
1126         // hsl_z     = 0.5 * mi + 0.5 * ma
1127         // maminusmi =     - mi +       ma
1128         mi = hsl_z - 0.5 * maminusmi;
1129         ma = hsl_z + 0.5 * maminusmi;
1130
1131         return hue_mi_ma_to_rgb(hsl_x, mi, ma);
1132 }
1133
1134 string rgb_to_hexcolor(vector rgb)
1135 {
1136         return
1137                 strcat(
1138                         "^x",
1139                         DEC_TO_HEXDIGIT(floor(rgb_x * 15 + 0.5)),
1140                         DEC_TO_HEXDIGIT(floor(rgb_y * 15 + 0.5)),
1141                         DEC_TO_HEXDIGIT(floor(rgb_z * 15 + 0.5))
1142                 );
1143 }
1144
1145 // requires that m2>m1 in all coordinates, and that m4>m3
1146 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;}
1147
1148 // requires the same, but is a stronger condition
1149 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;}
1150
1151 #ifndef MENUQC
1152 #endif
1153
1154 float textLengthUpToWidth(string theText, float maxWidth, vector theSize, textLengthUpToWidth_widthFunction_t w)
1155 {
1156         // STOP.
1157         // The following function is SLOW.
1158         // For your safety and for the protection of those around you...
1159         // DO NOT CALL THIS AT HOME.
1160         // No really, don't.
1161         if(w(theText, theSize) <= maxWidth)
1162                 return strlen(theText); // yeah!
1163
1164         // binary search for right place to cut string
1165         float ch;
1166         float left, right, middle; // this always works
1167         left = 0;
1168         right = strlen(theText); // this always fails
1169         do
1170         {
1171                 middle = floor((left + right) / 2);
1172                 if(w(substring(theText, 0, middle), theSize) <= maxWidth)
1173                         left = middle;
1174                 else
1175                         right = middle;
1176         }
1177         while(left < right - 1);
1178
1179         if(w("^7", theSize) == 0) // detect color codes support in the width function
1180         {
1181                 // NOTE: when color codes are involved, this binary search is,
1182                 // mathematically, BROKEN. However, it is obviously guaranteed to
1183                 // terminate, as the range still halves each time - but nevertheless, it is
1184                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1185                 // range, and "right" is outside).
1186
1187                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1188                 // and decrease left on the basis of the chars detected of the truncated tag
1189                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1190                 // (sometimes too much but with a correct result)
1191                 // it fixes also ^[0-9]
1192                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1193                         left-=1;
1194
1195                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1196                         left-=2;
1197                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1198                         {
1199                                 ch = str2chr(theText, left-1);
1200                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1201                                         left-=3;
1202                         }
1203                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1204                         {
1205                                 ch = str2chr(theText, left-2);
1206                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1207                                 {
1208                                         ch = str2chr(theText, left-1);
1209                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1210                                                 left-=4;
1211                                 }
1212                         }
1213         }
1214
1215         return left;
1216 }
1217
1218 float textLengthUpToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t w)
1219 {
1220         // STOP.
1221         // The following function is SLOW.
1222         // For your safety and for the protection of those around you...
1223         // DO NOT CALL THIS AT HOME.
1224         // No really, don't.
1225         if(w(theText) <= maxWidth)
1226                 return strlen(theText); // yeah!
1227
1228         // binary search for right place to cut string
1229         float ch;
1230         float left, right, middle; // this always works
1231         left = 0;
1232         right = strlen(theText); // this always fails
1233         do
1234         {
1235                 middle = floor((left + right) / 2);
1236                 if(w(substring(theText, 0, middle)) <= maxWidth)
1237                         left = middle;
1238                 else
1239                         right = middle;
1240         }
1241         while(left < right - 1);
1242
1243         if(w("^7") == 0) // detect color codes support in the width function
1244         {
1245                 // NOTE: when color codes are involved, this binary search is,
1246                 // mathematically, BROKEN. However, it is obviously guaranteed to
1247                 // terminate, as the range still halves each time - but nevertheless, it is
1248                 // guaranteed that it finds ONE valid cutoff place (where "left" is in
1249                 // range, and "right" is outside).
1250
1251                 // terencehill: the following code detects truncated ^xrgb tags (e.g. ^x or ^x4)
1252                 // and decrease left on the basis of the chars detected of the truncated tag
1253                 // Even if the ^xrgb tag is not complete/correct, left is decreased
1254                 // (sometimes too much but with a correct result)
1255                 // it fixes also ^[0-9]
1256                 while(left >= 1 && substring(theText, left-1, 1) == "^")
1257                         left-=1;
1258
1259                 if (left >= 2 && substring(theText, left-2, 2) == "^x") // ^x/
1260                         left-=2;
1261                 else if (left >= 3 && substring(theText, left-3, 2) == "^x")
1262                         {
1263                                 ch = str2chr(theText, left-1);
1264                                 if( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xr/
1265                                         left-=3;
1266                         }
1267                 else if (left >= 4 && substring(theText, left-4, 2) == "^x")
1268                         {
1269                                 ch = str2chr(theText, left-2);
1270                                 if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') )
1271                                 {
1272                                         ch = str2chr(theText, left-1);
1273                                         if ( (ch >= '0' && ch <= '9') || (ch >= 'a' && ch <= 'f') || (ch >= 'A' && ch <= 'F') ) // ^xrg/
1274                                                 left-=4;
1275                                 }
1276                         }
1277         }
1278
1279         return left;
1280 }
1281
1282 string find_last_color_code(string s)
1283 {
1284         float start, len, i, carets;
1285         start = strstrofs(s, "^", 0);
1286         if (start == -1) // no caret found
1287                 return "";
1288         len = strlen(s)-1;
1289         for(i = len; i >= start; --i)
1290         {
1291                 if(substring(s, i, 1) != "^")
1292                         continue;
1293
1294                 carets = 1;
1295                 while (i-carets >= start && substring(s, i-carets, 1) == "^")
1296                         ++carets;
1297
1298                 // check if carets aren't all escaped
1299                 if (carets == 1 || mod(carets, 2) == 1) // first check is just an optimization
1300                 {
1301                         if(i+1 <= len)
1302                         if(strstrofs("0123456789", substring(s, i+1, 1), 0) >= 0)
1303                                 return substring(s, i, 2);
1304
1305                         if(i+4 <= len)
1306                         if(substring(s, i+1, 1) == "x")
1307                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+2, 1), 0) >= 0)
1308                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+3, 1), 0) >= 0)
1309                         if(strstrofs("0123456789abcdefABCDEF", substring(s, i+4, 1), 0) >= 0)
1310                                 return substring(s, i, 5);
1311                 }
1312                 i -= carets; // this also skips one char before the carets
1313         }
1314
1315         return "";
1316 }
1317
1318 string getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1319 {
1320         float cantake;
1321         float take;
1322         string s;
1323
1324         s = getWrappedLine_remaining;
1325
1326         if(w <= 0)
1327         {
1328                 getWrappedLine_remaining = string_null;
1329                 return s; // the line has no size ANYWAY, nothing would be displayed.
1330         }
1331
1332         cantake = textLengthUpToWidth(s, w, theFontSize, tw);
1333         if(cantake > 0 && cantake < strlen(s))
1334         {
1335                 take = cantake - 1;
1336                 while(take > 0 && substring(s, take, 1) != " ")
1337                         --take;
1338                 if(take == 0)
1339                 {
1340                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1341                         if(getWrappedLine_remaining == "")
1342                                 getWrappedLine_remaining = string_null;
1343                         else if (tw("^7", theFontSize) == 0)
1344                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1345                         return substring(s, 0, cantake);
1346                 }
1347                 else
1348                 {
1349                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1350                         if(getWrappedLine_remaining == "")
1351                                 getWrappedLine_remaining = string_null;
1352                         else if (tw("^7", theFontSize) == 0)
1353                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1354                         return substring(s, 0, take);
1355                 }
1356         }
1357         else
1358         {
1359                 getWrappedLine_remaining = string_null;
1360                 return s;
1361         }
1362 }
1363
1364 string getWrappedLineLen(float w, textLengthUpToLength_lenFunction_t tw)
1365 {
1366         float cantake;
1367         float take;
1368         string s;
1369
1370         s = getWrappedLine_remaining;
1371
1372         if(w <= 0)
1373         {
1374                 getWrappedLine_remaining = string_null;
1375                 return s; // the line has no size ANYWAY, nothing would be displayed.
1376         }
1377
1378         cantake = textLengthUpToLength(s, w, tw);
1379         if(cantake > 0 && cantake < strlen(s))
1380         {
1381                 take = cantake - 1;
1382                 while(take > 0 && substring(s, take, 1) != " ")
1383                         --take;
1384                 if(take == 0)
1385                 {
1386                         getWrappedLine_remaining = substring(s, cantake, strlen(s) - cantake);
1387                         if(getWrappedLine_remaining == "")
1388                                 getWrappedLine_remaining = string_null;
1389                         else if (tw("^7") == 0)
1390                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, cantake)), getWrappedLine_remaining);
1391                         return substring(s, 0, cantake);
1392                 }
1393                 else
1394                 {
1395                         getWrappedLine_remaining = substring(s, take + 1, strlen(s) - take);
1396                         if(getWrappedLine_remaining == "")
1397                                 getWrappedLine_remaining = string_null;
1398                         else if (tw("^7") == 0)
1399                                 getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take)), getWrappedLine_remaining);
1400                         return substring(s, 0, take);
1401                 }
1402         }
1403         else
1404         {
1405                 getWrappedLine_remaining = string_null;
1406                 return s;
1407         }
1408 }
1409
1410 string textShortenToWidth(string theText, float maxWidth, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
1411 {
1412         if(tw(theText, theFontSize) <= maxWidth)
1413                 return theText;
1414         else
1415                 return strcat(substring(theText, 0, textLengthUpToWidth(theText, maxWidth - tw("...", theFontSize), theFontSize, tw)), "...");
1416 }
1417
1418 string textShortenToLength(string theText, float maxWidth, textLengthUpToLength_lenFunction_t tw)
1419 {
1420         if(tw(theText) <= maxWidth)
1421                 return theText;
1422         else
1423                 return strcat(substring(theText, 0, textLengthUpToLength(theText, maxWidth - tw("..."), tw)), "...");
1424 }
1425
1426 float isGametypeInFilter(float gt, float tp, float ts, string pattern)
1427 {
1428         string subpattern, subpattern2, subpattern3, subpattern4;
1429         subpattern = strcat(",", MapInfo_Type_ToString(gt), ",");
1430         if(tp)
1431                 subpattern2 = ",teams,";
1432         else
1433                 subpattern2 = ",noteams,";
1434         if(ts)
1435                 subpattern3 = ",teamspawns,";
1436         else
1437                 subpattern3 = ",noteamspawns,";
1438         if(gt == MAPINFO_TYPE_RACE || gt == MAPINFO_TYPE_CTS)
1439                 subpattern4 = ",race,";
1440         else
1441                 subpattern4 = string_null;
1442
1443         if(substring(pattern, 0, 1) == "-")
1444         {
1445                 pattern = substring(pattern, 1, strlen(pattern) - 1);
1446                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) >= 0)
1447                         return 0;
1448                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) >= 0)
1449                         return 0;
1450                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) >= 0)
1451                         return 0;
1452                 if(subpattern4 && strstrofs(strcat(",", pattern, ","), subpattern4, 0) >= 0)
1453                         return 0;
1454         }
1455         else
1456         {
1457                 if(substring(pattern, 0, 1) == "+")
1458                         pattern = substring(pattern, 1, strlen(pattern) - 1);
1459                 if(strstrofs(strcat(",", pattern, ","), subpattern, 0) < 0)
1460                 if(strstrofs(strcat(",", pattern, ","), subpattern2, 0) < 0)
1461                 if(strstrofs(strcat(",", pattern, ","), subpattern3, 0) < 0)
1462                 if((!subpattern4) || strstrofs(strcat(",", pattern, ","), subpattern4, 0) < 0)
1463                         return 0;
1464         }
1465         return 1;
1466 }
1467
1468 void shuffle(float n, swapfunc_t swap, entity pass)
1469 {
1470         float i, j;
1471         for(i = 1; i < n; ++i)
1472         {
1473                 // swap i-th item at a random position from 0 to i
1474                 // proof for even distribution:
1475                 //   n = 1: obvious
1476                 //   n -> n+1:
1477                 //     item n+1 gets at any position with chance 1/(n+1)
1478                 //     all others will get their 1/n chance reduced by factor n/(n+1)
1479                 //     to be on place n+1, their chance will be 1/(n+1)
1480                 //     1/n * n/(n+1) = 1/(n+1)
1481                 //     q.e.d.
1482                 j = floor(random() * (i + 1));
1483                 if(j != i)
1484                         swap(j, i, pass);
1485         }
1486 }
1487
1488 string substring_range(string s, float b, float e)
1489 {
1490         return substring(s, b, e - b);
1491 }
1492
1493 string swapwords(string str, float i, float j)
1494 {
1495         float n;
1496         string s1, s2, s3, s4, s5;
1497         float si, ei, sj, ej, s0, en;
1498         n = tokenizebyseparator(str, " "); // must match g_maplist processing in ShuffleMaplist and "shuffle"
1499         si = argv_start_index(i);
1500         sj = argv_start_index(j);
1501         ei = argv_end_index(i);
1502         ej = argv_end_index(j);
1503         s0 = argv_start_index(0);
1504         en = argv_end_index(n-1);
1505         s1 = substring_range(str, s0, si);
1506         s2 = substring_range(str, si, ei);
1507         s3 = substring_range(str, ei, sj);
1508         s4 = substring_range(str, sj, ej);
1509         s5 = substring_range(str, ej, en);
1510         return strcat(s1, s4, s3, s2, s5);
1511 }
1512
1513 string _shufflewords_str;
1514 void _shufflewords_swapfunc(float i, float j, entity pass)
1515 {
1516         _shufflewords_str = swapwords(_shufflewords_str, i, j);
1517 }
1518 string shufflewords(string str)
1519 {
1520         float n;
1521         _shufflewords_str = str;
1522         n = tokenizebyseparator(str, " ");
1523         shuffle(n, _shufflewords_swapfunc, world);
1524         str = _shufflewords_str;
1525         _shufflewords_str = string_null;
1526         return str;
1527 }
1528
1529 vector solve_quadratic(float a, float b, float c) // ax^2 + bx + c = 0
1530 {
1531         vector v;
1532         float D;
1533         v = '0 0 0';
1534         if(a == 0)
1535         {
1536                 if(b != 0)
1537                 {
1538                         v_x = v_y = -c / b;
1539                         v_z = 1;
1540                 }
1541                 else
1542                 {
1543                         if(c == 0)
1544                         {
1545                                 // actually, every number solves the equation!
1546                                 v_z = 1;
1547                         }
1548                 }
1549         }
1550         else
1551         {
1552                 D = b*b - 4*a*c;
1553                 if(D >= 0)
1554                 {
1555                         D = sqrt(D);
1556                         if(a > 0) // put the smaller solution first
1557                         {
1558                                 v_x = ((-b)-D) / (2*a);
1559                                 v_y = ((-b)+D) / (2*a);
1560                         }
1561                         else
1562                         {
1563                                 v_x = (-b+D) / (2*a);
1564                                 v_y = (-b-D) / (2*a);
1565                         }
1566                         v_z = 1;
1567                 }
1568                 else
1569                 {
1570                         // complex solutions!
1571                         D = sqrt(-D);
1572                         v_x = -b / (2*a);
1573                         if(a > 0)
1574                                 v_y =  D / (2*a);
1575                         else
1576                                 v_y = -D / (2*a);
1577                         v_z = 0;
1578                 }
1579         }
1580         return v;
1581 }
1582
1583 void check_unacceptable_compiler_bugs()
1584 {
1585         if(cvar("_allow_unacceptable_compiler_bugs"))
1586                 return;
1587         tokenize_console("foo bar");
1588         if(strcat(argv(0), substring("foo bar", 4, 7 - argv_start_index(1))) == "barbar")
1589                 error("fteqcc bug introduced with revision 3178 detected. Please upgrade fteqcc to a later revision, downgrade fteqcc to revision 3177, or pester Spike until he fixes it. You can set _allow_unacceptable_compiler_bugs 1 to skip this check, but expect stuff to be horribly broken then.");
1590
1591         string s = "";
1592         if not(s)
1593                 error("The empty string counts as false. We do not want that!");
1594 }
1595
1596 float compressShotOrigin(vector v)
1597 {
1598         float x, y, z;
1599         x = rint(v_x * 2);
1600         y = rint(v_y * 4) + 128;
1601         z = rint(v_z * 4) + 128;
1602         if(x > 255 || x < 0)
1603         {
1604                 print("shot origin ", vtos(v), " x out of bounds\n");
1605                 x = bound(0, x, 255);
1606         }
1607         if(y > 255 || y < 0)
1608         {
1609                 print("shot origin ", vtos(v), " y out of bounds\n");
1610                 y = bound(0, y, 255);
1611         }
1612         if(z > 255 || z < 0)
1613         {
1614                 print("shot origin ", vtos(v), " z out of bounds\n");
1615                 z = bound(0, z, 255);
1616         }
1617         return x * 0x10000 + y * 0x100 + z;
1618 }
1619 vector decompressShotOrigin(float f)
1620 {
1621         vector v;
1622         v_x = ((f & 0xFF0000) / 0x10000) / 2;
1623         v_y = ((f & 0xFF00) / 0x100 - 128) / 4;
1624         v_z = ((f & 0xFF) - 128) / 4;
1625         return v;
1626 }
1627
1628 void heapsort(float n, swapfunc_t swap, comparefunc_t cmp, entity pass)
1629 {
1630         float start, end, root, child;
1631
1632         // heapify
1633         start = floor((n - 2) / 2);
1634         while(start >= 0)
1635         {
1636                 // siftdown(start, count-1);
1637                 root = start;
1638                 while(root * 2 + 1 <= n-1)
1639                 {
1640                         child = root * 2 + 1;
1641                         if(child < n-1)
1642                                 if(cmp(child, child+1, pass) < 0)
1643                                         ++child;
1644                         if(cmp(root, child, pass) < 0)
1645                         {
1646                                 swap(root, child, pass);
1647                                 root = child;
1648                         }
1649                         else
1650                                 break;
1651                 }
1652                 // end of siftdown
1653                 --start;
1654         }
1655
1656         // extract
1657         end = n - 1;
1658         while(end > 0)
1659         {
1660                 swap(0, end, pass);
1661                 --end;
1662                 // siftdown(0, end);
1663                 root = 0;
1664                 while(root * 2 + 1 <= end)
1665                 {
1666                         child = root * 2 + 1;
1667                         if(child < end && cmp(child, child+1, pass) < 0)
1668                                 ++child;
1669                         if(cmp(root, child, pass) < 0)
1670                         {
1671                                 swap(root, child, pass);
1672                                 root = child;
1673                         }
1674                         else
1675                                 break;
1676                 }
1677                 // end of siftdown
1678         }
1679 }
1680
1681 void RandomSelection_Init()
1682 {
1683         RandomSelection_totalweight = 0;
1684         RandomSelection_chosen_ent = world;
1685         RandomSelection_chosen_float = 0;
1686         RandomSelection_chosen_string = string_null;
1687         RandomSelection_best_priority = -1;
1688 }
1689 void RandomSelection_Add(entity e, float f, string s, float weight, float priority)
1690 {
1691         if(priority > RandomSelection_best_priority)
1692         {
1693                 RandomSelection_best_priority = priority;
1694                 RandomSelection_chosen_ent = e;
1695                 RandomSelection_chosen_float = f;
1696                 RandomSelection_chosen_string = s;
1697                 RandomSelection_totalweight = weight;
1698         }
1699         else if(priority == RandomSelection_best_priority)
1700         {
1701                 RandomSelection_totalweight += weight;
1702                 if(random() * RandomSelection_totalweight <= weight)
1703                 {
1704                         RandomSelection_chosen_ent = e;
1705                         RandomSelection_chosen_float = f;
1706                         RandomSelection_chosen_string = s;
1707                 }
1708         }
1709 }
1710
1711 vector healtharmor_maxdamage(float h, float a, float armorblock)
1712 {
1713         // NOTE: we'll always choose the SMALLER value...
1714         float healthdamage, armordamage, armorideal;
1715         vector v;
1716         healthdamage = (h - 1) / (1 - armorblock); // damage we can take if we could use more health
1717         armordamage = a + (h - 1); // damage we can take if we could use more armor
1718         armorideal = healthdamage * armorblock;
1719         v_y = armorideal;
1720         if(armordamage < healthdamage)
1721         {
1722                 v_x = armordamage;
1723                 v_z = 1;
1724         }
1725         else
1726         {
1727                 v_x = healthdamage;
1728                 v_z = 0;
1729         }
1730         return v;
1731 }
1732
1733 vector healtharmor_applydamage(float a, float armorblock, float damage)
1734 {
1735         vector v;
1736         v_y = bound(0, damage * armorblock, a); // save
1737         v_x = bound(0, damage - v_y, damage); // take
1738         v_z = 0;
1739         return v;
1740 }
1741
1742 string getcurrentmod()
1743 {
1744         float n;
1745         string m;
1746         m = cvar_string("fs_gamedir");
1747         n = tokenize_console(m);
1748         if(n == 0)
1749                 return "data";
1750         else
1751                 return argv(n - 1);
1752 }
1753
1754 #ifndef MENUQC
1755 #ifdef CSQC
1756 float ReadInt24_t()
1757 {
1758         float v;
1759         v = ReadShort() * 256; // note: this is signed
1760         v += ReadByte(); // note: this is unsigned
1761         return v;
1762 }
1763 #else
1764 void WriteInt24_t(float dst, float val)
1765 {
1766         float v;
1767         WriteShort(dst, (v = floor(val / 256)));
1768         WriteByte(dst, val - v * 256); // 0..255
1769 }
1770 #endif
1771 #endif
1772
1773 float float2range11(float f)
1774 {
1775         // continuous function mapping all reals into -1..1
1776         return f / (fabs(f) + 1);
1777 }
1778
1779 float float2range01(float f)
1780 {
1781         // continuous function mapping all reals into 0..1
1782         return 0.5 + 0.5 * float2range11(f);
1783 }
1784
1785 // from the GNU Scientific Library
1786 float gsl_ran_gaussian_lastvalue;
1787 float gsl_ran_gaussian_lastvalue_set;
1788 float gsl_ran_gaussian(float sigma)
1789 {
1790         float a, b;
1791         if(gsl_ran_gaussian_lastvalue_set)
1792         {
1793                 gsl_ran_gaussian_lastvalue_set = 0;
1794                 return sigma * gsl_ran_gaussian_lastvalue;
1795         }
1796         else
1797         {
1798                 a = random() * 2 * M_PI;
1799                 b = sqrt(-2 * log(random()));
1800                 gsl_ran_gaussian_lastvalue = cos(a) * b;
1801                 gsl_ran_gaussian_lastvalue_set = 1;
1802                 return sigma * sin(a) * b;
1803         }
1804 }
1805
1806 string car(string s)
1807 {
1808         float o;
1809         o = strstrofs(s, " ", 0);
1810         if(o < 0)
1811                 return s;
1812         return substring(s, 0, o);
1813 }
1814 string cdr(string s)
1815 {
1816         float o;
1817         o = strstrofs(s, " ", 0);
1818         if(o < 0)
1819                 return string_null;
1820         return substring(s, o + 1, strlen(s) - (o + 1));
1821 }
1822 float matchacl(string acl, string str)
1823 {
1824         string t, s;
1825         float r, d;
1826         r = 0;
1827         while(acl)
1828         {
1829                 t = car(acl); acl = cdr(acl);
1830
1831                 d = 1;
1832                 if(substring(t, 0, 1) == "-")
1833                 {
1834                         d = -1;
1835                         t = substring(t, 1, strlen(t) - 1);
1836                 }
1837                 else if(substring(t, 0, 1) == "+")
1838                         t = substring(t, 1, strlen(t) - 1);
1839
1840                 if(substring(t, -1, 1) == "*")
1841                 {
1842                         t = substring(t, 0, strlen(t) - 1);
1843                         s = substring(str, 0, strlen(t));
1844                 }
1845                 else
1846                         s = str;
1847
1848                 if(s == t)
1849                 {
1850                         r = d;
1851                 }
1852         }
1853         return r;
1854 }
1855 float startsWith(string haystack, string needle)
1856 {
1857         return substring(haystack, 0, strlen(needle)) == needle;
1858 }
1859 float startsWithNocase(string haystack, string needle)
1860 {
1861         return strcasecmp(substring(haystack, 0, strlen(needle)), needle) == 0;
1862 }
1863
1864 string get_model_datafilename(string m, float sk, string fil)
1865 {
1866         if(m)
1867                 m = strcat(m, "_");
1868         else
1869                 m = "models/player/*_";
1870         if(sk >= 0)
1871                 m = strcat(m, ftos(sk));
1872         else
1873                 m = strcat(m, "*");
1874         return strcat(m, ".", fil);
1875 }
1876
1877 float get_model_parameters(string m, float sk)
1878 {
1879         string fn, s, c;
1880         float fh;
1881
1882         get_model_parameters_modelname = string_null;
1883         get_model_parameters_modelskin = -1;
1884         get_model_parameters_name = string_null;
1885         get_model_parameters_species = -1;
1886         get_model_parameters_sex = string_null;
1887         get_model_parameters_weight = -1;
1888         get_model_parameters_age = -1;
1889         get_model_parameters_desc = string_null;
1890
1891         if not(m)
1892                 return 1;
1893         if(sk < 0)
1894         {
1895                 if(substring(m, -4, -1) != ".txt")
1896                         return 0;
1897                 if(substring(m, -6, 1) != "_")
1898                         return 0;
1899                 sk = stof(substring(m, -5, 1));
1900                 m = substring(m, 0, -7);
1901         }
1902
1903         fn = get_model_datafilename(m, sk, "txt");
1904         fh = fopen(fn, FILE_READ);
1905         if(fh < 0)
1906         {
1907                 sk = 0;
1908                 fn = get_model_datafilename(m, sk, "txt");
1909                 fh = fopen(fn, FILE_READ);
1910                 if(fh < 0)
1911                         return 0;
1912         }
1913
1914         get_model_parameters_modelname = m;
1915         get_model_parameters_modelskin = sk;
1916         while((s = fgets(fh)))
1917         {
1918                 if(s == "")
1919                         break; // next lines will be description
1920                 c = car(s);
1921                 s = cdr(s);
1922                 if(c == "name")
1923                         get_model_parameters_name = s;
1924                 if(c == "species")
1925                         switch(s)
1926                         {
1927                                 case "human":       get_model_parameters_species = SPECIES_HUMAN;       break;
1928                                 case "alien":       get_model_parameters_species = SPECIES_ALIEN;       break;
1929                                 case "robot_shiny": get_model_parameters_species = SPECIES_ROBOT_SHINY; break;
1930                                 case "robot_rusty": get_model_parameters_species = SPECIES_ROBOT_RUSTY; break;
1931                                 case "robot_solid": get_model_parameters_species = SPECIES_ROBOT_SOLID; break;
1932                                 case "animal":      get_model_parameters_species = SPECIES_ANIMAL;      break;
1933                                 case "reserved":    get_model_parameters_species = SPECIES_RESERVED;    break;
1934                         }
1935                 if(c == "sex")
1936                         get_model_parameters_sex = s;
1937                 if(c == "weight")
1938                         get_model_parameters_weight = stof(s);
1939                 if(c == "age")
1940                         get_model_parameters_age = stof(s);
1941         }
1942
1943         while((s = fgets(fh)))
1944         {
1945                 if(get_model_parameters_desc)
1946                         get_model_parameters_desc = strcat(get_model_parameters_desc, "\n");
1947                 if(s != "")
1948                         get_model_parameters_desc = strcat(get_model_parameters_desc, s);
1949         }
1950
1951         fclose(fh);
1952
1953         return 1;
1954 }
1955
1956 vector vec2(vector v)
1957 {
1958         v_z = 0;
1959         return v;
1960 }
1961
1962 #ifndef MENUQC
1963 vector NearestPointOnBox(entity box, vector org)
1964 {
1965         vector m1, m2, nearest;
1966
1967         m1 = box.mins + box.origin;
1968         m2 = box.maxs + box.origin;
1969
1970         nearest_x = bound(m1_x, org_x, m2_x);
1971         nearest_y = bound(m1_y, org_y, m2_y);
1972         nearest_z = bound(m1_z, org_z, m2_z);
1973
1974         return nearest;
1975 }
1976 #endif
1977
1978 float vercmp_recursive(string v1, string v2)
1979 {
1980         float dot1, dot2;
1981         string s1, s2;
1982         float r;
1983
1984         dot1 = strstrofs(v1, ".", 0);
1985         dot2 = strstrofs(v2, ".", 0);
1986         if(dot1 == -1)
1987                 s1 = v1;
1988         else
1989                 s1 = substring(v1, 0, dot1);
1990         if(dot2 == -1)
1991                 s2 = v2;
1992         else
1993                 s2 = substring(v2, 0, dot2);
1994
1995         r = stof(s1) - stof(s2);
1996         if(r != 0)
1997                 return r;
1998
1999         r = strcasecmp(s1, s2);
2000         if(r != 0)
2001                 return r;
2002
2003         if(dot1 == -1)
2004                 if(dot2 == -1)
2005                         return 0;
2006                 else
2007                         return -1;
2008         else
2009                 if(dot2 == -1)
2010                         return 1;
2011                 else
2012                         return vercmp_recursive(substring(v1, dot1 + 1, 999), substring(v2, dot2 + 1, 999));
2013 }
2014
2015 float vercmp(string v1, string v2)
2016 {
2017         if(strcasecmp(v1, v2) == 0) // early out check
2018                 return 0;
2019
2020         // "git" beats all
2021         if(v1 == "git")
2022                 return 1;
2023         if(v2 == "git")
2024                 return -1;
2025
2026         return vercmp_recursive(v1, v2);
2027 }
2028
2029 float u8_strsize(string s)
2030 {
2031         float l, i, c;
2032         l = 0;
2033         for(i = 0; ; ++i)
2034         {
2035                 c = str2chr(s, i);
2036                 if(c <= 0)
2037                         break;
2038                 ++l;
2039                 if(c >= 0x80)
2040                         ++l;
2041                 if(c >= 0x800)
2042                         ++l;
2043                 if(c >= 0x10000)
2044                         ++l;
2045         }
2046         return l;
2047 }
2048
2049 // translation helpers
2050 string language_filename(string s)
2051 {
2052         string fn;
2053         float fh;
2054         fn = prvm_language;
2055         if(fn == "" || fn == "dump")
2056                 return s;
2057         fn = strcat(s, ".", fn);
2058         if((fh = fopen(fn, FILE_READ)) >= 0)
2059         {
2060                 fclose(fh);
2061                 return fn;
2062         }
2063         return s;
2064 }
2065 string CTX(string s)
2066 {
2067         float p = strstrofs(s, "^", 0);
2068         if(p < 0)
2069                 return s;
2070         return substring(s, p+1, -1);
2071 }
2072
2073 // x-encoding (encoding as zero length invisible string)
2074 const string XENCODE_2  = "xX";
2075 const string XENCODE_22 = "0123456789abcdefABCDEF";
2076 string xencode(float f)
2077 {
2078         float a, b, c, d;
2079         d = mod(f, 22); f = floor(f / 22);
2080         c = mod(f, 22); f = floor(f / 22);
2081         b = mod(f, 22); f = floor(f / 22);
2082         a = mod(f,  2); // f = floor(f /  2);
2083         return strcat(
2084                 "^",
2085                 substring(XENCODE_2,  a, 1),
2086                 substring(XENCODE_22, b, 1),
2087                 substring(XENCODE_22, c, 1),
2088                 substring(XENCODE_22, d, 1)
2089         );
2090 }
2091 float xdecode(string s)
2092 {
2093         float a, b, c, d;
2094         if(substring(s, 0, 1) != "^")
2095                 return -1;
2096         if(strlen(s) < 5)
2097                 return -1;
2098         a = strstrofs(XENCODE_2,  substring(s, 1, 1), 0);
2099         b = strstrofs(XENCODE_22, substring(s, 2, 1), 0);
2100         c = strstrofs(XENCODE_22, substring(s, 3, 1), 0);
2101         d = strstrofs(XENCODE_22, substring(s, 4, 1), 0);
2102         if(a < 0 || b < 0 || c < 0 || d < 0)
2103                 return -1;
2104         return ((a * 22 + b) * 22 + c) * 22 + d;
2105 }
2106
2107 float lowestbit(float f)
2108 {
2109         f &~= f * 2;
2110         f &~= f * 4;
2111         f &~= f * 16;
2112         f &~= f * 256;
2113         f &~= f * 65536;
2114         return f;
2115 }
2116
2117 /*
2118 string strlimitedlen(string input, string truncation, float strip_colors, float limit)
2119 {
2120         if(strlen((strip_colors ? strdecolorize(input) : input)) <= limit)
2121                 return input;
2122         else
2123                 return strcat(substring(input, 0, (strlen(input) - strlen(truncation))), truncation);
2124 }*/
2125
2126 // escape the string to make it safe for consoles
2127 string MakeConsoleSafe(string input)
2128 {
2129         input = strreplace("\n", "", input);
2130         input = strreplace("\\", "\\\\", input);
2131         input = strreplace("$", "$$", input);
2132         input = strreplace("\"", "\\\"", input);
2133         return input;
2134 }
2135
2136 #ifndef MENUQC
2137 // get true/false value of a string with multiple different inputs
2138 float InterpretBoolean(string input)
2139 {
2140         switch(strtolower(input))
2141         {
2142                 case "yes":
2143                 case "true":
2144                 case "on":
2145                         return TRUE;
2146
2147                 case "no":
2148                 case "false":
2149                 case "off":
2150                         return FALSE;
2151
2152                 default: return stof(input);
2153         }
2154 }
2155 #endif
2156
2157 #ifdef CSQC
2158 entity ReadCSQCEntity()
2159 {
2160         float f;
2161         f = ReadShort();
2162         if(f == 0)
2163                 return world;
2164         return findfloat(world, entnum, f);
2165 }
2166 #endif
2167
2168 float shutdown_running;
2169 #ifdef SVQC
2170 void SV_Shutdown()
2171 #endif
2172 #ifdef CSQC
2173 void CSQC_Shutdown()
2174 #endif
2175 #ifdef MENUQC
2176 void m_shutdown()
2177 #endif
2178 {
2179         if(shutdown_running)
2180         {
2181                 print("Recursive shutdown detected! Only restoring cvars...\n");
2182         }
2183         else
2184         {
2185                 shutdown_running = 1;
2186                 Shutdown();
2187         }
2188         cvar_settemp_restore(); // this must be done LAST, but in any case
2189 }
2190
2191 #define APPROXPASTTIME_ACCURACY_REQUIREMENT 0.05
2192 #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2193 #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
2194 // this will use the value:
2195 //   128
2196 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
2197 // accuracy at x is 1/derivative, i.e.
2198 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
2199 #ifdef SVQC
2200 void WriteApproxPastTime(float dst, float t)
2201 {
2202         float dt = time - t;
2203
2204         // warning: this is approximate; do not resend when you don't have to!
2205         // be careful with sendflags here!
2206         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
2207
2208         // map to range...
2209         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
2210
2211         // round...
2212         dt = rint(bound(0, dt, 255));
2213
2214         WriteByte(dst, dt);
2215 }
2216 #endif
2217 #ifdef CSQC
2218 float ReadApproxPastTime()
2219 {
2220         float dt = ReadByte();
2221
2222         // map from range...PPROXPASTTIME_MAX / 256
2223         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
2224
2225         return servertime - dt;
2226 }
2227 #endif
2228
2229 #ifndef MENUQC
2230 .float skeleton_bones_index;
2231 void Skeleton_SetBones(entity e)
2232 {
2233         // set skeleton_bones to the total number of bones on the model
2234         if(e.skeleton_bones_index == e.modelindex)
2235                 return; // same model, nothing to update
2236
2237         float skelindex;
2238         skelindex = skel_create(e.modelindex);
2239         e.skeleton_bones = skel_get_numbones(skelindex);
2240         skel_delete(skelindex);
2241         e.skeleton_bones_index = e.modelindex;
2242 }
2243 #endif
2244
2245 string to_execute_next_frame;
2246 void execute_next_frame()
2247 {
2248         if(to_execute_next_frame)
2249         {
2250                 localcmd("\n", to_execute_next_frame, "\n");
2251                 strunzone(to_execute_next_frame);
2252                 to_execute_next_frame = string_null;
2253         }
2254 }
2255 void queue_to_execute_next_frame(string s)
2256 {
2257         if(to_execute_next_frame)
2258         {
2259                 s = strcat(s, "\n", to_execute_next_frame);
2260                 strunzone(to_execute_next_frame);
2261         }
2262         to_execute_next_frame = strzone(s);
2263 }