f4bd359ece79d350a1034427607a470a7dd374db
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / dialog_multiplayer_playersetup.c
1 #ifdef INTERFACE
2 CLASS(XonoticPlayerSettingsTab) EXTENDS(XonoticTab)
3         METHOD(XonoticPlayerSettingsTab, fill, void(entity))
4         METHOD(XonoticPlayerSettingsTab, draw, void(entity))
5         ATTRIB(XonoticPlayerSettingsTab, title, string, _("Player Setup"))
6         ATTRIB(XonoticPlayerSettingsTab, intendedWidth, float, 0.9)
7         ATTRIB(XonoticPlayerSettingsTab, rows, float, 22)
8         ATTRIB(XonoticPlayerSettingsTab, columns, float, 6.2) // added extra .2 for center space
9         ATTRIB(XonoticPlayerSettingsTab, playerNameLabel, entity, NULL)
10         ATTRIB(XonoticPlayerSettingsTab, playerNameLabelAlpha, float, 0)
11 ENDCLASS(XonoticPlayerSettingsTab)
12 entity makeXonoticPlayerSettingsTab();
13 #endif
14
15 #ifdef IMPLEMENTATION
16 entity makeXonoticPlayerSettingsTab()
17 {
18         entity me;
19         me = spawnXonoticPlayerSettingsTab();
20         me.configureDialog(me);
21         return me;
22 }
23 void XonoticPlayerSettingsTab_draw(entity me)
24 {
25         if(cvar_string("_cl_name") == "Player")
26                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
27         else
28                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
29         SUPER(XonoticPlayerSettingsTab).draw(me);
30 }
31 void XonoticPlayerSettingsTab_fill(entity me)
32 {
33         entity e, pms, label, box;
34         float i;
35
36         me.TR(me);
37                 me.TD(me, 1, 0.5, me.playerNameLabel = makeXonoticTextLabel(0, _("Name:")));
38                         me.playerNameLabelAlpha = me.playerNameLabel.alpha;
39                 me.TD(me, 1, 2.5, label = makeXonoticTextLabel(0, string_null));
40                         label.allowCut = 1;
41                         label.allowColors = 1;
42                         label.alpha = 1;
43         me.TR(me);
44                 me.TD(me, 1, 3.0, box = makeXonoticInputBox(1, "_cl_name"));
45                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
46                         box.maxLength = -127; // negative means encoded length in bytes
47                         box.saveImmediately = 1;
48                         box.enableClearButton = 0;
49                         label.textEntity = box;
50         me.TR(me);
51                 me.TD(me, 5, 1, e = makeXonoticColorpicker(box));
52                 me.TD(me, 5, 2, e = makeXonoticCharmap(box));
53         me.TR(me);
54         me.TR(me);
55         me.TR(me);
56         me.TR(me);
57         me.TR(me);
58
59         me.TR(me);
60                 me.TDempty(me, 1);
61                 me.TD(me, 1, 2, e = makeXonoticTextLabel(0.5, _("Model:")));
62         me.TR(me);
63                 me.TDempty(me, 1);
64                 pms = makeXonoticPlayerModelSelector();
65                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
66                         e.onClick = PlayerModelSelector_Prev_Click;
67                         e.onClickEntity = pms;
68                 me.TD(me, me.rows - (me.currentRow + 2), 1.4, pms);
69                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
70                         e.onClick = PlayerModelSelector_Next_Click;
71                         e.onClickEntity = pms;
72         me.TR(me);
73                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0.5, _("Glowing color:")));
74                 for(i = 0; i < 15; ++i)
75                 {
76                         if(mod(i, 5) == 0)
77                                 me.TR(me);
78                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(1, 0, i), '0 1 0');
79                 }
80         me.TR(me);
81         me.TR(me);
82                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0.5, _("Detail color:")));
83                 for(i = 0; i < 15; ++i)
84                 {
85                         if(mod(i, 5) == 0)
86                                 me.TR(me);
87                         me.TDNoMargin(me, 1, 0.2, e = makeXonoticColorButton(2, 1, i), '0 1 0');
88                 }
89
90         // crosshair_enabled: 0 = no crosshair options, 1 = no crosshair selection, but everything else enabled, 2 = all crosshair options enabled
91         // FIXME: In the future, perhaps make one global crosshair_type cvar which has 0 for disabled, 1 for custom, 2 for per weapon, etc?
92         me.gotoRC(me, 0, 3.2); me.setFirstColumn(me, me.currentColumn);
93                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_enabled", "0", _("No crosshair")));
94         me.TR(me);
95                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_per_weapon", string_null, _("Per weapon crosshair")));
96                 makeMulti(e, "crosshair_enabled");
97         me.TR(me);
98                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_enabled", "2", _("Custom crosshair")));
99         me.TR(me);
100                 me.TDempty(me, 0.1);
101                 for(i = 1; i <= 14; ++i) {
102                         me.TDNoMargin(me, 1, 2 / 14, e = makeXonoticCrosshairButton(4, i), '1 1 0');
103                                 setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
104                 }
105                 // show a larger preview of the selected crosshair
106                 me.TDempty(me, 0.1);
107                 me.TDNoMargin(me, 3, 0.8, e = makeXonoticCrosshairButton(7, -1), '1 1 0'); // crosshair -1 makes this a preview
108                         setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
109         me.TR(me);
110                 me.TDempty(me, 0.1);
111                 for(i = 15; i <= 28; ++i) {
112                         me.TDNoMargin(me, 1, 2 / 14, e = makeXonoticCrosshairButton(4, i), '1 1 0');
113                                 setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
114                 }
115         me.TR(me);
116         me.TR(me);
117                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair size:")));
118                         setDependent(e, "crosshair_enabled", 1, 2);
119                 me.TD(me, 1, 2, e = makeXonoticSlider(0.1, 1.0, 0.01, "crosshair_size"));
120                         setDependent(e, "crosshair_enabled", 1, 2);
121         me.TR(me);
122                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair alpha:")));
123                         setDependent(e, "crosshair_enabled", 1, 2);
124                 me.TD(me, 1, 2, e = makeXonoticSlider(0, 1, 0.1, "crosshair_alpha"));
125                         setDependent(e, "crosshair_enabled", 1, 2);
126         me.TR(me);
127         me.TR(me);
128                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair color:")));
129                         setDependent(e, "crosshair_enabled", 1, 2);
130                 me.TD(me, 1, 1, e = makeXonoticRadioButton(5, "crosshair_color_special", "1", _("Per weapon")));
131                         setDependent(e, "crosshair_enabled", 1, 2);
132                 me.TD(me, 1, 1, e = makeXonoticRadioButton(5, "crosshair_color_special", "2", _("By health")));
133                         setDependent(e, "crosshair_enabled", 1, 2);
134         me.TR(me);
135                 me.TDempty(me, 0.1);
136                 me.TD(me, 1, 0.9, e = makeXonoticRadioButton(5, "crosshair_color_special", "0", _("Custom")));
137                         setDependent(e, "crosshair_enabled", 1, 2);
138                 me.TD(me, 2, 2, e = makeXonoticColorpickerString("crosshair_color", "crosshair_color"));
139                         setDependentAND(e, "crosshair_color_special", 0, 0, "crosshair_enabled", 1, 2);
140         me.TR(me);
141         me.TR(me);
142         me.TR(me);
143                 me.TDempty(me, 0.5);
144                 me.TD(me, 1, 2, e = makeXonoticButton(_("Other crosshair settings"), '0 0 0'));
145                         e.onClick = DialogOpenButton_Click;
146                         e.onClickEntity = main.crosshairDialog;
147                 setDependent(e, "crosshair_enabled", 1, 2);
148                 // TODO: show status of crosshair dot and hittest and pickups and such here with text
149         me.TR(me);
150         me.TR(me);
151                 me.TDempty(me, 0.5);
152                 me.TD(me, 1, 2, e = makeXonoticButton(_("Model settings"), '0 0 0'));
153                         e.onClick = DialogOpenButton_Click;
154                         e.onClickEntity = main.modelDialog;
155                 // TODO: show csqc model settings like forcemyplayer and deglowing/ghosting bodies with text here
156         me.TR(me);
157                 me.TDempty(me, 0.5);
158                 me.TD(me, 1, 2, e = makeXonoticButton(_("View settings"), '0 0 0'));
159                         e.onClick = DialogOpenButton_Click;
160                         e.onClickEntity = main.viewDialog;
161                 // TODO: show fov and other settings with text here
162         me.TR(me);
163                 me.TDempty(me, 0.5);
164                 me.TD(me, 1, 2, e = makeXonoticButton(_("Weapon settings"), '0 0 0'));
165                         e.onClick = DialogOpenButton_Click;
166                         e.onClickEntity = main.weaponsDialog;
167                 // I don't really think this is useful as is, and especially it doesn't look very clean...
168                 // In the future, if ALL of these buttons had some information, then it would be justified/clean
169                 //me.TD(me, 1, 1, e0 = makeXonoticTextLabel(0, string_null));
170                 //      e0.textEntity = main.weaponsDialog;
171                 //      e0.allowCut = 1;
172         me.TR(me);
173                 me.TDempty(me, 0.5);
174                 me.TD(me, 1, 2, e = makeXonoticButton(_("HUD settings"), '0 0 0'));
175                         e.onClick = DialogOpenButton_Click;
176                         e.onClickEntity = main.hudDialog;
177                 // TODO: show hud config name with text here
178
179         me.gotoRC(me, me.rows - 1, 0);
180                 me.TD(me, 1, me.columns, makeXonoticCommandButton(_("Apply immediately"), '0 0 0', "color -1 -1;name \"$_cl_name\";sendcvar cl_weaponpriority;sendcvar cl_autoswitch;sendcvar cl_forceplayermodels;sendcvar cl_forceplayermodelsfromxonotic;playermodel $_cl_playermodel;playerskin $_cl_playerskin", COMMANDBUTTON_APPLY));
181 }
182 #endif