qcsrc/common/weapons/weapon/vaporizer.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Vaporizer, Weapon)
   3 /* ammotype  */ ATTRIB(Vaporizer, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Vaporizer, impulse, int, 7)
   5 /* flags     */ ATTRIB(Vaporizer, spawnflags, int, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Vaporizer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Vaporizer, wpcolor, vector, '0.5 1 1');
   8 /* modelname */ ATTRIB(Vaporizer, mdl, string, "minstanex");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Vaporizer, m_model, Model, MDL_VAPORIZER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Vaporizer, w_crosshair, string, "gfx/crosshairminstanex");
  13 /* crosshair */ ATTRIB(Vaporizer, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Vaporizer, model2, string, "weaponminstanex");
  15 /* refname   */ ATTRIB(Vaporizer, netname, string, "vaporizer");
  16 /* wepname   */ ATTRIB(Vaporizer, m_name, string, _("Vaporizer"));
  17 ENDCLASS(Vaporizer)
  18 REGISTER_WEAPON(VAPORIZER, NEW(Vaporizer));
  19
  20 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  21 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, PRI, ammo) \
  23         w_cvar(id, sn, PRI, animtime) \
  24         w_cvar(id, sn, PRI, damage) \
  25         w_cvar(id, sn, PRI, refire) \
  26         w_cvar(id, sn, SEC, ammo) \
  27         w_cvar(id, sn, SEC, animtime) \
  28         w_cvar(id, sn, SEC, damage) \
  29         w_cvar(id, sn, SEC, delay) \
  30         w_cvar(id, sn, SEC, edgedamage) \
  31         w_cvar(id, sn, SEC, force) \
  32         w_cvar(id, sn, SEC, lifetime) \
  33         w_cvar(id, sn, SEC, radius) \
  34         w_cvar(id, sn, SEC, refire) \
  35         w_cvar(id, sn, SEC, shotangle) \
  36         w_cvar(id, sn, SEC, speed) \
  37         w_cvar(id, sn, SEC, spread) \
  38         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  39         w_prop(id, sn, float,  reloading_time, reload_time) \
  40         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  43         w_prop(id, sn, float,  weaponstart, weaponstart) \
  44         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  45         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  46
  47 #ifdef SVQC
  48 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  49 .float vaporizer_lasthit;
  50 .float jump_interval;
  51 .float jump_interval2;
  52 .bool held_down;
  53 .float rm_force;
  54 .float rm_damage;
  55 .float rm_edmg;
  56 #endif
  57 #endif
  58 #ifdef IMPLEMENTATION
  59
  60 REGISTER_NET_TEMP(TE_CSQC_VAPORBEAMPARTICLE)
  61
  62 #if defined(SVQC)
  63 void SendCSQCVaporizerBeamParticle(entity player, int hit) {
  64         vector v;
  65         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  66         WriteHeader(MSG_BROADCAST, TE_CSQC_VAPORBEAMPARTICLE);
  67         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  68         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  69         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  70         WriteCoord(MSG_BROADCAST, v.x);
  71         WriteCoord(MSG_BROADCAST, v.y);
  72         WriteCoord(MSG_BROADCAST, v.z);
  73         WriteByte(MSG_BROADCAST, hit);
  74         WriteShort(MSG_BROADCAST, num_for_edict(player));
  75         WriteByte(MSG_BROADCAST, player.team);
  76 }
  77 #elif defined(CSQC)
  78 bool autocvar_cl_vaporizerbeam_particle = false;
  79 float autocvar_cl_vaporizerbeam_lifetime = 0.8;
  80 float autocvar_cl_vaporizerbeam_colorboost = 0.7;
  81
  82 string Draw_VaporizerBeam_trace_callback_tex;
  83 float Draw_VaporizerBeam_trace_callback_rnd;
  84 vector Draw_VaporizerBeam_trace_callback_rgb;
  85 float Draw_VaporizerBeam_trace_callback_a;
  86 void Draw_VaporizerBeam_trace_callback(vector start, vector hit, vector end)
  87 {
  88         float i;
  89         vector vorg;
  90         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
  91         for(i = 0; i < Draw_VaporizerBeam_trace_callback_a; ++i)
  92                 Draw_CylindricLine(hit, start, 8, Draw_VaporizerBeam_trace_callback_tex, 0.25, Draw_VaporizerBeam_trace_callback_rnd, Draw_VaporizerBeam_trace_callback_rgb, min(1, Draw_VaporizerBeam_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
  93         Draw_VaporizerBeam_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
  94 }
  95
  96 .vector vorg1, vorg2;
  97 .float spawn_time;
  98 void VaporizerBeam_Draw(entity this)
  99 {
 100         //draw either the old v2.3 beam or the new beam
 101         particles_alphamin = particles_alphamax = particles_fade = 1;
 102
 103         string tex = "particles/lgbeam";
 104         if(this.cnt)
 105                 tex = "particles/gauntletbeam";
 106         vector rgb = getcsqcplayercolor(this.sv_entnum);
 107         rgb *= (1 + autocvar_cl_vaporizerbeam_colorboost);
 108
 109         float fail = (self.nextthink - time);
 110
 111         Draw_VaporizerBeam_trace_callback_tex = tex;
 112         Draw_VaporizerBeam_trace_callback_rnd = 0;
 113         Draw_VaporizerBeam_trace_callback_rgb = rgb;
 114         Draw_VaporizerBeam_trace_callback_a = bound(0, fail, 1);
 115         WarpZone_TraceBox_ThroughZone(this.vorg1, '0 0 0', '0 0 0', this.vorg2, MOVE_NOTHING, world, world, Draw_VaporizerBeam_trace_callback);
 116         Draw_VaporizerBeam_trace_callback_tex = string_null;
 117
 118         /*if(!MUTATOR_CALLHOOK(Particles_VaporizerBeam, this.vorg1, this.vorg2))
 119         if(autocvar_cl_particles_oldvortexbeam && (getstati(STAT_ALLOW_OLDVORTEXBEAM) || isdemo()))
 120                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 121         else
 122                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);*/
 123 }
 124
 125 NET_HANDLE(TE_CSQC_VAPORBEAMPARTICLE, bool isNew)
 126 {
 127         Net_Accept(vortex_beam);
 128         this.think = SUB_Remove_self;
 129         this.nextthink = time + bound(0, autocvar_cl_vaporizerbeam_lifetime, 10);
 130         this.draw = VaporizerBeam_Draw;
 131         this.drawmask = MASK_NORMAL;
 132
 133         this.vorg1_x = ReadCoord(); this.vorg1_y = ReadCoord(); this.vorg1_z = ReadCoord();
 134         this.vorg2_x = ReadCoord(); this.vorg2_y = ReadCoord(); this.vorg2_z = ReadCoord();
 135         this.cnt = ReadByte();
 136         this.sv_entnum = ReadShort();
 137         this.team = ReadByte() - 1;
 138
 139         if(autocvar_cl_vaporizerbeam_particle)
 140         {
 141                 WarpZone_TrailParticles(world, particleeffectnum(((this.cnt) ? EFFECT_VAPORIZER_HIT(this.team) : EFFECT_VAPORIZER(this.team))), this.vorg1, this.vorg2);
 142                 this.draw = func_null;
 143                 this.drawmask = MASK_NORMAL;
 144                 remove(this);
 145         }
 146
 147         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, this.vorg1, normalize(this.vorg2 - this.vorg1) * 1000, 1);
 148         return true;
 149 }
 150 #endif
 151
 152 #ifdef SVQC
 153 spawnfunc(weapon_vaporizer) { weapon_defaultspawnfunc(this, WEP_VAPORIZER); }
 154 spawnfunc(weapon_minstanex) { spawnfunc_weapon_vaporizer(this); }
 155
 156 void W_RocketMinsta_Explosion(vector loc)
 157 {SELFPARAM();
 158         if(accuracy_canbegooddamage(self))
 159                 accuracy_add(self, WEP_DEVASTATOR.m_id, autocvar_g_rm_damage, 0);
 160         entity dmgent = spawn();
 161         dmgent.owner = dmgent.realowner = self;
 162         setorigin(dmgent, loc);
 163         RadiusDamage (dmgent, self, autocvar_g_rm_damage, autocvar_g_rm_edgedamage, autocvar_g_rm_radius, world, world, autocvar_g_rm_force, WEP_DEVASTATOR.m_id | HITTYPE_SPLASH, other);
 164         remove(dmgent);
 165 }
 166
 167 void W_Vaporizer_Attack(Weapon thiswep)
 168 {SELFPARAM();
 169         bool flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
 170         float vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
 171
 172         W_SetupShot(self, true, 0, "", CH_WEAPON_A, vaporizer_damage);
 173         // handle sound separately so we can change the volume
 174         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
 175         sound (self, CH_WEAPON_A, SND_MINSTANEXFIRE, VOL_BASE * 0.8, ATTEN_NORM);
 176
 177         yoda = 0;
 178         damage_goodhits = 0;
 179         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, vaporizer_damage, 800, 0, 0, 0, 0, WEP_VAPORIZER.m_id);
 180
 181         // do this now, as goodhits is disabled below
 182         SendCSQCVaporizerBeamParticle(self, damage_goodhits);
 183
 184         if(yoda && flying)
 185                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 186         if(damage_goodhits && self.vaporizer_lasthit)
 187         {
 188                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 189                 damage_goodhits = 0; // only every second time
 190         }
 191
 192         self.vaporizer_lasthit = damage_goodhits;
 193
 194         if(autocvar_g_rm)
 195         if(!(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT)))
 196                 W_RocketMinsta_Explosion(trace_endpos);
 197
 198         W_DecreaseAmmo(thiswep, self, ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 199 }
 200
 201 void W_RocketMinsta_Laser_Explode ()
 202 {SELFPARAM();
 203         if(other.takedamage == DAMAGE_AIM)
 204                 if(IS_PLAYER(other))
 205                         if(DIFF_TEAM(self.realowner, other))
 206                                 if(other.deadflag == DEAD_NO)
 207                                         if(IsFlying(other))
 208                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 209
 210         self.event_damage = func_null;
 211         self.takedamage = DAMAGE_NO;
 212         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 213         remove(self);
 214 }
 215
 216 void W_RocketMinsta_Laser_Touch ()
 217 {SELFPARAM();
 218         PROJECTILE_TOUCH;
 219         //W_RocketMinsta_Laser_Explode ();
 220         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 221         remove(self);
 222 }
 223
 224 void W_RocketMinsta_Attack2()
 225 {SELFPARAM();
 226         makevectors(self.v_angle);
 227
 228         entity proj;
 229         float counter = 0;
 230         float total = autocvar_g_rm_laser_count;
 231         float spread = autocvar_g_rm_laser_spread;
 232         float rndspread = autocvar_g_rm_laser_spread_random;
 233
 234         float w = self.weapon;
 235         self.weapon = WEP_ELECTRO.m_id;
 236         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(CRYLINK_FIRE), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 237         self.weapon = w;
 238
 239         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 240
 241     while(counter < total)
 242         {
 243         proj = new(plasma_prim);
 244         proj.owner = proj.realowner = self;
 245         proj.bot_dodge = true;
 246         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 247         proj.use = W_RocketMinsta_Laser_Explode;
 248         proj.think = adaptor_think2use_hittype_splash;
 249         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 250         PROJECTILE_MAKETRIGGER(proj);
 251         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 252         setorigin(proj, w_shotorg);
 253
 254                 proj.rm_force = autocvar_g_rm_laser_force / total;
 255                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 256                 proj.rm_edmg = proj.rm_damage;
 257
 258         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 259
 260         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 261         //W_SETUPPROJECTILEVELOCITY(proj, g_balance_minstanex_laser);
 262                 proj.velocity = (w_shotdir + (((counter + 0.5) / total) * 2 - 1) * v_right * (spread * (rndspread ? random() : 1))) * cvar("g_rm_laser_speed");
 263                 proj.velocity_z = proj.velocity_z + cvar("g_rm_laser_zspread") * (random() - 0.5);
 264                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 265         proj.angles = vectoangles(proj.velocity);
 266         proj.touch = W_RocketMinsta_Laser_Touch;
 267         setsize(proj, '0 0 -3', '0 0 -3');
 268         proj.flags = FL_PROJECTILE;
 269         proj.missile_flags = MIF_SPLASH;
 270
 271         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 272
 273         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 274         counter++;
 275     }
 276 }
 277
 278 void W_RocketMinsta_Attack3 ()
 279 {SELFPARAM();
 280         makevectors(self.v_angle);
 281
 282         entity proj;
 283         float counter = 0;
 284         float total = 1;
 285
 286         int w = self.weapon;
 287         self.weapon = WEP_ELECTRO.m_id;
 288         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(ELECTRO_FIRE2), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 289         self.weapon = w;
 290
 291         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 292
 293     while(counter < total)
 294         {
 295         proj = new(plasma_prim);
 296         proj.owner = proj.realowner = self;
 297         proj.bot_dodge = true;
 298         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 299         proj.use = W_RocketMinsta_Laser_Explode;
 300         proj.think = adaptor_think2use_hittype_splash;
 301         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 302         PROJECTILE_MAKETRIGGER(proj);
 303         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 304         setorigin(proj, w_shotorg);
 305
 306                 proj.rm_force = autocvar_g_rm_laser_force / total;
 307                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 308                 proj.rm_edmg = proj.rm_damage;
 309
 310         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 311
 312         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 313                 proj.velocity = w_shotdir * autocvar_g_rm_laser_speed;
 314                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 315         proj.angles = vectoangles(proj.velocity);
 316         proj.touch = W_RocketMinsta_Laser_Touch;
 317         setsize(proj, '0 0 -3', '0 0 -3');
 318         proj.flags = FL_PROJECTILE;
 319         proj.missile_flags = MIF_SPLASH;
 320
 321         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 322
 323         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 324         counter++;
 325     }
 326 }
 327
 328                 METHOD(Vaporizer, wr_aim, void(entity thiswep))
 329                 {
 330                         if(self.WEP_AMMO(VAPORIZER) > 0)
 331                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, false);
 332                         else
 333                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 334                 }
 335                 METHOD(Vaporizer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 336                 {
 337                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 338                         // if the laser uses load, we also consider its ammo for reloading
 339                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && actor.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) { // forced reload
 340                                 Weapon w = get_weaponinfo(actor.weapon);
 341                                 w.wr_reload(w);
 342                         } else if(WEP_CVAR(vaporizer, reload_ammo) && actor.clip_load < vaporizer_ammo) { // forced reload
 343                                 Weapon w = get_weaponinfo(actor.weapon);
 344                                 w.wr_reload(w);
 345                         }
 346                         if((fire & 1) && (actor.ammo_cells || !autocvar_g_rm) && !forbidWeaponUse(actor))
 347                         {
 348                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vaporizer, refire)))
 349                                 {
 350                                         W_Vaporizer_Attack(thiswep);
 351                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 352                                 }
 353                         }
 354                         if((fire & 2) || ((fire & 1) && !actor.ammo_cells && autocvar_g_rm))
 355                         {
 356                                 if((autocvar_g_rm && autocvar_g_rm_laser) || autocvar_g_rm_laser == 2)
 357                                 {
 358                                         bool rapid = autocvar_g_rm_laser_rapid;
 359                                         if(actor.jump_interval <= time && !actor.held_down)
 360                                         {
 361                                                 if(rapid)
 362                                                         actor.held_down = true;
 363                                                 actor.jump_interval = time + autocvar_g_rm_laser_refire;
 364                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_delay;
 365                                                 damage_goodhits = 0;
 366                                                 W_RocketMinsta_Attack2();
 367                                         }
 368                                         else if(rapid && actor.jump_interval2 <= time && actor.held_down)
 369                                         {
 370                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_refire;
 371                                                 damage_goodhits = 0;
 372                                                 W_RocketMinsta_Attack3();
 373                                                 //weapon_thinkf(actor, WFRAME_FIRE2, autocvar_g_rm_laser_rapid_animtime, w_ready);
 374                                         }
 375                                 }
 376                                 else if (actor.jump_interval <= time)
 377                                 {
 378                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 379                                         actor.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 380
 381                                         // decrease ammo for the laser?
 382                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 383                                                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(vaporizer, ammo));
 384
 385                                         // ugly instagib hack to reuse the fire mode of the laser
 386                                         makevectors(actor.v_angle);
 387                                         int oldwep = actor.weapon; // we can't avoid this hack
 388                                         actor.weapon = WEP_BLASTER.m_id;
 389                                         W_Blaster_Attack(
 390                                                 actor,
 391                                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 392                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 393                                                 WEP_CVAR_SEC(vaporizer, damage),
 394                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 395                                                 WEP_CVAR_SEC(vaporizer, radius),
 396                                                 WEP_CVAR_SEC(vaporizer, force),
 397                                                 WEP_CVAR_SEC(vaporizer, speed),
 398                                                 WEP_CVAR_SEC(vaporizer, spread),
 399                                                 WEP_CVAR_SEC(vaporizer, delay),
 400                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 401                                         );
 402                                         actor.weapon = oldwep;
 403
 404                                         // now do normal refire
 405                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 406                                 }
 407                         }
 408                         else
 409                                 actor.held_down = false;
 410                 }
 411                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 412                 {
 413                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 414                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 415                 }
 416                 METHOD(Vaporizer, wr_setup, void(entity thiswep))
 417                 {
 418                         self.ammo_field = WEP_AMMO(VAPORIZER);
 419                         self.vaporizer_lasthit = 0;
 420                 }
 421                 METHOD(Vaporizer, wr_checkammo1, bool(entity thiswep))
 422                 {
 423                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 424                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 425                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= vaporizer_ammo;
 426                         return ammo_amount;
 427                 }
 428                 METHOD(Vaporizer, wr_checkammo2, bool(entity thiswep))
 429                 {
 430                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 431                                 return true;
 432                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 433                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= WEP_CVAR_SEC(vaporizer, ammo);
 434                         return ammo_amount;
 435                 }
 436                 METHOD(Vaporizer, wr_config, void(entity thiswep))
 437                 {
 438                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 439                 }
 440                 METHOD(Vaporizer, wr_resetplayer, void(entity thiswep))
 441                 {
 442                         self.vaporizer_lasthit = 0;
 443                 }
 444                 METHOD(Vaporizer, wr_reload, void(entity thiswep))
 445                 {
 446                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 447                         float used_ammo;
 448                         if(WEP_CVAR_SEC(vaporizer, ammo))
 449                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 450                         else
 451                                 used_ammo = vaporizer_ammo;
 452
 453                         W_Reload(self, used_ammo, SND(RELOAD));
 454                 }
 455                 METHOD(Vaporizer, wr_suicidemessage, int(entity thiswep))
 456                 {
 457                         return WEAPON_THINKING_WITH_PORTALS;
 458                 }
 459                 METHOD(Vaporizer, wr_killmessage, int(entity thiswep))
 460                 {
 461                         return WEAPON_VAPORIZER_MURDER;
 462                 }
 463
 464 #endif
 465 #ifdef CSQC
 466
 467                 METHOD(Vaporizer, wr_impacteffect, void(entity thiswep))
 468                 {
 469                         vector org2 = w_org + w_backoff * 6;
 470                         if(w_deathtype & HITTYPE_SECONDARY)
 471                         {
 472                                 pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 473                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 474                         }
 475                         else
 476                         {
 477                                 pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 478                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM); }
 479                         }
 480                 }
 481                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 482                 {
 483                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 484                         {
 485                                 precache_pic("gfx/reticle_nex");
 486                         }
 487                 }
 488                 METHOD(Vaporizer, wr_zoomreticle, bool(entity thiswep))
 489                 {
 490                         if(button_zoom || zoomscript_caught)
 491                         {
 492                                 reticle_image = "gfx/reticle_nex";
 493                                 return true;
 494                         }
 495                         else
 496                         {
 497                                 // no weapon specific image for this weapon
 498                                 return false;
 499                         }
 500                 }
 501
 502 #endif
 503 #endif