qcsrc/menu/item/slider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
   3 #ifndef ITEM_SLIDER_H
   4 #define ITEM_SLIDER_H
   5 CLASS(Slider, Label)
   6         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string))
   8         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float))
   9         METHOD(Slider, draw, void(entity))
  10         METHOD(Slider, keyDown, float(entity, float, float, float))
  11         METHOD(Slider, keyUp, float(entity, float, float, float))
  12         METHOD(Slider, mousePress, float(entity, vector))
  13         METHOD(Slider, mouseDrag, float(entity, vector))
  14         METHOD(Slider, mouseRelease, float(entity, vector))
  15         METHOD(Slider, valueToText, string(entity, float))
  16         METHOD(Slider, toString, string(entity))
  17         METHOD(Slider, setValue, void(entity, float))
  18         METHOD(Slider, setSliderValue, void(entity, float))
  19         METHOD(Slider, showNotify, void(entity))
  20         ATTRIB(Slider, src, string, string_null)
  21         ATTRIB(Slider, focusable, float, 1)
  22         ATTRIB(Slider, allowFocusSound, float, 1)
  23         ATTRIB(Slider, value, float, 0)
  24         ATTRIB(Slider, animated, float, 1)
  25         ATTRIB(Slider, sliderValue, float, 0)
  26         ATTRIB(Slider, valueMin, float, 0)
  27         ATTRIB(Slider, valueMax, float, 0)
  28         ATTRIB(Slider, valueStep, float, 0)
  29         ATTRIB(Slider, valueDigits, float, 0)
  30         ATTRIB(Slider, valueKeyStep, float, 0)
  31         ATTRIB(Slider, valuePageStep, float, 0)
  32         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
  33         ATTRIB(Slider, textSpace, float, 0)
  34         ATTRIB(Slider, controlWidth, float, 0)
  35         ATTRIB(Slider, pressed, float, 0)
  36         ATTRIB(Slider, pressOffset, float, 0)
  37         ATTRIB(Slider, previousValue, float, 0)
  38         ATTRIB(Slider, tolerance, vector, '0 0 0')
  39         ATTRIB(Slider, disabled, float, 0)
  40         ATTRIB(Slider, color, vector, '1 1 1')
  41         ATTRIB(Slider, color2, vector, '1 1 1')
  42         ATTRIB(Slider, colorD, vector, '1 1 1')
  43         ATTRIB(Slider, colorC, vector, '1 1 1')
  44         ATTRIB(Slider, colorF, vector, '1 1 1')
  45         ATTRIB(Slider, disabledAlpha, float, 0.3)
  46 ENDCLASS(Slider)
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50 void Slider_setValue(entity me, float val)
  51 {
  52         if (me.animated) {
  53                 anim.removeObjAnim(anim, me);
  54                 makeHostedEasing(me, Slider_setSliderValue, easingQuadInOut, 1, me.sliderValue, val);
  55         } else {
  56                 me.setSliderValue(me, val);
  57         }
  58         me.value = val;
  59 }
  60 void Slider_setSliderValue(entity me, float val)
  61 {
  62         me.sliderValue = val;
  63 }
  64 string Slider_toString(entity me)
  65 {
  66         return sprintf("%d (%s)", me.value, me.valueToText(me, me.value));
  67 }
  68 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  69 {
  70         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  71         me.controlWidth = absSize.y / absSize.x;
  72 }
  73 string Slider_valueToText(entity me, float val)
  74 {
  75         if(almost_in_bounds(me.valueMin, val, me.valueMax))
  76                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
  77         return "";
  78 }
  79 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
  80 {
  81         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
  82         me.textSpace = theTextSpace;
  83         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
  84         me.src = gfx;
  85 }
  86 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
  87 {
  88         me.value = theValue;
  89         me.sliderValue = theValue;
  90         me.valueStep = theValueStep;
  91         me.valueMin = theValueMin;
  92         me.valueMax = theValueMax;
  93         me.valueKeyStep = theValueKeyStep;
  94         me.valuePageStep = theValuePageStep;
  95         me.valueDigits = 3;
  96         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
  97                 me.valueDigits = 2;
  98         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
  99                 me.valueDigits = 1;
 100         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
 101                 me.valueDigits = 0;
 102 }
 103 float Slider_keyDown(entity me, float key, float ascii, float shift)
 104 {
 105         float inRange;
 106         if(me.disabled)
 107                 return 0;
 108         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 109         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELDOWN)
 110         {
 111                 if(inRange)
 112                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
 113                 else
 114                         me.setValue(me, me.valueMax);
 115                 return 1;
 116         }
 117         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELUP)
 118         {
 119                 if(inRange)
 120                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
 121                 else
 122                         me.setValue(me, me.valueMin);
 123                 return 1;
 124         }
 125         if(key == K_PGDN || key == K_KP_PGDN)
 126         {
 127                 if(inRange)
 128                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
 129                 else
 130                         me.setValue(me, me.valueMax);
 131                 return 1;
 132         }
 133         if(key == K_PGUP || key == K_KP_PGUP)
 134         {
 135                 if(inRange)
 136                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
 137                 else
 138                         me.setValue(me, me.valueMin);
 139                 return 1;
 140         }
 141         if(key == K_HOME || key == K_KP_HOME)
 142         {
 143                 me.setValue(me, me.valueMin);
 144                 return 1;
 145         }
 146         if(key == K_END || key == K_KP_END)
 147         {
 148                 me.setValue(me, me.valueMax);
 149                 return 1;
 150         }
 151         // TODO more keys (NOTE also add them to Slider_keyUp)
 152         return 0;
 153 }
 154 float Slider_keyUp(entity me, float key, float ascii, float shift)
 155 {
 156         if(me.disabled)
 157                 return 0;
 158         switch(key)
 159         {
 160                 case K_LEFTARROW:
 161                 case K_KP_LEFTARROW:
 162                 case K_RIGHTARROW:
 163                 case K_KP_RIGHTARROW:
 164                 case K_PGUP:
 165                 case K_KP_PGUP:
 166                 case K_PGDN:
 167                 case K_KP_PGDN:
 168                 case K_HOME:
 169                 case K_KP_HOME:
 170                 case K_END:
 171                 case K_KP_END:
 172                         m_play_click_sound(MENU_SOUND_SLIDE);
 173         }
 174         return 0;
 175 }
 176 float Slider_mouseDrag(entity me, vector pos)
 177 {
 178         float hit;
 179         float v, animed;
 180         if(me.disabled)
 181                 return 0;
 182
 183         anim.removeObjAnim(anim, me);
 184         animed = me.animated;
 185         me.animated = false;
 186
 187         if(me.pressed)
 188         {
 189                 hit = 1;
 190                 if(pos.x < 0 - me.tolerance.x) hit = 0;
 191                 if(pos.y < 0 - me.tolerance.y) hit = 0;
 192                 if(pos.x >= 1 - me.textSpace + me.tolerance.x) hit = 0;
 193                 if(pos.y >= 1 + me.tolerance.y) hit = 0;
 194                 if(hit)
 195                 {
 196                         v = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 197                         if(me.valueStep)
 198                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
 199                         me.setValue(me, v);
 200                 }
 201                 else
 202                         me.setValue(me, me.previousValue);
 203         }
 204
 205         me.animated = animed;
 206
 207         return 1;
 208 }
 209 float Slider_mousePress(entity me, vector pos)
 210 {
 211         float controlCenter;
 212         if(me.disabled)
 213                 return 0;
 214         if(pos.x < 0) return 0;
 215         if(pos.y < 0) return 0;
 216         if(pos.x >= 1 - me.textSpace) return 0;
 217         if(pos.y >= 1) return 0;
 218         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 219         if(fabs(pos.x - controlCenter) <= 0.5 * me.controlWidth)
 220         {
 221                 me.pressed = 1;
 222                 me.pressOffset = pos.x - controlCenter;
 223                 me.previousValue = me.value;
 224                 //me.mouseDrag(me, pos);
 225         }
 226         else
 227         {
 228                 float clickValue, pageValue, inRange;
 229                 clickValue = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 230                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 231                 if(pos.x < controlCenter)
 232                 {
 233                         pageValue = me.value - me.valuePageStep;
 234                         if(me.valueStep)
 235                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
 236                         pageValue = max(pageValue, clickValue);
 237                         if(inRange)
 238                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 239                         else
 240                                 me.setValue(me, me.valueMax);
 241                 }
 242                 else
 243                 {
 244                         pageValue = me.value + me.valuePageStep;
 245                         if(me.valueStep)
 246                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
 247                         pageValue = min(pageValue, clickValue);
 248                         if(inRange)
 249                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 250                         else
 251                                 me.setValue(me, me.valueMax);
 252                 }
 253                 if(pageValue == clickValue)
 254                 {
 255                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 256                         me.pressed = 1;
 257                         me.pressOffset = pos.x - controlCenter;
 258                         me.previousValue = me.value;
 259                         //me.mouseDrag(me, pos);
 260                 }
 261         }
 262         return 1;
 263 }
 264 float Slider_mouseRelease(entity me, vector pos)
 265 {
 266         me.pressed = 0;
 267         if(me.disabled)
 268                 return 0;
 269         m_play_click_sound(MENU_SOUND_SLIDE);
 270         return 1;
 271 }
 272 void Slider_showNotify(entity me)
 273 {
 274         me.focusable = !me.disabled;
 275 }
 276 void Slider_draw(entity me)
 277 {
 278         float controlLeft;
 279         float save;
 280         me.focusable = !me.disabled;
 281         save = draw_alpha;
 282         if(me.disabled)
 283                 draw_alpha *= me.disabledAlpha;
 284         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
 285         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
 286         {
 287                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
 288                 if(me.disabled)
 289                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
 290                 else if(me.pressed)
 291                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
 292                 else if(me.focused)
 293                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
 294                 else
 295                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
 296         }
 297         me.setText(me, me.valueToText(me, me.value));
 298         draw_alpha = save;
 299         SUPER(Slider).draw(me);
 300         me.text = string_null; // TEMPSTRING!
 301 }
 302 #endif